m4/utimbuf.m4

   1 # serial 9
   2
   3 # Copyright (C) 1998-2001, 2003-2004, 2007, 2009-2014 Free Software Foundation,
   4 # Inc.
   5 #
   6 # This file is free software; the Free Software Foundation
   7 # gives unlimited permission to copy and/or distribute it,
   8 # with or without modifications, as long as this notice is preserved.
   9
  10 dnl From Jim Meyering
  11
  12 dnl Define HAVE_STRUCT_UTIMBUF if 'struct utimbuf' is declared --
  13 dnl usually in <utime.h>.
  14 dnl Some systems have utime.h but don't declare the struct anywhere.
  15
  16 AC_DEFUN([gl_CHECK_TYPE_STRUCT_UTIMBUF],
  17 [
  18   AC_CHECK_HEADERS_ONCE([sys/time.h utime.h])
  19   AC_CACHE_CHECK([for struct utimbuf], [gl_cv_sys_struct_utimbuf],
  20     [AC_COMPILE_IFELSE(
  21        [AC_LANG_PROGRAM(
  22           [[#if HAVE_SYS_TIME_H
  23              #include <sys/time.h>
  24             #endif
  25             #include <time.h>
  26             #ifdef HAVE_UTIME_H
  27              #include <utime.h>
  28             #endif
  29           ]],
  30           [[static struct utimbuf x; x.actime = x.modtime;]])],
  31        [gl_cv_sys_struct_utimbuf=yes],
  32        [gl_cv_sys_struct_utimbuf=no])])
  33
  34   if test $gl_cv_sys_struct_utimbuf = yes; then
  35     AC_DEFINE([HAVE_STRUCT_UTIMBUF], [1],
  36       [Define if struct utimbuf is declared -- usually in <utime.h>.
  37        Some systems have utime.h but don't declare the struct anywhere. ])
  38   fi
  39 ])