guix-package.in

   1 #!/bin/sh
   2 # aside from this initial boilerplate, this is actually -*- scheme -*- code
   3
   4 prefix="@prefix@"
   5 datarootdir="@datarootdir@"
   6
   7 GUILE_LOAD_COMPILED_PATH="@guilemoduledir@:$GUILE_LOAD_COMPILED_PATH"
   8 export GUILE_LOAD_COMPILED_PATH
   9
  10 main='(module-ref (resolve-interface '\''(guix-package)) '\'guix-package')'
  11 exec ${GUILE-@GUILE@} -L "@guilemoduledir@" -l "$0"    \
  12          -c "(apply $main (cdr (command-line)))" "$@"
  13 !#
  14 ;;; Guix --- Nix package management from Guile.         -*- coding: utf-8 -*-
  15 ;;; Copyright (C) 2012 Ludovic Courtès <ludo@gnu.org>
  16 ;;;
  17 ;;; This file is part of Guix.
  18 ;;;
  19 ;;; Guix is free software; you can redistribute it and/or modify it
  20 ;;; under the terms of the GNU General Public License as published by
  21 ;;; the Free Software Foundation; either version 3 of the License, or (at
  22 ;;; your option) any later version.
  23 ;;;
  24 ;;; Guix is distributed in the hope that it will be useful, but
  25 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  26 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  27 ;;; GNU General Public License for more details.
  28 ;;;
  29 ;;; You should have received a copy of the GNU General Public License
  30 ;;; along with Guix.  If not, see <http://www.gnu.org/licenses/>.
  31
  32 (define-module (guix-package)
  33   #:use-module (guix ui)
  34   #:use-module (guix store)
  35   #:use-module (guix derivations)
  36   #:use-module (guix packages)
  37   #:use-module (guix utils)
  38   #:use-module (ice-9 ftw)
  39   #:use-module (ice-9 format)
  40   #:use-module (ice-9 match)
  41   #:use-module (ice-9 regex)
  42   #:use-module (srfi srfi-1)
  43   #:use-module (srfi srfi-11)
  44   #:use-module (srfi srfi-26)
  45   #:use-module (srfi srfi-34)
  46   #:use-module (srfi srfi-37)
  47   #:autoload   (distro) (find-packages-by-name)
  48   #:use-module (distro packages guile)
  49   #:export (guix-package))
  50
  51 (define %store
  52   (open-connection))
  53
  54 \f
  55 ;;;
  56 ;;; User environment.
  57 ;;;
  58
  59 (define %user-environment-directory
  60   (and=> (getenv "HOME")
  61          (cut string-append <> "/.guix-profile")))
  62
  63 (define %profile-directory
  64   (string-append "/nix/var/nix/profiles/"
  65                  "guix/"
  66                  (or (and=> (getenv "USER")
  67                             (cut string-append "per-user/" <>))
  68                      "default")))
  69
  70 (define %current-profile
  71   (string-append %profile-directory "/profile"))
  72
  73 (define (profile-manifest profile)
  74   "Return the PROFILE's manifest."
  75   (let ((manifest (string-append profile "/manifest")))
  76     (if (file-exists? manifest)
  77         (call-with-input-file manifest read)
  78         '(manifest (version 0) (packages ())))))
  79
  80 (define (manifest-packages manifest)
  81   "Return the packages listed in MANIFEST."
  82   (match manifest
  83     (('manifest ('version 0) ('packages packages))
  84      packages)
  85     (_
  86      (error "unsupported manifest format" manifest))))
  87
  88 (define (latest-profile-number profile)
  89   "Return the identifying number of the latest generation of PROFILE.
  90 PROFILE is the name of the symlink to the current generation."
  91   (define %profile-rx
  92     (make-regexp (string-append "^" (regexp-quote (basename profile))
  93                                 "-([0-9]+)")))
  94
  95   (define* (scandir name #:optional (select? (const #t))
  96                     (entry<? (@ (ice-9 i18n) string-locale<?)))
  97     ;; XXX: Bug-fix version introduced in Guile v2.0.6-62-g139ce19.
  98     (define (enter? dir stat result)
  99       (and stat (string=? dir name)))
 100
 101     (define (visit basename result)
 102       (if (select? basename)
 103           (cons basename result)
 104           result))
 105
 106     (define (leaf name stat result)
 107       (and result
 108            (visit (basename name) result)))
 109
 110     (define (down name stat result)
 111       (visit "." '()))
 112
 113     (define (up name stat result)
 114       (visit ".." result))
 115
 116     (define (skip name stat result)
 117       ;; All the sub-directories are skipped.
 118       (visit (basename name) result))
 119
 120     (define (error name* stat errno result)
 121       (if (string=? name name*)             ; top-level NAME is unreadable
 122           result
 123           (visit (basename name*) result)))
 124
 125     (and=> (file-system-fold enter? leaf down up skip error #f name lstat)
 126            (lambda (files)
 127              (sort files entry<?))))
 128
 129   (match (scandir (dirname profile)
 130                   (cut regexp-exec %profile-rx <>))
 131     (#f                                         ; no profile directory
 132      0)
 133     (()                                         ; no profiles
 134      0)
 135     ((profiles ...)                             ; former profiles around
 136      (let ((numbers (map (compose string->number
 137                                   (cut match:substring <> 1)
 138                                   (cut regexp-exec %profile-rx <>))
 139                          profiles)))
 140        (fold (lambda (number highest)
 141                (if (> number highest)
 142                    number
 143                    highest))
 144              0
 145              numbers)))))
 146
 147 (define (profile-derivation store packages)
 148   "Return a derivation that builds a profile (a user environment) with
 149 all of PACKAGES, a list of name/version/output/path tuples."
 150   (define builder
 151     `(begin
 152        (use-modules (ice-9 pretty-print)
 153                     (guix build union))
 154
 155        (setvbuf (current-output-port) _IOLBF)
 156        (setvbuf (current-error-port) _IOLBF)
 157
 158        (let ((output (assoc-ref %outputs "out"))
 159              (inputs (map cdr %build-inputs)))
 160          (format #t "building user environment `~a' with ~a packages...~%"
 161                  output (length inputs))
 162          (union-build output inputs)
 163          (call-with-output-file (string-append output "/manifest")
 164            (lambda (p)
 165              (pretty-print '(manifest (version 0)
 166                                       (packages ,packages))
 167                            p))))))
 168
 169   (build-expression->derivation store "user-environment"
 170                                 (%current-system)
 171                                 builder
 172                                 (map (match-lambda
 173                                       ((name version output path)
 174                                        `(,name ,path)))
 175                                      packages)
 176                                 #:modules '((guix build union))))
 177
 178 \f
 179 ;;;
 180 ;;; Command-line options.
 181 ;;;
 182
 183 (define %default-options
 184   ;; Alist of default option values.
 185   `((profile . ,%current-profile)))
 186
 187 (define (show-help)
 188   (display (_ "Usage: guix-package [OPTION]... PACKAGES...
 189 Install, remove, or upgrade PACKAGES in a single transaction.\n"))
 190   (display (_ "
 191   -i, --install=PACKAGE  install PACKAGE"))
 192   (display (_ "
 193   -r, --remove=PACKAGE   remove PACKAGE"))
 194   (display (_ "
 195   -u, --upgrade=REGEXP   upgrade all the installed packages matching REGEXP"))
 196   (newline)
 197   (display (_ "
 198   -p, --profile=PROFILE  use PROFILE instead of the user's default profile"))
 199   (display (_ "
 200   -n, --dry-run          show what would be done without actually doing it"))
 201   (display (_ "
 202   -b, --bootstrap        use the bootstrap Guile to build the profile"))
 203   (newline)
 204   (display (_ "
 205   -h, --help             display this help and exit"))
 206   (display (_ "
 207   -V, --version          display version information and exit"))
 208   (newline)
 209   (format #t (_ "
 210 Report bugs to: ~a.~%") "@PACKAGE_BUGREPORT@"))
 211
 212 (define %options
 213   ;; Specification of the command-line options.
 214   (list (option '(#\h "help") #f #f
 215                 (lambda args
 216                   (show-help)
 217                   (exit 0)))
 218         (option '(#\V "version") #f #f
 219                 (lambda args
 220                   (show-version-and-exit "guix-package")))
 221
 222         (option '(#\i "install") #t #f
 223                 (lambda (opt name arg result)
 224                   (alist-cons 'install arg result)))
 225         (option '(#\r "remove") #t #f
 226                 (lambda (opt name arg result)
 227                   (alist-cons 'remove arg result)))
 228         (option '(#\p "profile") #t #f
 229                 (lambda (opt name arg result)
 230                   (alist-cons 'profile arg
 231                               (alist-delete 'profile result))))
 232         (option '(#\n "dry-run") #f #f
 233                 (lambda (opt name arg result)
 234                   (alist-cons 'dry-run? #t result)))
 235         (option '(#\b "bootstrap") #f #f
 236                 (lambda (opt name arg result)
 237                   (alist-cons 'bootstrap? #t result)))))
 238
 239 \f
 240 ;;;
 241 ;;; Entry point.
 242 ;;;
 243
 244 (define (guix-package . args)
 245   (define (parse-options)
 246     ;; Return the alist of option values.
 247     (args-fold args %options
 248                (lambda (opt name arg result)
 249                  (leave (_ "~A: unrecognized option~%") name))
 250                (lambda (arg result)
 251                  (alist-cons 'argument arg result))
 252                %default-options))
 253
 254   (define (show-what-to-build drv dry-run?)
 255     ;; Show what will/would be built in realizing the derivations listed
 256     ;; in DRV.
 257     (let* ((req  (append-map (lambda (drv-path)
 258                                (let ((d (call-with-input-file drv-path
 259                                           read-derivation)))
 260                                  (derivation-prerequisites-to-build %store d)))
 261                              drv))
 262            (req* (delete-duplicates
 263                   (append (remove (compose (cut valid-path? %store <>)
 264                                            derivation-path->output-path)
 265                                   drv)
 266                           (map derivation-input-path req)))))
 267       (if dry-run?
 268           (format (current-error-port)
 269                   (N_ "~:[the following derivation would be built:~%~{   ~a~%~}~;~]"
 270                       "~:[the following derivations would be built:~%~{    ~a~%~}~;~]"
 271                       (length req*))
 272                   (null? req*) req*)
 273           (format (current-error-port)
 274                   (N_ "~:[the following derivation will be built:~%~{   ~a~%~}~;~]"
 275                       "~:[the following derivations will be built:~%~{    ~a~%~}~;~]"
 276                       (length req*))
 277                   (null? req*) req*))))
 278
 279   (define (find-package name)
 280     ;; Find the package NAME; NAME may contain a version number and a
 281     ;; sub-derivation name.
 282     (define request name)
 283
 284     (let*-values (((name sub-drv)
 285                    (match (string-rindex name #\:)
 286                      (#f    (values name "out"))
 287                      (colon (values (substring name (+ 1 colon))
 288                                     (substring name colon)))))
 289                   ((name version)
 290                    (package-name->name+version name)))
 291       (match (find-packages-by-name name version)
 292         ((p)
 293          (list name version sub-drv p))
 294         ((p _ ...)
 295          (format (current-error-port)
 296                  (_ "warning: ambiguous package specification `~a'~%")
 297                  request)
 298          (format (current-error-port)
 299                  (_ "warning: choosing ~s~%")
 300                  p)
 301          (list name version sub-drv p))
 302         (()
 303          (leave (_ "~a: package not found~%") request)))))
 304
 305   (setlocale LC_ALL "")
 306   (textdomain "guix")
 307   (setvbuf (current-output-port) _IOLBF)
 308   (setvbuf (current-error-port) _IOLBF)
 309
 310   (let ((opts (parse-options)))
 311     (with-error-handling
 312       (parameterize ((%guile-for-build
 313                       (package-derivation %store
 314                                           (if (assoc-ref opts 'bootstrap?)
 315                                               (@@ (distro packages base)
 316                                                   %bootstrap-guile)
 317                                               guile-2.0))))
 318         (let* ((dry-run? (assoc-ref opts 'dry-run?))
 319                (profile  (assoc-ref opts 'profile))
 320                (install  (filter-map (match-lambda
 321                                       (('install . (? store-path?))
 322                                        #f)
 323                                       (('install . package)
 324                                        (find-package package))
 325                                       (_ #f))
 326                                      opts))
 327                (drv      (filter-map (match-lambda
 328                                       ((name version sub-drv
 329                                              (? package? package))
 330                                        (package-derivation %store package))
 331                                       (_ #f))
 332                                      install))
 333                (install* (append
 334                           (filter-map (match-lambda
 335                                        (('install . (? store-path? path))
 336                                         `(,(store-path-package-name path)
 337                                           #f #f ,path))
 338                                        (_ #f))
 339                                       opts)
 340                           (map (lambda (tuple drv)
 341                                  (match tuple
 342                                    ((name version sub-drv _)
 343                                     (let ((output-path
 344                                            (derivation-path->output-path
 345                                             drv sub-drv)))
 346                                       `(,name ,version ,sub-drv ,output-path)))))
 347                                install drv)))
 348                (remove   (filter-map (match-lambda
 349                                       (('remove . package)
 350                                        package)
 351                                       (_ #f))
 352                                      opts))
 353                (packages (append install*
 354                                  (fold alist-delete
 355                                        (manifest-packages
 356                                         (profile-manifest profile))
 357                                        remove))))
 358
 359           (show-what-to-build drv dry-run?)
 360
 361           (or dry-run?
 362               (and (build-derivations %store drv)
 363                    (let* ((prof-drv (profile-derivation %store packages))
 364                           (prof     (derivation-path->output-path prof-drv))
 365                           (number   (latest-profile-number profile))
 366                           (name     (format #f "~a/~a-~a-link"
 367                                             (dirname profile)
 368                                             (basename profile) (+ 1 number))))
 369                      (and (build-derivations %store (list prof-drv))
 370                           (begin
 371                             (symlink prof name)
 372                             (when (file-exists? profile)
 373                               (delete-file profile))
 374                             (symlink name profile)))))))))))
 375
 376 ;; Local Variables:
 377 ;; eval: (put 'guard 'scheme-indent-function 1)
 378 ;; End: