gnu/build/vm.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013, 2014, 2015, 2016, 2017, 2018, 2019, 2020 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2016 Christopher Allan Webber <cwebber@dustycloud.org>
   4 ;;; Copyright © 2016, 2017 Leo Famulari <leo@famulari.name>
   5 ;;; Copyright © 2017 Mathieu Othacehe <m.othacehe@gmail.com>
   6 ;;; Copyright © 2017 Marius Bakke <mbakke@fastmail.com>
   7 ;;; Copyright © 2018 Chris Marusich <cmmarusich@gmail.com>
   8 ;;; Copyright © 2020 Tobias Geerinckx-Rice <me@tobias.gr>
   9 ;;;
  10 ;;; This file is part of GNU Guix.
  11 ;;;
  12 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  13 ;;; under the terms of the GNU General Public License as published by
  14 ;;; the Free Software Foundation; either version 3 of the License, or (at
  15 ;;; your option) any later version.
  16 ;;;
  17 ;;; GNU Guix is distributed in the hope that it will be useful, but
  18 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;;; GNU General Public License for more details.
  21 ;;;
  22 ;;; You should have received a copy of the GNU General Public License
  23 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 (define-module (gnu build vm)
  26   #:use-module (guix build utils)
  27   #:use-module (guix build store-copy)
  28   #:use-module (guix build syscalls)
  29   #:use-module (guix store database)
  30   #:use-module (gnu build bootloader)
  31   #:use-module (gnu build linux-boot)
  32   #:use-module (gnu build install)
  33   #:use-module (gnu system uuid)
  34   #:use-module (guix records)
  35   #:use-module ((guix combinators) #:select (fold2))
  36   #:use-module (ice-9 format)
  37   #:use-module (ice-9 ftw)
  38   #:use-module (ice-9 match)
  39   #:use-module (ice-9 regex)
  40   #:use-module (ice-9 popen)
  41   #:use-module (srfi srfi-1)
  42   #:use-module (srfi srfi-9)
  43   #:use-module (srfi srfi-19)
  44   #:use-module (srfi srfi-26)
  45   #:export (qemu-command
  46             load-in-linux-vm
  47             format-partition
  48
  49             partition
  50             partition?
  51             partition-device
  52             partition-size
  53             partition-file-system
  54             partition-label
  55             partition-flags
  56             partition-initializer
  57
  58             estimated-partition-size
  59             root-partition-initializer
  60             initialize-partition-table
  61             initialize-hard-disk))
  62
  63 ;;; Commentary:
  64 ;;;
  65 ;;; This module provides supporting code to run virtual machines and build
  66 ;;; virtual machine images using QEMU.
  67 ;;;
  68 ;;; Code:
  69
  70 (define* (qemu-command #:optional (system %host-type))
  71   "Return the default name of the QEMU command for SYSTEM."
  72   (let ((cpu (substring system 0
  73                         (string-index system #\-))))
  74     (string-append "qemu-system-"
  75                    (cond
  76                     ((string-match "^i[3456]86$" cpu) "i386")
  77                     ((string-match "armhf" cpu) "arm")
  78                     (else cpu)))))
  79
  80 (define* (load-in-linux-vm builder
  81                            #:key
  82                            output
  83                            (qemu (qemu-command)) (memory-size 512)
  84                            linux initrd
  85                            make-disk-image?
  86                            single-file-output?
  87                            (disk-image-size (* 100 (expt 2 20)))
  88                            (disk-image-format "qcow2")
  89                            (references-graphs '()))
  90   "Run BUILDER, a Scheme file, into a VM running LINUX with INITRD, and copy
  91 the result to OUTPUT.  If SINGLE-FILE-OUTPUT? is true, copy a single file from
  92 /xchg to OUTPUT.  Otherwise, copy the contents of /xchg to a new directory
  93 OUTPUT.
  94
  95 When MAKE-DISK-IMAGE? is true, OUTPUT will contain a VM image of
  96 DISK-IMAGE-SIZE bytes resulting from the execution of BUILDER, which may
  97 access it via /dev/hda.
  98
  99 REFERENCES-GRAPHS can specify a list of reference-graph files as produced by
 100 the #:references-graphs parameter of 'derivation'."
 101
 102   (define target-arm32?
 103     (string-prefix? "arm-" %host-type))
 104
 105   (define target-aarch64?
 106     (string-prefix? "aarch64-" %host-type))
 107
 108   (define target-arm?
 109     (or target-arm32? target-aarch64?))
 110
 111   (define arch-specific-flags
 112     `(;; On ARM, a machine has to be specified. Use "virt" machine to avoid
 113       ;; hardware limits imposed by other machines.
 114       ,@(if target-arm?
 115             '("-M" "virt")
 116             '())
 117
 118       ;; On ARM32, if the kernel is built without LPAE support, ECAM conflicts
 119       ;; with VIRT_PCIE_MMIO causing PCI devices not to show up.  Disable
 120       ;; explicitely highmem to fix it.
 121       ;; See: https://bugs.launchpad.net/qemu/+bug/1790975.
 122       ,@(if target-arm32?
 123             '("-machine" "highmem=off")
 124             '())
 125
 126       ;; Only enable kvm if we see /dev/kvm exists.  This allows users without
 127       ;; hardware virtualization to still use these commands.  KVM support is
 128       ;; still buggy on some ARM boards. Do not use it even if available.
 129       ,@(if (and (file-exists? "/dev/kvm")
 130                  (not target-arm?))
 131             '("-enable-kvm")
 132             '())
 133
 134       ;; Pass "panic=1" so that the guest dies upon error.
 135       "-append"
 136       ,(string-append "panic=1 --load=" builder
 137
 138                       ;; The serial port name differs between emulated
 139                       ;; architectures/machines.
 140                       " console="
 141                       (if target-arm? "ttyAMA0" "ttyS0"))))
 142
 143   (when make-disk-image?
 144     (format #t "creating ~a image of ~,2f MiB...~%"
 145             disk-image-format (/ disk-image-size (expt 2 20)))
 146     (force-output)
 147     (invoke "qemu-img" "create" "-f" disk-image-format output
 148              (number->string disk-image-size)))
 149
 150   (mkdir "xchg")
 151   (mkdir "tmp")
 152
 153   (match references-graphs
 154     ((graph-files ...)
 155      ;; Copy the reference-graph files under xchg/ so EXP can access it.
 156      (map (lambda (file)
 157             (copy-file file (string-append "xchg/" file)))
 158           graph-files))
 159     (_ #f))
 160
 161   (apply invoke qemu "-nographic" "-no-reboot"
 162          ;; CPU "max" behaves as "host" when KVM is enabled, and like a system
 163          ;; CPU with the maximum possible feature set otherwise.
 164          "-cpu" "max"
 165          "-m" (number->string memory-size)
 166          "-nic" "user,model=virtio-net-pci"
 167          "-object" "rng-random,filename=/dev/urandom,id=guixsd-vm-rng"
 168          "-device" "virtio-rng-pci,rng=guixsd-vm-rng"
 169          "-virtfs"
 170          (string-append "local,id=store_dev,path="
 171                         (%store-directory)
 172                         ",security_model=none,mount_tag=store")
 173          "-virtfs"
 174          (string-append "local,id=xchg_dev,path=xchg"
 175                         ",security_model=none,mount_tag=xchg")
 176          "-virtfs"
 177          ;; Some programs require more space in /tmp than is normally
 178          ;; available in the guest.  Accommodate such programs by sharing a
 179          ;; temporary directory.
 180          (string-append "local,id=tmp_dev,path=tmp"
 181                         ",security_model=none,mount_tag=tmp")
 182          "-kernel" linux
 183          "-initrd" initrd
 184          (append
 185           (if make-disk-image?
 186               `("-device" "virtio-blk,drive=myhd"
 187                 "-drive" ,(string-append "if=none,file=" output
 188                                          ",format=" disk-image-format
 189                                          ",id=myhd"))
 190               '())
 191           arch-specific-flags))
 192
 193   (unless (file-exists? "xchg/.exit-status")
 194     (error "VM did not produce an exit code"))
 195
 196   (match (call-with-input-file "xchg/.exit-status" read)
 197     (0 #t)
 198     (status (error "guest VM code exited with a non-zero status" status)))
 199
 200   (delete-file "xchg/.exit-status")
 201
 202   ;; When MAKE-DISK-IMAGE? is true, the image is in OUTPUT already.
 203   (unless make-disk-image?
 204     (if single-file-output?
 205         (let ((graph? (lambda (name stat)
 206                         (member (basename name) references-graphs))))
 207           (match (find-files "xchg" (negate graph?))
 208             ((result)
 209              (copy-file result output))
 210             (x
 211              (error "did not find a single result file" x))))
 212         (begin
 213           (mkdir output)
 214           (copy-recursively "xchg" output)))))
 215
 216 (define* (register-closure prefix closure
 217                            #:key
 218                            (schema (sql-schema)))
 219   "Register CLOSURE in PREFIX, where PREFIX is the directory name of the
 220 target store and CLOSURE is the name of a file containing a reference graph as
 221 produced by #:references-graphs."
 222   (let ((items (call-with-input-file closure read-reference-graph)))
 223     (parameterize ((sql-schema schema))
 224       (with-database (store-database-file #:prefix prefix) db
 225         (register-items db items
 226                         #:prefix prefix
 227                         #:registration-time %epoch)))))
 228
 229 \f
 230 ;;;
 231 ;;; Partitions.
 232 ;;;
 233
 234 (define-record-type* <partition> partition make-partition
 235   partition?
 236   (device      partition-device (default #f))
 237   (size        partition-size)
 238   (file-system partition-file-system (default "ext4"))
 239   (file-system-options partition-file-system-options ;passed to 'mkfs.FS'
 240                        (default '()))
 241   (label       partition-label (default #f))
 242   (uuid        partition-uuid (default #f))
 243   (flags       partition-flags (default '()))
 244   (initializer partition-initializer (default (const #t))))
 245
 246 (define (estimated-partition-size graphs)
 247   "Return the estimated size of a partition that can store the store items
 248 given by GRAPHS, a list of file names produced by #:references-graphs."
 249   ;; Simply add a 25% overhead.
 250   (round (* 1.25 (closure-size graphs))))
 251
 252 (define* (initialize-partition-table device partitions
 253                                      #:key
 254                                      (label-type "msdos")
 255                                      (offset (expt 2 20)))
 256   "Create on DEVICE a partition table of type LABEL-TYPE, containing the given
 257 PARTITIONS (a list of <partition> objects), starting at OFFSET bytes.  On
 258 success, return PARTITIONS with their 'device' field changed to reflect their
 259 actual /dev name based on DEVICE."
 260   (define (partition-options part offset index)
 261     (cons* "mkpart" "primary" "ext2"
 262            (format #f "~aB" offset)
 263            (format #f "~aB" (+ offset (partition-size part)))
 264            (append-map (lambda (flag)
 265                          (list "set" (number->string index)
 266                                (symbol->string flag) "on"))
 267                        (partition-flags part))))
 268
 269   (define (options partitions offset)
 270     (let loop ((partitions partitions)
 271                (offset     offset)
 272                (index      1)
 273                (result     '()))
 274       (match partitions
 275         (()
 276          (concatenate (reverse result)))
 277         ((head tail ...)
 278          (loop tail
 279                ;; Leave one sector (512B) between partitions to placate
 280                ;; Parted.
 281                (+ offset 512 (partition-size head))
 282                (+ 1 index)
 283                (cons (partition-options head offset index)
 284                      result))))))
 285
 286   (format #t "creating partition table with ~a partitions (~a)...\n"
 287           (length partitions)
 288           (string-join (map (compose (cut string-append <> " MiB")
 289                                      number->string
 290                                      (lambda (size)
 291                                        (round (/ size (expt 2. 20))))
 292                                      partition-size)
 293                             partitions)
 294                        ", "))
 295   (apply invoke "parted" "--script"
 296          device "mklabel" label-type
 297          (options partitions offset))
 298
 299   ;; Set the 'device' field of each partition.
 300   (reverse
 301    (fold2 (lambda (part result index)
 302             (values (cons  (partition
 303                             (inherit part)
 304                             (device (string-append device
 305                                                    (number->string index))))
 306                            result)
 307                     (+ 1 index)))
 308           '()
 309           1
 310           partitions)))
 311
 312 (define MS_BIND 4096)                             ; <sys/mounts.h> again!
 313
 314 (define* (create-ext-file-system partition type
 315                                  #:key label uuid (options '()))
 316   "Create an ext-family file system of TYPE on PARTITION.  If LABEL is true,
 317 use that as the volume name.  If UUID is true, use it as the partition UUID."
 318   (format #t "creating ~a partition... ~@[label: ~s~] ~@[uuid: ~s~]\n"
 319           type label (and uuid (uuid->string uuid)))
 320   (apply invoke (string-append "mkfs." type)
 321          "-F" partition
 322          `(,@(if label
 323                  `("-L" ,label)
 324                  '())
 325            ,@(if uuid
 326                  `("-U" ,(uuid->string uuid))
 327                  '())
 328            ,@options)))
 329
 330 (define* (create-fat-file-system partition
 331                                  #:key label uuid (options '()))
 332   "Create a FAT file system on PARTITION.  The number of File Allocation Tables
 333 will be determined based on file system size.  If LABEL is true, use that as the
 334 volume name."
 335   ;; FIXME: UUID is ignored!
 336   (format #t "creating FAT partition...\n")
 337   (apply invoke "mkfs.fat" partition
 338          (append (if label `("-n" ,label) '()) options)))
 339
 340 (define* (format-partition partition type
 341                            #:key label uuid (options '()))
 342   "Create a file system TYPE on PARTITION.  If LABEL is true, use that as the
 343 volume name.  Options is a list of command-line options passed to 'mkfs.FS'."
 344   (cond ((string-prefix? "ext" type)
 345          (create-ext-file-system partition type #:label label #:uuid uuid
 346                                  #:options options))
 347         ((or (string-prefix? "fat" type) (string= "vfat" type))
 348          (create-fat-file-system partition #:label label #:uuid uuid
 349                                  #:options options))
 350         (else (error "Unsupported file system."))))
 351
 352 (define (initialize-partition partition)
 353   "Format PARTITION, a <partition> object with a non-#f 'device' field, mount
 354 it, run its initializer, and unmount it."
 355   (let ((target "/fs"))
 356    (format-partition (partition-device partition)
 357                      (partition-file-system partition)
 358                      #:label (partition-label partition)
 359                      #:uuid (partition-uuid partition)
 360                      #:options (partition-file-system-options partition))
 361    (mkdir-p target)
 362    (mount (partition-device partition) target
 363           (partition-file-system partition))
 364
 365    ((partition-initializer partition) target)
 366
 367    (umount target)
 368    partition))
 369
 370 (define* (root-partition-initializer #:key (closures '())
 371                                      copy-closures?
 372                                      (register-closures? #t)
 373                                      system-directory
 374                                      (deduplicate? #t)
 375                                      (make-device-nodes
 376                                       make-essential-device-nodes)
 377                                      (extra-directives '()))
 378   "Return a procedure to initialize a root partition.
 379
 380 If REGISTER-CLOSURES? is true, register all of CLOSURES in the partition's
 381 store.  If DEDUPLICATE? is true, then also deduplicate files common to
 382 CLOSURES and the rest of the store when registering the closures.  If
 383 COPY-CLOSURES? is true, copy all of CLOSURES to the partition.
 384 SYSTEM-DIRECTORY is the name of the directory of the 'system' derivation.
 385
 386 EXTRA-DIRECTIVES is an optional list of directives to populate the root file
 387 system that is passed to 'populate-root-file-system'."
 388   (lambda (target)
 389     (define target-store
 390       (string-append target (%store-directory)))
 391
 392     (when copy-closures?
 393       ;; Populate the store.
 394       (populate-store (map (cut string-append "/xchg/" <>) closures)
 395                       target
 396                       #:deduplicate? deduplicate?))
 397
 398     ;; Populate /dev.
 399     (make-device-nodes target)
 400
 401     ;; Optionally, register the inputs in the image's store.
 402     (when register-closures?
 403       (unless copy-closures?
 404         ;; XXX: 'register-closure' wants to palpate the things it registers, so
 405         ;; bind-mount the store on the target.
 406         (mkdir-p target-store)
 407         (mount (%store-directory) target-store "" MS_BIND))
 408
 409       (display "registering closures...\n")
 410       (for-each (lambda (closure)
 411                   (register-closure target
 412                                     (string-append "/xchg/" closure)))
 413                 closures)
 414       (unless copy-closures?
 415         (umount target-store)))
 416
 417     ;; Add the non-store directories and files.
 418     (display "populating...\n")
 419     (populate-root-file-system system-directory target
 420                                #:extras extra-directives)
 421
 422     ;; 'register-closure' resets timestamps and everything, so no need to do it
 423     ;; once more in that case.
 424     (unless register-closures?
 425       ;; 'reset-timestamps' also resets file permissions; do that everywhere
 426       ;; except on /dev so that /dev/null remains writable, etc.
 427       (for-each (lambda (directory)
 428                   (reset-timestamps (string-append target "/" directory)))
 429                 (scandir target
 430                          (match-lambda
 431                            ((or "." ".." "dev") #f)
 432                            (_ #t))))
 433       (reset-timestamps (string-append target "/dev")
 434                         #:preserve-permissions? #t))))
 435
 436 (define (register-bootcfg-root target bootcfg)
 437   "On file system TARGET, register BOOTCFG as a GC root."
 438   (let ((directory (string-append target "/var/guix/gcroots")))
 439     (mkdir-p directory)
 440     (symlink bootcfg (string-append directory "/bootcfg"))))
 441
 442 (define* (initialize-hard-disk device
 443                                #:key
 444                                bootloader-package
 445                                bootcfg
 446                                bootcfg-location
 447                                bootloader-installer
 448                                (grub-efi #f)
 449                                (partitions '()))
 450   "Initialize DEVICE as a disk containing all the <partition> objects listed
 451 in PARTITIONS, and using BOOTCFG as its bootloader configuration file.
 452
 453 Each partition is initialized by calling its 'initializer' procedure,
 454 passing it a directory name where it is mounted."
 455
 456   (define (partition-bootable? partition)
 457     "Return the first partition found with the boot flag set."
 458     (member 'boot (partition-flags partition)))
 459
 460   (define (partition-esp? partition)
 461     "Return the first EFI System Partition."
 462     (member 'esp (partition-flags partition)))
 463
 464   (let* ((partitions (initialize-partition-table device partitions))
 465          (root       (find partition-bootable? partitions))
 466          (esp        (find partition-esp? partitions))
 467          (target     "/fs"))
 468     (unless root
 469       (error "no bootable partition specified" partitions))
 470
 471     (for-each initialize-partition partitions)
 472
 473     (display "mounting root partition...\n")
 474     (mkdir-p target)
 475     (mount (partition-device root) target (partition-file-system root))
 476     (install-boot-config bootcfg bootcfg-location target)
 477     (when bootloader-installer
 478       (display "installing bootloader...\n")
 479       (bootloader-installer bootloader-package device target))
 480
 481     (when esp
 482       ;; Mount the ESP somewhere and install GRUB UEFI image.
 483       (let ((mount-point (string-append target "/boot/efi")))
 484         (display "mounting EFI system partition...\n")
 485         (mkdir-p mount-point)
 486         (mount (partition-device esp) mount-point
 487                (partition-file-system esp))
 488
 489         (display "creating EFI firmware image...")
 490         (install-efi-loader grub-efi mount-point)
 491         (display "done.\n")
 492
 493         (umount mount-point)))
 494
 495     ;; Register BOOTCFG as a GC root.
 496     (register-bootcfg-root target bootcfg)
 497
 498     (umount target)))
 499
 500 ;;; vm.scm ends here