guix/gnu-maintenance.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2010, 2011, 2012, 2013, 2014, 2015 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2012, 2013 Nikita Karetnikov <nikita@karetnikov.org>
   4 ;;;
   5 ;;; This file is part of GNU Guix.
   6 ;;;
   7 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   8 ;;; under the terms of the GNU General Public License as published by
   9 ;;; the Free Software Foundation; either version 3 of the License, or (at
  10 ;;; your option) any later version.
  11 ;;;
  12 ;;; GNU Guix is distributed in the hope that it will be useful, but
  13 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;;; GNU General Public License for more details.
  16 ;;;
  17 ;;; You should have received a copy of the GNU General Public License
  18 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 (define-module (guix gnu-maintenance)
  21   #:use-module (web uri)
  22   #:use-module (web client)
  23   #:use-module (web response)
  24   #:use-module (ice-9 regex)
  25   #:use-module (ice-9 match)
  26   #:use-module (srfi srfi-1)
  27   #:use-module (srfi srfi-11)
  28   #:use-module (srfi srfi-26)
  29   #:use-module (system foreign)
  30   #:use-module (guix http-client)
  31   #:use-module (guix ftp-client)
  32   #:use-module (guix utils)
  33   #:use-module (guix records)
  34   #:use-module (guix upstream)
  35   #:use-module (guix packages)
  36   #:export (gnu-package-name
  37             gnu-package-mundane-name
  38             gnu-package-copyright-holder
  39             gnu-package-savannah
  40             gnu-package-fsd
  41             gnu-package-language
  42             gnu-package-logo
  43             gnu-package-doc-category
  44             gnu-package-doc-summary
  45             gnu-package-doc-description
  46             gnu-package-doc-urls
  47             gnu-package-download-url
  48
  49             official-gnu-packages
  50             find-packages
  51             gnu-package?
  52
  53             release-file?
  54             releases
  55             latest-release
  56             gnu-release-archive-types
  57             gnu-package-name->name+version
  58
  59             %gnu-updater
  60             %gnome-updater
  61             %xorg-updater))
  62
  63 ;;; Commentary:
  64 ;;;
  65 ;;; Code for dealing with the maintenance of GNU packages, such as
  66 ;;; auto-updates.
  67 ;;;
  68 ;;; Code:
  69
  70 \f
  71 ;;;
  72 ;;; List of GNU packages.
  73 ;;;
  74
  75 (define %gnumaint-base-url
  76   "http://cvs.savannah.gnu.org/viewvc/*checkout*/gnumaint/")
  77
  78 (define %package-list-url
  79   (string->uri
  80    (string-append %gnumaint-base-url "gnupackages.txt?root=womb")))
  81
  82 (define %package-description-url
  83   ;; This file contains package descriptions in recutils format.
  84   ;; See <https://lists.gnu.org/archive/html/guix-devel/2013-10/msg00071.html>.
  85   (string->uri
  86    (string-append %gnumaint-base-url "pkgblurbs.txt?root=womb")))
  87
  88 (define-record-type* <gnu-package-descriptor>
  89   gnu-package-descriptor
  90   make-gnu-package-descriptor
  91
  92   gnu-package-descriptor?
  93
  94   (name             gnu-package-name)
  95   (mundane-name     gnu-package-mundane-name)
  96   (copyright-holder gnu-package-copyright-holder)
  97   (savannah         gnu-package-savannah)
  98   (fsd              gnu-package-fsd)
  99   (language         gnu-package-language)         ; list of strings
 100   (logo             gnu-package-logo)
 101   (doc-category     gnu-package-doc-category)
 102   (doc-summary      gnu-package-doc-summary)
 103   (doc-description  gnu-package-doc-description)  ; taken from 'pkgdescr.txt'
 104   (doc-urls         gnu-package-doc-urls)         ; list of strings
 105   (download-url     gnu-package-download-url))
 106
 107 (define* (official-gnu-packages
 108           #:optional (fetch http-fetch/cached))
 109   "Return a list of records, which are GNU packages.  Use FETCH,
 110 to fetch the list of GNU packages over HTTP."
 111   (define (read-records port)
 112     ;; Return a list of alists.  Each alist contains fields of a GNU
 113     ;; package.
 114     (let loop ((alist  (recutils->alist port))
 115                (result '()))
 116       (if (null? alist)
 117           (reverse result)
 118           (loop (recutils->alist port)
 119                 (cons alist result)))))
 120
 121   (define official-description
 122     (let ((db (read-records (fetch %package-description-url #:text? #t))))
 123       (lambda (name)
 124         ;; Return the description found upstream for package NAME, or #f.
 125         (and=> (find (lambda (alist)
 126                        (equal? name (assoc-ref alist "package")))
 127                      db)
 128                (lambda (record)
 129                  (let ((field (assoc-ref record "blurb")))
 130                    ;; The upstream description file uses "redirect PACKAGE" as
 131                    ;; a blurb in cases where the description of the two
 132                    ;; packages should be considered the same (e.g., GTK+ has
 133                    ;; "redirect gnome".)  This is usually not acceptable for
 134                    ;; us because we prefer to have distinct descriptions in
 135                    ;; such cases.  Thus, ignore the 'blurb' field when that
 136                    ;; happens.
 137                    (and field
 138                         (not (string-prefix? "redirect " field))
 139                         field)))))))
 140
 141   (map (lambda (alist)
 142          (let ((name (assoc-ref alist "package")))
 143            (alist->record `(("description" . ,(official-description name))
 144                             ,@alist)
 145                           make-gnu-package-descriptor
 146                           (list "package" "mundane-name" "copyright-holder"
 147                                 "savannah" "fsd" "language" "logo"
 148                                 "doc-category" "doc-summary" "description"
 149                                 "doc-url"
 150                                 "download-url")
 151                           '("doc-url" "language"))))
 152        (let* ((port (fetch %package-list-url #:text? #t))
 153               (lst  (read-records port)))
 154          (close-port port)
 155          lst)))
 156
 157 (define (find-packages regexp)
 158   "Find GNU packages which satisfy REGEXP."
 159   (let ((name-rx (make-regexp regexp)))
 160     (filter (lambda (package)
 161               (false-if-exception
 162                (regexp-exec name-rx (gnu-package-name package))))
 163             (official-gnu-packages))))
 164
 165 (define gnu-package?
 166   (memoize
 167    (let ((official-gnu-packages (memoize official-gnu-packages)))
 168      (lambda (package)
 169        "Return true if PACKAGE is a GNU package.  This procedure may access the
 170 network to check in GNU's database."
 171        (define (mirror-type url)
 172          (let ((uri (string->uri url)))
 173            (and (eq? (uri-scheme uri) 'mirror)
 174                 (cond
 175                  ((member (uri-host uri)
 176                           '("gnu" "gnupg" "gcc" "gnome"))
 177                   ;; Definitely GNU.
 178                   'gnu)
 179                  ((equal? (uri-host uri) "cran")
 180                   ;; Possibly GNU: mirror://cran could be either GNU R itself
 181                   ;; or a non-GNU package.
 182                   #f)
 183                  (else
 184                   ;; Definitely non-GNU.
 185                   'non-gnu)))))
 186
 187        (define (gnu-home-page? package)
 188          (and=> (package-home-page package)
 189                 (lambda (url)
 190                   (and=> (uri-host (string->uri url))
 191                          (lambda (host)
 192                            (member host '("www.gnu.org" "gnu.org")))))))
 193
 194        (or (gnu-home-page? package)
 195            (let ((url  (and=> (package-source package) origin-uri))
 196                  (name (package-name package)))
 197              (case (and (string? url) (mirror-type url))
 198                ((gnu) #t)
 199                ((non-gnu) #f)
 200                (else
 201                 (and (member name (map gnu-package-name (official-gnu-packages)))
 202                      #t)))))))))
 203
 204 \f
 205 ;;;
 206 ;;; Latest release.
 207 ;;;
 208
 209 (define (ftp-server/directory package)
 210   "Return the FTP server and directory where PACKAGE's tarball are stored."
 211   (values (or (assoc-ref (package-properties package) 'ftp-server)
 212               "ftp.gnu.org")
 213           (or (assoc-ref (package-properties package) 'ftp-directory)
 214               (string-append "/gnu/" (package-name package)))))
 215
 216 (define (sans-extension tarball)
 217   "Return TARBALL without its .tar.* or .zip extension."
 218   (let ((end (or (string-contains tarball ".tar")
 219                  (string-contains tarball ".zip"))))
 220     (substring tarball 0 end)))
 221
 222 (define %tarball-rx
 223   ;; The .zip extensions is notably used for freefont-ttf.
 224   ;; The "-src" pattern is for "TeXmacs-1.0.7.9-src.tar.gz".
 225   ;; The "-gnu[0-9]" pattern is for "icecat-38.4.0-gnu1.tar.bz2".
 226   (make-regexp "^([^.]+)-([0-9]|[^-])+(-(src|gnu[0-9]))?\\.(tar\\.|zip$)"))
 227
 228 (define %alpha-tarball-rx
 229   (make-regexp "^.*-.*[0-9](-|~)?(alpha|beta|rc|cvs|svn|git)-?[0-9\\.]*\\.tar\\."))
 230
 231 (define (release-file? project file)
 232   "Return #f if FILE is not a release tarball of PROJECT, otherwise return
 233 true."
 234   (and (not (string-suffix? ".sig" file))
 235        (and=> (regexp-exec %tarball-rx file)
 236               (lambda (match)
 237                 ;; Filter out unrelated files, like `guile-www-1.1.1'.
 238                 ;; Case-insensitive for things like "TeXmacs" vs. "texmacs".
 239                 ;; The "-src" suffix is for "freefont-src-20120503.tar.gz".
 240                 (and=> (match:substring match 1)
 241                        (lambda (name)
 242                          (or (string-ci=? name project)
 243                              (string-ci=? name
 244                                           (string-append project
 245                                                          "-src")))))))
 246        (not (regexp-exec %alpha-tarball-rx file))
 247        (let ((s (sans-extension file)))
 248          (regexp-exec %package-name-rx s))))
 249
 250 (define (tarball->version tarball)
 251   "Return the version TARBALL corresponds to.  TARBALL is a file name like
 252 \"coreutils-8.23.tar.xz\"."
 253   (let-values (((name version)
 254                 (gnu-package-name->name+version (sans-extension tarball))))
 255     version))
 256
 257 (define* (releases project
 258                    #:key
 259                    (server "ftp.gnu.org")
 260                    (directory (string-append "/gnu/" project)))
 261   "Return the list of <upstream-release> of PROJECT as a list of release
 262 name/directory pairs."
 263   ;; TODO: Parse something like fencepost.gnu.org:/gd/gnuorg/packages-ftp.
 264   (define conn (ftp-open server))
 265
 266   (let loop ((directories (list directory))
 267              (result      '()))
 268     (match directories
 269       (()
 270        (ftp-close conn)
 271        (coalesce-sources result))
 272       ((directory rest ...)
 273        (let* ((files   (ftp-list conn directory))
 274               (subdirs (filter-map (match-lambda
 275                                      ((name 'directory . _) name)
 276                                      (_ #f))
 277                                    files)))
 278          (define (file->url file)
 279            (string-append "ftp://" server directory "/" file))
 280
 281          (define (file->source file)
 282            (let ((url (file->url file)))
 283              (upstream-source
 284               (package project)
 285               (version (tarball->version file))
 286               (urls (list url))
 287               (signature-urls (list (string-append url ".sig"))))))
 288
 289          (loop (append (map (cut string-append directory "/" <>)
 290                             subdirs)
 291                        rest)
 292                (append
 293                 ;; Filter out signatures, deltas, and files which
 294                 ;; are potentially not releases of PROJECT--e.g.,
 295                 ;; in /gnu/guile, filter out guile-oops and
 296                 ;; guile-www; in mit-scheme, filter out binaries.
 297                 (filter-map (match-lambda
 298                               ((file 'file . _)
 299                                (and (release-file? project file)
 300                                     (file->source file)))
 301                               (_ #f))
 302                             files)
 303                 result)))))))
 304
 305 (define* (latest-ftp-release project
 306                              #:key
 307                              (server "ftp.gnu.org")
 308                              (directory (string-append "/gnu/" project))
 309                              (keep-file? (const #t))
 310                              (file->signature (cut string-append <> ".sig"))
 311                              (ftp-open ftp-open) (ftp-close ftp-close))
 312   "Return an <upstream-source> for the latest release of PROJECT on SERVER
 313 under DIRECTORY, or #f.  Use FTP-OPEN and FTP-CLOSE to open (resp. close) FTP
 314 connections; this can be useful to reuse connections.
 315
 316 KEEP-FILE? is a predicate to decide whether to enter a directory and to
 317 consider a given file (source tarball) as a valid candidate based on its name.
 318
 319 FILE->SIGNATURE must be a procedure; it is passed a source file URL and must
 320 return the corresponding signature URL, or #f it signatures are unavailable."
 321   (define (latest a b)
 322     (if (version>? a b) a b))
 323
 324   (define (latest-release a b)
 325     (if (version>? (upstream-source-version a) (upstream-source-version b))
 326         a b))
 327
 328   (define contains-digit?
 329     (cut string-any char-set:digit <>))
 330
 331   (define patch-directory-name?
 332     ;; Return #t for patch directory names such as 'bash-4.2-patches'.
 333     (cut string-suffix? "patches" <>))
 334
 335   (define conn (ftp-open server))
 336
 337   (define (file->url directory file)
 338     (string-append "ftp://" server directory "/" file))
 339
 340   (define (file->source directory file)
 341     (let ((url (file->url directory file)))
 342       (upstream-source
 343        (package project)
 344        (version (tarball->version file))
 345        (urls (list url))
 346        (signature-urls (match (file->signature url)
 347                          (#f #f)
 348                          (sig (list sig)))))))
 349
 350   (let loop ((directory directory)
 351              (result    #f))
 352     (let* ((entries (ftp-list conn directory))
 353
 354            ;; Filter out sub-directories that do not contain digits---e.g.,
 355            ;; /gnuzilla/lang and /gnupg/patches.  Filter out "w32"
 356            ;; directories as found on ftp.gnutls.org.
 357            (subdirs (filter-map (match-lambda
 358                                   (((? patch-directory-name? dir)
 359                                     'directory . _)
 360                                    #f)
 361                                   (("w32" 'directory . _)
 362                                    #f)
 363                                   (((? contains-digit? dir) 'directory . _)
 364                                    (and (keep-file? dir) dir))
 365                                   (_ #f))
 366                                 entries))
 367
 368            ;; Whether or not SUBDIRS is empty, compute the latest releases
 369            ;; for the current directory.  This is necessary for packages
 370            ;; such as 'sharutils' that have a sub-directory that contains
 371            ;; only an older release.
 372            (releases (filter-map (match-lambda
 373                                    ((file 'file . _)
 374                                     (and (release-file? project file)
 375                                          (keep-file? file)
 376                                          (file->source directory file)))
 377                                    (_ #f))
 378                                  entries)))
 379
 380       ;; Assume that SUBDIRS correspond to versions, and jump into the
 381       ;; one with the highest version number.
 382       (let* ((release  (reduce latest-release #f
 383                                (coalesce-sources releases)))
 384              (result   (if (and result release)
 385                            (latest-release release result)
 386                            (or release result)))
 387              (target   (reduce latest #f subdirs)))
 388         (if target
 389             (loop (string-append directory "/" target)
 390                   result)
 391             (begin
 392               (ftp-close conn)
 393               result))))))
 394
 395 (define* (latest-release package
 396                          #:key
 397                          (server "ftp.gnu.org")
 398                          (directory (string-append "/gnu/" package)))
 399   "Return the <upstream-source> for the latest version of PACKAGE or #f.
 400 PACKAGE must be the canonical name of a GNU package."
 401   (latest-ftp-release package
 402                       #:server server
 403                       #:directory directory))
 404
 405 (define-syntax-rule (false-if-ftp-error exp)
 406   "Return #f if an FTP error is raise while evaluating EXP; return the result
 407 of EXP otherwise."
 408   (catch 'ftp-error
 409     (lambda ()
 410       exp)
 411     (lambda (key port . rest)
 412       (if (ftp-connection? port)
 413           (ftp-close port)
 414           (close-port port))
 415       #f)))
 416
 417 (define (latest-release* package)
 418   "Like 'latest-release', but (1) take a <package> object, and (2) ignore FTP
 419 errors that might occur when PACKAGE is not actually a GNU package, or not
 420 hosted on ftp.gnu.org, or not under that name (this is the case for
 421 \"emacs-auctex\", for instance.)"
 422   (let-values (((server directory)
 423                 (ftp-server/directory package)))
 424     (let ((name (or (assoc-ref (package-properties package) 'upstream-name)
 425                     (package-name package))))
 426       (false-if-ftp-error (latest-release name
 427                                           #:server server
 428                                           #:directory directory)))))
 429
 430 (define %package-name-rx
 431   ;; Regexp for a package name, e.g., "foo-X.Y".  Since TeXmacs uses
 432   ;; "TeXmacs-X.Y-src", the `-src' suffix is allowed.
 433   (make-regexp "^(.*)-(([0-9]|\\.)+)(-src)?"))
 434
 435 (define (gnu-package-name->name+version name+version)
 436   "Return the package name and version number extracted from NAME+VERSION."
 437   (let ((match (regexp-exec %package-name-rx name+version)))
 438     (if (not match)
 439         (values name+version #f)
 440         (values (match:substring match 1) (match:substring match 2)))))
 441
 442 (define (pure-gnu-package? package)
 443   "Return true if PACKAGE is a non-Emacs and non-GNOME GNU package.  This
 444 excludes AucTeX, for instance, whose releases are now uploaded to
 445 elpa.gnu.org, and all the GNOME packages."
 446   (and (not (string-prefix? "emacs-" (package-name package)))
 447        (not (gnome-package? package))
 448        (gnu-package? package)))
 449
 450 (define (gnome-package? package)
 451   "Return true if PACKAGE is a GNOME package, hosted on gnome.org."
 452   (define gnome-uri?
 453     (match-lambda
 454       ((? string? uri)
 455        (string-prefix? "mirror://gnome/" uri))
 456       (_
 457        #f)))
 458
 459   (match (package-source package)
 460     ((? origin? origin)
 461      (match (origin-uri origin)
 462        ((? gnome-uri?) #t)
 463        (_              #f)))
 464     (_ #f)))
 465
 466 (define (latest-gnome-release package)
 467   "Return the latest release of PACKAGE, the name of a GNOME package."
 468   (define %not-dot
 469     (char-set-complement (char-set #\.)))
 470
 471   (define (even-minor-version? version)
 472     (match (string-tokenize version %not-dot)
 473       (((= string->number major) (= string->number minor) . rest)
 474        (and minor (even? minor)))
 475       (_
 476        #t)))                                      ;cross fingers
 477
 478   (define (even-numbered? file)
 479     ;; Return true if FILE somehow denotes an even-numbered file name.  The
 480     ;; trick here is that we want this to match both directories such as
 481     ;; "3.18.6" and actual file names such as "gtk+-3.18.6.tar.bz2".
 482     (let-values (((name version) (package-name->name+version file)))
 483       (even-minor-version? (or version name))))
 484
 485   (false-if-ftp-error
 486    (latest-ftp-release (package-name package)
 487                        #:server "ftp.gnome.org"
 488                        #:directory (string-append "/pub/gnome/sources/"
 489                                                   (match (package-name package)
 490                                                     ("gconf" "GConf")
 491                                                     (x       x)))
 492
 493
 494                        ;; <https://www.gnome.org/gnome-3/source/> explains
 495                        ;; that odd minor version numbers represent development
 496                        ;; releases, which we are usually not interested in.
 497                        #:keep-file? even-numbered?
 498
 499                        ;; ftp.gnome.org provides no signatures, only
 500                        ;; checksums.
 501                        #:file->signature (const #f))))
 502
 503 (define (xorg-package? package)
 504   "Return true if PACKAGE is an X.org package, developed by X.org."
 505   (define xorg-uri?
 506     (match-lambda
 507       ((? string? uri)
 508        (string-prefix? "mirror://xorg/" uri))
 509       (_
 510        #f)))
 511
 512   (match (package-source package)
 513     ((? origin? origin)
 514      (match (origin-uri origin)
 515        ((? xorg-uri?) #t)
 516        (_              #f)))
 517     (_ #f)))
 518
 519 (define (latest-xorg-release package)
 520   "Return the latest release of PACKAGE, the name of an X.org package."
 521   (let ((uri (string->uri (origin-uri (package-source package)))))
 522     (false-if-ftp-error
 523      (latest-ftp-release
 524       (package-name package)
 525       #:server "ftp.freedesktop.org"
 526       #:directory
 527       (string-append "/pub/xorg/" (dirname (uri-path uri)))))))
 528
 529 (define %gnu-updater
 530   (upstream-updater
 531    (name 'gnu)
 532    (description "Updater for GNU packages")
 533    (pred pure-gnu-package?)
 534    (latest latest-release*)))
 535
 536 (define %gnome-updater
 537   (upstream-updater
 538    (name 'gnome)
 539    (description "Updater for GNOME packages")
 540    (pred gnome-package?)
 541    (latest latest-gnome-release)))
 542
 543 (define %xorg-updater
 544   (upstream-updater
 545    (name 'xorg)
 546    (description "Updater for X.org packages")
 547    (pred xorg-package?)
 548    (latest latest-xorg-release)))
 549
 550 ;;; gnu-maintenance.scm ends here