gnu/packages/photo.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2014, 2015, 2017, 2019 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2015 Ricardo Wurmus <rekado@elephly.net>
   4 ;;; Copyright © 2015, 2017 Andreas Enge <andreas@enge.fr>
   5 ;;; Copyright © 2016, 2017, 2018, 2019 Efraim Flashner <efraim@flashner.co.il>
   6 ;;; Copyright © 2017 Roel Janssen <roel@gnu.org>
   7 ;;; Copyright © 2018–2021 Tobias Geerinckx-Rice <me@tobias.gr>
   8 ;;; Copyright © 2018 Leo Famulari <leo@famulari.name>
   9 ;;; Copyright © 2020 Sebastian Schott <sschott@mailbox.org>
  10 ;;; Copyright © 2020 Vincent Legoll <vincent.legoll@gmail.com>
  11 ;;; Copyright © 2020. 2021 Vinicius Monego <monego@posteo.net>
  12 ;;;
  13 ;;; This file is part of GNU Guix.
  14 ;;;
  15 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  16 ;;; under the terms of the GNU General Public License as published by
  17 ;;; the Free Software Foundation; either version 3 of the License, or (at
  18 ;;; your option) any later version.
  19 ;;;
  20 ;;; GNU Guix is distributed in the hope that it will be useful, but
  21 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  22 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 ;;; GNU General Public License for more details.
  24 ;;;
  25 ;;; You should have received a copy of the GNU General Public License
  26 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  27
  28 (define-module (gnu packages photo)
  29   #:use-module (guix build-system cmake)
  30   #:use-module (guix build-system gnu)
  31   #:use-module (guix build-system meson)
  32   #:use-module (guix build-system perl)
  33   #:use-module (guix build-system python)
  34   #:use-module (guix download)
  35   #:use-module (guix git-download)
  36   #:use-module ((guix licenses) #:prefix license:)
  37   #:use-module (guix packages)
  38   #:use-module (guix utils)
  39   #:use-module (gnu packages)
  40   #:use-module (gnu packages algebra)
  41   #:use-module (gnu packages autotools)
  42   #:use-module (gnu packages base)
  43   #:use-module (gnu packages boost)
  44   #:use-module (gnu packages check)
  45   #:use-module (gnu packages cmake)
  46   #:use-module (gnu packages compression)
  47   #:use-module (gnu packages cups)
  48   #:use-module (gnu packages curl)
  49   #:use-module (gnu packages file)
  50   #:use-module (gnu packages freedesktop)
  51   #:use-module (gnu packages geo)
  52   #:use-module (gnu packages gettext)
  53   #:use-module (gnu packages ghostscript)
  54   #:use-module (gnu packages gl)
  55   #:use-module (gnu packages gnome)
  56   #:use-module (gnu packages glib)
  57   #:use-module (gnu packages graphics)
  58   #:use-module (gnu packages gstreamer)
  59   #:use-module (gnu packages gtk)
  60   #:use-module (gnu packages image)
  61   #:use-module (gnu packages image-processing)
  62   #:use-module (gnu packages imagemagick)
  63   #:use-module (gnu packages iso-codes)
  64   #:use-module (gnu packages libcanberra)
  65   #:use-module (gnu packages libusb)
  66   #:use-module (gnu packages llvm)
  67   #:use-module (gnu packages lua)
  68   #:use-module (gnu packages man)
  69   #:use-module (gnu packages maths)
  70   #:use-module (gnu packages opencl)
  71   #:use-module (gnu packages perl)
  72   #:use-module (gnu packages pkg-config)
  73   #:use-module (gnu packages popt)
  74   #:use-module (gnu packages python)
  75   #:use-module (gnu packages python-xyz)
  76   #:use-module (gnu packages python-web)
  77   #:use-module (gnu packages qt)
  78   #:use-module (gnu packages readline)
  79   #:use-module (gnu packages ruby)
  80   #:use-module (gnu packages sqlite)
  81   #:use-module (gnu packages tex)
  82   #:use-module (gnu packages time)
  83   #:use-module (gnu packages video)
  84   #:use-module (gnu packages web)
  85   #:use-module (gnu packages wxwidgets)
  86   #:use-module (gnu packages xfig)
  87   #:use-module (gnu packages xorg)
  88   #:use-module (gnu packages xml)
  89   #:use-module ((srfi srfi-1) #:hide (zip))
  90   #:use-module (srfi srfi-26))
  91
  92 (define-public rapid-photo-downloader
  93   (package
  94     (name "rapid-photo-downloader")
  95     (version "0.9.18")
  96     (source (origin
  97               (method url-fetch)
  98               (uri (string-append "https://launchpad.net/rapid/pyqt/"
  99                                   version "/+download/" name "-"
 100                                   version ".tar.gz"))
 101               (sha256
 102                (base32
 103                 "15p7sssg6vmqbm5xnc4j5dr89d7gl7y5qyq44a240yl5aqkjnybw"))))
 104     (build-system python-build-system)
 105     (native-inputs
 106      `(("file" ,file)
 107        ("intltool" ,intltool)
 108        ("gobject-introspection" ,gobject-introspection)))
 109     (inputs
 110      `(("gdk-pixbuf" ,gdk-pixbuf)
 111        ("gexiv2" ,gexiv2)
 112        ("gst-libav" ,gst-libav)
 113        ("gst-plugins-base" ,gst-plugins-base)
 114        ("gst-plugins-good" ,gst-plugins-good)
 115        ("gstreamer" ,gstreamer)
 116        ("libgudev" ,libgudev)
 117        ("libnotify" ,libnotify)
 118        ("libmediainfo" ,libmediainfo)
 119        ("usdisks" ,udisks)
 120        ("python-pyqt" ,python-pyqt)
 121        ("python-pygobject" ,python-pygobject)
 122        ("python-gphoto2" ,python-gphoto2)
 123        ("python-pyzmq" ,python-pyzmq)
 124        ("python-tornado" ,python-tornado)
 125        ("python-psutil" ,python-psutil)
 126        ("python-pyxdg" ,python-pyxdg)
 127        ("python-arrow" ,python-arrow)
 128        ("python-dateutil" ,python-dateutil)
 129        ("python-easygui" ,python-easygui)
 130        ("python-colour" ,python-colour)
 131        ("python-pymediainfo" ,python-pymediainfo)
 132        ("python-sortedcontainers" ,python-sortedcontainers)
 133        ("python-rawkit" ,python-rawkit)
 134        ("python-requests" ,python-requests)
 135        ("python-colorlog" ,python-colorlog)
 136        ("python-pyprind" ,python-pyprind)
 137        ("python-tenacity" ,python-tenacity)
 138        ("perl-image-exiftool" ,perl-image-exiftool)))
 139     (arguments
 140      `(#:phases
 141        (modify-phases %standard-phases
 142          (add-after 'unpack 'patch-libmediainfo
 143            (lambda _
 144              (substitute* "raphodo/metadatavideo.py"
 145                (("pymedia_library_file = 'libmediainfo.so.0'")
 146                 (string-append "pymedia_library_file = '"
 147                                (assoc-ref %build-inputs "libmediainfo")
 148                                "/lib/libmediainfo.so.0'")))
 149              #t))
 150          (add-after 'install 'wrap
 151            (lambda* (#:key inputs outputs #:allow-other-keys)
 152              (let ((out               (assoc-ref outputs "out"))
 153                    (path              (string-join
 154                                        (list (string-append
 155                                               (assoc-ref inputs "perl-image-exiftool")
 156                                               "/bin"))
 157                                        ":"))
 158                    (gi-typelib-path   (getenv "GI_TYPELIB_PATH"))
 159                    (python-path       (getenv "PYTHONPATH")))
 160                (for-each
 161                 (lambda (program)
 162                   (wrap-program program
 163                     `("PATH" ":" prefix (,path))
 164                     `("GI_TYPELIB_PATH" ":" prefix (,gi-typelib-path))
 165                     `("PYTHONPATH"             ":" prefix (,python-path))))
 166                 (map (lambda (name)
 167                        (string-append out "/bin/" name))
 168                      '("analyze-pv-structure"
 169                        "rapid-photo-downloader"))))
 170              #t)))))
 171     (home-page "https://www.damonlynch.net/rapid/")
 172     (synopsis "Import photos and videos from cameras, phones and memory cards")
 173     (description "Import photos and videos from cameras, phones and memory
 174 cards and generate meaningful file and folder names.")
 175     (license license:gpl2+)))
 176
 177 (define-public libraw
 178   (package
 179     (name "libraw")
 180     (version "0.20.0")
 181     (source (origin
 182               (method url-fetch)
 183               (uri (string-append "https://www.libraw.org/data/LibRaw-"
 184                                   version ".tar.gz"))
 185               (sha256
 186                (base32
 187                 "18wlsvj6c1rv036ph3695kknpgzc3lk2ikgshy8417yfl8ykh2hz"))))
 188     (build-system gnu-build-system)
 189     (native-inputs
 190      `(("pkg-config" ,pkg-config)))
 191     (inputs
 192      `(("libjpeg" ,libjpeg-turbo)))     ;for lossy DNGs and old Kodak cameras
 193     (propagated-inputs
 194      `(("lcms" ,lcms)))                 ;for color profiles
 195     (home-page "https://www.libraw.org")
 196     (synopsis "Raw image decoder")
 197     (description
 198      "LibRaw is a library for reading RAW files obtained from digital photo
 199 cameras (CRW/CR2, NEF, RAF, DNG, and others).")
 200     ;; LibRaw is distributed under both LGPL2.1 and CDDL 1.0.  From the README:
 201     ;; "You may use one of these licensing modes and switch between them.  If
 202     ;; you modify LibRaw source and made your changes public, you should accept
 203     ;; both two licensing modes for your changes/additions."
 204     (license (list license:lgpl2.1 license:cddl1.0))))
 205
 206 (define-public libraw-0.18
 207   (package (inherit libraw)
 208     (name "libraw")
 209     (version "0.18.12")
 210     (source (origin
 211               (method url-fetch)
 212               (uri (string-append "https://www.libraw.org/data/LibRaw-"
 213                                   version ".tar.gz"))
 214               (sha256
 215                (base32
 216                 "1m2khr2cij8z6lawgbmdksjn14fpnjsy8ad4qahnpqapm1slsxap"))))))
 217
 218 (define-public libexif
 219   (package
 220     (name "libexif")
 221     (version "0.6.22")
 222     (source (origin
 223               (method url-fetch)
 224               (uri (string-append
 225                     "https://github.com/libexif/libexif/releases"
 226                     "/download/libexif-"
 227                     (string-map (lambda (x) (if (char=? x #\.) #\_ x)) version)
 228                     "-release/libexif-" version ".tar.xz"))
 229               (sha256
 230                (base32
 231                 "0mhcad5zab7fsn120rd585h8ncwkq904nzzrq8vcd72hzk4g2j2h"))))
 232     (build-system gnu-build-system)
 233     (home-page "https://libexif.github.io/")
 234     (synopsis "Read and manipulate EXIF data in digital photographs")
 235     (description
 236      "The libexif C library allows applications to read, edit, and save EXIF
 237 data as produced by digital cameras.")
 238     (license license:lgpl2.1+)))
 239
 240 (define-public libgphoto2
 241   (package
 242     (name "libgphoto2")
 243     (version "2.5.27")
 244     (source (origin
 245               (method url-fetch)
 246               (uri (string-append "mirror://sourceforge/gphoto/libgphoto/"
 247                                   version "/libgphoto2-" version ".tar.bz2"))
 248               (sha256
 249                (base32
 250                 "1ms06b3dj1p33aypcb16gg5pn7fylbylsk9cnnqa0j29qiw59f7q"))))
 251     (build-system gnu-build-system)
 252     (native-inputs `(("pkg-config" ,pkg-config)))
 253     (inputs
 254      `(("libjpeg-turbo" ,libjpeg-turbo)
 255        ("libltdl" ,libltdl)
 256        ("libusb" ,libusb)
 257        ("libxml2" ,libxml2)))
 258     (propagated-inputs
 259      `(;; The .pc refers to libexif.
 260        ("libexif" ,libexif)))
 261     (home-page "http://www.gphoto.org/proj/libgphoto2/")
 262     (synopsis "Accessing digital cameras")
 263     (description
 264      "This is the library backend for gphoto2.  It contains the code for PTP,
 265 MTP, and other vendor specific protocols for controlling and transferring data
 266 from digital cameras.")
 267
 268     ;; 'COPYING' says LGPLv2.1+, but in practices files are under LGPLv2+.
 269     (license license:lgpl2.1+)))
 270
 271 (define-public gphoto2
 272   (package
 273     (name "gphoto2")
 274     (version "2.5.27")
 275     (source (origin
 276               (method url-fetch)
 277               (uri (string-append "mirror://sourceforge/gphoto/gphoto/" version
 278                                   "/gphoto2-" version ".tar.bz2"))
 279               (sha256
 280                (base32
 281                 "0f4d3q381jnnkcqkb2dj1k709skp65qihl5xm80zandvl69lw19h"))))
 282     (build-system gnu-build-system)
 283     (native-inputs
 284      `(("pkg-config" ,pkg-config)))
 285     (inputs
 286      `(("readline" ,readline)
 287        ("libjpeg-turbo" ,libjpeg-turbo)
 288        ("popt" ,popt)
 289        ("libexif" ,libexif)
 290        ("libgphoto2" ,libgphoto2)))
 291     (arguments
 292      '(#:phases
 293        (modify-phases %standard-phases
 294          (add-before 'check 'pre-check
 295            (lambda* (#:key inputs #:allow-other-keys)
 296              (substitute* (find-files "tests/data" "\\.param$")
 297                (("/usr/bin/env")
 298                 (which "env")))
 299              #t)))
 300
 301        ;; FIXME: There is 1 test failure, most likely related to the build
 302        ;; environment.
 303        #:tests? #f))
 304
 305     (home-page "http://www.gphoto.org/")
 306     (synopsis "Command-line tools to access digital cameras")
 307     (description
 308      "Gphoto2 is a set of command line utilities for manipulating a large
 309 number of different digital cameras.  Through libgphoto2, it supports PTP,
 310 MTP, and much more.")
 311
 312     ;; Files are typically under LGPLv2+, but 'COPYING' says GPLv2+.
 313     (license license:gpl2+)))
 314
 315 ;; Note: See <https://metacpan.org/pod/Image::ExifTool> for the latest
 316 ;; release.  The versions at <https://www.sno.phy.queensu.ca/~phil/exiftool/>
 317 ;; are not meant for production use according to the Changes file.
 318 (define-public perl-image-exiftool
 319   (package
 320     (name "perl-image-exiftool")
 321     (version "12.00")
 322     (source
 323      (origin
 324        (method url-fetch)
 325        (uri (list
 326              (string-append "mirror://cpan/authors/id/E/EX/EXIFTOOL/"
 327                             "Image-ExifTool-" version ".tar.gz")
 328              ;; New releases may take a while to hit CPAN.
 329              (string-append "https://www.sno.phy.queensu.ca/~phil/exiftool/"
 330                             "Image-ExifTool-" version ".tar.gz")))
 331        (sha256
 332         (base32
 333          "0nl5djf6hs6brnp7qnqvj3xwhj1qnjwcv35ih4yqp2mm9b4jqyfh"))))
 334     (build-system perl-build-system)
 335     (arguments
 336      '(#:phases
 337        (modify-phases %standard-phases
 338          (add-after 'install 'post-install
 339            (lambda* (#:key outputs #:allow-other-keys)
 340              ;; Make sure the 'exiftool' commands finds the library.
 341              ;; XXX: Shouldn't it be handled by PERL-BUILD-SYSTEM?
 342              (let* ((out (assoc-ref outputs "out"))
 343                     (pm  (find-files out "^ExifTool\\.pm$"))
 344                     (lib (dirname (dirname (car pm)))))
 345                (wrap-program (string-append out "/bin/exiftool")
 346                  `("PERL5LIB" prefix (,lib)))
 347                #t))))))
 348     (home-page "https://metacpan.org/release/Image-ExifTool")
 349     (synopsis "Program and Perl library to manipulate EXIF and other metadata")
 350     (description "This package provides the @code{exiftool} command and the
 351 @code{Image::ExifTool} Perl library to manipulate EXIF tags of digital images
 352 and a wide variety of other metadata.")
 353     (license license:perl-license)))
 354
 355 (define-public libpano13
 356   (package
 357     (name "libpano13")
 358     (version "2.9.19")
 359     (source (origin
 360               (method url-fetch)
 361               (uri (string-append "mirror://sourceforge/panotools/libpano13/"
 362                                   "libpano13-" version "/"
 363                                   "libpano13-" version ".tar.gz"))
 364               (sha256
 365                (base32
 366                 "1a4m3plmfcrrplqs9zfzhc5apibn10m5sajpizm1sd3q74w5fwq3"))))
 367     (build-system cmake-build-system)
 368     (inputs
 369      `(("libjpeg" ,libjpeg-turbo)
 370        ("libpng" ,libpng)
 371        ("libtiff" ,libtiff)
 372        ("zlib" ,zlib)))
 373     (home-page "http://panotools.sourceforge.net/")
 374     (synopsis "Library for panoramic images")
 375     (description
 376      "The libpano13 package contains the backend library written by the
 377 Panorama Tools project for building panoramic images from a set of
 378 overlapping images, as well as some command line tools.")
 379     (license license:gpl2+)))
 380
 381 (define-public enblend-enfuse
 382   (package
 383     (name "enblend-enfuse")
 384     (version "4.2")
 385     (source (origin
 386               (method url-fetch)
 387               (uri (string-append "mirror://sourceforge/enblend/"
 388                                   name "/"
 389                                   name "-" (version-major+minor version) "/"
 390                                   name "-" version ".tar.gz"))
 391               (sha256
 392                (base32
 393                 "0j5x011ilalb47ssah50ag0a4phgh1b0wdgxdbbp1gcyjcjf60w7"))))
 394     (build-system gnu-build-system)
 395     (native-inputs
 396      `(("pkg-config" ,pkg-config)
 397        ("perl" ,perl)
 398        ("perl-timedate" ,perl-timedate)
 399        ;; for building the documentation
 400        ("gnuplot" ,gnuplot)
 401        ("help2man" ,help2man)
 402        ("imagemagick" ,imagemagick)
 403        ("libxml2" ,libxml2)
 404        ("texlive-minimal" ,texlive-tiny)
 405        ("tidy" ,tidy)
 406        ("transfig" ,transfig)))
 407     (inputs
 408      `(("boost" ,boost)
 409        ("gsl" ,gsl)
 410        ("lcms" ,lcms)
 411        ("libjpeg" ,libjpeg-turbo)
 412        ("libpng" ,libpng)
 413        ("libtiff" ,libtiff)
 414        ("openexr" ,openexr)
 415        ("vigra" ,vigra)
 416        ("zlib" ,zlib)))
 417     (arguments
 418      `(#:configure-flags `("--enable-openmp")))
 419     (home-page "http://enblend.sourceforge.net/")
 420     (synopsis "Tools for combining and blending images")
 421     (description
 422      "Enblend blends away the seams in a panoramic image mosaic using a
 423 multi-resolution spline.  Enfuse merges different exposures of the same
 424 scene to produce an image that looks much like a tone-mapped image.")
 425     (license license:gpl2+)))
 426
 427 (define-public lensfun
 428   (package
 429     (name "lensfun")
 430     (version "0.3.2")
 431     (source (origin
 432               (method url-fetch)
 433               (uri (string-append
 434                     "mirror://sourceforge/lensfun/"
 435                     version "/lensfun-" version ".tar.gz"))
 436               (sha256
 437                (base32
 438                 "0cfk8jjhs9nbfjfdy98plrj9ayi59aph0nx6ppslgjhlcvacm2xf"))))
 439     (build-system cmake-build-system)
 440     (arguments
 441      `(,@(if (any (cute string-prefix? <> (or (%current-system)
 442                                               (%current-target-system)))
 443                   '("x86_64" "i686"))
 444         ;; SSE and SSE2 are supported only on Intel processors.
 445         '()
 446         '(#:configure-flags '("-DBUILD_FOR_SSE=OFF" "-DBUILD_FOR_SSE2=OFF")))
 447        #:tests? #f)) ; There are no tests to run.
 448     (native-inputs
 449      `(("pkg-config" ,pkg-config)))
 450     (inputs
 451      `(("glib" ,glib)))
 452     (home-page "https://sourceforge.net/projects/lensfun/")
 453     (synopsis "Library to correct optical lens defects with a lens database")
 454     (description "Digital photographs are not ideal.  Of course, the better is
 455 your camera, the better the results will be, but in any case if you look
 456 carefully at shots taken even by the most expensive cameras equipped with the
 457 most expensive lenses you will see various artifacts.  It is very hard to make
 458 ideal cameras, because there are a lot of factors that affect the final image
 459 quality, and at some point camera and lens designers have to trade one factor
 460 for another to achieve the optimal image quality, within the given design
 461 restrictions and budget.  But we all want ideal shots, don't we?  So that's
 462 what's Lensfun is all about: rectifying the defects introduced by your
 463 photographic equipment.")
 464     ;; The libraries are licensed under the LGPL3, the programs are
 465     ;; licensed GPL3, and the database is license CC-BY-SA 3.0.  See the
 466     ;; README.md file for this clarification.
 467     (license (list license:lgpl3 license:gpl3 license:cc-by-sa3.0))))
 468
 469 (define-public darktable
 470   (package
 471     (name "darktable")
 472     (version "3.4.1")
 473     (source
 474      (origin
 475        (method url-fetch)
 476        (uri (string-append
 477              "https://github.com/darktable-org/darktable/releases/"
 478              "download/release-" version "/darktable-" version ".tar.xz"))
 479        (sha256
 480         (base32 "07llfhhz5dhh43smhv4ax4xi1diym8hrzl7cad87rkcvv98zihvz"))))
 481     (build-system cmake-build-system)
 482     (arguments
 483      `(#:configure-flags '("-DBINARY_PACKAGE_BUILD=On"
 484                            "-DBUILD_TESTING=On")
 485        #:phases
 486        (modify-phases %standard-phases
 487          (add-before 'configure 'prepare-build-environment
 488            (lambda* (#:key inputs #:allow-other-keys)
 489              ;; Rawspeed fails to build with GCC due to OpenMP error:
 490              ;; "undefined reference to `GOMP_loop_nonmonotonic_dynamic_next'"
 491              (setenv "CC" "clang") (setenv "CXX" "clang++")
 492              ;; Darktable looks for opencl-c.h in the LLVM dir. Guix installs
 493              ;; it to the Clang dir. We fix this by patching CMakeLists.txt.
 494              (substitute* "CMakeLists.txt"
 495                (("\\$\\{LLVM_INSTALL_PREFIX\\}")
 496                 (assoc-ref %build-inputs "clang")))
 497              #t))
 498          (add-before 'configure 'set-LDFLAGS-and-CPATH
 499            (lambda* (#:key inputs outputs #:allow-other-keys)
 500              (setenv "LDFLAGS"
 501                      (string-append
 502                       "-Wl,-rpath="
 503                       (assoc-ref outputs "out") "/lib/darktable"))
 504
 505              ;; Ensure the OpenEXR headers are found.
 506              (setenv "CPATH"
 507                      (string-append (assoc-ref inputs "ilmbase")
 508                                     "/include/OpenEXR:" (or (getenv "CPATH") "")))
 509              #t))
 510          (add-after 'install 'wrap-program
 511            (lambda* (#:key inputs outputs #:allow-other-keys)
 512              (wrap-program (string-append (assoc-ref outputs "out")
 513                                           "/bin/darktable")
 514                ;; For GtkFileChooserDialog.
 515                `("GSETTINGS_SCHEMA_DIR" =
 516                  (,(string-append (assoc-ref inputs "gtk+")
 517                                   "/share/glib-2.0/schemas")))
 518                ;; For libOpenCL.so.
 519                `("LD_LIBRARY_PATH" =
 520                  (,(string-append (assoc-ref inputs "ocl-icd")
 521                                   "/lib"))))
 522              #t)))))
 523     (native-inputs
 524      `(("clang" ,clang-11)
 525        ("cmocka" ,cmocka)
 526        ("desktop-file-utils" ,desktop-file-utils)
 527        ("glib:bin" ,glib "bin")
 528        ("gobject-introspection" ,gobject-introspection)
 529        ("intltool" ,intltool)
 530        ("llvm" ,llvm-11) ;should match the Clang version
 531        ("opencl-headers" ,opencl-headers)
 532        ("perl" ,perl)
 533        ("pkg-config" ,pkg-config)
 534        ("po4a" ,po4a)
 535        ("python" ,python-wrapper)
 536        ("ruby" ,ruby)))
 537     (inputs
 538      `(("cairo" ,cairo)
 539        ("colord-gtk" ,colord-gtk) ;optional, for color profile support
 540        ("cups" ,cups) ;optional, for printing support
 541        ("curl" ,curl)
 542        ("dbus-glib" ,dbus-glib)
 543        ("exiv2" ,exiv2)
 544        ("freeimage" ,freeimage)
 545        ("gmic" ,gmic) ;optional, for HaldcLUT support
 546        ("graphicsmagick" ,graphicsmagick)
 547        ("gsettings-desktop-schemas" ,gsettings-desktop-schemas)
 548        ("gtk+" ,gtk+)
 549        ("ilmbase" ,ilmbase)
 550        ("iso-codes" ,iso-codes) ;optional, for language names in the preferences
 551        ("json-glib" ,json-glib)
 552        ("lcms" ,lcms)
 553        ("lensfun" ,lensfun) ;optional, for the lens distortion plugin
 554        ("libgphoto2" ,libgphoto2) ;optional, for camera tethering
 555        ("libavif" ,libavif) ;optional, for AVIF support
 556        ("libjpeg" ,libjpeg-turbo)
 557        ("libomp" ,libomp)
 558        ("libpng" ,libpng)
 559        ("librsvg" ,librsvg)
 560        ("libsecret" ,libsecret) ;optional, for storing passwords
 561        ("libsoup" ,libsoup)
 562        ("libtiff" ,libtiff)
 563        ("libwebp" ,libwebp) ;optional, for WebP support
 564        ("libxml2" ,libxml2)
 565        ("libxslt" ,libxslt)
 566        ("lua" ,lua) ;optional, for plugins
 567        ("ocl-icd" ,ocl-icd) ;optional, for OpenCL support
 568        ("openexr" ,openexr) ;optional, for EXR import/export
 569        ("openjpeg" ,openjpeg) ;optional, for JPEG2000 export
 570        ("osm-gps-map" ,osm-gps-map) ;optional, for geotagging view
 571        ("pugixml" ,pugixml)
 572        ("python-jsonschema" ,python-jsonschema)
 573        ("sqlite" ,sqlite)))
 574     (home-page "https://www.darktable.org")
 575     (synopsis "Virtual lighttable and darkroom for photographers")
 576     (description "Darktable is a photography workflow application and RAW
 577 developer.  It manages your digital negatives in a database, lets you view
 578 them through a zoomable lighttable and enables you to develop raw images
 579 and enhance them.")
 580     ;; See src/is_supported_platform.h for supported platforms.
 581     (supported-systems '("x86_64-linux" "aarch64-linux"))
 582     (license (list license:gpl3+ ;; Darktable itself.
 583                    license:lgpl2.1+)))) ;; Rawspeed library.
 584
 585 (define-public photoflare
 586   (package
 587     (name "photoflare")
 588     (version "1.6.7")
 589     (source
 590      (origin
 591        (method git-fetch)
 592        (uri (git-reference
 593              (url "https://github.com/photoflare/photoflare")
 594              (commit (string-append "v" version))))
 595        (file-name (git-file-name name version))
 596        (sha256
 597         (base32 "0rh5gvnc1zwx4p9h599s82m69gsxp19nnfcxsblx3b2ddwzxh78v"))))
 598     (build-system gnu-build-system)
 599     (arguments
 600      '(#:tests? #f                      ;no tests
 601        #:phases
 602        (modify-phases %standard-phases
 603          (replace 'configure
 604            (lambda* (#:key inputs outputs #:allow-other-keys)
 605              (let ((magickpp (assoc-ref inputs "graphicsmagick"))
 606                    (out (assoc-ref outputs "out")))
 607                (invoke "qmake"
 608                        (string-append "INCLUDEPATH += " magickpp
 609                                       "/include/GraphicsMagick")
 610                        (string-append "PREFIX=" out)
 611                        "Photoflare.pro")))))))
 612     (native-inputs
 613      `(("pkg-config" ,pkg-config)
 614        ("qttools" ,qttools)))
 615     (inputs
 616      `(("graphicsmagick" ,graphicsmagick)
 617        ("libomp" ,libomp)
 618        ("qtbase" ,qtbase)))
 619     (home-page "https://photoflare.io")
 620     (synopsis "Quick, simple but powerful image editor")
 621     (description "Photoflare is a cross-platform image editor with an aim
 622 to balance between powerful features and a very friendly graphical user
 623 interface.  It suits a wide variety of different tasks and users who value a
 624 more nimble workflow.  Features include basic image editing capabilities,
 625 paint brushes, image filters, colour adjustments and more advanced features
 626 such as Batch image processing.")
 627     (license license:gpl3+)))
 628
 629 (define-public entangle
 630   (package
 631     (name "entangle")
 632     (version "3.0")
 633     (source
 634      (origin
 635        (method git-fetch)
 636        (uri (git-reference
 637              (url "https://gitlab.com/entangle/entangle")
 638              (commit (string-append "v" version))))
 639        (file-name (git-file-name name version))
 640        (sha256
 641         (base32 "1pdmgxjdb3xlcqsaz7l8qzj5f7g7nwzhsrgid8929bm36d49cgc7"))))
 642     (build-system meson-build-system)
 643     (arguments
 644      `(#:glib-or-gtk? #t
 645        #:phases
 646        (modify-phases %standard-phases
 647          (add-after 'unpack 'skip-gtk-update-icon-cache
 648            ;; Don't create 'icon-theme.cache'.
 649            (lambda _
 650              (substitute* "meson_post_install.py"
 651                (("gtk-update-icon-cache") "true"))
 652              #t))
 653          (add-after 'install 'wrap-gi-python
 654            ;; Make GTK find files needed by plugins.
 655            (lambda* (#:key inputs outputs #:allow-other-keys)
 656              (let ((out               (assoc-ref outputs "out"))
 657                    (gi-typelib-path   (getenv "GI_TYPELIB_PATH"))
 658                    (python-path       (getenv "PYTHONPATH")))
 659                (wrap-program (string-append out "/bin/entangle")
 660                  `("GI_TYPELIB_PATH" ":" prefix (,gi-typelib-path))
 661                  `("PYTHONPATH" ":" prefix (,python-path))))
 662              #t)))))
 663     (native-inputs
 664      `(("cmake" ,cmake)
 665        ("gettext" ,gettext-minimal)
 666        ("glib:bin" ,glib "bin")
 667        ("gobject-introspection" ,gobject-introspection)
 668        ("gtk-doc" ,gtk-doc)
 669        ("perl" ,perl)
 670        ("pkg-config" ,pkg-config)
 671        ("xmllint" ,libxml2)))
 672     (inputs
 673      `(("gdk-pixbuf" ,gdk-pixbuf)
 674        ("gexiv2" ,gexiv2)
 675        ("gst-plugins-base" ,gst-plugins-base)
 676        ("gstreamer" ,gstreamer)
 677        ("gtk+" ,gtk+)
 678        ("lcms" ,lcms)
 679        ("libgphoto2" ,libgphoto2)
 680        ("libgudev" ,libgudev)
 681        ("libpeas" ,libpeas)
 682        ("libraw" ,libraw)
 683        ("python" ,python)
 684        ("python-pygobject" ,python-pygobject)))
 685     (home-page "https://entangle-photo.org/")
 686     (synopsis "Camera control and capture")
 687     (description
 688      "Entangle is an application which uses GTK and libgphoto2 to provide a
 689 graphical interface for tethered photography with digital cameras.  It
 690 includes control over camera shooting and configuration settings and 'hands
 691 off' shooting directly from the controlling computer.")
 692     (license license:gpl3+)))
 693
 694 (define-public hugin
 695   (package
 696     (name "hugin")
 697     (version "2020.0.0")
 698     (source (origin
 699               (method url-fetch)
 700               (uri (string-append "mirror://sourceforge/hugin/hugin/hugin-"
 701                                   (version-major+minor version)
 702                                   "/hugin-" version ".tar.bz2"))
 703               (sha256
 704                (base32
 705                 "1jyazc0mbr9g7vrichpqqnfl72lj21244csk0z5i8ycs4l0pcgi8"))))
 706     (build-system cmake-build-system)
 707     (native-inputs
 708      `(("gettext" ,gettext-minimal)
 709        ("pkg-config" ,pkg-config)))
 710     (inputs
 711      `(("boost" ,boost)
 712        ("enblend-enfuse" ,enblend-enfuse)
 713        ("exiv2" ,exiv2)
 714        ("fftw" ,fftw)
 715        ("flann" ,flann)
 716        ("freeglut" ,freeglut)
 717        ("glew" ,glew)
 718        ("lcms" ,lcms)
 719        ("libjpeg" ,libjpeg-turbo)
 720        ("libpano13" ,libpano13)
 721        ("libpng" ,libpng)
 722        ("libtiff" ,libtiff)
 723        ("libxi" ,libxi)
 724        ("libxmu" ,libxmu)
 725        ("mesa" ,mesa)
 726        ("openexr" ,openexr)
 727        ("sqlite" ,sqlite)
 728        ("vigra" ,vigra)
 729        ("wxwidgets" ,wxwidgets)
 730        ("zlib" ,zlib)))
 731     (arguments
 732      `(#:tests? #f                      ; no check target
 733        #:configure-flags
 734        (list
 735         ;; The header files of ilmbase (propagated by openexr) are not found
 736         ;; when included by the header files of openexr, and an explicit
 737         ;; flag needs to be set.
 738         (string-append "-DCMAKE_CXX_FLAGS=-I"
 739                        (assoc-ref %build-inputs "ilmbase")
 740                        "/include/OpenEXR")
 741         ;; Disable installation of the Python scripting interface.
 742         ;; It would require the additional inputs python and swig.
 743         ;; Installation would need to be tweaked, as it tries to install
 744         ;; into the python directory.
 745         "-DBUILD_HSI=OFF")
 746        #:phases
 747        (modify-phases %standard-phases
 748          (add-before 'configure 'substitute
 749            (lambda _
 750              (substitute* "src/hugin1/base_wx/StitchingExecutor.cpp"
 751                (("wxT\\(\"enblend\"\\)")
 752                 (string-append "wxT(\"" (which "enblend") "\")"))
 753                (("wxT\\(\"enfuse\"\\)")
 754                 (string-append "wxT(\"" (which "enfuse") "\")")))
 755              #t)))))
 756     (home-page "http://hugin.sourceforge.net/")
 757     (synopsis "Panorama photo stitcher")
 758     (description
 759      "Hugin is an easy to use panoramic imaging toolchain with a graphical
 760 user interface.  It can be used to assemble a mosaic of photographs into
 761 a complete panorama and stitch any series of overlapping pictures.")
 762     (license license:gpl2+)))
 763
 764 (define-public rawtherapee
 765   (package
 766     (name "rawtherapee")
 767     (version "5.8")
 768     (source (origin
 769               (method url-fetch)
 770               (uri (string-append "http://rawtherapee.com/shared/source/"
 771                                   "rawtherapee-" version ".tar.xz"))
 772               (sha256
 773                (base32
 774                 "0lq8qi7g0a28h3rab7bk5bbbd4gvfma42bvlz1dfn8p9mah2h19n"))))
 775     (build-system cmake-build-system)
 776     (arguments
 777      '(#:tests? #f                      ; no test suite
 778        #:build-type "release"
 779        #:configure-flags
 780        (list (string-append "-DLENSFUNDBDIR="
 781                             (assoc-ref %build-inputs "lensfun")
 782                             "/share/lensfun")
 783              ;; Don't optimize the build for the host machine. See the file
 784              ;; 'ProcessorTargets.cmake' in the source distribution for more
 785              ;; information.
 786              "-DPROC_TARGET_NUMBER=1"
 787              ;; These flags are recommended by upstream for distributed packages.
 788              ;; See the file 'RELEASE_NOTES.txt' in the source distribution.
 789              "-O3"
 790              "-DCACHE_NAME_SUFFIX=\"\"")))
 791     (native-inputs
 792      `(("pkg-config" ,pkg-config)))
 793     (inputs
 794      `(("expat" ,expat)
 795        ("fftw" ,fftwf)
 796        ("glib" ,glib)
 797        ("glibmm" ,glibmm)
 798        ("gtk+" ,gtk+)
 799        ("gtkmm" ,gtkmm)
 800        ("lcms" ,lcms)
 801        ("lensfun" ,lensfun)
 802        ("libcanberra" ,libcanberra)
 803        ("libiptcdata" ,libiptcdata)
 804        ("libjpeg" ,libjpeg-turbo)
 805        ("libpng" ,libpng)
 806        ("librsvg" ,librsvg)
 807        ("libsigc++" ,libsigc++)
 808        ("libtiff" ,libtiff)
 809        ("zlib" ,zlib)))
 810     (home-page "http://rawtherapee.com")
 811     (synopsis "Raw image developing and processing")
 812     (description "RawTherapee is a raw image processing suite.  It comprises a
 813 subset of image editing operations specifically aimed at non-destructive raw
 814 photo post-production and is primarily focused on improving a photographer's
 815 workflow by facilitating the handling of large numbers of images.  Most raw
 816 formats are supported, including Pentax Pixel Shift, Canon Dual-Pixel, and those
 817 from Foveon and X-Trans sensors.")
 818     (license license:gpl3+)))