[bpt/guile.git] / m4 / gnulib-common.m4

# gnulib-common.m4 serial 26
dnl Copyright (C) 2007-2011 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

# gl_COMMON
# is expanded unconditionally through gnulib-tool magic.
AC_DEFUN([gl_COMMON], [
  dnl Use AC_REQUIRE here, so that the code is expanded once only.
  AC_REQUIRE([gl_00GNULIB])
  AC_REQUIRE([gl_COMMON_BODY])
])
AC_DEFUN([gl_COMMON_BODY], [
  AH_VERBATIM([isoc99_inline],
[/* Work around a bug in Apple GCC 4.0.1 build 5465: In C99 mode, it supports
   the ISO C 99 semantics of 'extern inline' (unlike the GNU C semantics of
   earlier versions), but does not display it by setting __GNUC_STDC_INLINE__.
   __APPLE__ && __MACH__ test for MacOS X.
   __APPLE_CC__ tests for the Apple compiler and its version.
   __STDC_VERSION__ tests for the C99 mode.  */
#if defined __APPLE__ && defined __MACH__ && __APPLE_CC__ >= 5465 && !defined __cplusplus && __STDC_VERSION__ >= 199901L && !defined __GNUC_STDC_INLINE__
# define __GNUC_STDC_INLINE__ 1
#endif])
  AH_VERBATIM([unused_parameter],
[/* Define as a marker that can be attached to declarations that might not
    be used.  This helps to reduce warnings, such as from
    GCC -Wunused-parameter.  */
#if __GNUC__ >= 3 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
# define _GL_UNUSED __attribute__ ((__unused__))
#else
# define _GL_UNUSED
#endif
/* The name _UNUSED_PARAMETER_ is an earlier spelling, although the name
   is a misnomer outside of parameter lists.  */
#define _UNUSED_PARAMETER_ _GL_UNUSED

/* The __pure__ attribute was added in gcc 2.96.  */
#if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 96)
# define _GL_ATTRIBUTE_PURE __attribute__ ((__pure__))
#else
# define _GL_ATTRIBUTE_PURE /* empty */
#endif

/* The __const__ attribute was added in gcc 2.95.  */
#if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 95)
# define _GL_ATTRIBUTE_CONST __attribute__ ((__const__))
#else
# define _GL_ATTRIBUTE_CONST /* empty */
#endif
])
  dnl Preparation for running test programs:
  dnl Tell glibc to write diagnostics from -D_FORTIFY_SOURCE=2 to stderr, not
  dnl to /dev/tty, so they can be redirected to log files.  Such diagnostics
  dnl arise e.g., in the macros gl_PRINTF_DIRECTIVE_N, gl_SNPRINTF_DIRECTIVE_N.
  LIBC_FATAL_STDERR_=1
  export LIBC_FATAL_STDERR_
])

# gl_MODULE_INDICATOR_CONDITION
# expands to a C preprocessor expression that evaluates to 1 or 0, depending
# whether a gnulib module that has been requested shall be considered present
# or not.
m4_define([gl_MODULE_INDICATOR_CONDITION], [1])

# gl_MODULE_INDICATOR_SET_VARIABLE([modulename])
# sets the shell variable that indicates the presence of the given module to
# a C preprocessor expression that will evaluate to 1.
AC_DEFUN([gl_MODULE_INDICATOR_SET_VARIABLE],
[
  gl_MODULE_INDICATOR_SET_VARIABLE_AUX(
    [GNULIB_[]m4_translit([[$1]],
                          [abcdefghijklmnopqrstuvwxyz./-],
                          [ABCDEFGHIJKLMNOPQRSTUVWXYZ___])],
    [gl_MODULE_INDICATOR_CONDITION])
])

# gl_MODULE_INDICATOR_SET_VARIABLE_AUX([variable])
# modifies the shell variable to include the gl_MODULE_INDICATOR_CONDITION.
# The shell variable's value is a C preprocessor expression that evaluates
# to 0 or 1.
AC_DEFUN([gl_MODULE_INDICATOR_SET_VARIABLE_AUX],
[
  m4_if(m4_defn([gl_MODULE_INDICATOR_CONDITION]), [1],
    [
     dnl Simplify the expression VALUE || 1 to 1.
     $1=1
    ],
    [gl_MODULE_INDICATOR_SET_VARIABLE_AUX_OR([$1],
                                             [gl_MODULE_INDICATOR_CONDITION])])
])

# gl_MODULE_INDICATOR_SET_VARIABLE_AUX_OR([variable], [condition])
# modifies the shell variable to include the given condition.  The shell
# variable's value is a C preprocessor expression that evaluates to 0 or 1.
AC_DEFUN([gl_MODULE_INDICATOR_SET_VARIABLE_AUX_OR],
[
  dnl Simplify the expression 1 || CONDITION to 1.
  if test "$[]$1" != 1; then
    dnl Simplify the expression 0 || CONDITION to CONDITION.
    if test "$[]$1" = 0; then
      $1=$2
    else
      $1="($[]$1 || $2)"
    fi
  fi
])

# gl_MODULE_INDICATOR([modulename])
# defines a C macro indicating the presence of the given module
# in a location where it can be used.
#                                             |  Value  |   Value   |
#                                             | in lib/ | in tests/ |
# --------------------------------------------+---------+-----------+
# Module present among main modules:          |    1    |     1     |
# --------------------------------------------+---------+-----------+
# Module present among tests-related modules: |    0    |     1     |
# --------------------------------------------+---------+-----------+
# Module not present at all:                  |    0    |     0     |
# --------------------------------------------+---------+-----------+
AC_DEFUN([gl_MODULE_INDICATOR],
[
  AC_DEFINE_UNQUOTED([GNULIB_]m4_translit([[$1]],
      [abcdefghijklmnopqrstuvwxyz./-],
      [ABCDEFGHIJKLMNOPQRSTUVWXYZ___]),
    [gl_MODULE_INDICATOR_CONDITION],
    [Define to a C preprocessor expression that evaluates to 1 or 0,
     depending whether the gnulib module $1 shall be considered present.])
])

# gl_MODULE_INDICATOR_FOR_TESTS([modulename])
# defines a C macro indicating the presence of the given module
# in lib or tests. This is useful to determine whether the module
# should be tested.
#                                             |  Value  |   Value   |
#                                             | in lib/ | in tests/ |
# --------------------------------------------+---------+-----------+
# Module present among main modules:          |    1    |     1     |
# --------------------------------------------+---------+-----------+
# Module present among tests-related modules: |    1    |     1     |
# --------------------------------------------+---------+-----------+
# Module not present at all:                  |    0    |     0     |
# --------------------------------------------+---------+-----------+
AC_DEFUN([gl_MODULE_INDICATOR_FOR_TESTS],
[
  AC_DEFINE([GNULIB_TEST_]m4_translit([[$1]],
      [abcdefghijklmnopqrstuvwxyz./-],
      [ABCDEFGHIJKLMNOPQRSTUVWXYZ___]), [1],
    [Define to 1 when the gnulib module $1 should be tested.])
])

# gl_ASSERT_NO_GNULIB_POSIXCHECK
# asserts that there will never be a need to #define GNULIB_POSIXCHECK.
# and thereby enables an optimization of configure and config.h.
# Used by Emacs.
AC_DEFUN([gl_ASSERT_NO_GNULIB_POSIXCHECK],
[
  dnl Override gl_WARN_ON_USE_PREPARE.
  dnl But hide this definition from 'aclocal'.
  AC_DEFUN([gl_W][ARN_ON_USE_PREPARE], [])
])

# gl_ASSERT_NO_GNULIB_TESTS
# asserts that there will be no gnulib tests in the scope of the configure.ac
# and thereby enables an optimization of config.h.
# Used by Emacs.
AC_DEFUN([gl_ASSERT_NO_GNULIB_TESTS],
[
  dnl Override gl_MODULE_INDICATOR_FOR_TESTS.
  AC_DEFUN([gl_MODULE_INDICATOR_FOR_TESTS], [])
])

# Test whether <features.h> exists.
# Set HAVE_FEATURES_H.
AC_DEFUN([gl_FEATURES_H],
[
  AC_CHECK_HEADERS_ONCE([features.h])
  if test $ac_cv_header_features_h = yes; then
    HAVE_FEATURES_H=1
  else
    HAVE_FEATURES_H=0
  fi
  AC_SUBST([HAVE_FEATURES_H])
])

# m4_foreach_w
# is a backport of autoconf-2.59c's m4_foreach_w.
# Remove this macro when we can assume autoconf >= 2.60.
m4_ifndef([m4_foreach_w],
  [m4_define([m4_foreach_w],
    [m4_foreach([$1], m4_split(m4_normalize([$2]), [ ]), [$3])])])

# AS_VAR_IF(VAR, VALUE, [IF-MATCH], [IF-NOT-MATCH])
# ----------------------------------------------------
# Backport of autoconf-2.63b's macro.
# Remove this macro when we can assume autoconf >= 2.64.
m4_ifndef([AS_VAR_IF],
[m4_define([AS_VAR_IF],
[AS_IF([test x"AS_VAR_GET([$1])" = x""$2], [$3], [$4])])])

# AC_PROG_MKDIR_P
# is a backport of autoconf-2.60's AC_PROG_MKDIR_P, with a fix
# for interoperability with automake-1.9.6 from autoconf-2.62.
# Remove this macro when we can assume autoconf >= 2.62 or
# autoconf >= 2.60 && automake >= 1.10.
m4_ifdef([AC_PROG_MKDIR_P], [
  dnl For automake-1.9.6 && autoconf < 2.62: Ensure MKDIR_P is AC_SUBSTed.
  m4_define([AC_PROG_MKDIR_P],
    m4_defn([AC_PROG_MKDIR_P])[
    AC_SUBST([MKDIR_P])])], [
  dnl For autoconf < 2.60: Backport of AC_PROG_MKDIR_P.
  AC_DEFUN_ONCE([AC_PROG_MKDIR_P],
    [AC_REQUIRE([AM_PROG_MKDIR_P])dnl defined by automake
     MKDIR_P='$(mkdir_p)'
     AC_SUBST([MKDIR_P])])])

# AC_C_RESTRICT
# This definition overrides the AC_C_RESTRICT macro from autoconf 2.60..2.61,
# so that mixed use of GNU C and GNU C++ and mixed use of Sun C and Sun C++
# works.
# This definition can be removed once autoconf >= 2.62 can be assumed.
m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]),[2.62]),[-1],[
AC_DEFUN([AC_C_RESTRICT],
[AC_CACHE_CHECK([for C/C++ restrict keyword], [ac_cv_c_restrict],
  [ac_cv_c_restrict=no
   # The order here caters to the fact that C++ does not require restrict.
   for ac_kw in __restrict __restrict__ _Restrict restrict; do
     AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
      [[typedef int * int_ptr;
        int foo (int_ptr $ac_kw ip) {
        return ip[0];
       }]],
      [[int s[1];
        int * $ac_kw t = s;
        t[0] = 0;
        return foo(t)]])],
      [ac_cv_c_restrict=$ac_kw])
     test "$ac_cv_c_restrict" != no && break
   done
  ])
 AH_VERBATIM([restrict],
[/* Define to the equivalent of the C99 'restrict' keyword, or to
   nothing if this is not supported.  Do not define if restrict is
   supported directly.  */
#undef restrict
/* Work around a bug in Sun C++: it does not support _Restrict, even
   though the corresponding Sun C compiler does, which causes
   "#define restrict _Restrict" in the previous line.  Perhaps some future
   version of Sun C++ will work with _Restrict; if so, it'll probably
   define __RESTRICT, just as Sun C does.  */
#if defined __SUNPRO_CC && !defined __RESTRICT
# define _Restrict
#endif])
 case $ac_cv_c_restrict in
   restrict) ;;
   no) AC_DEFINE([restrict], []) ;;
   *)  AC_DEFINE_UNQUOTED([restrict], [$ac_cv_c_restrict]) ;;
 esac
])
])

