configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.68)
   5 AC_INIT([GNU Guix], [0.8.2], [bug-guix@gnu.org], [guix],
   6   [http://www.gnu.org/software/guix/])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AM_INIT_AUTOMAKE([1.12 gnu silent-rules subdir-objects \
  10  color-tests parallel-tests -Woverride -Wno-portability])
  11
  12 # Enable silent rules by default.
  13 AM_SILENT_RULES([yes])
  14
  15 AC_CONFIG_SRCDIR([guix.scm])
  16 AC_CONFIG_MACRO_DIR([m4])
  17
  18 dnl For the C++ code.  This must be used early.
  19 AC_USE_SYSTEM_EXTENSIONS
  20
  21 AM_GNU_GETTEXT([external])
  22 AM_GNU_GETTEXT_VERSION([0.18.1])
  23
  24 guilemoduledir="${datarootdir}/guile/site/2.0"
  25 AC_SUBST([guilemoduledir])
  26
  27 GUIX_SYSTEM_TYPE
  28 GUIX_ASSERT_SUPPORTED_SYSTEM
  29
  30 AC_ARG_WITH(store-dir,
  31   AC_HELP_STRING([--with-store-dir=PATH],
  32     [file name of the store (defaults to /gnu/store)]),
  33   [storedir="$withval"],
  34   [storedir="/gnu/store"])
  35 AC_SUBST(storedir)
  36
  37 AC_ARG_WITH([bash-completion-dir],
  38   AC_HELP_STRING([--with-bash-completion-dir=DIR],
  39     [name of the Bash completion directory]),
  40   [bashcompletiondir="$withval"],
  41   [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  42 AC_SUBST([bashcompletiondir])
  43
  44 dnl Better be verbose.
  45 AC_MSG_CHECKING([for the store directory])
  46 AC_MSG_RESULT([$storedir])
  47
  48 AC_ARG_ENABLE([daemon],
  49   [AS_HELP_STRING([--disable-daemon], [build the Nix daemon (C++)])],
  50   [guix_build_daemon="$enableval"],
  51   [guix_build_daemon="yes"])
  52
  53 # Prepare a version of $localstatedir & co. that does not contain references
  54 # to shell variables.
  55 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  56 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  57 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  58 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  59 AC_SUBST([guix_localstatedir])
  60 AC_SUBST([guix_sysconfdir])
  61 AC_SUBST([guix_sbindir])
  62
  63 GUIX_CHECK_FILE_NAME_LIMITS
  64
  65 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  66 dnl Make sure they are available.
  67 m4_pattern_forbid([PKG_CHECK_MODULES])
  68 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  69
  70 PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.7])
  71 AC_PATH_PROG([GUILE], [guile])
  72 AC_PATH_PROG([GUILD], [guild])
  73 if test "x$GUILD" = "x"; then
  74    AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
  75 fi
  76
  77 dnl guile-json is used for the PyPI package importer
  78 GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
  79 AM_CONDITIONAL([HAVE_GUILE_JSON], [test "x$have_guile_json" = "xyes"])
  80
  81 dnl Make sure we have a full-fledged Guile.
  82 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
  83
  84 dnl Check whether (srfi srfi-37) works, and provide our own if it doesn't.
  85 GUIX_CHECK_SRFI_37
  86 AM_CONDITIONAL([INSTALL_SRFI_37], [test "x$ac_cv_guix_srfi_37_broken" = xyes])
  87
  88 AC_ARG_WITH([nix-prefix],
  89   [AS_HELP_STRING([--with-nix-prefix=DIR],
  90     [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
  91   [case "$withval" in
  92     yes|no) ;;
  93     *)
  94       NIX_PREFIX="$withval"
  95       PATH="$NIX_PREFIX/bin:$PATH"; export PATH
  96       AC_SUBST([NIX_PREFIX])
  97       ;;
  98    esac],
  99   [])
 100
 101 AC_PATH_PROG([NIX_INSTANTIATE], [nix-instantiate])
 102 AC_PATH_PROG([NIX_HASH], [nix-hash])
 103 if test "x$guix_build_daemon$NIX_INSTANTIATE$NIX_HASH" = "xno"; then
 104    AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
 105 fi
 106
 107 if test "x$NIX_INSTANTIATE" = "x"; then
 108    # This program is an optional dependency, so we just want it to be
 109    # taken from $PATH if it's not available right now.
 110    NIX_INSTANTIATE="nix-instantiate"
 111 fi
 112
 113 AC_ARG_WITH([nixpkgs],
 114   [AS_HELP_STRING([--with-nixpkgs=DIR],
 115     [search for Nixpkgs in DIR (for testing purposes only)])],
 116   [case "$withval" in
 117     yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
 118     *)      NIXPKGS="$withval";;
 119    esac],
 120   [])
 121
 122 AC_MSG_CHECKING([for Nixpkgs source tree])
 123 if test -f "$NIXPKGS/default.nix"; then
 124    AC_MSG_RESULT([$NIXPKGS])
 125    AC_SUBST([NIXPKGS])
 126 else
 127    AC_MSG_RESULT([not found])
 128 fi
 129
 130 AC_ARG_WITH([libgcrypt-prefix],
 131   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 132   [case "$withval" in
 133     yes|no)
 134       LIBGCRYPT="libgcrypt"
 135       LIBGCRYPT_PREFIX="no"
 136       LIBGCRYPT_LIBDIR="no"
 137       ;;
 138     *)
 139       LIBGCRYPT="$withval/lib/libgcrypt"
 140       LIBGCRYPT_PREFIX="$withval"
 141       LIBGCRYPT_LIBDIR="$withval/lib"
 142       ;;
 143    esac],
 144   [LIBGCRYPT="libgcrypt"
 145    LIBGCRYPT_PREFIX="no"
 146    LIBGCRYPT_LIBDIR="no"])
 147
 148 AC_ARG_WITH([libgcrypt-libdir],
 149   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 150      [search for GNU libgcrypt's shared library in DIR])],
 151   [case "$withval" in
 152     yes|no)
 153       LIBGCRYPT="libgcrypt"
 154       LIBGCRYPT_LIBDIR="no"
 155       ;;
 156     *)
 157       LIBGCRYPT="$withval/libgcrypt"
 158       LIBGCRYPT_LIBDIR="$withval"
 159       ;;
 160    esac],
 161   [if test "x$LIBGCRYPT" = x; then
 162       LIBGCRYPT="libgcrypt"
 163    fi
 164    if test "x$LIBGCRYPT_LIBDIR" = x; then
 165       LIBGCRYPT_LIBDIR="no"
 166    fi])
 167
 168 dnl Library name suitable for `dynamic-link'.
 169 AC_MSG_CHECKING([for libgcrypt shared library name])
 170 AC_MSG_RESULT([$LIBGCRYPT])
 171 AC_SUBST([LIBGCRYPT])
 172 AC_SUBST([LIBGCRYPT_PREFIX])
 173 AC_SUBST([LIBGCRYPT_LIBDIR])
 174
 175 GUIX_ASSERT_LIBGCRYPT_USABLE
 176
 177 AC_CACHE_SAVE
 178
 179 m4_include([config-daemon.ac])
 180
 181 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 182 dnl See `HACKING' for more info.
 183 AM_MISSING_PROG([DOT], [dot])
 184
 185 AC_CONFIG_FILES([Makefile
 186                  po/guix/Makefile.in
 187                  po/packages/Makefile.in
 188                  guix/config.scm])
 189
 190 AC_CONFIG_FILES([scripts/guix], [chmod +x scripts/guix])
 191 AC_CONFIG_FILES([pre-inst-env], [chmod +x pre-inst-env])
 192 AC_CONFIG_FILES([test-env],     [chmod +x test-env])
 193
 194 dnl Emacs interface.
 195 AM_PATH_LISPDIR
 196 AM_CONDITIONAL([HAVE_EMACS], [test "x$EMACS" != "xno"])
 197
 198 emacsuidir="${guilemoduledir}/guix/emacs"
 199 AC_SUBST([emacsuidir])
 200 AC_CONFIG_FILES([emacs/guix-init.el
 201                  emacs/guix-profiles.el
 202                  emacs/guix-helper.scm])
 203
 204 AC_OUTPUT