gnu/services/cuirass.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2016 Mathieu Lirzin <mthl@gnu.org>
   3 ;;; Copyright © 2016, 2017, 2018, 2019 Ludovic Courtès <ludo@gnu.org>
   4 ;;; Copyright © 2017 Mathieu Othacehe <m.othacehe@gmail.com>
   5 ;;; Copyright © 2017 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;; Copyright © 2018 Ricardo Wurmus <rekado@elephly.net>
   7 ;;; Copyright © 2018 Clément Lassieur <clement@lassieur.org>
   8 ;;;
   9 ;;; This file is part of GNU Guix.
  10 ;;;
  11 ;;; GNU Guix is free software; you can redistribute it and/or modify
  12 ;;; it under the terms of the GNU General Public License as published by
  13 ;;; the Free Software Foundation, either version 3 of the License, or
  14 ;;; (at your option) any later version.
  15 ;;;
  16 ;;; GNU Guix is distributed in the hope that it will be useful,
  17 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;;; GNU General Public License for more details.
  20 ;;;
  21 ;;; You should have received a copy of the GNU General Public License
  22 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 (define-module (gnu services cuirass)
  25   #:use-module (guix gexp)
  26   #:use-module (guix records)
  27   #:use-module (gnu packages admin)
  28   #:autoload   (gnu packages ci) (cuirass)
  29   #:autoload   (gnu packages version-control) (git)
  30   #:use-module (gnu services)
  31   #:use-module (gnu services base)
  32   #:use-module (gnu services shepherd)
  33   #:use-module (gnu services admin)
  34   #:use-module (gnu system shadow)
  35   #:export (<cuirass-configuration>
  36             cuirass-configuration
  37             cuirass-configuration?
  38
  39             cuirass-service-type))
  40
  41 ;;;; Commentary:
  42 ;;;
  43 ;;; This module implements a service that to run instances of Cuirass, a
  44 ;;; continuous integration tool.
  45 ;;;
  46 ;;;; Code:
  47
  48 (define-record-type* <cuirass-configuration>
  49   cuirass-configuration make-cuirass-configuration
  50   cuirass-configuration?
  51   (cuirass          cuirass-configuration-cuirass ;package
  52                     (default cuirass))
  53   (log-file         cuirass-configuration-log-file ;string
  54                     (default "/var/log/cuirass.log"))
  55   (cache-directory  cuirass-configuration-cache-directory ;string (dir-name)
  56                     (default "/var/cache/cuirass"))
  57   (ttl              cuirass-configuration-ttl     ;integer
  58                     (default (* 30 24 3600)))
  59   (user             cuirass-configuration-user ;string
  60                     (default "cuirass"))
  61   (group            cuirass-configuration-group ;string
  62                     (default "cuirass"))
  63   (interval         cuirass-configuration-interval ;integer (seconds)
  64                     (default 60))
  65   (database         cuirass-configuration-database ;string (file-name)
  66                     (default "/var/lib/cuirass/cuirass.db"))
  67   (port             cuirass-configuration-port ;integer (port)
  68                     (default 8081))
  69   (host             cuirass-configuration-host ;string
  70                     (default "localhost"))
  71   (specifications   cuirass-configuration-specifications)
  72                                   ;gexp that evaluates to specification-alist
  73   (use-substitutes? cuirass-configuration-use-substitutes? ;boolean
  74                     (default #f))
  75   (one-shot?        cuirass-configuration-one-shot? ;boolean
  76                     (default #f))
  77   (fallback?        cuirass-configuration-fallback? ;boolean
  78                     (default #f)))
  79
  80 (define (cuirass-shepherd-service config)
  81   "Return a <shepherd-service> for the Cuirass service with CONFIG."
  82   (and
  83    (cuirass-configuration? config)
  84    (let ((cuirass          (cuirass-configuration-cuirass config))
  85          (cache-directory  (cuirass-configuration-cache-directory config))
  86          (log-file         (cuirass-configuration-log-file config))
  87          (user             (cuirass-configuration-user config))
  88          (group            (cuirass-configuration-group config))
  89          (interval         (cuirass-configuration-interval config))
  90          (database         (cuirass-configuration-database config))
  91          (ttl              (cuirass-configuration-ttl config))
  92          (port             (cuirass-configuration-port config))
  93          (host             (cuirass-configuration-host config))
  94          (specs            (cuirass-configuration-specifications config))
  95          (use-substitutes? (cuirass-configuration-use-substitutes? config))
  96          (one-shot?        (cuirass-configuration-one-shot? config))
  97          (fallback?        (cuirass-configuration-fallback? config)))
  98      (list (shepherd-service
  99             (documentation "Run Cuirass.")
 100             (provision '(cuirass))
 101             (requirement '(guix-daemon networking))
 102             (start #~(make-forkexec-constructor
 103                       (list (string-append #$cuirass "/bin/cuirass")
 104                             "--cache-directory" #$cache-directory
 105                             "--specifications"
 106                             #$(scheme-file "cuirass-specs.scm" specs)
 107                             "--database" #$database
 108                             "--ttl" #$(string-append (number->string ttl) "s")
 109                             "--port" #$(number->string port)
 110                             "--listen" #$host
 111                             "--interval" #$(number->string interval)
 112                             #$@(if use-substitutes? '("--use-substitutes") '())
 113                             #$@(if one-shot? '("--one-shot") '())
 114                             #$@(if fallback? '("--fallback") '()))
 115
 116                       #:environment-variables
 117                       (list "GIT_SSL_CAINFO=/etc/ssl/certs/ca-certificates.crt"
 118                             (string-append "GIT_EXEC_PATH=" #$git
 119                                            "/libexec/git-core"))
 120
 121                       #:user #$user
 122                       #:group #$group
 123                       #:log-file #$log-file))
 124             (stop #~(make-kill-destructor)))))))
 125
 126 (define (cuirass-account config)
 127   "Return the user accounts and user groups for CONFIG."
 128   (let ((cuirass-user  (cuirass-configuration-user config))
 129         (cuirass-group (cuirass-configuration-group config)))
 130     (list (user-group
 131            (name cuirass-group)
 132            (system? #t))
 133           (user-account
 134            (name cuirass-user)
 135            (group cuirass-group)
 136            (system? #t)
 137            (comment "Cuirass privilege separation user")
 138            (home-directory (string-append "/var/lib/" cuirass-user))
 139            (shell (file-append shadow "/sbin/nologin"))))))
 140
 141 (define (cuirass-activation config)
 142   "Return the activation code for CONFIG."
 143   (let ((cache (cuirass-configuration-cache-directory config))
 144         (db    (dirname (cuirass-configuration-database config)))
 145         (user  (cuirass-configuration-user config))
 146         (group (cuirass-configuration-group config)))
 147     (with-imported-modules '((guix build utils))
 148       #~(begin
 149           (use-modules (guix build utils))
 150
 151           (mkdir-p #$cache)
 152           (mkdir-p #$db)
 153
 154           (let ((uid (passwd:uid (getpw #$user)))
 155                 (gid (group:gid (getgr #$group))))
 156             (chown #$cache uid gid)
 157             (chown #$db uid gid))))))
 158
 159 (define (cuirass-log-rotations config)
 160   "Return the list of log rotations that corresponds to CONFIG."
 161   (list (log-rotation
 162          (files (list (cuirass-configuration-log-file config)))
 163          (frequency 'weekly)
 164          (options '("rotate 40")))))              ;worth keeping
 165
 166 (define cuirass-service-type
 167   (service-type
 168    (name 'cuirass)
 169    (extensions
 170     (list
 171      (service-extension profile-service-type      ;for 'info cuirass'
 172                         (compose list cuirass-configuration-cuirass))
 173      (service-extension rottlog-service-type cuirass-log-rotations)
 174      (service-extension activation-service-type cuirass-activation)
 175      (service-extension shepherd-root-service-type cuirass-shepherd-service)
 176      (service-extension account-service-type cuirass-account)))
 177    (description
 178     "Run the Cuirass continuous integration service.")))
 179