[bpt/guile.git] / configure.in

dnl   configuration script for Guile
dnl   Process this file with autoconf to produce configure.
dnl
dnl  Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003 Free Software Foundation, Inc.
dnl
dnl  This file is part of GUILE
dnl
dnl  GUILE is free software; you can redistribute it and/or modify it
dnl  under the terms of the GNU General Public License as published by
dnl  the Free Software Foundation; either version 2, or (at your
dnl  option) any later version.
dnl
dnl  GUILE is distributed in the hope that it will be useful, but
dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
dnl  General Public License for more details.
dnl
dnl  You should have received a copy of the GNU General Public License
dnl  along with GUILE; see the file COPYING.  If not, write to the
dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
dnl  Boston, MA 02111-1307, USA.

AC_PREREQ(2.53)

AC_INIT
AC_CONFIG_SRCDIR([GUILE-VERSION])
. $srcdir/GUILE-VERSION
AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
AM_MAINTAINER_MODE
AM_CONFIG_HEADER([config.h])

#--------------------------------------------------------------------
#
# Independent Subdirectories
#
#--------------------------------------------------------------------

AC_CONFIG_SUBDIRS(guile-readline)

#--------------------------------------------------------------------

dnl Some more checks for Win32
AC_CYGWIN
AC_MINGW32
AC_LIBTOOL_WIN32_DLL

AC_PROG_INSTALL
AC_PROG_CC
AC_PROG_CPP
AC_PROG_AWK

AC_AIX
AC_ISC_POSIX
AC_MINIX

AM_PROG_CC_STDC

AC_LIBTOOL_DLOPEN
AM_PROG_LIBTOOL
AC_LIB_LTDL

AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)

#--------------------------------------------------------------------
#
# User options (after above tests that may set default CFLAGS etc.)
#
#--------------------------------------------------------------------

GUILE_ERROR_ON_WARNING="yes"

AC_ARG_ENABLE(error-on-warning,
  [  --enable-error-on-warning    treat compile warnings as errors],
  [case "${enableval}" in
     yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
     no | n)  GUILE_ERROR_ON_WARNING="no" ;;
     *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
   esac])

SCM_I_GSC_GUILE_DEBUG_FREELIST=0
AC_ARG_ENABLE(debug-freelist,
  [  --enable-debug-freelist include garbage collector freelist debugging code],
  if test "$enable_debug_freelist" = y \
     || test "$enable_debug_freelist" = yes; then
    SCM_I_GSC_GUILE_DEBUG_FREELIST=1
  fi)

AC_ARG_ENABLE(debug-malloc,
  [  --enable-debug-malloc   include malloc debugging code],
  if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
    AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
      [Define this if you want to debug scm_must_malloc/realloc/free calls.])
  fi)

SCM_I_GSC_GUILE_DEBUG=0
AC_ARG_ENABLE(guile-debug,
  [AC_HELP_STRING([--enable-guile-debug],
                  [include internal debugging functions])],
  if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
    SCM_I_GSC_GUILE_DEBUG=1
  fi)

AC_ARG_ENABLE(arrays,
  [AC_HELP_STRING([--disable-arrays],[omit array and uniform array support])],
  ,
  enable_arrays=yes)

AC_ARG_ENABLE(posix,
  [  --disable-posix         omit posix interfaces],,
  enable_posix=yes)

AC_ARG_ENABLE(networking,
  [  --disable-networking    omit networking interfaces],,
  enable_networking=yes)

AC_ARG_ENABLE(regex,
  [  --disable-regex         omit regular expression interfaces],,
  enable_regex=yes)

