[bpt/guile.git] / m4 / iconv.m4

# iconv.m4 serial 18 (gettext-0.18.2)
dnl Copyright (C) 2000-2002, 2007-2014 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

dnl From Bruno Haible.

AC_DEFUN([AM_ICONV_LINKFLAGS_BODY],
[
  dnl Prerequisites of AC_LIB_LINKFLAGS_BODY.
  AC_REQUIRE([AC_LIB_PREPARE_PREFIX])
  AC_REQUIRE([AC_LIB_RPATH])

  dnl Search for libiconv and define LIBICONV, LTLIBICONV and INCICONV
  dnl accordingly.
  AC_LIB_LINKFLAGS_BODY([iconv])
])

AC_DEFUN([AM_ICONV_LINK],
[
  dnl Some systems have iconv in libc, some have it in libiconv (OSF/1 and
  dnl those with the standalone portable GNU libiconv installed).
  AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles

  dnl Search for libiconv and define LIBICONV, LTLIBICONV and INCICONV
  dnl accordingly.
  AC_REQUIRE([AM_ICONV_LINKFLAGS_BODY])

  dnl Add $INCICONV to CPPFLAGS before performing the following checks,
  dnl because if the user has installed libiconv and not disabled its use
  dnl via --without-libiconv-prefix, he wants to use it. The first
  dnl AC_LINK_IFELSE will then fail, the second AC_LINK_IFELSE will succeed.
  am_save_CPPFLAGS="$CPPFLAGS"
  AC_LIB_APPENDTOVAR([CPPFLAGS], [$INCICONV])

  AC_CACHE_CHECK([for iconv], [am_cv_func_iconv], [
    am_cv_func_iconv="no, consider installing GNU libiconv"
    am_cv_lib_iconv=no
    AC_LINK_IFELSE(
      [AC_LANG_PROGRAM(
         [[
#include <stdlib.h>
#include <iconv.h>
         ]],
         [[iconv_t cd = iconv_open("","");
           iconv(cd,NULL,NULL,NULL,NULL);
           iconv_close(cd);]])],
      [am_cv_func_iconv=yes])
    if test "$am_cv_func_iconv" != yes; then
      am_save_LIBS="$LIBS"
      LIBS="$LIBS $LIBICONV"
      AC_LINK_IFELSE(
        [AC_LANG_PROGRAM(
           [[
#include <stdlib.h>
#include <iconv.h>
           ]],
           [[iconv_t cd = iconv_open("","");
             iconv(cd,NULL,NULL,NULL,NULL);
             iconv_close(cd);]])],
        [am_cv_lib_iconv=yes]
        [am_cv_func_iconv=yes])
      LIBS="$am_save_LIBS"
    fi
  ])
  if test "$am_cv_func_iconv" = yes; then
    AC_CACHE_CHECK([for working iconv], [am_cv_func_iconv_works], [
      dnl This tests against bugs in AIX 5.1, AIX 6.1..7.1, HP-UX 11.11,
      dnl Solaris 10.
      am_save_LIBS="$LIBS"
      if test $am_cv_lib_iconv = yes; then
        LIBS="$LIBS $LIBICONV"
      fi
      AC_RUN_IFELSE(
        [AC_LANG_SOURCE([[
#include <iconv.h>
#include <string.h>
int main ()
{
  int result = 0;
  /* Test against AIX 5.1 bug: Failures are not distinguishable from successful
     returns.  */
  {
    iconv_t cd_utf8_to_88591 = iconv_open ("ISO8859-1", "UTF-8");
    if (cd_utf8_to_88591 != (iconv_t)(-1))
      {
        static const char input[] = "\342\202\254"; /* EURO SIGN */
        char buf[10];
        const char *inptr = input;
        size_t inbytesleft = strlen (input);
        char *outptr = buf;
        size_t outbytesleft = sizeof (buf);
        size_t res = iconv (cd_utf8_to_88591,
                            (char **) &inptr, &inbytesleft,
                            &outptr, &outbytesleft);
        if (res == 0)
          result |= 1;
        iconv_close (cd_utf8_to_88591);
      }
  }
  /* Test against Solaris 10 bug: Failures are not distinguishable from
     successful returns.  */
  {
    iconv_t cd_ascii_to_88591 = iconv_open ("ISO8859-1", "646");
    if (cd_ascii_to_88591 != (iconv_t)(-1))
      {
        static const char input[] = "\263";
        char buf[10];
        const char *inptr = input;
        size_t inbytesleft = strlen (input);
        char *outptr = buf;
        size_t outbytesleft = sizeof (buf);
        size_t res = iconv (cd_ascii_to_88591,
                            (char **) &inptr, &inbytesleft,
                            &outptr, &outbytesleft);
        if (res == 0)
          result |= 2;
        iconv_close (cd_ascii_to_88591);
      }
  }
  /* Test against AIX 6.1..7.1 bug: Buffer overrun.  */
  {
    iconv_t cd_88591_to_utf8 = iconv_open ("UTF-8", "ISO-8859-1");
    if (cd_88591_to_utf8 != (iconv_t)(-1))
      {
        static const char input[] = "\304";
        static char buf[2] = { (char)0xDE, (char)0xAD };
        const char *inptr = input;
        size_t inbytesleft = 1;
        char *outptr = buf;
        size_t outbytesleft = 1;
        size_t res = iconv (cd_88591_to_utf8,
                            (char **) &inptr, &inbytesleft,
                            &outptr, &outbytesleft);
        if (res != (size_t)(-1) || outptr - buf > 1 || buf[1] != (char)0xAD)
          result |= 4;
        iconv_close (cd_88591_to_utf8);
      }
  }
#if 0 /* This bug could be worked around by the caller.  */
  /* Test against HP-UX 11.11 bug: Positive return value instead of 0.  */
  {
    iconv_t cd_88591_to_utf8 = iconv_open ("utf8", "iso88591");
    if (cd_88591_to_utf8 != (iconv_t)(-1))
      {
        static const char input[] = "\304rger mit b\366sen B\374bchen ohne Augenma\337";
        char buf[50];
        const char *inptr = input;
        size_t inbytesleft = strlen (input);
        char *outptr = buf;
        size_t outbytesleft = sizeof (buf);
        size_t res = iconv (cd_88591_to_utf8,
                            (char **) &inptr, &inbytesleft,
                            &outptr, &outbytesleft);
        if ((int)res > 0)
          result |= 8;
        iconv_close (cd_88591_to_utf8);
      }
  }
#endif
  /* Test against HP-UX 11.11 bug: No converter from EUC-JP to UTF-8 is
     provided.  */
  if (/* Try standardized names.  */
      iconv_open ("UTF-8", "EUC-JP") == (iconv_t)(-1)
      /* Try IRIX, OSF/1 names.  */
      && iconv_open ("UTF-8", "eucJP") == (iconv_t)(-1)
      /* Try AIX names.  */
      && iconv_open ("UTF-8", "IBM-eucJP") == (iconv_t)(-1)
      /* Try HP-UX names.  */
      && iconv_open ("utf8", "eucJP") == (iconv_t)(-1))
    result |= 16;
  return result;
}]])],
        [am_cv_func_iconv_works=yes],
        [am_cv_func_iconv_works=no],
        [
changequote(,)dnl
         case "$host_os" in
           aix* | hpux*) am_cv_func_iconv_works="guessing no" ;;
           *)            am_cv_func_iconv_works="guessing yes" ;;
         esac
changequote([,])dnl
        ])
      LIBS="$am_save_LIBS"
    ])
    case "$am_cv_func_iconv_works" in
      *no) am_func_iconv=no am_cv_lib_iconv=no ;;
      *)   am_func_iconv=yes ;;
    esac
  else
    am_func_iconv=no am_cv_lib_iconv=no
  fi
  if test "$am_func_iconv" = yes; then
    AC_DEFINE([HAVE_ICONV], [1],
      [Define if you have the iconv() function and it works.])
  fi
  if test "$am_cv_lib_iconv" = yes; then
    AC_MSG_CHECKING([how to link with libiconv])
    AC_MSG_RESULT([$LIBICONV])
  else
    dnl If $LIBICONV didn't lead to a usable library, we don't need $INCICONV
    dnl either.
    CPPFLAGS="$am_save_CPPFLAGS"
    LIBICONV=
    LTLIBICONV=
  fi
  AC_SUBST([LIBICONV])
  AC_SUBST([LTLIBICONV])
])

