gnu/services/cuirass.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2016 Mathieu Lirzin <mthl@gnu.org>
   3 ;;; Copyright © 2016, 2017 Ludovic Courtès <ludo@gnu.org>
   4 ;;; Copyright © 2017 Mathieu Othacehe <m.othacehe@gmail.com>
   5 ;;; Copyright © 2017 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;
   7 ;;; This file is part of GNU Guix.
   8 ;;;
   9 ;;; GNU Guix is free software: you can redistribute it and/or modify
  10 ;;; it under the terms of the GNU General Public License as published by
  11 ;;; the Free Software Foundation, either version 3 of the License, or
  12 ;;; (at your option) any later version.
  13 ;;;
  14 ;;; GNU Guix is distributed in the hope that it will be useful,
  15 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;;; GNU General Public License for more details.
  18 ;;;
  19 ;;; You should have received a copy of the GNU General Public License
  20 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 (define-module (gnu services cuirass)
  23   #:use-module (guix gexp)
  24   #:use-module (guix records)
  25   #:use-module (gnu packages admin)
  26   #:autoload   (gnu packages ci) (cuirass)
  27   #:autoload   (gnu packages version-control) (git)
  28   #:use-module (gnu services)
  29   #:use-module (gnu services base)
  30   #:use-module (gnu services shepherd)
  31   #:use-module (gnu services admin)
  32   #:use-module (gnu system shadow)
  33   #:export (<cuirass-configuration>
  34             cuirass-configuration
  35             cuirass-configuration?
  36
  37             cuirass-service-type))
  38
  39 ;;;; Commentary:
  40 ;;;
  41 ;;; This module implements a service that to run instances of Cuirass, a
  42 ;;; continuous integration tool.
  43 ;;;
  44 ;;;; Code:
  45
  46 (define-record-type* <cuirass-configuration>
  47   cuirass-configuration make-cuirass-configuration
  48   cuirass-configuration?
  49   (cuirass          cuirass-configuration-cuirass ;package
  50                     (default cuirass))
  51   (log-file         cuirass-configuration-log-file ;string
  52                     (default "/var/log/cuirass.log"))
  53   (cache-directory  cuirass-configuration-cache-directory ;string (dir-name)
  54                     (default "/var/cache/cuirass"))
  55   (user             cuirass-configuration-user ;string
  56                     (default "cuirass"))
  57   (group            cuirass-configuration-group ;string
  58                     (default "cuirass"))
  59   (interval         cuirass-configuration-interval ;integer (seconds)
  60                     (default 60))
  61   (database         cuirass-configuration-database ;string (file-name)
  62                     (default "/var/run/cuirass/cuirass.db"))
  63   (port             cuirass-configuration-port ;integer (port)
  64                     (default 8081))
  65   (host             cuirass-configuration-host ;string
  66                     (default "localhost"))
  67   (specifications   cuirass-configuration-specifications)
  68                                   ;gexp that evaluates to specification-alist
  69   (use-substitutes? cuirass-configuration-use-substitutes? ;boolean
  70                     (default #f))
  71   (one-shot?        cuirass-configuration-one-shot? ;boolean
  72                     (default #f))
  73   (fallback?        cuirass-configuration-fallback? ;boolean
  74                     (default #f))
  75   (load-path        cuirass-configuration-load-path
  76                     (default '())))
  77
  78 (define (cuirass-shepherd-service config)
  79   "Return a <shepherd-service> for the Cuirass service with CONFIG."
  80   (and
  81    (cuirass-configuration? config)
  82    (let ((cuirass          (cuirass-configuration-cuirass config))
  83          (cache-directory  (cuirass-configuration-cache-directory config))
  84          (log-file         (cuirass-configuration-log-file config))
  85          (user             (cuirass-configuration-user config))
  86          (group            (cuirass-configuration-group config))
  87          (interval         (cuirass-configuration-interval config))
  88          (database         (cuirass-configuration-database config))
  89          (port             (cuirass-configuration-port config))
  90          (host             (cuirass-configuration-host config))
  91          (specs            (cuirass-configuration-specifications config))
  92          (use-substitutes? (cuirass-configuration-use-substitutes? config))
  93          (one-shot?        (cuirass-configuration-one-shot? config))
  94          (fallback?        (cuirass-configuration-fallback? config))
  95          (load-path        (cuirass-configuration-load-path config)))
  96      (list (shepherd-service
  97             (documentation "Run Cuirass.")
  98             (provision '(cuirass))
  99             (requirement '(guix-daemon networking))
 100             (start #~(make-forkexec-constructor
 101                       (list (string-append #$cuirass "/bin/cuirass")
 102                             "--cache-directory" #$cache-directory
 103                             "--specifications"
 104                             #$(scheme-file "cuirass-specs.scm" specs)
 105                             "--database" #$database
 106                             "--port" #$(number->string port)
 107                             "--listen" #$host
 108                             "--interval" #$(number->string interval)
 109                             #$@(if use-substitutes? '("--use-substitutes") '())
 110                             #$@(if one-shot? '("--one-shot") '())
 111                             #$@(if fallback? '("--fallback") '())
 112                             #$@(if (null? load-path) '()
 113                                  `("--load-path" ,(string-join load-path ":"))))
 114
 115                       #:environment-variables
 116                       (list "GIT_SSL_CAINFO=/etc/ssl/certs/ca-certificates.crt"
 117                             (string-append "GIT_EXEC_PATH=" #$git
 118                                            "/libexec/git-core"))
 119
 120                       #:user #$user
 121                       #:group #$group
 122                       #:log-file #$log-file))
 123             (stop #~(make-kill-destructor)))))))
 124
 125 (define (cuirass-account config)
 126   "Return the user accounts and user groups for CONFIG."
 127   (let ((cuirass-user  (cuirass-configuration-user config))
 128         (cuirass-group (cuirass-configuration-group config)))
 129     (list (user-group
 130            (name cuirass-group)
 131            (system? #t))
 132           (user-account
 133            (name cuirass-user)
 134            (group cuirass-group)
 135            (system? #t)
 136            (comment "Cuirass privilege separation user")
 137            (home-directory (string-append "/var/run/" cuirass-user))
 138            (shell #~(string-append #$shadow "/sbin/nologin"))))))
 139
 140 (define (cuirass-activation config)
 141   "Return the activation code for CONFIG."
 142   (let ((cache (cuirass-configuration-cache-directory config))
 143         (db    (dirname (cuirass-configuration-database config)))
 144         (user  (cuirass-configuration-user config))
 145         (group (cuirass-configuration-group config)))
 146     (with-imported-modules '((guix build utils))
 147       #~(begin
 148           (use-modules (guix build utils))
 149
 150           (mkdir-p #$cache)
 151           (mkdir-p #$db)
 152
 153           (let ((uid (passwd:uid (getpw #$user)))
 154                 (gid (group:gid (getgr #$group))))
 155             (chown #$cache uid gid)
 156             (chown #$db uid gid))))))
 157
 158 (define (cuirass-log-rotations config)
 159   "Return the list of log rotations that corresponds to CONFIG."
 160   (list (log-rotation
 161          (files (list (cuirass-configuration-log-file config)))
 162          (frequency 'weekly)
 163          (options '("rotate 40")))))              ;worth keeping
 164
 165 (define cuirass-service-type
 166   (service-type
 167    (name 'cuirass)
 168    (extensions
 169     (list
 170      (service-extension profile-service-type      ;for 'info cuirass'
 171                         (compose list cuirass-configuration-cuirass))
 172      (service-extension rottlog-service-type cuirass-log-rotations)
 173      (service-extension activation-service-type cuirass-activation)
 174      (service-extension shepherd-root-service-type cuirass-shepherd-service)
 175      (service-extension account-service-type cuirass-account)))))
 176