guix/gnu-maintenance.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2012, 2013 Nikita Karetnikov <nikita@karetnikov.org>
   4 ;;;
   5 ;;; This file is part of GNU Guix.
   6 ;;;
   7 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   8 ;;; under the terms of the GNU General Public License as published by
   9 ;;; the Free Software Foundation; either version 3 of the License, or (at
  10 ;;; your option) any later version.
  11 ;;;
  12 ;;; GNU Guix is distributed in the hope that it will be useful, but
  13 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;;; GNU General Public License for more details.
  16 ;;;
  17 ;;; You should have received a copy of the GNU General Public License
  18 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 (define-module (guix gnu-maintenance)
  21   #:use-module (web uri)
  22   #:use-module (web client)
  23   #:use-module (web response)
  24   #:use-module (ice-9 regex)
  25   #:use-module (ice-9 match)
  26   #:use-module (srfi srfi-1)
  27   #:use-module (srfi srfi-11)
  28   #:use-module (srfi srfi-26)
  29   #:use-module (rnrs io ports)
  30   #:use-module (system foreign)
  31   #:use-module (guix http-client)
  32   #:use-module (guix ftp-client)
  33   #:use-module (guix utils)
  34   #:use-module (guix memoization)
  35   #:use-module (guix records)
  36   #:use-module (guix upstream)
  37   #:use-module (guix packages)
  38   #:use-module (guix zlib)
  39   #:export (gnu-package-name
  40             gnu-package-mundane-name
  41             gnu-package-copyright-holder
  42             gnu-package-savannah
  43             gnu-package-fsd
  44             gnu-package-language
  45             gnu-package-logo
  46             gnu-package-doc-category
  47             gnu-package-doc-summary
  48             gnu-package-doc-description
  49             gnu-package-doc-urls
  50             gnu-package-download-url
  51
  52             official-gnu-packages
  53             find-package
  54             gnu-package?
  55
  56             release-file?
  57             releases
  58             latest-release
  59             gnu-release-archive-types
  60             gnu-package-name->name+version
  61
  62             %gnu-updater
  63             %gnu-ftp-updater
  64             %gnome-updater
  65             %kde-updater
  66             %xorg-updater
  67             %kernel.org-updater))
  68
  69 ;;; Commentary:
  70 ;;;
  71 ;;; Code for dealing with the maintenance of GNU packages, such as
  72 ;;; auto-updates.
  73 ;;;
  74 ;;; Code:
  75
  76 \f
  77 ;;;
  78 ;;; List of GNU packages.
  79 ;;;
  80
  81 (define %gnumaint-base-url
  82   "http://cvs.savannah.gnu.org/viewvc/*checkout*/womb/gnumaint/")
  83
  84 (define %package-list-url
  85   (string->uri
  86    (string-append %gnumaint-base-url "gnupackages.txt")))
  87
  88 (define %package-description-url
  89   ;; This file contains package descriptions in recutils format.
  90   ;; See <https://lists.gnu.org/archive/html/guix-devel/2013-10/msg00071.html>.
  91   (string->uri
  92    (string-append %gnumaint-base-url "pkgblurbs.txt")))
  93
  94 (define-record-type* <gnu-package-descriptor>
  95   gnu-package-descriptor
  96   make-gnu-package-descriptor
  97
  98   gnu-package-descriptor?
  99
 100   (name             gnu-package-name)
 101   (mundane-name     gnu-package-mundane-name)
 102   (copyright-holder gnu-package-copyright-holder)
 103   (savannah         gnu-package-savannah)
 104   (fsd              gnu-package-fsd)
 105   (language         gnu-package-language)         ; list of strings
 106   (logo             gnu-package-logo)
 107   (doc-category     gnu-package-doc-category)
 108   (doc-summary      gnu-package-doc-summary)
 109   (doc-description  gnu-package-doc-description)  ; taken from 'pkgdescr.txt'
 110   (doc-urls         gnu-package-doc-urls)         ; list of strings
 111   (download-url     gnu-package-download-url))
 112
 113 (define* (official-gnu-packages
 114           #:optional (fetch http-fetch/cached))
 115   "Return a list of records, which are GNU packages.  Use FETCH,
 116 to fetch the list of GNU packages over HTTP."
 117   (define (read-records port)
 118     ;; Return a list of alists.  Each alist contains fields of a GNU
 119     ;; package.
 120     (let loop ((alist  (recutils->alist port))
 121                (result '()))
 122       (if (null? alist)
 123           (reverse result)
 124           (loop (recutils->alist port)
 125                 (cons alist result)))))
 126
 127   (define official-description
 128     (let ((db (read-records (fetch %package-description-url #:text? #t))))
 129       (lambda (name)
 130         ;; Return the description found upstream for package NAME, or #f.
 131         (and=> (find (lambda (alist)
 132                        (equal? name (assoc-ref alist "package")))
 133                      db)
 134                (lambda (record)
 135                  (let ((field (assoc-ref record "blurb")))
 136                    ;; The upstream description file uses "redirect PACKAGE" as
 137                    ;; a blurb in cases where the description of the two
 138                    ;; packages should be considered the same (e.g., GTK+ has
 139                    ;; "redirect gnome".)  This is usually not acceptable for
 140                    ;; us because we prefer to have distinct descriptions in
 141                    ;; such cases.  Thus, ignore the 'blurb' field when that
 142                    ;; happens.
 143                    (and field
 144                         (not (string-prefix? "redirect " field))
 145                         field)))))))
 146
 147   (map (lambda (alist)
 148          (let ((name (assoc-ref alist "package")))
 149            (alist->record `(("description" . ,(official-description name))
 150                             ,@alist)
 151                           make-gnu-package-descriptor
 152                           (list "package" "mundane-name" "copyright-holder"
 153                                 "savannah" "fsd" "language" "logo"
 154                                 "doc-category" "doc-summary" "description"
 155                                 "doc-url"
 156                                 "download-url")
 157                           '("doc-url" "language"))))
 158        (let* ((port (fetch %package-list-url #:text? #t))
 159               (lst  (read-records port)))
 160          (close-port port)
 161          lst)))
 162
 163 (define (find-package name)
 164   "Find GNU package called NAME and return it.  Return #f if it was not
 165 found."
 166   (find (lambda (package)
 167           (string=? name (gnu-package-name package)))
 168         (official-gnu-packages)))
 169
 170 (define gnu-package?
 171   (let ((official-gnu-packages (memoize official-gnu-packages)))
 172     (mlambdaq (package)
 173       "Return true if PACKAGE is a GNU package.  This procedure may access the
 174 network to check in GNU's database."
 175       (define (mirror-type url)
 176         (let ((uri (string->uri url)))
 177           (and (eq? (uri-scheme uri) 'mirror)
 178                (cond
 179                 ((member (uri-host uri)
 180                          '("gnu" "gnupg" "gcc" "gnome"))
 181                  ;; Definitely GNU.
 182                  'gnu)
 183                 ((equal? (uri-host uri) "cran")
 184                  ;; Possibly GNU: mirror://cran could be either GNU R itself
 185                  ;; or a non-GNU package.
 186                  #f)
 187                 (else
 188                  ;; Definitely non-GNU.
 189                  'non-gnu)))))
 190
 191       (define (gnu-home-page? package)
 192         (letrec-syntax ((>> (syntax-rules ()
 193                               ((_ value proc)
 194                                (and=> value proc))
 195                               ((_ value proc rest ...)
 196                                (and=> value
 197                                       (lambda (next)
 198                                         (>> (proc next) rest ...)))))))
 199           (>> package package-home-page
 200               string->uri uri-host
 201               (lambda (host)
 202                 (member host '("www.gnu.org" "gnu.org"))))))
 203
 204       (or (gnu-home-page? package)
 205           (let ((url  (and=> (package-source package) origin-uri))
 206                 (name (package-upstream-name package)))
 207             (case (and (string? url) (mirror-type url))
 208               ((gnu) #t)
 209               ((non-gnu) #f)
 210               (else
 211                (and (member name (map gnu-package-name (official-gnu-packages)))
 212                     #t))))))))
 213
 214 \f
 215 ;;;
 216 ;;; Latest release.
 217 ;;;
 218
 219 (define (ftp-server/directory package)
 220   "Return the FTP server and directory where PACKAGE's tarball are stored."
 221   (let ((name (package-upstream-name package)))
 222     (values (or (assoc-ref (package-properties package) 'ftp-server)
 223                 "ftp.gnu.org")
 224             (or (assoc-ref (package-properties package) 'ftp-directory)
 225                 (string-append "/gnu/" name)))))
 226
 227 (define (sans-extension tarball)
 228   "Return TARBALL without its .tar.* or .zip extension."
 229   (let ((end (or (string-contains tarball ".tar")
 230                  (string-contains tarball ".zip"))))
 231     (substring tarball 0 end)))
 232
 233 (define %tarball-rx
 234   ;; The .zip extensions is notably used for freefont-ttf.
 235   ;; The "-src" pattern is for "TeXmacs-1.0.7.9-src.tar.gz".
 236   ;; The "-gnu[0-9]" pattern is for "icecat-38.4.0-gnu1.tar.bz2".
 237   (make-regexp "^([^.]+)-([0-9]|[^-])+(-(src|gnu[0-9]))?\\.(tar\\.|zip$)"))
 238
 239 (define %alpha-tarball-rx
 240   (make-regexp "^.*-.*[0-9](-|~)?(alpha|beta|rc|cvs|svn|git)-?[0-9\\.]*\\.tar\\."))
 241
 242 (define (release-file? project file)
 243   "Return #f if FILE is not a release tarball of PROJECT, otherwise return
 244 true."
 245   (and (not (string-suffix? ".sig" file))
 246        (and=> (regexp-exec %tarball-rx file)
 247               (lambda (match)
 248                 ;; Filter out unrelated files, like `guile-www-1.1.1'.
 249                 ;; Case-insensitive for things like "TeXmacs" vs. "texmacs".
 250                 ;; The "-src" suffix is for "freefont-src-20120503.tar.gz".
 251                 (and=> (match:substring match 1)
 252                        (lambda (name)
 253                          (or (string-ci=? name project)
 254                              (string-ci=? name
 255                                           (string-append project
 256                                                          "-src")))))))
 257        (not (regexp-exec %alpha-tarball-rx file))
 258        (let ((s (sans-extension file)))
 259          (regexp-exec %package-name-rx s))))
 260
 261 (define (tarball->version tarball)
 262   "Return the version TARBALL corresponds to.  TARBALL is a file name like
 263 \"coreutils-8.23.tar.xz\"."
 264   (let-values (((name version)
 265                 (gnu-package-name->name+version (sans-extension tarball))))
 266     version))
 267
 268 (define* (releases project
 269                    #:key
 270                    (server "ftp.gnu.org")
 271                    (directory (string-append "/gnu/" project)))
 272   "Return the list of <upstream-release> of PROJECT as a list of release
 273 name/directory pairs."
 274   ;; TODO: Parse something like fencepost.gnu.org:/gd/gnuorg/packages-ftp.
 275   (define conn (ftp-open server))
 276
 277   (let loop ((directories (list directory))
 278              (result      '()))
 279     (match directories
 280       (()
 281        (ftp-close conn)
 282        (coalesce-sources result))
 283       ((directory rest ...)
 284        (let* ((files   (ftp-list conn directory))
 285               (subdirs (filter-map (match-lambda
 286                                      ((name 'directory . _) name)
 287                                      (_ #f))
 288                                    files)))
 289          (define (file->url file)
 290            (string-append "ftp://" server directory "/" file))
 291
 292          (define (file->source file)
 293            (let ((url (file->url file)))
 294              (upstream-source
 295               (package project)
 296               (version (tarball->version file))
 297               (urls (list url))
 298               (signature-urls (list (string-append url ".sig"))))))
 299
 300          (loop (append (map (cut string-append directory "/" <>)
 301                             subdirs)
 302                        rest)
 303                (append
 304                 ;; Filter out signatures, deltas, and files which
 305                 ;; are potentially not releases of PROJECT--e.g.,
 306                 ;; in /gnu/guile, filter out guile-oops and
 307                 ;; guile-www; in mit-scheme, filter out binaries.
 308                 (filter-map (match-lambda
 309                               ((file 'file . _)
 310                                (and (release-file? project file)
 311                                     (file->source file)))
 312                               (_ #f))
 313                             files)
 314                 result)))))))
 315
 316 (define* (latest-ftp-release project
 317                              #:key
 318                              (server "ftp.gnu.org")
 319                              (directory (string-append "/gnu/" project))
 320                              (keep-file? (const #t))
 321                              (file->signature (cut string-append <> ".sig"))
 322                              (ftp-open ftp-open) (ftp-close ftp-close))
 323   "Return an <upstream-source> for the latest release of PROJECT on SERVER
 324 under DIRECTORY, or #f.  Use FTP-OPEN and FTP-CLOSE to open (resp. close) FTP
 325 connections; this can be useful to reuse connections.
 326
 327 KEEP-FILE? is a predicate to decide whether to enter a directory and to
 328 consider a given file (source tarball) as a valid candidate based on its name.
 329
 330 FILE->SIGNATURE must be a procedure; it is passed a source file URL and must
 331 return the corresponding signature URL, or #f it signatures are unavailable."
 332   (define (latest a b)
 333     (if (version>? a b) a b))
 334
 335   (define (latest-release a b)
 336     (if (version>? (upstream-source-version a) (upstream-source-version b))
 337         a b))
 338
 339   (define contains-digit?
 340     (cut string-any char-set:digit <>))
 341
 342   (define patch-directory-name?
 343     ;; Return #t for patch directory names such as 'bash-4.2-patches'.
 344     (cut string-suffix? "patches" <>))
 345
 346   (define conn (ftp-open server))
 347
 348   (define (file->url directory file)
 349     (string-append "ftp://" server directory "/" file))
 350
 351   (define (file->source directory file)
 352     (let ((url (file->url directory file)))
 353       (upstream-source
 354        (package project)
 355        (version (tarball->version file))
 356        (urls (list url))
 357        (signature-urls (match (file->signature url)
 358                          (#f #f)
 359                          (sig (list sig)))))))
 360
 361   (let loop ((directory directory)
 362              (result    #f))
 363     (let* ((entries (ftp-list conn directory))
 364
 365            ;; Filter out sub-directories that do not contain digits---e.g.,
 366            ;; /gnuzilla/lang and /gnupg/patches.  Filter out "w32"
 367            ;; directories as found on ftp.gnutls.org.
 368            (subdirs (filter-map (match-lambda
 369                                   (((? patch-directory-name? dir)
 370                                     'directory . _)
 371                                    #f)
 372                                   (("w32" 'directory . _)
 373                                    #f)
 374                                   (((? contains-digit? dir) 'directory . _)
 375                                    (and (keep-file? dir) dir))
 376                                   (_ #f))
 377                                 entries))
 378
 379            ;; Whether or not SUBDIRS is empty, compute the latest releases
 380            ;; for the current directory.  This is necessary for packages
 381            ;; such as 'sharutils' that have a sub-directory that contains
 382            ;; only an older release.
 383            (releases (filter-map (match-lambda
 384                                    ((file 'file . _)
 385                                     (and (release-file? project file)
 386                                          (keep-file? file)
 387                                          (file->source directory file)))
 388                                    (_ #f))
 389                                  entries)))
 390
 391       ;; Assume that SUBDIRS correspond to versions, and jump into the
 392       ;; one with the highest version number.
 393       (let* ((release  (reduce latest-release #f
 394                                (coalesce-sources releases)))
 395              (result   (if (and result release)
 396                            (latest-release release result)
 397                            (or release result)))
 398              (target   (reduce latest #f subdirs)))
 399         (if target
 400             (loop (string-append directory "/" target)
 401                   result)
 402             (begin
 403               (ftp-close conn)
 404               result))))))
 405
 406 (define* (latest-release package
 407                          #:key
 408                          (server "ftp.gnu.org")
 409                          (directory (string-append "/gnu/" package)))
 410   "Return the <upstream-source> for the latest version of PACKAGE or #f.
 411 PACKAGE must be the canonical name of a GNU package."
 412   (latest-ftp-release package
 413                       #:server server
 414                       #:directory directory))
 415
 416 (define-syntax-rule (false-if-ftp-error exp)
 417   "Return #f if an FTP error is raise while evaluating EXP; return the result
 418 of EXP otherwise."
 419   (catch 'ftp-error
 420     (lambda ()
 421       exp)
 422     (lambda (key port . rest)
 423       (if (ftp-connection? port)
 424           (ftp-close port)
 425           (close-port port))
 426       #f)))
 427
 428 (define (latest-release* package)
 429   "Like 'latest-release', but (1) take a <package> object, and (2) ignore FTP
 430 errors that might occur when PACKAGE is not actually a GNU package, or not
 431 hosted on ftp.gnu.org, or not under that name (this is the case for
 432 \"emacs-auctex\", for instance.)"
 433   (let-values (((server directory)
 434                 (ftp-server/directory package)))
 435     (false-if-ftp-error (latest-release (package-upstream-name package)
 436                                         #:server server
 437                                         #:directory directory))))
 438
 439 (define %gnu-file-list-uri
 440   ;; URI of the file list for ftp.gnu.org.
 441   (string->uri "https://ftp.gnu.org/find.txt.gz"))
 442
 443 (define ftp.gnu.org-files
 444   (mlambda ()
 445     "Return the list of files available at ftp.gnu.org."
 446
 447     ;; XXX: Memoize the whole procedure to work around the fact that
 448     ;; 'http-fetch/cached' caches the gzipped version.
 449
 450     (define (trim-leading-components str)
 451       ;; Trim the leading ".", if any, in "./gnu/foo".
 452       (string-trim str (char-set #\.)))
 453
 454     (define (string->lines str)
 455       (string-tokenize str (char-set-complement (char-set #\newline))))
 456
 457     ;; Since https://ftp.gnu.org honors 'If-Modified-Since', the hard-coded
 458     ;; TTL can be relatively short.
 459     (let ((port (http-fetch/cached %gnu-file-list-uri #:ttl (* 15 60))))
 460       (map trim-leading-components
 461            (call-with-gzip-input-port port
 462              (compose string->lines get-string-all))))))
 463
 464 (define (latest-gnu-release package)
 465   "Return the latest release of PACKAGE, a GNU package available via
 466 ftp.gnu.org.
 467
 468 This method does not rely on FTP access at all; instead, it browses the file
 469 list available from %GNU-FILE-LIST-URI over HTTP(S)."
 470   (let-values (((server directory)
 471                 (ftp-server/directory package))
 472                ((name)
 473                 (package-upstream-name package)))
 474     (let* ((files    (ftp.gnu.org-files))
 475            (relevant (filter (lambda (file)
 476                                (and (string-prefix? "/gnu" file)
 477                                     (string-contains file directory)
 478                                     (release-file? name (basename file))))
 479                              files)))
 480       (match (sort relevant (lambda (file1 file2)
 481                               (version>? (sans-extension (basename file1))
 482                                          (sans-extension (basename file2)))))
 483         ((and tarballs (reference _ ...))
 484          (let* ((version  (tarball->version reference))
 485                 (tarballs (filter (lambda (file)
 486                                     (string=? (sans-extension
 487                                                (basename file))
 488                                               (sans-extension
 489                                                (basename reference))))
 490                                   tarballs)))
 491            (upstream-source
 492             (package name)
 493             (version version)
 494             (urls (map (lambda (file)
 495                          (string-append "mirror://gnu/"
 496                                         (string-drop file
 497                                                      (string-length "/gnu/"))))
 498                        tarballs))
 499             (signature-urls (map (cut string-append <> ".sig") urls)))))
 500         (()
 501          #f)))))
 502
 503 (define %package-name-rx
 504   ;; Regexp for a package name, e.g., "foo-X.Y".  Since TeXmacs uses
 505   ;; "TeXmacs-X.Y-src", the `-src' suffix is allowed.
 506   (make-regexp "^(.*)-(([0-9]|\\.)+)(-src)?"))
 507
 508 (define (gnu-package-name->name+version name+version)
 509   "Return the package name and version number extracted from NAME+VERSION."
 510   (let ((match (regexp-exec %package-name-rx name+version)))
 511     (if (not match)
 512         (values name+version #f)
 513         (values (match:substring match 1) (match:substring match 2)))))
 514
 515 (define (pure-gnu-package? package)
 516   "Return true if PACKAGE is a non-Emacs and non-GNOME GNU package.  This
 517 excludes AucTeX, for instance, whose releases are now uploaded to
 518 elpa.gnu.org, and all the GNOME packages; EMMS is included though, because its
 519 releases are on gnu.org."
 520   (and (or (not (string-prefix? "emacs-" (package-name package)))
 521            (gnu-hosted? package))
 522        (not (gnome-package? package))
 523        (gnu-package? package)))
 524
 525 (define (url-prefix-predicate prefix)
 526   "Return a predicate that returns true when passed a package where one of its
 527 source URLs starts with PREFIX."
 528   (lambda (package)
 529     (define matching-uri?
 530       (match-lambda
 531         ((? string? uri)
 532          (string-prefix? prefix uri))
 533         (_
 534          #f)))
 535
 536     (match (package-source package)
 537       ((? origin? origin)
 538        (match (origin-uri origin)
 539          ((? matching-uri?) #t)
 540          (_                 #f)))
 541       (_ #f))))
 542
 543 (define gnu-hosted?
 544   (url-prefix-predicate "mirror://gnu/"))
 545
 546 (define gnome-package?
 547   (url-prefix-predicate "mirror://gnome/"))
 548
 549 (define (latest-gnome-release package)
 550   "Return the latest release of PACKAGE, the name of a GNOME package."
 551   (define %not-dot
 552     (char-set-complement (char-set #\.)))
 553
 554   (define (even-minor-version? version)
 555     (match (string-tokenize version %not-dot)
 556       (((= string->number major) (= string->number minor) . rest)
 557        (and minor (even? minor)))
 558       (_
 559        #t)))                                      ;cross fingers
 560
 561   (define (even-numbered? file)
 562     ;; Return true if FILE somehow denotes an even-numbered file name.  The
 563     ;; trick here is that we want this to match both directories such as
 564     ;; "3.18.6" and actual file names such as "gtk+-3.18.6.tar.bz2".
 565     (let-values (((name version) (package-name->name+version file)))
 566       (even-minor-version? (or version name))))
 567
 568   (define upstream-name
 569     ;; Some packages like "NetworkManager" have camel-case names.
 570     (package-upstream-name package))
 571
 572   (false-if-ftp-error
 573    (latest-ftp-release upstream-name
 574                        #:server "ftp.gnome.org"
 575                        #:directory (string-append "/pub/gnome/sources/"
 576                                                   upstream-name)
 577
 578
 579                        ;; <https://www.gnome.org/gnome-3/source/> explains
 580                        ;; that odd minor version numbers represent development
 581                        ;; releases, which we are usually not interested in.
 582                        #:keep-file? even-numbered?
 583
 584                        ;; ftp.gnome.org provides no signatures, only
 585                        ;; checksums.
 586                        #:file->signature (const #f))))
 587
 588
 589 (define (latest-kde-release package)
 590   "Return the latest release of PACKAGE, the name of an KDE.org package."
 591   (let ((uri (string->uri (origin-uri (package-source package)))))
 592     (false-if-ftp-error
 593      (latest-ftp-release
 594       (package-upstream-name package)
 595       #:server "mirrors.mit.edu"
 596       #:directory
 597       (string-append "/kde" (dirname (dirname (uri-path uri))))
 598       #:file->signature (const #f)))))
 599
 600 (define (latest-xorg-release package)
 601   "Return the latest release of PACKAGE, the name of an X.org package."
 602   (let ((uri (string->uri (origin-uri (package-source package)))))
 603     (false-if-ftp-error
 604      (latest-ftp-release
 605       (package-name package)
 606       #:server "ftp.freedesktop.org"
 607       #:directory
 608       (string-append "/pub/xorg/" (dirname (uri-path uri)))))))
 609
 610 (define (latest-kernel.org-release package)
 611   "Return the latest release of PACKAGE, the name of a kernel.org package."
 612   (let ((uri (string->uri (origin-uri (package-source package)))))
 613     (false-if-ftp-error
 614      (latest-ftp-release
 615       (package-name package)
 616       #:server "ftp.free.fr"                      ;a mirror reachable over FTP
 617       #:directory (string-append "/mirrors/ftp.kernel.org"
 618                                  (dirname (uri-path uri)))
 619
 620       ;; kernel.org provides "foo-x.y.tar.sign" files, which are signatures of
 621       ;; the uncompressed tarball.
 622       #:file->signature (lambda (tarball)
 623                           (string-append (file-sans-extension tarball)
 624                                          ".sign"))))))
 625
 626 (define %gnu-updater
 627   ;; This is for everything at ftp.gnu.org.
 628   (upstream-updater
 629    (name 'gnu)
 630    (description "Updater for GNU packages")
 631    (pred gnu-hosted?)
 632    (latest latest-gnu-release)))
 633
 634 (define %gnu-ftp-updater
 635   ;; This is for GNU packages taken from alternate locations, such as
 636   ;; alpha.gnu.org, ftp.gnupg.org, etc.  It is obsolescent.
 637   (upstream-updater
 638    (name 'gnu-ftp)
 639    (description "Updater for GNU packages only available via FTP")
 640    (pred (lambda (package)
 641            (and (not (gnu-hosted? package))
 642                 (pure-gnu-package? package))))
 643    (latest latest-release*)))
 644
 645 (define %gnome-updater
 646   (upstream-updater
 647    (name 'gnome)
 648    (description "Updater for GNOME packages")
 649    (pred gnome-package?)
 650    (latest latest-gnome-release)))
 651
 652 (define %kde-updater
 653   (upstream-updater
 654     (name 'kde)
 655     (description "Updater for KDE packages")
 656     (pred (url-prefix-predicate "mirror://kde/"))
 657     (latest latest-kde-release)))
 658
 659 (define %xorg-updater
 660   (upstream-updater
 661    (name 'xorg)
 662    (description "Updater for X.org packages")
 663    (pred (url-prefix-predicate "mirror://xorg/"))
 664    (latest latest-xorg-release)))
 665
 666 (define %kernel.org-updater
 667   (upstream-updater
 668    (name 'kernel.org)
 669    (description "Updater for packages hosted on kernel.org")
 670    (pred (url-prefix-predicate "mirror://kernel.org/"))
 671    (latest latest-kernel.org-release)))
 672
 673 ;;; gnu-maintenance.scm ends here