| 1 | # configmake.m4 serial 1 |
| 2 | dnl Copyright (C) 2010-2013 Free Software Foundation, Inc. |
| 3 | dnl This file is free software; the Free Software Foundation |
| 4 | dnl gives unlimited permission to copy and/or distribute it, |
| 5 | dnl with or without modifications, as long as this notice is preserved. |
| 6 | |
| 7 | # gl_CONFIGMAKE_PREP |
| 8 | # ------------------ |
| 9 | # Guarantee all of the standard directory variables, even when used with |
| 10 | # autoconf 2.59 (datarootdir wasn't supported until 2.59c) or automake |
| 11 | # 1.9.6 (pkglibexecdir wasn't supported until 1.10b.). |
| 12 | AC_DEFUN([gl_CONFIGMAKE_PREP], |
| 13 | [ |
| 14 | dnl Technically, datadir should default to datarootdir. But if |
| 15 | dnl autoconf is too old to provide datarootdir, then reversing the |
| 16 | dnl definition is a reasonable compromise. Only AC_SUBST a variable |
| 17 | dnl if it was not already defined earlier by autoconf. |
| 18 | if test "x$datarootdir" = x; then |
| 19 | AC_SUBST([datarootdir], ['${datadir}']) |
| 20 | fi |
| 21 | dnl Copy the approach used in autoconf 2.60. |
| 22 | if test "x$docdir" = x; then |
| 23 | AC_SUBST([docdir], [m4_ifset([AC_PACKAGE_TARNAME], |
| 24 | ['${datarootdir}/doc/${PACKAGE_TARNAME}'], |
| 25 | ['${datarootdir}/doc/${PACKAGE}'])]) |
| 26 | fi |
| 27 | dnl The remaining variables missing from autoconf 2.59 are easier. |
| 28 | if test "x$htmldir" = x; then |
| 29 | AC_SUBST([htmldir], ['${docdir}']) |
| 30 | fi |
| 31 | if test "x$dvidir" = x; then |
| 32 | AC_SUBST([dvidir], ['${docdir}']) |
| 33 | fi |
| 34 | if test "x$pdfdir" = x; then |
| 35 | AC_SUBST([pdfdir], ['${docdir}']) |
| 36 | fi |
| 37 | if test "x$psdir" = x; then |
| 38 | AC_SUBST([psdir], ['${docdir}']) |
| 39 | fi |
| 40 | if test "x$lispdir" = x; then |
| 41 | AC_SUBST([lispdir], ['${datarootdir}/emacs/site-lisp']) |
| 42 | fi |
| 43 | if test "x$localedir" = x; then |
| 44 | AC_SUBST([localedir], ['${datarootdir}/locale']) |
| 45 | fi |
| 46 | |
| 47 | dnl Automake 1.9.6 only lacks pkglibexecdir; and since 1.11 merely |
| 48 | dnl provides it without AC_SUBST, this blind use of AC_SUBST is safe. |
| 49 | AC_SUBST([pkglibexecdir], ['${libexecdir}/${PACKAGE}']) |
| 50 | ]) |