configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.68)
   5 AC_INIT([GNU Guix], [0.8.2], [bug-guix@gnu.org], [guix],
   6   [http://www.gnu.org/software/guix/])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AM_INIT_AUTOMAKE([1.12 gnu silent-rules subdir-objects \
  10  color-tests parallel-tests -Woverride])
  11
  12 AC_CONFIG_SRCDIR([guix.scm])
  13 AC_CONFIG_MACRO_DIR([m4])
  14
  15 dnl For the C++ code.  This must be used early.
  16 AC_USE_SYSTEM_EXTENSIONS
  17
  18 AM_GNU_GETTEXT([external])
  19 AM_GNU_GETTEXT_VERSION([0.18.1])
  20
  21 guilemoduledir="${datarootdir}/guile/site/2.0"
  22 AC_SUBST([guilemoduledir])
  23
  24 GUIX_SYSTEM_TYPE
  25 GUIX_ASSERT_SUPPORTED_SYSTEM
  26
  27 AC_ARG_WITH(store-dir,
  28   AC_HELP_STRING([--with-store-dir=PATH],
  29     [file name of the store (defaults to /gnu/store)]),
  30   [storedir="$withval"],
  31   [storedir="/gnu/store"])
  32 AC_SUBST(storedir)
  33
  34 dnl Better be verbose.
  35 AC_MSG_CHECKING([for the store directory])
  36 AC_MSG_RESULT([$storedir])
  37
  38 AC_ARG_ENABLE([daemon],
  39   [AS_HELP_STRING([--disable-daemon], [build the Nix daemon (C++)])],
  40   [guix_build_daemon="$enableval"],
  41   [guix_build_daemon="yes"])
  42
  43 # Prepare a version of $localstatedir & co. that does not contain references
  44 # to shell variables.
  45 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  46 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  47 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  48 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  49 AC_SUBST([guix_localstatedir])
  50 AC_SUBST([guix_sysconfdir])
  51 AC_SUBST([guix_sbindir])
  52
  53 GUIX_CHECK_FILE_NAME_LIMITS
  54
  55 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  56 dnl Make sure they are available.
  57 m4_pattern_forbid([PKG_CHECK_MODULES])
  58 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  59
  60 PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.5])
  61 AC_PATH_PROG([GUILE], [guile])
  62 AC_PATH_PROG([GUILD], [guild])
  63 if test "x$GUILD" = "x"; then
  64    AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
  65 fi
  66
  67 dnl guile-json is used for the PyPI package importer
  68 GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
  69 AM_CONDITIONAL([HAVE_GUILE_JSON], [test "x$have_guile_json" = "xyes"])
  70
  71 dnl Make sure we have a full-fledged Guile.
  72 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
  73
  74 dnl Check whether (srfi srfi-37) works, and provide our own if it doesn't.
  75 GUIX_CHECK_SRFI_37
  76 AM_CONDITIONAL([INSTALL_SRFI_37], [test "x$ac_cv_guix_srfi_37_broken" = xyes])
  77
  78 AC_ARG_WITH([nix-prefix],
  79   [AS_HELP_STRING([--with-nix-prefix=DIR],
  80     [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
  81   [case "$withval" in
  82     yes|no) ;;
  83     *)
  84       NIX_PREFIX="$withval"
  85       PATH="$NIX_PREFIX/bin:$PATH"; export PATH
  86       AC_SUBST([NIX_PREFIX])
  87       ;;
  88    esac],
  89   [])
  90
  91 AC_PATH_PROG([NIX_INSTANTIATE], [nix-instantiate])
  92 AC_PATH_PROG([NIX_HASH], [nix-hash])
  93 if test "x$guix_build_daemon$NIX_INSTANTIATE$NIX_HASH" = "xno"; then
  94    AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
  95 fi
  96
  97 if test "x$NIX_INSTANTIATE" = "x"; then
  98    # This program is an optional dependency, so we just want it to be
  99    # taken from $PATH if it's not available right now.
 100    NIX_INSTANTIATE="nix-instantiate"
 101 fi
 102
 103 AC_ARG_WITH([nixpkgs],
 104   [AS_HELP_STRING([--with-nixpkgs=DIR],
 105     [search for Nixpkgs in DIR (for testing purposes only)])],
 106   [case "$withval" in
 107     yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
 108     *)      NIXPKGS="$withval";;
 109    esac],
 110   [])
 111
 112 AC_MSG_CHECKING([for Nixpkgs source tree])
 113 if test -f "$NIXPKGS/default.nix"; then
 114    AC_MSG_RESULT([$NIXPKGS])
 115    AC_SUBST([NIXPKGS])
 116 else
 117    AC_MSG_RESULT([not found])
 118 fi
 119
 120 AC_ARG_WITH([libgcrypt-prefix],
 121   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 122   [case "$withval" in
 123     yes|no)
 124       LIBGCRYPT="libgcrypt"
 125       LIBGCRYPT_PREFIX="no"
 126       LIBGCRYPT_LIBDIR="no"
 127       ;;
 128     *)
 129       LIBGCRYPT="$withval/lib/libgcrypt"
 130       LIBGCRYPT_PREFIX="$withval"
 131       LIBGCRYPT_LIBDIR="$withval/lib"
 132       ;;
 133    esac],
 134   [LIBGCRYPT="libgcrypt"
 135    LIBGCRYPT_PREFIX="no"
 136    LIBGCRYPT_LIBDIR="no"])
 137
 138 AC_ARG_WITH([libgcrypt-libdir],
 139   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 140      [search for GNU libgcrypt's shared library in DIR])],
 141   [case "$withval" in
 142     yes|no)
 143       LIBGCRYPT="libgcrypt"
 144       LIBGCRYPT_LIBDIR="no"
 145       ;;
 146     *)
 147       LIBGCRYPT="$withval/libgcrypt"
 148       LIBGCRYPT_LIBDIR="$withval"
 149       ;;
 150    esac],
 151   [if test "x$LIBGCRYPT" = x; then
 152       LIBGCRYPT="libgcrypt"
 153    fi
 154    if test "x$LIBGCRYPT_LIBDIR" = x; then
 155       LIBGCRYPT_LIBDIR="no"
 156    fi])
 157
 158 dnl Library name suitable for `dynamic-link'.
 159 AC_MSG_CHECKING([for libgcrypt shared library name])
 160 AC_MSG_RESULT([$LIBGCRYPT])
 161 AC_SUBST([LIBGCRYPT])
 162 AC_SUBST([LIBGCRYPT_PREFIX])
 163 AC_SUBST([LIBGCRYPT_LIBDIR])
 164
 165 GUIX_ASSERT_LIBGCRYPT_USABLE
 166
 167 AC_CACHE_SAVE
 168
 169 m4_include([config-daemon.ac])
 170
 171 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 172 dnl See `HACKING' for more info.
 173 AM_MISSING_PROG([DOT], [dot])
 174
 175 AC_CONFIG_FILES([Makefile
 176                  po/guix/Makefile.in
 177                  po/packages/Makefile.in
 178                  guix/config.scm])
 179
 180 AC_CONFIG_FILES([scripts/guix], [chmod +x scripts/guix])
 181 AC_CONFIG_FILES([pre-inst-env], [chmod +x pre-inst-env])
 182 AC_CONFIG_FILES([test-env],     [chmod +x test-env])
 183
 184 dnl Emacs interface.
 185 AM_PATH_LISPDIR
 186 AM_CONDITIONAL([HAVE_EMACS], [test "x$EMACS" != "xno"])
 187
 188 emacsuidir="${guilemoduledir}/guix/emacs"
 189 AC_SUBST([emacsuidir])
 190 AC_CONFIG_FILES([emacs/guix-init.el
 191                  emacs/guix-profiles.el
 192                  emacs/guix-helper.scm])
 193
 194 AC_OUTPUT