AC_ARG_ENABLE(htmldoc,
  [  --enable-htmldoc        build HTML documentation as well as Info],
  [if test "$enable_htmldoc" = "" || test "$enable_htmldoc" = y || test "$enable_htmldoc" = yes; then
     htmldoc_enabled=yes
     AC_PATH_PROG(TEXI2HTML, texi2html, not found)
     if test "$TEXI2HTML" = "not found"; then
       echo
       echo Building HTML documentation requires the \`texi2html\' program,
       echo which appears not to be present on your machine.
       echo
       echo \`texi2html\' is available from
       echo 'http://www.mathematik.uni-kl.de/~obachman/Texi2html/.'
       echo
       echo In the meantime, to build the guile-doc distribution
       echo without HTML enabled, please rerun \`./configure\' without
       echo the \`--enable-htmldoc\' option.
       exit -1
     fi
   fi])

AM_CONDITIONAL(HTMLDOC, test x$htmldoc_enabled = xyes)

AC_ARG_ENABLE([deprecated],
  AC_HELP_STRING([--disable-deprecated],[omit deprecated features]))

if test "$enable_deprecated" = no; then
  SCM_I_GSC_ENABLE_DEPRECATED=0
else
  if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
    warn_default=summary
  elif test "$enable_deprecated" = shutup; then
    warn_default=no
  else
    warn_default=$enable_deprecated
  fi
  SCM_I_GSC_ENABLE_DEPRECATED=1
  AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
  [Define this to control the default warning level for deprecated features.])
fi

AC_ARG_ENABLE(elisp,
  [  --disable-elisp         omit Emacs Lisp support],,
  enable_elisp=yes)

#--------------------------------------------------------------------

dnl Check for dynamic linking

use_modules=yes
AC_ARG_WITH(modules,
[  --with-modules[=FILES]  Add support for dynamic modules],
use_modules="$withval")
test -z "$use_modules" && use_modules=yes
DLPREOPEN=
if test "$use_modules" != no; then
  if test "$use_modules" = yes; then
    DLPREOPEN="-dlpreopen force"
  else
    DLPREOPEN="-export-dynamic"
    for module in $use_modules; do
      DLPREOPEN="$DLPREOPEN -dlopen $module"
    done
  fi
fi

dnl files which are destined for separate modules.

if test "$use_modules" != no; then
   AC_LIBOBJ([dynl])
fi

SCM_I_GSC_HAVE_ARRAYS=0
if test "$enable_arrays" = yes; then
   AC_LIBOBJ([ramap])
   AC_LIBOBJ([unif])
   SCM_I_GSC_HAVE_ARRAYS=1
fi

if test "$enable_posix" = yes; then
   AC_LIBOBJ([filesys])
   AC_LIBOBJ([posix])
   AC_DEFINE(HAVE_POSIX, 1,
     [Define this if you want support for POSIX system calls in Guile.])
fi

if test "$enable_networking" = yes; then
   AC_LIBOBJ([net_db])
   AC_LIBOBJ([socket])
   AC_DEFINE(HAVE_NETWORKING, 1,
     [Define this if you want support for networking in Guile.])
fi

if test "$enable_debug_malloc" = yes; then
   AC_LIBOBJ([debug-malloc])
fi

if test "$enable_elisp" = yes; then
  SCM_I_GSC_ENABLE_ELISP=1
else
  SCM_I_GSC_ENABLE_ELISP=0
fi

AC_C_CONST

AC_C_INLINE
if test "$ac_cv_c_inline" != no; then
  SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
else
  SCM_I_GSC_C_INLINE=NULL
fi

AC_C_BIGENDIAN

AC_CHECK_SIZEOF(char)
AC_CHECK_SIZEOF(unsigned char)
AC_CHECK_SIZEOF(short)
AC_CHECK_SIZEOF(unsigned short)
AC_CHECK_SIZEOF(int)
AC_CHECK_SIZEOF(unsigned int)
AC_CHECK_SIZEOF(long)
AC_CHECK_SIZEOF(unsigned long)
AC_CHECK_SIZEOF(size_t)
AC_CHECK_SIZEOF(long long)
AC_CHECK_SIZEOF(unsigned long long)
AC_CHECK_SIZEOF(void *)
AC_CHECK_SIZEOF(intptr_t)
AC_CHECK_SIZEOF(uintptr_t)
AC_CHECK_SIZEOF(ptrdiff_t)

if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
  AC_MSG_ERROR(sizes of long and void* are not identical)
fi

if test "$ac_cv_sizeof_ptrdiff_t" -eq 0; then
  SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
else
  SCM_I_GSC_T_PTRDIFF='"long"'
fi
AC_SUBST([SCM_I_GSC_T_PTRDIFF])

AC_CHECK_HEADERS([stdint.h])
AC_CHECK_HEADERS([inttypes.h])

SCM_I_GSC_NEEDS_STDINT_H=0
SCM_I_GSC_NEEDS_INTTYPES_H=0

### intptr and uintptr (try not to use inttypes if we don't have to)
if test "$ac_cv_header_inttypes_h" = yes; then
  if test "$ac_cv_sizeof_intptr_t" -eq 0; then
    AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
#include <stdio.h>])
    if test "$ac_cv_sizeof_intptr_t" -ne 0; then
      SCM_I_GSC_NEEDS_INTTYPES_H=1
    fi
  fi
  if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
    AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
#include <stdio.h>])
    if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
      SCM_I_GSC_NEEDS_INTTYPES_H=1
    fi
  fi
fi

### See what's provided by stdint.h
if test "$ac_cv_header_stdint_h" = yes; then
   AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
   AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
   AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
   AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
   AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
   AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
   AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
   AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
fi

# so we don't get confused by the cache (wish there was a better way
# to check particular headers for the same type...)

unset ac_cv_type_int8_t
unset ac_cv_type_uint8_t
unset ac_cv_type_int16_t
unset ac_cv_type_uint16_t
unset ac_cv_type_int32_t
unset ac_cv_type_uint32_t
unset ac_cv_type_int64_t
unset ac_cv_type_uint64_t

### See what's provided by inttypes.h
if test "$ac_cv_header_inttypes_h" = yes; then
  AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
  AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
  AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
  AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
  AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
  AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
  AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
  AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
fi

# Try hard to find definitions for some required scm_t_*int* types.

### Required type scm_t_int8
if test "$ac_cv_sizeof_char" -eq 1; then
  SCM_I_GSC_T_INT8='"char"'
elif test "$scm_stdint_has_int8"; then
  SCM_I_GSC_T_INT8='"int8_t"'
  SCM_I_GSC_NEEDS_STDINT_H=1
elif test "$scm_inttypes_has_int8"; then
  SCM_I_GSC_T_INT8='"int8_t"'
  SCM_I_GSC_NEEDS_INTTYPES_H=1
else
  AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
fi
AC_SUBST([SCM_I_GSC_T_INT8])

### Required type scm_t_uint8
if test "$ac_cv_sizeof_unsigned_char" -eq 1; then
  SCM_I_GSC_T_UINT8='"unsigned char"'
elif test "$scm_stdint_has_uint8"; then
  SCM_I_GSC_T_UINT8='"uint8_t"'
  SCM_I_GSC_NEEDS_STDINT_H=1
elif test "$scm_inttypes_has_uint8"; then
  SCM_I_GSC_T_UINT8='"uint8_t"'
  SCM_I_GSC_NEEDS_INTTYPES_H=1
else
  AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
fi
AC_SUBST([SCM_I_GSC_T_UINT8])


### Required type scm_t_int16 (ANSI C says int or short might work)
if test "$ac_cv_sizeof_int" -eq 2; then
  SCM_I_GSC_T_INT16='"int"'
elif test "$ac_cv_sizeof_short" -eq 2; then
  SCM_I_GSC_T_INT16='"short"'
elif test "$scm_stdint_has_int16"; then
  SCM_I_GSC_T_INT16='"int16_t"'
  SCM_I_GSC_NEEDS_STDINT_H=1
elif test "$scm_inttypes_has_int16"; then
  SCM_I_GSC_T_INT16='"int16_t"'
  SCM_I_GSC_NEEDS_INTTYPES_H=1
else
  AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
fi
AC_SUBST([SCM_I_GSC_T_INT16])

### Required type scm_t_uint16 (ANSI C says int or short might work)
if test "$ac_cv_sizeof_unsigned_int" -eq 2; then
  SCM_I_GSC_T_UINT16='"unsigned int"'
elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
  SCM_I_GSC_T_UINT16='"unsigned short"'
elif test "$scm_stdint_has_uint16"; then
  SCM_I_GSC_T_UINT16='"uint16_t"'
  SCM_I_GSC_NEEDS_STDINT_H=1
elif test "$scm_inttypes_has_uint16"; then
  SCM_I_GSC_T_UINT16='"uint16_t"'
  SCM_I_GSC_NEEDS_INTTYPES_H=1
else
  AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
fi
AC_SUBST([SCM_I_GSC_T_UINT16])


### Required type scm_t_int32 (ANSI C says int, short, or long might work)
if test "$ac_cv_sizeof_int" -eq 4; then
  SCM_I_GSC_T_INT32='"int"'
elif test "$ac_cv_sizeof_long" -eq 4; then
  SCM_I_GSC_T_INT32='"long"'
elif test "$ac_cv_sizeof_short" -eq 4; then
  SCM_I_GSC_T_INT32='"short"'
elif test "$scm_stdint_has_int32"; then
  SCM_I_GSC_T_INT32='"int32_t"'
  SCM_I_GSC_NEEDS_STDINT_H=1
elif test "$scm_inttypes_has_int32"; then
  SCM_I_GSC_T_INT32='"int32_t"'
  SCM_I_GSC_NEEDS_INTTYPES_H=1
else
  AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
fi
AC_SUBST([SCM_I_GSC_T_INT32])

### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
if test "$ac_cv_sizeof_unsigned_int" -eq 4; then
  SCM_I_GSC_T_UINT32='"unsigned int"'
elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
  SCM_I_GSC_T_UINT32='"unsigned long"'
elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
  SCM_I_GSC_T_UINT32='"unsigned short"'
elif test "$scm_stdint_has_uint32"; then
  SCM_I_GSC_T_UINT32='"uint32_t"'
  SCM_I_GSC_NEEDS_STDINT_H=1
elif test "$scm_inttypes_has_uint32"; then
  SCM_I_GSC_T_UINT32='"uint32_t"'
  SCM_I_GSC_NEEDS_INTTYPES_H=1
else
  AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
fi
AC_SUBST([SCM_I_GSC_T_UINT32])

### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
### Also try long long if we have it.
SCM_I_GSC_T_INT64=0
if test "$ac_cv_sizeof_int" -eq 8; then
  SCM_I_GSC_T_INT64='"int"'
elif test "$ac_cv_sizeof_long" -eq 8; then
  SCM_I_GSC_T_INT64='"long"'
elif test "$ac_cv_sizeof_short" -eq 8; then
  SCM_I_GSC_T_INT64='"short"'
elif test "$ac_cv_sizeof_long_long" -eq 8; then
  SCM_I_GSC_T_INT64='"long long"'
elif test "$scm_stdint_has_int64"; then
  SCM_I_GSC_T_INT64='"int64_t"'
  SCM_I_GSC_NEEDS_STDINT_H=1
elif test "$scm_inttypes_has_int64"; then
  SCM_I_GSC_T_INT64='"int64_t"'
  SCM_I_GSC_NEEDS_INTTYPES_H=1
else
  AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
fi
AC_SUBST([SCM_I_GSC_T_INT64])

### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
### Also try long long if we have it.
SCM_I_GSC_T_UINT64=0
if test "$ac_cv_sizeof_unsigned_int" -eq 8; then
  SCM_I_GSC_T_UINT64='"unsigned int"'
elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
  SCM_I_GSC_T_UINT64='"unsigned long"'
elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
  SCM_I_GSC_T_UINT64='"unsigned short"'
elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
  SCM_I_GSC_T_UINT64='"unsigned long long"'
elif test "$scm_stdint_has_uint64"; then
  SCM_I_GSC_T_UINT64='"uint64_t"'
  SCM_I_GSC_NEEDS_STDINT_H=1
elif test "$scm_inttypes_has_uint64"; then
  SCM_I_GSC_T_UINT64='"uint64_t"'
  SCM_I_GSC_NEEDS_INTTYPES_H=1
else
  AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
fi
AC_SUBST([SCM_I_GSC_T_UINT64])


AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])

AC_HEADER_STDC
AC_HEADER_DIRENT
AC_HEADER_TIME
AC_HEADER_SYS_WAIT

AC_CHECK_HEADERS([io.h libc.h limits.h malloc.h memory.h string.h \
regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
direct.h])

GUILE_HEADER_LIBC_WITH_UNISTD

AC_TYPE_GETGROUPS
AC_TYPE_SIGNAL
AC_TYPE_MODE_T

AC_CHECK_LIB(m, main)
AC_CHECK_FUNCS(gethostbyname)
if test $ac_cv_func_gethostbyname = no; then
    AC_CHECK_LIB(nsl, gethostbyname)
fi

AC_CHECK_FUNCS(connect)
if test $ac_cv_func_connect = no; then
    AC_CHECK_LIB(socket, connect)
fi

dnl
dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
dnl
EXTRA_DEFS=""
if test "$MINGW32" = "yes" ; then
    AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
      [Define if you have the <winsock2.h> header file.])])
    AC_CHECK_LIB(ws2_32, main)
    AC_LIBOBJ([win32-uname])
    AC_LIBOBJ([win32-dirent])
    if test "$enable_networking" = yes ; then
      AC_LIBOBJ([win32-socket])
    fi
    if test "$enable_shared" = yes ; then
      EXTRA_DEFS="-DSCM_IMPORT"
      AC_DEFINE(USE_DLL_IMPORT, 1,
        [Define if you need additional CPP macros on Win32 platforms.])
    fi
    if test x"$enable_ltdl_install" = x"yes" ; then
      INCLTDL="-DLIBLTDL_DLL_IMPORT $INCLTDL"
    fi
fi
AC_SUBST(EXTRA_DEFS)

# FIXME: check to see if we still need these.
#AC_SUBST(INCLTDL)
#AC_SUBST(LIBLTDL)

AC_SUBST(DLPREOPEN)

AC_CHECK_HEADERS([assert.h])

AC_CHECK_FUNCS([ctermid ftime fchown getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex])

AC_CHECK_HEADERS(crypt.h sys/resource.h sys/file.h)
AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
AC_CHECK_LIB(crypt, crypt)

dnl GMP tests
AC_CHECK_LIB([gmp], [__gmpz_init], ,
  [AC_MSG_ERROR([GNU MP not found, see http://swox.com/gmp])])

# mpz_import is a macro so we need to include <gmp.h>
AC_TRY_LINK([#include <gmp.h>],
            [mpz_import (0, 0, 0, 0, 0, 0, 0);] , ,
  [AC_MSG_ERROR([At least GNU MP 4.1 is required, see http://swox.com/gmp])])

### Some systems don't declare some functions.  On such systems, we
### need to at least provide our own K&R-style declarations.

### GUILE_FUNC_DECLARED(function, headerfile)

### Check for a declaration of FUNCTION in HEADERFILE; if it is
### not there, #define MISSING_FUNCTION_DECL.
AC_DEFUN(GUILE_FUNC_DECLARED, [
  AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
    AC_EGREP_HEADER($1, $2,
		    guile_cv_func_$1_declared=yes,
		    guile_cv_func_$1_declared=no))
  if test [x$guile_cv_func_]$1[_declared] = xno; then
    AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
      [Define if the operating system supplies $1 without declaring it.])
  fi
])

GUILE_FUNC_DECLARED(strptime, time.h)
GUILE_FUNC_DECLARED(sleep, unistd.h)
GUILE_FUNC_DECLARED(usleep, unistd.h)

### On some systems usleep has no return value.  If it does have one,
### we'd like to return it; otherwise, we'll fake it.
AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
  [AC_EGREP_HEADER(changequote(<, >)<void[ 	]+usleep>changequote([, ]),
                   unistd.h,
		   [guile_cv_func_usleep_return_type=void],
		   [guile_cv_func_usleep_return_type=int])])
case "$guile_cv_func_usleep_return_type" in
  "void" )
    AC_DEFINE(USLEEP_RETURNS_VOID, 1,
      [Define if the system headers declare usleep to return void.])
  ;;
esac

AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
if test -n "$have_sys_un_h" ; then
  AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
    [Define if the system supports Unix-domain (file-domain) sockets.])
fi

AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)

AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
               setnetent    getnetent    endnetent    dnl
               setprotoent  getprotoent  endprotoent  dnl
               setservent   getservent   endservent   dnl
               getnetbyaddr getnetbyname dnl
	       inet_lnaof inet_makeaddr inet_netof hstrerror dnl
	       inet_pton inet_ntop)

AC_MSG_CHECKING(for __libc_stack_end)
AC_TRY_LINK([extern char *__libc_stack_end;],
            [char *p = __libc_stack_end;],
            have_libc_stack_end=yes,
            have_libc_stack_end=no)
AC_MSG_RESULT($have_libc_stack_end)

if test $have_libc_stack_end = yes; then
  AC_DEFINE(HAVE_LIBC_STACK_END, 1,
           [Define if you have the __libc_stack_end variable.])
fi

dnl Some systems do not declare this.  Some systems do declare it, as a
dnl macro.  With cygwin it may be in a DLL.

AC_MSG_CHECKING(whether netdb.h declares h_errno)
AC_CACHE_VAL(guile_cv_have_h_errno,
[AC_TRY_COMPILE([#include <netdb.h>],
[int a = h_errno;],
guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
AC_MSG_RESULT($guile_cv_have_h_errno)
if test $guile_cv_have_h_errno = yes; then
  AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
fi

AC_MSG_CHECKING(whether uint32_t is defined)
AC_CACHE_VAL(guile_cv_have_uint32_t,
  [AC_TRY_COMPILE([#include <sys/types.h>
		   #if HAVE_STDINT_H
		   #include <stdint.h>
                   #endif
		   #ifndef __MINGW32__
	           #include <netdb.h>
		   #endif],
		  [uint32_t a;],
		  guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
AC_MSG_RESULT($guile_cv_have_uint32_t)
if test $guile_cv_have_uint32_t = yes; then
  AC_DEFINE(HAVE_UINT32_T, 1,
    [Define if uint32_t typedef is defined when netdb.h is include.])
fi

AC_MSG_CHECKING(for working IPv6 support)
AC_CACHE_VAL(guile_cv_have_ipv6,
[AC_TRY_COMPILE([
#ifdef HAVE_SYS_TYPES_H
#include <sys/types.h>
#endif
#include <netinet/in.h>
#include <sys/socket.h>],
[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
AC_MSG_RESULT($guile_cv_have_ipv6)
if test $guile_cv_have_ipv6 = yes; then
  AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
fi

# included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
[AC_TRY_COMPILE([
#ifdef HAVE_SYS_TYPES_H
#include <sys/types.h>
#endif
#include <netinet/in.h>],
[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
if test $guile_cv_have_sin6_scope_id = yes; then
  AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
    [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
fi

AC_MSG_CHECKING(whether localtime caches TZ)
AC_CACHE_VAL(guile_cv_localtime_cache,
[if test x$ac_cv_func_tzset = xyes; then
AC_TRY_RUN([#include <time.h>
#if STDC_HEADERS
# include <stdlib.h>
#endif
extern char **environ;
unset_TZ ()
{
  char **from, **to;
  for (to = from = environ; (*to = *from); from++)
    if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
      to++;
}
char TZ_GMT0[] = "TZ=GMT0";
char TZ_PST8[] = "TZ=PST8";
main()
{
  time_t now = time ((time_t *) 0);
  int hour_GMT0, hour_unset;
  if (putenv (TZ_GMT0) != 0)
    exit (1);
  hour_GMT0 = localtime (&now)->tm_hour;
  unset_TZ ();
  hour_unset = localtime (&now)->tm_hour;
  if (putenv (TZ_PST8) != 0)
    exit (1);
  if (localtime (&now)->tm_hour == hour_GMT0)
    exit (1);
  unset_TZ ();
  if (localtime (&now)->tm_hour != hour_unset)
    exit (1);
  exit (0);
}], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
[# If we have tzset, assume the worst when cross-compiling.
guile_cv_localtime_cache=yes])
else
        # If we lack tzset, report that localtime does not cache TZ,
        # since we can't invalidate the cache if we don't have tzset.
        guile_cv_localtime_cache=no
fi])dnl
AC_MSG_RESULT($guile_cv_localtime_cache)
if test $guile_cv_localtime_cache = yes; then
  AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
fi

dnl Test whether system calls are restartable by default on the
dnl current system.  If they are not, we put a loop around every system
dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
dnl change from the default behaviour.  On the other hand, if signals
dnl are restartable then the loop is not installed and when libguile
dnl initialises it also resets the behaviour of each signal to cause a
dnl restart (in case a different runtime had a different default
dnl behaviour for some reason: e.g., different versions of linux seem
dnl to behave differently.)

AC_SYS_RESTARTABLE_SYSCALLS

if test "$enable_regex" = yes; then
   if test "$ac_cv_header_regex_h" = yes ||
      test "$ac_cv_header_rxposix_h" = yes ||
      test "$ac_cv_header_rx_rxposix_h" = yes; then
     GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
     [AC_CHECK_LIB(rx, main)
      GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
     [AC_CHECK_LIB(regex, main)
      GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
     )
     dnl The following should not be necessary, but for some reason
     dnl autoheader misses it if we don't include it!
     if test "$ac_cv_func_regcomp_norx" = yes ||
        test "$ac_cv_func_regcomp_regex" = yes ||
        test "$ac_cv_func_regcomp_rx" = yes; then
       AC_DEFINE(HAVE_REGCOMP, 1,
         [This is included as part of a workaround for a autoheader bug.])
     fi
   fi
fi

AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)

AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)

AC_CHECK_FUNCS(finite isinf isnan copysign)

# When testing for the presence of alloca, we need to add alloca.o
# explicitly to LIBOBJS to make sure that it is translated to
# `alloca.lo' for libtool later on.  This can and should be done more cleanly.
AC_FUNC_ALLOCA
if test "$ALLOCA" = "alloca.o"; then AC_LIBOBJ([alloca]); fi

AC_CHECK_MEMBERS([struct stat.st_rdev])
AC_CHECK_MEMBERS([struct stat.st_blksize])

AC_STRUCT_ST_BLOCKS

AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
  [AC_TRY_CPP([#include <sys/stat.h>
               #ifndef S_ISLNK
               #error no S_ISLNK
               #endif],
               ac_cv_macro_S_ISLNK=yes,
               ac_cv_macro_S_ISLNK=no)])
if test $ac_cv_macro_S_ISLNK = yes; then
  AC_DEFINE(HAVE_S_ISLNK, 1,
    [Define this if your system defines S_ISLNK in sys/stat.h.])
fi

AC_STRUCT_TIMEZONE
GUILE_STRUCT_UTIMBUF

#--------------------------------------------------------------------
#
# Which way does the stack grow?
#
#--------------------------------------------------------------------

SCM_I_GSC_STACK_GROWS_UP=0
AC_TRY_RUN(aux (l) unsigned long l;
	     { int x; exit (l >= ((unsigned long)&x)); }
	   main () { int q; aux((unsigned long)&q); },
           SCM_I_GSC_STACK_GROWS_UP=1
	   [],
           [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])

AH_TEMPLATE([SCM_SINGLES],
  [Define this if floats are the same size as longs.])

AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
    [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
		[guile_cv_type_float_fits_long=yes],
		[guile_cv_type_float_fits_long=no],
		[guile_cv_type_float_fits_long=guess-yes])])
