src/msg.sml

   1 (* HCoop Domtool (http://hcoop.sourceforge.net/)
   2  * Copyright (c) 2006, Adam Chlipala
   3  *
   4  * This program is free software; you can redistribute it and/or
   5  * modify it under the terms of the GNU General Public License
   6  * as published by the Free Software Foundation; either version 2
   7  * of the License, or (at your option) any later version.
   8  *
   9  * This program is distributed in the hope that it will be useful,
  10  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12  * GNU General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU General Public License
  15  * along with this program; if not, write to the Free Software
  16  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
  17  *)
  18
  19 (* Network messages *)
  20
  21 structure Msg :> MSG = struct
  22
  23 open OpenSSL MsgTypes Slave
  24
  25 val a2i = fn Add => 0
  26            | Delete => 1
  27            | Modify => 2
  28
  29 val i2a = fn 0 => Add
  30            | 1 => Delete
  31            | 2 => Modify
  32            | _ => raise OpenSSL.OpenSSL "Bad action number to deserialize"
  33
  34 fun sendAcl (bio, {user, class, value}) =
  35     (OpenSSL.writeString (bio, user);
  36      OpenSSL.writeString (bio, class);
  37      OpenSSL.writeString (bio, value))
  38
  39 fun recvAcl bio =
  40     case (OpenSSL.readString bio, OpenSSL.readString bio, OpenSSL.readString bio) of
  41         (SOME user, SOME class, SOME value) => SOME {user = user, class = class, value = value}
  42       | _ => NONE
  43
  44 fun sendList f (bio, ls) =
  45     (app (fn x =>
  46              (OpenSSL.writeInt (bio, 1);
  47               f (bio, x))) ls;
  48      OpenSSL.writeInt (bio, 0))
  49
  50 fun recvList f bio =
  51     let
  52         fun loop ls =
  53             case OpenSSL.readInt bio of
  54                 SOME 0 => SOME (rev ls)
  55               | SOME 1 =>
  56                 (case f bio of
  57                      SOME x => loop (x :: ls)
  58                    | NONE => NONE)
  59               | _ => NONE
  60     in
  61         loop []
  62     end
  63
  64 fun sendOption f (bio, opt) =
  65     case opt of
  66         NONE => OpenSSL.writeInt (bio, 0)
  67       | SOME x => (OpenSSL.writeInt (bio, 1);
  68                    f (bio, x))
  69
  70 fun recvOption f bio =
  71     case OpenSSL.readInt bio of
  72         SOME 0 => SOME NONE
  73       | SOME 1 =>
  74         (case f bio of
  75              SOME x => SOME (SOME x)
  76            | NONE => NONE)
  77       | _ => NONE
  78
  79 fun send (bio, m) =
  80     case m of
  81         MsgOk => OpenSSL.writeInt (bio, 1)
  82       | MsgError s => (OpenSSL.writeInt (bio, 2);
  83                        OpenSSL.writeString (bio, s))
  84       | MsgConfig s => (OpenSSL.writeInt (bio, 3);
  85                        OpenSSL.writeString (bio, s))
  86       | MsgFile {action, domain, dir, file} =>
  87         (OpenSSL.writeInt (bio, 4);
  88          OpenSSL.writeInt (bio, a2i action);
  89          OpenSSL.writeString (bio, domain);
  90          OpenSSL.writeString (bio, dir);
  91          OpenSSL.writeString (bio, file))
  92       | MsgDoFiles => OpenSSL.writeInt (bio, 5)
  93       | MsgGrant acl => (OpenSSL.writeInt (bio, 6);
  94                          sendAcl (bio, acl))
  95       | MsgRevoke acl => (OpenSSL.writeInt (bio, 7);
  96                           sendAcl (bio, acl))
  97       | MsgListPerms user => (OpenSSL.writeInt (bio, 8);
  98                               OpenSSL.writeString (bio, user))
  99       | MsgPerms classes => (OpenSSL.writeInt (bio, 9);
 100                              sendList (fn (bio, (class, values)) =>
 101                                           (OpenSSL.writeString (bio, class);
 102                                            sendList OpenSSL.writeString (bio, values)))
 103                                       (bio, classes))
 104       | MsgWhoHas {class, value} => (OpenSSL.writeInt (bio, 10);
 105                                      OpenSSL.writeString (bio, class);
 106                                      OpenSSL.writeString (bio, value))
 107       | MsgWhoHasResponse users => (OpenSSL.writeInt (bio, 11);
 108                                     sendList OpenSSL.writeString (bio, users))
 109       | MsgMultiConfig codes => (OpenSSL.writeInt (bio, 12);
 110                                  sendList OpenSSL.writeString (bio, codes))
 111       | MsgRmdom doms => (OpenSSL.writeInt (bio, 13);
 112                           sendList OpenSSL.writeString (bio, doms))
 113       | MsgRegenerate => OpenSSL.writeInt (bio, 14)
 114       | MsgRmuser dom => (OpenSSL.writeInt (bio, 15);
 115                           OpenSSL.writeString (bio, dom))
 116       | MsgCreateDbUser {dbtype, passwd} => (OpenSSL.writeInt (bio, 16);
 117                                              OpenSSL.writeString (bio, dbtype);
 118                                              sendOption OpenSSL.writeString (bio, passwd))
 119       | MsgCreateDbTable {dbtype, dbname} => (OpenSSL.writeInt (bio, 17);
 120                                               OpenSSL.writeString (bio, dbtype);
 121                                               OpenSSL.writeString (bio, dbname))
 122
 123 fun checkIt v =
 124     case v of
 125         NONE => raise OpenSSL.OpenSSL "Bad Msg format"
 126       | _ => v
 127
 128 fun recv bio =
 129     case OpenSSL.readInt bio of
 130         NONE => NONE
 131       | SOME n =>
 132         checkIt (case n of
 133                      1 => SOME MsgOk
 134                    | 2 => Option.map MsgError (OpenSSL.readString bio)
 135                    | 3 => Option.map MsgConfig (OpenSSL.readString bio)
 136                    | 4 => (case (OpenSSL.readInt bio,
 137                                  OpenSSL.readString bio,
 138                                  OpenSSL.readString bio,
 139                                  OpenSSL.readString bio) of
 140                                (SOME action, SOME domain, SOME dir, SOME file) =>
 141                                SOME (MsgFile {action = i2a action,
 142                                               domain = domain,
 143                                               dir = dir,
 144                                               file = file})
 145                              | _ => NONE)
 146                    | 5 => SOME MsgDoFiles
 147                    | 6 => (case recvAcl bio of
 148                                SOME acl => SOME (MsgGrant acl)
 149                              | _ => NONE)
 150                    | 7 => (case recvAcl bio of
 151                                SOME acl => SOME (MsgRevoke acl)
 152                              | _ => NONE)
 153                    | 8 => (case OpenSSL.readString bio of
 154                                SOME user => SOME (MsgListPerms user)
 155                              | _ => NONE)
 156                    | 9 => Option.map MsgPerms
 157                                      (recvList (fn bio =>
 158                                                    case (OpenSSL.readString bio,
 159                                                          recvList OpenSSL.readString bio) of
 160                                                        (SOME class, SOME values) => SOME (class, values)
 161                                                      | _ => NONE) bio)
 162                    | 10 => (case (OpenSSL.readString bio, OpenSSL.readString bio) of
 163                                 (SOME class, SOME value) => SOME (MsgWhoHas {class = class, value = value})
 164                               | _ => NONE)
 165                    | 11 => Option.map MsgWhoHasResponse
 166                            (recvList OpenSSL.readString bio)
 167                    | 12 => Option.map MsgMultiConfig
 168                            (recvList OpenSSL.readString bio)
 169                    | 13 => Option.map MsgRmdom (recvList OpenSSL.readString bio)
 170                    | 14 => SOME MsgRegenerate
 171                    | 15 => Option.map MsgRmuser (OpenSSL.readString bio)
 172                    | 16 => (case (OpenSSL.readString bio, recvOption OpenSSL.readString bio) of
 173                                 (SOME dbtype, SOME passwd) =>
 174                                 SOME (MsgCreateDbUser {dbtype = dbtype, passwd = passwd})
 175                               | _ => NONE)
 176                    | 17 => (case (OpenSSL.readString bio, OpenSSL.readString bio) of
 177                                 (SOME dbtype, SOME dbname) =>
 178                                 SOME (MsgCreateDbTable {dbtype = dbtype, dbname = dbname})
 179                               | _ => NONE)
 180                    | _ => NONE)
 181
 182 end