configure.ac

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it under
  12 the terms of the GNU Lesser General Public License as published by the
  13 Free Software Foundation; either version 3, or (at your option) any
  14 later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but WITHOUT
  17 ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  18 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  19 License for more details.
  20
  21 You should have received a copy of the GNU Lesser General Public
  22 License along with GUILE; see the file COPYING.LESSER.  If not, write
  23 to the Free Software Foundation, Inc., 51 Franklin Street, Fifth
  24 Floor, Boston, MA 02110-1301, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.61)
  29
  30 AC_INIT([GNU Guile],
  31         m4_esyscmd([build-aux/git-version-gen                                   \
  32           .tarball-version                                                      \
  33           's/^release_\([0-9][0-9]*\)-\([0-9][0-9]*\)-\([0-9][0-9]*\)/v\1.\2\.\3/g']),
  34         [bug-guile@gnu.org])
  35 AC_CONFIG_AUX_DIR([build-aux])
  36 AC_CONFIG_MACRO_DIR([m4])
  37 AC_CONFIG_SRCDIR(GUILE-VERSION)
  38
  39 AM_INIT_AUTOMAKE([gnu no-define -Wall -Wno-override])
  40 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AC_SUBST([AM_DEFAULT_VERBOSITY],1)])
  41
  42 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  43 AC_CONFIG_SRCDIR([GUILE-VERSION])
  44
  45 . $srcdir/GUILE-VERSION
  46 GUILE_VERSION="$PACKAGE_VERSION"
  47
  48 AC_CONFIG_HEADERS([config.h])
  49 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  50
  51 #--------------------------------------------------------------------
  52
  53 AC_LANG([C])
  54
  55 dnl Some more checks for Win32
  56 AC_CANONICAL_HOST
  57
  58 AC_LIBTOOL_WIN32_DLL
  59
  60 AC_PROG_INSTALL
  61 AC_PROG_CC
  62 gl_EARLY
  63 AC_PROG_CPP
  64 AC_PROG_SED
  65 AC_PROG_AWK
  66
  67 dnl Gnulib.
  68 gl_INIT
  69
  70 AC_PROG_CC_C89
  71
  72 # for per-target cflags in the libguile subdir
  73 AM_PROG_CC_C_O
  74
  75 AC_LIBTOOL_DLOPEN
  76 AC_PROG_LIBTOOL
  77
  78 dnl Check for libltdl.
  79 AC_LIB_HAVE_LINKFLAGS([ltdl], [], [#include <ltdl.h>],
  80   [lt_dlopenext ("foo");])
  81 if text "x$HAVE_LIBLTDL" != "xyes"; then
  82   AC_MSG_ERROR([GNU libltdl (Libtool) not found, see README.])
  83 fi
  84
  85 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  86 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  87
  88 AM_PATH_LISPDIR
  89
  90 AC_DEFINE_UNQUOTED([HOST_TYPE], ["$host"],
  91   [Define to the host's GNU triplet.])
  92
  93 #--------------------------------------------------------------------
  94 #
  95 # User options (after above tests that may set default CFLAGS etc.)
  96 #
  97 #--------------------------------------------------------------------
  98
  99 GUILE_ERROR_ON_WARNING="no"
 100
 101 AC_ARG_ENABLE(error-on-warning,
 102   [  --enable-error-on-warning    treat compile warnings as errors],
 103   [case "${enableval}" in
 104      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
 105      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
 106      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
 107    esac])
 108
 109 AC_ARG_ENABLE(debug-malloc,
 110   [  --enable-debug-malloc   include malloc debugging code],
 111   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 112     AC_DEFINE([GUILE_DEBUG_MALLOC], 1,
 113       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 114   fi)
 115
 116 SCM_I_GSC_GUILE_DEBUG=0
 117 AC_ARG_ENABLE(guile-debug,
 118   [AS_HELP_STRING([--enable-guile-debug],
 119                   [include internal debugging functions])],
 120   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 121     SCM_I_GSC_GUILE_DEBUG=1
 122   fi)
 123
 124 AC_ARG_ENABLE(posix,
 125   [  --disable-posix         omit posix interfaces],,
 126   enable_posix=yes)
 127
 128 AC_ARG_ENABLE(networking,
 129   [  --disable-networking    omit networking interfaces],,
 130   enable_networking=yes)
 131
 132 AC_ARG_ENABLE(regex,
 133   [  --disable-regex         omit regular expression interfaces],,
 134   enable_regex=yes)
 135
 136 AC_ARG_ENABLE([deprecated],
 137   AS_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 138
 139 if test "$enable_deprecated" = no; then
 140   SCM_I_GSC_ENABLE_DEPRECATED=0
 141   warn_default=no
 142 else
 143   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 144     warn_default=summary
 145   elif test "$enable_deprecated" = shutup; then
 146     warn_default=no
 147   else
 148     warn_default=$enable_deprecated
 149   fi
 150   SCM_I_GSC_ENABLE_DEPRECATED=1
 151 fi
 152 AC_DEFINE_UNQUOTED([SCM_WARN_DEPRECATED_DEFAULT], "$warn_default",
 153 [Define this to control the default warning level for deprecated features.])
 154
 155 dnl  Added the following configure option in January 2008 following
 156 dnl  investigation of problems with "64" system and library calls on
 157 dnl  Darwin (MacOS X).  The libguile code (_scm.h) assumes that if a
 158 dnl  system has stat64, it will have all the other 64 APIs too; but on
 159 dnl  Darwin, stat64 is there but other APIs are missing.
 160 dnl
 161 dnl  It also appears, from the Darwin docs, that most system call APIs
 162 dnl  there (i.e. the traditional ones _without_ "64" in their names) have
 163 dnl  been 64-bit-capable for a long time now, so it isn't necessary to
 164 dnl  use "64" versions anyway.  For example, Darwin's off_t is 64-bit.
 165 dnl
 166 dnl  A similar problem has been reported for HP-UX:
 167 dnl  http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html
 168 dnl
 169 dnl  Therefore, and also because a Guile without LARGEFILE64 support is
 170 dnl  better than no Guile at all, we provide this option to suppress
 171 dnl  trying to use "64" calls.
 172 dnl
 173 dnl  It may be that for some 64-bit function on Darwin/HP-UX we do need
 174 dnl  to use a "64" call, and hence that by using --without-64-calls we're
 175 dnl  missing out on that.  If so, someone can work on that in the future.
 176 dnl  For now, --without-64-calls allows Guile to build on OSs where it
 177 dnl  wasn't building before.
 178 AC_MSG_CHECKING([whether to use system and library "64" calls])
 179 AC_ARG_WITH([64-calls],
 180   AS_HELP_STRING([--without-64-calls],
 181                  [don't attempt to use system and library calls with "64" in their names]),
 182   [use_64_calls=$withval],
 183   [use_64_calls=yes
 184    case $host in
 185      *-apple-darwin* )
 186        use_64_calls=no
 187        ;;
 188      powerpc-ibm-aix* )
 189        use_64_calls=no
 190        ;;
 191    esac])
 192 AC_MSG_RESULT($use_64_calls)
 193 case "$use_64_calls" in
 194   y* )
 195     AC_DEFINE([GUILE_USE_64_CALLS], 1,
 196       [Define to 1 in order to try to use "64" versions of system and library calls.])
 197     ;;
 198 esac
 199
 200 #--------------------------------------------------------------------
 201
 202 dnl Check for dynamic linking
 203
 204 use_modules=yes
 205 AC_ARG_WITH(modules,
 206 [  --with-modules[=FILES]  Add support for dynamic modules],
 207 use_modules="$withval")
 208 test -z "$use_modules" && use_modules=yes
 209 DLPREOPEN=
 210 if test "$use_modules" != no; then
 211   if test "$use_modules" = yes; then
 212     DLPREOPEN="-dlpreopen force"
 213   else
 214     DLPREOPEN="-export-dynamic"
 215     for module in $use_modules; do
 216       DLPREOPEN="$DLPREOPEN -dlopen $module"
 217     done
 218   fi
 219 fi
 220
 221 dnl files which are destined for separate modules.
 222
 223 if test "$use_modules" != no; then
 224    AC_LIBOBJ([dynl])
 225 fi
 226
 227 if test "$enable_posix" = yes; then
 228    AC_LIBOBJ([filesys])
 229    AC_LIBOBJ([posix])
 230    AC_DEFINE([HAVE_POSIX], 1,
 231      [Define this if you want support for POSIX system calls in Guile.])
 232 fi
 233
 234 if test "$enable_networking" = yes; then
 235    AC_LIBOBJ([net_db])
 236    AC_LIBOBJ([socket])
 237    AC_DEFINE([HAVE_NETWORKING], 1,
 238      [Define this if you want support for networking in Guile.])
 239 fi
 240
 241 if test "$enable_debug_malloc" = yes; then
 242    AC_LIBOBJ([debug-malloc])
 243 fi
 244
 245 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 246
 247 AC_C_CONST
 248
 249 # "volatile" is used in a couple of tests below.
 250 AC_C_VOLATILE
 251
 252 AC_C_INLINE
 253 if test "$ac_cv_c_inline" != no; then
 254   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 255 else
 256   SCM_I_GSC_C_INLINE=NULL
 257 fi
 258 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 259
 260 AC_C_BIGENDIAN
 261
 262 AC_C_LABELS_AS_VALUES
 263
 264 AC_CHECK_SIZEOF(char)
 265 AC_CHECK_SIZEOF(unsigned char)
 266 AC_CHECK_SIZEOF(short)
 267 AC_CHECK_SIZEOF(unsigned short)
 268 AC_CHECK_SIZEOF(int)
 269 AC_CHECK_SIZEOF(unsigned int)
 270 AC_CHECK_SIZEOF(long)
 271 AC_CHECK_SIZEOF(unsigned long)
 272 AC_CHECK_SIZEOF(size_t)
 273 AC_CHECK_SIZEOF(long long)
 274 AC_CHECK_SIZEOF(unsigned long long)
 275 AC_CHECK_SIZEOF(__int64)
 276 AC_CHECK_SIZEOF(unsigned __int64)
 277 AC_CHECK_SIZEOF(void *)
 278 AC_CHECK_SIZEOF(intptr_t)
 279 AC_CHECK_SIZEOF(uintptr_t)
 280 AC_CHECK_SIZEOF(ptrdiff_t)
 281 AC_CHECK_SIZEOF(size_t)
 282 AC_CHECK_SIZEOF(off_t)
 283
 284 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 285   AC_MSG_ERROR(sizes of long and void* are not identical)
 286 fi
 287
 288 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 289   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 290 else
 291   SCM_I_GSC_T_PTRDIFF='"long"'
 292 fi
 293 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 294
 295 AC_CHECK_HEADERS([stdint.h])
 296 AC_CHECK_HEADERS([inttypes.h])
 297
 298 AC_CHECK_SIZEOF(intmax_t)
 299
 300 SCM_I_GSC_NEEDS_STDINT_H=0
 301 SCM_I_GSC_NEEDS_INTTYPES_H=0
 302
 303 ### intptr and uintptr (try not to use inttypes if we don't have to)
 304 if test "$ac_cv_header_inttypes_h" = yes; then
 305   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 306     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 307 #include <stdio.h>])
 308     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 309       SCM_I_GSC_NEEDS_INTTYPES_H=1
 310     fi
 311   fi
 312   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 313     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 314 #include <stdio.h>])
 315     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 316       SCM_I_GSC_NEEDS_INTTYPES_H=1
 317     fi
 318   fi
 319 fi
 320
 321 ### See what's provided by stdint.h
 322 if test "$ac_cv_header_stdint_h" = yes; then
 323    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 324    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 325    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 326    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 327    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 328    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 329    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 330    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 331    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 332    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 333    AC_CHECK_TYPE([intptr_t],[scm_stdint_has_intptr=1],,[#include <stdint.h>])
 334    AC_CHECK_TYPE([uintptr_t],[scm_stdint_has_uintptr=1],,[#include <stdint.h>])
 335 fi
 336
 337 # so we don't get confused by the cache (wish there was a better way
 338 # to check particular headers for the same type...)
 339
 340 unset ac_cv_type_int8_t
 341 unset ac_cv_type_uint8_t
 342 unset ac_cv_type_int16_t
 343 unset ac_cv_type_uint16_t
 344 unset ac_cv_type_int32_t
 345 unset ac_cv_type_uint32_t
 346 unset ac_cv_type_int64_t
 347 unset ac_cv_type_uint64_t
 348 unset ac_cv_type_intmax_t
 349 unset ac_cv_type_uintmax_t
 350
 351 ### See what's provided by inttypes.h
 352 if test "$ac_cv_header_inttypes_h" = yes; then
 353   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 354   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 355   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 356   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 357   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 358   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 359   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 360   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 361   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 362   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 363   AC_CHECK_TYPE([intptr_t],[scm_inttypes_has_intptr=1],,[#include <inttypes.h>])
 364   AC_CHECK_TYPE([uintptr_t],[scm_inttypes_has_uintptr=1],,[#include <inttypes.h>])
 365 fi
 366
 367 # Try hard to find definitions for some required scm_t_*int* types.
 368
 369 ### Required type scm_t_int8
 370 if test "$scm_stdint_has_int8"; then
 371   SCM_I_GSC_T_INT8='"int8_t"'
 372   SCM_I_GSC_NEEDS_STDINT_H=1
 373 elif test "$scm_inttypes_has_int8"; then
 374   SCM_I_GSC_T_INT8='"int8_t"'
 375   SCM_I_GSC_NEEDS_INTTYPES_H=1
 376 elif test "$ac_cv_sizeof_char" -eq 1; then
 377   SCM_I_GSC_T_INT8='"signed char"'
 378 else
 379   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 380 fi
 381 AC_SUBST([SCM_I_GSC_T_INT8])
 382
 383 ### Required type scm_t_uint8
 384 if test "$scm_stdint_has_uint8"; then
 385   SCM_I_GSC_T_UINT8='"uint8_t"'
 386   SCM_I_GSC_NEEDS_STDINT_H=1
 387 elif test "$scm_inttypes_has_uint8"; then
 388   SCM_I_GSC_T_UINT8='"uint8_t"'
 389   SCM_I_GSC_NEEDS_INTTYPES_H=1
 390 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 391   SCM_I_GSC_T_UINT8='"unsigned char"'
 392 else
 393   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 394 fi
 395 AC_SUBST([SCM_I_GSC_T_UINT8])
 396
 397 ### Required type scm_t_int16 (ANSI C says int or short might work)
 398 if test "$scm_stdint_has_int16"; then
 399   SCM_I_GSC_T_INT16='"int16_t"'
 400   SCM_I_GSC_NEEDS_STDINT_H=1
 401 elif test "$scm_inttypes_has_int16"; then
 402   SCM_I_GSC_T_INT16='"int16_t"'
 403   SCM_I_GSC_NEEDS_INTTYPES_H=1
 404 elif test "$ac_cv_sizeof_int" -eq 2; then
 405   SCM_I_GSC_T_INT16='"int"'
 406 elif test "$ac_cv_sizeof_short" -eq 2; then
 407   SCM_I_GSC_T_INT16='"short"'
 408 else
 409   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 410 fi
 411 AC_SUBST([SCM_I_GSC_T_INT16])
 412
 413 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 414 if test "$scm_stdint_has_uint16"; then
 415   SCM_I_GSC_T_UINT16='"uint16_t"'
 416   SCM_I_GSC_NEEDS_STDINT_H=1
 417 elif test "$scm_inttypes_has_uint16"; then
 418   SCM_I_GSC_T_UINT16='"uint16_t"'
 419   SCM_I_GSC_NEEDS_INTTYPES_H=1
 420 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 421   SCM_I_GSC_T_UINT16='"unsigned int"'
 422 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 423   SCM_I_GSC_T_UINT16='"unsigned short"'
 424 else
 425   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 426 fi
 427 AC_SUBST([SCM_I_GSC_T_UINT16])
 428
 429
 430 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 431 if test "$scm_stdint_has_int32"; then
 432   SCM_I_GSC_T_INT32='"int32_t"'
 433   SCM_I_GSC_NEEDS_STDINT_H=1
 434 elif test "$scm_inttypes_has_int32"; then
 435   SCM_I_GSC_T_INT32='"int32_t"'
 436   SCM_I_GSC_NEEDS_INTTYPES_H=1
 437 elif test "$ac_cv_sizeof_int" -eq 4; then
 438   SCM_I_GSC_T_INT32='"int"'
 439 elif test "$ac_cv_sizeof_long" -eq 4; then
 440   SCM_I_GSC_T_INT32='"long"'
 441 elif test "$ac_cv_sizeof_short" -eq 4; then
 442   SCM_I_GSC_T_INT32='"short"'
 443 else
 444   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 445 fi
 446 AC_SUBST([SCM_I_GSC_T_INT32])
 447
 448 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 449 if test "$scm_stdint_has_uint32"; then
 450   SCM_I_GSC_T_UINT32='"uint32_t"'
 451   SCM_I_GSC_NEEDS_STDINT_H=1
 452 elif test "$scm_inttypes_has_uint32"; then
 453   SCM_I_GSC_T_UINT32='"uint32_t"'
 454   SCM_I_GSC_NEEDS_INTTYPES_H=1
 455 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 456   SCM_I_GSC_T_UINT32='"unsigned int"'
 457 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 458   SCM_I_GSC_T_UINT32='"unsigned long"'
 459 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 460   SCM_I_GSC_T_UINT32='"unsigned short"'
 461 else
 462   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 463 fi
 464 AC_SUBST([SCM_I_GSC_T_UINT32])
 465
 466 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 467 ### Also try 'long long' and '__int64' if we have it.
 468 SCM_I_GSC_T_INT64=0
 469 if test "$scm_stdint_has_int64"; then
 470   SCM_I_GSC_T_INT64='"int64_t"'
 471   SCM_I_GSC_NEEDS_STDINT_H=1
 472 elif test "$scm_inttypes_has_int64"; then
 473   SCM_I_GSC_T_INT64='"int64_t"'
 474   SCM_I_GSC_NEEDS_INTTYPES_H=1
 475 elif test "$ac_cv_sizeof_int" -eq 8; then
 476   SCM_I_GSC_T_INT64='"int"'
 477 elif test "$ac_cv_sizeof_long" -eq 8; then
 478   SCM_I_GSC_T_INT64='"long"'
 479 elif test "$ac_cv_sizeof_short" -eq 8; then
 480   SCM_I_GSC_T_INT64='"short"'
 481 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 482   SCM_I_GSC_T_INT64='"long long"'
 483 elif test "$ac_cv_sizeof___int64" -eq 8; then
 484   SCM_I_GSC_T_INT64='"__int64"'
 485 else
 486   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 487 fi
 488 AC_SUBST([SCM_I_GSC_T_INT64])
 489
 490
 491 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 492 ### Also try 'long long' and '__int64' if we have it.
 493 SCM_I_GSC_T_UINT64=0
 494 if test "$scm_stdint_has_uint64"; then
 495   SCM_I_GSC_T_UINT64='"uint64_t"'
 496   SCM_I_GSC_NEEDS_STDINT_H=1
 497 elif test "$scm_inttypes_has_uint64"; then
 498   SCM_I_GSC_T_UINT64='"uint64_t"'
 499   SCM_I_GSC_NEEDS_INTTYPES_H=1
 500 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 501   SCM_I_GSC_T_UINT64='"unsigned int"'
 502 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 503   SCM_I_GSC_T_UINT64='"unsigned long"'
 504 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 505   SCM_I_GSC_T_UINT64='"unsigned short"'
 506 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 507   SCM_I_GSC_T_UINT64='"unsigned long long"'
 508 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 509   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 510 else
 511   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 512 fi
 513 AC_SUBST([SCM_I_GSC_T_UINT64])
 514
 515 ### Required type scm_t_intmax
 516 ###
 517 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 518 ### none of them is available, we use 'long'.
 519 ###
 520 SCM_I_GSC_T_INTMAX=0
 521 if test "$scm_stdint_has_intmax"; then
 522   SCM_I_GSC_T_INTMAX='"intmax_t"'
 523   SCM_I_GSC_NEEDS_STDINT_H=1
 524 elif test "$scm_inttypes_has_intmax"; then
 525   SCM_I_GSC_T_INTMAX='"intmax_t"'
 526   SCM_I_GSC_NEEDS_INTTYPES_H=1
 527 elif test "$ac_cv_sizeof___int64" -ne 0; then
 528   SCM_I_GSC_T_INTMAX='"__int64"'
 529 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 530   SCM_I_GSC_T_INTMAX='"long long"'
 531 else
 532   SCM_I_GSC_T_INTMAX='"long"'
 533 fi
 534 AC_SUBST([SCM_I_GSC_T_INTMAX])
 535
 536 ### Required type scm_t_uintmax
 537 ###
 538 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 539 ### this order.  When none of them is available, we use 'unsigned long'.
 540 ###
 541 SCM_I_GSC_T_UINTMAX=0
 542 if test "$scm_stdint_has_uintmax"; then
 543   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 544   SCM_I_GSC_NEEDS_STDINT_H=1
 545 elif test "$scm_inttypes_has_uintmax"; then
 546   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 547   SCM_I_GSC_NEEDS_INTTYPES_H=1
 548 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 549   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 550 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 551   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 552 else
 553   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 554 fi
 555 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 556
 557 ### Required type scm_t_intptr
 558 ###
 559 SCM_I_GSC_T_INTPTR=0
 560 if test "$scm_stdint_has_intptr"; then
 561   SCM_I_GSC_T_INTPTR='"intptr_t"'
 562   SCM_I_GSC_NEEDS_STDINT_H=1
 563 elif test "$scm_inttypes_has_intptr"; then
 564   SCM_I_GSC_T_INTPTR='"intptr_t"'
 565   SCM_I_GSC_NEEDS_INTTYPES_H=1
 566 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 567   SCM_I_GSC_T_INTPTR='"int"'
 568 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 569   SCM_I_GSC_T_INTPTR='"long"'
 570 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 571   SCM_I_GSC_T_INTPTR='"long long"'
 572 else
 573   AC_MSG_ERROR([Can't find appropriate type for `scm_t_intptr'.])
 574 fi
 575 AC_SUBST([SCM_I_GSC_T_INTPTR])
 576
 577 ### Required type scm_t_uintptr
 578 ###
 579 SCM_I_GSC_T_UINTPTR=0
 580 if test "$scm_stdint_has_uintptr"; then
 581   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 582   SCM_I_GSC_NEEDS_STDINT_H=1
 583 elif test "$scm_inttypes_has_uintptr"; then
 584   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 585   SCM_I_GSC_NEEDS_INTTYPES_H=1
 586 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 587   SCM_I_GSC_T_UINTPTR='"unsigned int"'
 588 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 589   SCM_I_GSC_T_UINTPTR='"unsigned long"'
 590 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 591   SCM_I_GSC_T_UINTPTR='"unsigned long long"'
 592 else
 593   AC_MSG_ERROR([Can't find appropriate type for `scm_t_uintptr'.])
 594 fi
 595 AC_SUBST([SCM_I_GSC_T_UINTPTR])
 596
 597
 598 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 599 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 600
 601 AC_HEADER_STDC
 602 AC_HEADER_TIME
 603 AC_HEADER_SYS_WAIT
 604 AC_HEADER_DIRENT
 605
 606 # Reason for checking:
 607 #
 608 #   HP-UX 11.11 (at least) doesn't provide `struct dirent64', even
 609 #   with `_LARGEFILE64_SOURCE', so check whether it's available.
 610 #
 611 AC_CHECK_MEMBER([struct dirent64.d_name],
 612   [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0],
 613   [ #ifndef _LARGEFILE64_SOURCE
 614     # define _LARGEFILE64_SOURCE
 615     #endif
 616
 617     /* Per Autoconf manual.  */
 618     #include <sys/types.h>
 619     #ifdef HAVE_DIRENT_H
 620     # include <dirent.h>
 621     #else
 622     # define dirent direct
 623     # ifdef HAVE_SYS_NDIR_H
 624     #  include <sys/ndir.h>
 625     # endif
 626     # ifdef HAVE_SYS_DIR_H
 627     #  include <sys/dir.h>
 628     # endif
 629     # ifdef HAVE_NDIR_H
 630     #  include <ndir.h>
 631     # endif
 632     #endif ])
 633 AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64])
 634
 635 # Reasons for testing:
 636 #   complex.h - new in C99
 637 #   fenv.h - available in C99, but not older systems
 638 #   machine/fpu.h - on Tru64 5.1b, the declaration of fesetround(3) is in
 639 #     this file instead of <fenv.h>
 640 #   process.h - mingw specific
 641 #   langinfo.h, nl_types.h - SuS v2
 642 #
 643 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h malloc.h memory.h process.h string.h \
 644 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 645 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 646 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 647 direct.h langinfo.h nl_types.h machine/fpu.h])
 648
 649 # Reasons for testing:
 650 #   nl_item - lacking on Cygwin
 651 AC_CHECK_TYPES([nl_item], [], [],
 652   [[#ifdef HAVE_LANGINFO_H
 653     # include <langinfo.h>
 654     #endif
 655     #ifdef HAVE_NL_TYPES_H
 656     # include <nl_types.h>
 657     #endif]])
 658
 659 # "complex double" is new in C99, and "complex" is only a keyword if
 660 # <complex.h> is included
 661 AC_CHECK_TYPES(complex double,,,
 662 [#if HAVE_COMPLEX_H
 663 #include <complex.h>
 664 #endif])
 665
 666 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 667 # when testing.
 668 AC_CHECK_TYPE(socklen_t, ,
 669   [AC_DEFINE_UNQUOTED([socklen_t], int,
 670                       [Define to `int' if <sys/socket.h> does not define.])],
 671   [#if HAVE_SYS_TYPES_H
 672 #include <sys/types.h>
 673 #endif
 674 #include <sys/socket.h>
 675 ])
 676 AC_CHECK_TYPE(struct ip_mreq)
 677
 678 GUILE_HEADER_LIBC_WITH_UNISTD
 679
 680 AC_TYPE_GETGROUPS
 681 AC_TYPE_SIGNAL
 682 AC_TYPE_MODE_T
 683
 684 # On mingw -lm is empty, so this test is unnecessary, but it's
 685 # harmless so we don't hard-code to suppress it.
 686 #
 687 AC_CHECK_LIB(m, cos)
 688
 689 AC_CHECK_FUNCS(gethostbyname)
 690 if test $ac_cv_func_gethostbyname = no; then
 691     AC_CHECK_LIB(nsl, gethostbyname)
 692 fi
 693
 694 AC_CHECK_FUNCS(connect)
 695 if test $ac_cv_func_connect = no; then
 696     AC_CHECK_LIB(socket, connect)
 697 fi
 698
 699 dnl
 700 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 701 dnl
 702 EXTRA_DEFS=""
 703 case $host in
 704   *-*-mingw*)
 705     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 706       [Define if you have the <winsock2.h> header file.])])
 707     AC_CHECK_LIB(ws2_32, main)
 708     AC_LIBOBJ([win32-uname])
 709     AC_LIBOBJ([win32-dirent])
 710     if test "$enable_networking" = yes ; then
 711       AC_LIBOBJ([win32-socket])
 712     fi
 713     if test "$enable_shared" = yes ; then
 714       EXTRA_DEFS="-DSCM_IMPORT"
 715       AC_DEFINE([USE_DLL_IMPORT], 1,
 716         [Define if you need additional CPP macros on Win32 platforms.])
 717     fi
 718     ;;
 719 esac
 720 AC_SUBST(EXTRA_DEFS)
 721
 722 # Reasons for testing:
 723 #   crt_externs.h - Darwin specific
 724 #
 725 AC_CHECK_HEADERS([assert.h crt_externs.h])
 726
 727 # Reasons for testing:
 728 #   DINFINITY - OSF specific
 729 #   DQNAN - OSF specific
 730 #       (DINFINITY and DQNAN are actually global variables, not functions)
 731 #   chsize - an MS-DOS-ism, found in mingw
 732 #   cexp, clog - not in various pre-c99 systems, and note that it's possible
 733 #       for gcc to provide the "complex double" type but the system to not
 734 #       have functions like cexp and clog
 735 #   clog10 - not in mingw (though others like clog and csqrt are)
 736 #   fesetround - available in C99, but not older systems
 737 #   ftruncate - posix, but probably not older systems (current mingw
 738 #               has it as an inline for chsize)
 739 #   ioctl - not in mingw.
 740 #   gmtime_r - recent posix, not on old systems
 741 #   pipe - not in mingw
 742 #   _pipe - specific to mingw, taking 3 args
 743 #   readdir_r - recent posix, not on old systems
 744 #   readdir64_r - not available on HP-UX 11.11
 745 #   stat64 - SuS largefile stuff, not on old systems
 746 #   sysconf - not on old systems
 747 #   truncate - not in mingw
 748 #   isblank - available as a GNU extension or in C99
 749 #   _NSGetEnviron - Darwin specific
 750 #   strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin
 751 #   nl_langinfo - X/Open, not available on Windows.
 752 #   utimensat: posix.1-2008
 753 #
 754 AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid fesetround ftime ftruncate fchown getcwd geteuid getsid gettimeofday gmtime_r ioctl lstat mkdir mknod nice pipe _pipe readdir_r readdir64_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron strcoll strcoll_l newlocale nl_langinfo utimensat])
 755
 756 # Reasons for testing:
 757 #   netdb.h - not in mingw
 758 #   sys/param.h - not in mingw
 759 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 760 #       check this specifically, we need it for the timespec test below.
 761 #   sethostname - the function itself check because it's not in mingw,
 762 #       the DECL is checked because Solaris 10 doens't have in any header
 763 #   hstrerror - on Tru64 5.1b the symbol is available in libc but the
 764 #       declaration isn't anywhere.
 765 #   cuserid - on Tru64 5.1b the declaration is documented to be available
 766 #       only with `_XOPEN_SOURCE' or some such.
 767 #
 768 AC_CHECK_HEADERS([crypt.h netdb.h pthread.h sys/param.h sys/resource.h sys/file.h])
 769 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 770 AC_CHECK_DECLS([sethostname, hstrerror, cuserid])
 771
 772 # crypt() may or may not be available, for instance in some countries there
 773 # are restrictions on cryptography.
 774 #
 775 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 776 # -lcrypt library (eg. Debian GNU/Linux).
 777 #
 778 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 779 # be careful to avoid -lcrypt in this case, since libtool will see there's
 780 # only a static libcrypt and decide to build only a static libguile.
 781 #
 782 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 783 # libraries already in that list.
 784 #
 785 AC_SEARCH_LIBS(crypt, crypt,
 786   [AC_DEFINE([HAVE_CRYPT],1,
 787              [Define to 1 if you have the `crypt' function.])])
 788
 789 # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't
 790 # work; in the reported cases so far, 1.0fi works well instead.  According
 791 # to the C99 spec, the complex.h header must provide a working definition
 792 # of _Complex_I, so we always try _Complex_I first.  The 1.0fi fallback
 793 # is a workaround for the failure of some systems to conform to C99.
 794 if test "$ac_cv_type_complex_double" = yes; then
 795   AC_MSG_CHECKING([for i])
 796   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 797 #if HAVE_COMPLEX_H
 798 #include <complex.h>
 799 #endif
 800 complex double z;
 801 ]], [[
 802 z = _Complex_I;
 803 ]])],
 804     [AC_DEFINE([GUILE_I],_Complex_I,[The imaginary unit (positive square root of -1).])
 805      AC_MSG_RESULT([_Complex_I])],
 806     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 807 #if HAVE_COMPLEX_H
 808 #include <complex.h>
 809 #endif
 810 complex double z;
 811 ]],[[
 812 z = 1.0fi;
 813 ]])],
 814   [AC_DEFINE([GUILE_I],1.0fi)
 815    AC_MSG_RESULT([1.0fi])],
 816   [ac_cv_type_complex_double=no
 817    AC_MSG_RESULT([not available])])])
 818 fi
 819
 820 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 821 # csqrt(-i) returned a negative real part, when it should be positive
 822 # for the principal root.
 823 #
 824 if test "$ac_cv_type_complex_double" = yes; then
 825
 826   AC_CACHE_CHECK([whether csqrt is usable],
 827     guile_cv_use_csqrt,
 828     [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 829 #include <complex.h>
 830 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 831    constant, we want to test libc. */
 832 volatile complex double z = - _Complex_I;
 833 int
 834 main (void)
 835 {
 836   z = csqrt (z);
 837   if (creal (z) > 0.0)
 838     return 0;  /* good */
 839   else
 840     return 1;  /* bad */
 841 }]])],
 842     [guile_cv_use_csqrt=yes],
 843     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 844     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 845   case $guile_cv_use_csqrt in
 846     yes*)
 847       AC_DEFINE([HAVE_USABLE_CSQRT], 1, [Define to 1 if csqrt is bug-free])
 848       ;;
 849   esac
 850 fi
 851
 852
 853 dnl GMP tests
 854 AC_LIB_HAVE_LINKFLAGS([gmp],
 855   [],
 856   [#include <gmp.h>],
 857   [mpz_import (0, 0, 0, 0, 0, 0, 0);])
 858
 859 if test "x$HAVE_LIBGMP" != "xyes"; then
 860   AC_MSG_ERROR([GNU MP 4.1 or greater not found, see README])
 861 fi
 862
 863 dnl GNU libunistring is checked for by Gnulib's `libunistring' module.
 864 if test "x$LTLIBUNISTRING" != "x"; then
 865   LIBS="$LTLIBUNISTRING $LIBS"
 866 else
 867   AC_MSG_ERROR([GNU libunistring is required, please install it.])
 868 fi
 869
 870 dnl Libffi is needed to compile Guile's foreign function interface, but its
 871 dnl interface isn't exposed in Guile's API.
 872 PKG_CHECK_MODULES(LIBFFI, libffi)
 873 AC_SUBST(LIBFFI_CFLAGS)
 874 AC_SUBST(LIBFFI_LIBS)
 875
 876 dnl figure out approriate ffi type for size_t
 877 AC_CHECK_SIZEOF(size_t)
 878 AC_CHECK_SIZEOF(ssize_t)
 879 ffi_size_type=uint$(($ac_cv_sizeof_size_t*8))
 880 ffi_ssize_type=sint$(($ac_cv_sizeof_ssize_t*8))
 881 AC_DEFINE_UNQUOTED([ffi_type_size_t], ffi_type_${ffi_size_type},
 882                    [ffi type for size_t])
 883 AC_DEFINE_UNQUOTED([ffi_type_ssize_t], ffi_type_${ffi_ssize_type},
 884                    [ffi type for ssize_t])
 885
 886 dnl i18n tests
 887 #AC_CHECK_HEADERS([libintl.h])
 888 #AC_CHECK_FUNCS(gettext)
 889 #if test $ac_cv_func_gettext = no; then
 890 #   AC_CHECK_LIB(intl, gettext)
 891 #fi
 892 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 893 AM_GNU_GETTEXT([external], [need-ngettext])
 894
 895 ### Some systems don't declare some functions.  On such systems, we
 896 ### need to at least provide our own K&R-style declarations.
 897
 898 ### GUILE_FUNC_DECLARED(function, headerfile)
 899
 900 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 901 ### not there, #define MISSING_FUNCTION_DECL.
 902 AC_DEFUN([GUILE_FUNC_DECLARED], [
 903   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 904     AC_EGREP_HEADER($1, $2,
 905                     guile_cv_func_$1_declared=yes,
 906                     guile_cv_func_$1_declared=no))
 907   if test [x$guile_cv_func_]$1[_declared] = xno; then
 908     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 909       [Define if the operating system supplies $1 without declaring it.])
 910   fi
 911 ])
 912
 913 GUILE_FUNC_DECLARED(sleep, unistd.h)
 914 GUILE_FUNC_DECLARED(usleep, unistd.h)
 915
 916 AC_CHECK_DECLS([strptime],,,
 917 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 918 #include <time.h>])
 919
 920 ### On some systems usleep has no return value.  If it does have one,
 921 ### we'd like to return it; otherwise, we'll fake it.
 922 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 923   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 924                    unistd.h,
 925                    [guile_cv_func_usleep_return_type=void],
 926                    [guile_cv_func_usleep_return_type=int])])
 927 case "$guile_cv_func_usleep_return_type" in
 928   "void" )
 929     AC_DEFINE([USLEEP_RETURNS_VOID], 1,
 930       [Define if the system headers declare usleep to return void.])
 931   ;;
 932 esac
 933
 934 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 935 if test -n "$have_sys_un_h" ; then
 936   AC_DEFINE([HAVE_UNIX_DOMAIN_SOCKETS], 1,
 937     [Define if the system supports Unix-domain (file-domain) sockets.])
 938 fi
 939
 940 AC_CHECK_FUNCS(getrlimit setrlimit)
 941
 942 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 943
 944 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 945                setnetent    getnetent    endnetent    dnl
 946                setprotoent  getprotoent  endprotoent  dnl
 947                setservent   getservent   endservent   dnl
 948                getnetbyaddr getnetbyname dnl
 949                inet_lnaof inet_makeaddr inet_netof hstrerror)
 950
 951 # struct sockaddr field sin_len is only present on BSD systems.
 952 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 953 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 954 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 955 [#ifdef HAVE_SYS_TYPES_H
 956 #include <sys/types.h>
 957 #endif
 958 #include <netinet/in.h>])
 959
 960 AC_MSG_CHECKING(for __libc_stack_end)
 961 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 962 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 963 extern char *__libc_stack_end;]],
 964    [[printf("%p", (char*) __libc_stack_end);]])],
 965    [guile_cv_have_libc_stack_end=yes],
 966    [guile_cv_have_libc_stack_end=no])])
 967 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 968
 969 if test $guile_cv_have_libc_stack_end = yes; then
 970   AC_DEFINE([HAVE_LIBC_STACK_END], 1,
 971            [Define if you have the __libc_stack_end variable.])
 972 fi
 973
 974 dnl Some systems do not declare this.  Some systems do declare it, as a
 975 dnl macro.  With cygwin it may be in a DLL.
 976
 977 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 978 AC_CACHE_VAL(guile_cv_have_h_errno,
 979   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 980                                       [[int a = h_errno;]])],
 981   [guile_cv_have_h_errno=yes],
 982   [guile_cv_have_h_errno=no])])
 983 AC_MSG_RESULT($guile_cv_have_h_errno)
 984 if test $guile_cv_have_h_errno = yes; then
 985   AC_DEFINE([HAVE_H_ERRNO], 1, [Define if h_errno is declared in netdb.h.])
 986 fi
 987
 988 AC_MSG_CHECKING(whether uint32_t is defined)
 989 AC_CACHE_VAL(guile_cv_have_uint32_t,
 990   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 991                    #if HAVE_STDINT_H
 992                    #include <stdint.h>
 993                    #endif
 994                    #ifndef HAVE_NETDB_H
 995                    #include <netdb.h>
 996                    #endif]],
 997                    [[uint32_t a;]])],
 998                    [guile_cv_have_uint32_t=yes],
 999                    [guile_cv_have_uint32_t=no])])
1000 AC_MSG_RESULT($guile_cv_have_uint32_t)
1001 if test $guile_cv_have_uint32_t = yes; then
1002   AC_DEFINE([HAVE_UINT32_T], 1,
1003     [Define if uint32_t typedef is defined when netdb.h is include.])
1004 fi
1005
1006 AC_MSG_CHECKING(for working IPv6 support)
1007 AC_CACHE_VAL(guile_cv_have_ipv6,
1008 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1009 #ifdef HAVE_SYS_TYPES_H
1010 #include <sys/types.h>
1011 #endif
1012 #include <netinet/in.h>
1013 #include <sys/socket.h>]],
1014 [[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;]])],
1015 [guile_cv_have_ipv6=yes],
1016 [guile_cv_have_ipv6=no])])
1017 AC_MSG_RESULT($guile_cv_have_ipv6)
1018 if test $guile_cv_have_ipv6 = yes; then
1019   AC_DEFINE([HAVE_IPV6], 1, [Define if you want support for IPv6.])
1020 fi
1021
1022 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
1023 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
1024 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
1025 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1026 #ifdef HAVE_SYS_TYPES_H
1027 #include <sys/types.h>
1028 #endif
1029 #include <netinet/in.h>]],
1030 [[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;]])],
1031 [guile_cv_have_sin6_scope_id=yes],
1032 [guile_cv_have_sin6_scope_id=no])])
1033 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
1034 if test $guile_cv_have_sin6_scope_id = yes; then
1035   AC_DEFINE([HAVE_SIN6_SCOPE_ID], 1,
1036     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
1037 fi
1038
1039 # struct sockaddr_in6 field sin_len is only present on BSD systems
1040 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
1041 [#ifdef HAVE_SYS_TYPES_H
1042 #include <sys/types.h>
1043 #endif
1044 #include <netinet/in.h>])
1045
1046 AC_MSG_CHECKING(whether localtime caches TZ)
1047 AC_CACHE_VAL(guile_cv_localtime_cache,
1048 [if test x$ac_cv_func_tzset = xyes; then
1049 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
1050 #if STDC_HEADERS
1051 # include <stdlib.h>
1052 #endif
1053 extern char **environ;
1054 unset_TZ ()
1055 {
1056   char **from, **to;
1057   for (to = from = environ; (*to = *from); from++)
1058     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1059       to++;
1060 }
1061 char TZ_GMT0[] = "TZ=GMT0";
1062 char TZ_PST8[] = "TZ=PST8";
1063 main()
1064 {
1065   time_t now = time ((time_t *) 0);
1066   int hour_GMT0, hour_unset;
1067   if (putenv (TZ_GMT0) != 0)
1068     exit (1);
1069   hour_GMT0 = localtime (&now)->tm_hour;
1070   unset_TZ ();
1071   hour_unset = localtime (&now)->tm_hour;
1072   if (putenv (TZ_PST8) != 0)
1073     exit (1);
1074   if (localtime (&now)->tm_hour == hour_GMT0)
1075     exit (1);
1076   unset_TZ ();
1077   if (localtime (&now)->tm_hour != hour_unset)
1078     exit (1);
1079   exit (0);
1080 }]])],
1081 [guile_cv_localtime_cache=no],
1082 [guile_cv_localtime_cache=yes],
1083 [# If we have tzset, assume the worst when cross-compiling.
1084 guile_cv_localtime_cache=yes])
1085 else
1086         # If we lack tzset, report that localtime does not cache TZ,
1087         # since we can't invalidate the cache if we don't have tzset.
1088         guile_cv_localtime_cache=no
1089 fi])dnl
1090 AC_MSG_RESULT($guile_cv_localtime_cache)
1091 if test $guile_cv_localtime_cache = yes; then
1092   AC_DEFINE([LOCALTIME_CACHE], 1, [Define if localtime caches the TZ setting.])
1093 fi
1094
1095 if test "$enable_regex" = yes; then
1096    if test "$ac_cv_header_regex_h" = yes ||
1097       test "$ac_cv_header_rxposix_h" = yes ||
1098       test "$ac_cv_header_rx_rxposix_h" = yes; then
1099      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
1100      [AC_CHECK_LIB(rx, main)
1101       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
1102      [AC_CHECK_LIB(regex, main)
1103       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
1104      )
1105      dnl The following should not be necessary, but for some reason
1106      dnl autoheader misses it if we don't include it!
1107      if test "$ac_cv_func_regcomp_norx" = yes ||
1108         test "$ac_cv_func_regcomp_regex" = yes ||
1109         test "$ac_cv_func_regcomp_rx" = yes; then
1110        AC_DEFINE([HAVE_REGCOMP], 1,
1111          [This is included as part of a workaround for a autoheader bug.])
1112      fi
1113    fi
1114 fi
1115
1116 AC_REPLACE_FUNCS([strerror memmove mkstemp])
1117
1118 # Reasons for testing:
1119 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
1120 #                                older systems
1121 #   sincos - GLIBC extension
1122 #
1123 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
1124
1125 # C99 specifies isinf and isnan as macros.
1126 # HP-UX provides only macros, no functions.
1127 # glibc 2.3.2 provides both macros and functions.
1128 # IRIX 6.5 and Solaris 8 only provide functions.
1129 #
1130 # The following tests detect isinf and isnan either as functions or as
1131 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
1132 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
1133 #
1134 AC_MSG_CHECKING([for isinf])
1135 AC_LINK_IFELSE(AC_LANG_SOURCE(
1136 [[#include <math.h>
1137 volatile double x = 0.0;
1138 int main () { return (isinf(x) != 0); }]]),
1139   [AC_MSG_RESULT([yes])
1140    AC_DEFINE([HAVE_ISINF], 1,
1141              [Define to 1 if you have the `isinf' macro or function.])],
1142   [AC_MSG_RESULT([no])])
1143 AC_MSG_CHECKING([for isnan])
1144 AC_LINK_IFELSE(AC_LANG_SOURCE(
1145 [[#include <math.h>
1146 volatile double x = 0.0;
1147 int main () { return (isnan(x) != 0); }]]),
1148   [AC_MSG_RESULT([yes])
1149    AC_DEFINE([HAVE_ISNAN], 1,
1150              [Define to 1 if you have the `isnan' macro or function.])],
1151   [AC_MSG_RESULT([no])])
1152
1153 # Reasons for checking:
1154 #
1155 #     st_rdev
1156 #     st_blksize
1157 #     st_blocks   not in mingw
1158 #     tm_gmtoff   BSD+GNU, not in C99
1159 #
1160 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
1161 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
1162 #
1163 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks, struct stat.st_atim, struct stat.st_mtim, struct stat.st_ctim],,,
1164                  [#define _GNU_SOURCE
1165 AC_INCLUDES_DEFAULT
1166 ])
1167
1168 AC_STRUCT_TIMEZONE
1169 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
1170 [#include <time.h>
1171 #ifdef TIME_WITH_SYS_TIME
1172 # include <sys/time.h>
1173 # include <time.h>
1174 #else
1175 # if HAVE_SYS_TIME_H
1176 #  include <sys/time.h>
1177 # else
1178 #  include <time.h>
1179 # endif
1180 #endif
1181 ])
1182 GUILE_STRUCT_UTIMBUF
1183
1184
1185 #--------------------------------------------------------------------
1186 #
1187 # Which way does the stack grow?
1188 #
1189 # Following code comes from Autoconf 2.61's internal _AC_LIBOBJ_ALLOCA
1190 # macro (/usr/share/autoconf/autoconf/functions.m4).  Gnulib has
1191 # very similar code, so in future we could look at using that.
1192 #
1193 # An important detail is that the code involves find_stack_direction
1194 # calling _itself_ - which means that find_stack_direction (or at
1195 # least the second find_stack_direction() call) cannot be inlined.
1196 # If the code could be inlined, that might cause the test to give
1197 # an incorrect answer.
1198 #--------------------------------------------------------------------
1199
1200 SCM_I_GSC_STACK_GROWS_UP=0
1201 AC_RUN_IFELSE([AC_LANG_SOURCE(
1202 [AC_INCLUDES_DEFAULT
1203 int
1204 find_stack_direction ()
1205 {
1206   static char *addr = 0;
1207   auto char dummy;
1208   if (addr == 0)
1209     {
1210       addr = &dummy;
1211       return find_stack_direction ();
1212     }
1213   else
1214     return (&dummy > addr) ? 1 : -1;
1215 }
1216
1217 int
1218 main ()
1219 {
1220   return find_stack_direction () < 0;
1221 }])],
1222                [SCM_I_GSC_STACK_GROWS_UP=1],
1223                [],
1224                [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1225
1226 #--------------------------------------------------------------------
1227 #
1228 # Boehm's GC library
1229 #
1230 #--------------------------------------------------------------------
1231 PKG_CHECK_MODULES([BDW_GC], [bdw-gc])
1232
1233 CFLAGS="$BDW_GC_CFLAGS $CFLAGS"
1234 LIBS="$BDW_GC_LIBS $LIBS"
1235
1236 # `GC_do_blocking ()' is available in GC 7.1 but not declared.
1237 AC_CHECK_FUNCS([GC_do_blocking])
1238 AC_CHECK_DECL([GC_do_blocking],
1239   [AC_DEFINE([HAVE_DECL_GC_DO_BLOCKING], [1],
1240     [Define this if the `GC_do_blocking ()' function is declared])],
1241   [],
1242   [#include <gc/gc.h>])
1243
1244 # `GC_fn_type' is not available in GC 7.1 and earlier.
1245 AC_CHECK_TYPE([GC_fn_type],
1246   [AC_DEFINE([HAVE_GC_FN_TYPE], [1],
1247     [Define this if the `GC_fn_type' type is available.])],
1248   [],
1249   [#include <gc/gc.h>])
1250
1251
1252 AC_CHECK_SIZEOF(float)
1253 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1254     AC_DEFINE([SCM_SINGLES], 1,
1255               [Define this if floats are the same size as longs.])
1256 fi
1257
1258 AC_MSG_CHECKING(for struct linger)
1259 AC_CACHE_VAL(scm_cv_struct_linger,
1260         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1261 #include <sys/types.h>
1262 #include <sys/socket.h>]],
1263                           [[struct linger lgr;  lgr.l_linger = 100]])],
1264                           [scm_cv_struct_linger="yes"],
1265                           [scm_cv_struct_linger="no"]))
1266 AC_MSG_RESULT($scm_cv_struct_linger)
1267 if test $scm_cv_struct_linger = yes; then
1268         AC_DEFINE([HAVE_STRUCT_LINGER], 1,
1269           [Define this if your system defines struct linger, for use with the
1270            getsockopt and setsockopt system calls.])
1271 fi
1272
1273
1274 # On mingw, struct timespec is in <pthread.h>.
1275 #
1276 AC_MSG_CHECKING(for struct timespec)
1277 AC_CACHE_VAL(scm_cv_struct_timespec,
1278         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1279 #include <time.h>
1280 #if HAVE_PTHREAD_H
1281 #include <pthread.h>
1282 #endif]], [[struct timespec t;  t.tv_nsec = 100]])],
1283           [scm_cv_struct_timespec="yes"],
1284           [scm_cv_struct_timespec="no"]))
1285 AC_MSG_RESULT($scm_cv_struct_timespec)
1286 if test $scm_cv_struct_timespec = yes; then
1287   AC_DEFINE([HAVE_STRUCT_TIMESPEC], 1,
1288     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1289 fi
1290
1291 #--------------------------------------------------------------------
1292 #
1293 # Flags for thread support
1294 #
1295 #--------------------------------------------------------------------
1296
1297 SCM_I_GSC_USE_PTHREAD_THREADS=0
1298 SCM_I_GSC_USE_NULL_THREADS=0
1299 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1300 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1301
1302 ### What thread package has the user asked for?
1303 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1304             , with_threads=yes)
1305
1306 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1307 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0)
1308
1309 case "$with_threads" in
1310   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1311
1312     build_pthread_support="yes"
1313
1314     ACX_PTHREAD([CC="$PTHREAD_CC"
1315        LIBS="$PTHREAD_LIBS $LIBS"
1316        SCM_I_GSC_USE_PTHREAD_THREADS=1
1317        with_threads="pthreads"],
1318       [with_threads="null"
1319        build_pthread_support="no"])
1320
1321     old_CFLAGS="$CFLAGS"
1322     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1323
1324     # Reasons for testing:
1325     #     pthread_getattr_np - "np" meaning "non portable" says it
1326     #         all; not present on MacOS X or Solaris 10
1327     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1328     #         all; specific to MacOS X
1329     #     pthread_sigmask - not available on mingw
1330     #
1331     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_sigmask)
1332
1333     # On past versions of Solaris, believe 8 through 10 at least, you
1334     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1335     # This is contrary to POSIX:
1336     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1337     # Check here if this style is required.
1338     #
1339     # glibc (2.3.6 at least) works both with or without braces, so the
1340     # test checks whether it works without.
1341     #
1342
1343     if test "$GCC" = "yes"; then
1344       # Since GCC only issues a warning for missing braces, so we need
1345       # `-Werror' to catch it.
1346       CFLAGS="-Werror -Wmissing-braces $CFLAGS"
1347     fi
1348
1349     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1350       guile_cv_need_braces_on_pthread_once_init,
1351       [AC_COMPILE_IFELSE([#include <pthread.h>
1352          pthread_once_t foo = PTHREAD_ONCE_INIT;],
1353         [guile_cv_need_braces_on_pthread_once_init=no],
1354         [guile_cv_need_braces_on_pthread_once_init=yes])])
1355     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1356       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1357     fi
1358
1359     # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX
1360     # 6.5.30m with GCC 3.3.
1361     AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces],
1362       guile_cv_need_braces_on_pthread_mutex_initializer,
1363       [AC_COMPILE_IFELSE([#include <pthread.h>
1364          pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;],
1365         [guile_cv_need_braces_on_pthread_mutex_initializer=no],
1366         [guile_cv_need_braces_on_pthread_mutex_initializer=yes])])
1367     if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then
1368       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1
1369     fi
1370
1371     CFLAGS="$old_CFLAGS"
1372
1373     # On Solaris, sched_yield lives in -lrt.
1374     AC_SEARCH_LIBS(sched_yield, rt)
1375
1376   ;;
1377 esac
1378
1379 case "$with_threads" in
1380   "pthreads")
1381   ;;
1382   "no" | "null")
1383     SCM_I_GSC_USE_NULL_THREADS=1
1384     SCM_I_GSC_HAVE_THREAD_STORAGE_CLASS=0
1385     with_threads="null-threads"
1386   ;;
1387   * )
1388     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1389   ;;
1390 esac
1391
1392 AC_MSG_CHECKING(what kind of threads to support)
1393 AC_MSG_RESULT($with_threads)
1394
1395 AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT],
1396   [test "x$build_pthread_support" = "xyes"])
1397
1398
1399 ## Check whether pthread_attr_getstack works for the main thread
1400
1401 if test "$with_threads" = pthreads; then
1402
1403 AC_MSG_CHECKING([whether pthread_attr_getstack works for the main thread])
1404 old_CFLAGS="$CFLAGS"
1405 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1406 if test "$cross_compiling" = "no"; then
1407   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1408   #if HAVE_PTHREAD_ATTR_GETSTACK
1409   #include <pthread.h>
1410
1411   int main ()
1412   {
1413     pthread_attr_t attr;
1414     void *start, *end;
1415     size_t size;
1416
1417     pthread_getattr_np (pthread_self (), &attr);
1418     pthread_attr_getstack (&attr, &start, &size);
1419     end = (char *)start + size;
1420
1421     if ((void *)&attr < start || (void *)&attr >= end)
1422       return 1;
1423     else
1424       return 0;
1425   }
1426   #else
1427   int main ()
1428   {
1429     return 1;
1430   }
1431   #endif
1432   ]])],
1433   [works=yes
1434    AC_DEFINE([PTHREAD_ATTR_GETSTACK_WORKS], [1], [Define when pthread_att_get_stack works for the main thread])],
1435   [works=no],
1436   [])
1437 else
1438   works="assuming it doesn't"
1439 fi
1440 CFLAGS="$old_CFLAGS"
1441 AC_MSG_RESULT($works)
1442
1443 GUILE_THREAD_LOCAL_STORAGE
1444
1445 fi # with_threads=pthreads
1446
1447
1448 ## Cross building
1449 if test "$cross_compiling" = "yes"; then
1450   AC_MSG_CHECKING(cc for build)
1451   ## /usr/bin/cc still uses wrong assembler
1452   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1453   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1454 else
1455   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1456 fi
1457
1458 ## AC_MSG_CHECKING("if we are cross compiling")
1459 ## AC_MSG_RESULT($cross_compiling)
1460 if test "$cross_compiling" = "yes"; then
1461    AC_MSG_RESULT($CC_FOR_BUILD)
1462 fi
1463
1464 ## No need as yet to be more elaborate
1465 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1466
1467 AC_SUBST(cross_compiling)
1468 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1469 AC_SUBST(CCLD_FOR_BUILD)
1470
1471 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1472 ## --HOST is the platform that PACKAGE is compiled for.
1473 HOST_CC="$CC_FOR_BUILD"
1474 AC_SUBST(HOST_CC)
1475
1476 if test "$cross_compiling" = "yes"; then
1477   AC_MSG_CHECKING(guile for build)
1478   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1479 else
1480   GUILE_FOR_BUILD='$(preinstguile)'
1481 fi
1482
1483 ## AC_MSG_CHECKING("if we are cross compiling")
1484 ## AC_MSG_RESULT($cross_compiling)
1485 if test "$cross_compiling" = "yes"; then
1486    AC_MSG_RESULT($GUILE_FOR_BUILD)
1487 fi
1488 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1489 AC_SUBST(GUILE_FOR_BUILD)
1490
1491 ## If we're using GCC, ask for aggressive warnings.
1492 GCC_CFLAGS=""
1493 case "$GCC" in
1494   yes )
1495     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1496     ## much stuff with generic function pointers for that to really be
1497     ## less than exasperating.
1498     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1499     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1500     POTENTIAL_GCC_CFLAGS="-Wall -Wmissing-prototypes \
1501       -Wdeclaration-after-statement -Wundef \
1502       -Wswitch-enum"
1503     # Do this here so we don't screw up any of the tests above that might
1504     # not be "warning free"
1505     if test "${GUILE_ERROR_ON_WARNING}" = yes
1506     then
1507         POTENTIAL_GCC_CFLAGS="${POTENTIAL_GCC_CFLAGS} -Werror"
1508         enable_compile_warnings=no
1509     fi
1510
1511     for flag in $POTENTIAL_GCC_CFLAGS
1512     do
1513         gl_WARN_ADD([$flag], [GCC_CFLAGS])
1514     done
1515     ;;
1516 esac
1517
1518 AC_SUBST(GCC_CFLAGS)
1519
1520 # Check for GNU ld's "-z relro".
1521 GUILE_GNU_LD_RELRO
1522
1523
1524 ## If we're creating a shared library (using libtool!), then we'll
1525 ## need to generate a list of .lo files corresponding to the .o files
1526 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1527 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1528
1529 ## We also need to create corresponding .doc and .x files
1530 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1531 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1532
1533 # GNU Readline bindings.
1534 GUILE_READLINE
1535
1536 AC_SUBST(GUILE_MAJOR_VERSION)
1537 AC_SUBST(GUILE_MINOR_VERSION)
1538 AC_SUBST(GUILE_MICRO_VERSION)
1539 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1540 AC_SUBST(GUILE_VERSION)
1541
1542 #######################################################################
1543 # library versioning
1544
1545 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1546 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1547 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1548 AC_SUBST(LIBGUILE_INTERFACE)
1549
1550 AC_SUBST(LIBGUILE_SRFI_SRFI_1_MAJOR)
1551 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1552 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1553 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1554 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1555
1556 AC_SUBST(LIBGUILE_SRFI_SRFI_60_MAJOR)
1557 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_CURRENT)
1558 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_REVISION)
1559 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_AGE)
1560 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE)
1561
1562 AC_SUBST(LIBGUILE_I18N_MAJOR)
1563 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1564 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1565 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1566 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1567
1568
1569 #######################################################################
1570
1571 dnl Tell guile-config what flags guile users should compile and link with.
1572 GUILE_LIBS="$LDFLAGS $LIBS"
1573 GUILE_CFLAGS="$CPPFLAGS $PTHREAD_CFLAGS"
1574 AC_SUBST(GUILE_LIBS)
1575 AC_SUBST(GUILE_CFLAGS)
1576
1577 AC_SUBST(AWK)
1578 AC_SUBST(LIBLOBJS)
1579 AC_SUBST(EXTRA_DOT_DOC_FILES)
1580 AC_SUBST(EXTRA_DOT_X_FILES)
1581
1582 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1583 top_builddir_absolute=`pwd`
1584 AC_SUBST(top_builddir_absolute)
1585 top_srcdir_absolute=`(cd $srcdir && pwd)`
1586 AC_SUBST(top_srcdir_absolute)
1587
1588 dnl `sitedir' goes into libpath.h and the pkg-config file.
1589 pkgdatadir="$datadir/$PACKAGE_TARNAME"
1590 sitedir="$pkgdatadir/site/$GUILE_EFFECTIVE_VERSION"
1591 AC_SUBST([sitedir])
1592
1593 # Additional SCM_I_GSC definitions are above.
1594 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1595 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1596 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1597 AC_SUBST([SCM_I_GSC_C_INLINE])
1598 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1599
1600 AC_CONFIG_FILES([
1601   Makefile
1602   am/Makefile
1603   lib/Makefile
1604   benchmark-suite/Makefile
1605   doc/Makefile
1606   doc/r5rs/Makefile
1607   doc/ref/Makefile
1608   emacs/Makefile
1609   examples/Makefile
1610   libguile/Makefile
1611   libguile/version.h
1612   srfi/Makefile
1613   guile-readline/Makefile
1614   test-suite/Makefile
1615   test-suite/standalone/Makefile
1616   test-suite/vm/Makefile
1617   meta/Makefile
1618   module/Makefile
1619 ])
1620
1621 AC_CONFIG_FILES([meta/guile-2.0.pc])
1622 AC_CONFIG_FILES([meta/guile-2.0-uninstalled.pc])
1623 AC_CONFIG_FILES([doc/ref/effective-version.texi])
1624
1625 GUILE_CONFIG_SCRIPT([check-guile])
1626 GUILE_CONFIG_SCRIPT([benchmark-guile])
1627 GUILE_CONFIG_SCRIPT([meta/guile])
1628 GUILE_CONFIG_SCRIPT([meta/uninstalled-env])
1629 GUILE_CONFIG_SCRIPT([meta/gdb-uninstalled-guile])
1630 GUILE_CONFIG_SCRIPT([meta/guile-tools])
1631 GUILE_CONFIG_SCRIPT([libguile/guile-snarf])
1632 GUILE_CONFIG_SCRIPT([libguile/guile-snarf-docs])
1633 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-use-srfi])
1634 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-fast-slot-ref])
1635
1636 AC_OUTPUT
1637
1638 dnl Local Variables:
1639 dnl comment-start: "dnl "
1640 dnl comment-end: ""
1641 dnl comment-start-skip: "\\bdnl\\b\\s *"
1642 dnl End: