gnu: Add kafs-client

[jackhill/guix/guix.git] / gnu / packages / afs.scm

;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2020 Jack Hill <jackhill@jackhill.us>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu packages afs)
  #:use-module (gnu packages)
  #:use-module (gnu packages crypto)
  #:use-module (gnu packages kerberos)
  #:use-module (guix build-system gnu)
  #:use-module (guix git-download)
  #:use-module ((guix licenses) #:prefix license:)
  #:use-module (guix packages)
  #:use-module (guix utils))

(define-public kafs-client
  (package
    (name "kafs-client")
    (version "0.5")
    (source (origin
              (method git-fetch)
              (uri (git-reference
                    (url "git://git.infradead.org/users/dhowells/kafs-client.git")
                    (commit (string-append "v" version))))
              (file-name (git-file-name name version))
              (sha256
               (base32
                "066s04wzfpsmkks9wcf02wxnwb57ix6982w9kwi4r4gvm2fr83cn"))
              (patches
               (search-patches "kafs-client-soname-symlink.patch"))))
    (build-system gnu-build-system)
    (arguments
     `(#:tests? #f ;no tests
       #:make-flags
       (let ((out (assoc-ref %outputs "out")))
         (list "BINDIR=/bin"
               (string-append "CC=" ,(cc-for-target))
               "DATADIR=/share/kafs"
               (string-append "DESTDIR=" out)
               "INCLUDEDIR=/include"
               "LIBDIR=/lib"
               "LIBEXECDIR=/libexec"
               "MANDIR=/share/man"
               "SBINDIR=/sbin"
               "UNITDIR=/lib/systemd"
               (string-append "LDFLAGS=-Wl,-rpath=" out "/lib")))
       #:phases
       (modify-phases %standard-phases
         (delete 'configure)
         (add-after 'patch-generated-file-shebangs 'patch-etc-paths
           (lambda* (#:key outputs #:allow-other-keys)
             (substitute*
              (find-files "conf")
              (("/usr") (assoc-ref outputs "out")))
             #t))
         (add-before 'build 'set-library-path
           (lambda _
             (setenv "LIBRARY_PATH" (string-append (getenv "LIBRARY_PATH") ":"
                                                   (getcwd) "/src"))
             #t))
         (add-after 'install 'openafs-compatible-executable-names
           (lambda* (#:key outputs #:allow-other-keys)
             (system (string-append "ln -s aklog-kafs "
                                    (assoc-ref outputs "out")
                                    "/bin/aklog"))
             #t)))))
    (inputs
     `(("keyutils" ,keyutils)
       ("mit-krb5" ,mit-krb5)))
    (home-page "https://www.infradead.org/~dhowells/kafs/kafs_client.html")
    (synopsis "Utility programs for the Linux AFS client")
    (description "This package provides the user space utilities for
interacting with the Linux kernel AFS distributed file system client.  The
included @command{aklog} facilitates adding authentication tokens to the
kernel keyring.  Additional keyring management features are provided by the
keyutils package.  This package also provides AFS cell server location
information to the kernel via DNS or a static cellservdb file.")
    (license license:gpl2)))