dnl Define AM_ICONV using AC_DEFUN_ONCE for Autoconf >= 2.64, in order to
dnl avoid warnings like
dnl "warning: AC_REQUIRE: `AM_ICONV' was expanded before it was required".
dnl This is tricky because of the way 'aclocal' is implemented:
dnl - It requires defining an auxiliary macro whose name ends in AC_DEFUN.
dnl   Otherwise aclocal's initial scan pass would miss the macro definition.
dnl - It requires a line break inside the AC_DEFUN_ONCE and AC_DEFUN expansions.
dnl   Otherwise aclocal would emit many "Use of uninitialized value $1"
dnl   warnings.
m4_define([gl_iconv_AC_DEFUN],
  m4_version_prereq([2.64],
    [[AC_DEFUN_ONCE(
        [$1], [$2])]],
    [m4_ifdef([gl_00GNULIB],
       [[AC_DEFUN_ONCE(
           [$1], [$2])]],
       [[AC_DEFUN(
           [$1], [$2])]])]))
gl_iconv_AC_DEFUN([AM_ICONV],
[
  AM_ICONV_LINK
  if test "$am_cv_func_iconv" = yes; then
    AC_MSG_CHECKING([for iconv declaration])
    AC_CACHE_VAL([am_cv_proto_iconv], [
      AC_COMPILE_IFELSE(
        [AC_LANG_PROGRAM(
           [[
#include <stdlib.h>
#include <iconv.h>
extern
#ifdef __cplusplus
"C"
#endif
#if defined(__STDC__) || defined(_MSC_VER) || defined(__cplusplus)
size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
#else
size_t iconv();
#endif
           ]],
           [[]])],
        [am_cv_proto_iconv_arg1=""],
        [am_cv_proto_iconv_arg1="const"])
      am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"])
    am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'`
    AC_MSG_RESULT([
         $am_cv_proto_iconv])
    AC_DEFINE_UNQUOTED([ICONV_CONST], [$am_cv_proto_iconv_arg1],
      [Define as const if the declaration of iconv() needs const.])
    dnl Also substitute ICONV_CONST in the gnulib generated <iconv.h>.
    m4_ifdef([gl_ICONV_H_DEFAULTS],
      [AC_REQUIRE([gl_ICONV_H_DEFAULTS])
       if test -n "$am_cv_proto_iconv_arg1"; then
         ICONV_CONST="const"
       fi
      ])
  fi
])
Commit	Line	Data
35428fb6	1	# iconv.m4 serial 18 (gettext-0.18.2)
5e69ceb7	2	dnl Copyright (C) 2000-2002, 2007-2014 Free Software Foundation, Inc.
24d56127 LC	3	dnl This file is free software; the Free Software Foundation
	4	dnl gives unlimited permission to copy and/or distribute it,
	5	dnl with or without modifications, as long as this notice is preserved.
	6
	7	dnl From Bruno Haible.
	8
	9	AC_DEFUN([AM_ICONV_LINKFLAGS_BODY],
	10	[
	11	dnl Prerequisites of AC_LIB_LINKFLAGS_BODY.
	12	AC_REQUIRE([AC_LIB_PREPARE_PREFIX])
	13	AC_REQUIRE([AC_LIB_RPATH])
	14
	15	dnl Search for libiconv and define LIBICONV, LTLIBICONV and INCICONV
	16	dnl accordingly.
	17	AC_LIB_LINKFLAGS_BODY([iconv])
	18	])
	19
	20	AC_DEFUN([AM_ICONV_LINK],
	21	[
	22	dnl Some systems have iconv in libc, some have it in libiconv (OSF/1 and
	23	dnl those with the standalone portable GNU libiconv installed).
	24	AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
	25
	26	dnl Search for libiconv and define LIBICONV, LTLIBICONV and INCICONV
	27	dnl accordingly.
	28	AC_REQUIRE([AM_ICONV_LINKFLAGS_BODY])
	29
	30	dnl Add $INCICONV to CPPFLAGS before performing the following checks,
	31	dnl because if the user has installed libiconv and not disabled its use
	32	dnl via --without-libiconv-prefix, he wants to use it. The first
9157d901	33	dnl AC_LINK_IFELSE will then fail, the second AC_LINK_IFELSE will succeed.
24d56127 LC	34	am_save_CPPFLAGS="$CPPFLAGS"
	35	AC_LIB_APPENDTOVAR([CPPFLAGS], [$INCICONV])
	36
	37	AC_CACHE_CHECK([for iconv], [am_cv_func_iconv], [
	38	am_cv_func_iconv="no, consider installing GNU libiconv"
	39	am_cv_lib_iconv=no
9157d901 LC	40	AC_LINK_IFELSE(
	41	[AC_LANG_PROGRAM(
	42	[[
	43	#include <stdlib.h>
	44	#include <iconv.h>
	45	]],
	46	[[iconv_t cd = iconv_open("","");
	47	iconv(cd,NULL,NULL,NULL,NULL);
	48	iconv_close(cd);]])],
24d56127 LC	49	[am_cv_func_iconv=yes])
	50	if test "$am_cv_func_iconv" != yes; then
	51	am_save_LIBS="$LIBS"
	52	LIBS="$LIBS $LIBICONV"
9157d901 LC	53	AC_LINK_IFELSE(
	54	[AC_LANG_PROGRAM(
	55	[[
	56	#include <stdlib.h>
	57	#include <iconv.h>
	58	]],
	59	[[iconv_t cd = iconv_open("","");
	60	iconv(cd,NULL,NULL,NULL,NULL);
	61	iconv_close(cd);]])],
24d56127 LC	62	[am_cv_lib_iconv=yes]
	63	[am_cv_func_iconv=yes])
	64	LIBS="$am_save_LIBS"
	65	fi
	66	])
	67	if test "$am_cv_func_iconv" = yes; then
	68	AC_CACHE_CHECK([for working iconv], [am_cv_func_iconv_works], [
9157d901 LC	69	dnl This tests against bugs in AIX 5.1, AIX 6.1..7.1, HP-UX 11.11,
9157d901 LC	70	dnl Solaris 10.
24d56127 LC	71	am_save_LIBS="$LIBS"
	72	if test $am_cv_lib_iconv = yes; then
	73	LIBS="$LIBS $LIBICONV"
	74	fi
9157d901 LC	75	AC_RUN_IFELSE(
9157d901 LC	76	[AC_LANG_SOURCE([[
24d56127 LC	77	#include <iconv.h>
	78	#include <string.h>
	79	int main ()
	80	{
0f00f2c3	81	int result = 0;
24d56127 LC	82	/* Test against AIX 5.1 bug: Failures are not distinguishable from successful
	83	returns. */
	84	{
	85	iconv_t cd_utf8_to_88591 = iconv_open ("ISO8859-1", "UTF-8");
	86	if (cd_utf8_to_88591 != (iconv_t)(-1))
	87	{
	88	static const char input[] = "\342\202\254"; /* EURO SIGN */
	89	char buf[10];
	90	const char *inptr = input;
	91	size_t inbytesleft = strlen (input);
	92	char *outptr = buf;
	93	size_t outbytesleft = sizeof (buf);
	94	size_t res = iconv (cd_utf8_to_88591,
	95	(char **) &inptr, &inbytesleft,
	96	&outptr, &outbytesleft);
	97	if (res == 0)
0f00f2c3 LC	98	result \|= 1;
0f00f2c3 LC	99	iconv_close (cd_utf8_to_88591);
24d56127 LC	100	}
24d56127 LC	101	}
61cd9dc9 LC	102	/* Test against Solaris 10 bug: Failures are not distinguishable from
	103	successful returns. */
	104	{
	105	iconv_t cd_ascii_to_88591 = iconv_open ("ISO8859-1", "646");
	106	if (cd_ascii_to_88591 != (iconv_t)(-1))
	107	{
	108	static const char input[] = "\263";
	109	char buf[10];
	110	const char *inptr = input;
	111	size_t inbytesleft = strlen (input);
	112	char *outptr = buf;
	113	size_t outbytesleft = sizeof (buf);
	114	size_t res = iconv (cd_ascii_to_88591,
	115	(char **) &inptr, &inbytesleft,
	116	&outptr, &outbytesleft);
	117	if (res == 0)
0f00f2c3 LC	118	result \|= 2;
0f00f2c3 LC	119	iconv_close (cd_ascii_to_88591);
61cd9dc9 LC	120	}
61cd9dc9 LC	121	}
9157d901 LC	122	/* Test against AIX 6.1..7.1 bug: Buffer overrun. */
	123	{
	124	iconv_t cd_88591_to_utf8 = iconv_open ("UTF-8", "ISO-8859-1");
	125	if (cd_88591_to_utf8 != (iconv_t)(-1))
	126	{
	127	static const char input[] = "\304";
	128	static char buf[2] = { (char)0xDE, (char)0xAD };
	129	const char *inptr = input;
	130	size_t inbytesleft = 1;
	131	char *outptr = buf;
	132	size_t outbytesleft = 1;
	133	size_t res = iconv (cd_88591_to_utf8,
	134	(char **) &inptr, &inbytesleft,
	135	&outptr, &outbytesleft);
	136	if (res != (size_t)(-1) \|\| outptr - buf > 1 \|\| buf[1] != (char)0xAD)
0f00f2c3 LC	137	result \|= 4;
0f00f2c3 LC	138	iconv_close (cd_88591_to_utf8);
9157d901 LC	139	}
9157d901 LC	140	}
24d56127 LC	141	#if 0 /* This bug could be worked around by the caller. */
	142	/* Test against HP-UX 11.11 bug: Positive return value instead of 0. */
	143	{
	144	iconv_t cd_88591_to_utf8 = iconv_open ("utf8", "iso88591");
	145	if (cd_88591_to_utf8 != (iconv_t)(-1))
	146	{
	147	static const char input[] = "\304rger mit b\366sen B\374bchen ohne Augenma\337";
	148	char buf[50];
	149	const char *inptr = input;
	150	size_t inbytesleft = strlen (input);
	151	char *outptr = buf;
	152	size_t outbytesleft = sizeof (buf);
	153	size_t res = iconv (cd_88591_to_utf8,
	154	(char **) &inptr, &inbytesleft,
	155	&outptr, &outbytesleft);
	156	if ((int)res > 0)
0f00f2c3 LC	157	result \|= 8;
0f00f2c3 LC	158	iconv_close (cd_88591_to_utf8);
24d56127 LC	159	}
	160	}
	161	#endif
	162	/* Test against HP-UX 11.11 bug: No converter from EUC-JP to UTF-8 is
	163	provided. */
	164	if (/* Try standardized names. */
	165	iconv_open ("UTF-8", "EUC-JP") == (iconv_t)(-1)
	166	/* Try IRIX, OSF/1 names. */
	167	&& iconv_open ("UTF-8", "eucJP") == (iconv_t)(-1)
	168	/* Try AIX names. */
	169	&& iconv_open ("UTF-8", "IBM-eucJP") == (iconv_t)(-1)
	170	/* Try HP-UX names. */
	171	&& iconv_open ("utf8", "eucJP") == (iconv_t)(-1))
0f00f2c3 LC	172	result \|= 16;
0f00f2c3 LC	173	return result;
9157d901 LC	174	}]])],
	175	[am_cv_func_iconv_works=yes],
	176	[am_cv_func_iconv_works=no],
	177	[
	178	changequote(,)dnl
	179	case "$host_os" in
24d56127 LC	180	aix* \| hpux*) am_cv_func_iconv_works="guessing no" ;;
24d56127 LC	181	*) am_cv_func_iconv_works="guessing yes" ;;
9157d901 LC	182	esac
	183	changequote([,])dnl
	184	])
24d56127 LC	185	LIBS="$am_save_LIBS"
	186	])
	187	case "$am_cv_func_iconv_works" in
	188	*no) am_func_iconv=no am_cv_lib_iconv=no ;;
	189	*) am_func_iconv=yes ;;
	190	esac
	191	else
	192	am_func_iconv=no am_cv_lib_iconv=no
	193	fi
	194	if test "$am_func_iconv" = yes; then
	195	AC_DEFINE([HAVE_ICONV], [1],
	196	[Define if you have the iconv() function and it works.])
	197	fi
	198	if test "$am_cv_lib_iconv" = yes; then
	199	AC_MSG_CHECKING([how to link with libiconv])
	200	AC_MSG_RESULT([$LIBICONV])
	201	else
	202	dnl If $LIBICONV didn't lead to a usable library, we don't need $INCICONV
	203	dnl either.
	204	CPPFLAGS="$am_save_CPPFLAGS"
	205	LIBICONV=
	206	LTLIBICONV=
	207	fi
	208	AC_SUBST([LIBICONV])
	209	AC_SUBST([LTLIBICONV])
	210	])
	211
