gnu/packages/emacs.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013, 2014, 2015, 2016, 2017, 2019 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2013 Andreas Enge <andreas@enge.fr>
   4 ;;; Copyright © 2014 Taylan Ulrich Bayirli/Kammer <taylanbayirli@gmail.com>
   5 ;;; Copyright © 2014, 2015, 2016, 2017, 2018, 2019 Mark H Weaver <mhw@netris.org>
   6 ;;; Copyright © 2014, 2015, 2016, 2017 Alex Kost <alezost@gmail.com>
   7 ;;; Copyright © 2016, 2018 Arun Isaac <arunisaac@systemreboot.net>
   8 ;;; Copyright © 2016 Federico Beffa <beffa@fbengineering.ch>
   9 ;;; Copyright © 2016 David Thompson <dthompson2@worcester.edu>
  10 ;;; Copyright © 2016 Nikita <nikita@n0.is>
  11 ;;; Copyright © 2017 Marius Bakke <mbakke@fastmail.com>
  12 ;;; Copyright © 2017, 2019, 2020 Maxim Cournoyer <maxim.cournoyer@gmail.com>
  13 ;;; Copyright © 2017 Alex Vong <alexvong1995@gmail.com>
  14 ;;; Copyright © 2017, 2018 Ricardo Wurmus <rekado@elephly.net>
  15 ;;; Copyright © 2017 Jan Nieuwenhuizen <janneke@gnu.org>
  16 ;;; Copyright © 2018 Efraim Flashner <efraim@flashner.co.il>
  17 ;;; Copyright © 2018 Mathieu Othacehe <m.othacehe@gmail.com>
  18 ;;; Copyright © 2018, 2019 Tobias Geerinckx-Rice <me@tobias.gr>
  19 ;;; Copyright © 2019 Jesse John Gildersleve <jessejohngildersleve@zohomail.eu>
  20 ;;; Copyright © 2019 Valentin Ignatev <valentignatev@gmail.com>
  21 ;;; Copyright © 2019 Leo Prikler <leo.prikler@student.tugraz.at>
  22 ;;; Copyright © 2019 Amin Bandali <bandali@gnu.org>
  23 ;;; Copyright © 2020 Jack Hill <jackhill@jackhill.us>
  24 ;;;
  25 ;;; This file is part of GNU Guix.
  26 ;;;
  27 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  28 ;;; under the terms of the GNU General Public License as published by
  29 ;;; the Free Software Foundation; either version 3 of the License, or (at
  30 ;;; your option) any later version.
  31 ;;;
  32 ;;; GNU Guix is distributed in the hope that it will be useful, but
  33 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  34 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  35 ;;; GNU General Public License for more details.
  36 ;;;
  37 ;;; You should have received a copy of the GNU General Public License
  38 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  39
  40 (define-module (gnu packages emacs)
  41   #:use-module ((guix licenses) #:prefix license:)
  42   #:use-module (guix packages)
  43   #:use-module (guix download)
  44   #:use-module (guix git-download)
  45   #:use-module (guix build-system gnu)
  46   #:use-module (guix build-system glib-or-gtk)
  47   #:use-module (gnu packages)
  48   #:use-module (gnu packages acl)
  49   #:use-module (gnu packages autotools)
  50   #:use-module (gnu packages base)
  51   #:use-module (gnu packages compression)
  52   #:use-module (gnu packages fontutils)
  53   #:use-module (gnu packages fribidi)
  54   #:use-module (gnu packages gd)
  55   #:use-module (gnu packages gettext)
  56   #:use-module (gnu packages glib)
  57   #:use-module (gnu packages gnome)     ; for librsvg
  58   #:use-module (gnu packages gtk)
  59   #:use-module (gnu packages guile)
  60   #:use-module (gnu packages image)
  61   #:use-module (gnu packages imagemagick)
  62   #:use-module (gnu packages linux)     ; alsa-lib
  63   #:use-module (gnu packages mail)      ; for mailutils
  64   #:use-module (gnu packages ncurses)
  65   #:use-module (gnu packages pkg-config)
  66   #:use-module (gnu packages texinfo)
  67   #:use-module (gnu packages tls)
  68   #:use-module (gnu packages web)       ; for jansson
  69   #:use-module (gnu packages webkit)
  70   #:use-module (gnu packages xml)
  71   #:use-module (gnu packages xorg)
  72   #:use-module (guix utils)
  73   #:use-module (srfi srfi-1))
  74
  75 (define-public emacs
  76   (package
  77     (name "emacs")
  78     (version "26.3")
  79     (source (origin
  80               (method url-fetch)
  81               (uri (string-append "mirror://gnu/emacs/emacs-"
  82                                   version ".tar.xz"))
  83               (sha256
  84                (base32
  85                 "119ldpk7sgn9jlpyngv5y4z3i7bb8q3xp4p0qqi7i5nq39syd42d"))
  86               (patches (search-patches "emacs-exec-path.patch"
  87                                        "emacs-fix-scheme-indent-function.patch"
  88                                        "emacs-source-date-epoch.patch"))
  89               (modules '((guix build utils)))
  90               (snippet
  91                '(with-directory-excursion "lisp"
  92                   ;; Delete the bundled byte-compiled elisp files and generated
  93                   ;; autoloads.
  94                   (for-each delete-file
  95                             (append (find-files "." "\\.elc$")
  96                                     (find-files "." "loaddefs\\.el$")
  97                                     ;; This is the only "autoloads" file that
  98                                     ;; does not have "*loaddefs.el" name.
  99                                     ;; TODO: Next time changing this package,
 100                                     ;; replace the following with a call to
 101                                     ;; `find-files', so that `delete-file'
 102                                     ;; wouldn't error out when the file is
 103                                     ;; missing, making the entire snippet field
 104                                     ;; reusable as-is for `emacs-next' below.
 105                                     '("eshell/esh-groups.el")))
 106
 107                   ;; Make sure Tramp looks for binaries in the right places on
 108                   ;; remote Guix System machines, where 'getconf PATH' returns
 109                   ;; something bogus.
 110                   (substitute* "net/tramp-sh.el"
 111                     ;; Patch the line after "(defcustom tramp-remote-path".
 112                     (("\\(tramp-default-remote-path")
 113                      (format #f "(tramp-default-remote-path ~s ~s ~s ~s "
 114                              "~/.guix-profile/bin" "~/.guix-profile/sbin"
 115                              "/run/current-system/profile/bin"
 116                              "/run/current-system/profile/sbin")))
 117
 118                   ;; Make sure Man looks for C header files in the right
 119                   ;; places.
 120                   (substitute* "man.el"
 121                     (("\"/usr/local/include\"" line)
 122                      (string-join
 123                       (list line
 124                             "\"~/.guix-profile/include\""
 125                             "\"/var/guix/profiles/system/profile/include\"")
 126                       " ")))
 127                   #t))))
 128     (build-system glib-or-gtk-build-system)
 129     (arguments
 130      `(#:tests? #f                      ; no check target
 131        #:configure-flags (list "--with-modules"
 132                                "--disable-build-details")
 133        #:phases
 134        (modify-phases %standard-phases
 135          (add-after 'unpack 'patch-program-file-names
 136            (lambda _
 137              (substitute* '("src/callproc.c"
 138                             "lisp/term.el"
 139                             "lisp/htmlfontify.el"
 140                             "lisp/textmodes/artist.el"
 141                             "lisp/progmodes/sh-script.el")
 142                (("\"/bin/sh\"")
 143                 (format #f "~s" (which "sh"))))
 144              #t))
 145          (add-before 'configure 'fix-/bin/pwd
 146            (lambda _
 147              ;; Use `pwd', not `/bin/pwd'.
 148              (substitute* (find-files "." "^Makefile\\.in$")
 149                (("/bin/pwd")
 150                 "pwd"))
 151              #t))
 152          (add-after 'install 'install-site-start
 153            ;; Use 'guix-emacs' in "site-start.el", which is used autoload the
 154            ;; Elisp packages found in EMACSLOADPATH.
 155            (lambda* (#:key inputs outputs #:allow-other-keys)
 156              (let* ((out      (assoc-ref outputs "out"))
 157                     (lisp-dir (string-append out "/share/emacs/site-lisp"))
 158                     (emacs (string-append out "/bin/emacs")))
 159
 160                ;; This is duplicated from emacs-utils to prevent coupling.
 161                (define* (emacs-byte-compile-directory dir)
 162                  (let ((expr `(progn
 163                                (setq byte-compile-debug t)
 164                                (byte-recompile-directory
 165                                 (file-name-as-directory ,dir) 0 1))))
 166                    (invoke emacs "--quick" "--batch"
 167                            (format #f "--eval=~s" expr))))
 168
 169                (copy-file (assoc-ref inputs "guix-emacs.el")
 170                           (string-append lisp-dir "/guix-emacs.el"))
 171                (with-output-to-file (string-append lisp-dir "/site-start.el")
 172                  (lambda ()
 173                    (display
 174                     (string-append "(when (require 'guix-emacs nil t)\n"
 175                                    "  (guix-emacs-autoload-packages))\n"))))
 176                ;; Remove the extraneous subdirs.el file, as it causes Emacs to
 177                ;; add recursively all the the sub-directories of a profile's
 178                ;; share/emacs/site-lisp union when added to EMACSLOADPATH,
 179                ;; which leads to conflicts.
 180                (delete-file (string-append lisp-dir "/subdirs.el"))
 181                ;; Byte compile the site-start files.
 182                (emacs-byte-compile-directory lisp-dir)))))))
 183     (inputs
 184      `(("gnutls" ,gnutls)
 185        ("ncurses" ,ncurses)
 186
 187        ;; Avoid Emacs's limited movemail substitute that retrieves POP3 email
 188        ;; only via insecure channels.  This is not needed for (modern) IMAP.
 189        ("mailutils" ,mailutils)
 190
 191        ;; TODO: Add the optional dependencies.
 192        ("libx11" ,libx11)
 193        ("gtk+" ,gtk+)
 194        ("libxft" ,libxft)
 195        ("libtiff" ,libtiff)
 196        ("giflib" ,giflib)
 197        ("libjpeg" ,libjpeg-turbo)
 198        ("imagemagick" ,imagemagick)
 199        ("acl" ,acl)
 200
 201        ;; When looking for libpng `configure' links with `-lpng -lz', so we
 202        ;; must also provide zlib as an input.
 203        ("libpng" ,libpng)
 204        ("zlib" ,zlib)
 205
 206        ("librsvg" ,librsvg)
 207        ("libxpm" ,libxpm)
 208        ("libxml2" ,libxml2)
 209        ("libice" ,libice)
 210        ("libsm" ,libsm)
 211        ("alsa-lib" ,alsa-lib)
 212        ("dbus" ,dbus)
 213
 214        ;; multilingualization support
 215        ("libotf" ,libotf)
 216        ("m17n-lib" ,m17n-lib)))
 217     (native-inputs
 218      `(("guix-emacs.el" ,(search-auxiliary-file "emacs/guix-emacs.el"))
 219        ("pkg-config" ,pkg-config)
 220        ("texinfo" ,texinfo)))
 221
 222     (native-search-paths
 223      (list (search-path-specification
 224             (variable "EMACSLOADPATH")
 225             ;; The versioned entry is for the Emacs' builtin libraries.
 226             (files (list "share/emacs/site-lisp"
 227                          (string-append "share/emacs/" version "/lisp"))))
 228            (search-path-specification
 229             (variable "INFOPATH")
 230             (files '("share/info")))))
 231
 232     (home-page "https://www.gnu.org/software/emacs/")
 233     (synopsis "The extensible, customizable, self-documenting text editor")
 234     (description
 235      "GNU Emacs is an extensible and highly customizable text editor.  It is
 236 based on an Emacs Lisp interpreter with extensions for text editing.  Emacs
 237 has been extended in essentially all areas of computing, giving rise to a
 238 vast array of packages supporting, e.g., email, IRC and XMPP messaging,
 239 spreadsheets, remote server editing, and much more.  Emacs includes extensive
 240 documentation on all aspects of the system, from basic editing to writing
 241 large Lisp programs.  It has full Unicode support for nearly all human
 242 languages.")
 243     (license license:gpl3+)))
 244
 245 (define-public emacs-next
 246   (let ((commit "c36c5a3dedbb2e0349be1b6c3b7567ea7b594f1c")
 247         (revision "0")
 248         (emacs-version "27.0.91"))
 249     (package
 250       (inherit emacs)
 251       (name "emacs-next")
 252       (version (git-version emacs-version revision commit))
 253       (source
 254        (origin
 255          (method git-fetch)
 256          (uri (git-reference
 257                (url "https://git.savannah.gnu.org/git/emacs.git")
 258                (commit commit)))
 259          (sha256
 260           (base32 "0mlrg2npy1r79laahkgzhxd1qassfcdz8qk1cpw7mqgf6y5x505h"))
 261          (file-name (git-file-name name version))
 262          (patches (search-patches "emacs27-exec-path.patch"
 263                                   "emacs-fix-scheme-indent-function.patch"
 264                                   "emacs-source-date-epoch.patch"))
 265          (modules (origin-modules (package-source emacs)))
 266          ;; TODO: once the snippet for `emacs' is changed to not fail when
 267          ;; eshell/esh-groups.el does not exist, replace this snippet with
 268          ;; (snippet (origin-snippet (package-source emacs))))).
 269          (snippet
 270           '(with-directory-excursion "lisp"
 271              ;; Make sure Tramp looks for binaries in the right places on
 272              ;; remote Guix System machines, where 'getconf PATH' returns
 273              ;; something bogus.
 274              (substitute* "net/tramp-sh.el"
 275                ;; Patch the line after "(defcustom tramp-remote-path".
 276                (("\\(tramp-default-remote-path")
 277                 (format #f "(tramp-default-remote-path ~s ~s ~s ~s "
 278                         "~/.guix-profile/bin" "~/.guix-profile/sbin"
 279                         "/run/current-system/profile/bin"
 280                         "/run/current-system/profile/sbin")))
 281
 282              ;; Make sure Man looks for C header files in the right
 283              ;; places.
 284              (substitute* "man.el"
 285                (("\"/usr/local/include\"" line)
 286                 (string-join
 287                  (list line
 288                        "\"~/.guix-profile/include\""
 289                        "\"/var/guix/profiles/system/profile/include\"")
 290                  " ")))
 291              #t))))
 292       (arguments
 293        (substitute-keyword-arguments (package-arguments emacs)
 294          ((#:configure-flags flags)
 295           `(cons* "--with-harfbuzz" ,flags))
 296          ((#:phases phases)
 297           `(modify-phases ,phases
 298              ;; The 'reset-gzip-timestamps phase will throw a
 299              ;; permission error if gzip files aren't writable then
 300              (add-before
 301                  'reset-gzip-timestamps
 302                  'make-compressed-files-writable
 303                (lambda _
 304                  (for-each make-file-writable
 305                            (find-files %output ".*\\.t?gz$"))
 306                  #t))
 307              ;; restore the dump file that Emacs installs somewhere in
 308              ;; libexec/ to its original state
 309              (add-after 'glib-or-gtk-wrap 'restore-emacs-pdmp
 310                (lambda* (#:key outputs target #:allow-other-keys)
 311                  (let* ((libexec (string-append (assoc-ref outputs "out")
 312                                                 "/libexec"))
 313                         ;; each of these find-files should return one file
 314                         (pdmp (find-files libexec "^emacs\\.pdmp$"))
 315                         (pdmp-real (find-files libexec
 316                                                "^\\.emacs\\.pdmp-real$")))
 317                    (for-each (lambda (wrapper real)
 318                                (delete-file wrapper)
 319                                (rename-file real wrapper))
 320                              pdmp pdmp-real)
 321                    #t)))))))
 322       (inputs
 323        `(("jansson" ,jansson)
 324          ("harfbuzz" ,harfbuzz)
 325          ;; Emacs no longer uses ImageMagick by default
 326          ;; https://git.savannah.gnu.org/cgit/emacs.git/tree/etc/NEWS?h=emacs-27.0.91&id=c36c5a3dedbb2e0349be1b6c3b7567ea7b594f1c#n102
 327          ,@(alist-delete "imagemagick" (package-inputs emacs))))
 328       (native-inputs
 329        `(("autoconf" ,autoconf)      ; needed when building from trunk
 330          ,@(package-native-inputs emacs)))
 331
 332       ;; TODO: consider changing `emacs' to use a more robust way of
 333       ;; specifying version for "EMACSLOADPATH", so as to avoid having to
 334       ;; duplicate native-search-paths here.
 335       (native-search-paths
 336        (list (search-path-specification
 337               (variable "EMACSLOADPATH")
 338               ;; The versioned entry is for the Emacs' builtin libraries.
 339               (files
 340                (list "share/emacs/site-lisp"
 341                      (string-append "share/emacs/" emacs-version "/lisp"))))
 342              (search-path-specification
 343               (variable "INFOPATH")
 344               (files '("share/info"))))))))
 345
 346 (define-public emacs-minimal
 347   ;; This is the version that you should use as an input to packages that just
 348   ;; need to byte-compile .el files.
 349   (package (inherit emacs)
 350     (name "emacs-minimal")
 351     (synopsis "The extensible text editor (used only for byte-compilation)")
 352     (build-system gnu-build-system)
 353     (arguments
 354      (substitute-keyword-arguments (package-arguments emacs)
 355        ((#:configure-flags flags ''())
 356         `(list "--with-gnutls=no" "--disable-build-details"))))
 357     (inputs
 358      `(("guix-emacs.el" ,(search-auxiliary-file "emacs/guix-emacs.el"))
 359        ("ncurses" ,ncurses)))
 360     (native-inputs
 361      `(("pkg-config" ,pkg-config)))))
 362
 363 (define-public emacs-xwidgets
 364   (package
 365     (inherit emacs)
 366     (name "emacs-xwidgets")
 367     (synopsis "The extensible, customizable, self-documenting text
 368 editor (with xwidgets support)")
 369     (build-system gnu-build-system)
 370     (arguments
 371      (substitute-keyword-arguments (package-arguments emacs)
 372        ((#:configure-flags flags ''())
 373         `(cons "--with-xwidgets" ,flags))))
 374     (inputs
 375      `(("webkitgtk" ,webkitgtk)
 376        ("libxcomposite" ,libxcomposite)
 377        ,@(package-inputs emacs)))))
 378
 379 (define-public emacs-no-x
 380   (package (inherit emacs)
 381     (name "emacs-no-x")
 382     (synopsis "The extensible, customizable, self-documenting text
 383 editor (console only)")
 384     (build-system gnu-build-system)
 385     (inputs (fold alist-delete
 386                   (package-inputs emacs)
 387                   '("libx11" "gtk+" "libxft" "libtiff" "giflib" "libjpeg"
 388                     "imagemagick" "libpng" "librsvg" "libxpm" "libice"
 389                     "libsm"
 390
 391                     ;; These depend on libx11, so remove them as well.
 392                     "libotf" "m17n-lib" "dbus")))))
 393
 394 (define-public emacs-no-x-toolkit
 395   (package (inherit emacs)
 396     (name "emacs-no-x-toolkit")
 397     (synopsis "The extensible, customizable, self-documenting text
 398 editor (without an X toolkit)" )
 399     (build-system gnu-build-system)
 400     (inputs (append `(("inotify-tools" ,inotify-tools))
 401                     (alist-delete "gtk+" (package-inputs emacs))))
 402     (arguments
 403      `(,@(substitute-keyword-arguments (package-arguments emacs)
 404            ((#:configure-flags cf)
 405             `(cons "--with-x-toolkit=no" ,cf)))))))
 406
 407 (define-public emacs-wide-int
 408   (package
 409     (inherit emacs)
 410     (name "emacs-wide-int")
 411     (synopsis "The extensible, customizable, self-documenting text
 412 editor (with wide ints)" )
 413     (arguments
 414      (substitute-keyword-arguments (package-arguments emacs)
 415        ((#:configure-flags flags)
 416         `(cons "--with-wide-int" ,flags))))))
 417
 418 (define-public guile-emacs
 419   (let ((commit "41120e0f595b16387eebfbf731fff70481de1b4b")
 420         (revision "0"))
 421     (package (inherit emacs)
 422       (name "guile-emacs")
 423       (version (git-version "0.0.0" revision commit))
 424       (source (origin
 425                 (method git-fetch)
 426                 (uri (git-reference
 427                       (url "https://git.hcoop.net/git/bpt/emacs.git")
 428                       (commit commit)))
 429                 (file-name (git-file-name name version))
 430                 (patches (search-patches "guile-emacs-fix-configure.patch"))
 431                 (sha256
 432                  (base32
 433                   "0lvcvsz0f4mawj04db35p1dvkffdqkz8pkhc0jzh9j9x2i63kcz6"))))
 434       (native-inputs
 435        `(("autoconf" ,autoconf)
 436          ("automake" ,automake)
 437          ("guile" ,guile-for-guile-emacs)
 438          ,@(package-native-inputs emacs)))
 439       (arguments
 440        (substitute-keyword-arguments `(;; Build fails if we allow parallel build.
 441                                        #:parallel-build? #f
 442                                        ;; Tests aren't passing for now.
 443                                        #:tests? #f
 444                                        ,@(package-arguments emacs))
 445          ((#:phases phases)
 446           `(modify-phases ,phases
 447              (add-after 'unpack 'autogen
 448                (lambda _
 449                  (invoke "sh" "autogen.sh")))
 450              ;; Build sometimes fails: deps/dispnew.d: No such file or directory
 451              (add-before 'build 'make-deps-dir
 452                (lambda _
 453                  (invoke "mkdir" "-p" "src/deps"))))))))))
 454
 455 (define-public m17n-db
 456   (package
 457     (name "m17n-db")
 458     (version "1.8.0")
 459     (source
 460      (origin
 461        (method url-fetch)
 462        (uri (string-append "mirror://savannah/m17n/m17n-db-"
 463                            version ".tar.gz"))
 464        (sha256
 465         (base32
 466          "0vfw7z9i2s9np6nmx1d4dlsywm044rkaqarn7akffmb6bf1j6zv5"))))
 467     (build-system gnu-build-system)
 468     (inputs
 469      `(("gettext" ,gettext-minimal)))
 470     (arguments
 471      `(#:configure-flags
 472        (list (string-append "--with-charmaps="
 473                             (assoc-ref %build-inputs "libc")
 474                             "/share/i18n/charmaps"))))
 475     ;; With `guix lint' the home-page URI returns a small page saying
 476     ;; that your browser does not handle frames. This triggers the "URI
 477     ;; returns suspiciously small file" warning.
 478     (home-page "https://www.nongnu.org/m17n/")
 479     (synopsis "Multilingual text processing library (database)")
 480     (description "The m17n library realizes multilingualization of
 481 many aspects of applications.  The m17n library represents
 482 multilingual text as an object named M-text.  M-text is a string with
 483 attributes called text properties, and designed to substitute for
 484 string in C.  Text properties carry any information required to input,
 485 display and edit the text.
 486
 487 This package contains the library database.")
 488     (license license:lgpl2.1+)))
 489
 490 (define-public m17n-lib
 491   (package
 492     (name "m17n-lib")
 493     (version "1.8.0")
 494     (source
 495      (origin
 496        (method url-fetch)
 497        (uri (string-append "mirror://savannah/m17n/m17n-lib-"
 498                            version ".tar.gz"))
 499        (sha256
 500         (base32
 501          "0jp61y09xqj10mclpip48qlfhniw8gwy8b28cbzxy8hq8pkwmfkq"))))
 502     (build-system gnu-build-system)
 503     (inputs
 504      `(("fribidi" ,fribidi)
 505        ("gd" ,gd)
 506        ("libotf" ,libotf)
 507        ("libxft" ,libxft)
 508        ("libxml2" ,libxml2)
 509        ("m17n-db" ,m17n-db)))
 510     (arguments
 511      `(#:parallel-build? #f))
 512     ;; With `guix lint' the home-page URI returns a small page saying
 513     ;; that your browser does not handle frames. This triggers the "URI
 514     ;; returns suspiciously small file" warning.
 515     (home-page "https://www.nongnu.org/m17n/")
 516     (synopsis "Multilingual text processing library (runtime)")
 517     (description "The m17n library realizes multilingualization of
 518 many aspects of applications.  The m17n library represents
 519 multilingual text as an object named M-text.  M-text is a string with
 520 attributes called text properties, and designed to substitute for
 521 string in C.  Text properties carry any information required to input,
 522 display and edit the text.
 523
 524 This package contains the library runtime.")
 525     (license license:lgpl2.1+)))