src/.gdbinit

   1 # Copyright (C) 1992-1998, 2000-2012  Free Software Foundation, Inc.
   2 #
   3 # This file is part of GNU Emacs.
   4 #
   5 # GNU Emacs is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3, or (at your option)
   8 # any later version.
   9 #
  10 # GNU Emacs is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # Force loading of symbols, enough to give us VALBITS etc.
  19 set $dummy = main + 8
  20 # With some compilers, we need this to give us struct Lisp_Symbol etc.:
  21 set $dummy = Fmake_symbol + 8
  22
  23 # Find lwlib source files too.
  24 dir ../lwlib
  25 #dir /gd/gnu/lesstif-0.89.9/lib/Xm
  26
  27 # Don't enter GDB when user types C-g to quit.
  28 # This has one unfortunate effect: you can't type C-c
  29 # at the GDB to stop Emacs, when using X.
  30 # However, C-z works just as well in that case.
  31 handle 2 noprint pass
  32
  33 # Make it work like SIGINT normally does.
  34 handle SIGTSTP nopass
  35
  36 # Pass on user signals
  37 handle SIGUSR1 noprint pass
  38 handle SIGUSR2 noprint pass
  39
  40 # Don't pass SIGALRM to Emacs.  This makes problems when
  41 # debugging.
  42 handle SIGALRM ignore
  43
  44 # Use $bugfix so that the value isn't a constant.
  45 # Using a constant runs into GDB bugs sometimes.
  46 define xgetptr
  47   if (CHECK_LISP_OBJECT_TYPE)
  48     set $bugfix = $arg0.i
  49   else
  50     set $bugfix = $arg0
  51   end
  52   set $ptr = ($bugfix & VALMASK) | DATA_SEG_BITS
  53 end
  54
  55 define xgetint
  56   if (CHECK_LISP_OBJECT_TYPE)
  57     set $bugfix = $arg0.i
  58   else
  59     set $bugfix = $arg0
  60   end
  61   set $int = $bugfix << (USE_LSB_TAG ? 0 : INTTYPEBITS) >> INTTYPEBITS
  62 end
  63
  64 define xgettype
  65   if (CHECK_LISP_OBJECT_TYPE)
  66     set $bugfix = $arg0.i
  67   else
  68     set $bugfix = $arg0
  69   end
  70   set $type = (enum Lisp_Type) (USE_LSB_TAG ? $bugfix & (1 << GCTYPEBITS) - 1 : $bugfix >> VALBITS)
  71 end
  72
  73 # Set up something to print out s-expressions.
  74 # We save and restore print_output_debug_flag to prevent the w32 port
  75 # from calling OutputDebugString, which causes GDB to display each
  76 # character twice (yuk!).
  77 define pr
  78   pp $
  79 end
  80 document pr
  81 Print the emacs s-expression which is $.
  82 Works only when an inferior emacs is executing.
  83 end
  84
  85 # Print out s-expressions
  86 define pp
  87   set $tmp = $arg0
  88   set $output_debug = print_output_debug_flag
  89   set print_output_debug_flag = 0
  90   call safe_debug_print ($tmp)
  91   set print_output_debug_flag = $output_debug
  92 end
  93 document pp
  94 Print the argument as an emacs s-expression
  95 Works only when an inferior emacs is executing.
  96 end
  97
  98 # Print value of lisp variable
  99 define pv
 100   set $tmp = "$arg0"
 101   set $output_debug = print_output_debug_flag
 102   set print_output_debug_flag = 0
 103   call safe_debug_print (find_symbol_value (intern ($tmp)))
 104   set print_output_debug_flag = $output_debug
 105 end
 106 document pv
 107 Print the value of the lisp variable given as argument.
 108 Works only when an inferior emacs is executing.
 109 end
 110
 111 # Print out current buffer point and boundaries
 112 define ppt
 113   set $b = current_buffer
 114   set $t = $b->text
 115   printf "BUF PT: %d", $b->pt
 116   if ($b->pt != $b->pt_byte)
 117     printf "[%d]", $b->pt_byte
 118   end
 119   printf " of 1..%d", $t->z
 120   if ($t->z != $t->z_byte)
 121     printf "[%d]", $t->z_byte
 122   end
 123   if ($b->begv != 1 || $b->zv != $t->z)
 124     printf " NARROW=%d..%d", $b->begv, $b->zv
 125     if ($b->begv != $b->begv_byte || $b->zv != $b->zv_byte)
 126       printf " [%d..%d]", $b->begv_byte, $b->zv_byte
 127     end
 128   end
 129   printf " GAP: %d", $t->gpt
 130   if ($t->gpt != $t->gpt_byte)
 131     printf "[%d]", $t->gpt_byte
 132   end
 133   printf " SZ=%d\n", $t->gap_size
 134 end
 135 document ppt
 136 Print current buffer's point and boundaries.
 137 Prints values of point, beg, end, narrow, and gap for current buffer.
 138 end
 139
 140 define pitmethod
 141   set $itmethod = $arg0
 142   # output $itmethod
 143   if ($itmethod == 0)
 144     printf "GET_FROM_BUFFER"
 145   end
 146   if ($itmethod == 1)
 147     printf "GET_FROM_DISPLAY_VECTOR"
 148   end
 149   if ($itmethod == 2)
 150     printf "GET_FROM_STRING"
 151   end
 152   if ($itmethod == 3)
 153     printf "GET_FROM_C_STRING"
 154   end
 155   if ($itmethod == 4)
 156     printf "GET_FROM_IMAGE"
 157   end
 158   if ($itmethod == 5)
 159     printf "GET_FROM_STRETCH"
 160   end
 161   if ($itmethod < 0 || $itmethod > 5)
 162     output $itmethod
 163   end
 164 end
 165 document pitmethod
 166 Pretty print it->method given as first arg
 167 end
 168
 169 # Print out iterator given as first arg
 170 define pitx
 171   set $it = $arg0
 172   printf "cur=%d", $it->current.pos.charpos
 173   if ($it->current.pos.charpos != $it->current.pos.bytepos)
 174     printf "[%d]", $it->current.pos.bytepos
 175   end
 176   printf " pos=%d", $it->position.charpos
 177   if ($it->position.charpos != $it->position.bytepos)
 178     printf "[%d]", $it->position.bytepos
 179   end
 180   printf " start=%d", $it->start.pos.charpos
 181   if ($it->start.pos.charpos != $it->start.pos.bytepos)
 182     printf "[%d]", $it->start.pos.bytepos
 183   end
 184   printf " end=%d", $it->end_charpos
 185   printf " stop=%d", $it->stop_charpos
 186   printf " face=%d", $it->face_id
 187   if ($it->multibyte_p)
 188     printf " MB"
 189   end
 190   if ($it->header_line_p)
 191     printf " HL"
 192   end
 193   if ($it->n_overlay_strings > 0)
 194     printf " nov=%d", $it->n_overlay_strings
 195   end
 196   if ($it->sp != 0)
 197     printf " sp=%d", $it->sp
 198   end
 199   # IT_CHARACTER
 200   if ($it->what == 0)
 201     if ($it->len == 1 && $it->c >= ' ' && it->c < 255)
 202       printf " ch='%c'", $it->c
 203     else
 204       printf " ch=[%d,%d]", $it->c, $it->len
 205     end
 206   else
 207     printf " "
 208     # output $it->what
 209     if ($it->what == 0)
 210       printf "IT_CHARACTER"
 211     end
 212     if ($it->what == 1)
 213       printf "IT_COMPOSITION"
 214     end
 215     if ($it->what == 2)
 216       printf "IT_IMAGE"
 217     end
 218     if ($it->what == 3)
 219       printf "IT_STRETCH"
 220     end
 221     if ($it->what == 4)
 222       printf "IT_EOB"
 223     end
 224     if ($it->what == 5)
 225       printf "IT_TRUNCATION"
 226     end
 227     if ($it->what == 6)
 228       printf "IT_CONTINUATION"
 229     end
 230     if ($it->what < 0 || $it->what > 6)
 231       output $it->what
 232     end
 233   end
 234   if ($it->method != 0)
 235     # !GET_FROM_BUFFER
 236     printf " next="
 237     pitmethod $it->method
 238     if ($it->method == 2)
 239       # GET_FROM_STRING
 240       printf "[%d]", $it->current.string_pos.charpos
 241     end
 242     if ($it->method == 4)
 243       # GET_FROM_IMAGE
 244       printf "[%d]", $it->image_id
 245     end
 246   end
 247   printf "\n"
 248   if ($it->bidi_p)
 249     printf "BIDI: base_stop=%d prev_stop=%d level=%d\n", $it->base_level_stop, $it->prev_stop, $it->bidi_it.resolved_level
 250   end
 251   if ($it->region_beg_charpos >= 0)
 252     printf "reg=%d-%d ", $it->region_beg_charpos, $it->region_end_charpos
 253   end
 254   printf "vpos=%d hpos=%d", $it->vpos, $it->hpos,
 255   printf " y=%d lvy=%d", $it->current_y, $it->last_visible_y
 256   printf " x=%d vx=%d-%d", $it->current_x, $it->first_visible_x, $it->last_visible_x
 257   printf " w=%d", $it->pixel_width
 258   printf " a+d=%d+%d=%d", $it->ascent, $it->descent, $it->ascent+$it->descent
 259   printf " max=%d+%d=%d", $it->max_ascent, $it->max_descent, $it->max_ascent+$it->max_descent
 260   printf "\n"
 261   set $i = 0
 262   while ($i < $it->sp && $i < 4)
 263     set $e = $it->stack[$i]
 264     printf "stack[%d]: ", $i
 265     pitmethod $e.method
 266     printf "[%d]", $e.position.charpos
 267     printf "\n"
 268     set $i = $i + 1
 269   end
 270 end
 271 document pitx
 272 Pretty print a display iterator.
 273 Take one arg, an iterator object or pointer.
 274 end
 275
 276 define pit
 277   pitx it
 278 end
 279 document pit
 280 Pretty print the display iterator it.
 281 end
 282
 283 define prowx
 284   set $row = $arg0
 285   printf "y=%d x=%d pwid=%d", $row->y, $row->x, $row->pixel_width
 286   printf " a+d=%d+%d=%d", $row->ascent, $row->height-$row->ascent, $row->height
 287   printf " phys=%d+%d=%d", $row->phys_ascent, $row->phys_height-$row->phys_ascent, $row->phys_height
 288   printf " vis=%d\n", $row->visible_height
 289   printf "used=(LMargin=%d,Text=%d,RMargin=%d) Hash=%d\n", $row->used[0], $row->used[1], $row->used[2], $row->hash
 290   printf "start=%d end=%d", $row->start.pos.charpos, $row->end.pos.charpos
 291   if ($row->enabled_p)
 292     printf " ENA"
 293   end
 294   if ($row->displays_text_p)
 295     printf " DISP"
 296   end
 297   if ($row->mode_line_p)
 298     printf " MODEL"
 299   end
 300   if ($row->continued_p)
 301     printf " CONT"
 302   end
 303   if ($row-> truncated_on_left_p)
 304     printf " TRUNC:L"
 305   end
 306   if ($row-> truncated_on_right_p)
 307     printf " TRUNC:R"
 308   end
 309   if ($row->starts_in_middle_of_char_p)
 310     printf " STARTMID"
 311   end
 312   if ($row->ends_in_middle_of_char_p)
 313     printf " ENDMID"
 314   end
 315   if ($row->ends_in_newline_from_string_p)
 316     printf " ENDNLFS"
 317   end
 318   if ($row->ends_at_zv_p)
 319     printf " ENDZV"
 320   end
 321   if ($row->overlapped_p)
 322     printf " OLAPD"
 323   end
 324   if ($row->overlapping_p)
 325     printf " OLAPNG"
 326   end
 327   printf "\n"
 328 end
 329 document prowx
 330 Pretty print information about glyph_row.
 331 Takes one argument, a row object or pointer.
 332 end
 333
 334 define prow
 335   prowx row
 336 end
 337 document prow
 338 Pretty print information about glyph_row in row.
 339 end
 340
 341
 342 define pcursorx
 343   set $cp = $arg0
 344   printf "y=%d x=%d vpos=%d hpos=%d", $cp->y, $cp->x, $cp->vpos, $cp->hpos
 345 end
 346 document pcursorx
 347 Pretty print a window cursor.
 348 end
 349
 350 define pcursor
 351   printf "output: "
 352   pcursorx output_cursor
 353   printf "\n"
 354 end
 355 document pcursor
 356 Pretty print the output_cursor.
 357 end
 358
 359 define pwinx
 360   set $w = $arg0
 361   xgetint $w->sequence_number
 362   if ($w->mini_p != Qnil)
 363     printf "Mini "
 364   end
 365   printf "Window %d ", $int
 366   xgetptr $w->buffer
 367   set $tem = (struct buffer *) $ptr
 368   xgetptr $tem->name_
 369   printf "%s", ((struct Lisp_String *) $ptr)->data
 370   printf "\n"
 371   xgetptr $w->start
 372   set $tem = (struct Lisp_Marker *) $ptr
 373   printf "start=%d end:", $tem->charpos
 374   if ($w->window_end_valid != Qnil)
 375     xgetint $w->window_end_pos
 376     printf "pos=%d", $int
 377     xgetint $w->window_end_vpos
 378     printf " vpos=%d", $int
 379   else
 380     printf "invalid"
 381   end
 382   printf " vscroll=%d", $w->vscroll
 383   if ($w->force_start != Qnil)
 384     printf " FORCE_START"
 385   end
 386   if ($w->must_be_updated_p)
 387     printf " MUST_UPD"
 388   end
 389   printf "\n"
 390   printf "cursor: "
 391   pcursorx $w->cursor
 392   printf "  phys: "
 393   pcursorx $w->phys_cursor
 394   if ($w->phys_cursor_on_p)
 395     printf " ON"
 396   else
 397     printf " OFF"
 398   end
 399   printf " blk="
 400   if ($w->last_cursor_off_p != $w->cursor_off_p)
 401     if ($w->last_cursor_off_p)
 402       printf "ON->"
 403     else
 404       printf "OFF->"
 405     end
 406   end
 407   if ($w->cursor_off_p)
 408     printf "ON"
 409   else
 410     printf "OFF"
 411   end
 412   printf "\n"
 413 end
 414 document pwinx
 415 Pretty print a window structure.
 416 Takes one argument, a pointer to a window structure.
 417 end
 418
 419 define pwin
 420   pwinx w
 421 end
 422 document pwin
 423 Pretty print window structure w.
 424 end
 425
 426 define pbiditype
 427   if ($arg0 == 0)
 428     printf "UNDEF"
 429   end
 430   if ($arg0 == 1)
 431     printf "L"
 432   end
 433   if ($arg0 == 2)
 434     printf "R"
 435   end
 436   if ($arg0 == 3)
 437     printf "EN"
 438   end
 439   if ($arg0 == 4)
 440     printf "AN"
 441   end
 442   if ($arg0 == 5)
 443     printf "BN"
 444   end
 445   if ($arg0 == 6)
 446     printf "B"
 447   end
 448   if ($arg0 < 0 || $arg0 > 6)
 449     printf "%d??", $arg0
 450   end
 451 end
 452 document pbiditype
 453 Print textual description of bidi type given as first argument.
 454 end
 455
 456 define pgx
 457   set $g = $arg0
 458   # CHAR_GLYPH
 459   if ($g.type == 0)
 460     if ($g.u.ch >= ' ' && $g.u.ch < 127)
 461       printf "CHAR[%c]", $g.u.ch
 462     else
 463       printf "CHAR[0x%x]", $g.u.ch
 464     end
 465   end
 466   # COMPOSITE_GLYPH
 467   if ($g.type == 1)
 468     printf "COMP[%d (%d..%d)]", $g.u.cmp.id, $g.slice.cmp.from, $g.slice.cmp.to
 469   end
 470   # GLYPHLESS_GLYPH
 471   if ($g.type == 2)
 472     printf "GLYPHLESS["
 473     if ($g.u.glyphless.method == 0)
 474       printf "THIN]"
 475     end
 476     if ($g.u.glyphless.method == 1)
 477       printf "EMPTY]"
 478     end
 479     if ($g.u.glyphless.method == 2)
 480       printf "ACRO]"
 481     end
 482     if ($g.u.glyphless.method == 3)
 483       printf "HEX]"
 484     end
 485   end
 486   # IMAGE_GLYPH
 487   if ($g.type == 3)
 488     printf "IMAGE[%d]", $g.u.img_id
 489   end
 490   # STRETCH_GLYPH
 491   if ($g.type == 4)
 492     printf "STRETCH[%d+%d]", $g.u.stretch.height, $g.u.stretch.ascent
 493   end
 494   xgettype ($g.object)
 495   if ($type == Lisp_String)
 496     xgetptr $g.object
 497     printf " str=0x%x[%d]", ((struct Lisp_String *)$ptr)->data, $g.charpos
 498   else
 499     printf " pos=%d", $g.charpos
 500   end
 501   # For characters, print their resolved level and bidi type
 502   if ($g.type == 0)
 503     printf " blev=%d,btyp=", $g.resolved_level
 504     pbiditype $g.bidi_type
 505   end
 506   printf " w=%d a+d=%d+%d", $g.pixel_width, $g.ascent, $g.descent
 507   # If not DEFAULT_FACE_ID
 508   if ($g.face_id != 0)
 509     printf " face=%d", $g.face_id
 510   end
 511   if ($g.voffset)
 512     printf " vof=%d", $g.voffset
 513   end
 514   if ($g.multibyte_p)
 515     printf " MB"
 516   end
 517   if ($g.padding_p)
 518     printf " PAD"
 519   end
 520   if ($g.glyph_not_available_p)
 521     printf " N/A"
 522   end
 523   if ($g.overlaps_vertically_p)
 524     printf " OVL"
 525   end
 526   if ($g.avoid_cursor_p)
 527     printf " AVOID"
 528   end
 529   if ($g.left_box_line_p)
 530     printf " ["
 531   end
 532   if ($g.right_box_line_p)
 533     printf " ]"
 534   end
 535   if ($g.slice.img.x || $g.slice.img.y || $g.slice.img.width || $g.slice.img.height)
 536     printf " slice=%d,%d,%d,%d" ,$g.slice.img.x, $g.slice.img.y, $g.slice.img.width, $g.slice.img.height
 537   end
 538   printf "\n"
 539 end
 540 document pgx
 541 Pretty print a glyph structure.
 542 Takes one argument, a pointer to a glyph structure.
 543 end
 544
 545 define pg
 546   set $pgidx = 0
 547   pgx glyph
 548 end
 549 document pg
 550 Pretty print glyph structure glyph.
 551 end
 552
 553 define pgi
 554   set $pgidx = $arg0
 555   pgx (&glyph[$pgidx])
 556 end
 557 document pgi
 558 Pretty print glyph structure glyph[I].
 559 Takes one argument, a integer I.
 560 end
 561
 562 define pgn
 563   set $pgidx = $pgidx + 1
 564   pgx (&glyph[$pgidx])
 565 end
 566 document pgn
 567 Pretty print next glyph structure.
 568 end
 569
 570 define pgrowx
 571   set $row = $arg0
 572   set $area = 0
 573   set $xofs = $row->x
 574   while ($area < 3)
 575     set $used = $row->used[$area]
 576     if ($used > 0)
 577       set $gl0 = $row->glyphs[$area]
 578       set $pgidx = 0
 579       printf "%s: %d glyphs\n", ($area == 0 ? "LEFT" : $area == 2 ? "RIGHT" : "TEXT"), $used
 580       while ($pgidx < $used)
 581         printf "%3d %4d: ", $pgidx, $xofs
 582         pgx $gl0[$pgidx]
 583         set $xofs = $xofs + $gl0[$pgidx]->pixel_width
 584         set $pgidx = $pgidx + 1
 585       end
 586     end
 587     set $area = $area + 1
 588   end
 589 end
 590 document pgrowx
 591 Pretty print all glyphs in a row structure.
 592 Takes one argument, a pointer to a row structure.
 593 end
 594
 595 define pgrow
 596   pgrowx row
 597 end
 598 document pgrow
 599 Pretty print all glyphs in row structure row.
 600 end
 601
 602 define pgrowit
 603   pgrowx it->glyph_row
 604 end
 605 document pgrowit
 606 Pretty print all glyphs in it->glyph_row.
 607 end
 608
 609 define prowlims
 610   printf "edges=(%d,%d),r2l=%d,cont=%d,trunc=(%d,%d),at_zv=%d\n", $arg0->minpos.charpos, $arg0->maxpos.charpos, $arg0->reversed_p, $arg0->continued_p, $arg0->truncated_on_left_p, $arg0->truncated_on_right_p, $arg0->ends_at_zv_p
 611 end
 612 document prowlims
 613 Print important attributes of a glyph_row structure.
 614 Takes one argument, a pointer to a glyph_row structure.
 615 end
 616
 617 define pmtxrows
 618   set $mtx = $arg0
 619   set $gl = $mtx->rows
 620   set $glend = $mtx->rows + $mtx->nrows - 1
 621   set $i = 0
 622   while ($gl < $glend)
 623     printf "%d: ", $i
 624     prowlims $gl
 625     set $gl = $gl + 1
 626     set $i = $i + 1
 627   end
 628 end
 629 document pmtxrows
 630 Print data about glyph rows in a glyph matrix.
 631 Takes one argument, a pointer to a glyph_matrix structure.
 632 end
 633
 634 define xtype
 635   xgettype $
 636   output $type
 637   echo \n
 638   if $type == Lisp_Misc
 639     xmisctype
 640   else
 641     if $type == Lisp_Vectorlike
 642       xvectype
 643     end
 644   end
 645 end
 646 document xtype
 647 Print the type of $, assuming it is an Emacs Lisp value.
 648 If the first type printed is Lisp_Vector or Lisp_Misc,
 649 a second line gives the more precise type.
 650 end
 651
 652 define xvectype
 653   xgetptr $
 654   set $size = ((struct Lisp_Vector *) $ptr)->header.size
 655   if ($size & PSEUDOVECTOR_FLAG)
 656     output (enum pvec_type) (($size & PVEC_TYPE_MASK) >> PSEUDOVECTOR_SIZE_BITS)
 657   else
 658     output $size & ~ARRAY_MARK_FLAG
 659   end
 660   echo \n
 661 end
 662 document xvectype
 663 Print the size or vector subtype of $.
 664 This command assumes that $ is a vector or pseudovector.
 665 end
 666
 667 define xmisctype
 668   xgetptr $
 669   output (enum Lisp_Misc_Type) (((struct Lisp_Free *) $ptr)->type)
 670   echo \n
 671 end
 672 document xmisctype
 673 Assume that $ is some misc type and print its specific type.
 674 end
 675
 676 define xint
 677   xgetint $
 678   print $int
 679 end
 680 document xint
 681 Print $ as an Emacs Lisp integer.  This gets the sign right.
 682 end
 683
 684 define xptr
 685   xgetptr $
 686   print (void *) $ptr
 687 end
 688 document xptr
 689 Print the pointer portion of an Emacs Lisp value in $.
 690 end
 691
 692 define xmarker
 693   xgetptr $
 694   print (struct Lisp_Marker *) $ptr
 695 end
 696 document xmarker
 697 Print $ as a marker pointer.
 698 This command assumes that $ is an Emacs Lisp marker value.
 699 end
 700
 701 define xoverlay
 702   xgetptr $
 703   print (struct Lisp_Overlay *) $ptr
 704 end
 705 document xoverlay
 706 Print $ as a overlay pointer.
 707 This command assumes that $ is an Emacs Lisp overlay value.
 708 end
 709
 710 define xmiscfree
 711   xgetptr $
 712   print (struct Lisp_Free *) $ptr
 713 end
 714 document xmiscfree
 715 Print $ as a misc free-cell pointer.
 716 This command assumes that $ is an Emacs Lisp Misc value.
 717 end
 718
 719 define xsymbol
 720   set $sym = $
 721   xgetptr $sym
 722   print (struct Lisp_Symbol *) $ptr
 723   xprintsym $sym
 724   echo \n
 725 end
 726 document xsymbol
 727 Print the name and address of the symbol $.
 728 This command assumes that $ is an Emacs Lisp symbol value.
 729 end
 730
 731 define xstring
 732   xgetptr $
 733   print (struct Lisp_String *) $ptr
 734   xprintstr $
 735   echo \n
 736 end
 737 document xstring
 738 Print the contents and address of the string $.
 739 This command assumes that $ is an Emacs Lisp string value.
 740 end
 741
 742 define xvector
 743   xgetptr $
 744   print (struct Lisp_Vector *) $ptr
 745   output ($->header.size > 50) ? 0 : ($->contents[0])@($->header.size & ~ARRAY_MARK_FLAG)
 746 echo \n
 747 end
 748 document xvector
 749 Print the contents and address of the vector $.
 750 This command assumes that $ is an Emacs Lisp vector value.
 751 end
 752
 753 define xprocess
 754   xgetptr $
 755   print (struct Lisp_Process *) $ptr
 756   output *$
 757   echo \n
 758 end
 759 document xprocess
 760 Print the address of the struct Lisp_process to which $ points.
 761 This command assumes that $ is a Lisp_Object.
 762 end
 763
 764 define xframe
 765   xgetptr $
 766   print (struct frame *) $ptr
 767   xgetptr $->name
 768   set $ptr = (struct Lisp_String *) $ptr
 769   xprintstr $ptr
 770   echo \n
 771 end
 772 document xframe
 773 Print $ as a frame pointer.
 774 This command assumes $ is an Emacs Lisp frame value.
 775 end
 776
 777 define xcompiled
 778   xgetptr $
 779   print (struct Lisp_Vector *) $ptr
 780   output ($->contents[0])@($->header.size & 0xff)
 781 end
 782 document xcompiled
 783 Print $ as a compiled function pointer.
 784 This command assumes that $ is an Emacs Lisp compiled value.
 785 end
 786
 787 define xwindow
 788   xgetptr $
 789   print (struct window *) $ptr
 790   set $window = (struct window *) $ptr
 791   xgetint $window->total_cols
 792   set $width=$int
 793   xgetint $window->total_lines
 794   set $height=$int
 795   xgetint $window->left_col
 796   set $left=$int
 797   xgetint $window->top_line
 798   set $top=$int
 799   printf "%dx%d+%d+%d\n", $width, $height, $left, $top
 800 end
 801 document xwindow
 802 Print $ as a window pointer, assuming it is an Emacs Lisp window value.
 803 Print the window's position as "WIDTHxHEIGHT+LEFT+TOP".
 804 end
 805
 806 define xwinconfig
 807   xgetptr $
 808   print (struct save_window_data *) $ptr
 809 end
 810 document xwinconfig
 811 Print $ as a window configuration pointer.
 812 This command assumes that $ is an Emacs Lisp window configuration value.
 813 end
 814
 815 define xsubr
 816   xgetptr $
 817   print (struct Lisp_Subr *) $ptr
 818   output *$
 819   echo \n
 820 end
 821 document xsubr
 822 Print the address of the subr which the Lisp_Object $ points to.
 823 end
 824
 825 define xchartable
 826   xgetptr $
 827   print (struct Lisp_Char_Table *) $ptr
 828   printf "Purpose: "
 829   xprintsym $->purpose
 830   printf "  %d extra slots", ($->header.size & 0x1ff) - 68
 831   echo \n
 832 end
 833 document xchartable
 834 Print the address of the char-table $, and its purpose.
 835 This command assumes that $ is an Emacs Lisp char-table value.
 836 end
 837
 838 define xsubchartable
 839   xgetptr $
 840   print (struct Lisp_Sub_Char_Table *) $ptr
 841   xgetint $->depth
 842   set $depth = $int
 843   xgetint $->min_char
 844   printf "Depth: %d, Min char: %d (0x%x)\n", $depth, $int, $int
 845 end
 846 document xsubchartable
 847 Print the address of the sub-char-table $, its depth and min-char.
 848 This command assumes that $ is an Emacs Lisp sub-char-table value.
 849 end
 850
 851 define xboolvector
 852   xgetptr $
 853   print (struct Lisp_Bool_Vector *) $ptr
 854   output ($->size > 256) ? 0 : ($->data[0])@(($->size + BOOL_VECTOR_BITS_PER_CHAR - 1)/ BOOL_VECTOR_BITS_PER_CHAR)
 855   echo \n
 856 end
 857 document xboolvector
 858 Print the contents and address of the bool-vector $.
 859 This command assumes that $ is an Emacs Lisp bool-vector value.
 860 end
 861
 862 define xbuffer
 863   xgetptr $
 864   print (struct buffer *) $ptr
 865   xgetptr $->name_
 866   output ((struct Lisp_String *) $ptr)->data
 867   echo \n
 868 end
 869 document xbuffer
 870 Set $ as a buffer pointer and the name of the buffer.
 871 This command assumes $ is an Emacs Lisp buffer value.
 872 end
 873
 874 define xhashtable
 875   xgetptr $
 876   print (struct Lisp_Hash_Table *) $ptr
 877 end
 878 document xhashtable
 879 Set $ as a hash table pointer.
 880 This command assumes that $ is an Emacs Lisp hash table value.
 881 end
 882
 883 define xcons
 884   xgetptr $
 885   print (struct Lisp_Cons *) $ptr
 886   output/x *$
 887   echo \n
 888 end
 889 document xcons
 890 Print the contents of $ as an Emacs Lisp cons.
 891 end
 892
 893 define nextcons
 894   p $.u.cdr
 895   xcons
 896 end
 897 document nextcons
 898 Print the contents of the next cell in a list.
 899 This command assumes that the last thing you printed was a cons cell contents
 900 (type struct Lisp_Cons) or a pointer to one.
 901 end
 902 define xcar
 903   xgetptr $
 904   xgettype $
 905   print/x ($type == Lisp_Cons ? ((struct Lisp_Cons *) $ptr)->car : 0)
 906 end
 907 document xcar
 908 Assume that $ is an Emacs Lisp pair and print its car.
 909 end
 910
 911 define xcdr
 912   xgetptr $
 913   xgettype $
 914   print/x ($type == Lisp_Cons ? ((struct Lisp_Cons *) $ptr)->u.cdr : 0)
 915 end
 916 document xcdr
 917 Assume that $ is an Emacs Lisp pair and print its cdr.
 918 end
 919
 920 define xlist
 921   xgetptr $
 922   set $cons = (struct Lisp_Cons *) $ptr
 923   xgetptr Qnil
 924   set $nil = $ptr
 925   set $i = 0
 926   while $cons != $nil && $i < 10
 927     p/x $cons->car
 928     xpr
 929     xgetptr $cons->u.cdr
 930     set $cons = (struct Lisp_Cons *) $ptr
 931     set $i = $i + 1
 932     printf "---\n"
 933   end
 934   if $cons == $nil
 935     printf "nil\n"
 936   else
 937     printf "...\n"
 938     p $ptr
 939   end
 940 end
 941 document xlist
 942 Print $ assuming it is a list.
 943 end
 944
 945 define xfloat
 946   xgetptr $
 947   print ((struct Lisp_Float *) $ptr)->u.data
 948 end
 949 document xfloat
 950 Print $ assuming it is a lisp floating-point number.
 951 end
 952
 953 define xscrollbar
 954   xgetptr $
 955   print (struct scrollbar *) $ptr
 956 output *$
 957 echo \n
 958 end
 959 document xscrollbar
 960 Print $ as a scrollbar pointer.
 961 end
 962
 963 define xpr
 964   xtype
 965   if $type == Lisp_Int0 || $type == Lisp_Int1
 966     xint
 967   end
 968   if $type == Lisp_Symbol
 969     xsymbol
 970   end
 971   if $type == Lisp_String
 972     xstring
 973   end
 974   if $type == Lisp_Cons
 975     xcons
 976   end
 977   if $type == Lisp_Float
 978     xfloat
 979   end
 980   if $type == Lisp_Misc
 981     set $misc = (enum Lisp_Misc_Type) (((struct Lisp_Free *) $ptr)->type)
 982     if $misc == Lisp_Misc_Free
 983       xmiscfree
 984     end
 985     if $misc == Lisp_Misc_Marker
 986       xmarker
 987     end
 988     if $misc == Lisp_Misc_Overlay
 989       xoverlay
 990     end
 991 #    if $misc == Lisp_Misc_Save_Value
 992 #      xsavevalue
 993 #    end
 994   end
 995   if $type == Lisp_Vectorlike
 996     set $size = ((struct Lisp_Vector *) $ptr)->header.size
 997     if ($size & PSEUDOVECTOR_FLAG)
 998       set $vec = (enum pvec_type) (($size & PVEC_TYPE_MASK) >> PSEUDOVECTOR_SIZE_BITS)
 999       if $vec == PVEC_NORMAL_VECTOR
