gnu/services/ssh.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2014, 2015, 2016 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2016 David Craven <david@craven.ch>
   4 ;;; Copyright © 2016 Julien Lepiller <julien@lepiller.eu>
   5 ;;; Copyright © 2017 Clément Lassieur <clement@lassieur.org>
   6 ;;;
   7 ;;; This file is part of GNU Guix.
   8 ;;;
   9 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  10 ;;; under the terms of the GNU General Public License as published by
  11 ;;; the Free Software Foundation; either version 3 of the License, or (at
  12 ;;; your option) any later version.
  13 ;;;
  14 ;;; GNU Guix is distributed in the hope that it will be useful, but
  15 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;;; GNU General Public License for more details.
  18 ;;;
  19 ;;; You should have received a copy of the GNU General Public License
  20 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 (define-module (gnu services ssh)
  23   #:use-module (gnu packages ssh)
  24   #:use-module (gnu packages admin)
  25   #:use-module (gnu services)
  26   #:use-module (gnu services shepherd)
  27   #:use-module (gnu system pam)
  28   #:use-module (gnu system shadow)
  29   #:use-module (guix gexp)
  30   #:use-module (guix records)
  31   #:use-module (srfi srfi-26)
  32   #:use-module (ice-9 match)
  33   #:export (lsh-configuration
  34             lsh-configuration?
  35             lsh-service
  36             lsh-service-type
  37
  38             openssh-configuration
  39             openssh-configuration?
  40             openssh-service-type
  41
  42             dropbear-configuration
  43             dropbear-configuration?
  44             dropbear-service-type
  45             dropbear-service))
  46
  47 ;;; Commentary:
  48 ;;;
  49 ;;; This module implements secure shell (SSH) services.
  50 ;;;
  51 ;;; Code:
  52
  53 (define-record-type* <lsh-configuration>
  54   lsh-configuration make-lsh-configuration
  55   lsh-configuration?
  56   (lsh lsh-configuration-lsh
  57        (default lsh))
  58   (daemonic? lsh-configuration-daemonic?)
  59   (host-key lsh-configuration-host-key)
  60   (interfaces lsh-configuration-interfaces)
  61   (port-number lsh-configuration-port-number)
  62   (allow-empty-passwords? lsh-configuration-allow-empty-passwords?)
  63   (root-login? lsh-configuration-root-login?)
  64   (syslog-output? lsh-configuration-syslog-output?)
  65   (pid-file? lsh-configuration-pid-file?)
  66   (pid-file lsh-configuration-pid-file)
  67   (x11-forwarding? lsh-configuration-x11-forwarding?)
  68   (tcp/ip-forwarding? lsh-configuration-tcp/ip-forwarding?)
  69   (password-authentication? lsh-configuration-password-authentication?)
  70   (public-key-authentication? lsh-configuration-public-key-authentication?)
  71   (initialize? lsh-configuration-initialize?))
  72
  73 (define %yarrow-seed
  74   "/var/spool/lsh/yarrow-seed-file")
  75
  76 (define (lsh-initialization lsh host-key)
  77   "Return the gexp to initialize the LSH service for HOST-KEY."
  78   #~(begin
  79       (unless (file-exists? #$%yarrow-seed)
  80         (system* (string-append #$lsh "/bin/lsh-make-seed")
  81                  "--sloppy" "-o" #$%yarrow-seed))
  82
  83       (unless (file-exists? #$host-key)
  84         (mkdir-p (dirname #$host-key))
  85         (format #t "creating SSH host key '~a'...~%" #$host-key)
  86
  87         ;; FIXME: We're just doing a simple pipeline, but 'system' cannot be
  88         ;; used yet because /bin/sh might be dangling; factorize this somehow.
  89         (let* ((in+out (pipe))
  90                (keygen (primitive-fork)))
  91           (case keygen
  92             ((0)
  93              (close-port (car in+out))
  94              (close-fdes 1)
  95              (dup2 (fileno (cdr in+out)) 1)
  96              (execl (string-append #$lsh "/bin/lsh-keygen")
  97                     "lsh-keygen" "--server"))
  98             (else
  99              (let ((write-key (primitive-fork)))
 100                (case write-key
 101                  ((0)
 102                   (close-port (cdr in+out))
 103                   (close-fdes 0)
 104                   (dup2 (fileno (car in+out)) 0)
 105                   (execl (string-append #$lsh "/bin/lsh-writekey")
 106                          "lsh-writekey" "--server" "-o" #$host-key))
 107                  (else
 108                   (close-port (car in+out))
 109                   (close-port (cdr in+out))
 110                   (waitpid keygen)
 111                   (waitpid write-key))))))))))
 112
 113 (define (lsh-activation config)
 114   "Return the activation gexp for CONFIG."
 115   #~(begin
 116       (use-modules (guix build utils))
 117       (mkdir-p "/var/spool/lsh")
 118       #$(if (lsh-configuration-initialize? config)
 119             (lsh-initialization (lsh-configuration-lsh config)
 120                                 (lsh-configuration-host-key config))
 121             #t)))
 122
 123 (define (lsh-shepherd-service config)
 124   "Return a <shepherd-service> for lsh with CONFIG."
 125   (define lsh (lsh-configuration-lsh config))
 126   (define pid-file (lsh-configuration-pid-file config))
 127   (define pid-file? (lsh-configuration-pid-file? config))
 128   (define daemonic? (lsh-configuration-daemonic? config))
 129   (define interfaces (lsh-configuration-interfaces config))
 130
 131   (define lsh-command
 132     (append
 133      (cons (file-append lsh "/sbin/lshd")
 134            (if daemonic?
 135                (let ((syslog (if (lsh-configuration-syslog-output? config)
 136                                  '()
 137                                  (list "--no-syslog"))))
 138                  (cons "--daemonic"
 139                        (if pid-file?
 140                            (cons #~(string-append "--pid-file=" #$pid-file)
 141                                  syslog)
 142                            (cons "--no-pid-file" syslog))))
 143                (if pid-file?
 144                    (list #~(string-append "--pid-file=" #$pid-file))
 145                    '())))
 146      (cons* #~(string-append "--host-key="
 147                              #$(lsh-configuration-host-key config))
 148             #~(string-append "--password-helper=" #$lsh "/sbin/lsh-pam-checkpw")
 149             #~(string-append "--subsystems=sftp=" #$lsh "/sbin/sftp-server")
 150             "-p" (number->string (lsh-configuration-port-number config))
 151             (if (lsh-configuration-password-authentication? config)
 152                 "--password" "--no-password")
 153             (if (lsh-configuration-public-key-authentication? config)
 154                 "--publickey" "--no-publickey")
 155             (if (lsh-configuration-root-login? config)
 156                 "--root-login" "--no-root-login")
 157             (if (lsh-configuration-x11-forwarding? config)
 158                 "--x11-forward" "--no-x11-forward")
 159             (if (lsh-configuration-tcp/ip-forwarding? config)
 160                 "--tcpip-forward" "--no-tcpip-forward")
 161             (if (null? interfaces)
 162                 '()
 163                 (map (cut string-append "--interface=" <>)
 164                      interfaces)))))
 165
 166   (define requires
 167     (if (and daemonic? (lsh-configuration-syslog-output? config))
 168         '(networking syslogd)
 169         '(networking)))
 170
 171   (list (shepherd-service
 172          (documentation "GNU lsh SSH server")
 173          (provision '(ssh-daemon))
 174          (requirement requires)
 175          (start #~(make-forkexec-constructor (list #$@lsh-command)))
 176          (stop  #~(make-kill-destructor)))))
 177
 178 (define (lsh-pam-services config)
 179   "Return a list of <pam-services> for lshd with CONFIG."
 180   (list (unix-pam-service
 181          "lshd"
 182          #:allow-empty-passwords?
 183          (lsh-configuration-allow-empty-passwords? config))))
 184
 185 (define lsh-service-type
 186   (service-type (name 'lsh)
 187                 (extensions
 188                  (list (service-extension shepherd-root-service-type
 189                                           lsh-shepherd-service)
 190                        (service-extension pam-root-service-type
 191                                           lsh-pam-services)
 192                        (service-extension activation-service-type
 193                                           lsh-activation)))))
 194
 195 (define* (lsh-service #:key
 196                       (lsh lsh)
 197                       (daemonic? #t)
 198                       (host-key "/etc/lsh/host-key")
 199                       (interfaces '())
 200                       (port-number 22)
 201                       (allow-empty-passwords? #f)
 202                       (root-login? #f)
 203                       (syslog-output? #t)
 204                       (pid-file? #f)
 205                       (pid-file "/var/run/lshd.pid")
 206                       (x11-forwarding? #t)
 207                       (tcp/ip-forwarding? #t)
 208                       (password-authentication? #t)
 209                       (public-key-authentication? #t)
 210                       (initialize? #t))
 211   "Run the @command{lshd} program from @var{lsh} to listen on port @var{port-number}.
 212 @var{host-key} must designate a file containing the host key, and readable
 213 only by root.
 214
 215 When @var{daemonic?} is true, @command{lshd} will detach from the
 216 controlling terminal and log its output to syslogd, unless one sets
 217 @var{syslog-output?} to false.  Obviously, it also makes lsh-service
 218 depend on existence of syslogd service.  When @var{pid-file?} is true,
 219 @command{lshd} writes its PID to the file called @var{pid-file}.
 220
 221 When @var{initialize?} is true, automatically create the seed and host key
 222 upon service activation if they do not exist yet.  This may take long and
 223 require interaction.
 224
 225 When @var{initialize?} is false, it is up to the user to initialize the
 226 randomness generator (@pxref{lsh-make-seed,,, lsh, LSH Manual}), and to create
 227 a key pair with the private key stored in file @var{host-key} (@pxref{lshd
 228 basics,,, lsh, LSH Manual}).
 229
 230 When @var{interfaces} is empty, lshd listens for connections on all the
 231 network interfaces; otherwise, @var{interfaces} must be a list of host names
 232 or addresses.
 233
 234 @var{allow-empty-passwords?} specifies whether to accept log-ins with empty
 235 passwords, and @var{root-login?} specifies whether to accept log-ins as
 236 root.
 237
 238 The other options should be self-descriptive."
 239   (service lsh-service-type
 240            (lsh-configuration (lsh lsh) (daemonic? daemonic?)
 241                               (host-key host-key) (interfaces interfaces)
 242                               (port-number port-number)
 243                               (allow-empty-passwords? allow-empty-passwords?)
 244                               (root-login? root-login?)
 245                               (syslog-output? syslog-output?)
 246                               (pid-file? pid-file?) (pid-file pid-file)
 247                               (x11-forwarding? x11-forwarding?)
 248                               (tcp/ip-forwarding? tcp/ip-forwarding?)
 249                               (password-authentication?
 250                                password-authentication?)
 251                               (public-key-authentication?
 252                                public-key-authentication?)
 253                               (initialize? initialize?))))
 254
 255 \f
 256 ;;;
 257 ;;; OpenSSH.
 258 ;;;
 259
 260 (define-record-type* <openssh-configuration>
 261   openssh-configuration make-openssh-configuration
 262   openssh-configuration?
 263   (pid-file              openssh-configuration-pid-file
 264                          (default "/var/run/sshd.pid"))
 265   (port-number           openssh-configuration-port-number ;integer
 266                          (default 22))
 267   (permit-root-login     openssh-configuration-permit-root-login ;Boolean | 'without-password
 268                          (default #f))
 269   (allow-empty-passwords? openssh-configuration-allow-empty-passwords? ;Boolean
 270                           (default #f))
 271   (password-authentication? openssh-configuration-password-authentication? ;Boolean
 272                             (default #t))
 273   (public-key-authentication? openssh-configuration-public-key-authentication?
 274                               (default #t))                         ;Boolean
 275   (rsa-authentication?   openssh-configuration-rsa-authentication?  ;Boolean
 276                          (default #t))
 277   (x11-forwarding?       openssh-configuration-x11-forwarding? ;Boolean
 278                          (default #f))
 279   (protocol-number       openssh-configuration-protocol-number ;integer
 280                          (default 2)))
 281
 282 (define %openssh-accounts
 283   (list (user-group (name "sshd") (system? #t))
 284         (user-account
 285           (name "sshd")
 286           (group "sshd")
 287           (system? #t)
 288           (comment "sshd privilege separation user")
 289           (home-directory "/var/run/sshd")
 290           (shell #~(string-append #$shadow "/sbin/nologin")))))
 291
 292 (define (openssh-activation config)
 293   "Return the activation GEXP for CONFIG."
 294   #~(begin
 295       (use-modules (guix build utils))
 296       (mkdir-p "/etc/ssh")
 297       (mkdir-p (dirname #$(openssh-configuration-pid-file config)))
 298
 299       ;; Generate missing host keys.
 300       (system* (string-append #$openssh "/bin/ssh-keygen") "-A")))
 301
 302 (define (openssh-config-file config)
 303   "Return the sshd configuration file corresponding to CONFIG."
 304   (computed-file
 305    "sshd_config"
 306    #~(call-with-output-file #$output
 307        (lambda (port)
 308          (display "# Generated by 'openssh-service'.\n" port)
 309          (format port "Protocol ~a\n"
 310                  #$(if (eq? (openssh-configuration-protocol-number config) 1)
 311                        "1" "2"))
 312          (format port "Port ~a\n"
 313                  #$(number->string (openssh-configuration-port-number config)))
 314          (format port "PermitRootLogin ~a\n"
 315                  #$(match (openssh-configuration-permit-root-login config)
 316                      (#t "yes")
 317                      (#f "no")
 318                      ('without-password "without-password")))
 319          (format port "PermitEmptyPasswords ~a\n"
 320                  #$(if (openssh-configuration-allow-empty-passwords? config)
 321                        "yes" "no"))
 322          (format port "PasswordAuthentication ~a\n"
 323                  #$(if (openssh-configuration-password-authentication? config)
 324                        "yes" "no"))
 325          (format port "PubkeyAuthentication ~a\n"
 326                  #$(if (openssh-configuration-public-key-authentication? config)
 327                        "yes" "no"))
 328          (format port "RSAAuthentication ~a\n"
 329                  #$(if (openssh-configuration-rsa-authentication? config)
 330                        "yes" "no"))
 331          (format port "X11Forwarding ~a\n"
 332                  #$(if (openssh-configuration-x11-forwarding? config)
 333                        "yes" "no"))
 334          (format port "PidFile ~a\n"
 335                  #$(openssh-configuration-pid-file config))
 336          #t))))
 337
 338 (define (openssh-shepherd-service config)
 339   "Return a <shepherd-service> for openssh with CONFIG."
 340
 341   (define pid-file
 342     (openssh-configuration-pid-file config))
 343
 344   (define openssh-command
 345     #~(list (string-append #$openssh "/sbin/sshd")
 346             "-D" "-f" #$(openssh-config-file config)))
 347
 348   (list (shepherd-service
 349          (documentation "OpenSSH server.")
 350          (requirement '(networking syslogd))
 351          (provision '(ssh-daemon))
 352          (start #~(make-forkexec-constructor #$openssh-command
 353                                              #:pid-file #$pid-file))
 354          (stop #~(make-kill-destructor)))))
 355
 356 (define openssh-service-type
 357   (service-type (name 'openssh)
 358                 (extensions
 359                  (list (service-extension shepherd-root-service-type
 360                                           openssh-shepherd-service)
 361                        (service-extension activation-service-type
 362                                           openssh-activation)
 363                        (service-extension account-service-type
 364                                           (const %openssh-accounts))))))
 365
 366 \f
 367 ;;;
 368 ;;; Dropbear.
 369 ;;;
 370
 371 (define-record-type* <dropbear-configuration>
 372   dropbear-configuration make-dropbear-configuration
 373   dropbear-configuration?
 374   (dropbear               dropbear-configuration-dropbear
 375                           (default dropbear))
 376   (port-number            dropbear-configuration-port-number
 377                           (default 22))
 378   (syslog-output?         dropbear-configuration-syslog-output?
 379                           (default #t))
 380   (pid-file               dropbear-configuration-pid-file
 381                           (default "/var/run/dropbear.pid"))
 382   (root-login?            dropbear-configuration-root-login?
 383                           (default #f))
 384   (allow-empty-passwords? dropbear-configuration-allow-empty-passwords?
 385                           (default #f))
 386   (password-authentication? dropbear-configuration-password-authentication?
 387                             (default #t)))
 388
 389 (define (dropbear-activation config)
 390   "Return the activation gexp for CONFIG."
 391   #~(begin
 392       (use-modules (guix build utils))
 393       (mkdir-p "/etc/dropbear")))
 394
 395 (define (dropbear-shepherd-service config)
 396   "Return a <shepherd-service> for dropbear with CONFIG."
 397   (define dropbear
 398     (dropbear-configuration-dropbear config))
 399
 400   (define pid-file
 401     (dropbear-configuration-pid-file config))
 402
 403   (define dropbear-command
 404     #~(list (string-append #$dropbear "/sbin/dropbear")
 405
 406             ;; '-R' allows host keys to be automatically generated upon first
 407             ;; connection, at a time when /dev/urandom is more likely securely
 408             ;; seeded.
 409             "-F" "-R"
 410
 411             "-p" #$(number->string (dropbear-configuration-port-number config))
 412             "-P" #$pid-file
 413             #$@(if (dropbear-configuration-syslog-output? config) '() '("-E"))
 414             #$@(if (dropbear-configuration-root-login? config) '() '("-w"))
 415             #$@(if (dropbear-configuration-password-authentication? config)
 416                    '()
 417                    '("-s" "-g"))
 418             #$@(if (dropbear-configuration-allow-empty-passwords? config)
 419                    '("-B")
 420                    '())))
 421
 422   (define requires
 423     (if (dropbear-configuration-syslog-output? config)
 424         '(networking syslogd) '(networking)))
 425
 426   (list (shepherd-service
 427          (documentation "Dropbear SSH server.")
 428          (requirement requires)
 429          (provision '(ssh-daemon))
 430          (start #~(make-forkexec-constructor #$dropbear-command
 431                                              #:pid-file #$pid-file))
 432          (stop #~(make-kill-destructor)))))
 433
 434 (define dropbear-service-type
 435   (service-type (name 'dropbear)
 436                 (extensions
 437                  (list (service-extension shepherd-root-service-type
 438                                           dropbear-shepherd-service)
 439                        (service-extension activation-service-type
 440                                           dropbear-activation)))))
 441
 442 (define* (dropbear-service #:optional (config (dropbear-configuration)))
 443   "Run the @uref{https://matt.ucc.asn.au/dropbear/dropbear.html,Dropbear SSH
 444 daemon} with the given @var{config}, a @code{<dropbear-configuration>}
 445 object."
 446   (service dropbear-service-type config))
 447
 448 ;;; ssh.scm ends here