gnu/services/xorg.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2017 Andy Wingo <wingo@igalia.com>
   3 ;;; Copyright © 2013, 2014, 2015, 2016, 2017, 2019 Ludovic Courtès <ludo@gnu.org>
   4 ;;; Copyright © 2015 Sou Bunnbu <iyzsong@gmail.com>
   5 ;;; Copyright © 2018, 2019 Timothy Sample <samplet@ngyro.com>
   6 ;;; Copyright © 2019 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
   7 ;;; Copyright © 2019 Tim Gesthuizen <tim.gesthuizen@yahoo.de>
   8 ;;; Copyright © 2020 shtwzrd <shtwzrd@protonmail.com>
   9 ;;; Copyright © 2020 Jakub Kądziołka <kuba@kadziolka.net>
  10 ;;;
  11 ;;; This file is part of GNU Guix.
  12 ;;;
  13 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  14 ;;; under the terms of the GNU General Public License as published by
  15 ;;; the Free Software Foundation; either version 3 of the License, or (at
  16 ;;; your option) any later version.
  17 ;;;
  18 ;;; GNU Guix is distributed in the hope that it will be useful, but
  19 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;;; GNU General Public License for more details.
  22 ;;;
  23 ;;; You should have received a copy of the GNU General Public License
  24 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 (define-module (gnu services xorg)
  27   #:use-module (gnu artwork)
  28   #:use-module (gnu services)
  29   #:use-module (gnu services shepherd)
  30   #:use-module (gnu system pam)
  31   #:use-module (gnu system keyboard)
  32   #:use-module (gnu services base)
  33   #:use-module (gnu services dbus)
  34   #:use-module ((gnu packages base) #:select (canonical-package))
  35   #:use-module (gnu packages guile)
  36   #:use-module (gnu packages xorg)
  37   #:use-module (gnu packages fonts)
  38   #:use-module (gnu packages gl)
  39   #:use-module (gnu packages glib)
  40   #:use-module (gnu packages display-managers)
  41   #:use-module (gnu packages freedesktop)
  42   #:use-module (gnu packages gnustep)
  43   #:use-module (gnu packages gnome)
  44   #:use-module (gnu packages admin)
  45   #:use-module (gnu packages bash)
  46   #:use-module (gnu system shadow)
  47   #:use-module (guix gexp)
  48   #:use-module (guix store)
  49   #:use-module (guix packages)
  50   #:use-module (guix derivations)
  51   #:use-module (guix records)
  52   #:use-module (guix deprecation)
  53   #:use-module (srfi srfi-1)
  54   #:use-module (srfi srfi-9)
  55   #:use-module (srfi srfi-26)
  56   #:use-module (ice-9 match)
  57   #:export (xorg-configuration
  58             xorg-configuration?
  59             xorg-configuration-modules
  60             xorg-configuration-fonts
  61             xorg-configuration-drivers
  62             xorg-configuration-resolutions
  63             xorg-configuration-extra-config
  64             xorg-configuration-server
  65             xorg-configuration-server-arguments
  66
  67             %default-xorg-modules
  68             %default-xorg-fonts
  69             xorg-wrapper
  70             xorg-start-command
  71             xinitrc
  72
  73             %default-slim-theme
  74             %default-slim-theme-name
  75
  76             slim-configuration
  77             slim-configuration?
  78             slim-configuration-slim
  79             slim-configuration-allow-empty-passwords?
  80             slim-configuration-auto-login?
  81             slim-configuration-default-user
  82             slim-configuration-theme
  83             slim-configuration-theme-name
  84             slim-configuration-xauth
  85             slim-configuration-shepherd
  86             slim-configuration-auto-login-session
  87             slim-configuration-xorg
  88             slim-configuration-display
  89             slim-configuration-vt
  90             slim-configuration-sessreg
  91
  92             slim-service-type
  93             slim-service
  94
  95             screen-locker
  96             screen-locker?
  97             screen-locker-service-type
  98             screen-locker-service
  99
 100             localed-configuration
 101             localed-configuration?
 102             localed-service-type
 103
 104             gdm-configuration
 105             gdm-service-type
 106             gdm-service
 107
 108             handle-xorg-configuration
 109             set-xorg-configuration))
 110
 111 ;;; Commentary:
 112 ;;;
 113 ;;; Services that relate to the X Window System.
 114 ;;;
 115 ;;; Code:
 116
 117 (define %default-xorg-modules
 118   ;; Default list of modules loaded by the server.  When multiple drivers
 119   ;; match, the first one in the list is loaded.
 120   (list xf86-video-vesa
 121         xf86-video-fbdev
 122         xf86-video-amdgpu
 123         xf86-video-ati
 124         xf86-video-cirrus
 125         xf86-video-intel
 126         xf86-video-mach64
 127         xf86-video-nouveau
 128         xf86-video-nv
 129         xf86-video-sis
 130
 131         ;; Libinput is the new thing and is recommended over evdev/synaptics:
 132         ;; <http://who-t.blogspot.fr/2015/01/xf86-input-libinput-compatibility-with.html>.
 133         xf86-input-libinput
 134
 135         xf86-input-evdev
 136         xf86-input-keyboard
 137         xf86-input-mouse
 138         xf86-input-synaptics))
 139
 140 (define %default-xorg-fonts
 141   ;; Default list of fonts available to the X server.
 142   (list (file-append font-alias "/share/fonts/X11/75dpi")
 143         (file-append font-alias "/share/fonts/X11/100dpi")
 144         (file-append font-alias "/share/fonts/X11/misc")
 145         (file-append font-alias "/share/fonts/X11/cyrillic")
 146         (file-append font-misc-misc               ;default fonts for xterm
 147                      "/share/fonts/X11/misc")
 148         (file-append font-adobe75dpi "/share/fonts/X11/75dpi")))
 149
 150 (define %default-xorg-server-arguments
 151   ;; Default command-line arguments for X.
 152   '("-nolisten" "tcp"))
 153
 154 ;; Configuration of an Xorg server.
 155 (define-record-type* <xorg-configuration>
 156   xorg-configuration make-xorg-configuration
 157   xorg-configuration?
 158   (modules          xorg-configuration-modules    ;list of packages
 159                     ; filter out modules not supported on current system
 160                     (default (filter
 161                               (lambda (p)
 162                                 (member (%current-system)
 163                                         (package-supported-systems p)))
 164                               %default-xorg-modules)))
 165   (fonts            xorg-configuration-fonts      ;list of packges
 166                     (default %default-xorg-fonts))
 167   (drivers          xorg-configuration-drivers    ;list of strings
 168                     (default '()))
 169   (resolutions      xorg-configuration-resolutions ;list of tuples
 170                     (default '()))
 171   (keyboard-layout  xorg-configuration-keyboard-layout ;#f | <keyboard-layout>
 172                     (default #f))
 173   (extra-config     xorg-configuration-extra-config ;list of strings
 174                     (default '()))
 175   (server           xorg-configuration-server     ;package
 176                     (default xorg-server))
 177   (server-arguments xorg-configuration-server-arguments ;list of strings
 178                     (default %default-xorg-server-arguments)))
 179
 180 (define (xorg-configuration->file config)
 181   "Compute an Xorg configuration file corresponding to CONFIG, an
 182 <xorg-configuration> record."
 183   (define all-modules
 184     ;; 'xorg-server' provides 'fbdevhw.so' etc.
 185     (append (xorg-configuration-modules config)
 186             (list xorg-server)))
 187
 188   (define build
 189     #~(begin
 190         (use-modules (ice-9 match)
 191                      (srfi srfi-1)
 192                      (srfi srfi-26))
 193
 194         (call-with-output-file #$output
 195           (lambda (port)
 196             (define drivers
 197               '#$(xorg-configuration-drivers config))
 198
 199             (define (device-section driver)
 200               (string-append "
 201 Section \"Device\"
 202   Identifier \"device-" driver "\"
 203   Driver \"" driver "\"
 204 EndSection"))
 205
 206             (define (screen-section driver resolutions)
 207               (string-append "
 208 Section \"Screen\"
 209   Identifier \"screen-" driver "\"
 210   Device \"device-" driver "\"
 211   SubSection \"Display\"
 212     Modes "
 213   (string-join (map (match-lambda
 214                       ((x y)
 215                        (string-append "\"" (number->string x)
 216                                       "x" (number->string y) "\"")))
 217                     resolutions)) "
 218   EndSubSection
 219 EndSection"))
 220
 221             (define (input-class-section layout variant model options)
 222               (string-append "
 223 Section \"InputClass\"
 224   Identifier \"evdev keyboard catchall\"
 225   MatchIsKeyboard \"on\"
 226   Option \"XkbLayout\" " (object->string layout)
 227   (if variant
 228       (string-append "  Option \"XkbVariant\" \""
 229                      variant "\"")
 230       "")
 231   (if model
 232       (string-append "  Option \"XkbModel\" \""
 233                      model "\"")
 234       "")
 235   (match options
 236     (()
 237      "")
 238     (_
 239      (string-append "  Option \"XkbOptions\" \""
 240                     (string-join options ",") "\""))) "
 241
 242   MatchDevicePath \"/dev/input/event*\"
 243   Driver \"evdev\"
 244 EndSection\n"))
 245
 246             (define (expand modules)
 247               ;; Append to MODULES the relevant /lib/xorg/modules
 248               ;; sub-directories.
 249               (append-map (lambda (module)
 250                             (filter-map (lambda (directory)
 251                                           (let ((full (string-append module
 252                                                                      directory)))
 253                                             (and (file-exists? full)
 254                                                  full)))
 255                                         '("/lib/xorg/modules/drivers"
 256                                           "/lib/xorg/modules/input"
 257                                           "/lib/xorg/modules/multimedia"
 258                                           "/lib/xorg/modules/extensions")))
 259                           modules))
 260
 261             (display "Section \"Files\"\n" port)
 262             (for-each (lambda (font)
 263                         (format port "  FontPath \"~a\"~%" font))
 264                       '#$(xorg-configuration-fonts config))
 265             (for-each (lambda (module)
 266                         (format port
 267                                 "  ModulePath \"~a\"~%"
 268                                 module))
 269                       (append (expand '#$all-modules)
 270
 271                               ;; For fbdevhw.so and so on.
 272                               (list #$(file-append xorg-server
 273                                                    "/lib/xorg/modules"))))
 274             (display "EndSection\n" port)
 275             (display "
 276 Section \"ServerFlags\"
 277   Option \"AllowMouseOpenFail\" \"on\"
 278 EndSection\n" port)
 279
 280             (display (string-join (map device-section drivers) "\n")
 281                      port)
 282             (newline port)
 283             (display (string-join
 284                       (map (cut screen-section <>
 285                                 '#$(xorg-configuration-resolutions config))
 286                            drivers)
 287                       "\n")
 288                      port)
 289             (newline port)
 290
 291             (let ((layout  #$(and=> (xorg-configuration-keyboard-layout config)
 292                                     keyboard-layout-name))
 293                   (variant #$(and=> (xorg-configuration-keyboard-layout config)
 294                                     keyboard-layout-variant))
 295                   (model   #$(and=> (xorg-configuration-keyboard-layout config)
 296                                     keyboard-layout-model))
 297                   (options '#$(and=> (xorg-configuration-keyboard-layout config)
 298                                      keyboard-layout-options)))
 299               (when layout
 300                 (display (input-class-section layout variant model options)
 301                          port)
 302                 (newline port)))
 303
 304             (for-each (lambda (config)
 305                         (display config port))
 306                       '#$(xorg-configuration-extra-config config))))))
 307
 308   (computed-file "xserver.conf" build))
 309
 310 (define (xorg-configuration-directory modules)
 311   "Return a directory that contains the @code{.conf} files for X.org that
 312 includes the @code{share/X11/xorg.conf.d} directories of each package listed
 313 in @var{modules}."
 314   (with-imported-modules '((guix build utils))
 315     (computed-file "xorg.conf.d"
 316                    #~(begin
 317                        (use-modules (guix build utils)
 318                                     (srfi srfi-1))
 319
 320                        (define files
 321                          (append-map (lambda (module)
 322                                        (find-files (string-append
 323                                                     module
 324                                                     "/share/X11/xorg.conf.d")
 325                                                    "\\.conf$"))
 326                                      (list #$@modules)))
 327
 328                        (mkdir #$output)
 329                        (for-each (lambda (file)
 330                                    (symlink file
 331                                             (string-append #$output "/"
 332                                                            (basename file))))
 333                                  files)
 334                        #t))))
 335
 336 (define* (xorg-wrapper #:optional (config (xorg-configuration)))
 337   "Return a derivation that builds a script to start the X server with the
 338 given @var{config}.  The resulting script should be used in place of
 339 @code{/usr/bin/X}."
 340   (define exp
 341     ;; Write a small wrapper around the X server.
 342     #~(begin
 343         (setenv "XORG_DRI_DRIVER_PATH" (string-append #$mesa "/lib/dri"))
 344         (setenv "XKB_BINDIR" (string-append #$xkbcomp "/bin"))
 345
 346         (let ((X (string-append #$(xorg-configuration-server config) "/bin/X")))
 347           (apply execl X X
 348                  "-xkbdir" (string-append #$xkeyboard-config "/share/X11/xkb")
 349                  "-config" #$(xorg-configuration->file config)
 350                  "-configdir" #$(xorg-configuration-directory
 351                                  (xorg-configuration-modules config))
 352                  (cdr (command-line))))))
 353
 354   (program-file "X-wrapper" exp))
 355
 356 (define* (xorg-start-command #:optional (config (xorg-configuration)))
 357   "Return a @code{startx} script in which the modules, fonts, etc. specified
 358 in @var{config}, are available.  The result should be used in place of
 359 @code{startx}."
 360   (define X
 361     (xorg-wrapper config))
 362
 363   (define exp
 364     ;; Write a small wrapper around the X server.
 365     #~(apply execl #$X #$X ;; Second #$X is for argv[0].
 366              "-logverbose" "-verbose" "-terminate"
 367              #$@(xorg-configuration-server-arguments config)
 368               (cdr (command-line))))
 369
 370   (program-file "startx" exp))
 371
 372 (define* (xinitrc #:key fallback-session)
 373   "Return a system-wide xinitrc script that starts the specified X session,
 374 which should be passed to this script as the first argument.  If not, the
 375 @var{fallback-session} will be used or, if @var{fallback-session} is false, a
 376 desktop session from the system or user profile will be used."
 377   (define builder
 378     #~(begin
 379         (use-modules (ice-9 match)
 380                      (ice-9 regex)
 381                      (ice-9 ftw)
 382                      (ice-9 rdelim)
 383                      (srfi srfi-1)
 384                      (srfi srfi-26))
 385
 386         (define (close-all-fdes)
 387           ;; Close all the open file descriptors except 0 to 2.
 388           (let loop ((fd 3))
 389             (when (< fd 4096)               ;FIXME: use sysconf + _SC_OPEN_MAX
 390               (false-if-exception (close-fdes fd))
 391               (loop (+ 1 fd)))))
 392
 393         (define (exec-from-login-shell command . args)
 394           ;; Run COMMAND from a login shell so that it gets to see the same
 395           ;; environment variables that one gets when logging in on a tty, for
 396           ;; instance.
 397           (let* ((pw    (getpw (getuid)))
 398                  (shell (passwd:shell pw)))
 399             ;; Close any open file descriptors.  This is all the more
 400             ;; important that SLiM itself exec's us directly without closing
 401             ;; its own file descriptors!
 402             (close-all-fdes)
 403
 404             ;; The '--login' option is supported at least by Bash and zsh.
 405             (execl shell shell "--login" "-c"
 406                    (string-join (cons command args)))))
 407
 408         (define system-profile
 409           "/run/current-system/profile")
 410
 411         (define user-profile
 412           (and=> (getpw (getuid))
 413                  (lambda (pw)
 414                    (string-append (passwd:dir pw) "/.guix-profile"))))
 415
 416         (define (xsession-command desktop-file)
 417           ;; Read from DESKTOP-FILE its X session command and return it as a
 418           ;; list.
 419           (define exec-regexp
 420             (make-regexp "^[[:blank:]]*Exec=(.*)$"))
 421
 422           (call-with-input-file desktop-file
 423             (lambda (port)
 424               (let loop ()
 425                 (match (read-line port)
 426                   ((? eof-object?) #f)
 427                   ((= (cut regexp-exec exec-regexp <>) result)
 428                    (if result
 429                        (string-tokenize (match:substring result 1))
 430                        (loop))))))))
 431
 432         (define (find-session profile)
 433           ;; Return an X session command from PROFILE or #f if none was found.
 434           (let ((directory (string-append profile "/share/xsessions")))
 435             (match (scandir directory
 436                             (cut string-suffix? ".desktop" <>))
 437               ((or () #f)
 438                #f)
 439               ((sessions ...)
 440                (any xsession-command
 441                     (map (cut string-append directory "/" <>)
 442                          sessions))))))
 443
 444         (let* ((home          (getenv "HOME"))
 445                (xsession-file (string-append home "/.xsession"))
 446                (session       (match (command-line)
 447                                 ((_)
 448                                  #$(if fallback-session
 449                                        #~(list #$fallback-session)
 450                                        #f))
 451                                 ((_ x ..1)
 452                                  x))))
 453           (if (file-exists? xsession-file)
 454               ;; Run ~/.xsession when it exists.
 455               (apply exec-from-login-shell xsession-file
 456                      (or session '()))
 457               ;; Otherwise, start the specified session or a fallback.
 458               (apply exec-from-login-shell
 459                      (or session
 460                          (find-session user-profile)
 461                          (find-session system-profile)))))))
 462
 463   (program-file "xinitrc" builder))
 464
 465 (define-syntax handle-xorg-configuration
 466   (syntax-rules ()
 467     "Generate the `compose' and `extend' entries of a login manager
 468 `service-type' to handle specifying the `xorg-configuration' through
 469 a `service-extension', as used by `set-xorg-configuration'."
 470     ((_ configuration-record service-type-definition)
 471      (service-type
 472        (inherit service-type-definition)
 473        (compose (lambda (extensions)
 474                   (match extensions
 475                     (() #f)
 476                     ((config . _) config))))
 477        (extend (lambda (config xorg-configuration)
 478                  (if xorg-configuration
 479                      (configuration-record
 480                       (inherit config)
 481                       (xorg-configuration xorg-configuration))
 482                      config)))))))
 483
 484 \f
 485 ;;;
 486 ;;; SLiM log-in manager.
 487 ;;;
 488
 489 (define %default-slim-theme
 490   ;; Theme based on work by Felipe López.
 491   (file-append %artwork-repository "/slim"))
 492
 493 (define %default-slim-theme-name
 494   ;; This must be the name of the sub-directory in %DEFAULT-SLIM-THEME that
 495   ;; contains the actual theme files.
 496   "1.x")
 497
 498 (define-record-type* <slim-configuration>
 499   slim-configuration make-slim-configuration
 500   slim-configuration?
 501   (slim slim-configuration-slim
 502         (default slim))
 503   (allow-empty-passwords? slim-configuration-allow-empty-passwords?
 504                           (default #t))
 505   (auto-login? slim-configuration-auto-login?
 506                (default #f))
 507   (default-user slim-configuration-default-user
 508                 (default ""))
 509   (theme slim-configuration-theme
 510          (default %default-slim-theme))
 511   (theme-name slim-configuration-theme-name
 512               (default %default-slim-theme-name))
 513   (xauth slim-configuration-xauth
 514          (default xauth))
 515   (shepherd slim-configuration-shepherd
 516             (default shepherd))
 517   (auto-login-session slim-configuration-auto-login-session
 518                       (default #f))
 519   (xorg-configuration slim-configuration-xorg
 520                       (default (xorg-configuration)))
 521   (display slim-configuration-display
 522            (default ":0"))
 523   (vt slim-configuration-vt
 524       (default "vt7"))
 525   (sessreg slim-configuration-sessreg
 526            (default sessreg)))
 527
 528 (define (slim-pam-service config)
 529   "Return a PAM service for @command{slim}."
 530   (list (unix-pam-service
 531          "slim"
 532          #:login-uid? #t
 533          #:allow-empty-passwords?
 534          (slim-configuration-allow-empty-passwords? config))))
 535
 536 (define (slim-shepherd-service config)
 537   (let* ((xinitrc (xinitrc #:fallback-session
 538                            (slim-configuration-auto-login-session config)))
 539          (xauth   (slim-configuration-xauth config))
 540          (startx  (xorg-start-command (slim-configuration-xorg config)))
 541          (display (slim-configuration-display config))
 542          (vt (slim-configuration-vt config))
 543          (shepherd   (slim-configuration-shepherd config))
 544          (theme-name (slim-configuration-theme-name config))
 545          (sessreg (slim-configuration-sessreg config))
 546          (lockfile (string-append "/var/run/slim-" vt ".lock")))
 547     (define slim.cfg
 548       (mixed-text-file "slim.cfg"  "
 549 default_path /run/current-system/profile/bin
 550 default_xserver " startx "
 551 display_name " display "
 552 xserver_arguments " vt "
 553 xauth_path " xauth "/bin/xauth
 554 authfile /var/run/slim-" vt ".auth
 555 lockfile " lockfile "
 556 logfile /var/log/slim-" vt ".log
 557
 558 # The login command.  '%session' is replaced by the chosen session name, one
 559 # of the names specified in the 'sessions' setting: 'wmaker', 'xfce', etc.
 560 login_cmd  exec " xinitrc " %session
 561 sessiondir /run/current-system/profile/share/xsessions
 562 session_msg session (F1 to change):
 563 sessionstart_cmd " sessreg "/bin/sessreg -a -l $DISPLAY %user
 564 sessionstop_cmd " sessreg "/bin/sessreg -d -l $DISPLAY %user
 565
 566 halt_cmd " shepherd "/sbin/halt
 567 reboot_cmd " shepherd "/sbin/reboot\n"
 568 (if (slim-configuration-auto-login? config)
 569     (string-append "auto_login yes\ndefault_user "
 570                    (slim-configuration-default-user config) "\n")
 571     "")
 572 (if theme-name
 573     (string-append "current_theme " theme-name "\n")
 574     "")))
 575
 576     (define theme
 577       (slim-configuration-theme config))
 578
 579     (list (shepherd-service
 580            (documentation "Xorg display server")
 581            (provision (append
 582                        ;; For compatibility, also provide 'xorg-server'.
 583                        (if (string=? vt "vt7")
 584                            '(xorg-server)
 585                            '())
 586
 587                        (list (symbol-append 'xorg-server-
 588                                             (string->symbol vt)))))
 589            (requirement '(user-processes host-name udev))
 590            (start
 591             #~(lambda ()
 592                 ;; A stale lock file can prevent SLiM from starting, so remove it to
 593                 ;; be on the safe side.
 594                 (false-if-exception (delete-file lockfile))
 595
 596                 (fork+exec-command
 597                  (list (string-append #$(slim-configuration-slim config)
 598                                       "/bin/slim")
 599                        "-nodaemon")
 600                  #:environment-variables
 601                  (list (string-append "SLIM_CFGFILE=" #$slim.cfg)
 602                        #$@(if theme
 603                               (list #~(string-append "SLIM_THEMESDIR=" #$theme))
 604                               #~())))))
 605            (stop #~(make-kill-destructor))
 606            (respawn? #t)))))
 607
 608 (define slim-service-type
 609   (handle-xorg-configuration slim-configuration
 610     (service-type (name 'slim)
 611                   (extensions
 612                    (list (service-extension shepherd-root-service-type
 613                                             slim-shepherd-service)
 614                          (service-extension pam-root-service-type
 615                                             slim-pam-service)
 616
 617                          ;; Unconditionally add xterm to the system profile, to
 618                          ;; avoid bad surprises.
 619                          (service-extension profile-service-type
 620                                             (const (list xterm)))))
 621
 622                   (default-value (slim-configuration)))))
 623
 624 (define-deprecated (slim-service #:key (slim slim)
 625                                  (allow-empty-passwords? #t) auto-login?
 626                                  (default-user "")
 627                                  (theme %default-slim-theme)
 628                                  (theme-name %default-slim-theme-name)
 629                                  (xauth xauth) (shepherd shepherd)
 630                                  (auto-login-session #f)
 631                                  (startx (xorg-start-command)))
 632   slim-service-type
 633   "Return a service that spawns the SLiM graphical login manager, which in
 634 turn starts the X display server with @var{startx}, a command as returned by
 635 @code{xorg-start-command}.
 636
 637 @cindex X session
 638
 639 SLiM automatically looks for session types described by the @file{.desktop}
 640 files in @file{/run/current-system/profile/share/xsessions} and allows users
 641 to choose a session from the log-in screen using @kbd{F1}.  Packages such as
 642 @var{xfce}, @var{sawfish}, and @var{ratpoison} provide @file{.desktop} files;
 643 adding them to the system-wide set of packages automatically makes them
 644 available at the log-in screen.
 645
 646 In addition, @file{~/.xsession} files are honored.  When available,
 647 @file{~/.xsession} must be an executable that starts a window manager
 648 and/or other X clients.
 649
 650 When @var{allow-empty-passwords?} is true, allow logins with an empty
 651 password.  When @var{auto-login?} is true, log in automatically as
 652 @var{default-user} with @var{auto-login-session}.
 653
 654 If @var{theme} is @code{#f}, the use the default log-in theme; otherwise
 655 @var{theme} must be a gexp denoting the name of a directory containing the
 656 theme to use.  In that case, @var{theme-name} specifies the name of the
 657 theme."
 658   (service slim-service-type
 659            (slim-configuration
 660             (slim slim)
 661             (allow-empty-passwords? allow-empty-passwords?)
 662             (auto-login? auto-login?) (default-user default-user)
 663             (theme theme) (theme-name theme-name)
 664             (xauth xauth) (shepherd shepherd)
 665             (auto-login-session auto-login-session))))
 666
 667 \f
 668 ;;;
 669 ;;; Screen lockers & co.
 670 ;;;
 671
 672 (define-record-type <screen-locker>
 673   (screen-locker name program empty?)
 674   screen-locker?
 675   (name    screen-locker-name)                     ;string
 676   (program screen-locker-program)                  ;gexp
 677   (empty?  screen-locker-allows-empty-passwords?)) ;Boolean
 678
 679 (define screen-locker-pam-services
 680   (match-lambda
 681     (($ <screen-locker> name _ empty?)
 682      (list (unix-pam-service name
 683                              #:allow-empty-passwords? empty?)))))
 684
 685 (define screen-locker-setuid-programs
 686   (compose list screen-locker-program))
 687
 688 (define screen-locker-service-type
 689   (service-type (name 'screen-locker)
 690                 (extensions
 691                  (list (service-extension pam-root-service-type
 692                                           screen-locker-pam-services)
 693                        (service-extension setuid-program-service-type
 694                                           screen-locker-setuid-programs)))))
 695
 696 (define* (screen-locker-service package
 697                                 #:optional
 698                                 (program (package-name package))
 699                                 #:key allow-empty-passwords?)
 700   "Add @var{package}, a package for a screen locker or screen saver whose
 701 command is @var{program}, to the set of setuid programs and add a PAM entry
 702 for it.  For example:
 703
 704 @lisp
 705  (screen-locker-service xlockmore \"xlock\")
 706 @end lisp
 707
 708 makes the good ol' XlockMore usable."
 709   (service screen-locker-service-type
 710            (screen-locker program
 711                           (file-append package "/bin/" program)
 712                           allow-empty-passwords?)))
 713
 714 \f
 715 ;;;
 716 ;;; Locale service.
 717 ;;;
 718
 719 (define-record-type* <localed-configuration>
 720   localed-configuration make-localed-configuration
 721   localed-configuration?
 722   (localed         localed-configuration-localed
 723                    (default localed))
 724   (keyboard-layout localed-configuration-keyboard-layout
 725                    (default #f)))
 726
 727 (define (localed-dbus-service config)
 728   "Return the 'localed' D-Bus service for @var{config}, a
 729 @code{<localed-configuration>} record."
 730   (define keyboard-layout
 731     (localed-configuration-keyboard-layout config))
 732
 733   ;; The primary purpose of 'localed' is to tell GDM what the "current" Xorg
 734   ;; keyboard layout is.  If 'localed' is missing, or if it's unable to
 735   ;; determine the current XKB layout, then GDM forcefully installs its
 736   ;; default XKB config (US English).  Here we communicate the configured
 737   ;; layout through environment variables.
 738
 739   (if keyboard-layout
 740       (let* ((layout  (keyboard-layout-name keyboard-layout))
 741              (variant (keyboard-layout-variant keyboard-layout))
 742              (model   (keyboard-layout-model keyboard-layout))
 743              (options (keyboard-layout-options keyboard-layout)))
 744         (list (wrapped-dbus-service
 745                (localed-configuration-localed config)
 746                "libexec/localed/localed"
 747                `(("GUIX_XKB_LAYOUT" ,layout)
 748                  ,@(if variant
 749                        `(("GUIX_XKB_VARIANT" ,variant))
 750                        '())
 751                  ,@(if model
 752                        `(("GUIX_XKB_MODEL" ,model))
 753                        '())
 754                  ,@(if (null? options)
 755                        '()
 756                        `(("GUIX_XKB_OPTIONS"
 757                           ,(string-join options ","))))))))
 758       '()))
 759
 760 (define localed-service-type
 761   (let ((package (lambda (config)
 762                    ;; Don't bother if the user didn't specify any keyboard
 763                    ;; layout.
 764                    (if (localed-configuration-keyboard-layout config)
 765                        (list (localed-configuration-localed config))
 766                        '()))))
 767     (service-type (name 'localed)
 768                   (extensions
 769                    (list (service-extension dbus-root-service-type
 770                                             localed-dbus-service)
 771                          (service-extension udev-service-type package)
 772                          (service-extension polkit-service-type package)
 773
 774                          ;; Add 'localectl' to the profile.
 775                          (service-extension profile-service-type package)))
 776
 777                   ;; This service can be extended, typically by the X login
 778                   ;; manager, to communicate the chosen Xorg keyboard layout.
 779                   (compose (lambda (extensions)
 780                              (find keyboard-layout? extensions)))
 781                   (extend (lambda (config keyboard-layout)
 782                             (localed-configuration
 783                              (inherit config)
 784                              (keyboard-layout keyboard-layout))))
 785                   (description
 786                    "Run the locale daemon, @command{localed}, which can be used
 787 to control the system locale and keyboard mapping from user programs such as
 788 the GNOME desktop environment.")
 789                   (default-value (localed-configuration)))))
 790
 791 \f
 792 ;;;
 793 ;;; GNOME Desktop Manager.
 794 ;;;
 795
 796 (define %gdm-accounts
 797   (list (user-group (name "gdm") (system? #t))
 798         (user-account
 799          (name "gdm")
 800          (group "gdm")
 801          (system? #t)
 802          (comment "GNOME Display Manager user")
 803          (home-directory "/var/lib/gdm")
 804          (shell (file-append shadow "/sbin/nologin")))))
 805
 806 (define %gdm-activation
 807   ;; Ensure /var/lib/gdm is owned by the "gdm" user.  This is normally the
 808   ;; case but could be wrong if the "gdm" user was created, then removed, and
 809   ;; then recreated under a different UID/GID: <https://bugs.gnu.org/37423>.
 810   (with-imported-modules '((guix build utils))
 811     #~(begin
 812         (use-modules (guix build utils))
 813
 814         (let* ((gdm (getpwnam "gdm"))
 815                (uid (passwd:uid gdm))
 816                (gid (passwd:gid gdm))
 817                (st  (stat "/var/lib/gdm" #f)))
 818           ;; Recurse into /var/lib/gdm only if it has wrong ownership.
 819           (when (and st
 820                      (or (not (= uid (stat:uid st)))
 821                          (not (= gid (stat:gid st)))))
 822             (for-each (lambda (file)
 823                         (chown file uid gid))
 824                       (find-files "/var/lib/gdm"
 825                                   #:directories? #t)))))))
 826
 827 (define dbus-daemon-wrapper
 828   (program-file
 829    "gdm-dbus-wrapper"
 830    #~(begin
 831        (use-modules (srfi srfi-26))
 832
 833        (define system-profile
 834          "/run/current-system/profile")
 835
 836        (define user-profile
 837          (and=> (getpw (getuid))
 838                 (lambda (pw)
 839                   (string-append (passwd:dir pw) "/.guix-profile"))))
 840
 841        ;; If we are able to find the user's profile, we can add it to
 842        ;; the search paths set below.  We need to do this so that D-Bus
 843        ;; can start services installed by the user.  This allows
 844        ;; applications that require session D-Bus services (e.g,
 845        ;; 'evolution') to work even if those services are only available
 846        ;; in the user's profile.  See <https://bugs.gnu.org/35267>.
 847        (define profiles
 848          (if user-profile
 849              (list user-profile system-profile)
 850              (list system-profile)))
 851
 852        (setenv "XDG_CONFIG_DIRS"
 853                (string-join (map (cut string-append <> "/etc/xdg") profiles)
 854                             ":"))
 855        (setenv "XDG_DATA_DIRS"
 856                (string-join (map (cut string-append <> "/share") profiles)
 857                             ":"))
 858        (apply execl (string-append #$dbus "/bin/dbus-daemon")
 859               (program-arguments)))))
 860
 861 (define-record-type* <gdm-configuration>
 862   gdm-configuration make-gdm-configuration
 863   gdm-configuration?
 864   (gdm gdm-configuration-gdm (default gdm))
 865   (allow-empty-passwords? gdm-configuration-allow-empty-passwords? (default #t))
 866   (auto-login? gdm-configuration-auto-login? (default #f))
 867   (dbus-daemon gdm-configuration-dbus-daemon (default dbus-daemon-wrapper))
 868   (debug? gdm-configuration-debug? (default #f))
 869   (default-user gdm-configuration-default-user (default #f))
 870   (gnome-shell-assets gdm-configuration-gnome-shell-assets
 871                       (default (list adwaita-icon-theme font-cantarell)))
 872   (xorg-configuration gdm-configuration-xorg
 873                       (default (xorg-configuration)))
 874   (x-session gdm-configuration-x-session
 875              (default (xinitrc))))
 876
 877 (define (gdm-configuration-file config)
 878   (mixed-text-file "gdm-custom.conf"
 879                    "[daemon]\n"
 880                    "#User=gdm\n"
 881                    "#Group=gdm\n"
 882                    (if (gdm-configuration-auto-login? config)
 883                        (string-append
 884                         "AutomaticLoginEnable=true\n"
 885                         "AutomaticLogin="
 886                         (or (gdm-configuration-default-user config)
 887                             (error "missing default user for auto-login"))
 888                         "\n")
 889                        (string-append
 890                         "AutomaticLoginEnable=false\n"
 891                         "#AutomaticLogin=\n"))
 892                    "#TimedLoginEnable=false\n"
 893                    "#TimedLogin=\n"
 894                    "#TimedLoginDelay=0\n"
 895                    ;; Disable initial system setup inside GDM.
 896                    ;; Whatever settings are set there should already be
 897                    ;; taken care of through `guix system'.
 898                    ;; See also
 899                    ;; <https://debbugs.gnu.org/cgi/bugreport.cgi?bug=39281>.
 900                    "InitialSetupEnable=false\n"
 901                    ;; Enable me once X is working.
 902                    "WaylandEnable=false\n"
 903                    "\n"
 904                    "[debug]\n"
 905                    "Enable=" (if (gdm-configuration-debug? config)
 906                                  "true"
 907                                  "false") "\n"
 908                    "\n"
 909                    "[security]\n"
 910                    "#DisallowTCP=true\n"
 911                    "#AllowRemoteAutoLogin=false\n"))
 912
 913 (define (gdm-pam-service config)
 914   "Return a PAM service for @command{gdm}."
 915   (list
 916    (pam-service
 917     (inherit (unix-pam-service "gdm-autologin"
 918                                #:login-uid? #t))
 919     (auth (list (pam-entry
 920                  (control "[success=ok default=1]")
 921                  (module (file-append (gdm-configuration-gdm config)
 922                                       "/lib/security/pam_gdm.so")))
 923                 (pam-entry
 924                  (control "sufficient")
 925                  (module "pam_permit.so")))))
 926    (pam-service
 927     (inherit (unix-pam-service "gdm-launch-environment"))
 928     (auth (list (pam-entry
 929                  (control "required")
 930                  (module "pam_permit.so")))))
 931    (unix-pam-service "gdm-password"
 932                      #:login-uid? #t
 933                      #:allow-empty-passwords?
 934                      (gdm-configuration-allow-empty-passwords? config))))
 935
 936 (define (gdm-shepherd-service config)
 937   (list (shepherd-service
 938          (documentation "Xorg display server (GDM)")
 939          (provision '(xorg-server))
 940          (requirement '(dbus-system user-processes host-name udev))
 941          (start #~(lambda ()
 942                     (fork+exec-command
 943                      (list #$(file-append (gdm-configuration-gdm config)
 944                                           "/bin/gdm"))
 945                      #:environment-variables
 946                      (list (string-append
 947                             "GDM_CUSTOM_CONF="
 948                             #$(gdm-configuration-file config))
 949                            (string-append
 950                             "GDM_DBUS_DAEMON="
 951                             #$(gdm-configuration-dbus-daemon config))
 952                            (string-append
 953                             "GDM_X_SERVER="
 954                             #$(xorg-wrapper
 955                                (gdm-configuration-xorg config)))
 956                            (string-append
 957                             "GDM_X_SESSION="
 958                             #$(gdm-configuration-x-session config))
 959                            (string-append
 960                             "XDG_DATA_DIRS="
 961                             ((lambda (ls) (string-join ls ":"))
 962                              (map (lambda (path)
 963                                     (string-append path "/share"))
 964                                   ;; XXX: Remove gnome-shell below when GDM
 965                                   ;; can depend on GNOME Shell directly.
 966                                   (cons #$gnome-shell
 967                                         '#$(gdm-configuration-gnome-shell-assets
 968                                             config)))))))))
 969          (stop #~(make-kill-destructor))
 970          (respawn? #t))))
 971
 972 (define gdm-service-type
 973   (handle-xorg-configuration gdm-configuration
 974     (service-type (name 'gdm)
 975                   (extensions
 976                    (list (service-extension shepherd-root-service-type
 977                                             gdm-shepherd-service)
 978                          (service-extension activation-service-type
 979                                             (const %gdm-activation))
 980                          (service-extension account-service-type
 981                                             (const %gdm-accounts))
 982                          (service-extension pam-root-service-type
 983                                             gdm-pam-service)
 984                          (service-extension profile-service-type
 985                                             gdm-configuration-gnome-shell-assets)
 986                          (service-extension dbus-root-service-type
 987                                             (compose list
 988                                                      gdm-configuration-gdm))
 989                          (service-extension localed-service-type
 990                                             (compose
 991                                              xorg-configuration-keyboard-layout
 992                                              gdm-configuration-xorg))))
 993                   (default-value (gdm-configuration))
 994                   (description
 995                    "Run the GNOME Desktop Manager (GDM), a program that allows
 996 you to log in in a graphical session, whether or not you use GNOME."))))
 997
 998 (define-deprecated (gdm-service #:key (gdm gdm)
 999                                 (allow-empty-passwords? #t)
1000                                 (x-server (xorg-wrapper)))
1001   gdm-service-type
1002   "Return a service that spawns the GDM graphical login manager, which in turn
1003 starts the X display server with @var{X}, a command as returned by
1004 @code{xorg-wrapper}.
1005
1006 @cindex X session
1007
1008 GDM automatically looks for session types described by the @file{.desktop}
1009 files in @file{/run/current-system/profile/share/xsessions} and allows users
1010 to choose a session from the log-in screen using @kbd{F1}.  Packages such as
1011 @var{xfce}, @var{sawfish}, and @var{ratpoison} provide @file{.desktop} files;
1012 adding them to the system-wide set of packages automatically makes them
1013 available at the log-in screen.
1014
1015 In addition, @file{~/.xsession} files are honored.  When available,
1016 @file{~/.xsession} must be an executable that starts a window manager
1017 and/or other X clients.
1018
1019 When @var{allow-empty-passwords?} is true, allow logins with an empty
1020 password."
1021   (service gdm-service-type
1022            (gdm-configuration
1023             (gdm gdm)
1024             (allow-empty-passwords? allow-empty-passwords?))))
1025
1026 (define* (set-xorg-configuration config
1027                                  #:optional
1028                                  (login-manager-service-type
1029                                   gdm-service-type))
1030   "Tell the log-in manager (of type @var{login-manager-service-type}) to use
1031 @var{config}, an <xorg-configuration> record."
1032   (simple-service 'set-xorg-configuration
1033                   login-manager-service-type
1034                   config))
1035
1036 ;;; xorg.scm ends here