t/ps-tests.lisp

   1 (in-package :ps-test)
   2
   3 ;;; Hand-written unit tests
   4
   5 (eval-when (:compile-toplevel :load-toplevel :execute)
   6   (def-suite ps-tests))
   7 (in-suite ps-tests)
   8
   9 (test-ps-js plus-is-not-commutative
  10   (setf x (+ "before" x "after"))
  11   "x = 'before' + x + 'after';")
  12
  13 (test-ps-js plus-works-if-first
  14   (setf x (+ x "middle" "after"))
  15   "x += 'middle' + 'after';")
  16
  17 (test-ps-js setf-side-effects
  18   (progn
  19     (let ((x 10))
  20       (defun side-effect()
  21         (setf x 4)
  22         (return 3))
  23       (setf x (+ 2 (side-effect) x 5))))
  24   "var x = 10;
  25 function sideEffect() {
  26   x = 4;
  27   return 3;
  28 };
  29 x = 2 + sideEffect() + x + 5;")
  30 ;; Parenscript used to optimize incorrectly:
  31 ;;   var x = 10;
  32 ;;   function sideEffect() {
  33 ;;     x = 4;
  34 ;;     return 3;
  35 ;;   };
  36 ;;   x += 2 + sideEffect() + 5;
  37 ;;
  38 ;;   Which is 20, not 14
  39
  40
  41 (test-ps-js method-call-op-form
  42   ((@ (+ "" x) to-string))
  43   "('' + x).toString();")
  44
  45 (test-ps-js method-call-op-form-args
  46   ((@ (+ "" x) to-string) 1 2 :baz 3)
  47   "('' + x).toString(1, 2, 'baz', 3);")
  48
  49 (test-ps-js method-call-number
  50   ((@ 10 to-string))
  51   "( 10 ).toString();")
  52
  53 (test-ps-js method-call-string
  54   ((@ "hi" to-string))
  55   "'hi'.toString();")
  56
  57 (test-ps-js method-call-lit-object
  58   ((@ (create to-string (lambda () (return "it works"))) to-string))
  59   "( { toString : function () { return 'it works'; } } ).toString();")
  60
  61 (test-ps-js method-call-conditional
  62   ((if a x y) 1)
  63   "(a ? x : y)(1);")
  64
  65 (test-ps-js method-call-variable
  66   ((@ x to-string))
  67   "x.toString();")
  68
  69 (test-ps-js method-call-array
  70   ((@ (list 10 20) to-string))
  71   "[ 10, 20 ].toString();")
  72
  73 (test-ps-js method-call-fn-call
  74   ((@ (foo) to-string))
  75   "foo().toString();")
  76
  77 (test-ps-js method-call-lambda-fn
  78   ((@ (lambda () (alert 10)) to-string))
  79   "( function () { alert(10); } ).toString();")
  80
  81 (test-ps-js method-call-lambda-call
  82   ((@ ((lambda (x) (return x)) 10) to-string))
  83   "(function (x) { return x; })(10).toString();")
  84
  85 (test no-whitespace-before-dot
  86   (let* ((str (ps* '((@ ((lambda (x) (return x)) 10) to-string))))
  87          (dot-pos (position #\. str :test #'char=))
  88          (char-before (elt str (1- dot-pos)))
  89          (a-parenthesis #\)))
  90     (is (char= char-before a-parenthesis))))
  91
  92 (test-ps-js simple-slot-value
  93   (let ((foo (create a 1)))
  94     (alert (slot-value foo 'a)))
  95   "var foo = { a : 1 };
  96    alert(foo.a);")
  97
  98 (test-ps-js buggy-slot-value
  99    (let ((foo (create a 1))
 100          (slot-name "a"))
 101     (alert (slot-value foo slot-name)))
 102   " var foo = { a : 1 };
 103     var slotName = 'a';
 104     alert(foo[slotName]);
 105    "); Last line was alert(foo.slotName) before bug-fix.
 106
 107 (test-ps-js buggy-slot-value-two
 108   (slot-value foo (get-slot-name))
 109   "foo[getSlotName()];")
 110
 111 (test-ps-js old-case-is-now-switch
 112   ;; Switch was "case" before, but that was very non-lispish.
 113   ;; For example, this code makes three messages and not one
 114   ;; which may have been expected. This is because a switch
 115   ;; statment must have a break statement for it to return
 116   ;; after the alert. Otherwise it continues on the next
 117   ;; clause.
 118   (switch (aref blorg i)
 119      (1 (alert "one"))
 120      (2 (alert "two"))
 121      (default (alert "default clause")))
 122   "switch (blorg[i]) {
 123          case 1:   alert('one');
 124          case 2:   alert('two');
 125          default:   alert('default clause');
 126          };")
 127
 128 (test-ps-js lisp-like-case
 129    (case (aref blorg i)
 130      (1 (alert "one"))
 131      (2 (alert "two"))
 132      (default (alert "default clause")))
 133      "switch (blorg[i]) {
 134          case 1:
 135                    alert('one');
 136                    break;
 137          case 2:
 138                    alert('two');
 139                    break;
 140          default:   alert('default clause');
 141          };")
 142
 143
 144 (test-ps-js even-lispier-case
 145   (case (aref blorg i)
 146       ((1 2) (alert "Below three"))
 147       (3 (alert "Three"))
 148       (t (alert "Something else")))
 149    "switch (blorg[i]) {
 150          case 1:
 151          case 2:
 152                    alert('Below three');
 153                    break;
 154          case 3:
 155                    alert('Three');
 156                    break;
 157          default:   alert('Something else');
 158     };")
 159
 160 (test-ps-js otherwise-case
 161    (case (aref blorg i)
 162      (1 (alert "one"))
 163      (otherwise (alert "default clause")))
 164      "switch (blorg[i]) {
 165          case 1:
 166                    alert('one');
 167                    break;
 168          default:   alert('default clause');
 169          };")
 170
 171 (test escape-sequences-in-string
 172   (let ((escapes `((#\\ . #\\)
 173                    (#\b . #\Backspace)
 174                    (#\f . ,(code-char 12))
 175                    ("u000B" . ,(code-char #x000b));;Vertical tab, too uncommon to bother with
 176                    (#\n . #\Newline)
 177                    (#\r . #\Return)
 178                    (#\' . #\');;Double quote need not be quoted because parenscript strings are single quoted
 179                    (#\t . #\Tab)
 180                    ("u001F" . ,(code-char #x001f));; character below 32
 181                    ("u0080" . ,(code-char 128)) ;;Character over 127. Actually valid, parenscript escapes them to be sure.
 182                    ("uABCD" . ,(code-char #xabcd)))));; Really above ascii.
 183     (loop for (js-escape . lisp-char) in escapes
 184           for generated = (ps-doc* `(let ((x ,(format nil "hello~ahi" lisp-char)))))
 185           for wanted = (format nil "var x = 'hello\\~ahi';" js-escape)
 186           do (is (string= (normalize-js-code generated) wanted)))))
 187
 188 (test-ps-js slot-value-setf
 189   (setf (slot-value x 'y) (+ (+ a 3) 4))
 190   "x.y = (a + 3) + 4;")
 191
 192 (test-ps-js slot-value-conditional1
 193   (slot-value (if zoo foo bar) 'x)
 194   "(zoo ? foo : bar).x;")
 195
 196 (test-ps-js slot-value-conditional2
 197   (slot-value (if (not zoo) foo bar) 'x)
 198   "(!zoo ? foo : bar).x;")
 199
 200 (test script-star-eval1
 201   (is (string= "x = 1; y = 2;" (normalize-js-code (ps* '(setf x 1) '(setf y 2))))))
 202
 203 (test script-star-eval2
 204   (is (string= "x = 1;" (normalize-js-code (ps* '(setf x 1))))))
 205
 206 (test-ps-js unquoted-nil
 207   nil
 208   "null;")
 209
 210 (test-ps-js list-with-single-nil
 211   (array nil)
 212   "[null];")
 213
 214 (test-ps-js quoted-nil-is-array
 215   'nil
 216   "[];")
 217
 218 (test-ps-js defsetf1
 219   (progn (defsetf baz (x y) (newval) `(set-baz ,x ,y ,newval))
 220          (setf (baz 1 2) 3))
 221   "var _js2 = 1;
 222 var _js3 = 2;
 223 var _js1 = 3;
 224 setBaz(_js2, _js3, _js1);")
 225
 226 (test-ps-js setf-macroexpands1
 227   (macrolet ((baz (x y) `(aref ,x ,y 1)))
 228     (setf (baz foo 2) 3))
 229   "foo[2][1] = 3;")
 230
 231 (test-ps-js defsetf-short
 232   (progn (defsetf baz set-baz "docstring")
 233          (setf (baz 1 2 3) "foo"))
 234   "setBaz(1, 2, 3, 'foo');")
 235
 236 (test-ps-js defun-setf1
 237   (progn (defun (setf some-thing) (new-val i1 i2)
 238            (setf (aref *some-thing* i1 i2) new-val))
 239          (setf (some-thing 1 2) "foo"))
 240 "function __setf_someThing(newVal, i1, i2) {
 241     SOMETHING[i1][i2] = newVal;
 242 };
 243 var _js2 = 1;
 244 var _js3 = 2;
 245 var _js1 = 'foo';
 246 __setf_someThing(_js1, _js2, _js3);")
 247
 248 (test-ps-js defun-optional1
 249   (defun test-opt (&optional x) (return (if x "yes" "no")))
 250   "function testOpt(x) {
 251     if (x === undefined) {
 252         x = null;
 253     };
 254     return x ? 'yes' : 'no';
 255 };")
 256
 257 (test-ps-js defun-optional2
 258   (defun foo (x &optional y) (+ x y))
 259   "function foo(x, y) {
 260     if (y === undefined) {
 261         y = null;
 262     };
 263     x + y;
 264 };")
 265
 266 (test-ps-js defun-optional3
 267   (defun blah (&optional (x 0))
 268     (return x))
 269   "function blah(x) {
 270     if (x === undefined) {
 271         x = 0;
 272     };
 273     return x;
 274 };")
 275
 276 (test-ps-js return-nothing
 277   (return)
 278   "return null;")
 279
 280 (test-ps-js set-timeout
 281   (do-set-timeout (10) (alert "foo"))
 282   "setTimeout(function () { alert('foo'); }, 10);")
 283
 284 (test-ps-js operator-precedence
 285   (* 3 (+ 4 5) 6)
 286   "3 * (4 + 5) * 6;")
 287
 288 (test-ps-js operators-1
 289   (in prop obj)
 290   "prop in obj;")
 291
 292 (test-ps-js incf1
 293   (incf foo bar)
 294   "foo += bar;")
 295
 296 (test-ps-js decf1
 297   (decf foo bar)
 298   "foo -= bar;")
 299
 300 (test-ps-js incf2
 301   (incf x 5)
 302   "x += 5;")
 303
 304 (test-ps-js decf2
 305   (decf y 10)
 306   "y -= 10;")
 307
 308 (test-ps-js setf-conditional
 309   (setf foo (if x 1 2))
 310   "foo = x ? 1 : 2;")
 311
 312 (test-ps-js obj-literal-numbers
 313   (create 1 "foo")
 314   "{ 1 : 'foo' };")
 315
 316 (test-ps-js obj-literal-strings
 317   (create "foo" 2)
 318   "{ 'foo' : 2 };")
 319
 320 (test-ps-js slot-value-string
 321   (slot-value foo "bar")
 322   "foo['bar'];")
 323
 324 (test-ps-js slot-value-string1
 325   (slot-value "bar" 'length)
 326   "'bar'.length;")
 327
 328 (test-ps-js slot-value-progn
 329   (slot-value (progn (some-fun "abc") "123") "length")
 330   "(someFun('abc'), '123')['length'];")
 331
 332 (test-ps-js method-call-block
 333   ((@ (progn (some-fun "abc") "123") to-string))
 334   "(someFun('abc'), '123').toString();")
 335
 336 (test-ps-js create-blank
 337   (create)
 338   "{ };")
 339
 340 (test-ps-js blank-object-literal
 341   {}
 342   "{ };")
 343
 344 (test-ps-js array-literal1
 345   []
 346   "[];")
 347
 348 (test-ps-js array-literal2
 349   ([])
 350   "[];")
 351
 352 (test-ps-js array-literal3
 353   ([] 1 2 3)
 354   "[1, 2, 3];")
 355
 356 (test-ps-js array-literal4
 357   ([] 1 (2 3))
 358   "[1, [2, 3]];")
 359
 360 (test-ps-js array-literal5
 361   ([] (1 2) ("a" "b"))
 362   "[[1, 2], ['a', 'b']];")
 363
 364 (test-ps-js defun-rest1
 365   (defun foo (&rest bar) (alert (aref bar 1)))
 366   "function foo() {
 367     var bar = [];
 368     for (var i1 = 0; i1 < arguments.length - 0; i1 += 1) {
 369         bar[i1] = arguments[i1 + 0];
 370     };
 371     alert(bar[1]);
 372 };")
 373
 374 (test-ps-js defun-rest2
 375   (defun foo (baz &rest bar) (return (+ baz (aref bar 1))))
 376   "function foo(baz) {
 377     var bar = [];
 378     for (var i1 = 0; i1 < arguments.length - 1; i1 += 1) {
 379         bar[i1] = arguments[i1 + 1];
 380     };
 381     return baz + bar[1];
 382 };")
 383
 384 (test-ps-js defun-keyword1
 385   (defun zoo (foo bar &key baz) (return (+ foo bar baz)))
 386 "function zoo(foo, bar) {
 387     var baz;
 388     var _js2 = arguments.length;
 389     for (var n1 = 2; n1 < _js2; n1 += 2) {
 390         switch (arguments[n1]) {
 391         case 'baz':
 392             {
 393                 baz = arguments[n1 + 1];
 394             };
 395         };
 396     };
 397     if (baz === undefined) {
 398         baz = null;
 399     };
 400     return foo + bar + baz;
 401 };")
 402
 403 (test-ps-js defun-keyword2
 404   (defun zoo (&key baz) (return (* baz baz)))
 405   "function zoo() {
 406     var baz;
 407     var _js2 = arguments.length;
 408     for (var n1 = 0; n1 < _js2; n1 += 2) {
 409         switch (arguments[n1]) {
 410         case 'baz':
 411             {
 412                 baz = arguments[n1 + 1];
 413             };
 414         };
 415     };
 416     if (baz === undefined) {
 417         baz = null;
 418     };
 419     return baz * baz;
 420 };")
 421
 422 (test-ps-js defun-keyword3
 423   (defun zoo (&key baz (bar 4)) (return (* baz bar)))
 424   "function zoo() {
 425     var baz;
 426     var bar;
 427     var _js2 = arguments.length;
 428     for (var n1 = 0; n1 < _js2; n1 += 2) {
 429         switch (arguments[n1]) {
 430         case 'baz':
 431             {
 432                 baz = arguments[n1 + 1];
 433             };
 434             break;
 435         case 'bar':
 436             {
 437                 bar = arguments[n1 + 1];
 438             };
 439         };
 440     };
 441     if (baz === undefined) {
 442         baz = null;
 443     };
 444     if (bar === undefined) {
 445         bar = 4;
 446     };
 447     return baz * bar;
 448 };")
 449
 450 (test-ps-js defun-keyword4
 451   (defun hello-world (&key ((:my-name-key my-name) 1))
 452     my-name)
 453   "function helloWorld() {
 454     var myName;
 455     var _js2 = arguments.length;
 456     for (var n1 = 0; n1 < _js2; n1 += 2) {
 457         switch (arguments[n1]) {
 458         case 'my-name-key':
 459             {
 460                 myName = arguments[n1 + 1];
 461             };
 462         };
 463     };
 464     if (myName === undefined) {
 465         myName = 1;
 466     };
 467     myName;
 468 };")
 469
 470 (test-ps-js keyword-funcall1
 471   (func :baz 1)
 472   "func('baz', 1);")
 473
 474 (test-ps-js keyword-funcall2
 475   (func :baz 1 :bar foo)
 476   "func('baz', 1, 'bar', foo);")
 477
 478 (test-ps-js keyword-funcall3
 479   (fun a b :baz c)
 480   "fun(a, b, 'baz', c);")
 481
 482 (test-ps-js cond1
 483   (cond ((= x 1) 1))
 484   "if (x == 1) {
 485     1;
 486 };")
 487
 488 (test-ps-js cond2
 489   (cond ((= x 1) 2)
 490         ((= y (* x 4)) (foo "blah") (* x y)))
 491   "if (x == 1) {
 492     2;
 493 } else if (y == x * 4) {
 494     foo('blah');
 495     x * y;
 496 };")
 497
 498 (test-ps-js if-exp-without-else-returns-null
 499   (return (if x 1))
 500   "return x ? 1 : null;")
 501
 502 (test-ps-js progn-expression-single-statement
 503   (return (progn (* x y)))
 504   "return x * y;")
 505
 506 (test-ps-js cond-expression1
 507   (defun foo () (return (cond ((< 1 2) (bar "foo") (* 4 5)))))
 508   "function foo() {
 509     return 1 < 2 ? (bar('foo'), 4 * 5) : null;
 510 };")
 511
 512 (test-ps-js cond-expression2
 513   (defun foo () (return (cond ((< 2 1) "foo") ((= 7 7) "bar"))))
 514   "function foo() {
 515     return 2 < 1 ? 'foo' : (7 == 7 ? 'bar' : null);
 516 };")
 517
 518 (test-ps-js cond-expression-final-t-clause
 519   (defun foo ()
 520     (return (cond ((< 1 2) (bar "foo") (* 4 5))
 521                   ((= a b) (+ c d))
 522                   ((< 1 2 3 4 5) x)
 523                   (t "foo"))))
 524   "function foo() {
 525     var _cmp3;
 526     var _cmp2;
 527     var _cmp1;
 528     return 1 < 2 ? (bar('foo'), 4 * 5) : (a == b ? c + d : ((_cmp1 = 2, _cmp2 = 3, _cmp3 = 4, 1 < _cmp1 && _cmp1 < _cmp2 && _cmp2 < _cmp3 && _cmp3 < 5) ? x : 'foo'));
 529 };")
 530
 531 (test-ps-js cond-expression-middle-t-clause ;; should this signal a warning?
 532   (defun foo () (return (cond ((< 2 1) 5) (t "foo") ((< 1 2) "bar"))))
 533   "function foo() {
 534     return 2 < 1 ? 5 : 'foo';
 535 };")
 536
 537 (test-ps-js funcall-if-expression
 538   ((@ document write)
 539    (if (= *linkornot* 1)
 540        (ps-html ((:a :href "#"
 541                      :onclick (ps-inline (transport)))
 542                  img))
 543        img))
 544   "document.write(LINKORNOT == 1 ? '<A HREF=\"#\" ONCLICK=\"' + ('javascript:' + 'transport()') + '\">' + img + '</A>' : img);")
 545
 546 (test-ps-js negate-number-literal ;; ok, this was broken and fixed before, but no one bothered to add the test!
 547   (- 1)
 548   "-1;")
 549
 550 (test macro-environment1
 551   (is (string= (normalize-js-code (let* ((macroname (gensym)))
 552                                     (ps* `(defmacro ,macroname (x) `(+ ,x 123))
 553                                          `(defun test1 ()
 554                                            (macrolet ((,macroname (x) `(aref data ,x)))
 555                                              (when (,macroname x)
 556                                                (setf (,macroname x) 123)))))))
 557                (normalize-js-code
 558 "function test1() {
 559     if (data[x]) {
 560         data[x] = 123;
 561     };
 562 };
 563 "))))
 564
 565 (test macro-environment2
 566   (is (string= (normalize-js-code (let ((outer-lexical-variable 1))
 567                                     (defpsmacro macro-environment2-macro (x)
 568                                       `(+ ,outer-lexical-variable ,x))
 569                                     (ps* '(macro-environment2-macro 2))))
 570                (normalize-js-code "1 + 2;"))))
 571
 572 (test-ps-js ampersand-whole-1
 573   (macrolet ((foo (&whole foo bar baz)
 574                (declare (ignore bar baz))
 575                (format nil "~a" foo)))
 576     (foo 1 2))
 577   "'(FOO 1 2)';")
 578
 579 (test-ps-js keyword-consistent
 580   :x
 581   "'x';")
 582
 583 (test-ps-js simple-symbol-macrolet
 584   (symbol-macrolet ((x 1)) x)
 585   "1;")
 586
 587 (test-ps-js compound-symbol-macrolet
 588   (symbol-macrolet ((x 123)
 589                     (y (* 2 x)))
 590      y)
 591   "2 * 123;")
 592
 593 (test-ps-js define-symbol-macro
 594   (progn (define-symbol-macro tst-sym-macro 2)
 595          tst-sym-macro)
 596   "2;")
 597
 598 (test-ps-js expression-progn
 599   (defun f () (return (progn (foo) (if x 1 2))))
 600   "function f() {
 601     return (foo(), x ? 1 : 2);
 602 };")
 603
 604 (test-ps-js let-decl-in-expression
 605   (defun f (x)
 606     (return (if x
 607                 1
 608                 (let* ((foo x))
 609                   foo))))
 610   "function f(x) {
 611     var foo;
 612     return x ? 1 : (foo = x, foo);
 613 };")
 614
 615 (test-ps-js special-var1
 616   (progn (defvar *foo*)
 617          (let* ((*foo* 2))
 618            (* *foo* 2)))
 619   "var FOO;
 620 var FOO_TMPSTACK1;
 621 try {
 622     FOO_TMPSTACK1 = FOO;
 623     FOO = 2;
 624     FOO * 2;
 625 } finally {
 626     FOO = FOO_TMPSTACK1;
 627 };")
 628
 629 (test-ps-js special-var2
 630   (progn (defvar *foo*)
 631          (let* ((*baz* 3)
 632                 (*foo* 2))
 633            (* *foo* 2 *baz*)))
 634   "var FOO;
 635 var BAZ = 3;
 636 var FOO_TMPSTACK1;
 637 try {
 638     FOO_TMPSTACK1 = FOO;
 639     FOO = 2;
 640     FOO * 2 * BAZ;
 641 } finally {
 642     FOO = FOO_TMPSTACK1;
 643 };")
 644
 645 (test-ps-js literal1
 646   (setf x undefined)
 647   "x = undefined;")
 648
 649 (test-ps-js literal2
 650   (aref this x)
 651   "this[x];")
 652
 653 (test-ps-js setf-dec1
 654   (setf x (- 1 x 2))
 655   "x = 1 - x - 2;")
 656
 657 (test-ps-js setf-dec2
 658   (setf x (- x 1 2))
 659   "x = x - 1 - 2;")
 660
 661 (test-ps-js special-char-equals
 662   blah=
 663   "blahequals;")
 664
 665 (test-ps-js setf-operator-priority
 666   (return (or (slot-value cache id)
 667               (setf (slot-value cache id) ((@ document get-element-by-id) id))))
 668   "return cache[id] || (cache[id] = document.getElementById(id));")
 669
 670 (test-ps-js aref-operator-priority
 671   (aref (if (and x (> (length x) 0))
 672             (aref x 0)
 673             y)
 674         z)
 675   "(x && x.length > 0 ? x[0] : y)[z];")
 676
 677 (test-ps-js aref-operator-priority1
 678   (aref (or (slot-value x 'y)
 679             (slot-value a 'b))
 680         z)
 681   "(x.y || a.b)[z];")
 682
 683 (test-ps-js aref-operator-priority2
 684   (aref (if a b c) 0)
 685   "(a ? b : c)[0];")
 686
 687 (test-ps-js negative-operator-priority
 688   (- (if x y z))
 689   "-(x ? y : z);")
 690
 691 (test-ps-js op-p1
 692   (new (or a b))
 693   "new (a || b);")
 694
 695 (test-ps-js op-p2
 696   (delete (if a (or b c) d))
 697   "delete (a ? b || c : d);")
 698
 699 (test-ps-js op-p3
 700   (not (if (or x (not y)) z))
 701   "!(x || !y ? z : null);")
 702
 703 (test-ps-js op-p4
 704   (- (- (* 1 2) 3))
 705   "-(1 * 2 - 3);")
 706
 707 (test-ps-js op-p5
 708   (instanceof (or a b) (if x y z))
 709   "((a || b) instanceof (x ? y : z));")
 710
 711 (test-ps-js op-p7
 712   (or x (if (= x 0) "zero" "empty"))
 713   "x || (x == 0 ? 'zero' : 'empty');")
 714
 715 (test-ps-js named-op-expression
 716   (throw (if a b c))
 717   "throw a ? b : c;")
 718
 719 (test-ps-js named-op-expression1
 720   (typeof (or x y))
 721   "typeof (x || y);")
 722
 723 (test-ps-js aref-array-expression
 724   (aref (or a b c) 0)
 725   "(a || b || c)[0];")
 726
 727 (test-ps-js slot-value-operator
 728   (slot-value (or a b c) 'd)
 729   "(a || b || c).d;")
 730
 731 (test-ps-js slot-value-parens
 732   (slot-value (slot-value foo 'bar) 'baz)
 733   "foo.bar.baz;")
 734
 735 (test-ps-js funcall-funcall
 736   ((foo))
 737   "foo()();")
 738
 739 (test-ps-js expression-funcall
 740   ((or (@ window eval) eval) foo nil)
 741   "(window.eval || eval)(foo, null);")
 742
 743 (test-ps-js expression-funcall1
 744   (((or (@ window eval) eval) foo nil))
 745   "(window.eval || eval)(foo, null)();")
 746
 747 (test-ps-js expression-funcall2
 748   (((or (@ window eval) eval)) foo nil)
 749   "(window.eval || eval)()(foo, null);")
 750
 751 (test-ps-js slot-value-object-literal
 752   (slot-value (create a 1) 'a)
 753   "({ a : 1 }).a;")
 754
 755 (test-ps-js slot-value-lambda
 756   (slot-value (lambda ()) 'prototype)
 757   "(function () { }).prototype;")
 758
 759 (test-ps-js who-html1
 760   (who-ps-html (:span :class "ticker-symbol"
 761                       :ticker-symbol symbol
 762                       (:a :href "http://foo.com"
 763                           symbol)
 764                       (:span :class "ticker-symbol-popup")))
 765   "'<SPAN CLASS=\"ticker-symbol\" TICKER-SYMBOL=\"' + symbol + '\"><A HREF=\"http://foo.com\">' + symbol + '</A><SPAN CLASS=\"ticker-symbol-popup\"></SPAN></SPAN>';")
 766
 767 (test-ps-js flet1
 768   ((lambda () (flet ((foo (x)
 769                        (return (1+ x))))
 770                 (return (foo 1)))))
 771   "(function () {
 772     var foo1 = function (x) {
 773         return x + 1;
 774     };
 775     return foo1(1);
 776 })();")
 777
 778 (test-ps-js flet2
 779   (flet ((foo (x) (return (1+ x)))
 780          (bar (y) (return (+ 2 y))))
 781     (bar (foo 1)))
 782 "var foo1 = function (x) {
 783     return x + 1;
 784 };
 785 var bar2 = function (y) {
 786     return 2 + y;
 787 };
 788 bar2(foo1(1));")
 789
 790 (test-ps-js flet3
 791   (flet ((foo (x) (return (1+ x)))
 792          (bar (y) (return (+ 2 (foo y)))))
 793     (bar (foo 1)))
 794   "var foo1 = function (x) {
 795     return x + 1;
 796 };
 797 var bar2 = function (y) {
 798     return 2 + foo(y);
 799 };
 800 bar2(foo1(1));")
 801
 802 (test-ps-js labels1
 803   ((lambda () (labels ((foo (x)
 804                          (return (if (=== 0 x)
 805                                      0
 806                                      (+ x (foo (1- x)))))))
 807                 (return (foo 3)))))
 808   "(function () {
 809     var foo1 = function (x) {
 810         return 0 === x ? 0 : x + foo1(x - 1);
 811     };
 812     return foo1(3);
 813 })();")
 814
 815 (test-ps-js labels2
 816   (labels ((foo (x) (return (1+ (bar x))))
 817            (bar (y) (return (+ 2 (foo y)))))
 818     (bar (foo 1)))
 819   "var foo1 = function (x) {
 820     return bar2(x) + 1;
 821 };
 822 var bar2 = function (y) {
 823     return 2 + foo1(y);
 824 };
 825 bar2(foo1(1));")
 826
 827 (test-ps-js labels3
 828   (labels ((foo (x) (return (1+ x)))
 829            (bar (y) (return (+ 2 (foo y)))))
 830     (bar (foo 1)))
 831   "var foo1 = function (x) {
 832     return x + 1;
 833 };
 834 var bar2 = function (y) {
 835     return 2 + foo1(y);
 836 };
 837 bar2(foo1(1));")
 838
 839 (test-ps-js for-loop-var-init-exp
 840   ((lambda (x)
 841      (return (do* ((y (if x 0 1) (1+ y))
 842                    (z 0 (1+ z)))
 843                   ((= y 3) z))))
 844    true)
 845   "(function (x) {
 846     return (function () {
 847         for (var y = x ? 0 : 1, z = 0; y != 3; y += 1, z += 1) {
 848         };
 849         return z;
 850     })();
 851 })(true);")
 852
 853 (test-ps-js math-pi
 854   pi
 855   "Math.PI;")
 856
 857 (test-ps-js literal-array
 858   '(1 2 3)
 859   "[1, 2, 3];")
 860
 861 (test-ps-js literal-array-1
 862   '(1 foo 3)
 863   "[1, 'foo', 3];")
 864
 865 (test ps-lisp-expands-in-lexical-environment
 866   (is (string= "5;" (let ((x 5)) (ps (lisp x))))))
 867
 868 (test ps*-lisp-expands-in-null-lexical-environment
 869   (signals error (let ((x 5)) (declare (ignore x)) (ps* '(lisp x)))))
 870
 871 (test ps*-lisp-expands-in-dynamic-environment
 872   (is (string= "1 + 2;" (let ((*print-level* 2)) (ps* '(+ 1 (lisp *print-level*)))))))
 873
 874 (test ps-lisp-dynamic-environment
 875   (is (string= "1 + 2;" (let ((*print-level* 2)) (ps (+ 1 (lisp *print-level*)))))))
 876
 877 (test-ps-js ps-js-target-version-keyword-test1
 878   (defun foo (x y &key bar baz))
 879   "function foo(x, y) {
 880     var x1 = Array.prototype.indexOf.call(arguments, 'bar', 2);
 881     var bar = -1 == x1 ? null : arguments[x1 + 1];
 882     var x2 = Array.prototype.indexOf.call(arguments, 'baz', 2);
 883     var baz = -1 == x2 ? null : arguments[x2 + 1];
 884 };"
 885   :js-target-version 1.6)
 886
 887 (test-ps-js nested-if-expressions1
 888   (return (if (if x y z) a b))
 889   "return (x ? y : z) ? a : b;")
 890
 891 (test-ps-js nested-if-expressions2
 892   (return (if x y (if z a b)))
 893   "return x ? y : (z ? a : b);")
 894
 895 (test-ps-js let1
 896   (let (x)
 897     (+ x x))
 898   "var x = null;
 899 x + x;")
 900
 901 (test-ps-js let2
 902   (let ((x 1))
 903     (+ x x))
 904   "var x = 1;
 905 x + x;")
 906
 907 (test-ps-js let-x-x
 908   (let ((x (1+ x)))
 909     (+ x x))
 910   "var x1 = x + 1;
 911 x1 + x1;")
 912
 913 (test-ps-js let3
 914   (let ((x 1)
 915         (y 2))
 916     (+ x x))
 917   "var x = 1;
 918 var y = 2;
 919 x + x;")
 920
 921 (test-ps-js let4
 922   (let ((x 1)
 923         (y (1+ x)))
 924     (+ x y))
 925   "var x1 = 1;
 926 var y = x + 1;
 927 x1 + y;")
 928
 929 (test-ps-js let5
 930   (let ((x 1))
 931     (+ x 1)
 932     (let ((x (+ x 5)))
 933       (+ x 1))
 934     (+ x 1))
 935   "var x = 1;
 936 x + 1;
 937 var x1 = x + 5;
 938 x1 + 1;
 939 x + 1;")
 940
 941 (test-ps-js let6
 942   (let ((x 2))
 943     (let ((x 1)
 944           (y (1+ x)))
 945       (+ x y)))
 946   "var x = 2;
 947 var x1 = 1;
 948 var y = x + 1;
 949 x1 + y;")
 950
 951 (test-ps-js let-exp1
 952   (lambda ()
 953     (return (let (x) (+ x x))))
 954   "function () {
 955     var x;
 956     return (x = null, x + x);
 957 };")
 958
 959 (test-ps-js let*1
 960   (let* ((x 1)) (+ x x))
 961 "var x = 1;
 962 x + x;")
 963
 964 (test-ps-js let*2
 965   (let* ((x 1)
 966          (y (+ x 2)))
 967     (+ x y))
 968   "var x = 1;
 969 var y = x + 2;
 970 x + y;")
 971
 972 (test-ps-js let*3
 973   (let ((x 3))
 974         (let* ((x 1)
 975                (y (+ x 2)))
 976           (+ x y)))
 977   "var x = 3;
 978 var x1 = 1;
 979 var y = x1 + 2;
 980 x1 + y;")
 981
 982 (test-ps-js let*4
 983   (let ((x 3))
 984         (let* ((y (+ x 2))
 985                (x 1))
 986           (+ x y)))
 987   "var x = 3;
 988 var y = x + 2;
 989 var x1 = 1;
 990 x1 + y;")
 991
 992 (test-ps-js symbol-macrolet-var
 993   (symbol-macrolet ((x y))
 994     (var x))
 995   "var y;")
 996
 997 (test-ps-js setf-conditional1
 998   (setf x (unless (null a) (1+ a)))
 999   "x = a != null ? a + 1 : null;")
1000
1001 (test-ps-js setf-let1
1002   (setf x (let ((a 1)) a))
1003   "x = (a = 1, a);")
1004
1005 (test-ps-js setf-let2
1006   (setf x (let ((a (foo)))
1007             (unless (null a)
1008               (1+ a))))
1009   "x = (a = foo(), a != null ? a + 1 : null);")
1010
1011 (test-ps-js symbol-macro-env1
1012   (symbol-macrolet ((bar 1))
1013     (macrolet ((bar (x y) `(+ ,x ,y)))
1014       (bar bar bar)))
1015   "1 + 1;")
1016
1017 (test-ps-js symbol-macrolet-fun1
1018   (symbol-macrolet ((baz +))
1019     (baz 1 2))
1020   "baz(1, 2);")
1021
1022 (test-ps-js lisp2-namespaces1
1023   (let ((list nil))
1024     (setf list (list 1 2 3)))
1025   "var list = null;
1026 list = [1, 2, 3];")
1027
1028 (test-ps-js let-shadows-symbol-macrolet
1029   (symbol-macrolet ((x y))
1030     (let ((x 1))
1031       (+ x x))
1032     (+ x x))
1033   "var x1 = 1;
1034 x1 + x1;
1035 y + y;")
1036
1037 (test-ps-js let-rename-optimization1
1038   (let ((x 1))
1039     (+ x x))
1040   "var x = 1;
1041 x + x;")
1042
1043 (test-ps-js let-rename-optimization2
1044   (lambda (x)
1045     (let ((x (+ 1 x)))
1046       (return x)))
1047   "function (x) {
1048     var x1 = 1 + x;
1049     return x1;
1050 };")
1051
1052 (test-ps-js symbol-macro-array
1053   (symbol-macrolet ((x 1))
1054     (list x))
1055   "[1];")
1056
1057 (test-ps-js symbol-macro-obj
1058   (symbol-macrolet ((x y))
1059     (create x 1))
1060   "{ y : 1 };")
1061
1062 (test-ps-js symbol-macro-conditional1
1063   (symbol-macrolet ((x y))
1064     (if x x x))
1065   "if (y) {
1066     y;
1067 } else {
1068     y;
1069 };")
1070
1071 (test-ps-js symbol-macro-conditional2
1072   (symbol-macrolet ((x y))
1073     (return (if x x x)))
1074   "return y ? y : y;")
1075
1076 (test-ps-js flet-apply
1077   (flet ((foo () 'bar))
1078     (apply (function foo) nil))
1079   "var foo1 = function () {
1080     'bar';
1081 };
1082 foo1.apply(this, null);")
1083
1084 (test-ps-js let-apply
1085   (let ((foo (lambda () (return 1))))
1086     (let ((foo (lambda () (return 2))))
1087       (apply foo nil)))
1088   "var foo = function () {
1089     return 1;
1090 };
1091 var foo1 = function () {
1092     return 2;
1093 };
1094 foo1.apply(this, null);")
1095
1096 (test-ps-js flet-let
1097   (flet ((x (x) (return (1+ x))))
1098     (let ((x 2))
1099       (x x)))
1100   "var x1 = function (x) {
1101     return x + 1;
1102 };
1103 var x = 2;
1104 x1(x);")
1105
1106 (test-ps-js let-flet
1107   (let ((x 2))
1108     (flet ((x (x) (return (1+ x))))
1109       (x x)))
1110   "var x = 2;
1111 var x1 = function (x) {
1112     return x + 1;
1113 };
1114 x1(x);")
1115
1116 (test-ps-js macrolet-let-inteference
1117   (macrolet ((a (n) `(+ ,n 5)))
1118     (let ((a (a 1)))
1119       (let ((b (a (- a 4))))
1120         (+ a b))))
1121   "var a = 1 + 5;
1122 var b = (a - 4) + 5;
1123 a + b;")
1124
1125 (test-ps-js let-subtract-add
1126   (let ((x 1))
1127     (let ((x 2))
1128       (- x x)
1129       (- x)
1130       (decf x)
1131       (incf x)))
1132   "var x = 1;
1133 var x1 = 2;
1134 x1 - x1;
1135 -x1;
1136 --x1;
1137 ++x1;")
1138
1139 (test-ps-js create-reserved-word
1140   (create :default 1)
1141   "{ 'default' : 1 };")
1142
1143 (test-ps-js slot-value-reserved-word
1144   (slot-value foo :default)
1145   "foo['default'];")
1146
1147 (test-ps-js eval-when-ps-side
1148   (eval-when (:execute)
1149     5)
1150   "5;")
1151
1152 (defvar *lisp-output* nil)
1153
1154 (test eval-when-lisp-side ()
1155     (setf *lisp-output* 'original-value)
1156     (let ((js-output (normalize-js-code
1157               (ps-doc* `(eval-when (:compile-toplevel)
1158                   (setf *lisp-output* 'it-works))))))
1159       (is (eql 'it-works *lisp-output*))
1160       (is (string= "" js-output))))
1161
1162 (defpsmacro my-in-package (package-name)
1163   `(eval-when (:compile-toplevel)
1164      (setf *lisp-output* ,package-name)))
1165
1166 (test eval-when-macro-expansion ()
1167     (setf *lisp-output* 'original-value)
1168     (let ((js-output (normalize-js-code
1169               (ps-doc* `(progn
1170                   (my-in-package :cl-user)
1171                   3)))))
1172       (declare (ignore js-output))
1173       (is (eql :cl-user *lisp-output*))))
1174
1175 (test eval-when-macrolet-expansion ()
1176     (setf *lisp-output* 'original-value)
1177     (let ((js-output (normalize-js-code
1178               (ps-doc* `(macrolet ((my-in-package2 (package-name)
1179                          `(eval-when (:compile-toplevel)
1180                         (setf *lisp-output* ,package-name))))
1181                   (my-in-package2 :cl-user)
1182                   3)))))
1183       (declare (ignore js-output))
1184       (is (eql :cl-user *lisp-output*))))
1185
1186 (test-ps-js slot-value-keyword
1187   (slot-value foo :bar)
1188   "foo['bar'];")
1189
1190 (test-ps-js nary-comparison1
1191   (lambda () (return (< 1 2 3)))
1192   "function () {
1193     var _cmp1;
1194     return (_cmp1 = 2, 1 < _cmp1 && _cmp1 < 3);
1195 };")
1196
1197 (test-ps-js chain-slot-value1
1198   (chain ($ "foo") (bar x z) frob (baz 5))
1199   "$('foo').bar(x, z).frob.baz(5);")
1200
1201 (test-ps-js chain-slot-value2
1202   (chain ($ "foo") bar baz)
1203   "$('foo').bar.baz;")
1204
1205 (test-ps-js chain-slot-value3
1206   (chain ($ "foo") bar (x y) baz)
1207   "$('foo').bar.x(y).baz;")