configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.68)
   5 AC_INIT([GNU Guix],
   6   [m4_esyscmd([build-aux/git-version-gen .tarball-version])],
   7   [bug-guix@gnu.org], [guix],
   8   [https://www.gnu.org/software/guix/])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10
  11 AM_INIT_AUTOMAKE([1.14 gnu silent-rules subdir-objects \
  12  color-tests parallel-tests -Woverride -Wno-portability])
  13
  14 # Enable silent rules by default.
  15 AM_SILENT_RULES([yes])
  16
  17 AC_CONFIG_SRCDIR([guix.scm])
  18 AC_CONFIG_MACRO_DIR([m4])
  19
  20 dnl For the C++ code.  This must be used early.
  21 AC_USE_SYSTEM_EXTENSIONS
  22
  23 AM_GNU_GETTEXT([external])
  24 AM_GNU_GETTEXT_VERSION([0.18.1])
  25
  26 GUIX_SYSTEM_TYPE
  27 GUIX_ASSERT_SUPPORTED_SYSTEM
  28
  29 AC_ARG_WITH(store-dir,
  30   AC_HELP_STRING([--with-store-dir=PATH],
  31     [file name of the store (defaults to /gnu/store)]),
  32   [storedir="$withval"],
  33   [storedir="/gnu/store"])
  34 AC_SUBST(storedir)
  35
  36 AC_ARG_WITH([bash-completion-dir],
  37   AC_HELP_STRING([--with-bash-completion-dir=DIR],
  38     [name of the Bash completion directory]),
  39   [bashcompletiondir="$withval"],
  40   [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  41 AC_SUBST([bashcompletiondir])
  42
  43 AC_ARG_WITH([zsh-completion-dir],
  44   AC_HELP_STRING([--with-zsh-completion-dir=DIR],
  45     [name of the Zsh completion directory]),
  46   [zshcompletiondir="$withval"],
  47   [zshcompletiondir='${datadir}/zsh/site-functions'])
  48 AC_SUBST([zshcompletiondir])
  49
  50 AC_ARG_WITH([fish-completion-dir],
  51   AC_HELP_STRING([--with-fish-completion-dir=DIR],
  52     [name of the Fish completion directory]),
  53   [fishcompletiondir="$withval"],
  54   [fishcompletiondir='${datadir}/fish/vendor_completions.d'])
  55 AC_SUBST([fishcompletiondir])
  56
  57 AC_ARG_WITH([selinux-policy-dir],
  58   AC_HELP_STRING([--with-selinux-policy-dir=DIR],
  59     [name of the SELinux policy directory]),
  60   [selinux_policydir="$withval"],
  61   [selinux_policydir='${datadir}/selinux/'])
  62 AC_SUBST([selinux_policydir])
  63
  64 dnl Better be verbose.
  65 AC_MSG_CHECKING([for the store directory])
  66 AC_MSG_RESULT([$storedir])
  67
  68 AC_ARG_ENABLE([daemon],
  69   [AS_HELP_STRING([--disable-daemon], [do not build the Nix daemon (C++)])],
  70   [guix_build_daemon="$enableval"],
  71   [guix_build_daemon="yes"])
  72
  73 # Prepare a version of $localstatedir & co. that does not contain references
  74 # to shell variables.
  75 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  76 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  77 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  78 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  79 AC_SUBST([guix_localstatedir])
  80 AC_SUBST([guix_sysconfdir])
  81 AC_SUBST([guix_sbindir])
  82
  83 GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  84 AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  85
  86 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  87 dnl Make sure they are available.
  88 m4_pattern_forbid([PKG_CHECK_MODULES])
  89 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  90 m4_pattern_forbid([^GUILE_P])
  91 m4_pattern_allow([^GUILE_PKG_ERRORS])
  92 m4_pattern_forbid([^GUIX_])
  93
  94 dnl Search for 'guile' and 'guild'.  This macro defines
  95 dnl 'GUILE_EFFECTIVE_VERSION'.
  96 GUILE_PKG([2.2])
  97 GUILE_PROGS
  98 if test "x$GUILD" = "x"; then
  99    AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
 100 fi
 101
 102 dnl Installation directories for .scm and .go files.
 103 guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
 104 guileobjectdir="${libdir}/guile/$GUILE_EFFECTIVE_VERSION/site-ccache"
 105 AC_SUBST([guilemoduledir])
 106 AC_SUBST([guileobjectdir])
 107
 108 dnl The GnuTLS bindings are necessary for substitutes over HTTPS and for 'guix
 109 dnl pull', among other things.
 110 GUILE_MODULE_AVAILABLE([have_gnutls], [(gnutls)])
 111 if test "x$have_gnutls" != "xyes"; then
 112   AC_MSG_ERROR([The Guile bindings of GnuTLS are missing; please install them.])
 113 fi
 114
 115 dnl Check for Guile-Git.
 116 GUILE_MODULE_AVAILABLE([have_guile_git], [(git)])
 117 if test "x$have_guile_git" != "xyes"; then
 118   AC_MSG_ERROR([Guile-Git is missing; please install it.])
 119 fi
 120
 121 dnl Check for Guile-JSON.
 122 GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
 123 if test "x$have_guile_json" != "xyes"; then
 124   AC_MSG_ERROR([Guile-JSON is missing; please install it.])
 125 fi
 126
 127 dnl Guile-Sqlite3 is used by the (guix store ...) modules.
 128 GUIX_CHECK_GUILE_SQLITE3
 129 if test "x$guix_cv_have_recent_guile_sqlite3" != "xyes"; then
 130   AC_MSG_ERROR([A recent Guile-SQLite3 could not be found; please install it.])
 131 fi
 132
 133 GUILE_MODULE_AVAILABLE([have_guile_gcrypt], [(gcrypt hash)])
 134 if test "x$have_guile_gcrypt" != "xyes"; then
 135   AC_MSG_ERROR([Guile-Gcrypt could not be found; please install it.])
 136 fi
 137
 138 dnl Guile-newt is used by the graphical installer.
 139 GUILE_MODULE_AVAILABLE([have_guile_newt], [(newt)])
 140
 141 AC_ARG_ENABLE([installer],
 142     AS_HELP_STRING([--enable-installer], [Build the graphical installer sources.]))
 143
 144 AS_IF([test "x$enable_installer" = "xyes"], [
 145 if test "x$have_guile_newt" != "xyes"; then
 146   AC_MSG_ERROR([Guile-newt could not be found; please install it.])
 147 fi
 148 ])
 149
 150 AM_CONDITIONAL([ENABLE_INSTALLER],
 151   [test "x$enable_installer" = "xyes"])
 152
 153 dnl Make sure we have a full-fledged Guile.
 154 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
 155
 156 dnl Make sure we don't suffer from the bug in 'equal?' wrt. syntax objects
 157 dnl found in 2.2.1.  See <https://bugs.gnu.org/29903>.
 158 GUIX_ASSERT_SYNTAX_OBJECT_EQUAL
 159
 160 AC_PROG_SED
 161
 162 dnl Decompressors, for use by the substituter and other modules.
 163 AC_PATH_PROG([GZIP], [gzip])
 164 AC_PATH_PROG([BZIP2], [bzip2])
 165 AC_PATH_PROG([XZ], [xz])
 166 AC_SUBST([GZIP])
 167 AC_SUBST([BZIP2])
 168 AC_SUBST([XZ])
 169
 170 AC_ARG_WITH([nix-prefix],
 171   [AS_HELP_STRING([--with-nix-prefix=DIR],
 172     [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
 173   [case "$withval" in
 174     yes|no) ;;
 175     *)
 176       NIX_PREFIX="$withval"
 177       PATH="$NIX_PREFIX/bin:$PATH"; export PATH
 178       AC_SUBST([NIX_PREFIX])
 179       ;;
 180    esac],
 181   [])
 182
 183 AC_PATH_PROG([NIX_HASH], [nix-hash])
 184 if test "x$guix_build_daemon$NIX_HASH" = "xno"; then
 185    AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
 186 fi
 187
 188 AC_ARG_WITH([nixpkgs],
 189   [AS_HELP_STRING([--with-nixpkgs=DIR],
 190     [search for Nixpkgs in DIR (for testing purposes only)])],
 191   [case "$withval" in
 192     yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
 193     *)      NIXPKGS="$withval";;
 194    esac],
 195   [])
 196
 197 AC_MSG_CHECKING([for Nixpkgs source tree])
 198 if test -f "$NIXPKGS/default.nix"; then
 199    AC_MSG_RESULT([$NIXPKGS])
 200    AC_SUBST([NIXPKGS])
 201 else
 202    AC_MSG_RESULT([not found])
 203 fi
 204
 205 LIBGCRYPT="libgcrypt"
 206 LIBGCRYPT_LIBDIR="no"
 207 LIBGCRYPT_PREFIX="no"
 208
 209 AC_ARG_WITH([libgcrypt-prefix],
 210   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 211   [case "$withval" in
 212     yes|no)
 213       ;;
 214     *)
 215       LIBGCRYPT="$withval/lib/libgcrypt"
 216       LIBGCRYPT_PREFIX="$withval"
 217       LIBGCRYPT_LIBDIR="$withval/lib"
 218       ;;
 219    esac])
 220
 221 AC_ARG_WITH([libgcrypt-libdir],
 222   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 223      [search for GNU libgcrypt's shared library in DIR])],
 224   [case "$withval" in
 225     yes|no)
 226       LIBGCRYPT="libgcrypt"
 227       LIBGCRYPT_LIBDIR="no"
 228       ;;
 229     *)
 230       LIBGCRYPT="$withval/libgcrypt"
 231       LIBGCRYPT_LIBDIR="$withval"
 232       ;;
 233    esac])
 234
 235 dnl If none of the --with-libgcrypt-* options was used, try to determine the
 236 dnl the library directory.
 237 case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
 238   xnono)
 239     GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
 240     ;;
 241 esac
 242
 243 dnl Library name suitable for `dynamic-link'.
 244 AC_MSG_CHECKING([for libgcrypt shared library name])
 245 AC_MSG_RESULT([$LIBGCRYPT])
 246 AC_SUBST([LIBGCRYPT])
 247 AC_SUBST([LIBGCRYPT_PREFIX])
 248 AC_SUBST([LIBGCRYPT_LIBDIR])
 249
 250 dnl Library name of zlib suitable for 'dynamic-link'.
 251 GUIX_LIBZ_LIBDIR([libz_libdir])
 252 if test "x$libz_libdir" = "x"; then
 253   LIBZ="libz"
 254 else
 255   LIBZ="$libz_libdir/libz"
 256 fi
 257 AC_MSG_CHECKING([for zlib's shared library name])
 258 AC_MSG_RESULT([$LIBZ])
 259 AC_SUBST([LIBZ])
 260
 261 dnl Check for Guile-SSH, for the (guix ssh) module.
 262 GUIX_CHECK_GUILE_SSH
 263 AM_CONDITIONAL([HAVE_GUILE_SSH],
 264   [test "x$guix_cv_have_recent_guile_ssh" = "xyes"])
 265
 266 AC_CACHE_SAVE
 267
 268 m4_include([config-daemon.ac])
 269
 270 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 271 dnl See `Building from Git' in the manual for more info.
 272 AM_MISSING_PROG([DOT], [dot])
 273
 274 dnl Manual pages.
 275 AM_MISSING_PROG([HELP2MAN], [help2man])
 276
 277 dnl Documentation translation.
 278 AM_MISSING_PROG([PO4A_TRANSLATE], [po4a-translate])
 279 AM_MISSING_PROG([PO4A_UPDATEPO], [po4a-updatepo])
 280
 281 dnl Emacs (optional), for 'etc/indent-package.el'.
 282 AC_PATH_PROG([EMACS], [emacs], [/usr/bin/emacs])
 283 AC_SUBST([EMACS])
 284
 285 case "$storedir" in
 286   /gnu/store)
 287     ;;
 288   *)
 289     AC_MSG_WARN([Using a store directory other than '/gnu/store' will prevent you])
 290     AC_MSG_WARN([from downloading substitutes from gnu.org.])
 291     ;;
 292 esac
 293
 294 AC_CONFIG_FILES([Makefile
 295                  po/guix/Makefile.in
 296                  po/packages/Makefile.in
 297                  etc/guix-daemon.cil
 298                  guix/config.scm])
 299
 300 AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
 301 AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
 302   [chmod +x pre-inst-env])
 303 AC_CONFIG_FILES([etc/indent-code.el], [chmod +x etc/indent-code.el])
 304
 305 AC_OUTPUT