a927b6c1 LC	212	dnl Define AM_ICONV using AC_DEFUN_ONCE for Autoconf >= 2.64, in order to
	213	dnl avoid warnings like
	214	dnl "warning: AC_REQUIRE: `AM_ICONV' was expanded before it was required".
6f32e5c7 LC	215	dnl This is tricky because of the way 'aclocal' is implemented:
	216	dnl - It requires defining an auxiliary macro whose name ends in AC_DEFUN.
	217	dnl Otherwise aclocal's initial scan pass would miss the macro definition.
	218	dnl - It requires a line break inside the AC_DEFUN_ONCE and AC_DEFUN expansions.
	219	dnl Otherwise aclocal would emit many "Use of uninitialized value $1"
	220	dnl warnings.
	221	m4_define([gl_iconv_AC_DEFUN],
	222	m4_version_prereq([2.64],
	223	[[AC_DEFUN_ONCE(
	224	[$1], [$2])]],
9157d901 LC	225	[m4_ifdef([gl_00GNULIB],
	226	[[AC_DEFUN_ONCE(
	227	[$1], [$2])]],
	228	[[AC_DEFUN(
	229	[$1], [$2])]])]))
6f32e5c7	230	gl_iconv_AC_DEFUN([AM_ICONV],
24d56127 LC	231	[
	232	AM_ICONV_LINK
	233	if test "$am_cv_func_iconv" = yes; then
	234	AC_MSG_CHECKING([for iconv declaration])
	235	AC_CACHE_VAL([am_cv_proto_iconv], [
9157d901 LC	236	AC_COMPILE_IFELSE(
	237	[AC_LANG_PROGRAM(
	238	[[
24d56127 LC	239	#include <stdlib.h>
	240	#include <iconv.h>
	241	extern
	242	#ifdef __cplusplus
	243	"C"
	244	#endif
35428fb6	245	#if defined(__STDC__) \|\| defined(_MSC_VER) \|\| defined(__cplusplus)
24d56127 LC	246	size_t iconv (iconv_t cd, char * inbuf, size_t inbytesleft, char * outbuf, size_t outbytesleft);
	247	#else
	248	size_t iconv();
	249	#endif
9157d901 LC	250	]],
	251	[[]])],
	252	[am_cv_proto_iconv_arg1=""],
	253	[am_cv_proto_iconv_arg1="const"])
24d56127 LC	254	am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * inbuf, size_t inbytesleft, char * outbuf, size_t outbytesleft);"])
24d56127 LC	255	am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" \| tr -s ' ' \| sed -e 's/( /(/'`
25361e4b LC	256	AC_MSG_RESULT([
25361e4b LC	257	$am_cv_proto_iconv])
24d56127 LC	258	AC_DEFINE_UNQUOTED([ICONV_CONST], [$am_cv_proto_iconv_arg1],
24d56127 LC	259	[Define as const if the declaration of iconv() needs const.])
0f00f2c3 LC	260	dnl Also substitute ICONV_CONST in the gnulib generated <iconv.h>.
	261	m4_ifdef([gl_ICONV_H_DEFAULTS],
	262	[AC_REQUIRE([gl_ICONV_H_DEFAULTS])
	263	if test -n "$am_cv_proto_iconv_arg1"; then
	264	ICONV_CONST="const"
	265	fi
	266	])
24d56127 LC	267	fi
24d56127 LC	268	])