src/printer.lisp

   1 (in-package "PARENSCRIPT")
   2
   3 (defvar *ps-print-pretty* t)
   4 (defvar *indent-num-spaces* 4)
   5 (defvar *js-string-delimiter* #\'
   6   "Specifies which character should be used for delimiting strings.
   7
   8 This variable is used when you want to embed the resulting JavaScript
   9 in an html attribute delimited by #\\\" as opposed to #\\', or
  10 vice-versa.")
  11
  12 (defvar *indent-level*)
  13
  14 (defvar *psw-stream*)
  15
  16 (defun parenscript-print (form immediate?)
  17   (declare (special immediate?))
  18   (let ((*indent-level* 0)
  19         (*psw-stream* (if immediate?
  20                           *psw-stream*
  21                           (make-string-output-stream)))
  22         (%psw-accumulator ()))
  23     (declare (special %psw-accumulator))
  24     (if (and (listp form) (eq 'js:block (car form))) ; ignore top-level block
  25         (loop for (statement . remaining) on (cdr form) do
  26              (ps-print statement) (psw #\;) (when remaining (psw #\Newline)))
  27         (ps-print form))
  28     (unless immediate?
  29       (reverse (cons (get-output-stream-string *psw-stream*) %psw-accumulator)))))
  30
  31 (defun psw (obj)
  32   (declare (special %psw-accumulator immediate?))
  33   (typecase obj
  34     (string (write-string obj *psw-stream*))
  35     (character (write-char obj *psw-stream*))
  36     (otherwise
  37      (if immediate?
  38          (write-string (eval obj) *psw-stream*)
  39          (setf %psw-accumulator
  40                (cons obj
  41                      (cons (get-output-stream-string *psw-stream*)
  42                            %psw-accumulator)))))))
  43
  44 (defgeneric ps-print% (special-form-name special-form-args))
  45
  46 (defmacro defprinter (special-form content-args &body body)
  47   "Given a special-form name and a destructuring lambda-list for its
  48 arguments, defines a printer for that form using the given body."
  49   (let ((sf (gensym))
  50         (sf-args (gensym)))
  51     `(defmethod ps-print% ((,sf (eql ',special-form)) ,sf-args)
  52       (declare (ignorable ,sf))
  53       (destructuring-bind ,content-args
  54           ,sf-args
  55         ,@body))))
  56
  57 (defgeneric ps-print (compiled-form))
  58
  59 (defmethod ps-print ((form null))) ; don't print top-level nils (ex: result of defining macros, etc.)
  60
  61 (defmethod ps-print ((s symbol))
  62   (assert (keywordp s) nil "~S is not a symbol" s)
  63   (ps-print (string-downcase s)))
  64
  65 (defmethod ps-print ((compiled-form cons))
  66   (ps-print% (car compiled-form) (cdr compiled-form)))
  67
  68 (defun newline-and-indent ()
  69   (if *ps-print-pretty*
  70       (progn (psw #\Newline)
  71              (loop repeat (* *indent-level* *indent-num-spaces*) do (psw #\Space)))
  72       (psw #\Space)))
  73
  74 (defparameter *js-lisp-escaped-chars*
  75   '((#\' . #\')
  76     (#\\ . #\\)
  77     (#\b . #\Backspace)
  78     (#\f . #.(code-char 12))
  79     (#\n . #\Newline)
  80     (#\r . #\Return)
  81     (#\t . #\Tab)))
  82
  83 (defmethod ps-print ((string string))
  84   (flet ((lisp-special-char-to-js (lisp-char)
  85            (car (rassoc lisp-char *js-lisp-escaped-chars*))))
  86     (psw *js-string-delimiter*)
  87     (loop for char across string
  88           for code = (char-code char)
  89           for special = (lisp-special-char-to-js char)
  90           do (cond (special (psw #\\) (psw special))
  91                    ((or (<= code #x1f) (>= code #x80)) (format *psw-stream* "\\u~4,'0x" code))
  92                    (t (psw char))))
  93     (psw *js-string-delimiter*)))
  94
  95 (defmethod ps-print ((number number))
  96   (format *psw-stream* (if (integerp number) "~S" "~F") number))
  97
  98 ;;; expression and operator precedence rules
  99
 100 (defun expression-precedence (expr)
 101   (if (consp expr)
 102       (case (car expr)
 103         ((js:slot-value js:aref) (op-precedence (car expr)))
 104         (js:= (op-precedence 'js:=))
 105         (js:? (op-precedence 'js:?))
 106         (js:unary-operator (op-precedence (second expr)))
 107         (operator (op-precedence (second expr)))
 108         (otherwise -1))
 109       -1))
 110
 111 (defprinter js:literal (str)
 112   (psw str))
 113
 114 (defun print-comma-delimited-list (ps-forms)
 115   (loop for (form . remaining) on ps-forms do
 116         (ps-print form) (when remaining (psw ", "))))
 117
 118 (defprinter js:array (&rest initial-contents)
 119   (psw #\[) (print-comma-delimited-list initial-contents) (psw #\]))
 120
 121 (defprinter js:aref (array indices)
 122   (if (>= (expression-precedence array) (op-precedence 'js:aref))
 123       (parenthesize-print array)
 124       (ps-print array))
 125   (loop for idx in indices do
 126         (psw #\[) (ps-print idx) (psw #\])))
 127
 128 (defvar *lexical-bindings* nil)
 129
 130 (defun rename-js-variable (name)
 131   (or (cdr (assoc name *lexical-bindings*))
 132       name))
 133
 134 (defprinter js:let (variables expression)
 135   (let ((*lexical-bindings*
 136          (append (mapcar (lambda (var)
 137                            (cons var (if (assoc var *lexical-bindings*)
 138                                          (ps-gensym var)
 139                                          var)))
 140                          variables))))
 141     (ps-print expression)))
 142
 143 (defprinter js:variable (var)
 144   (psw (symbol-to-js-string (rename-js-variable var))))
 145
 146 ;;; arithmetic operators
 147 (defun parenthesize-print (ps-form)
 148   (psw #\() (ps-print ps-form) (psw #\)))
 149
 150 (defprinter js:operator (op &rest args)
 151   (loop for (arg . remaining) on args
 152         with precedence = (op-precedence op) do
 153         (if (>= (expression-precedence arg) precedence)
 154             (parenthesize-print arg)
 155             (ps-print arg))
 156         (when remaining (format *psw-stream* " ~(~A~) " op))))
 157
 158 (defprinter js:unary-operator (op arg &key prefix space)
 159   (when prefix (format *psw-stream* "~(~a~)~:[~; ~]" op space))
 160   (if (> (expression-precedence arg)
 161          (op-precedence (case op
 162                           (+ 'unary+)
 163                           (- 'unary-)
 164                           (t op))))
 165       (parenthesize-print arg)
 166       (ps-print arg))
 167   (unless prefix (format *psw-stream* "~(~a~)" op)))
 168
 169 (defprinter js:funcall (fun-designator &rest args)
 170   (funcall (if (member (car fun-designator) '(js:variable js:aref js:slot-value js:funcall))
 171                #'ps-print
 172                #'parenthesize-print)
 173            fun-designator)
 174   (psw #\() (print-comma-delimited-list args) (psw #\)))
 175
 176 (defprinter js:|,| (&rest expressions)
 177   (psw #\()
 178   (loop for (exp . remaining) on expressions do
 179        (ps-print exp) (when remaining (psw ", ")))
 180   (psw #\)))
 181
 182 (defprinter js:block (&rest statements)
 183   (psw #\{)
 184   (incf *indent-level*)
 185   (dolist (statement statements)
 186     (newline-and-indent) (ps-print statement) (psw #\;))
 187   (decf *indent-level*)
 188   (newline-and-indent)
 189   (psw #\}))
 190
 191 (defprinter js:lambda (args body)
 192   (print-fun-def nil args body))
 193
 194 (defprinter js:defun (name args body)
 195   (print-fun-def name args body))
 196
 197 (defun print-fun-def (name args body-block)
 198   (format *psw-stream* "function ~:[~;~A~](" name (symbol-to-js-string name))
 199   (loop for (arg . remaining) on args do
 200         (psw (symbol-to-js-string arg)) (when remaining (psw ", ")))
 201   (psw ") ")
 202   (ps-print body-block))
 203
 204 (defprinter js:object (&rest slot-defs)
 205   (psw "{ ")
 206   (loop for ((slot-name . slot-value) . remaining) on slot-defs do
 207        (ps-print slot-name) (psw " : ") (ps-print slot-value)
 208        (when remaining (psw ", ")))
 209   (psw " }"))
 210
 211 (defprinter js:slot-value (obj slot)
 212   (if (or (> (expression-precedence obj) (op-precedence 'js:slot-value))
 213           (numberp obj)
 214           (and (listp obj) (member (car obj) '(js:lambda js:object))))
 215       (parenthesize-print obj)
 216       (ps-print obj))
 217   (if (and (symbolp slot) (not (keywordp slot)))
 218       (progn (psw #\.) (psw (symbol-to-js-string slot)))
 219       (progn (psw #\[) (ps-print slot) (psw #\]))))
 220
 221 (defprinter js:if (test consequent &rest clauses)
 222   (psw "if (") (ps-print test) (psw ") ")
 223   (ps-print consequent)
 224   (loop while clauses do
 225        (ecase (car clauses)
 226          (:else-if (psw " else if (") (ps-print (cadr clauses)) (psw ") ")
 227                    (ps-print (caddr clauses))
 228                    (setf clauses (cdddr clauses)))
 229          (:else (psw " else ")
 230                 (ps-print (cadr clauses))
 231                 (return)))))
 232
 233 (defprinter js:? (test then else)
 234   (if (>= (expression-precedence test) (op-precedence 'js:?))
 235       (parenthesize-print test)
 236       (ps-print test))
 237   (psw " ? ")
 238   (if (>= (expression-precedence then) (op-precedence 'js:?))
 239       (parenthesize-print then)
 240       (ps-print then))
 241   (psw " : ")
 242   (if (>= (expression-precedence else) (op-precedence 'js:?))
 243       (parenthesize-print else)
 244       (ps-print else)))
 245
 246 (defprinter js:= (lhs rhs)
 247   (ps-print lhs) (psw " = ") (ps-print rhs))
 248
 249 (defprinter js:var (var-name &rest var-value)
 250   (psw "var ")
 251   (ps-print var-name)
 252   (when var-value
 253     (psw " = ")
 254     (ps-print (car var-value))))
 255
 256 (defprinter js:break (&optional label)
 257   (psw "break")
 258   (when label
 259     (psw " ")
 260     (psw (symbol-to-js-string label))))
 261
 262 (defprinter js:continue (&optional label)
 263   (psw "continue")
 264   (when label
 265     (psw " ")
 266     (psw (symbol-to-js-string label))))
 267
 268 ;;; iteration
 269 (defprinter js:for (label vars tests steps body-block)
 270   (when label (psw (symbol-to-js-string label)) (psw ": ") (newline-and-indent))
 271   (psw "for (")
 272   (loop for ((var-name . var-init) . remaining) on vars
 273         for decl = "var " then "" do
 274         (psw decl) (psw (symbol-to-js-string var-name)) (psw " = ") (ps-print var-init) (when remaining (psw ", ")))
 275   (psw "; ")
 276   (loop for (test . remaining) on tests do
 277        (ps-print test) (when remaining (psw ", ")))
 278   (psw "; ")
 279   (loop for (step . remaining) on steps do
 280        (ps-print step) (when remaining (psw ", ")))
 281   (psw ") ")
 282   (ps-print body-block))
 283
 284 (defprinter js:for-in (var object body-block)
 285   (psw "for (var ") (ps-print var) (psw " in ")
 286   (if (> (expression-precedence object) (op-precedence 'in))
 287       (parenthesize-print object)
 288       (ps-print object))
 289   (psw ") ")
 290   (ps-print body-block))
 291
 292 (defprinter js:while (test body-block)
 293   (psw "while (") (ps-print test) (psw ") ")
 294   (ps-print body-block))
 295
 296 (defprinter js:with (expression body-block)
 297   (psw "with (") (ps-print expression) (psw ") ")
 298   (ps-print body-block))
 299
 300 (defprinter js:switch (test clauses)
 301   (flet ((print-body-statements (body-statements)
 302            (incf *indent-level*)
 303            (loop for statement in body-statements do
 304                  (progn (newline-and-indent)
 305                         (ps-print statement)
 306                         (psw #\;)))
 307            (decf *indent-level*)))
 308     (psw "switch (") (ps-print test) (psw ") {")
 309     (loop for (val . statements) in clauses
 310           do (progn (newline-and-indent)
 311                     (if (eq val 'default)
 312                         (progn (psw "default: ")
 313                                (print-body-statements statements))
 314                         (progn (psw "case ")
 315                                (ps-print val)
 316                                (psw #\:)
 317                                (print-body-statements statements)))))
 318     (newline-and-indent)
 319     (psw #\})))
 320
 321 (defprinter js:try (body-block &key catch finally)
 322   (psw "try ")
 323   (ps-print body-block)
 324   (when catch
 325     (psw " catch (") (psw (symbol-to-js-string (first catch))) (psw ") ")
 326     (ps-print (second catch)))
 327   (when finally
 328     (psw " finally ")
 329     (ps-print finally)))
 330
 331 ;;; regex
 332 (defprinter js:regex (regex)
 333   (let ((slash (unless (and (> (length regex) 0) (char= (char regex 0) #\/)) "/")))
 334     (psw (concatenate 'string slash regex slash))))
 335
 336 ;;; conditional compilation
 337 (defprinter js:cc-if (test &rest body)
 338   (psw "/*@if ")
 339   (ps-print test)
 340   (incf *indent-level*)
 341   (dolist (form body)
 342     (newline-and-indent) (ps-print form) (psw #\;))
 343   (decf *indent-level*)
 344   (newline-and-indent)
 345   (psw "@end @*/"))
 346
 347 (defprinter js:instanceof (value type)
 348   (psw #\()
 349   (if (> (expression-precedence value) (op-precedence 'js:instanceof))
 350       (parenthesize-print value)
 351       (ps-print value))
 352   (psw " instanceof ")
 353   (if (> (expression-precedence type) (op-precedence 'js:instanceof))
 354       (parenthesize-print type)
 355       (ps-print type))
 356   (psw #\)))
 357
 358 (defprinter js:escape (literal-js)
 359   ;; literal-js should be a form that evaluates to a string containing valid JavaScript
 360   (psw literal-js))
 361
 362 ;;; named statements
 363 (defprinter js:throw (x)
 364   (psw "throw ") (ps-print x))
 365
 366 (defprinter js:return (x)
 367   (psw "return ") (ps-print x))