Commit | Line | Data |
---|---|---|
dd7d0148 | 1 | # stdint.m4 serial 40 |
49114fd4 | 2 | dnl Copyright (C) 2001-2011 Free Software Foundation, Inc. |
f240aacb LC |
3 | dnl This file is free software; the Free Software Foundation |
4 | dnl gives unlimited permission to copy and/or distribute it, | |
5 | dnl with or without modifications, as long as this notice is preserved. | |
6 | ||
7 | dnl From Paul Eggert and Bruno Haible. | |
8 | dnl Test whether <stdint.h> is supported or must be substituted. | |
9 | ||
10 | AC_DEFUN([gl_STDINT_H], | |
11 | [ | |
12 | AC_PREREQ([2.59])dnl | |
13 | ||
14 | dnl Check for long long int and unsigned long long int. | |
15 | AC_REQUIRE([AC_TYPE_LONG_LONG_INT]) | |
16 | if test $ac_cv_type_long_long_int = yes; then | |
17 | HAVE_LONG_LONG_INT=1 | |
18 | else | |
19 | HAVE_LONG_LONG_INT=0 | |
20 | fi | |
21 | AC_SUBST([HAVE_LONG_LONG_INT]) | |
22 | AC_REQUIRE([AC_TYPE_UNSIGNED_LONG_LONG_INT]) | |
23 | if test $ac_cv_type_unsigned_long_long_int = yes; then | |
24 | HAVE_UNSIGNED_LONG_LONG_INT=1 | |
25 | else | |
26 | HAVE_UNSIGNED_LONG_LONG_INT=0 | |
27 | fi | |
28 | AC_SUBST([HAVE_UNSIGNED_LONG_LONG_INT]) | |
29 | ||
dd36ce77 MW |
30 | dnl Check for <wchar.h>, in the same way as gl_WCHAR_H does. |
31 | AC_CHECK_HEADERS_ONCE([wchar.h]) | |
32 | if test $ac_cv_header_wchar_h = yes; then | |
33 | HAVE_WCHAR_H=1 | |
34 | else | |
35 | HAVE_WCHAR_H=0 | |
36 | fi | |
37 | AC_SUBST([HAVE_WCHAR_H]) | |
38 | ||
f240aacb LC |
39 | dnl Check for <inttypes.h>. |
40 | dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_inttypes_h. | |
41 | if test $ac_cv_header_inttypes_h = yes; then | |
42 | HAVE_INTTYPES_H=1 | |
43 | else | |
44 | HAVE_INTTYPES_H=0 | |
45 | fi | |
46 | AC_SUBST([HAVE_INTTYPES_H]) | |
47 | ||
48 | dnl Check for <sys/types.h>. | |
49 | dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_sys_types_h. | |
50 | if test $ac_cv_header_sys_types_h = yes; then | |
51 | HAVE_SYS_TYPES_H=1 | |
52 | else | |
53 | HAVE_SYS_TYPES_H=0 | |
54 | fi | |
55 | AC_SUBST([HAVE_SYS_TYPES_H]) | |
56 | ||
57 | gl_CHECK_NEXT_HEADERS([stdint.h]) | |
58 | if test $ac_cv_header_stdint_h = yes; then | |
59 | HAVE_STDINT_H=1 | |
60 | else | |
61 | HAVE_STDINT_H=0 | |
62 | fi | |
63 | AC_SUBST([HAVE_STDINT_H]) | |
64 | ||
65 | dnl Now see whether we need a substitute <stdint.h>. | |
66 | if test $ac_cv_header_stdint_h = yes; then | |
67 | AC_CACHE_CHECK([whether stdint.h conforms to C99], | |
68 | [gl_cv_header_working_stdint_h], | |
69 | [gl_cv_header_working_stdint_h=no | |
70 | AC_COMPILE_IFELSE([ | |
71 | AC_LANG_PROGRAM([[ | |
72 | #define __STDC_LIMIT_MACROS 1 /* to make it work also in C++ mode */ | |
73 | #define __STDC_CONSTANT_MACROS 1 /* to make it work also in C++ mode */ | |
74 | #define _GL_JUST_INCLUDE_SYSTEM_STDINT_H 1 /* work if build isn't clean */ | |
75 | #include <stdint.h> | |
76 | /* Dragonfly defines WCHAR_MIN, WCHAR_MAX only in <wchar.h>. */ | |
77 | #if !(defined WCHAR_MIN && defined WCHAR_MAX) | |
78 | #error "WCHAR_MIN, WCHAR_MAX not defined in <stdint.h>" | |
79 | #endif | |
80 | ] | |
81 | gl_STDINT_INCLUDES | |
82 | [ | |
83 | #ifdef INT8_MAX | |
84 | int8_t a1 = INT8_MAX; | |
85 | int8_t a1min = INT8_MIN; | |
86 | #endif | |
87 | #ifdef INT16_MAX | |
88 | int16_t a2 = INT16_MAX; | |
89 | int16_t a2min = INT16_MIN; | |
90 | #endif | |
91 | #ifdef INT32_MAX | |
92 | int32_t a3 = INT32_MAX; | |
93 | int32_t a3min = INT32_MIN; | |
94 | #endif | |
95 | #ifdef INT64_MAX | |
96 | int64_t a4 = INT64_MAX; | |
97 | int64_t a4min = INT64_MIN; | |
98 | #endif | |
99 | #ifdef UINT8_MAX | |
100 | uint8_t b1 = UINT8_MAX; | |
101 | #else | |
102 | typedef int b1[(unsigned char) -1 != 255 ? 1 : -1]; | |
103 | #endif | |
104 | #ifdef UINT16_MAX | |
105 | uint16_t b2 = UINT16_MAX; | |
106 | #endif | |
107 | #ifdef UINT32_MAX | |
108 | uint32_t b3 = UINT32_MAX; | |
109 | #endif | |
110 | #ifdef UINT64_MAX | |
111 | uint64_t b4 = UINT64_MAX; | |
112 | #endif | |
113 | int_least8_t c1 = INT8_C (0x7f); | |
114 | int_least8_t c1max = INT_LEAST8_MAX; | |
115 | int_least8_t c1min = INT_LEAST8_MIN; | |
116 | int_least16_t c2 = INT16_C (0x7fff); | |
117 | int_least16_t c2max = INT_LEAST16_MAX; | |
118 | int_least16_t c2min = INT_LEAST16_MIN; | |
119 | int_least32_t c3 = INT32_C (0x7fffffff); | |
120 | int_least32_t c3max = INT_LEAST32_MAX; | |
121 | int_least32_t c3min = INT_LEAST32_MIN; | |
122 | int_least64_t c4 = INT64_C (0x7fffffffffffffff); | |
123 | int_least64_t c4max = INT_LEAST64_MAX; | |
124 | int_least64_t c4min = INT_LEAST64_MIN; | |
125 | uint_least8_t d1 = UINT8_C (0xff); | |
126 | uint_least8_t d1max = UINT_LEAST8_MAX; | |
127 | uint_least16_t d2 = UINT16_C (0xffff); | |
128 | uint_least16_t d2max = UINT_LEAST16_MAX; | |
129 | uint_least32_t d3 = UINT32_C (0xffffffff); | |
130 | uint_least32_t d3max = UINT_LEAST32_MAX; | |
131 | uint_least64_t d4 = UINT64_C (0xffffffffffffffff); | |
132 | uint_least64_t d4max = UINT_LEAST64_MAX; | |
133 | int_fast8_t e1 = INT_FAST8_MAX; | |
134 | int_fast8_t e1min = INT_FAST8_MIN; | |
135 | int_fast16_t e2 = INT_FAST16_MAX; | |
136 | int_fast16_t e2min = INT_FAST16_MIN; | |
137 | int_fast32_t e3 = INT_FAST32_MAX; | |
138 | int_fast32_t e3min = INT_FAST32_MIN; | |
139 | int_fast64_t e4 = INT_FAST64_MAX; | |
140 | int_fast64_t e4min = INT_FAST64_MIN; | |
141 | uint_fast8_t f1 = UINT_FAST8_MAX; | |
142 | uint_fast16_t f2 = UINT_FAST16_MAX; | |
143 | uint_fast32_t f3 = UINT_FAST32_MAX; | |
144 | uint_fast64_t f4 = UINT_FAST64_MAX; | |
145 | #ifdef INTPTR_MAX | |
146 | intptr_t g = INTPTR_MAX; | |
147 | intptr_t gmin = INTPTR_MIN; | |
148 | #endif | |
149 | #ifdef UINTPTR_MAX | |
150 | uintptr_t h = UINTPTR_MAX; | |
151 | #endif | |
152 | intmax_t i = INTMAX_MAX; | |
153 | uintmax_t j = UINTMAX_MAX; | |
154 | ||
155 | #include <limits.h> /* for CHAR_BIT */ | |
156 | #define TYPE_MINIMUM(t) \ | |
49114fd4 | 157 | ((t) ((t) 0 < (t) -1 ? (t) 0 : ~ TYPE_MAXIMUM (t))) |
f240aacb | 158 | #define TYPE_MAXIMUM(t) \ |
49114fd4 LC |
159 | ((t) ((t) 0 < (t) -1 \ |
160 | ? (t) -1 \ | |
161 | : ((((t) 1 << (sizeof (t) * CHAR_BIT - 2)) - 1) * 2 + 1))) | |
f240aacb LC |
162 | struct s { |
163 | int check_PTRDIFF: | |
164 | PTRDIFF_MIN == TYPE_MINIMUM (ptrdiff_t) | |
165 | && PTRDIFF_MAX == TYPE_MAXIMUM (ptrdiff_t) | |
166 | ? 1 : -1; | |
167 | /* Detect bug in FreeBSD 6.0 / ia64. */ | |
168 | int check_SIG_ATOMIC: | |
169 | SIG_ATOMIC_MIN == TYPE_MINIMUM (sig_atomic_t) | |
170 | && SIG_ATOMIC_MAX == TYPE_MAXIMUM (sig_atomic_t) | |
171 | ? 1 : -1; | |
172 | int check_SIZE: SIZE_MAX == TYPE_MAXIMUM (size_t) ? 1 : -1; | |
173 | int check_WCHAR: | |
174 | WCHAR_MIN == TYPE_MINIMUM (wchar_t) | |
175 | && WCHAR_MAX == TYPE_MAXIMUM (wchar_t) | |
176 | ? 1 : -1; | |
177 | /* Detect bug in mingw. */ | |
178 | int check_WINT: | |
179 | WINT_MIN == TYPE_MINIMUM (wint_t) | |
180 | && WINT_MAX == TYPE_MAXIMUM (wint_t) | |
181 | ? 1 : -1; | |
182 | ||
183 | /* Detect bugs in glibc 2.4 and Solaris 10 stdint.h, among others. */ | |
184 | int check_UINT8_C: | |
185 | (-1 < UINT8_C (0)) == (-1 < (uint_least8_t) 0) ? 1 : -1; | |
186 | int check_UINT16_C: | |
187 | (-1 < UINT16_C (0)) == (-1 < (uint_least16_t) 0) ? 1 : -1; | |
188 | ||
189 | /* Detect bugs in OpenBSD 3.9 stdint.h. */ | |
190 | #ifdef UINT8_MAX | |
191 | int check_uint8: (uint8_t) -1 == UINT8_MAX ? 1 : -1; | |
192 | #endif | |
193 | #ifdef UINT16_MAX | |
194 | int check_uint16: (uint16_t) -1 == UINT16_MAX ? 1 : -1; | |
195 | #endif | |
196 | #ifdef UINT32_MAX | |
197 | int check_uint32: (uint32_t) -1 == UINT32_MAX ? 1 : -1; | |
198 | #endif | |
199 | #ifdef UINT64_MAX | |
200 | int check_uint64: (uint64_t) -1 == UINT64_MAX ? 1 : -1; | |
201 | #endif | |
202 | int check_uint_least8: (uint_least8_t) -1 == UINT_LEAST8_MAX ? 1 : -1; | |
203 | int check_uint_least16: (uint_least16_t) -1 == UINT_LEAST16_MAX ? 1 : -1; | |
204 | int check_uint_least32: (uint_least32_t) -1 == UINT_LEAST32_MAX ? 1 : -1; | |
205 | int check_uint_least64: (uint_least64_t) -1 == UINT_LEAST64_MAX ? 1 : -1; | |
206 | int check_uint_fast8: (uint_fast8_t) -1 == UINT_FAST8_MAX ? 1 : -1; | |
207 | int check_uint_fast16: (uint_fast16_t) -1 == UINT_FAST16_MAX ? 1 : -1; | |
208 | int check_uint_fast32: (uint_fast32_t) -1 == UINT_FAST32_MAX ? 1 : -1; | |
209 | int check_uint_fast64: (uint_fast64_t) -1 == UINT_FAST64_MAX ? 1 : -1; | |
210 | int check_uintptr: (uintptr_t) -1 == UINTPTR_MAX ? 1 : -1; | |
211 | int check_uintmax: (uintmax_t) -1 == UINTMAX_MAX ? 1 : -1; | |
212 | int check_size: (size_t) -1 == SIZE_MAX ? 1 : -1; | |
213 | }; | |
214 | ]])], | |
215 | [dnl Determine whether the various *_MIN, *_MAX macros are usable | |
216 | dnl in preprocessor expression. We could do it by compiling a test | |
217 | dnl program for each of these macros. It is faster to run a program | |
218 | dnl that inspects the macro expansion. | |
219 | dnl This detects a bug on HP-UX 11.23/ia64. | |
220 | AC_RUN_IFELSE([ | |
221 | AC_LANG_PROGRAM([[ | |
222 | #define __STDC_LIMIT_MACROS 1 /* to make it work also in C++ mode */ | |
223 | #define __STDC_CONSTANT_MACROS 1 /* to make it work also in C++ mode */ | |
224 | #define _GL_JUST_INCLUDE_SYSTEM_STDINT_H 1 /* work if build isn't clean */ | |
225 | #include <stdint.h> | |
226 | ] | |
227 | gl_STDINT_INCLUDES | |
228 | [ | |
229 | #include <stdio.h> | |
230 | #include <string.h> | |
231 | #define MVAL(macro) MVAL1(macro) | |
232 | #define MVAL1(expression) #expression | |
233 | static const char *macro_values[] = | |
234 | { | |
235 | #ifdef INT8_MAX | |
236 | MVAL (INT8_MAX), | |
237 | #endif | |
238 | #ifdef INT16_MAX | |
239 | MVAL (INT16_MAX), | |
240 | #endif | |
241 | #ifdef INT32_MAX | |
242 | MVAL (INT32_MAX), | |
243 | #endif | |
244 | #ifdef INT64_MAX | |
245 | MVAL (INT64_MAX), | |
246 | #endif | |
247 | #ifdef UINT8_MAX | |
248 | MVAL (UINT8_MAX), | |
249 | #endif | |
250 | #ifdef UINT16_MAX | |
251 | MVAL (UINT16_MAX), | |
252 | #endif | |
253 | #ifdef UINT32_MAX | |
254 | MVAL (UINT32_MAX), | |
255 | #endif | |
256 | #ifdef UINT64_MAX | |
257 | MVAL (UINT64_MAX), | |
258 | #endif | |
259 | NULL | |
260 | }; | |
261 | ]], [[ | |
262 | const char **mv; | |
263 | for (mv = macro_values; *mv != NULL; mv++) | |
264 | { | |
265 | const char *value = *mv; | |
266 | /* Test whether it looks like a cast expression. */ | |
267 | if (strncmp (value, "((unsigned int)"/*)*/, 15) == 0 | |
268 | || strncmp (value, "((unsigned short)"/*)*/, 17) == 0 | |
269 | || strncmp (value, "((unsigned char)"/*)*/, 16) == 0 | |
270 | || strncmp (value, "((int)"/*)*/, 6) == 0 | |
271 | || strncmp (value, "((signed short)"/*)*/, 15) == 0 | |
272 | || strncmp (value, "((signed char)"/*)*/, 14) == 0) | |
0f00f2c3 | 273 | return mv - macro_values + 1; |
f240aacb LC |
274 | } |
275 | return 0; | |
276 | ]])], | |
277 | [gl_cv_header_working_stdint_h=yes], | |
278 | [], | |
279 | [dnl When cross-compiling, assume it works. | |
280 | gl_cv_header_working_stdint_h=yes | |
281 | ]) | |
282 | ]) | |
283 | ]) | |
284 | fi | |
285 | if test "$gl_cv_header_working_stdint_h" = yes; then | |
286 | STDINT_H= | |
287 | else | |
288 | dnl Check for <sys/inttypes.h>, and for | |
289 | dnl <sys/bitypes.h> (used in Linux libc4 >= 4.6.7 and libc5). | |
290 | AC_CHECK_HEADERS([sys/inttypes.h sys/bitypes.h]) | |
291 | if test $ac_cv_header_sys_inttypes_h = yes; then | |
292 | HAVE_SYS_INTTYPES_H=1 | |
293 | else | |
294 | HAVE_SYS_INTTYPES_H=0 | |
295 | fi | |
296 | AC_SUBST([HAVE_SYS_INTTYPES_H]) | |
297 | if test $ac_cv_header_sys_bitypes_h = yes; then | |
298 | HAVE_SYS_BITYPES_H=1 | |
299 | else | |
300 | HAVE_SYS_BITYPES_H=0 | |
301 | fi | |
302 | AC_SUBST([HAVE_SYS_BITYPES_H]) | |
303 | ||
f240aacb LC |
304 | gl_STDINT_TYPE_PROPERTIES |
305 | STDINT_H=stdint.h | |
306 | fi | |
307 | AC_SUBST([STDINT_H]) | |
dd7d0148 | 308 | AM_CONDITIONAL([GL_GENERATE_STDINT_H], [test -n "$STDINT_H"]) |
f240aacb LC |
309 | ]) |
310 | ||
311 | dnl gl_STDINT_BITSIZEOF(TYPES, INCLUDES) | |
312 | dnl Determine the size of each of the given types in bits. | |
313 | AC_DEFUN([gl_STDINT_BITSIZEOF], | |
314 | [ | |
315 | dnl Use a shell loop, to avoid bloating configure, and | |
316 | dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into | |
317 | dnl config.h.in, | |
318 | dnl - extra AC_SUBST calls, so that the right substitutions are made. | |
319 | m4_foreach_w([gltype], [$1], | |
9157d901 | 320 | [AH_TEMPLATE([BITSIZEOF_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]), |
f240aacb LC |
321 | [Define to the number of bits in type ']gltype['.])]) |
322 | for gltype in $1 ; do | |
323 | AC_CACHE_CHECK([for bit size of $gltype], [gl_cv_bitsizeof_${gltype}], | |
324 | [AC_COMPUTE_INT([result], [sizeof ($gltype) * CHAR_BIT], | |
325 | [$2 | |
326 | #include <limits.h>], [result=unknown]) | |
327 | eval gl_cv_bitsizeof_${gltype}=\$result | |
328 | ]) | |
329 | eval result=\$gl_cv_bitsizeof_${gltype} | |
330 | if test $result = unknown; then | |
331 | dnl Use a nonempty default, because some compilers, such as IRIX 5 cc, | |
332 | dnl do a syntax check even on unused #if conditions and give an error | |
333 | dnl on valid C code like this: | |
334 | dnl #if 0 | |
335 | dnl # if > 32 | |
336 | dnl # endif | |
337 | dnl #endif | |
338 | result=0 | |
339 | fi | |
340 | GLTYPE=`echo "$gltype" | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'` | |
341 | AC_DEFINE_UNQUOTED([BITSIZEOF_${GLTYPE}], [$result]) | |
342 | eval BITSIZEOF_${GLTYPE}=\$result | |
343 | done | |
344 | m4_foreach_w([gltype], [$1], | |
9157d901 | 345 | [AC_SUBST([BITSIZEOF_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))]) |
f240aacb LC |
346 | ]) |
347 | ||
348 | dnl gl_CHECK_TYPES_SIGNED(TYPES, INCLUDES) | |
349 | dnl Determine the signedness of each of the given types. | |
350 | dnl Define HAVE_SIGNED_TYPE if type is signed. | |
351 | AC_DEFUN([gl_CHECK_TYPES_SIGNED], | |
352 | [ | |
353 | dnl Use a shell loop, to avoid bloating configure, and | |
354 | dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into | |
355 | dnl config.h.in, | |
356 | dnl - extra AC_SUBST calls, so that the right substitutions are made. | |
357 | m4_foreach_w([gltype], [$1], | |
9157d901 | 358 | [AH_TEMPLATE([HAVE_SIGNED_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]), |
f240aacb LC |
359 | [Define to 1 if ']gltype[' is a signed integer type.])]) |
360 | for gltype in $1 ; do | |
361 | AC_CACHE_CHECK([whether $gltype is signed], [gl_cv_type_${gltype}_signed], | |
362 | [AC_COMPILE_IFELSE( | |
363 | [AC_LANG_PROGRAM([$2[ | |
364 | int verify[2 * (($gltype) -1 < ($gltype) 0) - 1];]])], | |
365 | result=yes, result=no) | |
366 | eval gl_cv_type_${gltype}_signed=\$result | |
367 | ]) | |
368 | eval result=\$gl_cv_type_${gltype}_signed | |
369 | GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'` | |
370 | if test "$result" = yes; then | |
371 | AC_DEFINE_UNQUOTED([HAVE_SIGNED_${GLTYPE}], [1]) | |
372 | eval HAVE_SIGNED_${GLTYPE}=1 | |
373 | else | |
374 | eval HAVE_SIGNED_${GLTYPE}=0 | |
375 | fi | |
376 | done | |
377 | m4_foreach_w([gltype], [$1], | |
9157d901 | 378 | [AC_SUBST([HAVE_SIGNED_]m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))]) |
f240aacb LC |
379 | ]) |
380 | ||
381 | dnl gl_INTEGER_TYPE_SUFFIX(TYPES, INCLUDES) | |
382 | dnl Determine the suffix to use for integer constants of the given types. | |
383 | dnl Define t_SUFFIX for each such type. | |
384 | AC_DEFUN([gl_INTEGER_TYPE_SUFFIX], | |
385 | [ | |
386 | dnl Use a shell loop, to avoid bloating configure, and | |
387 | dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into | |
388 | dnl config.h.in, | |
389 | dnl - extra AC_SUBST calls, so that the right substitutions are made. | |
390 | m4_foreach_w([gltype], [$1], | |
9157d901 | 391 | [AH_TEMPLATE(m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX], |
f240aacb LC |
392 | [Define to l, ll, u, ul, ull, etc., as suitable for |
393 | constants of type ']gltype['.])]) | |
394 | for gltype in $1 ; do | |
395 | AC_CACHE_CHECK([for $gltype integer literal suffix], | |
396 | [gl_cv_type_${gltype}_suffix], | |
397 | [eval gl_cv_type_${gltype}_suffix=no | |
398 | eval result=\$gl_cv_type_${gltype}_signed | |
399 | if test "$result" = yes; then | |
400 | glsufu= | |
401 | else | |
402 | glsufu=u | |
403 | fi | |
404 | for glsuf in "$glsufu" ${glsufu}l ${glsufu}ll ${glsufu}i64; do | |
405 | case $glsuf in | |
406 | '') gltype1='int';; | |
1cd4fffc LC |
407 | l) gltype1='long int';; |
408 | ll) gltype1='long long int';; | |
409 | i64) gltype1='__int64';; | |
410 | u) gltype1='unsigned int';; | |
411 | ul) gltype1='unsigned long int';; | |
412 | ull) gltype1='unsigned long long int';; | |
f240aacb LC |
413 | ui64)gltype1='unsigned __int64';; |
414 | esac | |
415 | AC_COMPILE_IFELSE( | |
416 | [AC_LANG_PROGRAM([$2[ | |
417 | extern $gltype foo; | |
418 | extern $gltype1 foo;]])], | |
419 | [eval gl_cv_type_${gltype}_suffix=\$glsuf]) | |
420 | eval result=\$gl_cv_type_${gltype}_suffix | |
421 | test "$result" != no && break | |
422 | done]) | |
423 | GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'` | |
424 | eval result=\$gl_cv_type_${gltype}_suffix | |
425 | test "$result" = no && result= | |
426 | eval ${GLTYPE}_SUFFIX=\$result | |
427 | AC_DEFINE_UNQUOTED([${GLTYPE}_SUFFIX], [$result]) | |
428 | done | |
429 | m4_foreach_w([gltype], [$1], | |
9157d901 | 430 | [AC_SUBST(m4_translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX])]) |
f240aacb LC |
431 | ]) |
432 | ||
433 | dnl gl_STDINT_INCLUDES | |
434 | AC_DEFUN([gl_STDINT_INCLUDES], | |
435 | [[ | |
436 | /* BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be | |
437 | included before <wchar.h>. */ | |
438 | #include <stddef.h> | |
439 | #include <signal.h> | |
440 | #if HAVE_WCHAR_H | |
441 | # include <stdio.h> | |
442 | # include <time.h> | |
443 | # include <wchar.h> | |
444 | #endif | |
445 | ]]) | |
446 | ||
447 | dnl gl_STDINT_TYPE_PROPERTIES | |
448 | dnl Compute HAVE_SIGNED_t, BITSIZEOF_t and t_SUFFIX, for all the types t | |
449 | dnl of interest to stdint.in.h. | |
450 | AC_DEFUN([gl_STDINT_TYPE_PROPERTIES], | |
451 | [ | |
452 | AC_REQUIRE([gl_MULTIARCH]) | |
453 | if test $APPLE_UNIVERSAL_BUILD = 0; then | |
454 | gl_STDINT_BITSIZEOF([ptrdiff_t size_t], | |
455 | [gl_STDINT_INCLUDES]) | |
456 | fi | |
457 | gl_STDINT_BITSIZEOF([sig_atomic_t wchar_t wint_t], | |
458 | [gl_STDINT_INCLUDES]) | |
459 | gl_CHECK_TYPES_SIGNED([sig_atomic_t wchar_t wint_t], | |
460 | [gl_STDINT_INCLUDES]) | |
461 | gl_cv_type_ptrdiff_t_signed=yes | |
462 | gl_cv_type_size_t_signed=no | |
463 | if test $APPLE_UNIVERSAL_BUILD = 0; then | |
464 | gl_INTEGER_TYPE_SUFFIX([ptrdiff_t size_t], | |
465 | [gl_STDINT_INCLUDES]) | |
466 | fi | |
467 | gl_INTEGER_TYPE_SUFFIX([sig_atomic_t wchar_t wint_t], | |
468 | [gl_STDINT_INCLUDES]) | |
469 | ]) | |
470 | ||
471 | dnl Autoconf >= 2.61 has AC_COMPUTE_INT built-in. | |
472 | dnl Remove this when we can assume autoconf >= 2.61. | |
473 | m4_ifdef([AC_COMPUTE_INT], [], [ | |
474 | AC_DEFUN([AC_COMPUTE_INT], [_AC_COMPUTE_INT([$2],[$1],[$3],[$4])]) | |
475 | ]) | |
476 | ||
477 | # Hey Emacs! | |
478 | # Local Variables: | |
479 | # indent-tabs-mode: nil | |
480 | # End: |