gnu/services/mail.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2015 Andy Wingo <wingo@igalia.com>
   3 ;;; Copyright © 2017, 2018 Clément Lassieur <clement@lassieur.org>
   4 ;;; Copyright © 2017 Carlo Zancanaro <carlo@zancanaro.id.au>
   5 ;;; Copyright © 2017 Tobias Geerinckx-Rice <me@tobias.gr>
   6 ;;; Copyright © 2019 Kristofer Buffington <kristoferbuffington@gmail.com>
   7 ;;;
   8 ;;; This file is part of GNU Guix.
   9 ;;;
  10 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  11 ;;; under the terms of the GNU General Public License as published by
  12 ;;; the Free Software Foundation; either version 3 of the License, or (at
  13 ;;; your option) any later version.
  14 ;;;
  15 ;;; GNU Guix is distributed in the hope that it will be useful, but
  16 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;;; GNU General Public License for more details.
  19 ;;;
  20 ;;; You should have received a copy of the GNU General Public License
  21 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  22 ;;;
  23 ;;; Some of the help text was taken from the default dovecot.conf files.
  24
  25 (define-module (gnu services mail)
  26   #:use-module (gnu services)
  27   #:use-module (gnu services base)
  28   #:use-module (gnu services configuration)
  29   #:use-module (gnu services shepherd)
  30   #:use-module (gnu system pam)
  31   #:use-module (gnu system shadow)
  32   #:use-module (gnu packages mail)
  33   #:use-module (gnu packages admin)
  34   #:use-module (gnu packages tls)
  35   #:use-module (guix records)
  36   #:use-module (guix packages)
  37   #:use-module (guix gexp)
  38   #:use-module (ice-9 match)
  39   #:use-module (ice-9 format)
  40   #:use-module (srfi srfi-1)
  41   #:export (dovecot-service
  42             dovecot-service-type
  43             dovecot-configuration
  44             opaque-dovecot-configuration
  45
  46             dict-configuration
  47             passdb-configuration
  48             userdb-configuration
  49             unix-listener-configuration
  50             fifo-listener-configuration
  51             inet-listener-configuration
  52             service-configuration
  53             protocol-configuration
  54             plugin-configuration
  55             mailbox-configuration
  56             namespace-configuration
  57
  58             opensmtpd-configuration
  59             opensmtpd-configuration?
  60             opensmtpd-service-type
  61             %default-opensmtpd-config-file
  62
  63             mail-aliases-service-type
  64
  65             exim-configuration
  66             exim-configuration?
  67             exim-service-type
  68             %default-exim-config-file
  69
  70             imap4d-configuration
  71             imap4d-configuration?
  72             imap4d-service-type
  73             %default-imap4d-config-file))
  74
  75 ;;; Commentary:
  76 ;;;
  77 ;;; This module provides service definitions for the Dovecot POP3 and IMAP
  78 ;;; mail server.
  79 ;;;
  80 ;;; Code:
  81
  82 (define (uglify-field-name field-name)
  83   (let ((str (symbol->string field-name)))
  84     (string-join (string-split (if (string-suffix? "?" str)
  85                                    (substring str 0 (1- (string-length str)))
  86                                    str)
  87                                #\-)
  88                  "_")))
  89
  90 (define (serialize-field field-name val)
  91   (format #t "~a=~a\n" (uglify-field-name field-name) val))
  92
  93 (define (serialize-string field-name val)
  94   (serialize-field field-name val))
  95
  96 (define (space-separated-string-list? val)
  97   (and (list? val)
  98        (and-map (lambda (x)
  99                   (and (string? x) (not (string-index x #\space))))
 100                 val)))
 101 (define (serialize-space-separated-string-list field-name val)
 102   (serialize-field field-name (string-join val " ")))
 103
 104 (define (comma-separated-string-list? val)
 105   (and (list? val)
 106        (and-map (lambda (x)
 107                   (and (string? x) (not (string-index x #\,))))
 108                 val)))
 109 (define (serialize-comma-separated-string-list field-name val)
 110   (serialize-field field-name (string-join val ",")))
 111
 112 (define (file-name? val)
 113   (and (string? val)
 114        (string-prefix? "/" val)))
 115 (define (serialize-file-name field-name val)
 116   (serialize-string field-name val))
 117
 118 (define (colon-separated-file-name-list? val)
 119   (and (list? val)
 120        ;; Trailing slashes not needed and not
 121        (and-map file-name? val)))
 122 (define (serialize-colon-separated-file-name-list field-name val)
 123   (serialize-field field-name (string-join val ":")))
 124
 125 (define (serialize-boolean field-name val)
 126   (serialize-string field-name (if val "yes" "no")))
 127
 128 (define (non-negative-integer? val)
 129   (and (exact-integer? val) (not (negative? val))))
 130 (define (serialize-non-negative-integer field-name val)
 131   (serialize-field field-name val))
 132
 133 (define (hours? val) (non-negative-integer? val))
 134 (define (serialize-hours field-name val)
 135   (serialize-field field-name (format #f "~a hours" val)))
 136
 137 (define (free-form-fields? val)
 138   (match val
 139     (() #t)
 140     ((((? symbol?) . (? string?)) . val) (free-form-fields? val))
 141     (_ #f)))
 142 (define (serialize-free-form-fields field-name val)
 143   (for-each (match-lambda ((k . v) (serialize-field k v))) val))
 144
 145 (define (free-form-args? val)
 146   (match val
 147     (() #t)
 148     ((((? symbol?) . (? string?)) . val) (free-form-args? val))
 149     (_ #f)))
 150 (define (serialize-free-form-args field-name val)
 151   (serialize-field field-name
 152                    (string-join
 153                     (map (match-lambda ((k . v) (format #t "~a=~a" k v))) val)
 154                     " ")))
 155
 156 (define-configuration dict-configuration
 157   (entries
 158    (free-form-fields '())
 159    "A list of key-value pairs that this dict should hold."))
 160
 161 (define (serialize-dict-configuration field-name val)
 162   (format #t "dict {\n")
 163   (serialize-configuration val dict-configuration-fields)
 164   (format #t "}\n"))
 165
 166 (define-configuration passdb-configuration
 167   (driver
 168    (string "pam")
 169    "The driver that the passdb should use.  Valid values include
 170 @samp{pam}, @samp{passwd}, @samp{shadow}, @samp{bsdauth}, and
 171 @samp{static}.")
 172   (args
 173    (space-separated-string-list '())
 174    "Space separated list of arguments to the passdb driver."))
 175
 176 (define (serialize-passdb-configuration field-name val)
 177   (format #t "passdb {\n")
 178   (serialize-configuration val passdb-configuration-fields)
 179   (format #t "}\n"))
 180 (define (passdb-configuration-list? val)
 181   (and (list? val) (and-map passdb-configuration? val)))
 182 (define (serialize-passdb-configuration-list field-name val)
 183   (for-each (lambda (val) (serialize-passdb-configuration field-name val)) val))
 184
 185 (define-configuration userdb-configuration
 186   (driver
 187    (string "passwd")
 188    "The driver that the userdb should use.  Valid values include
 189 @samp{passwd} and @samp{static}.")
 190   (args
 191    (space-separated-string-list '())
 192    "Space separated list of arguments to the userdb driver.")
 193   (override-fields
 194    (free-form-args '())
 195    "Override fields from passwd."))
 196
 197 (define (serialize-userdb-configuration field-name val)
 198   (format #t "userdb {\n")
 199   (serialize-configuration val userdb-configuration-fields)
 200   (format #t "}\n"))
 201 (define (userdb-configuration-list? val)
 202   (and (list? val) (and-map userdb-configuration? val)))
 203 (define (serialize-userdb-configuration-list field-name val)
 204   (for-each (lambda (val) (serialize-userdb-configuration field-name val)) val))
 205
 206 (define-configuration unix-listener-configuration
 207   (path
 208    (string (configuration-missing-field 'unix-listener 'path))
 209    "Path to the file, relative to @code{base-dir} field.  This is also used as
 210 the section name.")
 211   (mode
 212    (string "0600")
 213    "The access mode for the socket.")
 214   (user
 215    (string "")
 216    "The user to own the the socket.")
 217   (group
 218    (string "")
 219    "The group to own the socket."))
 220
 221 (define (serialize-unix-listener-configuration field-name val)
 222   (format #t "unix_listener ~a {\n" (unix-listener-configuration-path val))
 223   (serialize-configuration val (cdr unix-listener-configuration-fields))
 224   (format #t "}\n"))
 225
 226 (define-configuration fifo-listener-configuration
 227   (path
 228    (string (configuration-missing-field 'fifo-listener 'path))
 229    "Path to the file, relative to @code{base-dir} field.  This is also used as
 230 the section name.")
 231   (mode
 232    (string "0600")
 233    "The access mode for the socket.")
 234   (user
 235    (string "")
 236    "The user to own the the socket.")
 237   (group
 238    (string "")
 239    "The group to own the socket."))
 240
 241 (define (serialize-fifo-listener-configuration field-name val)
 242   (format #t "fifo_listener ~a {\n" (fifo-listener-configuration-path val))
 243   (serialize-configuration val (cdr fifo-listener-configuration-fields))
 244   (format #t "}\n"))
 245
 246 (define-configuration inet-listener-configuration
 247   (protocol
 248    (string (configuration-missing-field 'inet-listener 'protocol))
 249    "The protocol to listen for.")
 250   (address
 251    (string "")
 252    "The address on which to listen, or empty for all addresses.")
 253   (port
 254    (non-negative-integer
 255     (configuration-missing-field 'inet-listener 'port))
 256    "The port on which to listen.")
 257   (ssl?
 258    (boolean #t)
 259    "Whether to use SSL for this service; @samp{yes}, @samp{no}, or
 260 @samp{required}."))
 261
 262 (define (serialize-inet-listener-configuration field-name val)
 263   (format #t "inet_listener ~a {\n" (inet-listener-configuration-protocol val))
 264   (serialize-configuration val (cdr inet-listener-configuration-fields))
 265   (format #t "}\n"))
 266
 267 (define (listener-configuration? val)
 268   (or (unix-listener-configuration? val)
 269       (fifo-listener-configuration? val)
 270       (inet-listener-configuration? val)))
 271 (define (serialize-listener-configuration field-name val)
 272   (cond
 273    ((unix-listener-configuration? val)
 274     (serialize-unix-listener-configuration field-name val))
 275    ((fifo-listener-configuration? val)
 276     (serialize-fifo-listener-configuration field-name val))
 277    ((inet-listener-configuration? val)
 278     (serialize-inet-listener-configuration field-name val))
 279    (else (configuration-field-error field-name val))))
 280 (define (listener-configuration-list? val)
 281   (and (list? val) (and-map listener-configuration? val)))
 282 (define (serialize-listener-configuration-list field-name val)
 283   (for-each (lambda (val)
 284               (serialize-listener-configuration field-name val))
 285             val))
 286
 287 (define-configuration service-configuration
 288   (kind
 289    (string (configuration-missing-field 'service 'kind))
 290    "The service kind.  Valid values include @code{director},
 291 @code{imap-login}, @code{pop3-login}, @code{lmtp}, @code{imap},
 292 @code{pop3}, @code{auth}, @code{auth-worker}, @code{dict},
 293 @code{tcpwrap}, @code{quota-warning}, or anything else.")
 294   (listeners
 295    (listener-configuration-list '())
 296    "Listeners for the service.  A listener is either an
 297 @code{unix-listener-configuration}, a @code{fifo-listener-configuration}, or
 298 an @code{inet-listener-configuration}.")
 299   (client-limit
 300    (non-negative-integer 0)
 301    "Maximum number of simultaneous client connections per process.  Once this
 302 number of connections is received, the next incoming connection will prompt
 303 Dovecot to spawn another process.  If set to 0, @code{default-client-limit} is
 304 used instead.")
 305   (service-count
 306    (non-negative-integer 1)
 307    "Number of connections to handle before starting a new process.
 308 Typically the only useful values are 0 (unlimited) or 1.  1 is more
 309 secure, but 0 is faster.  <doc/wiki/LoginProcess.txt>.")
 310   (process-limit
 311    (non-negative-integer 0)
 312    "Maximum number of processes that can exist for this service.  If set to 0,
 313 @code{default-process-limit} is used instead.")
 314   (process-min-avail
 315    (non-negative-integer 0)
 316    "Number of processes to always keep waiting for more connections.")
 317   ;; FIXME: Need to be able to take the default for this value from other
 318   ;; parts of the config.
 319   (vsz-limit
 320    (non-negative-integer #e256e6)
 321    "If you set @samp{service-count 0}, you probably need to grow
 322 this."))
 323
 324 (define (serialize-service-configuration field-name val)
 325   (format #t "service ~a {\n" (service-configuration-kind val))
 326   (serialize-configuration val (cdr service-configuration-fields))
 327   (format #t "}\n"))
 328 (define (service-configuration-list? val)
 329   (and (list? val) (and-map service-configuration? val)))
 330 (define (serialize-service-configuration-list field-name val)
 331   (for-each (lambda (val)
 332               (serialize-service-configuration field-name val))
 333             val))
 334
 335 (define-configuration protocol-configuration
 336   (name
 337    (string (configuration-missing-field 'protocol 'name))
 338    "The name of the protocol.")
 339   (auth-socket-path
 340    (string "/var/run/dovecot/auth-userdb")
 341    "UNIX socket path to master authentication server to find users.
 342 This is used by imap (for shared users) and lda.")
 343   (mail-plugins
 344    (space-separated-string-list '("$mail_plugins"))
 345    "Space separated list of plugins to load.")
 346   (mail-max-userip-connections
 347    (non-negative-integer 10)
 348    "Maximum number of IMAP connections allowed for a user from each IP
 349 address.  NOTE: The username is compared case-sensitively."))
 350
 351 (define (serialize-protocol-configuration field-name val)
 352   (format #t "protocol ~a {\n" (protocol-configuration-name val))
 353   (serialize-configuration val (cdr protocol-configuration-fields))
 354   (format #t "}\n"))
 355 (define (protocol-configuration-list? val)
 356   (and (list? val) (and-map protocol-configuration? val)))
 357 (define (serialize-protocol-configuration-list field-name val)
 358   (serialize-field 'protocols
 359                    (string-join (map protocol-configuration-name val) " "))
 360   (for-each (lambda (val)
 361               (serialize-protocol-configuration field-name val))
 362             val))
 363
 364 (define-configuration plugin-configuration
 365   (entries
 366    (free-form-fields '())
 367    "A list of key-value pairs that this dict should hold."))
 368
 369 (define (serialize-plugin-configuration field-name val)
 370   (format #t "plugin {\n")
 371   (serialize-configuration val plugin-configuration-fields)
 372   (format #t "}\n"))
 373
 374 (define-configuration mailbox-configuration
 375   (name
 376    (string (error "mailbox name is required"))
 377    "Name for this mailbox.")
 378
 379   (auto
 380    (string "no")
 381    "@samp{create} will automatically create this mailbox.
 382 @samp{subscribe} will both create and subscribe to the mailbox.")
 383
 384   (special-use
 385    (space-separated-string-list '())
 386    "List of IMAP @code{SPECIAL-USE} attributes as specified by RFC 6154.
 387 Valid values are @code{\\All}, @code{\\Archive}, @code{\\Drafts},
 388 @code{\\Flagged}, @code{\\Junk}, @code{\\Sent}, and @code{\\Trash}."))
 389
 390 (define (serialize-mailbox-configuration field-name val)
 391   (format #t "mailbox \"~a\" {\n" (mailbox-configuration-name val))
 392   (serialize-configuration val (cdr mailbox-configuration-fields))
 393   (format #t "}\n"))
 394 (define (mailbox-configuration-list? val)
 395   (and (list? val) (and-map mailbox-configuration? val)))
 396 (define (serialize-mailbox-configuration-list field-name val)
 397   (for-each (lambda (val)
 398               (serialize-mailbox-configuration field-name val))
 399             val))
 400
 401 (define-configuration namespace-configuration
 402   (name
 403    (string (error "namespace name is required"))
 404    "Name for this namespace.")
 405
 406   (type
 407    (string "private")
 408    "Namespace type: @samp{private}, @samp{shared} or @samp{public}.")
 409
 410   (separator
 411    (string "")
 412    "Hierarchy separator to use. You should use the same separator for
 413 all namespaces or some clients get confused.  @samp{/} is usually a good
 414 one.  The default however depends on the underlying mail storage
 415 format.")
 416
 417   (prefix
 418    (string "")
 419    "Prefix required to access this namespace.  This needs to be
 420 different for all namespaces. For example @samp{Public/}.")
 421
 422   (location
 423    (string "")
 424    "Physical location of the mailbox. This is in same format as
 425 mail_location, which is also the default for it.")
 426
 427   (inbox?
 428    (boolean #f)
 429    "There can be only one INBOX, and this setting defines which
 430 namespace has it.")
 431
 432   (hidden?
 433    (boolean #f)
 434    "If namespace is hidden, it's not advertised to clients via NAMESPACE
 435 extension. You'll most likely also want to set @samp{list? #f}.  This is mostly
 436 useful when converting from another server with different namespaces
 437 which you want to deprecate but still keep working.  For example you can
 438 create hidden namespaces with prefixes @samp{~/mail/}, @samp{~%u/mail/}
 439 and @samp{mail/}.")
 440
 441   (list?
 442    (boolean #t)
 443    "Show the mailboxes under this namespace with LIST command. This
 444 makes the namespace visible for clients that don't support NAMESPACE
 445 extension.  The special @code{children} value lists child mailboxes, but
 446 hides the namespace prefix.")
 447
 448   (subscriptions?
 449    (boolean #t)
 450    "Namespace handles its own subscriptions.  If set to @code{#f}, the
 451 parent namespace handles them.  The empty prefix should always have this
 452 as @code{#t}.)")
 453
 454   (mailboxes
 455    (mailbox-configuration-list '())
 456    "List of predefined mailboxes in this namespace."))
 457
 458 (define (serialize-namespace-configuration field-name val)
 459   (format #t "namespace ~a {\n" (namespace-configuration-name val))
 460   (serialize-configuration val (cdr namespace-configuration-fields))
 461   (format #t "}\n"))
 462 (define (list-of-namespace-configuration? val)
 463   (and (list? val) (and-map namespace-configuration? val)))
 464 (define (serialize-list-of-namespace-configuration field-name val)
 465   (for-each (lambda (val)
 466               (serialize-namespace-configuration field-name val))
 467             val))
 468
 469 (define-configuration dovecot-configuration
 470   (dovecot
 471    (package dovecot)
 472    "The dovecot package.")
 473
 474   (listen
 475    (comma-separated-string-list '("*" "::"))
 476    "A list of IPs or hosts where to listen in for connections.  @samp{*}
 477 listens in all IPv4 interfaces, @samp{::} listens in all IPv6
 478 interfaces.  If you want to specify non-default ports or anything more
 479 complex, customize the address and port fields of the
 480 @samp{inet-listener} of the specific services you are interested in.")
 481
 482   (protocols
 483    (protocol-configuration-list
 484     (list (protocol-configuration
 485            (name "imap"))))
 486    "List of protocols we want to serve.  Available protocols include
 487 @samp{imap}, @samp{pop3}, and @samp{lmtp}.")
 488
 489   (services
 490    (service-configuration-list
 491     (list
 492      (service-configuration
 493       (kind "imap-login")
 494       (client-limit 0)
 495       (process-limit 0)
 496       (listeners
 497        (list
 498         (inet-listener-configuration (protocol "imap") (port 143) (ssl? #f))
 499         (inet-listener-configuration (protocol "imaps") (port 993) (ssl? #t)))))
 500      (service-configuration
 501       (kind "pop3-login")
 502       (listeners
 503        (list
 504         (inet-listener-configuration (protocol "pop3") (port 110) (ssl? #f))
 505         (inet-listener-configuration (protocol "pop3s") (port 995) (ssl? #t)))))
 506      (service-configuration
 507       (kind "lmtp")
 508       (client-limit 1)
 509       (process-limit 0)
 510       (listeners
 511        (list (unix-listener-configuration (path "lmtp") (mode "0666")))))
 512      (service-configuration
 513       (kind "imap")
 514       (client-limit 1)
 515       (process-limit 1024))
 516      (service-configuration
 517       (kind "pop3")
 518       (client-limit 1)
 519       (process-limit 1024))
 520      (service-configuration
 521       (kind "auth")
 522       (service-count 0)
 523       (client-limit 0)
 524       (process-limit 1)
 525       (listeners
 526        (list (unix-listener-configuration (path "auth-userdb")))))
 527      (service-configuration
 528       (kind "auth-worker")
 529       (client-limit 1)
 530       (process-limit 0))
 531      (service-configuration
 532       (kind "dict")
 533       (client-limit 1)
 534       (process-limit 0)
 535       (listeners (list (unix-listener-configuration (path "dict")))))))
 536    "List of services to enable.  Available services include @samp{imap},
 537 @samp{imap-login}, @samp{pop3}, @samp{pop3-login}, @samp{auth}, and
 538 @samp{lmtp}.")
 539
 540   (dict
 541    (dict-configuration (dict-configuration))
 542    "Dict configuration, as created by the @code{dict-configuration}
 543 constructor.")
 544
 545   (passdbs
 546    (passdb-configuration-list (list (passdb-configuration (driver "pam"))))
 547    "List of passdb configurations, each one created by the
 548 @code{passdb-configuration} constructor.")
 549
 550   (userdbs
 551    (userdb-configuration-list (list (userdb-configuration (driver "passwd"))))
 552    "List of userdb configurations, each one created by the
 553 @code{userdb-configuration} constructor.")
 554
 555   (plugin-configuration
 556    (plugin-configuration (plugin-configuration))
 557    "Plug-in configuration, created by the @code{plugin-configuration}
 558 constructor.")
 559
 560   (namespaces
 561    (list-of-namespace-configuration
 562     (list
 563      (namespace-configuration
 564       (name "inbox")
 565       (prefix "")
 566       (inbox? #t)
 567       (mailboxes
 568        (list
 569         (mailbox-configuration (name "Drafts") (special-use '("\\Drafts")))
 570         (mailbox-configuration (name "Junk") (special-use '("\\Junk")))
 571         (mailbox-configuration (name "Trash") (special-use '("\\Trash")))
 572         (mailbox-configuration (name "Sent") (special-use '("\\Sent")))
 573         (mailbox-configuration (name "Sent Messages") (special-use '("\\Sent")))
 574         (mailbox-configuration (name "Drafts") (special-use '("\\Drafts"))))))))
 575    "List of namespaces.  Each item in the list is created by the
 576 @code{namespace-configuration} constructor.")
 577
 578   (base-dir
 579    (file-name "/var/run/dovecot/")
 580    "Base directory where to store runtime data.")
 581
 582   (login-greeting
 583    (string "Dovecot ready.")
 584    "Greeting message for clients.")
 585
 586   (login-trusted-networks
 587    (space-separated-string-list '())
 588    "List of trusted network ranges.  Connections from these IPs are
 589 allowed to override their IP addresses and ports (for logging and for
 590 authentication checks).  @samp{disable-plaintext-auth} is also ignored
 591 for these networks.  Typically you'd specify your IMAP proxy servers
 592 here.")
 593
 594   (login-access-sockets
 595    (space-separated-string-list '())
 596    "List of login access check sockets (e.g. tcpwrap).")
 597
 598   (verbose-proctitle?
 599    (boolean #f)
 600    "Show more verbose process titles (in ps).  Currently shows user name
 601 and IP address.  Useful for seeing who are actually using the IMAP
 602 processes (e.g. shared mailboxes or if same uid is used for multiple
 603 accounts).")
 604
 605   (shutdown-clients?
 606    (boolean #t)
 607    "Should all processes be killed when Dovecot master process shuts down.
 608 Setting this to @code{#f} means that Dovecot can be upgraded without
 609 forcing existing client connections to close (although that could also
 610 be a problem if the upgrade is e.g. because of a security fix).")
 611
 612   (doveadm-worker-count
 613    (non-negative-integer 0)
 614    "If non-zero, run mail commands via this many connections to doveadm
 615 server, instead of running them directly in the same process.")
 616
 617   (doveadm-socket-path
 618    (string "doveadm-server")
 619    "UNIX socket or host:port used for connecting to doveadm server.")
 620
 621   (import-environment
 622    (space-separated-string-list '("TZ"))
 623    "List of environment variables that are preserved on Dovecot startup
 624 and passed down to all of its child processes.  You can also give
 625 key=value pairs to always set specific settings.")
 626
 627 ;;; Authentication processes
 628
 629   (disable-plaintext-auth?
 630    (boolean #t)
 631    "Disable LOGIN command and all other plaintext authentications unless
 632 SSL/TLS is used (LOGINDISABLED capability).  Note that if the remote IP
 633 matches the local IP (i.e. you're connecting from the same computer),
 634 the connection is considered secure and plaintext authentication is
 635 allowed.  See also ssl=required setting.")
 636
 637   (auth-cache-size
 638    (non-negative-integer 0)
 639    "Authentication cache size (e.g. @samp{#e10e6}).  0 means it's disabled.
 640 Note that bsdauth, PAM and vpopmail require @samp{cache-key} to be set
 641 for caching to be used.")
 642
 643   (auth-cache-ttl
 644    (string "1 hour")
 645    "Time to live for cached data.  After TTL expires the cached record
 646 is no longer used, *except* if the main database lookup returns internal
 647 failure.  We also try to handle password changes automatically: If
 648 user's previous authentication was successful, but this one wasn't, the
 649 cache isn't used.  For now this works only with plaintext
 650 authentication.")
 651
 652   (auth-cache-negative-ttl
 653    (string "1 hour")
 654    "TTL for negative hits (user not found, password mismatch).
 655 0 disables caching them completely.")
 656
 657   (auth-realms
 658    (space-separated-string-list '())
 659    "List of realms for SASL authentication mechanisms that need them.
 660 You can leave it empty if you don't want to support multiple realms.
 661 Many clients simply use the first one listed here, so keep the default
 662 realm first.")
 663
 664   (auth-default-realm
 665    (string "")
 666    "Default realm/domain to use if none was specified.  This is used for
 667 both SASL realms and appending @@domain to username in plaintext
 668 logins.")
 669
 670   (auth-username-chars
 671    (string
 672     "abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ01234567890.-_@")
 673    "List of allowed characters in username.  If the user-given username
 674 contains a character not listed in here, the login automatically fails.
 675 This is just an extra check to make sure user can't exploit any
 676 potential quote escaping vulnerabilities with SQL/LDAP databases.  If
 677 you want to allow all characters, set this value to empty.")
 678
 679   (auth-username-translation
 680    (string "")
 681    "Username character translations before it's looked up from
 682 databases.  The value contains series of from -> to characters.  For
 683 example @samp{#@@/@@} means that @samp{#} and @samp{/} characters are
 684 translated to @samp{@@}.")
 685
 686   (auth-username-format
 687    (string "%Lu")
 688    "Username formatting before it's looked up from databases.  You can
 689 use the standard variables here, e.g. %Lu would lowercase the username,
 690 %n would drop away the domain if it was given, or @samp{%n-AT-%d} would
 691 change the @samp{@@} into @samp{-AT-}.  This translation is done after
 692 @samp{auth-username-translation} changes.")
 693
 694   (auth-master-user-separator
 695    (string "")
 696    "If you want to allow master users to log in by specifying the master
 697 username within the normal username string (i.e. not using SASL
 698 mechanism's support for it), you can specify the separator character
 699 here.  The format is then <username><separator><master username>.
 700 UW-IMAP uses @samp{*} as the separator, so that could be a good
 701 choice.")
 702
 703   (auth-anonymous-username
 704    (string "anonymous")
 705    "Username to use for users logging in with ANONYMOUS SASL
 706 mechanism.")
 707
 708   (auth-worker-max-count
 709    (non-negative-integer 30)
 710    "Maximum number of dovecot-auth worker processes.  They're used to
 711 execute blocking passdb and userdb queries (e.g. MySQL and PAM).
 712 They're automatically created and destroyed as needed.")
 713
 714   (auth-gssapi-hostname
 715    (string "")
 716    "Host name to use in GSSAPI principal names.  The default is to use
 717 the name returned by gethostname().  Use @samp{$ALL} (with quotes) to
 718 allow all keytab entries.")
 719
 720   (auth-krb5-keytab
 721    (string "")
 722    "Kerberos keytab to use for the GSSAPI mechanism.  Will use the
 723 system default (usually /etc/krb5.keytab) if not specified.  You may
 724 need to change the auth service to run as root to be able to read this
 725 file.")
 726
 727   (auth-use-winbind?
 728    (boolean #f)
 729    "Do NTLM and GSS-SPNEGO authentication using Samba's winbind daemon
 730 and @samp{ntlm-auth} helper.
 731 <doc/wiki/Authentication/Mechanisms/Winbind.txt>.")
 732
 733   (auth-winbind-helper-path
 734    (file-name "/usr/bin/ntlm_auth")
 735    "Path for Samba's @samp{ntlm-auth} helper binary.")
 736
 737   (auth-failure-delay
 738    (string "2 secs")
 739    "Time to delay before replying to failed authentications.")
 740
 741   (auth-ssl-require-client-cert?
 742    (boolean #f)
 743    "Require a valid SSL client certificate or the authentication
 744 fails.")
 745
 746   (auth-ssl-username-from-cert?
 747    (boolean #f)
 748    "Take the username from client's SSL certificate, using
 749 @code{X509_NAME_get_text_by_NID()} which returns the subject's DN's
 750 CommonName.")
 751
 752   (auth-mechanisms
 753    (space-separated-string-list '("plain"))
 754    "List of wanted authentication mechanisms.  Supported mechanisms are:
 755 @samp{plain}, @samp{login}, @samp{digest-md5}, @samp{cram-md5},
 756 @samp{ntlm}, @samp{rpa}, @samp{apop}, @samp{anonymous}, @samp{gssapi},
 757 @samp{otp}, @samp{skey}, and @samp{gss-spnego}.  NOTE: See also
 758 @samp{disable-plaintext-auth} setting.")
 759
 760   (director-servers
 761    (space-separated-string-list '())
 762    "List of IPs or hostnames to all director servers, including ourself.
 763 Ports can be specified as ip:port.  The default port is the same as what
 764 director service's @samp{inet-listener} is using.")
 765
 766   (director-mail-servers
 767    (space-separated-string-list '())
 768    "List of IPs or hostnames to all backend mail servers.  Ranges are
 769 allowed too, like 10.0.0.10-10.0.0.30.")
 770
 771   (director-user-expire
 772    (string "15 min")
 773    "How long to redirect users to a specific server after it no longer
 774 has any connections.")
 775
 776   (director-username-hash
 777    (string "%Lu")
 778    "How the username is translated before being hashed.  Useful values
 779 include %Ln if user can log in with or without @@domain, %Ld if mailboxes
 780 are shared within domain.")
 781
 782 ;;; Log destination.
 783
 784   (log-path
 785    (string "syslog")
 786    "Log file to use for error messages.  @samp{syslog} logs to syslog,
 787 @samp{/dev/stderr} logs to stderr.")
 788
 789   (info-log-path
 790    (string "")
 791    "Log file to use for informational messages.  Defaults to
 792 @samp{log-path}.")
 793
 794   (debug-log-path
 795    (string "")
 796    "Log file to use for debug messages.  Defaults to
 797 @samp{info-log-path}.")
 798
 799   (syslog-facility
 800    (string "mail")
 801    "Syslog facility to use if you're logging to syslog.  Usually if you
 802 don't want to use @samp{mail}, you'll use local0..local7.  Also other
 803 standard facilities are supported.")
 804
 805   (auth-verbose?
 806    (boolean #f)
 807    "Log unsuccessful authentication attempts and the reasons why they
 808 failed.")
 809
 810   (auth-verbose-passwords
 811    (string "no")
 812    "In case of password mismatches, log the attempted password.  Valid
 813 values are no, plain and sha1.  sha1 can be useful for detecting brute
 814 force password attempts vs.  user simply trying the same password over
 815 and over again.  You can also truncate the value to n chars by appending
 816 \":n\" (e.g. sha1:6).")
 817
 818   (auth-debug?
 819    (boolean #f)
 820    "Even more verbose logging for debugging purposes.  Shows for example
 821 SQL queries.")
 822
 823   (auth-debug-passwords?
 824    (boolean #f)
 825    "In case of password mismatches, log the passwords and used scheme so
 826 the problem can be debugged.  Enabling this also enables
 827 @samp{auth-debug}.")
 828
 829   (mail-debug?
 830    (boolean #f)
 831    "Enable mail process debugging.  This can help you figure out why
 832 Dovecot isn't finding your mails.")
 833
 834   (verbose-ssl?
 835    (boolean #f)
 836    "Show protocol level SSL errors.")
 837
 838   (log-timestamp
 839    (string "\"%b %d %H:%M:%S \"")
 840    "Prefix for each line written to log file.  % codes are in
 841 strftime(3) format.")
 842
 843   (login-log-format-elements
 844    (space-separated-string-list
 845     '("user=<%u>" "method=%m" "rip=%r" "lip=%l" "mpid=%e" "%c"))
 846    "List of elements we want to log.  The elements which have a
 847 non-empty variable value are joined together to form a comma-separated
 848 string.")
 849
 850   (login-log-format
 851    (string "%$: %s")
 852    "Login log format.  %s contains @samp{login-log-format-elements}
 853 string, %$ contains the data we want to log.")
 854
 855   (mail-log-prefix
 856    (string "\"%s(%u)<%{pid}><%{session}>: \"")
 857    "Log prefix for mail processes.  See doc/wiki/Variables.txt for list
 858 of possible variables you can use.")
 859
 860   (deliver-log-format
 861    (string "msgid=%m: %$")
 862    "Format to use for logging mail deliveries.  You can use variables:
 863 @table @code
 864 @item %$
 865 Delivery status message (e.g. @samp{saved to INBOX})
 866 @item %m
 867 Message-ID
 868 @item %s
 869 Subject
 870 @item %f
 871 From address
 872 @item %p
 873 Physical size
 874 @item %w
 875 Virtual size.
 876 @end table")
 877
 878 ;;; Mailbox locations and namespaces
 879
 880   (mail-location
 881    (string "")
 882    "Location for users' mailboxes.  The default is empty, which means
 883 that Dovecot tries to find the mailboxes automatically.  This won't work
 884 if the user doesn't yet have any mail, so you should explicitly tell
 885 Dovecot the full location.
 886
 887 If you're using mbox, giving a path to the INBOX
 888 file (e.g. /var/mail/%u) isn't enough.  You'll also need to tell Dovecot
 889 where the other mailboxes are kept.  This is called the \"root mail
 890 directory\", and it must be the first path given in the
 891 @samp{mail-location} setting.
 892
 893 There are a few special variables you can use, eg.:
 894
 895 @table @samp
 896 @item %u
 897 username
 898 @item %n
 899 user part in user@@domain, same as %u if there's no domain
 900 @item %d
 901 domain part in user@@domain, empty if there's no domain
 902 @item %h
 903 home director
 904 @end table
 905
 906 See doc/wiki/Variables.txt for full list.  Some examples:
 907 @table @samp
 908 @item maildir:~/Maildir
 909 @item mbox:~/mail:INBOX=/var/mail/%u
 910 @item mbox:/var/mail/%d/%1n/%n:INDEX=/var/indexes/%d/%1n/%
 911 @end table")
 912
 913   (mail-uid
 914    (string "")
 915    "System user and group used to access mails.  If you use multiple,
 916 userdb can override these by returning uid or gid fields.  You can use
 917 either numbers or names.  <doc/wiki/UserIds.txt>.")
 918
 919   (mail-gid
 920    (string "")
 921    "")
 922
 923   (mail-privileged-group
 924    (string "")
 925    "Group to enable temporarily for privileged operations.  Currently
 926 this is used only with INBOX when either its initial creation or
 927 dotlocking fails.  Typically this is set to \"mail\" to give access to
 928 /var/mail.")
 929
 930   (mail-access-groups
 931    (string "")
 932    "Grant access to these supplementary groups for mail processes.
 933 Typically these are used to set up access to shared mailboxes.  Note
 934 that it may be dangerous to set these if users can create
 935 symlinks (e.g. if \"mail\" group is set here, ln -s /var/mail ~/mail/var
 936 could allow a user to delete others' mailboxes, or ln -s
 937 /secret/shared/box ~/mail/mybox would allow reading it).")
 938
 939   (mail-full-filesystem-access?
 940    (boolean #f)
 941    "Allow full file system access to clients.  There's no access checks
 942 other than what the operating system does for the active UID/GID.  It
 943 works with both maildir and mboxes, allowing you to prefix mailboxes
 944 names with e.g. /path/ or ~user/.")
 945
 946 ;;; Mail processes
 947
 948   (mmap-disable?
 949    (boolean #f)
 950    "Don't use mmap() at all.  This is required if you store indexes to
 951 shared file systems (NFS or clustered file system).")
 952
 953   (dotlock-use-excl?
 954    (boolean #t)
 955    "Rely on @samp{O_EXCL} to work when creating dotlock files.  NFS
 956 supports @samp{O_EXCL} since version 3, so this should be safe to use
 957 nowadays by default.")
 958
 959   (mail-fsync
 960    (string "optimized")
 961    "When to use fsync() or fdatasync() calls:
 962 @table @code
 963 @item optimized
 964 Whenever necessary to avoid losing important data
 965 @item always
 966 Useful with e.g. NFS when write()s are delayed
 967 @item never
 968 Never use it (best performance, but crashes can lose data).
 969 @end table")
 970
 971   (mail-nfs-storage?
 972    (boolean #f)
 973    "Mail storage exists in NFS.  Set this to yes to make Dovecot flush
 974 NFS caches whenever needed.  If you're using only a single mail server
 975 this isn't needed.")
 976
 977   (mail-nfs-index?
 978    (boolean #f)
 979    "Mail index files also exist in NFS.  Setting this to yes requires
 980 @samp{mmap-disable? #t} and @samp{fsync-disable? #f}.")
 981
 982   (lock-method
 983    (string "fcntl")
 984    "Locking method for index files.  Alternatives are fcntl, flock and
 985 dotlock.  Dotlocking uses some tricks which may create more disk I/O
 986 than other locking methods.  NFS users: flock doesn't work, remember to
 987 change @samp{mmap-disable}.")
 988
 989   (mail-temp-dir
 990    (file-name "/tmp")
 991    "Directory in which LDA/LMTP temporarily stores incoming mails >128
 992 kB.")
 993
 994   (first-valid-uid
 995    (non-negative-integer 500)
 996    "Valid UID range for users.  This is mostly to make sure that users can't
 997 log in as daemons or other system users.  Note that denying root logins is
 998 hardcoded to dovecot binary and can't be done even if @samp{first-valid-uid}
 999 is set to 0.")
1000
1001   (last-valid-uid
1002    (non-negative-integer 0)
1003    "")
1004
1005   (first-valid-gid
1006    (non-negative-integer 1)
1007    "Valid GID range for users.  Users having non-valid GID as primary group ID
1008 aren't allowed to log in.  If user belongs to supplementary groups with
1009 non-valid GIDs, those groups are not set.")
1010
1011   (last-valid-gid
1012    (non-negative-integer 0)
1013    "")
1014
1015   (mail-max-keyword-length
1016    (non-negative-integer 50)
1017    "Maximum allowed length for mail keyword name.  It's only forced when
1018 trying to create new keywords.")
1019
1020   (valid-chroot-dirs
1021    (colon-separated-file-name-list '())
1022    "List of directories under which chrooting is allowed for mail
1023 processes (i.e. /var/mail will allow chrooting to /var/mail/foo/bar
1024 too).  This setting doesn't affect @samp{login-chroot}
1025 @samp{mail-chroot} or auth chroot settings.  If this setting is empty,
1026 \"/./\" in home dirs are ignored.  WARNING: Never add directories here
1027 which local users can modify, that may lead to root exploit.  Usually
1028 this should be done only if you don't allow shell access for users.
1029 <doc/wiki/Chrooting.txt>.")
1030
1031   (mail-chroot
1032    (string "")
1033    "Default chroot directory for mail processes.  This can be overridden
1034 for specific users in user database by giving /./ in user's home
1035 directory (e.g. /home/./user chroots into /home).  Note that usually
1036 there is no real need to do chrooting, Dovecot doesn't allow users to
1037 access files outside their mail directory anyway.  If your home
1038 directories are prefixed with the chroot directory, append \"/.\" to
1039 @samp{mail-chroot}.  <doc/wiki/Chrooting.txt>.")
1040
1041   (auth-socket-path
1042    (file-name "/var/run/dovecot/auth-userdb")
1043    "UNIX socket path to master authentication server to find users.
1044 This is used by imap (for shared users) and lda.")
1045
1046   (mail-plugin-dir
1047    (file-name "/usr/lib/dovecot")
1048    "Directory where to look up mail plugins.")
1049
1050   (mail-plugins
1051    (space-separated-string-list '())
1052    "List of plugins to load for all services.  Plugins specific to IMAP,
1053 LDA, etc. are added to this list in their own .conf files.")
1054
1055
1056   (mail-cache-min-mail-count
1057    (non-negative-integer 0)
1058    "The minimum number of mails in a mailbox before updates are done to
1059 cache file.  This allows optimizing Dovecot's behavior to do less disk
1060 writes at the cost of more disk reads.")
1061
1062   (mailbox-idle-check-interval
1063    (string "30 secs")
1064    "When IDLE command is running, mailbox is checked once in a while to
1065 see if there are any new mails or other changes.  This setting defines
1066 the minimum time to wait between those checks.  Dovecot can also use
1067 dnotify, inotify and kqueue to find out immediately when changes
1068 occur.")
1069
1070   (mail-save-crlf?
1071    (boolean #f)
1072    "Save mails with CR+LF instead of plain LF.  This makes sending those
1073 mails take less CPU, especially with sendfile() syscall with Linux and
1074 FreeBSD.  But it also creates a bit more disk I/O which may just make it
1075 slower.  Also note that if other software reads the mboxes/maildirs,
1076 they may handle the extra CRs wrong and cause problems.")
1077
1078   (maildir-stat-dirs?
1079    (boolean #f)
1080    "By default LIST command returns all entries in maildir beginning
1081 with a dot.  Enabling this option makes Dovecot return only entries
1082 which are directories.  This is done by stat()ing each entry, so it
1083 causes more disk I/O.
1084  (For systems setting struct @samp{dirent->d_type} this check is free
1085 and it's done always regardless of this setting).")
1086
1087   (maildir-copy-with-hardlinks?
1088    (boolean #t)
1089    "When copying a message, do it with hard links whenever possible.
1090 This makes the performance much better, and it's unlikely to have any
1091 side effects.")
1092
1093   (maildir-very-dirty-syncs?
1094    (boolean #f)
1095    "Assume Dovecot is the only MUA accessing Maildir: Scan cur/
1096 directory only when its mtime changes unexpectedly or when we can't find
1097 the mail otherwise.")
1098
1099   (mbox-read-locks
1100    (space-separated-string-list '("fcntl"))
1101    "Which locking methods to use for locking mbox.  There are four
1102 available:
1103
1104 @table @code
1105 @item dotlock
1106 Create <mailbox>.lock file.  This is the oldest and most NFS-safe
1107 solution.  If you want to use /var/mail/ like directory, the users will
1108 need write access to that directory.
1109 @item dotlock-try
1110 Same as dotlock, but if it fails because of permissions or because there
1111 isn't enough disk space, just skip it.
1112 @item fcntl
1113 Use this if possible.  Works with NFS too if lockd is used.
1114 @item flock
1115 May not exist in all systems.  Doesn't work with NFS.
1116 @item lockf
1117 May not exist in all systems.  Doesn't work with NFS.
1118 @end table
1119
1120 You can use multiple locking methods; if you do the order they're declared
1121 in is important to avoid deadlocks if other MTAs/MUAs are using multiple
1122 locking methods as well.  Some operating systems don't allow using some of
1123 them simultaneously.")
1124
1125   (mbox-write-locks
1126    (space-separated-string-list '("dotlock" "fcntl"))
1127    "")
1128
1129   (mbox-lock-timeout
1130    (string "5 mins")
1131    "Maximum time to wait for lock (all of them) before aborting.")
1132
1133   (mbox-dotlock-change-timeout
1134    (string "2 mins")
1135    "If dotlock exists but the mailbox isn't modified in any way,
1136 override the lock file after this much time.")
1137
1138   (mbox-dirty-syncs?
1139    (boolean #t)
1140    "When mbox changes unexpectedly we have to fully read it to find out
1141 what changed.  If the mbox is large this can take a long time.  Since
1142 the change is usually just a newly appended mail, it'd be faster to
1143 simply read the new mails.  If this setting is enabled, Dovecot does
1144 this but still safely fallbacks to re-reading the whole mbox file
1145 whenever something in mbox isn't how it's expected to be.  The only real
1146 downside to this setting is that if some other MUA changes message
1147 flags, Dovecot doesn't notice it immediately.  Note that a full sync is
1148 done with SELECT, EXAMINE, EXPUNGE and CHECK commands.")
1149
1150   (mbox-very-dirty-syncs?
1151    (boolean #f)
1152    "Like @samp{mbox-dirty-syncs}, but don't do full syncs even with SELECT,
1153 EXAMINE, EXPUNGE or CHECK commands.  If this is set,
1154 @samp{mbox-dirty-syncs} is ignored.")
1155
1156   (mbox-lazy-writes?
1157    (boolean #t)
1158    "Delay writing mbox headers until doing a full write sync (EXPUNGE
1159 and CHECK commands and when closing the mailbox).  This is especially
1160 useful for POP3 where clients often delete all mails.  The downside is
1161 that our changes aren't immediately visible to other MUAs.")
1162
1163   (mbox-min-index-size
1164    (non-negative-integer 0)
1165    "If mbox size is smaller than this (e.g. 100k), don't write index
1166 files.  If an index file already exists it's still read, just not
1167 updated.")
1168
1169   (mdbox-rotate-size
1170    (non-negative-integer #e10e6)
1171    "Maximum dbox file size until it's rotated.")
1172
1173   (mdbox-rotate-interval
1174    (string "1d")
1175    "Maximum dbox file age until it's rotated.  Typically in days.  Day
1176 begins from midnight, so 1d = today, 2d = yesterday, etc.  0 = check
1177 disabled.")
1178
1179   (mdbox-preallocate-space?
1180    (boolean #f)
1181    "When creating new mdbox files, immediately preallocate their size to
1182 @samp{mdbox-rotate-size}.  This setting currently works only in Linux
1183 with some file systems (ext4, xfs).")
1184
1185   (mail-attachment-dir
1186    (string "")
1187    "sdbox and mdbox support saving mail attachments to external files,
1188 which also allows single instance storage for them.  Other backends
1189 don't support this for now.
1190
1191 WARNING: This feature hasn't been tested much yet.  Use at your own risk.
1192
1193 Directory root where to store mail attachments.  Disabled, if empty.")
1194
1195   (mail-attachment-min-size
1196    (non-negative-integer #e128e3)
1197    "Attachments smaller than this aren't saved externally.  It's also
1198 possible to write a plugin to disable saving specific attachments
1199 externally.")
1200
1201   (mail-attachment-fs
1202    (string "sis posix")
1203    "File system backend to use for saving attachments:
1204 @table @code
1205 @item posix
1206 No SiS done by Dovecot (but this might help FS's own deduplication)
1207 @item sis posix
1208 SiS with immediate byte-by-byte comparison during saving
1209 @item sis-queue posix
1210 SiS with delayed comparison and deduplication.
1211 @end table")
1212
1213   (mail-attachment-hash
1214    (string "%{sha1}")
1215    "Hash format to use in attachment filenames.  You can add any text and
1216 variables: @code{%@{md4@}}, @code{%@{md5@}}, @code{%@{sha1@}},
1217 @code{%@{sha256@}}, @code{%@{sha512@}}, @code{%@{size@}}.  Variables can be
1218 truncated, e.g. @code{%@{sha256:80@}} returns only first 80 bits.")
1219
1220   (default-process-limit
1221     (non-negative-integer 100)
1222     "")
1223
1224   (default-client-limit
1225     (non-negative-integer 1000)
1226     "")
1227
1228   (default-vsz-limit
1229     (non-negative-integer #e256e6)
1230     "Default VSZ (virtual memory size) limit for service processes.
1231 This is mainly intended to catch and kill processes that leak memory
1232 before they eat up everything.")
1233
1234   (default-login-user
1235     (string "dovenull")
1236     "Login user is internally used by login processes.  This is the most
1237 untrusted user in Dovecot system.  It shouldn't have access to anything
1238 at all.")
1239
1240   (default-internal-user
1241     (string "dovecot")
1242     "Internal user is used by unprivileged processes.  It should be
1243 separate from login user, so that login processes can't disturb other
1244 processes.")
1245
1246   (ssl?
1247    (string "required")
1248    "SSL/TLS support: yes, no, required.  <doc/wiki/SSL.txt>.")
1249
1250   (ssl-cert
1251    (string "</etc/dovecot/default.pem")
1252    "PEM encoded X.509 SSL/TLS certificate (public key).")
1253
1254   (ssl-key
1255    (string "</etc/dovecot/private/default.pem")
1256    "PEM encoded SSL/TLS private key.  The key is opened before
1257 dropping root privileges, so keep the key file unreadable by anyone but
1258 root.")
1259
1260   (ssl-key-password
1261    (string "")
1262    "If key file is password protected, give the password here.
1263 Alternatively give it when starting dovecot with -p parameter.  Since
1264 this file is often world-readable, you may want to place this setting
1265 instead to a different.")
1266
1267   (ssl-ca
1268    (string "")
1269    "PEM encoded trusted certificate authority.  Set this only if you
1270 intend to use @samp{ssl-verify-client-cert? #t}.  The file should
1271 contain the CA certificate(s) followed by the matching
1272 CRL(s).  (e.g. @samp{ssl-ca </etc/ssl/certs/ca.pem}).")
1273   (ssl-require-crl?
1274    (boolean #t)
1275    "Require that CRL check succeeds for client certificates.")
1276   (ssl-verify-client-cert?
1277    (boolean #f)
1278    "Request client to send a certificate.  If you also want to require
1279 it, set @samp{auth-ssl-require-client-cert? #t} in auth section.")
1280
1281   (ssl-cert-username-field
1282    (string "commonName")
1283    "Which field from certificate to use for username.  commonName and
1284 x500UniqueIdentifier are the usual choices.  You'll also need to set
1285 @samp{auth-ssl-username-from-cert? #t}.")
1286
1287   (ssl-min-protocol
1288    (string "TLSv1")
1289    "Minimum SSL protocol version to accept.")
1290
1291   (ssl-cipher-list
1292    (string "ALL:!kRSA:!SRP:!kDHd:!DSS:!aNULL:!eNULL:!EXPORT:!DES:!3DES:!MD5:!PSK:!RC4:!ADH:!LOW@STRENGTH")
1293    "SSL ciphers to use.")
1294
1295   (ssl-crypto-device
1296    (string "")
1297    "SSL crypto device to use, for valid values run \"openssl engine\".")
1298
1299   (postmaster-address
1300    (string "postmaster@%d")
1301    "Address to use when sending rejection mails.
1302 Default is postmaster@@<your domain>.  %d expands to recipient domain.")
1303
1304   (hostname
1305    (string "")
1306    "Hostname to use in various parts of sent mails (e.g. in Message-Id)
1307 and in LMTP replies.  Default is the system's real hostname@@domain.")
1308
1309   (quota-full-tempfail?
1310    (boolean #f)
1311    "If user is over quota, return with temporary failure instead of
1312 bouncing the mail.")
1313
1314   (sendmail-path
1315    (file-name "/usr/sbin/sendmail")
1316    "Binary to use for sending mails.")
1317
1318   (submission-host
1319    (string "")
1320    "If non-empty, send mails via this SMTP host[:port] instead of
1321 sendmail.")
1322
1323   (rejection-subject
1324    (string "Rejected: %s")
1325    "Subject: header to use for rejection mails.  You can use the same
1326 variables as for @samp{rejection-reason} below.")
1327
1328   (rejection-reason
1329    (string "Your message to <%t> was automatically rejected:%n%r")
1330    "Human readable error message for rejection mails.  You can use
1331 variables:
1332
1333 @table @code
1334 @item %n
1335 CRLF
1336 @item %r
1337 reason
1338 @item %s
1339 original subject
1340 @item %t
1341 recipient
1342 @end table")
1343
1344   (recipient-delimiter
1345    (string "+")
1346    "Delimiter character between local-part and detail in email
1347 address.")
1348
1349   (lda-original-recipient-header
1350    (string "")
1351    "Header where the original recipient address (SMTP's RCPT TO:
1352 address) is taken from if not available elsewhere.  With dovecot-lda -a
1353 parameter overrides this.  A commonly used header for this is
1354 X-Original-To.")
1355
1356   (lda-mailbox-autocreate?
1357    (boolean #f)
1358    "Should saving a mail to a nonexistent mailbox automatically create
1359 it?.")
1360
1361   (lda-mailbox-autosubscribe?
1362    (boolean #f)
1363    "Should automatically created mailboxes be also automatically
1364 subscribed?.")
1365
1366
1367   (imap-max-line-length
1368    (non-negative-integer #e64e3)
1369    "Maximum IMAP command line length.  Some clients generate very long
1370 command lines with huge mailboxes, so you may need to raise this if you
1371 get \"Too long argument\" or \"IMAP command line too large\" errors
1372 often.")
1373
1374   (imap-logout-format
1375    (string "in=%i out=%o deleted=%{deleted} expunged=%{expunged} trashed=%{trashed} hdr_count=%{fetch_hdr_count} hdr_bytes=%{fetch_hdr_bytes} body_count=%{fetch_body_count} body_bytes=%{fetch_body_bytes}")
1376    "IMAP logout format string:
1377 @table @code
1378 @item %i
1379 total number of bytes read from client
1380 @item %o
1381 total number of bytes sent to client.
1382 @end table
1383 See @file{doc/wiki/Variables.txt} for a list of all the variables you can use.")
1384
1385   (imap-capability
1386    (string "")
1387    "Override the IMAP CAPABILITY response.  If the value begins with '+',
1388 add the given capabilities on top of the defaults (e.g. +XFOO XBAR).")
1389
1390   (imap-idle-notify-interval
1391    (string "2 mins")
1392    "How long to wait between \"OK Still here\" notifications when client
1393 is IDLEing.")
1394
1395   (imap-id-send
1396    (string "")
1397    "ID field names and values to send to clients.  Using * as the value
1398 makes Dovecot use the default value.  The following fields have default
1399 values currently: name, version, os, os-version, support-url,
1400 support-email.")
1401
1402   (imap-id-log
1403    (string "")
1404    "ID fields sent by client to log.  * means everything.")
1405
1406   (imap-client-workarounds
1407    (space-separated-string-list '())
1408    "Workarounds for various client bugs:
1409
1410 @table @code
1411 @item delay-newmail
1412 Send EXISTS/RECENT new mail notifications only when replying to NOOP and
1413 CHECK commands.  Some clients ignore them otherwise, for example OSX
1414 Mail (<v2.1).  Outlook Express breaks more badly though, without this it
1415 may show user \"Message no longer in server\" errors.  Note that OE6
1416 still breaks even with this workaround if synchronization is set to
1417 \"Headers Only\".
1418
1419 @item tb-extra-mailbox-sep
1420 Thunderbird gets somehow confused with LAYOUT=fs (mbox and dbox) and
1421 adds extra @samp{/} suffixes to mailbox names.  This option causes Dovecot to
1422 ignore the extra @samp{/} instead of treating it as invalid mailbox name.
1423
1424 @item tb-lsub-flags
1425 Show \\Noselect flags for LSUB replies with LAYOUT=fs (e.g. mbox).
1426 This makes Thunderbird realize they aren't selectable and show them
1427 greyed out, instead of only later giving \"not selectable\" popup error.
1428 @end table
1429 ")
1430
1431   (imap-urlauth-host
1432    (string "")
1433    "Host allowed in URLAUTH URLs sent by client.  \"*\" allows all.")  )
1434
1435 (define-configuration opaque-dovecot-configuration
1436   (dovecot
1437    (package dovecot)
1438    "The dovecot package.")
1439
1440   (string
1441    (string (configuration-missing-field 'opaque-dovecot-configuration
1442                                         'string))
1443    "The contents of the @code{dovecot.conf} to use."))
1444
1445 (define %dovecot-accounts
1446   ;; Account and group for the Dovecot daemon.
1447   (list (user-group (name "dovecot") (system? #t))
1448         (user-account
1449          (name "dovecot")
1450          (group "dovecot")
1451          (system? #t)
1452          (comment "Dovecot daemon user")
1453          (home-directory "/var/empty")
1454          (shell (file-append shadow "/sbin/nologin")))
1455
1456         (user-group (name "dovenull") (system? #t))
1457         (user-account
1458          (name "dovenull")
1459          (group "dovenull")
1460          (system? #t)
1461          (comment "Dovecot daemon login user")
1462          (home-directory "/var/empty")
1463          (shell (file-append shadow "/sbin/nologin")))))
1464
1465 (define (%dovecot-activation config)
1466   ;; Activation gexp.
1467   (let ((config-str
1468          (cond
1469           ((opaque-dovecot-configuration? config)
1470            (opaque-dovecot-configuration-string config))
1471           (else
1472            (with-output-to-string
1473              (lambda ()
1474                (serialize-configuration config
1475                                         dovecot-configuration-fields)))))))
1476     #~(begin
1477         (use-modules (guix build utils))
1478         (define (mkdir-p/perms directory owner perms)
1479           (mkdir-p directory)
1480           (chown "/var/run/dovecot" (passwd:uid owner) (passwd:gid owner))
1481           (chmod directory perms))
1482         (define (build-subject parameters)
1483           (string-concatenate
1484            (map (lambda (pair)
1485                   (let ((k (car pair)) (v (cdr pair)))
1486                     (define (escape-char str chr)
1487                       (string-join (string-split str chr) (string #\\ chr)))
1488                     (string-append "/" k "="
1489                                    (escape-char (escape-char v #\=) #\/))))
1490                 (filter (lambda (pair) (cdr pair)) parameters))))
1491         (define* (create-self-signed-certificate-if-absent
1492                   #:key private-key public-key (owner (getpwnam "root"))
1493                   (common-name (gethostname))
1494                   (organization-name "Guix")
1495                   (organization-unit-name "Default Self-Signed Certificate")
1496                   (subject-parameters `(("CN" . ,common-name)
1497                                         ("O" . ,organization-name)
1498                                         ("OU" . ,organization-unit-name)))
1499                   (subject (build-subject subject-parameters)))
1500           ;; Note that by default, OpenSSL outputs keys in PEM format.  This
1501           ;; is what we want.
1502           (unless (file-exists? private-key)
1503             (cond
1504              ((zero? (system* (string-append #$openssl "/bin/openssl")
1505                               "genrsa" "-out" private-key "2048"))
1506               (chown private-key (passwd:uid owner) (passwd:gid owner))
1507               (chmod private-key #o400))
1508              (else
1509               (format (current-error-port)
1510                       "Failed to create private key at ~a.\n" private-key))))
1511           (unless (file-exists? public-key)
1512             (cond
1513              ((zero? (system* (string-append #$openssl "/bin/openssl")
1514                               "req" "-new" "-x509" "-key" private-key
1515                               "-out" public-key "-days" "3650"
1516                               "-batch" "-subj" subject))
1517               (chown public-key (passwd:uid owner) (passwd:gid owner))
1518               (chmod public-key #o444))
1519              (else
1520               (format (current-error-port)
1521                       "Failed to create public key at ~a.\n" public-key)))))
1522         (let ((user (getpwnam "dovecot")))
1523           (mkdir-p/perms "/var/run/dovecot" user #o755)
1524           (mkdir-p/perms "/var/lib/dovecot" user #o755)
1525           (mkdir-p/perms "/etc/dovecot" user #o755)
1526           (copy-file #$(plain-file "dovecot.conf" config-str)
1527                      "/etc/dovecot/dovecot.conf")
1528           (mkdir-p/perms "/etc/dovecot/private" user #o700)
1529           (create-self-signed-certificate-if-absent
1530            #:private-key "/etc/dovecot/private/default.pem"
1531            #:public-key "/etc/dovecot/default.pem"
1532            #:owner (getpwnam "root")
1533            #:common-name (format #f "Dovecot service on ~a" (gethostname)))))))
1534
1535 (define (dovecot-shepherd-service config)
1536   "Return a list of <shepherd-service> for CONFIG."
1537   (let ((dovecot (if (opaque-dovecot-configuration? config)
1538                      (opaque-dovecot-configuration-dovecot config)
1539                      (dovecot-configuration-dovecot config))))
1540     (list (shepherd-service
1541            (documentation "Run the Dovecot POP3/IMAP mail server.")
1542            (provision '(dovecot))
1543            (requirement '(networking))
1544            (start #~(make-forkexec-constructor
1545                      (list (string-append #$dovecot "/sbin/dovecot")
1546                            "-F")))
1547            (stop #~(make-forkexec-constructor
1548                     (list (string-append #$dovecot "/sbin/dovecot")
1549                           "stop")))))))
1550
1551 (define %dovecot-pam-services
1552   (list (unix-pam-service "dovecot")))
1553
1554 (define dovecot-service-type
1555   (service-type (name 'dovecot)
1556                 (extensions
1557                  (list (service-extension shepherd-root-service-type
1558                                           dovecot-shepherd-service)
1559                        (service-extension account-service-type
1560                                           (const %dovecot-accounts))
1561                        (service-extension pam-root-service-type
1562                                           (const %dovecot-pam-services))
1563                        (service-extension activation-service-type
1564                                           %dovecot-activation)))))
1565
1566 (define* (dovecot-service #:key (config (dovecot-configuration)))
1567   "Return a service that runs @command{dovecot}, a mail server that can run
1568 POP3, IMAP, and LMTP.  @var{config} should be a configuration object created
1569 by @code{dovecot-configuration}.  @var{config} may also be created by
1570 @code{opaque-dovecot-configuration}, which allows specification of the
1571 @code{dovecot.conf} as a string."
1572   (validate-configuration config
1573                           (if (opaque-dovecot-configuration? config)
1574                               opaque-dovecot-configuration-fields
1575                               dovecot-configuration-fields))
1576   (service dovecot-service-type config))
1577
1578 ;; A little helper to make it easier to document all those fields.
1579 (define (generate-dovecot-documentation)
1580   (generate-documentation
1581     `((dovecot-configuration
1582        ,dovecot-configuration-fields
1583        (dict dict-configuration)
1584        (namespaces namespace-configuration)
1585        (plugin plugin-configuration)
1586        (passdbs passdb-configuration)
1587        (userdbs userdb-configuration)
1588        (services service-configuration)
1589        (protocols protocol-configuration))
1590       (dict-configuration ,dict-configuration-fields)
1591       (plugin-configuration ,plugin-configuration-fields)
1592       (passdb-configuration ,passdb-configuration-fields)
1593       (userdb-configuration ,userdb-configuration-fields)
1594       (unix-listener-configuration ,unix-listener-configuration-fields)
1595       (fifo-listener-configuration ,fifo-listener-configuration-fields)
1596       (inet-listener-configuration ,inet-listener-configuration-fields)
1597       (namespace-configuration
1598        ,namespace-configuration-fields
1599        (mailboxes mailbox-configuration))
1600       (mailbox-configuration ,mailbox-configuration-fields)
1601       (service-configuration
1602        ,service-configuration-fields
1603        (listeners unix-listener-configuration fifo-listener-configuration
1604                   inet-listener-configuration))
1605       (protocol-configuration ,protocol-configuration-fields))
1606   'dovecot-configuration))
1607
1608 \f
1609 ;;;
1610 ;;; OpenSMTPD.
1611 ;;;
1612
1613 (define-record-type* <opensmtpd-configuration>
1614   opensmtpd-configuration make-opensmtpd-configuration
1615   opensmtpd-configuration?
1616   (package     opensmtpd-configuration-package
1617                (default opensmtpd))
1618   (config-file opensmtpd-configuration-config-file
1619                (default %default-opensmtpd-config-file)))
1620
1621 (define %default-opensmtpd-config-file
1622   (plain-file "smtpd.conf" "
1623 listen on lo
1624 accept from any for local deliver to mbox
1625 accept from local for any relay
1626 "))
1627
1628 (define opensmtpd-shepherd-service
1629   (match-lambda
1630     (($ <opensmtpd-configuration> package config-file)
1631      (list (shepherd-service
1632             (provision '(smtpd))
1633             (requirement '(loopback))
1634             (documentation "Run the OpenSMTPD daemon.")
1635             (start (let ((smtpd (file-append package "/sbin/smtpd")))
1636                      #~(make-forkexec-constructor
1637                         (list #$smtpd "-f" #$config-file)
1638                         #:pid-file "/var/run/smtpd.pid")))
1639             (stop #~(make-kill-destructor)))))))
1640
1641 (define %opensmtpd-accounts
1642   (list (user-group
1643          (name "smtpq")
1644          (system? #t))
1645         (user-account
1646          (name "smtpd")
1647          (group "nogroup")
1648          (system? #t)
1649          (comment "SMTP Daemon")
1650          (home-directory "/var/empty")
1651          (shell (file-append shadow "/sbin/nologin")))
1652         (user-account
1653          (name "smtpq")
1654          (group "smtpq")
1655          (system? #t)
1656          (comment "SMTPD Queue")
1657          (home-directory "/var/empty")
1658          (shell (file-append shadow "/sbin/nologin")))))
1659
1660 (define opensmtpd-activation
1661   (match-lambda
1662     (($ <opensmtpd-configuration> package config-file)
1663      (let ((smtpd (file-append package "/sbin/smtpd")))
1664        #~(begin
1665            (use-modules (guix build utils))
1666            ;; Create mbox and spool directories.
1667            (mkdir-p "/var/mail")
1668            (mkdir-p "/var/spool/smtpd")
1669            (chmod "/var/spool/smtpd" #o711))))))
1670
1671 (define %opensmtpd-pam-services
1672   (list (unix-pam-service "smtpd")))
1673
1674 (define opensmtpd-service-type
1675   (service-type
1676    (name 'opensmtpd)
1677    (extensions
1678     (list (service-extension account-service-type
1679                              (const %opensmtpd-accounts))
1680           (service-extension activation-service-type
1681                              opensmtpd-activation)
1682           (service-extension pam-root-service-type
1683                              (const %opensmtpd-pam-services))
1684           (service-extension profile-service-type
1685                              (compose list opensmtpd-configuration-package))
1686           (service-extension shepherd-root-service-type
1687                              opensmtpd-shepherd-service)))))
1688
1689 \f
1690 ;;;
1691 ;;; mail aliases.
1692 ;;;
1693
1694 (define (mail-aliases-etc aliases)
1695   `(("aliases" ,(plain-file "aliases"
1696                             ;; Ideally we'd use a format string like
1697                             ;; "~:{~a: ~{~a~^,~}\n~}", but it gives a
1698                             ;; warning that I can't figure out how to fix,
1699                             ;; so we'll just use string-join below instead.
1700                             (format #f "~:{~a: ~a\n~}"
1701                                     (map (match-lambda
1702                                            ((alias addresses ...)
1703                                             (list alias (string-join addresses ","))))
1704                                          aliases))))))
1705
1706 (define mail-aliases-service-type
1707   (service-type
1708    (name 'mail-aliases)
1709    (extensions
1710     (list (service-extension etc-service-type mail-aliases-etc)))
1711    (compose concatenate)
1712    (extend append)))
1713
1714 \f
1715 ;;;
1716 ;;; Exim.
1717 ;;;
1718
1719 (define-record-type* <exim-configuration> exim-configuration
1720   make-exim-configuration
1721   exim-configuration?
1722   (package       exim-configuration-package ;<package>
1723                  (default exim))
1724   (config-file   exim-configuration-config-file ;file-like
1725                  (default #f)))
1726
1727 (define %exim-accounts
1728   (list (user-group
1729          (name "exim")
1730          (system? #t))
1731         (user-account
1732          (name "exim")
1733          (group "exim")
1734          (system? #t)
1735          (comment "Exim Daemon")
1736          (home-directory "/var/empty")
1737          (shell (file-append shadow "/sbin/nologin")))))
1738
1739 (define (exim-computed-config-file package config-file)
1740   (computed-file "exim.conf"
1741                  #~(call-with-output-file #$output
1742                      (lambda (port)
1743                        (format port "
1744 exim_user = exim
1745 exim_group = exim
1746 .include ~a"
1747                                #$(or config-file
1748                                      (file-append package "/etc/exim.conf")))))))
1749
1750 (define exim-shepherd-service
1751   (match-lambda
1752     (($ <exim-configuration> package config-file)
1753      (list (shepherd-service
1754             (provision '(exim mta))
1755             (documentation "Run the exim daemon.")
1756             (requirement '(networking))
1757             (start #~(make-forkexec-constructor
1758                       '(#$(file-append package "/bin/exim")
1759                         "-bd" "-v" "-C"
1760                         #$(exim-computed-config-file package config-file))))
1761             (stop #~(make-kill-destructor)))))))
1762
1763 (define exim-activation
1764   (match-lambda
1765     (($ <exim-configuration> package config-file)
1766      (with-imported-modules '((guix build utils))
1767        #~(begin
1768            (use-modules (guix build utils))
1769
1770            (let ((uid (passwd:uid (getpw "exim")))
1771                  (gid (group:gid (getgr "exim"))))
1772              (mkdir-p "/var/spool/exim")
1773              (chown "/var/spool/exim" uid gid))
1774
1775            (zero? (system* #$(file-append package "/bin/exim")
1776                            "-bV" "-C" #$(exim-computed-config-file package config-file))))))))
1777
1778 (define exim-profile
1779   (compose list exim-configuration-package))
1780
1781 (define exim-service-type
1782   (service-type
1783    (name 'exim)
1784    (extensions
1785     (list (service-extension shepherd-root-service-type exim-shepherd-service)
1786           (service-extension account-service-type (const %exim-accounts))
1787           (service-extension activation-service-type exim-activation)
1788           (service-extension profile-service-type exim-profile)
1789           (service-extension mail-aliases-service-type (const '()))))))
1790
1791 \f
1792 ;;;
1793 ;;; GNU Mailutils IMAP4 Daemon.
1794 ;;;
1795
1796 (define %default-imap4d-config-file
1797   (plain-file "imap4d.conf" "server localhost {};\n"))
1798
1799 (define-record-type* <imap4d-configuration>
1800   imap4d-configuration make-imap4d-configuration imap4d-configuration?
1801   (package     imap4d-configuration-package
1802                (default mailutils))
1803   (config-file imap4d-configuration-config-file
1804                (default %default-imap4d-config-file)))
1805
1806 (define imap4d-shepherd-service
1807   (match-lambda
1808     (($ <imap4d-configuration> package config-file)
1809      (list (shepherd-service
1810             (provision '(imap4d))
1811             (requirement '(networking syslogd))
1812             (documentation "Run the imap4d daemon.")
1813             (start (let ((imap4d (file-append package "/sbin/imap4d")))
1814                      #~(make-forkexec-constructor
1815                         (list #$imap4d "--daemon" "--foreground"
1816                               "--config-file" #$config-file))))
1817             (stop #~(make-kill-destructor)))))))
1818
1819 (define imap4d-service-type
1820   (service-type
1821    (name 'imap4d)
1822    (description
1823     "Run the GNU @command{imap4d} to serve e-mail messages through IMAP.")
1824    (extensions
1825     (list (service-extension
1826            shepherd-root-service-type imap4d-shepherd-service)))
1827    (default-value (imap4d-configuration))))