gnu/packages/ghostscript.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013 Andreas Enge <andreas@enge.fr>
   3 ;;; Copyright © 2014, 2015, 2016, 2017 Mark H Weaver <mhw@netris.org>
   4 ;;; Copyright © 2015 Ricardo Wurmus <rekado@elephly.net>
   5 ;;; Copyright © 2013, 2015, 2016, 2017 Ludovic Courtès <ludo@gnu.org>
   6 ;;; Copyright © 2017 Alex Vong <alexvong1995@gmail.com>
   7 ;;; Copyright © 2017, 2018, 2019 Efraim Flashner <efraim@flashner.co.il>
   8 ;;; Copyright © 2017 Leo Famulari <leo@famulari.name>
   9 ;;; Copyright © 2018 Tobias Geerinckx-Rice <me@tobias.gr>
  10 ;;; Copyright © 2018 Marius Bakke <mbakke@fastmail.com>
  11 ;;;
  12 ;;; This file is part of GNU Guix.
  13 ;;;
  14 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  15 ;;; under the terms of the GNU General Public License as published by
  16 ;;; the Free Software Foundation; either version 3 of the License, or (at
  17 ;;; your option) any later version.
  18 ;;;
  19 ;;; GNU Guix is distributed in the hope that it will be useful, but
  20 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;;; GNU General Public License for more details.
  23 ;;;
  24 ;;; You should have received a copy of the GNU General Public License
  25 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 (define-module (gnu packages ghostscript)
  28   #:use-module (gnu packages)
  29   #:use-module (gnu packages autotools)
  30   #:use-module (gnu packages compression)
  31   #:use-module (gnu packages cups)
  32   #:use-module (gnu packages fontutils)
  33   #:use-module (gnu packages image)
  34   #:use-module (gnu packages perl)
  35   #:use-module (gnu packages pkg-config)
  36   #:use-module (gnu packages python)
  37   #:use-module (gnu packages tcl)
  38   #:use-module (gnu packages xorg)
  39   #:use-module ((guix licenses) #:prefix license:)
  40   #:use-module (guix packages)
  41   #:use-module (guix download)
  42   #:use-module (guix utils)
  43   #:use-module (guix build-system gnu)
  44   #:use-module (guix build-system trivial)
  45   #:use-module (srfi srfi-1))
  46
  47 (define-public lcms
  48   (package
  49    (name "lcms")
  50    (version "2.9")
  51    (source (origin
  52             (method url-fetch)
  53             (uri (string-append "mirror://sourceforge/lcms/lcms/" version
  54                                 "/lcms2-" version ".tar.gz"))
  55
  56             (patches (search-patches "lcms-CVE-2018-16435.patch"))
  57             (sha256 (base32
  58                      "083xisy6z01zhm7p7rgk4bx9d6zlr8l20qkfv1g29ylnhgwzvij8"))))
  59    (build-system gnu-build-system)
  60    (inputs `(("libjpeg" ,libjpeg)
  61              ("libtiff" ,libtiff)
  62              ("zlib" ,zlib)))
  63    (synopsis "Little CMS, a small-footprint colour management engine")
  64    (description
  65     "Little CMS is a small-footprint colour management engine, with special
  66 focus on accuracy and performance.  It uses the International Color
  67 Consortium standard (ICC), approved as ISO 15076-1.")
  68    (license license:x11)
  69    (home-page "http://www.littlecms.com/")
  70    (properties '((cpe-name . "little_cms_color_engine")))))
  71
  72 (define-public libpaper
  73   (package
  74    (name "libpaper")
  75    (version "1.1.24")
  76    (source (origin
  77             (method url-fetch)
  78             (uri (string-append
  79                    ;; Debian moved their libpaper-1.1.24 to archive.debian.net
  80                    ;; but in the move the hash of their tarball changed.
  81                    "http://pkgs.fedoraproject.org/repo/pkgs/libpaper/libpaper_"
  82                    version ".tar.gz/5bc87d494ba470aba54f6d2d51471834/libpaper_"
  83                    version ".tar.gz"))
  84             (sha256 (base32
  85                      "0zhcx67afb6b5r936w5jmaydj3ks8zh83n9rm5sv3m3k8q8jib1q"))))
  86    (build-system gnu-build-system)
  87    (synopsis "Library for handling paper sizes")
  88    (description
  89     "The paper library and accompanying files are intended to provide a simple
  90 way for applications to take actions based on a system- or user-specified
  91 paper size.")
  92    (license license:gpl2)
  93    (home-page "https://packages.qa.debian.org/libp/libpaper.html")))
  94
  95 (define-public psutils
  96   (package
  97    (name "psutils")
  98    (version "17")
  99    (source (origin
 100             (method url-fetch)
 101             (uri "ftp://ftp.knackered.org/pub/psutils/psutils.tar.gz")
 102             (sha256 (base32
 103                      "1r4ab1fvgganm02kmm70b2r1azwzbav2am41gbigpa2bb1wynlrq"))))
 104    (build-system gnu-build-system)
 105    (inputs `(("perl" ,perl)))
 106    (arguments
 107     `(#:tests? #f ; none provided
 108       #:phases
 109       (modify-phases %standard-phases
 110         (replace 'configure
 111           (lambda* (#:key inputs outputs #:allow-other-keys #:rest args)
 112            (let ((perl (assoc-ref inputs "perl"))
 113                  (out (assoc-ref outputs "out")))
 114             (copy-file "Makefile.unix" "Makefile")
 115             (substitute* "Makefile"
 116               (("/usr/local/bin/perl") (string-append perl "/bin/perl")))
 117             (substitute* "Makefile"
 118               (("/usr/local") out))
 119             ;; for the install phase
 120             (substitute* "Makefile"
 121               (("-mkdir") "mkdir -p"))
 122             ;; drop installation of non-free files
 123             (substitute* "Makefile"
 124               ((" install.include") "")))
 125            #t)))))
 126    (synopsis "Collection of utilities for manipulating PostScript documents")
 127    (description
 128     "PSUtils is a collection of utilities for manipulating PostScript
 129 documents.  Programs included are psnup, for placing out several logical pages
 130 on a single sheet of paper, psselect, for selecting pages from a document,
 131 pstops, for general imposition, psbook, for signature generation for booklet
 132 printing, and psresize, for adjusting page sizes.")
 133    (license (license:non-copyleft "file://LICENSE"
 134                                 "See LICENSE in the distribution."))
 135    (home-page "http://knackered.org/angus/psutils/")))
 136
 137 (define-public ghostscript
 138   (package
 139     (name "ghostscript")
 140     (version "9.27")
 141     (source
 142       (origin
 143         (method url-fetch)
 144         (uri (string-append "https://github.com/ArtifexSoftware/"
 145                             "ghostpdl-downloads/releases/download/gs"
 146                             (string-delete #\. version)
 147                             "/ghostscript-" version ".tar.xz"))
 148         (sha256
 149          (base32
 150           "06dnj0mxyaryfbwlsjwaqf847w91w2h8f108kxxcc41nrnx1y3zw"))
 151         (patches (search-patches "ghostscript-no-header-creationdate.patch"
 152                                  "ghostscript-no-header-id.patch"
 153                                  "ghostscript-no-header-uuid.patch"))
 154         (modules '((guix build utils)))
 155         (snippet
 156           ;; Remove bundled libraries. The bundled OpenJPEG is a patched fork so
 157           ;; we leave it, at least for now.
 158           ;; TODO Try unbundling ijs, which is developed alongside Ghostscript.
 159           ;; Likewise for the thread-safe lcms2 fork called "lcms2art".
 160          '(begin
 161             (for-each delete-file-recursively '("freetype" "jbig2dec" "jpeg"
 162                                                 "libpng" "tiff" "zlib"))
 163             #t))))
 164     (build-system gnu-build-system)
 165     (outputs '("out" "doc"))                  ;19 MiB of HTML/PS doc + examples
 166     (arguments
 167      `(#:disallowed-references ("doc")
 168        ;; XXX: Starting with version 9.27, building the tests in parallel
 169        ;; occasionally fails like this:
 170        ;;  In file included from ./base/memory_.h:23:0,
 171        ;;                   from ./obj/gsmd5.h:1,
 172        ;;                   from ./obj/gsmd5.c:56:
 173        ;;  ./base/std.h:25:10: fatal error: arch.h: No such file or directory
 174        #:parallel-tests? #f
 175        #:configure-flags
 176        (list (string-append "LDFLAGS=-Wl,-rpath="
 177                             (assoc-ref %outputs "out") "/lib")
 178              "--with-system-libtiff"
 179              "LIBS=-lz"
 180              (string-append "ZLIBDIR="
 181                             (assoc-ref %build-inputs "zlib") "/include")
 182              "--enable-dynamic"
 183
 184              ,@(if (%current-target-system)
 185                    '(;; Specify the native compiler, which is used to build 'echogs'
 186                      ;; and other intermediary tools when cross-compiling; see
 187                      ;; <https://ghostscript.com/FAQ.html>.
 188                      "CCAUX=gcc"
 189
 190                      ;; Save 'config.log' etc. of the native build under
 191                      ;; auxtmp/, useful for debugging.
 192                      "--enable-save_confaux")
 193                    '()))
 194        #:phases
 195        (modify-phases %standard-phases
 196         (add-before 'configure 'create-output-directory
 197           (lambda* (#:key outputs #:allow-other-keys)
 198             ;; The configure script refuses to function if the directory
 199             ;; specified as -rpath does not already exist.
 200             (mkdir-p (string-append (assoc-ref outputs "out") "/lib"))
 201             #t))
 202         (add-after 'configure 'remove-doc-reference
 203           (lambda _
 204             ;; Don't retain a reference to the 'doc' output in 'gs'.
 205             ;; The only use of this definition is in the output of
 206             ;; 'gs --help', so this change is fine.
 207             (substitute* "base/gscdef.c"
 208               (("GS_DOCDIR")
 209                "\"~/.guix-profile/share/doc/ghostscript\""))
 210             ;; The docdir default changed in 9.23 and a compatibility
 211             ;; symlink was added from datadir->docdir.  Remove it.
 212             (substitute* "base/unixinst.mak"
 213               (("ln -s \\$\\(DESTDIR\\)\\$\\(docdir\\).*") ""))
 214             #t))
 215          (add-after 'configure 'patch-config-files
 216            (lambda _
 217              (substitute* "base/unixhead.mak"
 218                (("/bin/sh") (which "sh")))
 219              #t))
 220          ,@(if (%current-target-system)
 221                `((add-after 'configure 'add-native-lz
 222                    (lambda _
 223                      ;; Add missing '-lz' for native tools such as 'mkromfs'.
 224                      (substitute* "Makefile"
 225                        (("^AUXEXTRALIBS=(.*)$" _ value)
 226                         (string-append "AUXEXTRALIBS = -lz " value "\n")))
 227                      #t)))
 228                '())
 229          (replace 'build
 230            (lambda _
 231              ;; Build 'libgs.so', but don't build the statically-linked 'gs'
 232              ;; binary (saves 22 MiB).
 233              (invoke "make" "so" "-j"
 234                      (number->string (parallel-job-count)))))
 235          (replace 'install
 236            (lambda _
 237              (invoke "make" "soinstall")))
 238          (add-after 'install 'create-gs-symlink
 239            (lambda* (#:key outputs #:allow-other-keys)
 240              (let ((out (assoc-ref outputs "out")))
 241                ;; Some programs depend on having a 'gs' binary available.
 242                (symlink "gsc" (string-append out "/bin/gs"))
 243                #t))))))
 244     (native-inputs
 245      `(("perl" ,perl)
 246        ("python" ,python-wrapper)
 247        ("tcl" ,tcl)
 248
 249        ;; When cross-compiling, some of the natively-built tools require all
 250        ;; these libraries.
 251        ,@(if (%current-target-system)
 252              `(("zlib/native" ,zlib)
 253                ("libjpeg/native" ,libjpeg))
 254              '())))
 255     (inputs
 256      `(("freetype" ,freetype)
 257        ("jbig2dec" ,jbig2dec)
 258        ("libjpeg" ,libjpeg)
 259        ("libpaper" ,libpaper)
 260        ("libpng" ,libpng)
 261        ("libtiff" ,libtiff)
 262        ("zlib" ,zlib)))
 263     (synopsis "PostScript and PDF interpreter")
 264     (description
 265      "Ghostscript is an interpreter for the PostScript language and the PDF
 266 file format.  It also includes a C library that implements the graphics
 267 capabilities of the PostScript language.  It supports a wide variety of
 268 output file formats and printers.")
 269     (home-page "https://www.ghostscript.com/")
 270     (license license:agpl3+)))
 271
 272 (define-public ghostscript/x
 273   (package/inherit ghostscript
 274     (name (string-append (package-name ghostscript) "-with-x"))
 275     (inputs `(("libxext" ,libxext)
 276               ("libxt" ,libxt)
 277               ,@(package-inputs ghostscript)))))
 278
 279 (define-public ghostscript/cups
 280   (package/inherit ghostscript
 281     (name "ghostscript-with-cups")
 282     (inputs `(("cups" ,cups-minimal)
 283               ,@(package-inputs ghostscript)))))
 284
 285 (define-public ijs
 286   (package
 287    (name "ijs")
 288    (version (package-version ghostscript))
 289    (source (package-source ghostscript))
 290    (build-system gnu-build-system)
 291    (native-inputs
 292     `(("libtool"    ,libtool)
 293       ("automake"   ,automake)
 294       ("autoconf"   ,autoconf)))
 295    (arguments
 296     `(#:phases
 297       (modify-phases %standard-phases
 298         (add-after 'unpack 'autogen
 299           (lambda _
 300             ;; need to regenerate macros
 301             (system* "autoreconf" "-if")
 302             ;; do not run configure
 303             (substitute* "autogen.sh"
 304               (("^.*\\$srcdir/configure.*") ""))
 305             (system* "bash" "autogen.sh")
 306             ;; create configure script in ./ijs/
 307             (chdir "ijs")
 308             ;; do not run configure
 309             (substitute* "autogen.sh"
 310               (("^.*\\$srcdir/configure.*") "")
 311               (("^ + && echo Now type.*$")  ""))
 312             (invoke "bash" "autogen.sh"))))))
 313    (synopsis "IJS driver framework for inkjet and other raster devices")
 314    (description
 315     "IJS is a protocol for transmission of raster page images.  This package
 316 provides the reference implementation of the raster printer driver
 317 architecture.")
 318    (license license:expat)
 319    (home-page (package-home-page ghostscript))))
 320
 321 (define-public gs-fonts
 322   (package
 323    (name "gs-fonts")
 324    (version "8.11")
 325    (source (origin
 326             (method url-fetch)
 327             (uri (string-append "mirror://sourceforge/gs-fonts/gs-fonts/"
 328                                 version
 329                                 "%20%28base%2035%2C%20GPL%29/ghostscript-fonts-std-"
 330                                 version
 331                                 ".tar.gz"))
 332             (sha256 (base32
 333                      "00f4l10xd826kak51wsmaz69szzm2wp8a41jasr4jblz25bg7dhf"))))
 334    (build-system gnu-build-system)
 335    (arguments
 336     `(#:tests? #f ; nothing to check, just files to copy
 337
 338       #:modules ((guix build gnu-build-system)
 339                  (guix build utils)
 340                  (srfi srfi-1))
 341       #:phases
 342       (modify-phases %standard-phases
 343         (delete 'configure)
 344         (delete 'build)
 345         (replace 'install
 346           (lambda* (#:key outputs #:allow-other-keys)
 347             (let* ((out (assoc-ref outputs "out"))
 348                    (dir (string-append out "/share/fonts/type1/ghostscript")))
 349               (mkdir-p dir)
 350               (for-each
 351                 (lambda (file)
 352                   (copy-file file (string-append dir "/" file)))
 353                 (find-files "." "pfb|afm"))
 354               #t))))))
 355    (synopsis "Free replacements for the PostScript fonts")
 356    (description
 357     "Ghostscript fonts provides fonts and font metrics customarily distributed with
 358 Ghostscript.  It currently includes the 35 standard PostScript fonts.")
 359    (license license:gpl2)
 360    (home-page "https://sourceforge.net/projects/gs-fonts/")))
 361
 362 (define-public libspectre
 363   (package
 364    (name "libspectre")
 365    (version "0.2.8")
 366    (source (origin
 367             (method url-fetch)
 368             (uri (string-append "https://libspectre.freedesktop.org/releases/libspectre-"
 369                                 version ".tar.gz"))
 370             (sha256 (base32
 371                      "1a67iglsc3r05mzngyg9kb1gy8whq4fgsnyjwi7bqfw2i7rnl9b5"))))
 372    (build-system gnu-build-system)
 373    (inputs `(("ghostscript" ,ghostscript)))
 374    (native-inputs `(("pkg-config" ,pkg-config)))
 375    (synopsis "Postscript rendering library")
 376    (description
 377     "libspectre is a small library for rendering Postscript documents.
 378 It provides a convenient easy to use API for handling and rendering
 379 Postscript documents.")
 380    (license license:gpl2+)
 381    (home-page "https://www.freedesktop.org/wiki/Software/libspectre")))