gnu/services/mcron.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2016, 2017, 2018 Ludovic Courtès <ludo@gnu.org>
   3 ;;;
   4 ;;; This file is part of GNU Guix.
   5 ;;;
   6 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU General Public License as published by
   8 ;;; the Free Software Foundation; either version 3 of the License, or (at
   9 ;;; your option) any later version.
  10 ;;;
  11 ;;; GNU Guix is distributed in the hope that it will be useful, but
  12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;; GNU General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU General Public License
  17 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 (define-module (gnu services mcron)
  20   #:use-module (gnu services)
  21   #:use-module (gnu services base)
  22   #:use-module (gnu services shepherd)
  23   #:autoload   (gnu packages guile) (mcron)
  24   #:use-module (guix records)
  25   #:use-module (guix gexp)
  26   #:use-module (srfi srfi-1)
  27   #:use-module (ice-9 match)
  28   #:use-module (ice-9 vlist)
  29   #:export (mcron-configuration
  30             mcron-configuration?
  31             mcron-configuration-mcron
  32             mcron-configuration-jobs
  33
  34             mcron-service-type
  35             mcron-service))
  36
  37 ;;; Commentary:
  38 ;;;
  39 ;;; This module implements a service that to run instances of GNU mcron, a
  40 ;;; periodic job execution daemon.  Example of a service:
  41 ;;
  42 ;;  (service mcron-service-type
  43 ;;           (mcron-configuration
  44 ;;            (jobs (list #~(job next-second-from
  45 ;;                               (lambda ()
  46 ;;                                 (call-with-output-file "/dev/console"
  47 ;;                                   (lambda (port)
  48 ;;                                     (display "hello!\n" port)))))))))
  49 ;;;
  50 ;;; Code:
  51
  52 (define-record-type* <mcron-configuration> mcron-configuration
  53   make-mcron-configuration
  54   mcron-configuration?
  55   (mcron             mcron-configuration-mcron    ;package
  56                      (default mcron))
  57   (jobs              mcron-configuration-jobs     ;list of <mcron-job>
  58                      (default '())))
  59
  60 (define (job-file job)
  61   (scheme-file "mcron-job" job))
  62
  63 (define (shepherd-schedule-action mcron files)
  64   "Return a Shepherd action that runs MCRON with '--schedule' for the given
  65 files."
  66   (shepherd-action
  67    (name 'schedule)
  68    (documentation
  69     "Display jobs that are going to be scheduled.")
  70    (procedure
  71     #~(lambda* (_ #:optional (n "5"))
  72         ;; XXX: This is a global side effect.
  73         (setenv "GUILE_AUTO_COMPILE" "0")
  74
  75         ;; Run 'mcron' in a pipe so we can explicitly redirect its output to
  76         ;; 'current-output-port', which at this stage is bound to the client
  77         ;; connection.
  78         (let ((pipe (open-pipe* OPEN_READ
  79                                 #$(file-append mcron "/bin/mcron")
  80                                 (string-append "--schedule=" n)
  81                                 #$@files)))
  82           (let loop ()
  83             (match (read-line pipe 'concat)
  84               ((? eof-object?)
  85                (catch 'system-error
  86                  (lambda ()
  87                    (zero? (close-pipe pipe)))
  88                  (lambda args
  89                    ;; There's a race with the SIGCHLD handler, which
  90                    ;; could call 'waitpid' before 'close-pipe' above does.  If
  91                    ;; we get ECHILD, that means we lost the race, but that's
  92                    ;; fine.
  93                    (or (= ECHILD (system-error-errno args))
  94                        (apply throw args)))))
  95               (line
  96                (display line)
  97                (loop)))))))))
  98
  99 (define mcron-shepherd-services
 100   (match-lambda
 101     (($ <mcron-configuration> mcron ())           ;nothing to do!
 102      '())
 103     (($ <mcron-configuration> mcron jobs)
 104      (let ((files (map job-file jobs)))
 105        (list (shepherd-service
 106               (provision '(mcron))
 107               (requirement '(user-processes))
 108               (modules `((srfi srfi-1)
 109                          (srfi srfi-26)
 110                          (ice-9 popen)            ;for the 'schedule' action
 111                          (ice-9 rdelim)
 112                          (ice-9 match)
 113                          ,@%default-modules))
 114               (start #~(make-forkexec-constructor
 115                         (list (string-append #$mcron "/bin/mcron") #$@files)
 116
 117                         ;; Disable auto-compilation of the job files and set a
 118                         ;; sane value for 'PATH'.
 119                         #:environment-variables
 120                         (cons* "GUILE_AUTO_COMPILE=0"
 121                                "PATH=/run/current-system/profile/bin"
 122                                (remove (cut string-prefix? "PATH=" <>)
 123                                        (environ)))))
 124               (stop #~(make-kill-destructor))
 125
 126               (actions
 127                (list (shepherd-schedule-action mcron files)))))))))
 128
 129 (define mcron-service-type
 130   (service-type (name 'mcron)
 131                 (extensions
 132                  (list (service-extension shepherd-root-service-type
 133                                           mcron-shepherd-services)
 134                        (service-extension profile-service-type
 135                                           (compose list
 136                                                    mcron-configuration-mcron))))
 137                 (compose concatenate)
 138                 (extend (lambda (config jobs)
 139                           (mcron-configuration
 140                            (inherit config)
 141                            (jobs (append (mcron-configuration-jobs config)
 142                                          jobs)))))
 143                 (default-value (mcron-configuration)))) ;empty job list
 144
 145 (define* (mcron-service jobs #:optional (mcron mcron))
 146   "Return an mcron service running @var{mcron} that schedules @var{jobs}, a
 147 list of gexps denoting mcron job specifications.
 148
 149 This is a shorthand for:
 150 @example
 151   (service mcron-service-type
 152            (mcron-configuration (mcron mcron) (jobs jobs)))
 153 @end example
 154 "
 155   (service mcron-service-type
 156            (mcron-configuration (mcron mcron) (jobs jobs))))
 157
 158 ;;; mcron.scm ends here