tests/file-systems.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2015, 2017 Ludovic Courtès <ludo@gnu.org>
   3 ;;;
   4 ;;; This file is part of GNU Guix.
   5 ;;;
   6 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU General Public License as published by
   8 ;;; the Free Software Foundation; either version 3 of the License, or (at
   9 ;;; your option) any later version.
  10 ;;;
  11 ;;; GNU Guix is distributed in the hope that it will be useful, but
  12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;; GNU General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU General Public License
  17 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 (define-module (test-file-systems)
  20   #:use-module (guix store)
  21   #:use-module (guix modules)
  22   #:use-module (gnu system file-systems)
  23   #:use-module (srfi srfi-64)
  24   #:use-module (rnrs bytevectors))
  25
  26 ;; Test the (gnu system file-systems) module.
  27
  28 (test-begin "file-systems")
  29
  30 (test-equal "uuid->string"
  31   "c5307e6b-d1ba-499d-89c5-cb0b143577c4"
  32   (uuid->string
  33    #vu8(197 48 126 107 209 186 73 157 137 197 203 11 20 53 119 196)))
  34
  35 (test-equal "string->uuid"
  36   '(16 "4dab5feb-d176-45de-b287-9b0a6e4c01cb")
  37   (let ((uuid (string->uuid "4dab5feb-d176-45de-b287-9b0a6e4c01cb")))
  38     (list (bytevector-length uuid) (uuid->string uuid))))
  39
  40 (test-assert "uuid"
  41   (let ((str "4dab5feb-d176-45de-b287-9b0a6e4c01cb"))
  42     (bytevector=? (uuid "4dab5feb-d176-45de-b287-9b0a6e4c01cb")
  43                   (string->uuid "4dab5feb-d176-45de-b287-9b0a6e4c01cb"))))
  44
  45 (test-assert "uuid, syntax error"
  46   (catch 'syntax-error
  47     (lambda ()
  48       (eval '(uuid "foobar") (current-module))
  49       #f)
  50     (lambda (key proc message location form . args)
  51       (and (eq? proc 'uuid)
  52            (string-contains message "invalid UUID")
  53            (equal? form '(uuid "foobar"))))))
  54
  55 (test-assert "file-system-needed-for-boot?"
  56   (let-syntax ((dummy-fs (syntax-rules ()
  57                            ((_ directory)
  58                             (file-system
  59                               (device "foo")
  60                               (mount-point directory)
  61                               (type "ext4"))))))
  62     (parameterize ((%store-prefix "/gnu/guix/store"))
  63       (and (file-system-needed-for-boot? (dummy-fs "/"))
  64            (file-system-needed-for-boot? (dummy-fs "/gnu"))
  65            (file-system-needed-for-boot? (dummy-fs "/gnu/guix"))
  66            (file-system-needed-for-boot? (dummy-fs "/gnu/guix/store"))
  67            (not (file-system-needed-for-boot?
  68                  (dummy-fs "/gnu/guix/store/foo")))
  69            (not (file-system-needed-for-boot? (dummy-fs "/gn")))
  70            (not (file-system-needed-for-boot?
  71                  (file-system
  72                    (inherit (dummy-fs (%store-prefix)))
  73                    (device "/foo")
  74                    (flags '(bind-mount read-only)))))))))
  75
  76 (test-assert "does not pull (guix config)"
  77   ;; This module is meant both for the host side and "build side", so make
  78   ;; sure it doesn't pull in (guix config), which depends on the user's
  79   ;; config.
  80   (not (member '(guix config)
  81                (source-module-closure '((gnu system file-systems))))))
  82
  83 (test-end)