# gl_BIGENDIAN
# is like AC_C_BIGENDIAN, except that it can be AC_REQUIREd.
# Note that AC_REQUIRE([AC_C_BIGENDIAN]) does not work reliably because some
# macros invoke AC_C_BIGENDIAN with arguments.
AC_DEFUN([gl_BIGENDIAN],
[
  AC_C_BIGENDIAN
])

# gl_CACHE_VAL_SILENT(cache-id, command-to-set-it)
# is like AC_CACHE_VAL(cache-id, command-to-set-it), except that it does not
# output a spurious "(cached)" mark in the midst of other configure output.
# This macro should be used instead of AC_CACHE_VAL when it is not surrounded
# by an AC_MSG_CHECKING/AC_MSG_RESULT pair.
AC_DEFUN([gl_CACHE_VAL_SILENT],
[
  saved_as_echo_n="$as_echo_n"
  as_echo_n=':'
  AC_CACHE_VAL([$1], [$2])
  as_echo_n="$saved_as_echo_n"
])
Commit	Line	Data
3d458a81	1	# gnulib-common.m4 serial 26
49114fd4	2	dnl Copyright (C) 2007-2011 Free Software Foundation, Inc.
103dc4d4 LC	3	dnl This file is free software; the Free Software Foundation
	4	dnl gives unlimited permission to copy and/or distribute it,
	5	dnl with or without modifications, as long as this notice is preserved.
	6
	7	# gl_COMMON
	8	# is expanded unconditionally through gnulib-tool magic.
	9	AC_DEFUN([gl_COMMON], [
	10	dnl Use AC_REQUIRE here, so that the code is expanded once only.
f240aacb	11	AC_REQUIRE([gl_00GNULIB])
103dc4d4 LC	12	AC_REQUIRE([gl_COMMON_BODY])
	13	])
	14	AC_DEFUN([gl_COMMON_BODY], [
	15	AH_VERBATIM([isoc99_inline],
	16	[/* Work around a bug in Apple GCC 4.0.1 build 5465: In C99 mode, it supports
	17	the ISO C 99 semantics of 'extern inline' (unlike the GNU C semantics of
	18	earlier versions), but does not display it by setting __GNUC_STDC_INLINE__.
	19	__APPLE__ && __MACH__ test for MacOS X.
	20	__APPLE_CC__ tests for the Apple compiler and its version.
	21	__STDC_VERSION__ tests for the C99 mode. */
	22	#if defined __APPLE__ && defined __MACH__ && __APPLE_CC__ >= 5465 && !defined __cplusplus && __STDC_VERSION__ >= 199901L && !defined __GNUC_STDC_INLINE__
	23	# define __GNUC_STDC_INLINE__ 1
	24	#endif])
aa7a939c	25	AH_VERBATIM([unused_parameter],
61cd9dc9 LC	26	[/* Define as a marker that can be attached to declarations that might not
	27	be used. This helps to reduce warnings, such as from
	28	GCC -Wunused-parameter. */
aa7a939c	29	#if __GNUC__ >= 3 \|\| (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
61cd9dc9	30	# define _GL_UNUSED __attribute__ ((__unused__))
aa7a939c	31	#else
61cd9dc9	32	# define _GL_UNUSED
aa7a939c	33	#endif
61cd9dc9 LC	34	/* The name _UNUSED_PARAMETER_ is an earlier spelling, although the name
	35	is a misnomer outside of parameter lists. */
	36	#define _UNUSED_PARAMETER_ _GL_UNUSED
3d458a81 AW	37
	38	/* The __pure__ attribute was added in gcc 2.96. */
	39	#if __GNUC__ > 2 \|\| (__GNUC__ == 2 && __GNUC_MINOR__ >= 96)
	40	# define _GL_ATTRIBUTE_PURE __attribute__ ((__pure__))
	41	#else
	42	# define _GL_ATTRIBUTE_PURE /* empty */
	43	#endif
	44
	45	/* The __const__ attribute was added in gcc 2.95. */
	46	#if __GNUC__ > 2 \|\| (__GNUC__ == 2 && __GNUC_MINOR__ >= 95)
	47	# define _GL_ATTRIBUTE_CONST __attribute__ ((__const__))
	48	#else
	49	# define _GL_ATTRIBUTE_CONST /* empty */
	50	#endif
aa7a939c	51	])
a927b6c1 LC	52	dnl Preparation for running test programs:
	53	dnl Tell glibc to write diagnostics from -D_FORTIFY_SOURCE=2 to stderr, not
	54	dnl to /dev/tty, so they can be redirected to log files. Such diagnostics
	55	dnl arise e.g., in the macros gl_PRINTF_DIRECTIVE_N, gl_SNPRINTF_DIRECTIVE_N.
	56	LIBC_FATAL_STDERR_=1
	57	export LIBC_FATAL_STDERR_
	58	])
	59
	60	# gl_MODULE_INDICATOR_CONDITION
	61	# expands to a C preprocessor expression that evaluates to 1 or 0, depending
	62	# whether a gnulib module that has been requested shall be considered present
	63	# or not.
3d458a81	64	m4_define([gl_MODULE_INDICATOR_CONDITION], [1])
a927b6c1 LC	65
	66	# gl_MODULE_INDICATOR_SET_VARIABLE([modulename])
	67	# sets the shell variable that indicates the presence of the given module to
	68	# a C preprocessor expression that will evaluate to 1.
	69	AC_DEFUN([gl_MODULE_INDICATOR_SET_VARIABLE],
	70	[
3d458a81 AW	71	gl_MODULE_INDICATOR_SET_VARIABLE_AUX(
	72	[GNULIB_[]m4_translit([[$1]],
	73	[abcdefghijklmnopqrstuvwxyz./-],
	74	[ABCDEFGHIJKLMNOPQRSTUVWXYZ___])],
	75	[gl_MODULE_INDICATOR_CONDITION])
	76	])
	77
	78	# gl_MODULE_INDICATOR_SET_VARIABLE_AUX([variable])
	79	# modifies the shell variable to include the gl_MODULE_INDICATOR_CONDITION.
	80	# The shell variable's value is a C preprocessor expression that evaluates
	81	# to 0 or 1.
	82	AC_DEFUN([gl_MODULE_INDICATOR_SET_VARIABLE_AUX],
	83	[
	84	m4_if(m4_defn([gl_MODULE_INDICATOR_CONDITION]), [1],
	85	[
	86	dnl Simplify the expression VALUE \|\| 1 to 1.
	87	$1=1
	88	],
	89	[gl_MODULE_INDICATOR_SET_VARIABLE_AUX_OR([$1],
	90	[gl_MODULE_INDICATOR_CONDITION])])
	91	])
	92
	93	# gl_MODULE_INDICATOR_SET_VARIABLE_AUX_OR([variable], [condition])
	94	# modifies the shell variable to include the given condition. The shell
	95	# variable's value is a C preprocessor expression that evaluates to 0 or 1.
	96	AC_DEFUN([gl_MODULE_INDICATOR_SET_VARIABLE_AUX_OR],
	97	[
	98	dnl Simplify the expression 1 \|\| CONDITION to 1.
	99	if test "$[]$1" != 1; then
	100	dnl Simplify the expression 0 \|\| CONDITION to CONDITION.
	101	if test "$[]$1" = 0; then
	102	$1=$2
	103	else
	104	$1="($[]$1 \|\| $2)"
	105	fi
	106	fi
103dc4d4 LC	107	])
	108
	109	# gl_MODULE_INDICATOR([modulename])
a927b6c1 LC	110	# defines a C macro indicating the presence of the given module
	111	# in a location where it can be used.
	112	# \| Value \| Value \|
	113	# \| in lib/ \| in tests/ \|
	114	# --------------------------------------------+---------+-----------+
	115	# Module present among main modules: \| 1 \| 1 \|
	116	# --------------------------------------------+---------+-----------+
	117	# Module present among tests-related modules: \| 0 \| 1 \|
	118	# --------------------------------------------+---------+-----------+
	119	# Module not present at all: \| 0 \| 0 \|
	120	# --------------------------------------------+---------+-----------+
103dc4d4 LC	121	AC_DEFUN([gl_MODULE_INDICATOR],
103dc4d4 LC	122	[
a927b6c1 LC	123	AC_DEFINE_UNQUOTED([GNULIB_]m4_translit([[$1]],
	124	[abcdefghijklmnopqrstuvwxyz./-],
	125	[ABCDEFGHIJKLMNOPQRSTUVWXYZ___]),
	126	[gl_MODULE_INDICATOR_CONDITION],
	127	[Define to a C preprocessor expression that evaluates to 1 or 0,
	128	depending whether the gnulib module $1 shall be considered present.])
	129	])
	130
	131	# gl_MODULE_INDICATOR_FOR_TESTS([modulename])
	132	# defines a C macro indicating the presence of the given module
	133	# in lib or tests. This is useful to determine whether the module
	134	# should be tested.
	135	# \| Value \| Value \|
	136	# \| in lib/ \| in tests/ \|
	137	# --------------------------------------------+---------+-----------+
	138	# Module present among main modules: \| 1 \| 1 \|
	139	# --------------------------------------------+---------+-----------+
	140	# Module present among tests-related modules: \| 1 \| 1 \|
	141	# --------------------------------------------+---------+-----------+
	142	# Module not present at all: \| 0 \| 0 \|
	143	# --------------------------------------------+---------+-----------+
	144	AC_DEFUN([gl_MODULE_INDICATOR_FOR_TESTS],
	145	[
	146	AC_DEFINE([GNULIB_TEST_]m4_translit([[$1]],
	147	[abcdefghijklmnopqrstuvwxyz./-],
	148	[ABCDEFGHIJKLMNOPQRSTUVWXYZ___]), [1],
	149	[Define to 1 when the gnulib module $1 should be tested.])
103dc4d4 LC	150	])
103dc4d4 LC	151
49114fd4 LC	152	# gl_ASSERT_NO_GNULIB_POSIXCHECK
	153	# asserts that there will never be a need to #define GNULIB_POSIXCHECK.
	154	# and thereby enables an optimization of configure and config.h.
	155	# Used by Emacs.
	156	AC_DEFUN([gl_ASSERT_NO_GNULIB_POSIXCHECK],
	157	[
	158	dnl Override gl_WARN_ON_USE_PREPARE.
dd7d0148 LC	159	dnl But hide this definition from 'aclocal'.
dd7d0148 LC	160	AC_DEFUN([gl_W][ARN_ON_USE_PREPARE], [])
49114fd4 LC	161	])
	162
	163	# gl_ASSERT_NO_GNULIB_TESTS
	164	# asserts that there will be no gnulib tests in the scope of the configure.ac
	165	# and thereby enables an optimization of config.h.
	166	# Used by Emacs.
	167	AC_DEFUN([gl_ASSERT_NO_GNULIB_TESTS],
	168	[
	169	dnl Override gl_MODULE_INDICATOR_FOR_TESTS.
	170	AC_DEFUN([gl_MODULE_INDICATOR_FOR_TESTS], [])
	171	])
	172
0f00f2c3 LC	173	# Test whether <features.h> exists.
	174	# Set HAVE_FEATURES_H.
	175	AC_DEFUN([gl_FEATURES_H],
	176	[
	177	AC_CHECK_HEADERS_ONCE([features.h])
	178	if test $ac_cv_header_features_h = yes; then
	179	HAVE_FEATURES_H=1
	180	else
	181	HAVE_FEATURES_H=0
	182	fi
	183	AC_SUBST([HAVE_FEATURES_H])
	184	])
	185
103dc4d4 LC	186	# m4_foreach_w
	187	# is a backport of autoconf-2.59c's m4_foreach_w.
	188	# Remove this macro when we can assume autoconf >= 2.60.
	189	m4_ifndef([m4_foreach_w],
	190	[m4_define([m4_foreach_w],
	191	[m4_foreach([$1], m4_split(m4_normalize([$2]), [ ]), [$3])])])
	192
61cd9dc9 LC	193	# AS_VAR_IF(VAR, VALUE, [IF-MATCH], [IF-NOT-MATCH])
	194	# ----------------------------------------------------
	195	# Backport of autoconf-2.63b's macro.
	196	# Remove this macro when we can assume autoconf >= 2.64.
	197	m4_ifndef([AS_VAR_IF],
	198	[m4_define([AS_VAR_IF],
	199	[AS_IF([test x"AS_VAR_GET([$1])" = x""$2], [$3], [$4])])])
	200
103dc4d4	201	# AC_PROG_MKDIR_P
f4c79b3c LC	202	# is a backport of autoconf-2.60's AC_PROG_MKDIR_P, with a fix
	203	# for interoperability with automake-1.9.6 from autoconf-2.62.
	204	# Remove this macro when we can assume autoconf >= 2.62 or
	205	# autoconf >= 2.60 && automake >= 1.10.
	206	m4_ifdef([AC_PROG_MKDIR_P], [
	207	dnl For automake-1.9.6 && autoconf < 2.62: Ensure MKDIR_P is AC_SUBSTed.
	208	m4_define([AC_PROG_MKDIR_P],
	209	m4_defn([AC_PROG_MKDIR_P])[
	210	AC_SUBST([MKDIR_P])])], [
	211	dnl For autoconf < 2.60: Backport of AC_PROG_MKDIR_P.
f240aacb	212	AC_DEFUN_ONCE([AC_PROG_MKDIR_P],
103dc4d4 LC	213	[AC_REQUIRE([AM_PROG_MKDIR_P])dnl defined by automake
	214	MKDIR_P='$(mkdir_p)'
	215	AC_SUBST([MKDIR_P])])])
	216
	217	# AC_C_RESTRICT
	218	# This definition overrides the AC_C_RESTRICT macro from autoconf 2.60..2.61,
	219	# so that mixed use of GNU C and GNU C++ and mixed use of Sun C and Sun C++
	220	# works.
	221	# This definition can be removed once autoconf >= 2.62 can be assumed.
a927b6c1	222	m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]),[2.62]),[-1],[
103dc4d4	223	AC_DEFUN([AC_C_RESTRICT],
f240aacb	224	[AC_CACHE_CHECK([for C/C++ restrict keyword], [ac_cv_c_restrict],
103dc4d4 LC	225	[ac_cv_c_restrict=no
	226	# The order here caters to the fact that C++ does not require restrict.
	227	for ac_kw in __restrict __restrict__ _Restrict restrict; do
	228	AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
	229	[[typedef int * int_ptr;
1cd4fffc LC	230	int foo (int_ptr $ac_kw ip) {
1cd4fffc LC	231	return ip[0];
103dc4d4 LC	232	}]],
103dc4d4 LC	233	[[int s[1];
1cd4fffc LC	234	int * $ac_kw t = s;
	235	t[0] = 0;
	236	return foo(t)]])],
103dc4d4 LC	237	[ac_cv_c_restrict=$ac_kw])
	238	test "$ac_cv_c_restrict" != no && break
	239	done
	240	])
	241	AH_VERBATIM([restrict],
	242	[/* Define to the equivalent of the C99 'restrict' keyword, or to
	243	nothing if this is not supported. Do not define if restrict is
	244	supported directly. */
	245	#undef restrict
	246	/* Work around a bug in Sun C++: it does not support _Restrict, even
	247	though the corresponding Sun C compiler does, which causes
	248	"#define restrict _Restrict" in the previous line. Perhaps some future
	249	version of Sun C++ will work with _Restrict; if so, it'll probably
	250	define __RESTRICT, just as Sun C does. */
	251	#if defined __SUNPRO_CC && !defined __RESTRICT
	252	# define _Restrict
	253	#endif])
	254	case $ac_cv_c_restrict in
	255	restrict) ;;
	256	no) AC_DEFINE([restrict], []) ;;
	257	*) AC_DEFINE_UNQUOTED([restrict], [$ac_cv_c_restrict]) ;;
	258	esac
	259	])
a927b6c1	260	])
f240aacb LC	261
	262	# gl_BIGENDIAN
	263	# is like AC_C_BIGENDIAN, except that it can be AC_REQUIREd.
	264	# Note that AC_REQUIRE([AC_C_BIGENDIAN]) does not work reliably because some
	265	# macros invoke AC_C_BIGENDIAN with arguments.
	266	AC_DEFUN([gl_BIGENDIAN],
	267	[
	268	AC_C_BIGENDIAN
	269	])
	270
	271	# gl_CACHE_VAL_SILENT(cache-id, command-to-set-it)
	272	# is like AC_CACHE_VAL(cache-id, command-to-set-it), except that it does not
	273	# output a spurious "(cached)" mark in the midst of other configure output.
	274	# This macro should be used instead of AC_CACHE_VAL when it is not surrounded
	275	# by an AC_MSG_CHECKING/AC_MSG_RESULT pair.
	276	AC_DEFUN([gl_CACHE_VAL_SILENT],
	277	[
	278	saved_as_echo_n="$as_echo_n"
	279	as_echo_n=':'
	280	AC_CACHE_VAL([$1], [$2])
	281	as_echo_n="$saved_as_echo_n"
	282	])