gnu/packages.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2012, 2013, 2014, 2015, 2016, 2017, 2018, 2019 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2013 Mark H Weaver <mhw@netris.org>
   4 ;;; Copyright © 2014 Eric Bavier <bavier@member.fsf.org>
   5 ;;; Copyright © 2016, 2017 Alex Kost <alezost@gmail.com>
   6 ;;; Copyright © 2016 Mathieu Lirzin <mthl@gnu.org>
   7 ;;;
   8 ;;; This file is part of GNU Guix.
   9 ;;;
  10 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  11 ;;; under the terms of the GNU General Public License as published by
  12 ;;; the Free Software Foundation; either version 3 of the License, or (at
  13 ;;; your option) any later version.
  14 ;;;
  15 ;;; GNU Guix is distributed in the hope that it will be useful, but
  16 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;;; GNU General Public License for more details.
  19 ;;;
  20 ;;; You should have received a copy of the GNU General Public License
  21 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 (define-module (gnu packages)
  24   #:use-module (guix packages)
  25   #:use-module (guix ui)
  26   #:use-module (guix utils)
  27   #:use-module (guix discovery)
  28   #:use-module (guix memoization)
  29   #:use-module ((guix build utils)
  30                 #:select ((package-name->name+version
  31                            . hyphen-separated-name->name+version)
  32                           mkdir-p))
  33   #:autoload   (guix profiles) (packages->manifest)
  34   #:use-module (guix describe)
  35   #:use-module (guix deprecation)
  36   #:use-module (ice-9 vlist)
  37   #:use-module (ice-9 match)
  38   #:autoload   (ice-9 binary-ports) (put-bytevector)
  39   #:autoload   (system base compile) (compile)
  40   #:use-module (srfi srfi-1)
  41   #:use-module (srfi srfi-11)
  42   #:use-module (srfi srfi-26)
  43   #:use-module (srfi srfi-34)
  44   #:use-module (srfi srfi-35)
  45   #:use-module (srfi srfi-39)
  46   #:export (search-patch
  47             search-patches
  48             search-auxiliary-file
  49             %patch-path
  50             %auxiliary-files-path
  51             %package-module-path
  52             %default-package-module-path
  53
  54             fold-packages
  55             fold-available-packages
  56
  57             find-newest-available-packages
  58             find-packages-by-name
  59             find-package-locations
  60             find-best-packages-by-name
  61
  62             specification->package
  63             specification->package+output
  64             specification->location
  65             specifications->manifest
  66
  67             generate-package-cache))
  68
  69 ;;; Commentary:
  70 ;;;
  71 ;;; General utilities for the software distribution---i.e., the modules under
  72 ;;; (gnu packages ...).
  73 ;;;
  74 ;;; Code:
  75
  76 ;; By default, we store patches and auxiliary files
  77 ;; alongside Guile modules.  This is so that these extra files can be
  78 ;; found without requiring a special setup, such as a specific
  79 ;; installation directory and an extra environment variable.  One
  80 ;; advantage of this setup is that everything just works in an
  81 ;; auto-compilation setting.
  82
  83 (define %auxiliary-files-path
  84   (make-parameter
  85    (map (cut string-append <> "/gnu/packages/aux-files")
  86         %load-path)))
  87
  88 (define (search-auxiliary-file file-name)
  89   "Search the auxiliary FILE-NAME.  Return #f if not found."
  90   (search-path (%auxiliary-files-path) file-name))
  91
  92 (define (search-patch file-name)
  93   "Search the patch FILE-NAME.  Raise an error if not found."
  94   (or (search-path (%patch-path) file-name)
  95       (raise (condition
  96               (&message (message (format #f (G_ "~a: patch not found")
  97                                          file-name)))))))
  98
  99 (define-syntax-rule (search-patches file-name ...)
 100   "Return the list of absolute file names corresponding to each
 101 FILE-NAME found in %PATCH-PATH."
 102   (list (search-patch file-name) ...))
 103
 104 (define %distro-root-directory
 105   ;; Absolute file name of the module hierarchy.  Since (gnu packages …) might
 106   ;; live in a directory different from (guix), try to get the best match.
 107   (letrec-syntax ((dirname* (syntax-rules ()
 108                               ((_ file)
 109                                (dirname file))
 110                               ((_ file head tail ...)
 111                                (dirname (dirname* file tail ...)))))
 112                   (try      (syntax-rules ()
 113                               ((_ (file things ...) rest ...)
 114                                (match (search-path %load-path file)
 115                                  (#f
 116                                   (try rest ...))
 117                                  (absolute
 118                                   (dirname* absolute things ...))))
 119                               ((_)
 120                                #f))))
 121     (try ("gnu/packages/base.scm" gnu/ packages/)
 122          ("gnu/packages.scm"      gnu/)
 123          ("guix.scm"))))
 124
 125 (define %default-package-module-path
 126   ;; Default search path for package modules.
 127   `((,%distro-root-directory . "gnu/packages")))
 128
 129 (define (cache-is-authoritative?)
 130   "Return true if the pre-computed package cache is authoritative.  It is not
 131 authoritative when entries have been added via GUIX_PACKAGE_PATH or '-L'
 132 flags."
 133   (equal? (%package-module-path)
 134           (append %default-package-module-path
 135                   (package-path-entries))))
 136
 137 (define %package-module-path
 138   ;; Search path for package modules.  Each item must be either a directory
 139   ;; name or a pair whose car is a directory and whose cdr is a sub-directory
 140   ;; to narrow the search.
 141   (let*-values (((not-colon)
 142                  (char-set-complement (char-set #\:)))
 143                 ((environment)
 144                  (string-tokenize (or (getenv "GUIX_PACKAGE_PATH") "")
 145                                   not-colon))
 146                 ((channels-scm channels-go)
 147                  (package-path-entries)))
 148     ;; Automatically add channels and items from $GUIX_PACKAGE_PATH to Guile's
 149     ;; search path.  For historical reasons, $GUIX_PACKAGE_PATH goes to the
 150     ;; front; channels go to the back so that they don't override Guix' own
 151     ;; modules.
 152     (set! %load-path
 153       (append environment %load-path channels-scm))
 154     (set! %load-compiled-path
 155       (append environment %load-compiled-path channels-go))
 156
 157     (make-parameter
 158      (append environment
 159              %default-package-module-path
 160              channels-scm))))
 161
 162 (define %patch-path
 163   ;; Define it after '%package-module-path' so that '%load-path' contains user
 164   ;; directories, allowing patches in $GUIX_PACKAGE_PATH to be found.
 165   (make-parameter
 166    (map (lambda (directory)
 167           (if (string=? directory %distro-root-directory)
 168               (string-append directory "/gnu/packages/patches")
 169               directory))
 170         %load-path)))
 171
 172 ;; This procedure is used by Emacs-Guix up to 0.5.1.1, so keep it for now.
 173 ;; See <https://github.com/alezost/guix.el/issues/30>.
 174 (define-deprecated find-newest-available-packages
 175   find-packages-by-name
 176   (mlambda ()
 177     "Return a vhash keyed by package names, and with
 178 associated values of the form
 179
 180   (newest-version newest-package ...)
 181
 182 where the preferred package is listed first."
 183     (fold-packages (lambda (p r)
 184                      (let ((name    (package-name p))
 185                            (version (package-version p)))
 186                        (match (vhash-assoc name r)
 187                          ((_ newest-so-far . pkgs)
 188                           (case (version-compare version newest-so-far)
 189                             ((>) (vhash-cons name `(,version ,p) r))
 190                             ((=) (vhash-cons name `(,version ,p ,@pkgs) r))
 191                             ((<) r)))
 192                          (#f (vhash-cons name `(,version ,p) r)))))
 193                    vlist-null)))
 194
 195 (define (fold-available-packages proc init)
 196   "Fold PROC over the list of available packages.  For each available package,
 197 PROC is called along these lines:
 198
 199   (PROC NAME VERSION RESULT
 200         #:outputs OUTPUTS
 201         #:location LOCATION
 202         …)
 203
 204 PROC can use #:allow-other-keys to ignore the bits it's not interested in.
 205 When a package cache is available, this procedure does not actually load any
 206 package module."
 207   (define cache
 208     (load-package-cache (current-profile)))
 209
 210   (if (and cache (cache-is-authoritative?))
 211       (vhash-fold (lambda (name vector result)
 212                     (match vector
 213                       (#(name version module symbol outputs
 214                               supported? deprecated?
 215                               file line column)
 216                        (proc name version result
 217                              #:outputs outputs
 218                              #:location (and file
 219                                              (location file line column))
 220                              #:supported? supported?
 221                              #:deprecated? deprecated?))))
 222                   init
 223                   cache)
 224       (fold-packages (lambda (package result)
 225                        (proc (package-name package)
 226                              (package-version package)
 227                              result
 228                              #:outputs (package-outputs package)
 229                              #:location (package-location package)
 230                              #:supported?
 231                              (->bool
 232                               (member (%current-system)
 233                                       (package-supported-systems package)))
 234                              #:deprecated?
 235                              (->bool
 236                               (package-superseded package))))
 237                      init)))
 238
 239 (define* (fold-packages proc init
 240                         #:optional
 241                         (modules (all-modules (%package-module-path)
 242                                               #:warn
 243                                               warn-about-load-error))
 244                         #:key (select? (negate hidden-package?)))
 245   "Call (PROC PACKAGE RESULT) for each available package defined in one of
 246 MODULES that matches SELECT?, using INIT as the initial value of RESULT.  It
 247 is guaranteed to never traverse the same package twice."
 248   (fold-module-public-variables (lambda (object result)
 249                                   (if (and (package? object) (select? object))
 250                                       (proc object result)
 251                                       result))
 252                                 init
 253                                 modules))
 254
 255 (define %package-cache-file
 256   ;; Location of the package cache.
 257   "/lib/guix/package.cache")
 258
 259 (define load-package-cache
 260   (mlambda (profile)
 261     "Attempt to load the package cache.  On success return a vhash keyed by
 262 package names.  Return #f on failure."
 263     (match profile
 264       (#f #f)
 265       (profile
 266        (catch 'system-error
 267          (lambda ()
 268            (define lst
 269              (load-compiled (string-append profile %package-cache-file)))
 270            (fold (lambda (item vhash)
 271                    (match item
 272                      (#(name version module symbol outputs
 273                              supported? deprecated?
 274                              file line column)
 275                       (vhash-cons name item vhash))))
 276                  vlist-null
 277                  lst))
 278          (lambda args
 279            (if (= ENOENT (system-error-errno args))
 280                #f
 281                (apply throw args))))))))
 282
 283 (define find-packages-by-name/direct              ;bypass the cache
 284   (let ((packages (delay
 285                     (fold-packages (lambda (p r)
 286                                      (vhash-cons (package-name p) p r))
 287                                    vlist-null)))
 288         (version>? (lambda (p1 p2)
 289                      (version>? (package-version p1) (package-version p2)))))
 290     (lambda* (name #:optional version)
 291       "Return the list of packages with the given NAME.  If VERSION is not #f,
 292 then only return packages whose version is prefixed by VERSION, sorted in
 293 decreasing version order."
 294       (let ((matching (sort (vhash-fold* cons '() name (force packages))
 295                             version>?)))
 296         (if version
 297             (filter (lambda (package)
 298                       (version-prefix? version (package-version package)))
 299                     matching)
 300             matching)))))
 301
 302 (define (cache-lookup cache name)
 303   "Lookup package NAME in CACHE.  Return a list sorted in increasing version
 304 order."
 305   (define (package-version<? v1 v2)
 306     (version>? (vector-ref v2 1) (vector-ref v1 1)))
 307
 308   (sort (vhash-fold* cons '() name cache)
 309         package-version<?))
 310
 311 (define* (find-packages-by-name name #:optional version)
 312   "Return the list of packages with the given NAME.  If VERSION is not #f,
 313 then only return packages whose version is prefixed by VERSION, sorted in
 314 decreasing version order."
 315   (define cache
 316     (load-package-cache (current-profile)))
 317
 318   (if (and (cache-is-authoritative?) cache)
 319       (match (cache-lookup cache name)
 320         (#f #f)
 321         ((#(_ versions modules symbols _ _ _ _ _ _) ...)
 322          (fold (lambda (version* module symbol result)
 323                  (if (or (not version)
 324                          (version-prefix? version version*))
 325                      (cons (module-ref (resolve-interface module)
 326                                        symbol)
 327                            result)
 328                      result))
 329                '()
 330                versions modules symbols)))
 331       (find-packages-by-name/direct name version)))
 332
 333 (define* (find-package-locations name #:optional version)
 334   "Return a list of version/location pairs corresponding to each package
 335 matching NAME and VERSION."
 336   (define cache
 337     (load-package-cache (current-profile)))
 338
 339   (if (and cache (cache-is-authoritative?))
 340       (match (cache-lookup cache name)
 341         (#f '())
 342         ((#(name versions modules symbols outputs
 343                  supported? deprecated?
 344                  files lines columns) ...)
 345          (fold (lambda (version* file line column result)
 346                  (if (and file
 347                           (or (not version)
 348                               (version-prefix? version version*)))
 349                      (alist-cons version* (location file line column)
 350                                  result)
 351                      result))
 352                '()
 353                versions files lines columns)))
 354       (map (lambda (package)
 355              (cons (package-version package) (package-location package)))
 356            (find-packages-by-name/direct name version))))
 357
 358 (define (find-best-packages-by-name name version)
 359   "If version is #f, return the list of packages named NAME with the highest
 360 version numbers; otherwise, return the list of packages named NAME and at
 361 VERSION."
 362   (if version
 363       (find-packages-by-name name version)
 364       (match (find-packages-by-name name)
 365         (()
 366          '())
 367         ((matches ...)
 368          ;; Return the subset of MATCHES with the higher version number.
 369          (let ((highest (package-version (first matches))))
 370            (take-while (lambda (p)
 371                          (string=? (package-version p) highest))
 372                        matches))))))
 373
 374 (define (generate-package-cache directory)
 375   "Generate under DIRECTORY a cache of all the available packages.
 376
 377 The primary purpose of the cache is to speed up package lookup by name such
 378 that we don't have to traverse and load all the package modules, thereby also
 379 reducing the memory footprint."
 380   (define cache-file
 381     (string-append directory %package-cache-file))
 382
 383   (define (expand-cache module symbol variable result+seen)
 384     (match (false-if-exception (variable-ref variable))
 385       ((? package? package)
 386        (match result+seen
 387          ((result . seen)
 388           (if (or (vhash-assq package seen)
 389                   (hidden-package? package))
 390               (cons result seen)
 391               (cons (cons `#(,(package-name package)
 392                              ,(package-version package)
 393                              ,(module-name module)
 394                              ,symbol
 395                              ,(package-outputs package)
 396                              ,(->bool
 397                                (member (%current-system)
 398                                        (package-supported-systems package)))
 399                              ,(->bool (package-superseded package))
 400                              ,@(let ((loc (package-location package)))
 401                                  (if loc
 402                                      `(,(location-file loc)
 403                                        ,(location-line loc)
 404                                        ,(location-column loc))
 405                                      '(#f #f #f))))
 406                           result)
 407                     (vhash-consq package #t seen))))))
 408       (_
 409        result+seen)))
 410
 411   (define exp
 412     (first
 413      (fold-module-public-variables* expand-cache
 414                                     (cons '() vlist-null)
 415                                     (all-modules (%package-module-path)
 416                                                  #:warn
 417                                                  warn-about-load-error))))
 418
 419   (mkdir-p (dirname cache-file))
 420   (call-with-output-file cache-file
 421     (lambda (port)
 422       ;; Store the cache as a '.go' file.  This makes loading fast and reduces
 423       ;; heap usage since some of the static data is directly mmapped.
 424       (put-bytevector port
 425                       (compile `'(,@exp)
 426                                #:to 'bytecode
 427                                #:opts '(#:to-file? #t)))))
 428   cache-file)
 429
 430 \f
 431 (define %sigint-prompt
 432   ;; The prompt to jump to upon SIGINT.
 433   (make-prompt-tag "interruptible"))
 434
 435 (define (call-with-sigint-handler thunk handler)
 436   "Call THUNK and return its value.  Upon SIGINT, call HANDLER with the signal
 437 number in the context of the continuation of the call to this function, and
 438 return its return value."
 439   (call-with-prompt %sigint-prompt
 440                     (lambda ()
 441                       (sigaction SIGINT
 442                         (lambda (signum)
 443                           (sigaction SIGINT SIG_DFL)
 444                           (abort-to-prompt %sigint-prompt signum)))
 445                       (dynamic-wind
 446                         (const #t)
 447                         thunk
 448                         (cut sigaction SIGINT SIG_DFL)))
 449                     (lambda (k signum)
 450                       (handler signum))))
 451
 452 \f
 453 ;;;
 454 ;;; Package specification.
 455 ;;;
 456
 457 (define* (%find-package spec name version)
 458   (match (find-best-packages-by-name name version)
 459     ((pkg . pkg*)
 460      (unless (null? pkg*)
 461        (warning (G_ "ambiguous package specification `~a'~%") spec)
 462        (warning (G_ "choosing ~a@~a from ~a~%")
 463                 (package-name pkg) (package-version pkg)
 464                 (location->string (package-location pkg))))
 465      (match (package-superseded pkg)
 466        ((? package? new)
 467         (info (G_ "package '~a' has been superseded by '~a'~%")
 468               (package-name pkg) (package-name new))
 469         new)
 470        (#f
 471         pkg)))
 472     (x
 473      (if version
 474          (leave (G_ "~A: package not found for version ~a~%") name version)
 475          (leave (G_ "~A: unknown package~%") name)))))
 476
 477 (define (specification->package spec)
 478   "Return a package matching SPEC.  SPEC may be a package name, or a package
 479 name followed by an at-sign and a version number.  If the version number is not
 480 present, return the preferred newest version."
 481   (let-values (((name version) (package-name->name+version spec)))
 482     (%find-package spec name version)))
 483
 484 (define (specification->location spec)
 485   "Return the location of the highest-numbered package matching SPEC, a
 486 specification such as \"guile@2\" or \"emacs\"."
 487   (let-values (((name version) (package-name->name+version spec)))
 488     (match (find-package-locations name version)
 489       (()
 490        (if version
 491            (leave (G_ "~A: package not found for version ~a~%") name version)
 492            (leave (G_ "~A: unknown package~%") name)))
 493       (lst
 494        (let* ((highest   (match lst (((version . _) _ ...) version)))
 495               (locations (take-while (match-lambda
 496                                        ((version . location)
 497                                         (string=? version highest)))
 498                                      lst)))
 499          (match locations
 500            (((version . location) . rest)
 501             (unless (null? rest)
 502               (warning (G_ "ambiguous package specification `~a'~%") spec)
 503               (warning (G_ "choosing ~a@~a from ~a~%")
 504                        name version
 505                        (location->string location)))
 506             location)))))))
 507
 508 (define* (specification->package+output spec #:optional (output "out"))
 509   "Return the package and output specified by SPEC, or #f and #f; SPEC may
 510 optionally contain a version number and an output name, as in these examples:
 511
 512   guile
 513   guile@2.0.9
 514   guile:debug
 515   guile@2.0.9:debug
 516
 517 If SPEC does not specify a version number, return the preferred newest
 518 version; if SPEC does not specify an output, return OUTPUT.
 519
 520 When OUTPUT is false and SPEC does not specify any output, return #f as the
 521 output."
 522   (let-values (((name version sub-drv)
 523                 (package-specification->name+version+output spec output)))
 524     (match (%find-package spec name version)
 525       (#f
 526        (values #f #f))
 527       (package
 528        (if (or (and (not output) (not sub-drv))
 529                (member sub-drv (package-outputs package)))
 530            (values package sub-drv)
 531            (leave (G_ "package `~a' lacks output `~a'~%")
 532                   (package-full-name package)
 533                   sub-drv))))))
 534
 535 (define (specifications->manifest specs)
 536   "Given SPECS, a list of specifications such as \"emacs@25.2\" or
 537 \"guile:debug\", return a profile manifest."
 538   ;; This procedure exists mostly so users of 'guix package -m' don't have to
 539   ;; fiddle with multiple-value returns.
 540   (packages->manifest
 541    (map (compose list specification->package+output) specs)))