gnu/packages/emacs.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2013, 2014, 2015, 2016, 2017, 2019, 2021 Ludovic Courtès <ludo@gnu.org>
   3 ;;; Copyright © 2013 Andreas Enge <andreas@enge.fr>
   4 ;;; Copyright © 2014 Taylan Ulrich Bayirli/Kammer <taylanbayirli@gmail.com>
   5 ;;; Copyright © 2014, 2015, 2016, 2017, 2018, 2019, 2020 Mark H Weaver <mhw@netris.org>
   6 ;;; Copyright © 2014, 2015, 2016, 2017 Alex Kost <alezost@gmail.com>
   7 ;;; Copyright © 2016, 2018 Arun Isaac <arunisaac@systemreboot.net>
   8 ;;; Copyright © 2016 Federico Beffa <beffa@fbengineering.ch>
   9 ;;; Copyright © 2016 David Thompson <dthompson2@worcester.edu>
  10 ;;; Copyright © 2016 Nikita <nikita@n0.is>
  11 ;;; Copyright © 2017 Marius Bakke <mbakke@fastmail.com>
  12 ;;; Copyright © 2017, 2019, 2020 Maxim Cournoyer <maxim.cournoyer@gmail.com>
  13 ;;; Copyright © 2017 Alex Vong <alexvong1995@gmail.com>
  14 ;;; Copyright © 2017, 2018 Ricardo Wurmus <rekado@elephly.net>
  15 ;;; Copyright © 2017 Jan Nieuwenhuizen <janneke@gnu.org>
  16 ;;; Copyright © 2018 Efraim Flashner <efraim@flashner.co.il>
  17 ;;; Copyright © 2018 Mathieu Othacehe <m.othacehe@gmail.com>
  18 ;;; Copyright © 2018, 2019, 2021 Tobias Geerinckx-Rice <me@tobias.gr>
  19 ;;; Copyright © 2019 Jesse John Gildersleve <jessejohngildersleve@zohomail.eu>
  20 ;;; Copyright © 2019 Valentin Ignatev <valentignatev@gmail.com>
  21 ;;; Copyright © 2019 Leo Prikler <leo.prikler@student.tugraz.at>
  22 ;;; Copyright © 2019 Amin Bandali <bandali@gnu.org>
  23 ;;; Copyright © 2020 Jack Hill <jackhill@jackhill.us>
  24 ;;; Copyright © 2020 Morgan Smith <Morgan.J.Smith@outlook.com>
  25 ;;;
  26 ;;; This file is part of GNU Guix.
  27 ;;;
  28 ;;; GNU Guix is free software; you can redistribute it and/or modify it
  29 ;;; under the terms of the GNU General Public License as published by
  30 ;;; the Free Software Foundation; either version 3 of the License, or (at
  31 ;;; your option) any later version.
  32 ;;;
  33 ;;; GNU Guix is distributed in the hope that it will be useful, but
  34 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  35 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  36 ;;; GNU General Public License for more details.
  37 ;;;
  38 ;;; You should have received a copy of the GNU General Public License
  39 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  40
  41 (define-module (gnu packages emacs)
  42   #:use-module ((guix licenses) #:prefix license:)
  43   #:use-module (guix packages)
  44   #:use-module (guix download)
  45   #:use-module (guix git-download)
  46   #:use-module (guix build-system gnu)
  47   #:use-module (guix build-system glib-or-gtk)
  48   #:use-module (gnu packages)
  49   #:use-module (gnu packages acl)
  50   #:use-module (gnu packages autotools)
  51   #:use-module (gnu packages base)
  52   #:use-module (gnu packages compression)
  53   #:use-module (gnu packages fontutils)
  54   #:use-module (gnu packages fribidi)
  55   #:use-module (gnu packages gd)
  56   #:use-module (gnu packages gettext)
  57   #:use-module (gnu packages glib)
  58   #:use-module (gnu packages gnome)     ; for librsvg
  59   #:use-module (gnu packages gtk)
  60   #:use-module (gnu packages guile)
  61   #:use-module (gnu packages image)
  62   #:use-module (gnu packages linux)     ; alsa-lib
  63   #:use-module (gnu packages mail)      ; for mailutils
  64   #:use-module (gnu packages multiprecision)
  65   #:use-module (gnu packages ncurses)
  66   #:use-module (gnu packages pkg-config)
  67   #:use-module (gnu packages texinfo)
  68   #:use-module (gnu packages tls)
  69   #:use-module (gnu packages web)       ; for jansson
  70   #:use-module (gnu packages webkit)
  71   #:use-module (gnu packages xml)
  72   #:use-module (gnu packages xorg)
  73   #:use-module (guix utils)
  74   #:use-module (srfi srfi-1))
  75
  76 (define-public emacs
  77   (package
  78     (name "emacs")
  79     (version "27.2")
  80     (source (origin
  81               (method url-fetch)
  82               (uri (string-append "mirror://gnu/emacs/emacs-"
  83                                   version ".tar.xz"))
  84               (sha256
  85                (base32
  86                 "1ff182gjw9wqsbx1kj5gl2r5pbqhp4ar54g04j33fgz6g17cr9xl"))
  87               (patches (search-patches "emacs-exec-path.patch"
  88                                        "emacs-fix-scheme-indent-function.patch"
  89                                        "emacs-ignore-empty-xim-styles.patch"
  90                                        "emacs-source-date-epoch.patch"))
  91               (modules '((guix build utils)))
  92               (snippet
  93                '(with-directory-excursion "lisp"
  94                   ;; Delete the bundled byte-compiled elisp files and generated
  95                   ;; autoloads.
  96                   (for-each delete-file
  97                             (append (find-files "." "\\.elc$")
  98                                     (find-files "." "loaddefs\\.el$")
  99                                     (find-files "eshell" "^esh-groups\\.el$")))
 100
 101                   ;; Make sure Tramp looks for binaries in the right places on
 102                   ;; remote Guix System machines, where 'getconf PATH' returns
 103                   ;; something bogus.
 104                   (substitute* "net/tramp-sh.el"
 105                     ;; Patch the line after "(defcustom tramp-remote-path".
 106                     (("\\(tramp-default-remote-path")
 107                      (format #f "(tramp-default-remote-path ~s ~s ~s ~s "
 108                              "~/.guix-profile/bin" "~/.guix-profile/sbin"
 109                              "/run/current-system/profile/bin"
 110                              "/run/current-system/profile/sbin")))
 111
 112                   ;; Make sure Man looks for C header files in the right
 113                   ;; places.
 114                   (substitute* "man.el"
 115                     (("\"/usr/local/include\"" line)
 116                      (string-join
 117                       (list line
 118                             "\"~/.guix-profile/include\""
 119                             "\"/var/guix/profiles/system/profile/include\"")
 120                       " ")))
 121                   #t))))
 122     (build-system glib-or-gtk-build-system)
 123     (arguments
 124      `(#:tests? #f                      ; no check target
 125        #:configure-flags (list "--with-modules"
 126                                "--with-cairo"
 127                                "--disable-build-details")
 128        #:phases
 129        (modify-phases %standard-phases
 130          (add-after 'unpack 'patch-program-file-names
 131            (lambda _
 132              (substitute* '("src/callproc.c"
 133                             "lisp/term.el"
 134                             "lisp/htmlfontify.el"
 135                             "lisp/textmodes/artist.el"
 136                             "lisp/progmodes/sh-script.el")
 137                (("\"/bin/sh\"")
 138                 (format #f "~s" (which "sh"))))
 139              #t))
 140          (add-before 'configure 'fix-/bin/pwd
 141            (lambda _
 142              ;; Use `pwd', not `/bin/pwd'.
 143              (substitute* (find-files "." "^Makefile\\.in$")
 144                (("/bin/pwd")
 145                 "pwd"))
 146              #t))
 147          (add-after 'install 'install-site-start
 148            ;; Use 'guix-emacs' in "site-start.el", which is used autoload the
 149            ;; Elisp packages found in EMACSLOADPATH.
 150            (lambda* (#:key inputs outputs #:allow-other-keys)
 151              (let* ((out      (assoc-ref outputs "out"))
 152                     (lisp-dir (string-append out "/share/emacs/site-lisp"))
 153                     (emacs    (string-append out "/bin/emacs")))
 154
 155                ;; This is duplicated from emacs-utils to prevent coupling.
 156                (define* (emacs-byte-compile-directory dir)
 157                  (let ((expr `(progn
 158                                (setq byte-compile-debug t)
 159                                (byte-recompile-directory
 160                                 (file-name-as-directory ,dir) 0 1))))
 161                    (invoke emacs "--quick" "--batch"
 162                            (format #f "--eval=~s" expr))))
 163
 164                (copy-file (assoc-ref inputs "guix-emacs.el")
 165                           (string-append lisp-dir "/guix-emacs.el"))
 166                (with-output-to-file (string-append lisp-dir "/site-start.el")
 167                  (lambda ()
 168                    (display
 169                     (string-append "(when (require 'guix-emacs nil t)\n"
 170                                    "  (guix-emacs-autoload-packages))\n"))))
 171                ;; Remove the extraneous subdirs.el file, as it causes Emacs to
 172                ;; add recursively all the the sub-directories of a profile's
 173                ;; share/emacs/site-lisp union when added to EMACSLOADPATH,
 174                ;; which leads to conflicts.
 175                (delete-file (string-append lisp-dir "/subdirs.el"))
 176                ;; Byte compile the site-start files.
 177                (emacs-byte-compile-directory lisp-dir))
 178              #t))
 179          (add-after 'glib-or-gtk-wrap 'restore-emacs-pdmp
 180            ;; restore the dump file that Emacs installs somewhere in
 181            ;; libexec/ to its original state
 182            (lambda* (#:key outputs target #:allow-other-keys)
 183              (let* ((libexec (string-append (assoc-ref outputs "out")
 184                                             "/libexec"))
 185                     ;; each of these find-files should return one file
 186                     (pdmp (find-files libexec "^emacs\\.pdmp$"))
 187                     (pdmp-real (find-files libexec
 188                                            "^\\.emacs\\.pdmp-real$")))
 189                (for-each (lambda (wrapper real)
 190                            (delete-file wrapper)
 191                            (rename-file real wrapper))
 192                          pdmp pdmp-real))
 193              #t))
 194          (add-after 'glib-or-gtk-wrap 'strip-double-wrap
 195            (lambda* (#:key outputs #:allow-other-keys)
 196              ;; Directly copy emacs-X.Y to emacs, so that it is not wrapped
 197              ;; twice.  This also fixes a minor issue, where WMs would not be
 198              ;; able to track emacs back to emacs.desktop.
 199              (with-directory-excursion (assoc-ref outputs "out")
 200                (copy-file
 201                 (car (find-files "bin" "^emacs-([0-9]+\\.)+[0-9]+$"))
 202                 "bin/emacs")
 203                #t)))
 204          (add-before 'reset-gzip-timestamps 'make-compressed-files-writable
 205            ;; The 'reset-gzip-timestamps phase will throw a permission error
 206            ;; if gzip files aren't writable then.  This phase is needed when
 207            ;; building from a git checkout.
 208            (lambda _
 209              (for-each make-file-writable
 210                        (find-files %output ".*\\.t?gz$"))
 211              #t)))))
 212     (inputs
 213      `(("gnutls" ,gnutls)
 214        ("ncurses" ,ncurses)
 215
 216        ;; Avoid Emacs's limited movemail substitute that retrieves POP3 email
 217        ;; only via insecure channels.  This is not needed for (modern) IMAP.
 218        ("mailutils" ,mailutils)
 219
 220        ;; TODO: Add the optional dependencies.
 221        ("libx11" ,libx11)
 222        ("gtk+" ,gtk+)
 223        ("cairo" ,cairo)
 224        ("pango" ,pango)
 225        ("harfbuzz" ,harfbuzz)
 226        ("libxft" ,libxft)
 227        ("libtiff" ,libtiff)
 228        ("giflib" ,giflib)
 229        ("libjpeg" ,libjpeg-turbo)
 230        ("acl" ,acl)
 231        ("jansson" ,jansson)
 232        ("gmp" ,gmp)
 233
 234        ;; When looking for libpng `configure' links with `-lpng -lz', so we
 235        ;; must also provide zlib as an input.
 236        ("libpng" ,libpng)
 237        ("zlib" ,zlib)
 238
 239        ("librsvg" ,librsvg)
 240        ("libxpm" ,libxpm)
 241        ("libxml2" ,libxml2)
 242        ("libice" ,libice)
 243        ("libsm" ,libsm)
 244        ("alsa-lib" ,alsa-lib)
 245        ("dbus" ,dbus)
 246
 247        ;; multilingualization support
 248        ("libotf" ,libotf)
 249        ("m17n-lib" ,m17n-lib)))
 250     (native-inputs
 251      `(("guix-emacs.el" ,(search-auxiliary-file "emacs/guix-emacs.el"))
 252        ("pkg-config" ,pkg-config)
 253        ("texinfo" ,texinfo)))
 254
 255     (native-search-paths
 256      (list (search-path-specification
 257             (variable "EMACSLOADPATH")
 258             ;; The versioned entry is for the Emacs' builtin libraries.
 259             (files (list "share/emacs/site-lisp"
 260                          (string-append "share/emacs/" version "/lisp"))))
 261            (search-path-specification
 262             (variable "INFOPATH")
 263             (files '("share/info")))))
 264
 265     (home-page "https://www.gnu.org/software/emacs/")
 266     (synopsis "The extensible, customizable, self-documenting text editor")
 267     (description
 268      "GNU Emacs is an extensible and highly customizable text editor.  It is
 269 based on an Emacs Lisp interpreter with extensions for text editing.  Emacs
 270 has been extended in essentially all areas of computing, giving rise to a
 271 vast array of packages supporting, e.g., email, IRC and XMPP messaging,
 272 spreadsheets, remote server editing, and much more.  Emacs includes extensive
 273 documentation on all aspects of the system, from basic editing to writing
 274 large Lisp programs.  It has full Unicode support for nearly all human
 275 languages.")
 276     (license license:gpl3+)))
 277
 278 (define-public emacs-next
 279   (let ((commit "2ea34662c20f71d35dd52a5ed996542c7386b9cb")
 280         (revision "0"))
 281     (package/inherit emacs
 282       (name "emacs-next")
 283       (version (git-version "28.0.50" revision commit))
 284       (source
 285        (origin
 286          (inherit (package-source emacs))
 287          (method git-fetch)
 288          (uri (git-reference
 289                (url "https://git.savannah.gnu.org/git/emacs.git/")
 290                (commit commit)))
 291          (file-name (git-file-name name version))
 292          (sha256
 293           (base32
 294            "0igjm9kwiswn2dpiy2k9xikbdfc7njs07ry48fqz70anljj8y7y3"))))
 295       (native-inputs
 296        `(("autoconf" ,autoconf)
 297          ,@(package-native-inputs emacs)))
 298       (native-search-paths
 299        (list (search-path-specification
 300               (variable "EMACSLOADPATH")
 301               ;; The versioned entry is for the Emacs' builtin libraries.
 302               (files (list "share/emacs/site-lisp"
 303                            (string-append "share/emacs/"
 304                                           (version-major+minor+point version)
 305                                           "/lisp"))))
 306              (search-path-specification
 307               (variable "INFOPATH")
 308               (files '("share/info"))))))))
 309
 310 (define-public emacs-next-pgtk
 311   (let ((commit "ae18c8ec4f0ef37c8c9cda473770ff47e41291e2")
 312         (revision "1"))
 313     (package/inherit emacs-next
 314       (name "emacs-next-pgtk")
 315       (version (git-version "28.0.50" revision commit))
 316       (source
 317        (origin
 318          (method git-fetch)
 319          (uri (git-reference
 320                (url "https://git.savannah.gnu.org/git/emacs.git/")
 321                (commit commit)))
 322          (file-name (git-file-name name version))
 323          (sha256
 324           (base32
 325            "07hgfqh965zmra0rbmnf63p3lsinpv5hn5payqcrjx25pl75xnaf"))))
 326       (arguments
 327        (substitute-keyword-arguments (package-arguments emacs-next)
 328          ((#:configure-flags flags ''())
 329           `(cons* "--with-pgtk" "--with-xwidgets" ,flags))))
 330       (propagated-inputs
 331        `(("gsettings-desktop-schemas" ,gsettings-desktop-schemas)
 332          ("glib-networking" ,glib-networking)))
 333       (inputs
 334        `(("webkitgtk" ,webkitgtk)
 335          ,@(package-inputs emacs-next)))
 336       (home-page "https://github.com/masm11/emacs")
 337       (synopsis "Emacs text editor with @code{pgtk} and @code{xwidgets} support")
 338       (description "This is an unofficial Emacs fork build with a pure-GTK
 339 graphical toolkit to work natively on Wayland.  In addition to that, xwidgets
 340 also enabled and works without glitches even on X server."))))
 341
 342 (define-public emacs-minimal
 343   ;; This is the version that you should use as an input to packages that just
 344   ;; need to byte-compile .el files.
 345   (package/inherit emacs
 346     (name "emacs-minimal")
 347     (synopsis "The extensible text editor (used only for byte-compilation)")
 348     (build-system gnu-build-system)
 349     (arguments
 350      (substitute-keyword-arguments (package-arguments emacs)
 351        ((#:configure-flags flags ''())
 352         `(list "--with-gnutls=no" "--disable-build-details"))
 353        ((#:phases phases)
 354         `(modify-phases ,phases
 355            (delete 'restore-emacs-pdmp)
 356            (delete 'strip-double-wrap)))))
 357     (inputs
 358      `(("guix-emacs.el" ,(search-auxiliary-file "emacs/guix-emacs.el"))
 359        ("ncurses" ,ncurses)))
 360     (native-inputs
 361      `(("pkg-config" ,pkg-config)))))
 362
 363 (define-public emacs-xwidgets
 364   (package/inherit emacs
 365     (name "emacs-xwidgets")
 366     (synopsis "The extensible, customizable, self-documenting text
 367 editor (with xwidgets support)")
 368     (build-system gnu-build-system)
 369     (arguments
 370      (substitute-keyword-arguments (package-arguments emacs)
 371        ((#:configure-flags flags ''())
 372         `(cons "--with-xwidgets" ,flags))
 373        ((#:phases phases)
 374         `(modify-phases ,phases
 375            (delete 'restore-emacs-pdmp)
 376            (delete 'strip-double-wrap)))))
 377     (inputs
 378      `(("webkitgtk" ,webkitgtk)
 379        ("libxcomposite" ,libxcomposite)
 380        ,@(package-inputs emacs)))))
 381
 382 (define-public emacs-no-x
 383   (package/inherit emacs
 384     (name "emacs-no-x")
 385     (synopsis "The extensible, customizable, self-documenting text
 386 editor (console only)")
 387     (build-system gnu-build-system)
 388     (inputs (fold alist-delete
 389                   (package-inputs emacs)
 390                   '("libx11" "gtk+" "libxft" "libtiff" "giflib" "libjpeg"
 391                     "imagemagick" "libpng" "librsvg" "libxpm" "libice"
 392                     "libsm" "cairo" "pango" "harfbuzz"
 393
 394                     ;; These depend on libx11, so remove them as well.
 395                     "libotf" "m17n-lib" "dbus")))
 396     (arguments
 397      (substitute-keyword-arguments (package-arguments emacs)
 398        ((#:configure-flags flags ''())
 399         `(delete "--with-cairo" ,flags))
 400        ((#:phases phases)
 401         `(modify-phases ,phases
 402            (delete 'restore-emacs-pdmp)
 403            (delete 'strip-double-wrap)))))))
 404
 405 (define-public emacs-no-x-toolkit
 406   (package/inherit emacs
 407     (name "emacs-no-x-toolkit")
 408     (synopsis "The extensible, customizable, self-documenting text
 409 editor (without an X toolkit)" )
 410     (build-system gnu-build-system)
 411     (inputs (append `(("inotify-tools" ,inotify-tools))
 412                     (alist-delete "gtk+" (package-inputs emacs))))
 413     (arguments
 414      (substitute-keyword-arguments (package-arguments emacs)
 415        ((#:configure-flags flags ''())
 416         `(cons "--with-x-toolkit=no" ,flags))
 417        ((#:phases phases)
 418         `(modify-phases ,phases
 419            (delete 'restore-emacs-pdmp)
 420            (delete 'strip-double-wrap)))))))
 421
 422 (define-public emacs-wide-int
 423   (package/inherit emacs
 424     (name "emacs-wide-int")
 425     (synopsis "The extensible, customizable, self-documenting text
 426 editor (with wide ints)" )
 427     (arguments
 428      (substitute-keyword-arguments (package-arguments emacs)
 429        ((#:configure-flags flags)
 430         `(cons "--with-wide-int" ,flags))))))
 431
 432 (define-public guile-emacs
 433   (let ((commit "41120e0f595b16387eebfbf731fff70481de1b4b")
 434         (revision "0"))
 435     (package/inherit emacs
 436       (name "guile-emacs")
 437       (version (git-version "0.0.0" revision commit))
 438       (source (origin
 439                 (method git-fetch)
 440                 (uri (git-reference
 441                       (url "https://git.hcoop.net/git/bpt/emacs.git")
 442                       (commit commit)))
 443                 (file-name (git-file-name name version))
 444                 (patches (search-patches "guile-emacs-fix-configure.patch"))
 445                 (sha256
 446                  (base32
 447                   "0lvcvsz0f4mawj04db35p1dvkffdqkz8pkhc0jzh9j9x2i63kcz6"))))
 448       (native-inputs
 449        `(("autoconf" ,autoconf)
 450          ("automake" ,automake)
 451          ("guile" ,guile-for-guile-emacs)
 452          ,@(package-native-inputs emacs)))
 453       (arguments
 454        (substitute-keyword-arguments `(;; Build fails if we allow parallel build.
 455                                        #:parallel-build? #f
 456                                        ;; Tests aren't passing for now.
 457                                        #:tests? #f
 458                                        ,@(package-arguments emacs))
 459          ((#:configure-flags flags ''())
 460           `(delete "--with-cairo" ,flags))
 461          ((#:phases phases)
 462           `(modify-phases ,phases
 463              (add-after 'unpack 'autogen
 464                (lambda _
 465                  (invoke "sh" "autogen.sh")))
 466              ;; Build sometimes fails: deps/dispnew.d: No such file or directory
 467              (add-before 'build 'make-deps-dir
 468                (lambda _
 469                  (invoke "mkdir" "-p" "src/deps")))
 470              (delete 'restore-emacs-pdmp)
 471              (delete 'strip-double-wrap))))))))
 472
 473 (define-public m17n-db
 474   (package
 475     (name "m17n-db")
 476     (version "1.8.0")
 477     (source
 478      (origin
 479        (method url-fetch)
 480        (uri (string-append "mirror://savannah/m17n/m17n-db-"
 481                            version ".tar.gz"))
 482        (sha256
 483         (base32
 484          "0vfw7z9i2s9np6nmx1d4dlsywm044rkaqarn7akffmb6bf1j6zv5"))))
 485     (build-system gnu-build-system)
 486     (inputs
 487      `(("gettext" ,gettext-minimal)))
 488     (arguments
 489      `(#:configure-flags
 490        (list (string-append "--with-charmaps="
 491                             (assoc-ref %build-inputs "libc")
 492                             "/share/i18n/charmaps"))))
 493     ;; With `guix lint' the home-page URI returns a small page saying
 494     ;; that your browser does not handle frames. This triggers the "URI
 495     ;; returns suspiciously small file" warning.
 496     (home-page "https://www.nongnu.org/m17n/")
 497     (synopsis "Multilingual text processing library (database)")
 498     (description "The m17n library realizes multilingualization of
 499 many aspects of applications.  The m17n library represents
 500 multilingual text as an object named M-text.  M-text is a string with
 501 attributes called text properties, and designed to substitute for
 502 string in C.  Text properties carry any information required to input,
 503 display and edit the text.
 504
 505 This package contains the library database.")
 506     (license license:lgpl2.1+)))
 507
 508 (define-public m17n-lib
 509   (package
 510     (name "m17n-lib")
 511     (version "1.8.0")
 512     (source
 513      (origin
 514        (method url-fetch)
 515        (uri (string-append "mirror://savannah/m17n/m17n-lib-"
 516                            version ".tar.gz"))
 517        (sha256
 518         (base32
 519          "0jp61y09xqj10mclpip48qlfhniw8gwy8b28cbzxy8hq8pkwmfkq"))))
 520     (build-system gnu-build-system)
 521     (inputs
 522      `(("fribidi" ,fribidi)
 523        ("gd" ,gd)
 524        ("libotf" ,libotf)
 525        ("libxft" ,libxft)
 526        ("libxml2" ,libxml2)
 527        ("m17n-db" ,m17n-db)))
 528     (arguments
 529      `(#:parallel-build? #f))
 530     ;; With `guix lint' the home-page URI returns a small page saying
 531     ;; that your browser does not handle frames. This triggers the "URI
 532     ;; returns suspiciously small file" warning.
 533     (home-page "https://www.nongnu.org/m17n/")
 534     (synopsis "Multilingual text processing library (runtime)")
 535     (description "The m17n library realizes multilingualization of
 536 many aspects of applications.  The m17n library represents
 537 multilingual text as an object named M-text.  M-text is a string with
 538 attributes called text properties, and designed to substitute for
 539 string in C.  Text properties carry any information required to input,
 540 display and edit the text.
 541
 542 This package contains the library runtime.")
 543     (license license:lgpl2.1+)))