1000         xvector
1001       end
1002       if $vec == PVEC_PROCESS
1003         xprocess
1004       end
1005       if $vec == PVEC_FRAME
1006         xframe
1007       end
1008       if $vec == PVEC_COMPILED
1009         xcompiled
1010       end
1011       if $vec == PVEC_WINDOW
1012         xwindow
1013       end
1014       if $vec == PVEC_WINDOW_CONFIGURATION
1015         xwinconfig
1016       end
1017       if $vec == PVEC_SUBR
1018         xsubr
1019       end
1020       if $vec == PVEC_CHAR_TABLE
1021         xchartable
1022       end
1023       if $vec == PVEC_BOOL_VECTOR
1024         xboolvector
1025       end
1026       if $vec == PVEC_BUFFER
1027         xbuffer
1028       end
1029       if $vec == PVEC_HASH_TABLE
1030         xhashtable
1031       end
1032     else
1033       xvector
1034     end
1035   end
1036 end
1037 document xpr
1038 Print $ as a lisp object of any type.
1039 end
1040
1041 define xprintstr
1042   set $data = (char *) $arg0->data
1043   output ($arg0->size > 1000) ? 0 : ($data[0])@($arg0->size_byte < 0 ? $arg0->size & ~ARRAY_MARK_FLAG : $arg0->size_byte)
1044 end
1045
1046 define xprintsym
1047   xgetptr $arg0
1048   set $sym = (struct Lisp_Symbol *) $ptr
1049   xgetptr $sym->name
1050   set $sym_name = (struct Lisp_String *) $ptr
1051   xprintstr $sym_name
1052 end
1053 document xprintsym
1054   Print argument as a symbol.
1055 end
1056
1057 define xcoding
1058   set $tmp = (struct Lisp_Hash_Table *) ((Vcoding_system_hash_table & VALMASK) | DATA_SEG_BITS)
1059   set $tmp = (struct Lisp_Vector *) (($tmp->key_and_value & VALMASK) | DATA_SEG_BITS)
1060   set $name = $tmp->contents[$arg0 * 2]
1061   print $name
1062   pr
1063   print $tmp->contents[$arg0 * 2 + 1]
1064   pr
1065 end
1066 document xcoding
1067   Print the name and attributes of coding system that has ID (argument).
1068 end
1069
1070 define xcharset
1071   set $tmp = (struct Lisp_Hash_Table *) ((Vcharset_hash_table & VALMASK) | DATA_SEG_BITS)
1072   set $tmp = (struct Lisp_Vector *) (($tmp->key_and_value & VALMASK) | DATA_SEG_BITS)
1073   p $tmp->contents[charset_table[$arg0].hash_index * 2]
1074   pr
1075 end
1076 document xcharset
1077   Print the name of charset that has ID (argument).
1078 end
1079
1080 define xfontset
1081   xgetptr $
1082   set $tbl = (struct Lisp_Char_Table *) $ptr
1083   print $tbl
1084   xgetint $tbl->extras[0]
1085   printf " ID:%d", $int
1086   xgettype $tbl->extras[1]
1087   xgetptr $tbl->extras[1]
1088   if $type == Lisp_String
1089     set $ptr = (struct Lisp_String *) $ptr
1090     printf " Name:"
1091     xprintstr $ptr
1092   else
1093     xgetptr $tbl->extras[2]
1094     set $ptr = (struct Lisp_Char_Table *) $ptr
1095     xgetptr $ptr->extras[1]
1096     set $ptr = (struct Lisp_String *) $ptr
1097     printf " Realized from:"
1098     xprintstr $ptr
1099   end
1100   echo \n
1101 end
1102
1103 define xfont
1104   xgetptr $
1105   set $size = (((struct Lisp_Vector *) $ptr)->header.size & 0x1FF)
1106   if $size == FONT_SPEC_MAX
1107     print (struct font_spec *) $ptr
1108   else
1109     if $size == FONT_ENTITY_MAX
1110       print (struct font_entity *) $ptr
1111     else
1112       print (struct font *) $ptr
1113     end
1114   end
1115 end
1116 document xfont
1117 Print $ assuming it is a list font (font-spec, font-entity, or font-object).
1118 end
1119
1120 define xbacktrace
1121   set $bt = backtrace_list
1122   while $bt
1123     xgettype ($bt->function)
1124     if $type == Lisp_Symbol
1125       xprintsym ($bt->function)
1126       printf " (0x%x)\n", $bt->args
1127     else
1128       xgetptr $bt->function
1129       printf "0x%x ", $ptr
1130       if $type == Lisp_Vectorlike
1131         xgetptr ($bt->function)
1132         set $size = ((struct Lisp_Vector *) $ptr)->header.size
1133         if ($size & PSEUDOVECTOR_FLAG)
1134           output (enum pvec_type) (($size & PVEC_TYPE_MASK) >> PSEUDOVECTOR_SIZE_BITS)
1135         else
1136           output $size & ~ARRAY_MARK_FLAG
1137         end
1138       else
1139         printf "Lisp type %d", $type
1140       end
1141       echo \n
1142     end
1143     set $bt = $bt->next
1144   end
1145 end
1146 document xbacktrace
1147   Print a backtrace of Lisp function calls from backtrace_list.
1148   Set a breakpoint at Fsignal and call this to see from where
1149   an error was signaled.
1150 end
1151
1152 define xprintbytestr
1153   set $data = (char *) $arg0->data
1154   printf "Bytecode: "
1155   output/u ($arg0->size > 1000) ? 0 : ($data[0])@($arg0->size_byte < 0 ? $arg0->size & ~ARRAY_MARK_FLAG : $arg0->size_byte)
1156 end
1157 document xprintbytestr
1158   Print a string of byte code.
1159 end
1160
1161 define xwhichsymbols
1162   set $output_debug = print_output_debug_flag
1163   set print_output_debug_flag = 0
1164   call safe_debug_print (which_symbols ($arg0, $arg1))
1165   set print_output_debug_flag = $output_debug
1166 end
1167 document xwhichsymbols
1168   Print symbols which references a given lisp object
1169   either as its symbol value or symbol function.
1170   Call with two arguments: the lisp object and the
1171   maximum number of symbols referencing it to produce.
1172 end
1173
1174 define xbytecode
1175   set $bt = byte_stack_list
1176   while $bt
1177     xgetptr $bt->byte_string
1178     set $ptr = (struct Lisp_String *) $ptr
1179     xprintbytestr $ptr
1180     printf "\n0x%x => ", $bt->byte_string
1181     xwhichsymbols $bt->byte_string 5
1182     set $bt = $bt->next
1183   end
1184 end
1185 document xbytecode
1186   Print a backtrace of the byte code stack.
1187 end
1188
1189 # Show Lisp backtrace after normal backtrace.
1190 define hookpost-backtrace
1191   set $bt = backtrace_list
1192   if $bt
1193     echo \n
1194     echo Lisp Backtrace:\n
1195     xbacktrace
1196   end
1197 end
1198
1199 # Flush display (X only)
1200 define ff
1201   set x_flush (0)
1202 end
1203 document ff
1204 Flush pending X window display updates to screen.
1205 Works only when an inferior emacs is executing.
1206 end
1207
1208
1209 set print pretty on
1210 set print sevenbit-strings
1211
1212 show environment DISPLAY
1213 show environment TERM
1214
1215 # When debugging, it is handy to be able to "return" from
1216 # terminate_due_to_signal when an assertion failure is non-fatal.
1217 break terminate_due_to_signal
1218
1219 # x_error_quitter is defined only on X.  But window-system is set up
1220 # only at run time, during Emacs startup, so we need to defer setting
1221 # the breakpoint.  init_sys_modes is the first function called on
1222 # every platform after init_display, where window-system is set.
1223 tbreak init_sys_modes
1224 commands
1225   silent
1226   xgetptr globals.f_Vinitial_window_system
1227   set $tem = (struct Lisp_Symbol *) $ptr
1228   xgetptr $tem->name
1229   set $tem = (struct Lisp_String *) $ptr
1230   set $tem = (char *) $tem->data
1231   # If we are running in synchronous mode, we want a chance to look
1232   # around before Emacs exits.  Perhaps we should put the break
1233   # somewhere else instead...
1234   if $tem[0] == 'x' && $tem[1] == '\0'
1235     break x_error_quitter
1236   end
1237   continue
1238 end