configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.68)
   5 AC_INIT([GNU Guix],
   6   [m4_esyscmd([build-aux/git-version-gen .tarball-version])],
   7   [bug-guix@gnu.org], [guix],
   8   [https://www.gnu.org/software/guix/])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10
  11 AM_INIT_AUTOMAKE([1.14 gnu silent-rules subdir-objects \
  12  color-tests parallel-tests -Woverride -Wno-portability])
  13
  14 # Enable silent rules by default.
  15 AM_SILENT_RULES([yes])
  16
  17 AC_CONFIG_SRCDIR([guix.scm])
  18 AC_CONFIG_MACRO_DIR([m4])
  19
  20 dnl For the C++ code.  This must be used early.
  21 AC_USE_SYSTEM_EXTENSIONS
  22
  23 AM_GNU_GETTEXT([external])
  24 AM_GNU_GETTEXT_VERSION([0.18.1])
  25
  26 GUIX_SYSTEM_TYPE
  27 GUIX_ASSERT_SUPPORTED_SYSTEM
  28
  29 AC_ARG_WITH(store-dir,
  30   AC_HELP_STRING([--with-store-dir=PATH],
  31     [file name of the store (defaults to /gnu/store)]),
  32   [storedir="$withval"],
  33   [storedir="/gnu/store"])
  34 AC_SUBST(storedir)
  35
  36 AC_ARG_WITH([bash-completion-dir],
  37   AC_HELP_STRING([--with-bash-completion-dir=DIR],
  38     [name of the Bash completion directory]),
  39   [bashcompletiondir="$withval"],
  40   [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  41 AC_SUBST([bashcompletiondir])
  42
  43 AC_ARG_WITH([zsh-completion-dir],
  44   AC_HELP_STRING([--with-zsh-completion-dir=DIR],
  45     [name of the Zsh completion directory]),
  46   [zshcompletiondir="$withval"],
  47   [zshcompletiondir='${datadir}/zsh/site-functions'])
  48 AC_SUBST([zshcompletiondir])
  49
  50 AC_ARG_WITH([fish-completion-dir],
  51   AC_HELP_STRING([--with-fish-completion-dir=DIR],
  52     [name of the Fish completion directory]),
  53   [fishcompletiondir="$withval"],
  54   [fishcompletiondir='${datadir}/fish/vendor_completions.d'])
  55 AC_SUBST([fishcompletiondir])
  56
  57 AC_ARG_WITH([selinux-policy-dir],
  58   AC_HELP_STRING([--with-selinux-policy-dir=DIR],
  59     [name of the SELinux policy directory]),
  60   [selinux_policydir="$withval"],
  61   [selinux_policydir='${datadir}/selinux/'])
  62 AC_SUBST([selinux_policydir])
  63
  64 dnl Better be verbose.
  65 AC_MSG_CHECKING([for the store directory])
  66 AC_MSG_RESULT([$storedir])
  67
  68 AC_ARG_ENABLE([daemon],
  69   [AS_HELP_STRING([--disable-daemon], [do not build the Nix daemon (C++)])],
  70   [guix_build_daemon="$enableval"],
  71   [guix_build_daemon="yes"])
  72
  73 # Prepare a version of $localstatedir & co. that does not contain references
  74 # to shell variables.
  75 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  76 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  77 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  78 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  79 AC_SUBST([guix_localstatedir])
  80 AC_SUBST([guix_sysconfdir])
  81 AC_SUBST([guix_sbindir])
  82
  83 GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  84 AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  85
  86 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  87 dnl Make sure they are available.
  88 m4_pattern_forbid([PKG_CHECK_MODULES])
  89 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  90 m4_pattern_forbid([^GUILE_P$])
  91
  92 dnl Search for 'guile' and 'guild'.  This macro defines
  93 dnl 'GUILE_EFFECTIVE_VERSION'.
  94 GUILE_PKG([2.2 2.0])
  95 GUILE_PROGS
  96 if test "x$GUILD" = "x"; then
  97    AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
  98 fi
  99
 100 if test "x$GUILE_EFFECTIVE_VERSION" = "x2.0"; then
 101   PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.13])
 102 fi
 103
 104 dnl Installation directories for .scm and .go files.
 105 guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
 106 guileobjectdir="${libdir}/guile/$GUILE_EFFECTIVE_VERSION/site-ccache"
 107 AC_SUBST([guilemoduledir])
 108 AC_SUBST([guileobjectdir])
 109
 110 dnl The GnuTLS bindings are necessary for substitutes over HTTPS and for 'guix
 111 dnl pull', among other things.
 112 GUILE_MODULE_AVAILABLE([have_gnutls], [(gnutls)])
 113 if test "x$have_gnutls" != "xyes"; then
 114   AC_MSG_ERROR([The Guile bindings of GnuTLS are missing; please install them.])
 115 fi
 116
 117 dnl Check for Guile-Git.
 118 GUILE_MODULE_AVAILABLE([have_guile_git], [(git)])
 119 if test "x$have_guile_git" != "xyes"; then
 120   AC_MSG_ERROR([Guile-Git is missing; please install it.])
 121 fi
 122
 123 dnl Guile-JSON is used in various places.
 124 GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
 125 AM_CONDITIONAL([HAVE_GUILE_JSON], [test "x$have_guile_json" = "xyes"])
 126
 127 dnl Guile-Sqlite3 is used by the (guix store ...) modules.
 128 GUIX_CHECK_GUILE_SQLITE3
 129 AM_CONDITIONAL([HAVE_GUILE_SQLITE3],
 130   [test "x$guix_cv_have_recent_guile_sqlite3" = "xyes"])
 131
 132 dnl Make sure we have a full-fledged Guile.
 133 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
 134
 135 dnl Make sure we don't suffer from the bug in 'equal?' wrt. syntax objects
 136 dnl found in 2.2.1.  See <https://bugs.gnu.org/29903>.
 137 GUIX_ASSERT_SYNTAX_OBJECT_EQUAL
 138
 139 AC_PROG_SED
 140
 141 dnl Decompressors, for use by the substituter and other modules.
 142 AC_PATH_PROG([GZIP], [gzip])
 143 AC_PATH_PROG([BZIP2], [bzip2])
 144 AC_PATH_PROG([XZ], [xz])
 145 AC_SUBST([GZIP])
 146 AC_SUBST([BZIP2])
 147 AC_SUBST([XZ])
 148
 149 AC_ARG_WITH([nix-prefix],
 150   [AS_HELP_STRING([--with-nix-prefix=DIR],
 151     [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
 152   [case "$withval" in
 153     yes|no) ;;
 154     *)
 155       NIX_PREFIX="$withval"
 156       PATH="$NIX_PREFIX/bin:$PATH"; export PATH
 157       AC_SUBST([NIX_PREFIX])
 158       ;;
 159    esac],
 160   [])
 161
 162 AC_PATH_PROG([NIX_INSTANTIATE], [nix-instantiate])
 163 AC_PATH_PROG([NIX_HASH], [nix-hash])
 164 if test "x$guix_build_daemon$NIX_INSTANTIATE$NIX_HASH" = "xno"; then
 165    AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
 166 fi
 167
 168 if test "x$NIX_INSTANTIATE" = "x"; then
 169    # This program is an optional dependency, so we just want it to be
 170    # taken from $PATH if it's not available right now.
 171    NIX_INSTANTIATE="nix-instantiate"
 172 fi
 173
 174 AC_ARG_WITH([nixpkgs],
 175   [AS_HELP_STRING([--with-nixpkgs=DIR],
 176     [search for Nixpkgs in DIR (for testing purposes only)])],
 177   [case "$withval" in
 178     yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
 179     *)      NIXPKGS="$withval";;
 180    esac],
 181   [])
 182
 183 AC_MSG_CHECKING([for Nixpkgs source tree])
 184 if test -f "$NIXPKGS/default.nix"; then
 185    AC_MSG_RESULT([$NIXPKGS])
 186    AC_SUBST([NIXPKGS])
 187 else
 188    AC_MSG_RESULT([not found])
 189 fi
 190
 191 LIBGCRYPT="libgcrypt"
 192 LIBGCRYPT_LIBDIR="no"
 193 LIBGCRYPT_PREFIX="no"
 194
 195 AC_ARG_WITH([libgcrypt-prefix],
 196   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 197   [case "$withval" in
 198     yes|no)
 199       ;;
 200     *)
 201       LIBGCRYPT="$withval/lib/libgcrypt"
 202       LIBGCRYPT_PREFIX="$withval"
 203       LIBGCRYPT_LIBDIR="$withval/lib"
 204       ;;
 205    esac])
 206
 207 AC_ARG_WITH([libgcrypt-libdir],
 208   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 209      [search for GNU libgcrypt's shared library in DIR])],
 210   [case "$withval" in
 211     yes|no)
 212       LIBGCRYPT="libgcrypt"
 213       LIBGCRYPT_LIBDIR="no"
 214       ;;
 215     *)
 216       LIBGCRYPT="$withval/libgcrypt"
 217       LIBGCRYPT_LIBDIR="$withval"
 218       ;;
 219    esac])
 220
 221 dnl If none of the --with-libgcrypt-* options was used, try to determine the
 222 dnl absolute file name of libgcrypt.so.
 223 case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
 224   xnono)
 225     GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
 226     if test "x$LIBGCRYPT_LIBDIR" != x; then
 227       LIBGCRYPT="$LIBGCRYPT_LIBDIR/libgcrypt"
 228     else
 229       dnl 'config-daemon.ac' expects "no" in this case.
 230       LIBGCRYPT_LIBDIR="no"
 231     fi
 232     ;;
 233 esac
 234
 235 dnl Library name suitable for `dynamic-link'.
 236 AC_MSG_CHECKING([for libgcrypt shared library name])
 237 AC_MSG_RESULT([$LIBGCRYPT])
 238 AC_SUBST([LIBGCRYPT])
 239 AC_SUBST([LIBGCRYPT_PREFIX])
 240 AC_SUBST([LIBGCRYPT_LIBDIR])
 241
 242 GUIX_ASSERT_LIBGCRYPT_USABLE
 243
 244 dnl Library name of zlib suitable for 'dynamic-link'.
 245 GUIX_LIBZ_LIBDIR([libz_libdir])
 246 if test "x$libz_libdir" = "x"; then
 247   LIBZ="libz"
 248 else
 249   LIBZ="$libz_libdir/libz"
 250 fi
 251 AC_MSG_CHECKING([for zlib's shared library name])
 252 AC_MSG_RESULT([$LIBZ])
 253 AC_SUBST([LIBZ])
 254
 255 dnl Check for Guile-SSH, for the (guix ssh) module.
 256 GUIX_CHECK_GUILE_SSH
 257 AM_CONDITIONAL([HAVE_GUILE_SSH],
 258   [test "x$guix_cv_have_recent_guile_ssh" = "xyes"])
 259
 260 AC_CACHE_SAVE
 261
 262 m4_include([config-daemon.ac])
 263
 264 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 265 dnl See `Building from Git' in the manual for more info.
 266 AM_MISSING_PROG([DOT], [dot])
 267
 268 dnl Manual pages.
 269 AM_MISSING_PROG([HELP2MAN], [help2man])
 270
 271 dnl Documentation translation.
 272 AM_MISSING_PROG([PO4A_TRANSLATE], [po4a-translate])
 273 AM_MISSING_PROG([PO4A_UPDATEPO], [po4a-updatepo])
 274
 275 dnl Emacs (optional), for 'etc/indent-package.el'.
 276 AC_PATH_PROG([EMACS], [emacs], [/usr/bin/emacs])
 277 AC_SUBST([EMACS])
 278
 279 case "$storedir" in
 280   /gnu/store)
 281     ;;
 282   *)
 283     AC_MSG_WARN([Using a store directory other than '/gnu/store' will prevent you])
 284     AC_MSG_WARN([from downloading substitutes from gnu.org.])
 285     ;;
 286 esac
 287
 288 AC_CONFIG_FILES([Makefile
 289                  po/guix/Makefile.in
 290                  po/packages/Makefile.in
 291                  etc/guix-daemon.cil
 292                  guix/config.scm])
 293
 294 AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
 295 AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
 296   [chmod +x pre-inst-env])
 297 AC_CONFIG_FILES([etc/indent-code.el], [chmod +x etc/indent-code.el])
 298
 299 AC_OUTPUT