gnu/system/shadow.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013, 2014, 2015, 2016, 2017 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2016 Alex Griffin <a@ajgrf.com>
   4 ;;;
   5 ;;; This file is part of GNU Guix.
   6 ;;;
   7 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   8 ;;; under the terms of the GNU General Public License as published by
   9 ;;; the Free Software Foundation; either version 3 of the License, or (at
  10 ;;; your option) any later version.
  11 ;;;
  12 ;;; GNU Guix is distributed in the hope that it will be useful, but
  13 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;;; GNU General Public License for more details.
  16 ;;;
  17 ;;; You should have received a copy of the GNU General Public License
  18 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 (define-module (gnu system shadow)
  21   #:use-module (guix records)
  22   #:use-module (guix gexp)
  23   #:use-module (guix store)
  24   #:use-module (guix modules)
  25   #:use-module (guix sets)
  26   #:use-module (guix ui)
  27   #:use-module (gnu services)
  28   #:use-module (gnu services shepherd)
  29   #:use-module ((gnu system file-systems)
  30                 #:select (%tty-gid))
  31   #:use-module ((gnu packages admin)
  32                 #:select (shadow))
  33   #:use-module (gnu packages bash)
  34   #:use-module (gnu packages guile-wm)
  35   #:use-module (srfi srfi-1)
  36   #:use-module (srfi srfi-26)
  37   #:use-module (srfi srfi-34)
  38   #:use-module (srfi srfi-35)
  39   #:export (user-account
  40             user-account?
  41             user-account-name
  42             user-account-password
  43             user-account-uid
  44             user-account-group
  45             user-account-supplementary-groups
  46             user-account-comment
  47             user-account-home-directory
  48             user-account-create-home-directory?
  49             user-account-shell
  50             user-account-system?
  51
  52             user-group
  53             user-group?
  54             user-group-name
  55             user-group-password
  56             user-group-id
  57             user-group-system?
  58
  59             default-skeletons
  60             skeleton-directory
  61             %base-groups
  62             %base-user-accounts
  63
  64             account-service-type
  65             account-service))
  66
  67 ;;; Commentary:
  68 ;;;
  69 ;;; Utilities for configuring the Shadow tool suite ('login', 'passwd', etc.)
  70 ;;;
  71 ;;; Code:
  72
  73 (define-record-type* <user-account>
  74   user-account make-user-account
  75   user-account?
  76   (name           user-account-name)
  77   (password       user-account-password (default #f))
  78   (uid            user-account-uid (default #f))
  79   (group          user-account-group)             ; number | string
  80   (supplementary-groups user-account-supplementary-groups
  81                         (default '()))            ; list of strings
  82   (comment        user-account-comment (default ""))
  83   (home-directory user-account-home-directory)
  84   (create-home-directory? user-account-create-home-directory? ;Boolean
  85                           (default #t))
  86   (shell          user-account-shell              ; gexp
  87                   (default (file-append bash "/bin/bash")))
  88   (system?        user-account-system?            ; Boolean
  89                   (default #f)))
  90
  91 (define-record-type* <user-group>
  92   user-group make-user-group
  93   user-group?
  94   (name           user-group-name)
  95   (password       user-group-password (default #f))
  96   (id             user-group-id (default #f))
  97   (system?        user-group-system?              ; Boolean
  98                   (default #f)))
  99
 100
 101 (define %base-groups
 102   ;; Default set of groups.
 103   (let-syntax ((system-group (syntax-rules ()
 104                                ((_ args ...)
 105                                 (user-group (system? #t) args ...)))))
 106     (list (system-group (name "root") (id 0))
 107           (system-group (name "wheel"))           ; root-like users
 108           (system-group (name "users"))           ; normal users
 109           (system-group (name "nogroup"))         ; for daemons etc.
 110
 111           ;; The following groups are conventionally used by things like udev to
 112           ;; control access to hardware devices.
 113           (system-group (name "tty") (id %tty-gid))
 114           (system-group (name "dialout"))
 115           (system-group (name "kmem"))
 116           (system-group (name "input"))           ; input devices, from udev
 117           (system-group (name "video"))
 118           (system-group (name "audio"))
 119           (system-group (name "netdev"))          ; used in avahi-dbus.conf
 120           (system-group (name "lp"))
 121           (system-group (name "disk"))
 122           (system-group (name "floppy"))
 123           (system-group (name "cdrom"))
 124           (system-group (name "tape"))
 125           (system-group (name "kvm")))))          ; for /dev/kvm
 126
 127 (define %base-user-accounts
 128   ;; List of standard user accounts.  Note that "root" is a special case, so
 129   ;; it's not listed here.
 130   (list (user-account
 131          (name "nobody")
 132          (uid 65534)
 133          (group "nogroup")
 134          (shell (file-append shadow "/sbin/nologin"))
 135          (home-directory "/nonexistent")
 136          (create-home-directory? #f)
 137          (system? #t))))
 138
 139 (define (default-skeletons)
 140   "Return the default skeleton files for /etc/skel.  These files are copied by
 141 'useradd' in the home directory of newly created user accounts."
 142   (define copy-guile-wm
 143     (with-imported-modules '((guix build utils))
 144       #~(begin
 145           (use-modules (guix build utils))
 146           (copy-file (car (find-files #+guile-wm "wm-init-sample.scm"))
 147                      #$output))))
 148
 149   (let ((profile (plain-file "bash_profile" "\
 150 # Honor per-interactive-shell startup file
 151 if [ -f ~/.bashrc ]; then . ~/.bashrc; fi\n"))
 152         (bashrc  (plain-file "bashrc" "\
 153 # Bash initialization for interactive non-login shells and
 154 # for remote shells (info \"(bash) Bash Startup Files\").
 155
 156 # Export 'SHELL' to child processes.  Programs such as 'screen'
 157 # honor it and otherwise use /bin/sh.
 158 export SHELL
 159
 160 if [[ $- != *i* ]]
 161 then
 162     # We are being invoked from a non-interactive shell.  If this
 163     # is an SSH session (as in \"ssh host command\"), source
 164     # /etc/profile so we get PATH and other essential variables.
 165     [[ -n \"$SSH_CLIENT\" ]] && source /etc/profile
 166
 167     # Don't do anything else.
 168     return
 169 fi
 170
 171 # Adjust the prompt depending on whether we're in 'guix environment'.
 172 if [ -n \"$GUIX_ENVIRONMENT\" ]
 173 then
 174     PS1='\\u@\\h \\w [env]\\$ '
 175 else
 176     PS1='\\u@\\h \\w\\$ '
 177 fi
 178 alias ls='ls -p --color'
 179 alias ll='ls -l'
 180 alias grep='grep --color'\n"))
 181         (zlogin    (plain-file "zlogin" "\
 182 # Honor system-wide environment variables
 183 source /etc/profile\n"))
 184         (guile-wm  (computed-file "guile-wm" copy-guile-wm))
 185         (xdefaults (plain-file "Xdefaults" "\
 186 XTerm*utf8: always
 187 XTerm*metaSendsEscape: true\n"))
 188         (gdbinit   (plain-file "gdbinit" "\
 189 # Tell GDB where to look for separate debugging files.
 190 set debug-file-directory ~/.guix-profile/lib/debug\n")))
 191     `((".bash_profile" ,profile)
 192       (".bashrc" ,bashrc)
 193       (".zlogin" ,zlogin)
 194       (".Xdefaults" ,xdefaults)
 195       (".guile" ,(plain-file "dot-guile"
 196                              "(cond ((false-if-exception (resolve-interface '(ice-9 readline)))
 197        =>
 198        (lambda (module)
 199          ;; Enable completion and input history at the REPL.
 200          ((module-ref module 'activate-readline))))
 201       (else
 202        (display \"Consider installing the 'guile-readline' package for
 203 convenient interactive line editing and input history.\\n\\n\")))\n"))
 204       (".guile-wm" ,guile-wm)
 205       (".gdbinit" ,gdbinit))))
 206
 207 (define (skeleton-directory skeletons)
 208   "Return a directory containing SKELETONS, a list of name/derivation tuples."
 209   (computed-file "skel"
 210                  (with-imported-modules '((guix build utils))
 211                    #~(begin
 212                        (use-modules (ice-9 match)
 213                                     (guix build utils))
 214
 215                        (mkdir #$output)
 216                        (chdir #$output)
 217
 218                        ;; Note: copy the skeletons instead of symlinking
 219                        ;; them like 'file-union' does, because 'useradd'
 220                        ;; would just copy the symlinks as is.
 221                        (for-each (match-lambda
 222                                    ((target source)
 223                                     (copy-recursively source target)))
 224                                  '#$skeletons)
 225                        #t))))
 226
 227 (define (assert-valid-users/groups users groups)
 228   "Raise an error if USERS refer to groups not listed in GROUPS."
 229   (let ((groups (list->set (map user-group-name groups))))
 230     (define (validate-supplementary-group user group)
 231       (unless (set-contains? groups group)
 232         (raise (condition
 233                 (&message
 234                  (message
 235                   (format #f (G_ "supplementary group '~a' \
 236 of user '~a' is undeclared")
 237                           group
 238                           (user-account-name user))))))))
 239
 240     (for-each (lambda (user)
 241                 (unless (set-contains? groups (user-account-group user))
 242                   (raise (condition
 243                           (&message
 244                            (message
 245                             (format #f (G_ "primary group '~a' \
 246 of user '~a' is undeclared")
 247                                     (user-account-group user)
 248                                     (user-account-name user)))))))
 249
 250                 (for-each (cut validate-supplementary-group user <>)
 251                           (user-account-supplementary-groups user)))
 252               users)))
 253
 254 \f
 255 ;;;
 256 ;;; Service.
 257 ;;;
 258
 259 (define (user-group->gexp group)
 260   "Turn GROUP, a <user-group> object, into a list-valued gexp suitable for
 261 'active-groups'."
 262   #~(list #$(user-group-name group)
 263           #$(user-group-password group)
 264           #$(user-group-id group)
 265           #$(user-group-system? group)))
 266
 267 (define (user-account->gexp account)
 268   "Turn ACCOUNT, a <user-account> object, into a list-valued gexp suitable for
 269 'activate-users'."
 270   #~`(#$(user-account-name account)
 271       #$(user-account-uid account)
 272       #$(user-account-group account)
 273       #$(user-account-supplementary-groups account)
 274       #$(user-account-comment account)
 275       #$(user-account-home-directory account)
 276       #$(user-account-create-home-directory? account)
 277       ,#$(user-account-shell account)             ; this one is a gexp
 278       #$(user-account-password account)
 279       #$(user-account-system? account)))
 280
 281 (define (account-activation accounts+groups)
 282   "Return a gexp that activates ACCOUNTS+GROUPS, a list of <user-account> and
 283 <user-group> objects.  Raise an error if a user account refers to a undefined
 284 group."
 285   (define accounts
 286     (filter user-account? accounts+groups))
 287
 288   (define user-specs
 289     (map user-account->gexp accounts))
 290
 291   (define groups
 292     (filter user-group? accounts+groups))
 293
 294   (define group-specs
 295     (map user-group->gexp groups))
 296
 297   (assert-valid-users/groups accounts groups)
 298
 299   ;; Add users and user groups.
 300   #~(begin
 301       (setenv "PATH"
 302               (string-append #$(@ (gnu packages admin) shadow) "/sbin"))
 303       (activate-users+groups (list #$@user-specs)
 304                              (list #$@group-specs))))
 305
 306 (define (account-shepherd-service accounts+groups)
 307   "Return a Shepherd service that creates the home directories for the user
 308 accounts among ACCOUNTS+GROUPS."
 309   (define accounts
 310     (filter user-account? accounts+groups))
 311
 312   ;; Create home directories only once 'file-systems' is up.  This makes sure
 313   ;; they are created in the right place if /home lives on a separate
 314   ;; partition.
 315   ;;
 316   ;; XXX: We arrange for this service to stop right after it's done its job so
 317   ;; that 'guix system reconfigure' knows that it can reload it fearlessly
 318   ;; (and thus create new home directories).  The cost of this hack is that
 319   ;; there's a small window during which first-time logins could happen before
 320   ;; the home directory has been created.
 321   (list (shepherd-service
 322          (requirement '(file-systems))
 323          (provision '(user-homes))
 324          (modules '((gnu build activation)))
 325          (start (with-imported-modules (source-module-closure
 326                                         '((gnu build activation)))
 327                   #~(lambda ()
 328                       (activate-user-home
 329                        (list #$@(map user-account->gexp accounts)))
 330                       #f)))                       ;stop
 331          (stop #~(const #f))
 332          (respawn? #f)
 333          (documentation "Create user home directories."))))
 334
 335 (define (shells-file shells)
 336   "Return a file-like object that builds a shell list for use as /etc/shells
 337 based on SHELLS.  /etc/shells is used by xterm, polkit, and other programs."
 338   (computed-file "shells"
 339                  #~(begin
 340                      (use-modules (srfi srfi-1))
 341
 342                      (define shells
 343                        (delete-duplicates (list #$@shells)))
 344
 345                      (call-with-output-file #$output
 346                        (lambda (port)
 347                          (display "\
 348 /bin/sh
 349 /run/current-system/profile/bin/sh
 350 /run/current-system/profile/bin/bash\n" port)
 351                          (for-each (lambda (shell)
 352                                      (display shell port)
 353                                      (newline port))
 354                                    shells))))))
 355 (define (etc-files arguments)
 356   "Filter out among ARGUMENTS things corresponding to skeletons, and return
 357 the /etc/skel directory for those."
 358   (let ((skels (filter pair? arguments))
 359         (users (filter user-account? arguments)))
 360     `(("skel" ,(skeleton-directory skels))
 361       ("shells" ,(shells-file (map user-account-shell users))))))
 362
 363 (define account-service-type
 364   (service-type (name 'account)
 365
 366                 ;; Concatenate <user-account>, <user-group>, and skeleton
 367                 ;; lists.
 368                 (compose concatenate)
 369                 (extend append)
 370
 371                 (extensions
 372                  (list (service-extension activation-service-type
 373                                           account-activation)
 374                        (service-extension shepherd-root-service-type
 375                                           account-shepherd-service)
 376                        (service-extension etc-service-type
 377                                           etc-files)))))
 378
 379 (define (account-service accounts+groups skeletons)
 380   "Return a <service> that takes care of user accounts and user groups, with
 381 ACCOUNTS+GROUPS as its initial list of accounts and groups."
 382   (service account-service-type
 383            (append skeletons accounts+groups)))
 384
 385 ;;; shadow.scm ends here