build-aux/build-self.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2014, 2016, 2017, 2018, 2019 Ludovic Courtès <ludo@gnu.org>
   3 ;;;
   4 ;;; This file is part of GNU Guix.
   5 ;;;
   6 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU General Public License as published by
   8 ;;; the Free Software Foundation; either version 3 of the License, or (at
   9 ;;; your option) any later version.
  10 ;;;
  11 ;;; GNU Guix is distributed in the hope that it will be useful, but
  12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;; GNU General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU General Public License
  17 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 (define-module (build-self)
  20   #:use-module (gnu)
  21   #:use-module (guix)
  22   #:use-module (guix ui)
  23   #:use-module (guix config)
  24   #:use-module (guix modules)
  25   #:use-module (guix build-system gnu)
  26   #:use-module (srfi srfi-1)
  27   #:use-module (srfi srfi-19)
  28   #:use-module (srfi srfi-34)
  29   #:use-module (srfi srfi-35)
  30   #:use-module (rnrs io ports)
  31   #:use-module (ice-9 match)
  32   #:use-module (ice-9 popen)
  33   #:export (build))
  34
  35 ;;; Commentary:
  36 ;;;
  37 ;;; When loaded, this module returns a monadic procedure of at least one
  38 ;;; argument: the source tree to build.  It returns a derivation that
  39 ;;; builds it.
  40 ;;;
  41 ;;; This file uses modules provided by the already-installed Guix.  Those
  42 ;;; modules may be arbitrarily old compared to the version we want to
  43 ;;; build.  Because of that, it must rely on the smallest set of features
  44 ;;; that are likely to be provided by the (guix) and (gnu) modules, and by
  45 ;;; Guile itself, forever and ever.
  46 ;;;
  47 ;;; Code:
  48
  49 \f
  50 ;;;
  51 ;;; Generating (guix config).
  52 ;;;
  53 ;;; This is copied from (guix self) because we cannot assume (guix self) is
  54 ;;; available at this point.
  55 ;;;
  56
  57 (define %dependency-variables
  58   ;; (guix config) variables corresponding to dependencies.
  59   '(%libgcrypt %libz %xz %gzip %bzip2))
  60
  61 (define %persona-variables
  62   ;; (guix config) variables that define Guix's persona.
  63   '(%guix-package-name
  64     %guix-version
  65     %guix-bug-report-address
  66     %guix-home-page-url))
  67
  68 (define %config-variables
  69   ;; (guix config) variables corresponding to Guix configuration.
  70   (letrec-syntax ((variables (syntax-rules ()
  71                                ((_)
  72                                 '())
  73                                ((_ variable rest ...)
  74                                 (cons `(variable . ,variable)
  75                                       (variables rest ...))))))
  76     (variables %localstatedir %storedir %sysconfdir %system)))
  77
  78 (define* (make-config.scm #:key zlib gzip xz bzip2
  79                           (package-name "GNU Guix")
  80                           (package-version "0")
  81                           (bug-report-address "bug-guix@gnu.org")
  82                           (home-page-url "https://gnu.org/s/guix"))
  83
  84   ;; Hack so that Geiser is not confused.
  85   (define defmod 'define-module)
  86
  87   (scheme-file "config.scm"
  88                #~(begin
  89                    (#$defmod (guix config)
  90                      #:export (%guix-package-name
  91                                %guix-version
  92                                %guix-bug-report-address
  93                                %guix-home-page-url
  94                                %store-directory
  95                                %state-directory
  96                                %store-database-directory
  97                                %config-directory
  98                                %libz
  99                                %gzip
 100                                %bzip2
 101                                %xz))
 102
 103                    ;; XXX: Work around <http://bugs.gnu.org/15602>.
 104                    (eval-when (expand load eval)
 105                      #$@(map (match-lambda
 106                                ((name . value)
 107                                 #~(define-public #$name #$value)))
 108                              %config-variables)
 109
 110                      (define %store-directory
 111                        (or (and=> (getenv "NIX_STORE_DIR") canonicalize-path)
 112                            %storedir))
 113
 114                      (define %state-directory
 115                        ;; This must match `NIX_STATE_DIR' as defined in
 116                        ;; `nix/local.mk'.
 117                        (or (getenv "GUIX_STATE_DIRECTORY")
 118                            (string-append %localstatedir "/guix")))
 119
 120                      (define %store-database-directory
 121                        (or (getenv "GUIX_DATABASE_DIRECTORY")
 122                            (string-append %state-directory "/db")))
 123
 124                      (define %config-directory
 125                        ;; This must match `GUIX_CONFIGURATION_DIRECTORY' as
 126                        ;; defined in `nix/local.mk'.
 127                        (or (getenv "GUIX_CONFIGURATION_DIRECTORY")
 128                            (string-append %sysconfdir "/guix")))
 129
 130                      (define %guix-package-name #$package-name)
 131                      (define %guix-version #$package-version)
 132                      (define %guix-bug-report-address #$bug-report-address)
 133                      (define %guix-home-page-url #$home-page-url)
 134
 135                      (define %gzip
 136                        #+(and gzip (file-append gzip "/bin/gzip")))
 137                      (define %bzip2
 138                        #+(and bzip2 (file-append bzip2 "/bin/bzip2")))
 139                      (define %xz
 140                        #+(and xz (file-append xz "/bin/xz")))
 141
 142                      (define %libz
 143                        #+(and zlib
 144                               (file-append zlib "/lib/libz")))))))
 145
 146 \f
 147 ;;;
 148 ;;; 'gexp->script'.
 149 ;;;
 150 ;;; This is our own variant of 'gexp->script' with an extra #:module-path
 151 ;;; parameter, which was unavailable in (guix gexp) until commit
 152 ;;; 1ae16033f34cebe802023922436883867010850f (March 2018.)
 153 ;;;
 154
 155 (define (load-path-expression modules path)
 156   "Return as a monadic value a gexp that sets '%load-path' and
 157 '%load-compiled-path' to point to MODULES, a list of module names.  MODULES
 158 are searched for in PATH."
 159   (mlet %store-monad ((modules  (imported-modules modules
 160                                                   #:module-path path))
 161                       (compiled (compiled-modules modules
 162                                                   #:module-path path)))
 163     (return (gexp (eval-when (expand load eval)
 164                     (set! %load-path
 165                       (cons (ungexp modules) %load-path))
 166                     (set! %load-compiled-path
 167                       (cons (ungexp compiled)
 168                             %load-compiled-path)))))))
 169
 170 (define* (gexp->script name exp
 171                        #:key (guile (default-guile))
 172                        (module-path %load-path))
 173   "Return an executable script NAME that runs EXP using GUILE, with EXP's
 174 imported modules in its search path."
 175   (mlet %store-monad ((set-load-path
 176                        (load-path-expression (gexp-modules exp)
 177                                              module-path)))
 178     (gexp->derivation name
 179                       (gexp
 180                        (call-with-output-file (ungexp output)
 181                          (lambda (port)
 182                            ;; Note: that makes a long shebang.  When the store
 183                            ;; is /gnu/store, that fits within the 128-byte
 184                            ;; limit imposed by Linux, but that may go beyond
 185                            ;; when running tests.
 186                            (format port
 187                                    "#!~a/bin/guile --no-auto-compile~%!#~%"
 188                                    (ungexp guile))
 189
 190                            (write '(ungexp set-load-path) port)
 191                            (write '(ungexp exp) port)
 192                            (chmod port #o555))))
 193                       #:module-path module-path)))
 194
 195 \f
 196 (define (date-version-string)
 197   "Return the current date and hour in UTC timezone, for use as a poor
 198 person's version identifier."
 199   ;; XXX: Replace with a Git commit id.
 200   (date->string (current-date 0) "~Y~m~d.~H"))
 201
 202 (define guile-gcrypt
 203   ;; The host Guix may or may not have 'guile-gcrypt', which was introduced in
 204   ;; August 2018.  If it has it, it's at least version 0.1.0, which is good
 205   ;; enough.  If it doesn't, specify our own package because the target Guix
 206   ;; requires it.
 207   (match (find-best-packages-by-name "guile-gcrypt" #f)
 208     (()
 209      (package
 210        (name "guile-gcrypt")
 211        (version "0.1.0")
 212        (home-page "https://notabug.org/cwebber/guile-gcrypt")
 213        (source (origin
 214                  (method url-fetch)
 215                  (uri (string-append home-page "/archive/v" version ".tar.gz"))
 216                  (sha256
 217                   (base32
 218                    "1gir7ifknbmbvjlql5j6wzk7bkb5lnmq80q59ngz43hhpclrk5k3"))
 219                  (file-name (string-append name "-" version ".tar.gz"))))
 220        (build-system gnu-build-system)
 221        (arguments
 222         ;; The 'bootstrap' phase appeared in 'core-updates', which was merged
 223         ;; into 'master' ca. June 2018.
 224         '(#:phases (modify-phases %standard-phases
 225                      (delete 'bootstrap)
 226                      (add-before 'configure 'bootstrap
 227                        (lambda _
 228                          (unless (zero? (system* "autoreconf" "-vfi"))
 229                            (error "autoreconf failed"))
 230                          #t)))))
 231        (native-inputs
 232         `(("pkg-config" ,(specification->package "pkg-config"))
 233           ("autoconf" ,(specification->package "autoconf"))
 234           ("automake" ,(specification->package "automake"))
 235           ("texinfo" ,(specification->package "texinfo"))))
 236        (inputs
 237         `(("guile" ,(specification->package "guile"))
 238           ("libgcrypt" ,(specification->package "libgcrypt"))))
 239        (synopsis "Cryptography library for Guile using Libgcrypt")
 240        (description
 241         "Guile-Gcrypt provides a Guile 2.x interface to a subset of the
 242 GNU Libgcrypt crytographic library.  It provides modules for cryptographic
 243 hash functions, message authentication codes (MAC), public-key cryptography,
 244 strong randomness, and more.  It is implemented using the foreign function
 245 interface (FFI) of Guile.")
 246        (license #f)))                             ;license:gpl3+
 247     ((package . _)
 248      package)))
 249
 250 (define* (build-program source version
 251                         #:optional (guile-version (effective-version))
 252                         #:key (pull-version 0))
 253   "Return a program that computes the derivation to build Guix from SOURCE."
 254   (define select?
 255     ;; Select every module but (guix config) and non-Guix modules.
 256     (match-lambda
 257       (('guix 'config) #f)
 258       (('guix _ ...)   #t)
 259       (('gnu _ ...)    #t)
 260       (_               #f)))
 261
 262   (define fake-gcrypt-hash
 263     ;; Fake (gcrypt hash) module; see below.
 264     (scheme-file "hash.scm"
 265                  #~(define-module (gcrypt hash)
 266                      #:export (sha1 sha256))))
 267
 268   (define fake-git
 269     (scheme-file "git.scm" #~(define-module (git))))
 270
 271   (with-imported-modules `(((guix config)
 272                             => ,(make-config.scm))
 273
 274                            ;; To avoid relying on 'with-extensions', which was
 275                            ;; introduced in 0.15.0, provide a fake (gcrypt
 276                            ;; hash) just so that we can build modules, and
 277                            ;; adjust %LOAD-PATH later on.
 278                            ((gcrypt hash) => ,fake-gcrypt-hash)
 279
 280                            ;; (guix git-download) depends on (git) but only
 281                            ;; for peripheral functionality.  Provide a dummy
 282                            ;; (git) to placate it.
 283                            ((git) => ,fake-git)
 284
 285                            ,@(source-module-closure `((guix store)
 286                                                       (guix self)
 287                                                       (guix derivations)
 288                                                       (gnu packages bootstrap))
 289                                                     (list source)
 290                                                     #:select? select?))
 291     (gexp->script "compute-guix-derivation"
 292                   #~(begin
 293                       (use-modules (ice-9 match))
 294
 295                       (eval-when (expand load eval)
 296                         ;; (gnu packages …) modules are going to be looked up
 297                         ;; under SOURCE.  (guix config) is looked up in FRONT.
 298                         (match (command-line)
 299                           ((_ source _ ...)
 300                            (match %load-path
 301                              ((front _ ...)
 302                               (unless (string=? front source) ;already done?
 303                                 (set! %load-path
 304                                   (list source
 305                                         (string-append #$guile-gcrypt
 306                                                        "/share/guile/site/"
 307                                                        (effective-version))
 308                                         front)))))))
 309
 310                         ;; Only load Guile-Gcrypt, our own modules, or those
 311                         ;; of Guile.
 312                         (set! %load-compiled-path
 313                           (cons (string-append #$guile-gcrypt "/lib/guile/"
 314                                                (effective-version)
 315                                                "/site-ccache")
 316                                 %load-compiled-path))
 317
 318                         ;; Disable position recording to save time and space
 319                         ;; when loading the package modules.
 320                         (read-disable 'positions))
 321
 322                       (use-modules (guix store)
 323                                    (guix self)
 324                                    (guix derivations)
 325                                    (srfi srfi-1))
 326
 327                       (define (spin system)
 328                         (define spin
 329                           (circular-list "-" "\\" "|" "/" "-" "\\" "|" "/"))
 330
 331                         (format (current-error-port)
 332                                 "Computing Guix derivation for '~a'...  "
 333                                 system)
 334                         (when (isatty? (current-error-port))
 335                           (let loop ((spin spin))
 336                             (display (string-append "\b" (car spin))
 337                                      (current-error-port))
 338                             (force-output (current-error-port))
 339                             (sleep 1)
 340                             (loop (cdr spin)))))
 341
 342                       (match (command-line)
 343                         ((_ source system version protocol-version)
 344                          ;; The current input port normally wraps a file
 345                          ;; descriptor connected to the daemon, or it is
 346                          ;; connected to /dev/null.  In the former case, reuse
 347                          ;; the connection such that we inherit build options
 348                          ;; such as substitute URLs and so on; in the latter
 349                          ;; case, attempt to open a new connection.
 350                          (let* ((proto (string->number protocol-version))
 351                                 (store (if (integer? proto)
 352                                            (port->connection (duplicate-port
 353                                                               (current-input-port)
 354                                                               "w+0")
 355                                                              #:version proto)
 356                                            (open-connection))))
 357                            (call-with-new-thread
 358                             (lambda ()
 359                               (spin system)))
 360
 361                            (display
 362                             (and=>
 363                              (run-with-store store
 364                                (guix-derivation source version
 365                                                 #$guile-version
 366                                                 #:pull-version
 367                                                 #$pull-version)
 368                                #:system system)
 369                              derivation-file-name))))))
 370                   #:module-path (list source))))
 371
 372 (define (call-with-clean-environment thunk)
 373   (let ((env (environ)))
 374     (dynamic-wind
 375       (lambda ()
 376         (environ '()))
 377       thunk
 378       (lambda ()
 379         (environ env)))))
 380
 381 (define-syntax-rule (with-clean-environment exp ...)
 382   "Evaluate EXP in a context where zero environment variables are defined."
 383   (call-with-clean-environment (lambda () exp ...)))
 384
 385 ;; The procedure below is our return value.
 386 (define* (build source
 387                 #:key verbose? (version (date-version-string)) system
 388                 (pull-version 0)
 389
 390                 ;; For the standalone Guix, default to Guile 2.2.  For old
 391                 ;; versions of 'guix pull' (pre-0.15.0), we have to use the
 392                 ;; same Guile as the current one.
 393                 (guile-version (if (> pull-version 0)
 394                                    "2.2"
 395                                    (effective-version)))
 396
 397                 #:allow-other-keys
 398                 #:rest rest)
 399   "Return a derivation that unpacks SOURCE into STORE and compiles Scheme
 400 files."
 401   ;; Build the build program and then use it as a trampoline to build from
 402   ;; SOURCE.
 403   (mlet %store-monad ((build  (build-program source version guile-version
 404                                              #:pull-version pull-version))
 405                       (system (if system (return system) (current-system)))
 406                       (port   ((store-lift nix-server-socket)))
 407                       (major  ((store-lift nix-server-major-version)))
 408                       (minor  ((store-lift nix-server-minor-version))))
 409     (mbegin %store-monad
 410       (show-what-to-build* (list build))
 411       (built-derivations (list build))
 412
 413       ;; Use the port beneath the current store as the stdin of BUILD.  This
 414       ;; way, we know 'open-pipe*' will not close it on 'exec'.  If PORT is
 415       ;; not a file port (e.g., it's an SSH channel), then the subprocess's
 416       ;; stdin will actually be /dev/null.
 417       (let* ((pipe   (with-input-from-port port
 418                        (lambda ()
 419                          ;; Make sure BUILD is not influenced by
 420                          ;; $GUILE_LOAD_PATH & co.
 421                          (with-clean-environment
 422                           (setenv "GUILE_WARN_DEPRECATED" "no") ;be quiet and drive
 423                           (open-pipe* OPEN_READ
 424                                       (derivation->output-path build)
 425                                       source system version
 426                                       (if (file-port? port)
 427                                           (number->string
 428                                            (logior major minor))
 429                                           "none"))))))
 430              (str    (get-string-all pipe))
 431              (status (close-pipe pipe)))
 432         (match str
 433           ((? eof-object?)
 434            (error "build program failed" (list build status)))
 435           ((? derivation-path? drv)
 436            (mbegin %store-monad
 437              (return (newline (current-error-port)))
 438              ((store-lift add-temp-root) drv)
 439              (return (read-derivation-from-file drv))))
 440           ("#f"
 441            ;; Unsupported PULL-VERSION.
 442            (return #f))
 443           ((? string? str)
 444            (raise (condition
 445                    (&message
 446                     (message (format #f "You found a bug: the program '~a'
 447 failed to compute the derivation for Guix (version: ~s; system: ~s;
 448 host version: ~s; pull-version: ~s).
 449 Please report it by email to <~a>.~%"
 450                                      (derivation->output-path build)
 451                                      version system %guix-version pull-version
 452                                      %guix-bug-report-address)))))))))))
 453
 454 ;; This file is loaded by 'guix pull'; return it the build procedure.
 455 build
 456
 457 ;; Local Variables:
 458 ;; eval: (put 'with-load-path 'scheme-indent-function 1)
 459 ;; End:
 460
 461 ;;; build-self.scm ends here