+ inet_lnaof inet_makeaddr inet_netof hstrerror dnl
+ inet_pton inet_ntop)
+
+dnl Some systems do not declare this. Some systems do declare it, as a
+dnl macro. With cygwin it may be in a DLL.
+
+AC_MSG_CHECKING(whether netdb.h declares h_errno)
+AC_CACHE_VAL(guile_cv_have_h_errno,
+[AC_TRY_COMPILE([#include <netdb.h>],
+[int a = h_errno;],
+guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
+AC_MSG_RESULT($guile_cv_have_h_errno)
+if test $guile_cv_have_h_errno = yes; then
+ AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
+fi
+
+AC_MSG_CHECKING(whether uint32_t is defined)
+AC_CACHE_VAL(guile_cv_have_uint32_t,
+ [AC_TRY_COMPILE([#include <sys/types.h>
+ #if HAVE_STDINT_H
+ #include <stdint.h>
+ #endif
+ #ifndef __MINGW32__
+ #include <netdb.h>
+ #endif],
+ [uint32_t a;],
+ guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
+AC_MSG_RESULT($guile_cv_have_uint32_t)
+if test $guile_cv_have_uint32_t = yes; then
+ AC_DEFINE(HAVE_UINT32_T, 1,
+ [Define if uint32_t typedef is defined when netdb.h is include.])
+fi
+
+AC_MSG_CHECKING(for working IPv6 support)
+AC_CACHE_VAL(guile_cv_have_ipv6,
+[AC_TRY_COMPILE([
+#ifdef HAVE_SYS_TYPES_H
+#include <sys/types.h>
+#endif
+#include <netinet/in.h>
+#include <sys/socket.h>],
+[struct sockaddr_in6 a; a.sin6_family = AF_INET6;],
+guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
+AC_MSG_RESULT($guile_cv_have_ipv6)
+if test $guile_cv_have_ipv6 = yes; then
+ AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
+fi