case $guile_cv_type_float_fits_long in
  "yes" )
    AC_DEFINE(SCM_SINGLES)
  ;;
  "guess-yes" )
    AC_DEFINE(SCM_SINGLES)
    AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
    AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
  ;;
esac


AC_MSG_CHECKING(for struct linger)
AC_CACHE_VAL(scm_cv_struct_linger,
	AC_TRY_COMPILE([
#include <sys/types.h>
#include <sys/socket.h>],
			[struct linger lgr;  lgr.l_linger = 100],
			scm_cv_struct_linger="yes",
			scm_cv_struct_linger="no"))
AC_MSG_RESULT($scm_cv_struct_linger)
if test $scm_cv_struct_linger = yes; then
	AC_DEFINE(HAVE_STRUCT_LINGER, 1,
          [Define this if your system defines struct linger, for use with the
           getsockopt and setsockopt system calls.])
fi


AC_MSG_CHECKING(for struct timespec)
AC_CACHE_VAL(scm_cv_struct_timespec,
	AC_TRY_COMPILE([
#include <time.h>],
			[struct timespec t;  t.tv_nsec = 100],
			scm_cv_struct_timespec="yes",
			scm_cv_struct_timespec="no"))
AC_MSG_RESULT($scm_cv_struct_timespec)
if test $scm_cv_struct_timespec = yes; then
  AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
    [Define this if your system defines struct timespec via <time.h>.])
fi

#--------------------------------------------------------------------
#
# Flags for thread support
#
#--------------------------------------------------------------------

SCM_I_GSC_USE_PTHREAD_THREADS=0
SCM_I_GSC_USE_NULL_THREADS=0
SCM_I_GSC_USE_COOP_THREADS=0
AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
AC_SUBST([SCM_I_GSC_USE_COOP_THREADS])

### What thread package has the user asked for?
AC_ARG_WITH(threads, [  --with-threads          thread interface],
            , with_threads=yes)

case "$with_threads" in
  "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
    AC_CHECK_LIB(pthread, main,
      LIBS="-lpthread $LIBS"
      SCM_I_GSC_USE_PTHREAD_THREADS=1
      with_threads="pthreads",
      with_threads="null")
      
    if test $GCC = yes; then
    AC_DEFINE(_THREAD_SAFE, 1,
      [Use thread safe versions of GNU Libc functions.])
    fi
    
    AC_MSG_CHECKING(if pthread_mutexattr_settype is declared)
    AC_CACHE_VAL(guile_cv_mutexattr_settype_declared,
      [AC_TRY_COMPILE([#include <pthread.h>],
    	  [int pthread_mutexattr_settype (int, int);],
    	  guile_cv_mutexattr_settype_declared=no,
    	  guile_cv_mutexattr_settype_declared=yes)])
    AC_MSG_RESULT($guile_cv_mutexattr_settype_declared)
    if test $guile_cv_mutexattr_settype_declared = yes; then
      AC_DEFINE(SCM_MUTEXATTR_SETTYPE_DECLARED, 1,
    	  [Define if pthread.h declares pthread_mutexattr_settype.])
    fi
    
    AC_MSG_CHECKING(how to get a fast mutex)
    AC_CACHE_VAL(guile_cv_have_mutex_fast,
      [AC_TRY_COMPILE([#include <pthread.h>],
    	  [int a = PTHREAD_MUTEX_ADAPTIVE_NP;],
    	  guile_cv_have_mutex_fast=PTHREAD_MUTEX_ADAPTIVE_NP,
    	  guile_cv_have_mutex_fast=none)])
    AC_MSG_RESULT($guile_cv_have_mutex_fast)
    if test ! $guile_cv_have_mutex_fast = none; then
      AC_DEFINE_UNQUOTED(SCM_MUTEX_FAST, $guile_cv_have_mutex_fast,
    	  [The mutex kind enum for fast mutexes.])
    fi
    
    AC_MSG_CHECKING(how to get a recursive mutex)
    AC_CACHE_VAL(guile_cv_have_mutex_recursive,
      [AC_TRY_COMPILE([#include <pthread.h>],
        [int a = PTHREAD_MUTEX_RECURSIVE_NP;],
         guile_cv_have_mutex_recursive=PTHREAD_MUTEX_RECURSIVE_NP)
      if test -z "$guile_cv_have_mutex_recursive"; then
    	  AC_TRY_COMPILE([#include <pthread.h>],
    	    [int a = PTHREAD_MUTEX_RECURSIVE;],
    	    guile_cv_have_mutex_recursive=PTHREAD_MUTEX_RECURSIVE,
    	    guile_cv_have_mutex_recursive=none)
    	fi])
    AC_MSG_RESULT($guile_cv_have_mutex_recursive)
    if test ! $guile_cv_have_mutex_recursive = none; then
      AC_DEFINE_UNQUOTED(SCM_MUTEX_RECURSIVE, $guile_cv_have_mutex_recursive,
    	 [The mutex kind enum for recursive mutexes.])
    fi
  ;;
esac

case "$with_threads" in
  "pthreads")
  ;;
  "no" | "null")
    SCM_I_GSC_USE_NULL_THREADS=1
    with_threads="null-threads"
  ;;
  * )
    AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
  ;;
esac

AC_MSG_CHECKING(what kind of threads to support)
AC_MSG_RESULT($with_threads)

## Cross building	
if test "$cross_compiling" = "yes"; then
  AC_MSG_CHECKING(cc for build)
  ## /usr/bin/cc still uses wrong assembler
  ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
  CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
else
  CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
fi   
AC_ARG_WITH(cc-for-build,
  [  --with-cc-for-build=CC  native C compiler, to be used during build])
test -n "$with_cc_for_build" && CC_FOR_BUILD="$with_cc_for_build"
     
## AC_MSG_CHECKING("if we are cross compiling")
## AC_MSG_RESULT($cross_compiling)
if test "$cross_compiling" = "yes"; then
   AC_MSG_RESULT($CC_FOR_BUILD)
fi

## No need as yet to be more elaborate
CCLD_FOR_BUILD="$CC_FOR_BUILD"

AC_SUBST(cross_compiling)
AC_SUBST(CC_FOR_BUILD)
AC_SUBST(CCLD_FOR_BUILD)
	
## libtool erroneously calls CC_FOR_BUILD HOST_CC;
## --HOST is the platform that PACKAGE is compiled for.
HOST_CC="$CC_FOR_BUILD"
AC_SUBST(HOST_CC)

if test "$cross_compiling" = "yes"; then
  AC_MSG_CHECKING(guile for build)
  GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
else
  GUILE_FOR_BUILD='$(preinstguile)'
fi   
AC_ARG_WITH(guile-for-build,
  [  --with-guile-for-build=guile  native guile executable, to be used during build])
test -n "$with_guile_for_build" && GUILE_FOR_BUILD="$with_guile_for_build"

## AC_MSG_CHECKING("if we are cross compiling")
## AC_MSG_RESULT($cross_compiling)
if test "$cross_compiling" = "yes"; then
   AC_MSG_RESULT($GUILE_FOR_BUILD)
fi
AC_SUBST(GUILE_FOR_BUILD)
  			
# Do this here so we don't screw up any of the tests above that might
# not be "warning free"

if test "${GUILE_ERROR_ON_WARNING}" = yes
then
  CFLAGS="${CFLAGS} -Werror"
  enable_compile_warnings=no
fi

## If we're using GCC, ask for aggressive warnings.
case "$GCC" in
  yes )
    ## We had -Wstrict-prototypes in here for a bit, but Guile does too
    ## much stuff with generic function pointers for that to really be
    ## less than exasperating.
    ## -Wpointer-arith was here too, but something changed in gcc/glibc
    ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
    CFLAGS="$CFLAGS -Wall -Wmissing-prototypes" ;;
esac

## NOTE the code below sets LIBOBJS directly and so is now forbidden
## -- I'm disabling it for now in the hopes that the newer autoconf
## will DTRT -- if not, we need to fix up the sed command to match the
## others...
##
## Remove fileblocks.o from the object list.  This file gets added by
## the Autoconf macro AC_STRUCT_ST_BLOCKS.  But there is no need.
#LIBOBJS="`echo ${LIBOBJS} | sed 's/fileblocks\.o//g'`"

## If we're creating a shared library (using libtool!), then we'll
## need to generate a list of .lo files corresponding to the .o files
## given in LIBOBJS.  We'll call it LIBLOBJS.
LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"

## We also need to create corresponding .doc and .x files
EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"

AC_SUBST(GUILE_MAJOR_VERSION)
AC_SUBST(GUILE_MINOR_VERSION)
AC_SUBST(GUILE_MICRO_VERSION)
AC_SUBST(GUILE_EFFECTIVE_VERSION)
AC_SUBST(GUILE_VERSION)

#######################################################################
# library versioning

AC_SUBST(LIBQTHREADS_INTERFACE_CURRENT)
AC_SUBST(LIBQTHREADS_INTERFACE_REVISION)
AC_SUBST(LIBQTHREADS_INTERFACE_AGE)
AC_SUBST(LIBQTHREADS_INTERFACE)

AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
AC_SUBST(LIBGUILE_INTERFACE_REVISION)
AC_SUBST(LIBGUILE_INTERFACE_AGE)
AC_SUBST(LIBGUILE_INTERFACE)

AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)

AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)

AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)

#######################################################################

dnl Tell guile-config what flags guile users should link against.
GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
AC_SUBST(GUILE_LIBS)

AC_SUBST(AWK)
AC_SUBST(LIBLOBJS)
AC_SUBST(EXTRA_DOT_DOC_FILES)
AC_SUBST(EXTRA_DOT_X_FILES)

dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
top_builddir_absolute=`pwd`
AC_SUBST(top_builddir_absolute)
top_srcdir_absolute=`(cd $srcdir && pwd)`
AC_SUBST(top_srcdir_absolute)

# Additional SCM_I_GSC definitions are above.
AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
AC_SUBST([SCM_I_GSC_GUILE_DEBUG_FREELIST])
AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
AC_SUBST([SCM_I_GSC_ENABLE_ELISP])
AC_SUBST([SCM_I_GSC_HAVE_ARRAYS])
AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
AC_SUBST([SCM_I_GSC_C_INLINE])
AC_CONFIG_FILES([libguile/gen-scmconfig.h])

AC_CONFIG_FILES([
  Makefile
  am/Makefile
  benchmark-suite/Makefile
  doc/Makefile
  doc/goops/Makefile
  doc/r5rs/Makefile
  doc/ref/Makefile
  doc/tutorial/Makefile
  examples/Makefile
  examples/box-dynamic-module/Makefile
  examples/box-dynamic/Makefile
  examples/box-module/Makefile
  examples/box/Makefile
  examples/modules/Makefile
  examples/safe/Makefile
  examples/scripts/Makefile
  guile-config/Makefile
  ice-9/Makefile
  ice-9/debugger/Makefile
  ice-9/debugger/breakpoints/Makefile
  lang/Makefile
  lang/elisp/Makefile
  lang/elisp/internals/Makefile
  lang/elisp/primitives/Makefile
  libguile-ltdl/Makefile
  libguile-ltdl/upstream/Makefile
  libguile/Makefile
  oop/Makefile
  oop/goops/Makefile
  scripts/Makefile
  srfi/Makefile
  test-suite/Makefile
  test-suite/standalone/Makefile
])

AC_CONFIG_FILES([check-guile], [chmod +x check-guile])
AC_CONFIG_FILES([benchmark-guile], [chmod +x benchmark-guile])
AC_CONFIG_FILES([guile-tools], [chmod +x guile-tools])
AC_CONFIG_FILES([pre-inst-guile], [chmod +x pre-inst-guile])
AC_CONFIG_FILES([pre-inst-guile-env], [chmod +x pre-inst-guile-env])
AC_CONFIG_FILES([libguile/guile-snarf],
                [chmod +x libguile/guile-snarf])
AC_CONFIG_FILES([libguile/guile-doc-snarf],
                [chmod +x libguile/guile-doc-snarf])
AC_CONFIG_FILES([libguile/guile-func-name-check],
                [chmod +x libguile/guile-func-name-check])
AC_CONFIG_FILES([libguile/guile-snarf-docs],
                [chmod +x libguile/guile-snarf-docs])

AC_OUTPUT

dnl Local Variables:
dnl comment-start: "dnl "
dnl comment-end: ""
dnl comment-start-skip: "\\bdnl\\b\\s *"
dnl End: