guix/build/linux-initrd.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013, 2014 Ludovic Courtès <ludo@gnu.org>
   3 ;;;
   4 ;;; This file is part of GNU Guix.
   5 ;;;
   6 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU General Public License as published by
   8 ;;; the Free Software Foundation; either version 3 of the License, or (at
   9 ;;; your option) any later version.
  10 ;;;
  11 ;;; GNU Guix is distributed in the hope that it will be useful, but
  12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;; GNU General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU General Public License
  17 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 (define-module (guix build linux-initrd)
  20   #:use-module (rnrs io ports)
  21   #:use-module (system foreign)
  22   #:autoload   (system repl repl) (start-repl)
  23   #:autoload   (system base compile) (compile-file)
  24   #:use-module (srfi srfi-1)
  25   #:use-module (srfi srfi-26)
  26   #:use-module (ice-9 match)
  27   #:use-module (ice-9 ftw)
  28   #:use-module (guix build utils)
  29   #:export (mount-essential-file-systems
  30             linux-command-line
  31             make-essential-device-nodes
  32             configure-qemu-networking
  33             mount-qemu-smb-share
  34             mount-qemu-9p
  35             bind-mount
  36             load-linux-module*
  37             device-number
  38             boot-system))
  39
  40 ;;; Commentary:
  41 ;;;
  42 ;;; Utility procedures useful in a Linux initial RAM disk (initrd).  Note that
  43 ;;; many of these use procedures not yet available in vanilla Guile (`mount',
  44 ;;; `load-linux-module', etc.); these are provided by a Guile patch used in
  45 ;;; the GNU distribution.
  46 ;;;
  47 ;;; Code:
  48
  49 (define* (mount-essential-file-systems #:key (root "/"))
  50   "Mount /proc and /sys under ROOT."
  51   (define (scope dir)
  52     (string-append root
  53                    (if (string-suffix? "/" root)
  54                        ""
  55                        "/")
  56                    dir))
  57
  58   (unless (file-exists? (scope "proc"))
  59     (mkdir (scope "proc")))
  60   (mount "none" (scope "proc") "proc")
  61
  62   (unless (file-exists? (scope "sys"))
  63     (mkdir (scope "sys")))
  64   (mount "none" (scope "sys") "sysfs"))
  65
  66 (define (linux-command-line)
  67   "Return the Linux kernel command line as a list of strings."
  68   (string-tokenize
  69    (call-with-input-file "/proc/cmdline"
  70      get-string-all)))
  71
  72 (define* (make-essential-device-nodes #:key (root "/"))
  73   "Make essential device nodes under ROOT/dev."
  74   ;; The hand-made udev!
  75
  76   (define (scope dir)
  77     (string-append root
  78                    (if (string-suffix? "/" root)
  79                        ""
  80                        "/")
  81                    dir))
  82
  83   (unless (file-exists? (scope "dev"))
  84     (mkdir (scope "dev")))
  85
  86   ;; Make the device nodes for SCSI disks.
  87   (mknod (scope "dev/sda") 'block-special #o644 (device-number 8 0))
  88   (mknod (scope "dev/sda1") 'block-special #o644 (device-number 8 1))
  89   (mknod (scope "dev/sda2") 'block-special #o644 (device-number 8 2))
  90
  91   ;; The virtio (para-virtualized) block devices, as supported by QEMU/KVM.
  92   (mknod (scope "dev/vda") 'block-special #o644 (device-number 252 0))
  93   (mknod (scope "dev/vda1") 'block-special #o644 (device-number 252 1))
  94   (mknod (scope "dev/vda2") 'block-special #o644 (device-number 252 2))
  95
  96   ;; Memory (used by Xorg's VESA driver.)
  97   (mknod (scope "dev/mem") 'char-special #o640 (device-number 1 1))
  98   (mknod (scope "dev/kmem") 'char-special #o640 (device-number 1 2))
  99
 100   ;; Inputs (used by Xorg.)
 101   (unless (file-exists? (scope "dev/input"))
 102     (mkdir (scope "dev/input")))
 103   (mknod (scope "dev/input/mice") 'char-special #o640 (device-number 13 63))
 104   (mknod (scope "dev/input/mouse0") 'char-special #o640 (device-number 13 32))
 105   (mknod (scope "dev/input/event0") 'char-special #o640 (device-number 13 64))
 106
 107   ;; TTYs.
 108   (mknod (scope "dev/tty") 'char-special #o600
 109          (device-number 5 0))
 110   (let loop ((n 0))
 111     (and (< n 50)
 112          (let ((name (format #f "dev/tty~a" n)))
 113            (mknod (scope name) 'char-special #o600
 114                   (device-number 4 n))
 115            (loop (+ 1 n)))))
 116
 117   ;; Rendez-vous point for syslogd.
 118   (mknod (scope "dev/log") 'socket #o666 0)
 119   (mknod (scope "dev/kmsg") 'char-special #o600 (device-number 1 11))
 120
 121   ;; Other useful nodes.
 122   (mknod (scope "dev/null") 'char-special #o666 (device-number 1 3))
 123   (mknod (scope "dev/zero") 'char-special #o666 (device-number 1 5))
 124   (chmod (scope "dev/null") #o666)
 125   (chmod (scope "dev/zero") #o666))
 126
 127 (define %host-qemu-ipv4-address
 128   (inet-pton AF_INET "10.0.2.10"))
 129
 130 (define* (configure-qemu-networking #:optional (interface "eth0"))
 131   "Setup the INTERFACE network interface and /etc/resolv.conf according to
 132 QEMU's default networking settings (see net/slirp.c in QEMU for default
 133 networking values.)  Return #t if INTERFACE is up, #f otherwise."
 134   (display "configuring QEMU networking...\n")
 135   (let* ((sock    (socket AF_INET SOCK_STREAM 0))
 136          (address (make-socket-address AF_INET %host-qemu-ipv4-address 0))
 137          (flags   (network-interface-flags sock interface)))
 138     (set-network-interface-address sock interface address)
 139     (set-network-interface-flags sock interface (logior flags IFF_UP))
 140
 141     (unless (file-exists? "/etc")
 142       (mkdir "/etc"))
 143     (call-with-output-file "/etc/resolv.conf"
 144       (lambda (p)
 145         (display "nameserver 10.0.2.3\n" p)))
 146
 147     (logand (network-interface-flags sock interface) IFF_UP)))
 148
 149 (define (mount-qemu-smb-share share mount-point)
 150   "Mount QEMU's CIFS/SMB SHARE at MOUNT-POINT.
 151
 152 Vanilla QEMU's `-smb' option just exports a /qemu share, whereas our
 153 `qemu-with-multiple-smb-shares' package exports the /xchg and /store shares
 154  (the latter allows the store to be shared between the host and guest.)"
 155
 156   (format #t "mounting QEMU's SMB share `~a'...\n" share)
 157   (let ((server "10.0.2.4"))
 158     (mount (string-append "//" server share) mount-point "cifs" 0
 159            (string->pointer "guest,sec=none"))))
 160
 161 (define (mount-qemu-9p source mount-point)
 162   "Mount QEMU's 9p file system from SOURCE at MOUNT-POINT.
 163
 164 This uses the 'virtio' transport, which requires the various virtio Linux
 165 modules to be loaded."
 166
 167   (format #t "mounting QEMU's 9p share '~a'...\n" source)
 168   (let ((server "10.0.2.4"))
 169     (mount source mount-point "9p" 0
 170            (string->pointer "trans=virtio"))))
 171
 172 (define (bind-mount source target)
 173   "Bind-mount SOURCE at TARGET."
 174   (define MS_BIND 4096)                           ; from libc's <sys/mount.h>
 175
 176   (mount source target "" MS_BIND))
 177
 178 (define (load-linux-module* file)
 179   "Load Linux module from FILE, the name of a `.ko' file."
 180   (define (slurp module)
 181     (call-with-input-file file get-bytevector-all))
 182
 183   (load-linux-module (slurp file)))
 184
 185 (define (device-number major minor)
 186   "Return the device number for the device with MAJOR and MINOR, for use as
 187 the last argument of `mknod'."
 188   (+ (* major 256) minor))
 189
 190 (define* (boot-system #:key
 191                       (linux-modules '())
 192                       qemu-guest-networking?
 193                       guile-modules-in-chroot?
 194                       volatile-root?
 195                       (mounts '()))
 196   "This procedure is meant to be called from an initrd.  Boot a system by
 197 first loading LINUX-MODULES, then setting up QEMU guest networking if
 198 QEMU-GUEST-NETWORKING? is true, mounting the file systems specified in MOUNTS,
 199 and finally booting into the new root if any.  The initrd supports kernel
 200 command-line options '--load', '--root', and '--repl'.
 201
 202 MOUNTS must be a list of elements of the form:
 203
 204   (FILE-SYSTEM-TYPE SOURCE TARGET)
 205
 206 When GUILE-MODULES-IN-CHROOT? is true, make core Guile modules available in
 207 the new root.
 208
 209 When VOLATILE-ROOT? is true, the root file system is writable but any changes
 210 to it are lost."
 211   (define (resolve file)
 212     ;; If FILE is a symlink to an absolute file name, resolve it as if we were
 213     ;; under /root.
 214     (let ((st (lstat file)))
 215       (if (eq? 'symlink (stat:type st))
 216           (let ((target (readlink file)))
 217             (resolve (string-append "/root" target)))
 218           file)))
 219
 220   (define MS_RDONLY 1)
 221
 222   (display "Welcome, this is GNU's early boot Guile.\n")
 223   (display "Use '--repl' for an initrd REPL.\n\n")
 224
 225   (mount-essential-file-systems)
 226   (let* ((args    (linux-command-line))
 227          (option  (lambda (opt)
 228                     (let ((opt (string-append opt "=")))
 229                       (and=> (find (cut string-prefix? opt <>)
 230                                    args)
 231                              (lambda (arg)
 232                                (substring arg (+ 1 (string-index arg #\=))))))))
 233          (to-load (option "--load"))
 234          (root    (option "--root")))
 235
 236     (when (member "--repl" args)
 237       (start-repl))
 238
 239     (display "loading kernel modules...\n")
 240     (for-each (compose load-linux-module*
 241                        (cut string-append "/modules/" <>))
 242               linux-modules)
 243
 244     (when qemu-guest-networking?
 245       (unless (configure-qemu-networking)
 246         (display "network interface is DOWN\n")))
 247
 248     ;; Make /dev nodes.
 249     (make-essential-device-nodes)
 250
 251     ;; Prepare the real root file system under /root.
 252     (unless (file-exists? "/root")
 253       (mkdir "/root"))
 254     (if root
 255         (catch #t
 256           (lambda ()
 257             (if volatile-root?
 258                 (begin
 259                   ;; XXX: For lack of a union file system...
 260                   (mkdir-p "/real-root")
 261                   (mount root "/real-root" "ext3" MS_RDONLY)
 262                   (mount "none" "/root" "tmpfs")
 263
 264                   ;; XXX: 'copy-recursively' cannot deal with device nodes, so
 265                   ;; explicitly avoid /dev.
 266                   (for-each (lambda (file)
 267                               (unless (string=? "dev" file)
 268                                 (copy-recursively (string-append "/real-root/"
 269                                                                  file)
 270                                                   (string-append "/root/"
 271                                                                  file)
 272                                                   #:log (%make-void-port
 273                                                          "w"))))
 274                             (scandir "/real-root"
 275                                      (lambda (file)
 276                                        (not (member file '("." ".."))))))
 277
 278                   ;; TODO: Unmount /real-root.
 279                   )
 280                 (mount root "/root" "ext3")))
 281           (lambda args
 282             (format (current-error-port) "exception while mounting '~a': ~s~%"
 283                     root args)
 284             (start-repl)))
 285         (mount "none" "/root" "tmpfs"))
 286
 287     (mount-essential-file-systems #:root "/root")
 288
 289     (unless (file-exists? "/root/dev")
 290       (mkdir "/root/dev")
 291       (make-essential-device-nodes #:root "/root"))
 292
 293     ;; Mount the specified file systems.
 294     (for-each (match-lambda
 295                (('cifs source target)
 296                 (let ((target (string-append "/root/" target)))
 297                   (mkdir-p target)
 298                   (mount-qemu-smb-share source target)))
 299                (('9p source target)
 300                 (let ((target (string-append "/root/" target)))
 301                   (mkdir-p target)
 302                   (mount-qemu-9p source target))))
 303               mounts)
 304
 305     (when guile-modules-in-chroot?
 306       ;; Copy the directories that contain .scm and .go files so that the
 307       ;; child process in the chroot can load modules (we would bind-mount
 308       ;; them but for some reason that fails with EINVAL -- XXX).
 309       (mkdir-p "/root/share")
 310       (mkdir-p "/root/lib")
 311       (mount "none" "/root/share" "tmpfs")
 312       (mount "none" "/root/lib" "tmpfs")
 313       (copy-recursively "/share" "/root/share"
 314                         #:log (%make-void-port "w"))
 315       (copy-recursively "/lib" "/root/lib"
 316                         #:log (%make-void-port "w")))
 317
 318     (if to-load
 319         (begin
 320           (format #t "loading '~a'...\n" to-load)
 321           (chdir "/root")
 322           (chroot "/root")
 323           ;; TODO: Remove /lib, /share, and /loader.go.
 324           (catch #t
 325             (lambda ()
 326               (primitive-load to-load))
 327             (lambda args
 328               (format (current-error-port) "'~a' raised an exception: ~s~%"
 329                       to-load args)
 330               (start-repl)))
 331           (format (current-error-port)
 332                   "boot program '~a' terminated, rebooting~%"
 333                   to-load)
 334           (sleep 2)
 335           (reboot))
 336         (begin
 337           (display "no boot file passed via '--load'\n")
 338           (display "entering a warm and cozy REPL\n")
 339           (start-repl)))))
 340
 341 ;;; linux-initrd.scm ends here