configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.68)
   5 AC_INIT([GNU Guix], [0.10.0], [bug-guix@gnu.org], [guix],
   6   [http://www.gnu.org/software/guix/])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8
   9 AM_INIT_AUTOMAKE([1.12 gnu silent-rules subdir-objects \
  10  color-tests parallel-tests -Woverride -Wno-portability])
  11
  12 # Enable silent rules by default.
  13 AM_SILENT_RULES([yes])
  14
  15 AC_CONFIG_SRCDIR([guix.scm])
  16 AC_CONFIG_MACRO_DIR([m4])
  17
  18 dnl For the C++ code.  This must be used early.
  19 AC_USE_SYSTEM_EXTENSIONS
  20
  21 AM_GNU_GETTEXT([external])
  22 AM_GNU_GETTEXT_VERSION([0.18.1])
  23
  24 guilemoduledir="${datarootdir}/guile/site/2.0"
  25 AC_SUBST([guilemoduledir])
  26
  27 GUIX_SYSTEM_TYPE
  28 GUIX_ASSERT_SUPPORTED_SYSTEM
  29
  30 AC_ARG_WITH(store-dir,
  31   AC_HELP_STRING([--with-store-dir=PATH],
  32     [file name of the store (defaults to /gnu/store)]),
  33   [storedir="$withval"],
  34   [storedir="/gnu/store"])
  35 AC_SUBST(storedir)
  36
  37 AC_ARG_WITH([bash-completion-dir],
  38   AC_HELP_STRING([--with-bash-completion-dir=DIR],
  39     [name of the Bash completion directory]),
  40   [bashcompletiondir="$withval"],
  41   [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  42 AC_SUBST([bashcompletiondir])
  43
  44 dnl Better be verbose.
  45 AC_MSG_CHECKING([for the store directory])
  46 AC_MSG_RESULT([$storedir])
  47
  48 AC_ARG_ENABLE([daemon],
  49   [AS_HELP_STRING([--disable-daemon], [build the Nix daemon (C++)])],
  50   [guix_build_daemon="$enableval"],
  51   [guix_build_daemon="yes"])
  52
  53 # Prepare a version of $localstatedir & co. that does not contain references
  54 # to shell variables.
  55 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  56 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  57 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  58 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  59 AC_SUBST([guix_localstatedir])
  60 AC_SUBST([guix_sysconfdir])
  61 AC_SUBST([guix_sbindir])
  62
  63 GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  64 AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  65
  66 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  67 dnl Make sure they are available.
  68 m4_pattern_forbid([PKG_CHECK_MODULES])
  69 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  70
  71 PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.7])
  72 AC_PATH_PROG([GUILE], [guile])
  73 AC_PATH_PROG([GUILD], [guild])
  74 if test "x$GUILD" = "x"; then
  75    AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
  76 fi
  77
  78 dnl guile-json is used for the PyPI package importer
  79 GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
  80 AM_CONDITIONAL([HAVE_GUILE_JSON], [test "x$have_guile_json" = "xyes"])
  81
  82 dnl Make sure we have a full-fledged Guile.
  83 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
  84
  85 dnl Check whether (srfi srfi-37) works, and provide our own if it doesn't.
  86 GUIX_CHECK_SRFI_37
  87 AM_CONDITIONAL([INSTALL_SRFI_37], [test "x$ac_cv_guix_srfi_37_broken" = xyes])
  88
  89 dnl Decompressors, for use by the substituter and other modules.
  90 AC_PATH_PROG([GZIP], [gzip])
  91 AC_PATH_PROG([BZIP2], [bzip2])
  92 AC_PATH_PROG([XZ], [xz])
  93 AC_SUBST([GZIP])
  94 AC_SUBST([BZIP2])
  95 AC_SUBST([XZ])
  96
  97 AC_ARG_WITH([nix-prefix],
  98   [AS_HELP_STRING([--with-nix-prefix=DIR],
  99     [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
 100   [case "$withval" in
 101     yes|no) ;;
 102     *)
 103       NIX_PREFIX="$withval"
 104       PATH="$NIX_PREFIX/bin:$PATH"; export PATH
 105       AC_SUBST([NIX_PREFIX])
 106       ;;
 107    esac],
 108   [])
 109
 110 AC_PATH_PROG([NIX_INSTANTIATE], [nix-instantiate])
 111 AC_PATH_PROG([NIX_HASH], [nix-hash])
 112 if test "x$guix_build_daemon$NIX_INSTANTIATE$NIX_HASH" = "xno"; then
 113    AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
 114 fi
 115
 116 if test "x$NIX_INSTANTIATE" = "x"; then
 117    # This program is an optional dependency, so we just want it to be
 118    # taken from $PATH if it's not available right now.
 119    NIX_INSTANTIATE="nix-instantiate"
 120 fi
 121
 122 AC_ARG_WITH([nixpkgs],
 123   [AS_HELP_STRING([--with-nixpkgs=DIR],
 124     [search for Nixpkgs in DIR (for testing purposes only)])],
 125   [case "$withval" in
 126     yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
 127     *)      NIXPKGS="$withval";;
 128    esac],
 129   [])
 130
 131 AC_MSG_CHECKING([for Nixpkgs source tree])
 132 if test -f "$NIXPKGS/default.nix"; then
 133    AC_MSG_RESULT([$NIXPKGS])
 134    AC_SUBST([NIXPKGS])
 135 else
 136    AC_MSG_RESULT([not found])
 137 fi
 138
 139 LIBGCRYPT="libgcrypt"
 140 LIBGCRYPT_LIBDIR="no"
 141 LIBGCRYPT_PREFIX="no"
 142
 143 AC_ARG_WITH([libgcrypt-prefix],
 144   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 145   [case "$withval" in
 146     yes|no)
 147       ;;
 148     *)
 149       LIBGCRYPT="$withval/lib/libgcrypt"
 150       LIBGCRYPT_PREFIX="$withval"
 151       LIBGCRYPT_LIBDIR="$withval/lib"
 152       ;;
 153    esac])
 154
 155 AC_ARG_WITH([libgcrypt-libdir],
 156   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 157      [search for GNU libgcrypt's shared library in DIR])],
 158   [case "$withval" in
 159     yes|no)
 160       LIBGCRYPT="libgcrypt"
 161       LIBGCRYPT_LIBDIR="no"
 162       ;;
 163     *)
 164       LIBGCRYPT="$withval/libgcrypt"
 165       LIBGCRYPT_LIBDIR="$withval"
 166       ;;
 167    esac])
 168
 169 dnl If none of the --with-libgcrypt-* options was used, try to determine the
 170 dnl absolute file name of libgcrypt.so.
 171 case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
 172   xnono)
 173     GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
 174     if test "x$LIBGCRYPT_LIBDIR" != x; then
 175       LIBGCRYPT="$LIBGCRYPT_LIBDIR/libgcrypt"
 176     else
 177       dnl 'config-daemon.ac' expects "no" in this case.
 178       LIBGCRYPT_LIBDIR="no"
 179     fi
 180     ;;
 181 esac
 182
 183 dnl Library name suitable for `dynamic-link'.
 184 AC_MSG_CHECKING([for libgcrypt shared library name])
 185 AC_MSG_RESULT([$LIBGCRYPT])
 186 AC_SUBST([LIBGCRYPT])
 187 AC_SUBST([LIBGCRYPT_PREFIX])
 188 AC_SUBST([LIBGCRYPT_LIBDIR])
 189
 190 GUIX_ASSERT_LIBGCRYPT_USABLE
 191
 192 dnl Library name of zlib suitable for 'dynamic-link'.
 193 GUIX_LIBZ_LIBDIR([libz_libdir])
 194 if test "x$libz_libdir" = "x"; then
 195   LIBZ="libz"
 196 else
 197   LIBZ="$libz_libdir/libz"
 198 fi
 199 AC_MSG_CHECKING([for zlib's shared library name])
 200 AC_MSG_RESULT([$LIBZ])
 201 AC_SUBST([LIBZ])
 202
 203 AC_CACHE_SAVE
 204
 205 m4_include([config-daemon.ac])
 206
 207 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 208 dnl See `Building from Git' in the manual for more info.
 209 AM_MISSING_PROG([DOT], [dot])
 210
 211 dnl Manual pages.
 212 AM_MISSING_PROG([HELP2MAN], [help2man])
 213
 214 AC_CONFIG_FILES([Makefile
 215                  po/guix/Makefile.in
 216                  po/packages/Makefile.in
 217                  guix/config.scm])
 218
 219 AC_CONFIG_FILES([scripts/guix], [chmod +x scripts/guix])
 220 AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
 221 AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
 222   [chmod +x pre-inst-env])
 223
 224 dnl Emacs interface.
 225 AC_PATH_PROG([DOT_USER_PROGRAM], [dot], [dot])
 226 AM_PATH_LISPDIR
 227 AM_CONDITIONAL([HAVE_EMACS], [test "x$EMACS" != "xno"])
 228
 229 emacsuidir="${guilemoduledir}/guix/emacs"
 230 AC_SUBST([emacsuidir])
 231 AC_CONFIG_FILES([emacs/guix-config.el
 232                  emacs/guix-helper.scm])
 233
 234 AC_OUTPUT