configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010, 2011
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.65)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  49 dnl Create a new --with option that defaults to being disabled.
  50 dnl NAME is the base name of the option.  The shell variable with_NAME
  51 dnl   will be set to either the user's value (if the option is
  52 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  53 dnl   option is not specified).  Note that the shell variable name is
  54 dnl   constructed as autoconf does, by replacing non-alphanumeric
  55 dnl   characters with "_".
  56 dnl HELP-STRING is the help text for the option.
  57 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  58   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  59     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  60 ])dnl
  61
  62 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  63 dnl Create a new --with option that defaults to being enabled.  NAME
  64 dnl   is the base name of the option.  The shell variable with_NAME
  65 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  66 dnl   'yes' (if the option is not specified).  Note that the shell
  67 dnl   variable name is constructed as autoconf does, by replacing
  68 dnl   non-alphanumeric characters with "_".
  69 dnl HELP-STRING is the help text for the option.
  70 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  71   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  72    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  73 ])dnl
  74
  75 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  76 if test "$with_pop" = yes; then
  77    AC_DEFINE(MAIL_USE_POP)
  78 fi
  79 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  80
  81 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  82 if test "$with_kerberos" != no; then
  83    AC_DEFINE(KERBEROS)
  84 fi
  85 AH_TEMPLATE(KERBEROS,
  86             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  87
  88 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  89 if test "${with_kerberos5}" != no; then
  90   if test "${with_kerberos}" = no; then
  91     with_kerberos=yes
  92     AC_DEFINE(KERBEROS)
  93   fi
  94   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  95 fi
  96
  97 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  98 dnl FIXME hesiod support may not be present, so it seems like an error
  99 dnl to define, or at least use, this unconditionally.
 100 if test "$with_hesiod" != no; then
 101   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 102 fi
 103
 104 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 105 if test "$with_mmdf" != no; then
 106    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 107 fi
 108
 109 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 110 if test "$with_mail_unlink" != no; then
 111    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 112 fi
 113
 114 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 115     [string giving default POP mail host])],
 116     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 117
 118 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 119
 120 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 121 if test "$with_sync_input" = yes; then
 122    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 123 fi
 124
 125 dnl FIXME currently it is not the last.
 126 dnl This should be the last --with option, because --with-x is
 127 dnl added later on when we find the path of X, and it's best to
 128 dnl keep them together visually.
 129 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 130  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 131 [         case "${withval}" in
 132             y | ye | yes )      val=gtk ;;
 133             n | no )            val=no  ;;
 134             l | lu | luc | luci | lucid )       val=lucid ;;
 135             a | at | ath | athe | athen | athena )      val=athena ;;
 136             m | mo | mot | moti | motif )       val=motif ;;
 137             g | gt | gtk  )     val=gtk ;;
 138             gtk3  )     val=gtk3 ;;
 139             * )
 140 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 141 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 142 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 143             ;;
 144           esac
 145           with_x_toolkit=$val
 146 ])
 147
 148 dnl _ON results in a '--without' option in the --help output, so
 149 dnl the help text should refer to "don't compile", etc.
 150 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 151 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 152 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 153 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 154 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 155 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 156 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 157 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 158
 159 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 160 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 161 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 162
 163 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 164 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 165 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 166 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 167
 168 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 169 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 170 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 171 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 172 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 173
 174 ## For the times when you want to build Emacs but don't have
 175 ## a suitable makeinfo, and can live without the manuals.
 176 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 177 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 178
 179 ## This is an option because I do not know if all info/man support
 180 ## compressed files, nor how to test if they do so.
 181 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 182 if test $with_compress_info = yes; then
 183    GZIP_INFO=yes
 184 else
 185    GZIP_INFO=
 186 fi
 187 AC_SUBST(GZIP_INFO)
 188
 189 AC_ARG_WITH([pkg-config-prog],dnl
 190 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 191                   [path to pkg-config for finding GTK and librsvg])])
 192 if test "X${with_pkg_config_prog}" != X; then
 193    if test "${with_pkg_config_prog}" != yes; then
 194       PKG_CONFIG="${with_pkg_config_prog}"
 195    fi
 196 fi
 197
 198 CRT_DIR=
 199 AC_ARG_WITH([crt-dir],dnl
 200 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 201 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 202 CRT_DIR="${with_crt_dir}"
 203
 204 AC_ARG_WITH(gameuser,dnl
 205 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 206 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 207   && gameuser="${with_gameuser}"
 208 test "X$gameuser" = X && gameuser=games
 209
 210 AC_ARG_WITH([gnustep-conf],dnl
 211 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 212 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 213   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 214 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 215      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 216
 217 AC_ARG_ENABLE(ns-self-contained,
 218 [AS_HELP_STRING([--disable-ns-self-contained],
 219                 [disable self contained build under NeXTstep])],
 220    EN_NS_SELF_CONTAINED=$enableval,
 221    EN_NS_SELF_CONTAINED=yes)
 222
 223 AC_ARG_ENABLE(asserts,
 224 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 225       USE_XASSERTS=$enableval,
 226       USE_XASSERTS=no)
 227
 228 AC_ARG_ENABLE(maintainer-mode,
 229 [AS_HELP_STRING([--enable-maintainer-mode],
 230                 [enable make rules and dependencies not useful (and sometimes
 231                  confusing) to the casual installer])],
 232       USE_MAINTAINER_MODE=$enableval,
 233       USE_MAINTAINER_MODE=no)
 234 if test $USE_MAINTAINER_MODE = yes; then
 235   MAINT=
 236 else
 237   MAINT=#
 238 fi
 239 AC_SUBST(MAINT)
 240
 241 AC_ARG_ENABLE(locallisppath,
 242 [AS_HELP_STRING([--enable-locallisppath=PATH],
 243                 [directories Emacs should search for lisp files specific
 244                  to this site])],
 245 if test "${enableval}" = "no"; then
 246   locallisppath=
 247 elif test "${enableval}" != "yes"; then
 248   locallisppath=${enableval}
 249 fi)
 250
 251 AC_ARG_ENABLE(checking,
 252 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 253                 [enable expensive run-time checks.  With LIST,
 254                  enable only specific categories of checks.
 255                  Categories are: all,yes,no.
 256                  Flags are: stringbytes, stringoverrun, stringfreelist,
 257                  xmallocoverrun, conslist])],
 258 [ac_checking_flags="${enableval}"],[])
 259 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 260 for check in $ac_checking_flags
 261 do
 262         case $check in
 263         # these set all the flags to specific states
 264         yes)            ac_enable_checking=1 ;;
 265         no)             ac_enable_checking= ;
 266                         ac_gc_check_stringbytes= ;
 267                         ac_gc_check_string_overrun= ;
 268                         ac_gc_check_string_free_list= ;
 269                         ac_xmalloc_overrun= ;
 270                         ac_gc_check_cons_list= ;;
 271         all)            ac_enable_checking=1 ;
 272                         ac_gc_check_stringbytes=1 ;
 273                         ac_gc_check_string_overrun=1 ;
 274                         ac_gc_check_string_free_list=1 ;
 275                         ac_xmalloc_overrun=1 ;
 276                         ac_gc_check_cons_list=1 ;;
 277         # these enable particular checks
 278         stringbytes)    ac_gc_check_stringbytes=1 ;;
 279         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 280         stringfreelist) ac_gc_check_string_free_list=1 ;;
 281         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 282         conslist)       ac_gc_check_cons_list=1 ;;
 283         *)      AC_MSG_ERROR(unknown check category $check) ;;
 284         esac
 285 done
 286 IFS="$ac_save_IFS"
 287
 288 if test x$ac_enable_checking != x ; then
 289   AC_DEFINE(ENABLE_CHECKING, 1,
 290 [Enable expensive run-time checking of data types?])
 291 fi
 292 if test x$ac_gc_check_stringbytes != x ; then
 293   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 294 [Define this temporarily to hunt a bug.  If defined, the size of
 295    strings is redundantly recorded in sdata structures so that it can
 296    be compared to the sizes recorded in Lisp strings.])
 297 fi
 298 if test x$ac_gc_check_stringoverrun != x ; then
 299   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 300 [Define this to check for short string overrun.])
 301 fi
 302 if test x$ac_gc_check_string_free_list != x ; then
 303   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 304 [Define this to check the string free list.])
 305 fi
 306 if test x$ac_xmalloc_overrun != x ; then
 307   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 308 [Define this to check for malloc buffer overrun.])
 309 fi
 310 if test x$ac_gc_check_cons_list != x ; then
 311   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 312 [Define this to check for errors in cons list.])
 313 fi
 314
 315 AC_ARG_ENABLE(use-lisp-union-type,
 316 [AS_HELP_STRING([--enable-use-lisp-union-type],
 317                 [use a union for the Lisp_Object data type.
 318                 This is only useful for development for catching certain types of bugs.])],
 319 if test "${enableval}" != "no"; then
 320    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 321    [Define this to use a lisp union for the Lisp_Object data type.])
 322 fi)
 323
 324
 325 AC_ARG_ENABLE(profiling,
 326 [AS_HELP_STRING([--enable-profiling],
 327                 [build emacs with profiling support.
 328                  This might not work on all platforms])],
 329 [ac_enable_profiling="${enableval}"],[])
 330 if test x$ac_enable_profiling != x ; then
 331    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 332 else
 333    PROFILING_CFLAGS=
 334 fi
 335 AC_SUBST(PROFILING_CFLAGS)
 336
 337 AC_ARG_ENABLE(autodepend,
 338 [AS_HELP_STRING([--enable-autodepend],
 339                 [automatically generate dependencies to .h-files.
 340                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 341                  found])],
 342 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 343
 344 #### Make srcdir absolute, if it isn't already.  It's important to
 345 #### avoid running the path through pwd unnecessarily, since pwd can
 346 #### give you automounter prefixes, which can go away.  We do all this
 347 #### so Emacs can find its files when run uninstalled.
 348 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 349 unset CDPATH
 350 case "${srcdir}" in
 351   /* ) ;;
 352   . )
 353     ## We may be able to use the $PWD environment variable to make this
 354     ## absolute.  But sometimes PWD is inaccurate.
 355     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 356     ## but that tested only for a well-formed and valid PWD,
 357     ## it did not object when PWD was well-formed and valid but just wrong.
 358     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 359     then
 360       srcdir="$PWD"
 361     else
 362       srcdir="`(cd ${srcdir}; pwd)`"
 363     fi
 364   ;;
 365   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 366 esac
 367
 368 #### Check if the source directory already has a configured system in it.
 369 if test `pwd` != `(cd ${srcdir} && pwd)` \
 370    && test -f "${srcdir}/src/config.h" ; then
 371   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 372    as a build directory right now; it has been configured in its own
 373    right.  To configure in another directory as well, you MUST
 374    use GNU make.  If you do not have GNU make, then you must
 375    now do `make distclean' in ${srcdir},
 376    and then run $0 again.]])
 377 fi
 378
 379 #### Given the configuration name, set machfile and opsysfile to the
 380 #### names of the m/*.h and s/*.h files we should use.
 381
 382 ### Canonicalize the configuration name.
 383
 384 AC_CANONICAL_HOST
 385 canonical=$host
 386 configuration=${host_alias-${build_alias-$host}}
 387
 388 dnl This used to use changequote, but, apart from `changequote is evil'
 389 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 390 dnl the great gob of text.  Thus it's not processed for possible expansion.
 391 dnl Just make sure the brackets remain balanced.
 392 dnl
 393 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 394 dnl indicated by comments.
 395 dnl quotation begins
 396 [
 397
 398 ### If you add support for a new configuration, add code to this
 399 ### switch statement to recognize your configuration name and select
 400 ### the appropriate operating system and machine description files.
 401
 402 ### You would hope that you could choose an m/*.h file pretty much
 403 ### based on the machine portion of the configuration name, and an s/*.h
 404 ### file based on the operating system portion.  However, it turns out
 405 ### that each m/*.h file is pretty manufacturer-specific - for
 406 ### example mips.h is MIPS
 407 ### So we basically have to have a special case for each
 408 ### configuration name.
 409 ###
 410 ### As far as handling version numbers on operating systems is
 411 ### concerned, make sure things will fail in a fixable way.  If
 412 ### /etc/MACHINES doesn't say anything about version numbers, be
 413 ### prepared to handle anything reasonably.  If version numbers
 414 ### matter, be sure /etc/MACHINES says something about it.
 415
 416 machine='' opsys='' unported=no
 417 case "${canonical}" in
 418
 419   ## GNU/Linux ports
 420   *-*-linux-gnu*)
 421     opsys=gnu-linux
 422     case ${canonical} in
 423       alpha*)   machine=alpha ;;
 424       s390-*)   machine=ibms390 ;;
 425       s390x-*)  machine=ibms390x ;;
 426       powerpc*) machine=macppc ;;
 427       sparc*)   machine=sparc ;;
 428       ia64*)    machine=ia64 ;;
 429       m68k*)    machine=m68k ;;
 430       x86_64*)  machine=amdx86-64 ;;
 431     esac
 432   ;;
 433
 434   ## FreeBSD ports
 435   *-*-freebsd* )
 436     opsys=freebsd
 437     case "${canonical}" in
 438       alpha*)           machine=alpha ;;
 439       amd64-*|x86_64-*) machine=amdx86-64 ;;
 440       ia64-*)           machine=ia64 ;;
 441       i[3456]86-*)      machine=intel386 ;;
 442       powerpc-*)        machine=macppc ;;
 443       sparc-*)          machine=sparc ;;
 444       sparc64-*)        machine=sparc ;;
 445     esac
 446   ;;
 447
 448   ## FreeBSD kernel + glibc based userland
 449   *-*-kfreebsd*gnu* )
 450     opsys=gnu-kfreebsd
 451     case "${canonical}" in
 452       alpha*)           machine=alpha ;;
 453       amd64-*|x86_64-*) machine=amdx86-64 ;;
 454       ia64-*)           machine=ia64 ;;
 455       i[3456]86-*)      machine=intel386 ;;
 456       powerpc-*)        machine=macppc ;;
 457       sparc-*)          machine=sparc ;;
 458       sparc64-*)        machine=sparc ;;
 459     esac
 460   ;;
 461
 462   ## NetBSD ports
 463   *-*-netbsd* )
 464     opsys=netbsd
 465     case "${canonical}" in
 466       alpha*)      machine=alpha ;;
 467       x86_64-*)    machine=amdx86-64 ;;
 468       i[3456]86-*) machine=intel386 ;;
 469       m68k-*)      machine=m68k ;;
 470       powerpc-*)   machine=macppc ;;
 471       sparc*-)     machine=sparc ;;
 472       vax-*)       machine=vax ;;
 473     esac
 474   ;;
 475
 476   ## OpenBSD ports
 477   *-*-openbsd* )
 478     opsys=openbsd
 479     case "${canonical}" in
 480       alpha*)    machine=alpha ;;
 481       x86_64-*)  machine=amdx86-64 ;;
 482       i386-*)    machine=intel386 ;;
 483       powerpc-*) machine=macppc ;;
 484       sparc*)    machine=sparc ;;
 485       vax-*)     machine=vax ;;
 486     esac
 487   ;;
 488
 489   ## Apple Darwin / Mac OS X
 490   *-apple-darwin* )
 491     case "${canonical}" in
 492       i[3456]86-* )  machine=intel386 ;;
 493       powerpc-* )    machine=macppc ;;
 494       x86_64-* )     machine=amdx86-64 ;;
 495       * )            unported=yes ;;
 496     esac
 497     opsys=darwin
 498     # Define CPP as follows to make autoconf work correctly.
 499     CPP="${CC-cc} -E -no-cpp-precomp"
 500     # Use fink packages if available.
 501     if test -d /sw/include && test -d /sw/lib; then
 502       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 503       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 504       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 505     fi
 506   ;;
 507
 508   ## HP 9000 series 700 and 800, running HP/UX
 509   hppa*-hp-hpux10.2* )
 510     opsys=hpux10-20
 511   ;;
 512   hppa*-hp-hpux1[1-9]* )
 513     opsys=hpux11
 514     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 515   ;;
 516
 517   ## IBM machines
 518   rs6000-ibm-aix4.[23]* )
 519     machine=ibmrs6000 opsys=aix4-2
 520   ;;
 521   powerpc-ibm-aix4.[23]*  )
 522     machine=ibmrs6000 opsys=aix4-2
 523   ;;
 524   rs6000-ibm-aix[56]* )
 525     machine=ibmrs6000 opsys=aix4-2
 526   ;;
 527   powerpc-ibm-aix[56]*  )
 528     machine=ibmrs6000 opsys=aix4-2
 529   ;;
 530
 531   ## Silicon Graphics machines
 532   ## Iris 4D
 533   mips-sgi-irix6.5 )
 534     machine=iris4d opsys=irix6-5
 535     # Without defining _LANGUAGE_C, things get masked out in the headers
 536     # so that, for instance, grepping for `free' in stdlib.h fails and
 537     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 538     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 539     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 540   ;;
 541
 542   ## Suns
 543   *-sun-solaris* \
 544     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 545     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 546     case "${canonical}" in
 547       i[3456]86-*-* )     machine=intel386 ;;
 548       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 549       sparc* )          machine=sparc ;;
 550       * )               unported=yes ;;
 551     esac
 552     case "${canonical}" in
 553       *-sunos5.6* | *-solaris2.6* )
 554                 opsys=sol2-6
 555                 NON_GNU_CPP=/usr/ccs/lib/cpp
 556                 RANLIB="ar -ts"
 557                 ;;
 558       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 559                 opsys=sol2-6
 560                 emacs_check_sunpro_c=yes
 561                 NON_GNU_CPP=/usr/ccs/lib/cpp
 562                 ;;
 563       *-sunos5* | *-solaris* )
 564                 opsys=sol2-10
 565                 emacs_check_sunpro_c=yes
 566                 NON_GNU_CPP=/usr/ccs/lib/cpp
 567                 ;;
 568     esac
 569     ## Watch out for a compiler that we know will not work.
 570     case "${canonical}" in
 571      *-solaris* | *-sunos5* )
 572                 if [ "x$CC" = x/usr/ucb/cc ]; then
 573                   ## /usr/ucb/cc doesn't work;
 574                   ## we should find some other compiler that does work.
 575                   unset CC
 576                 fi
 577                 ;;
 578       *) ;;
 579     esac
 580   ;;
 581
 582   ## Intel 386 machines where we don't care about the manufacturer.
 583   i[3456]86-*-* )
 584     machine=intel386
 585     case "${canonical}" in
 586       *-cygwin )                opsys=cygwin ;;
 587       *-darwin* )               opsys=darwin
 588                                 CPP="${CC-cc} -E -no-cpp-precomp"
 589                                 ;;
 590       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 591       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 592       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 593       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 594     esac
 595   ;;
 596
 597   * )
 598     unported=yes
 599   ;;
 600 esac
 601
 602 ### If the code above didn't choose an operating system, just choose
 603 ### an operating system based on the configuration name.  You really
 604 ### only want to use this when you have no idea what the right
 605 ### operating system is; if you know what operating systems a machine
 606 ### runs, it's cleaner to make it explicit in the case statement
 607 ### above.
 608 if test x"${opsys}" = x; then
 609   case "${canonical}" in
 610     *-gnu* )                            opsys=gnu ;;
 611     * )
 612       unported=yes
 613     ;;
 614   esac
 615 fi
 616
 617 ]
 618 dnl quotation ends
 619
 620 if test $unported = yes; then
 621   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 622 Check `etc/MACHINES' for recognized configuration names.])
 623 fi
 624
 625 if test -n "$machine"; then
 626   machfile="m/${machine}.h"
 627 else
 628   machfile=
 629 fi
 630 opsysfile="s/${opsys}.h"
 631
 632
 633 #### Choose a compiler.
 634 test -n "$CC" && cc_specified=yes
 635
 636 # Save the value of CFLAGS that the user specified.
 637 SPECIFIED_CFLAGS="$CFLAGS"
 638
 639 dnl Sets GCC=yes if using gcc.
 640 AC_PROG_CC
 641
 642 # On Suns, sometimes $CPP names a directory.
 643 if test -n "$CPP" && test -d "$CPP"; then
 644   CPP=
 645 fi
 646
 647 ## If not using gcc, and on Solaris, and no CPP specified, see if
 648 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 649 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 650  test x"$CPP" = x; then
 651   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 652   AC_CACHE_VAL(emacs_cv_sunpro_c,
 653   [AC_TRY_LINK([],
 654 [#ifndef __SUNPRO_C
 655 fail;
 656 #endif
 657 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 658   AC_MSG_RESULT($emacs_cv_sunpro_c)
 659
 660   if test x"$emacs_cv_sunpro_c" = xyes; then
 661     NON_GNU_CPP="$CC -E -Xs"
 662   fi
 663 fi
 664
 665 #### Some systems specify a CPP to use unless we are using GCC.
 666 #### Now that we know whether we are using GCC, we can decide whether
 667 #### to use that one.
 668 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 669 then
 670   CPP="$NON_GNU_CPP"
 671 fi
 672
 673 #### Some systems specify a CC to use unless we are using GCC.
 674 #### Now that we know whether we are using GCC, we can decide whether
 675 #### to use that one.
 676 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 677   test x$cc_specified != xyes
 678 then
 679   CC="$NON_GNU_CC"
 680 fi
 681
 682 if test x$GCC = xyes; then
 683   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 684 else
 685   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 686 fi
 687
 688 dnl checks for Unix variants
 689 AC_USE_SYSTEM_EXTENSIONS
 690
 691 ### Use -Wno-pointer-sign if the compiler supports it
 692 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 693 SAVE_CFLAGS="$CFLAGS"
 694 CFLAGS="$CFLAGS -Wno-pointer-sign"
 695 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 696 if test $has_option = yes; then
 697    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 698 fi
 699 AC_MSG_RESULT($has_option)
 700 CFLAGS="$SAVE_CFLAGS"
 701 unset has_option
 702 unset SAVE_CFLAGS
 703
 704 ### Use -Wdeclaration-after-statement if the compiler supports it
 705 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 706 SAVE_CFLAGS="$CFLAGS"
 707 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 708 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 709 if test $has_option = yes; then
 710    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 711 fi
 712 AC_MSG_RESULT($has_option)
 713 CFLAGS="$SAVE_CFLAGS"
 714 unset has_option
 715 unset SAVE_CFLAGS
 716
 717 ### Use -Wold-style-definition if the compiler supports it
 718 # This can be removed when conversion to standard C is finished.
 719 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 720 SAVE_CFLAGS="$CFLAGS"
 721 CFLAGS="$CFLAGS -Wold-style-definition"
 722 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 723 if test $has_option = yes; then
 724    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 725 fi
 726 AC_MSG_RESULT($has_option)
 727 CFLAGS="$SAVE_CFLAGS"
 728 unset has_option
 729 unset SAVE_CFLAGS
 730
 731 ### Use -Wimplicit-function-declaration if the compiler supports it
 732 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 733 SAVE_CFLAGS="$CFLAGS"
 734 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 735 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 736 if test $has_option = yes; then
 737    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 738 fi
 739 AC_MSG_RESULT($has_option)
 740 CFLAGS="$SAVE_CFLAGS"
 741 unset has_option
 742 unset SAVE_CFLAGS
 743
 744 AC_SUBST(C_WARNINGS_SWITCH)
 745
 746
 747 #### Some other nice autoconf tests.
 748
 749 dnl checks for programs
 750 AC_PROG_CPP
 751 AC_PROG_INSTALL
 752 if test "x$RANLIB" = x; then
 753   AC_PROG_RANLIB
 754 fi
 755
 756 ## Although we're running on an amd64 kernel, we're actually compiling for
 757 ## the x86 architecture.  The user should probably have provided an
 758 ## explicit --build to `configure', but if everything else than the kernel
 759 ## is running in i386 mode, we can help them out.
 760 if test "$machine" = "amdx86-64"; then
 761   AC_CHECK_DECL([i386])
 762   if test "$ac_cv_have_decl_i386" = "yes"; then
 763     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 764     machine=intel386
 765     machfile="m/${machine}.h"
 766   fi
 767 fi
 768
 769 AC_PATH_PROG(INSTALL_INFO, install-info)
 770 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 771 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 772 dnl Don't use GZIP, which is used by gzip for additional parameters.
 773 AC_PATH_PROG(GZIP_PROG, gzip)
 774
 775
 776 ## Need makeinfo >= 4.6 (?) to build the manuals.
 777 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 778 dnl By this stage, configure has already checked for egrep and set EGREP,
 779 dnl or exited with an error if no egrep was found.
 780 if test "$MAKEINFO" != "no" && \
 781   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 782    MAKEINFO=no
 783 fi
 784
 785 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 786 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 787 ## therefore in the category of "special tools" not normally required, which
 788 ## configure does not have to check for (eg autoconf itself).
 789 ## In a Bazaar checkout on the other hand, the manuals are not included.
 790 ## So makeinfo is a requirement to build from Bazaar, and configure
 791 ## should test for it as it does for any other build requirement.
 792 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 793 ## with pre-built manuals, from a Bazaar checkout.
 794 HAVE_MAKEINFO=yes
 795
 796 if test "$MAKEINFO" = "no"; then
 797   MAKEINFO=makeinfo
 798   if test "x${with_makeinfo}" = "xno"; then
 799     HAVE_MAKEINFO=no
 800   elif test ! -e $srcdir/info/emacs; then
 801     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 802 source tree does not seem to have pre-built manuals in the `info' directory.
 803 Either install a suitable version of makeinfo, or re-run configure
 804 with the `--without-makeinfo' option to build without the manuals.] )
 805   fi
 806 fi
 807 AC_SUBST(HAVE_MAKEINFO)
 808
 809 dnl Add our options to ac_link now, after it is set up.
 810
 811 if test x$GCC = xyes; then
 812   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 813     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 814 else
 815   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 816     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 817 fi
 818
 819 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 820 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 821 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 822 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 823 dnl if not built to support GNU ld.
 824
 825 late_LDFLAGS=$LDFLAGS
 826 if test x$GCC = xyes; then
 827   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 828 else
 829   LDFLAGS="$LDFLAGS -znocombreloc"
 830 fi
 831
 832 AC_MSG_CHECKING([for -znocombreloc])
 833 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 834   [AC_MSG_RESULT(yes)],
 835   LDFLAGS=$late_LDFLAGS
 836   [AC_MSG_RESULT(no)])
 837
 838
 839 # The value of CPP is a quoted variable reference, so we need to do this
 840 # to get its actual value...
 841 CPP=`eval "echo $CPP"`
 842
 843
 844 dnl Not used by any currently supported platform.
 845 dnl The function dump-emacs will not be defined and temacs will do
 846 dnl (load "loadup") automatically unless told otherwise.
 847 CANNOT_DUMP=no
 848 case "$opsys" in
 849   your-opsys-here)
 850    CANNOT_DUMP=yes
 851    AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 852   ;;
 853 esac
 854 AC_SUBST(CANNOT_DUMP)
 855
 856
 857 UNEXEC_OBJ=unexelf.o
 858 case "$opsys" in
 859   # MSDOS uses unexcoff.o
 860   # MSWindows uses unexw32.o
 861   aix4-2)
 862    UNEXEC_OBJ=unexaix.o
 863    ;;
 864   cygwin)
 865    UNEXEC_OBJ=unexcw.o
 866    ;;
 867   darwin)
 868    UNEXEC_OBJ=unexmacosx.o
 869    ;;
 870   hpux10-20 | hpux11)
 871    UNEXEC_OBJ=unexhp9k800.o
 872    ;;
 873   sol2-10)
 874    # Use the Solaris dldump() function, called from unexsol.c, to dump
 875    # emacs, instead of the generic ELF dump code found in unexelf.c.
 876    # The resulting binary has a complete symbol table, and is better
 877    # for debugging and other observability tools (debuggers, pstack, etc).
 878    #
 879    # If you encounter a problem using dldump(), please consider sending
 880    # a message to the OpenSolaris tools-linking mailing list:
 881    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 882    #
 883    # It is likely that dldump() works with older Solaris too, but this has
 884    # not been tested, so for now this change is for Solaris 10 or newer.
 885    UNEXEC_OBJ=unexsol.o
 886    ;;
 887 esac
 888
 889 LD_SWITCH_SYSTEM=
 890 case "$opsys" in
 891   freebsd)
 892    ## Let `ld' find image libs and similar things in /usr/local/lib.
 893    ## The system compiler, GCC, has apparently been modified to not
 894    ## look there, contrary to what a stock GCC would do.
 895    LD_SWITCH_SYSTEM=-L/usr/local/lib
 896    ;;
 897
 898   gnu-linux)
 899    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 900    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 901    ;;
 902
 903   netbsd)
 904    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 905    ;;
 906
 907   openbsd)
 908    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 909    ## otherwise Emacs dumps core on elf systems.
 910    LD_SWITCH_SYSTEM="-Z"
 911    ;;
 912 esac
 913 AC_SUBST(LD_SWITCH_SYSTEM)
 914
 915 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 916
 917 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 918 ## which has not been defined yet.  When this was handled with cpp,
 919 ## it was expanded to null when configure sourced the s/*.h file.
 920 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 921 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 922 ## (or somesuch), but because it is supposed to go at the _front_
 923 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 924 ## Compare with the gnu-linux case below, which added to the end
 925 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 926 ## LD_SWITCH_SYSTEM_TEMACS.
 927 case "$opsys" in
 928   netbsd|openbsd)
 929    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 930    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 931 esac
 932
 933
 934 C_SWITCH_MACHINE=
 935 if test "$machine" = "alpha"; then
 936   AC_CHECK_DECL([__ELF__])
 937   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 938     ## With ELF, make sure that all common symbols get allocated to in the
 939     ## data section.  Otherwise, the dump of temacs may miss variables in
 940     ## the shared library that have been initialized.  For example, with
 941     ## GNU libc, __malloc_initialized would normally be resolved to the
 942     ## shared library's .bss section, which is fatal.
 943     if test "x$GCC" = "xyes"; then
 944       C_SWITCH_MACHINE="-fno-common"
 945     else
 946       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 947     fi
 948   else
 949     UNEXEC_OBJ=unexalpha.o
 950   fi
 951 fi
 952 AC_SUBST(C_SWITCH_MACHINE)
 953
 954 AC_SUBST(UNEXEC_OBJ)
 955
 956 C_SWITCH_SYSTEM=
 957 ## Some programs in src produce warnings saying certain subprograms
 958 ## are too complex and need a MAXMEM value greater than 2000 for
 959 ## additional optimization.  --nils@exp-math.uni-essen.de
 960 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 961   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 962 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 963 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 964 AC_SUBST(C_SWITCH_SYSTEM)
 965
 966
 967 LIBS_SYSTEM=
 968 case "$opsys" in
 969   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 970   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 971
 972   freebsd) LIBS_SYSTEM="-lutil" ;;
 973
 974   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 975
 976   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
 977
 978   ## Motif needs -lgen.
 979   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 980 esac
 981 AC_SUBST(LIBS_SYSTEM)
 982
 983
 984 ### Make sure subsequent tests use flags consistent with the build flags.
 985
 986 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 987   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 988 else
 989   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 990 fi
 991
 992 dnl For AC_FUNC_GETLOADAVG, at least:
 993 AC_CONFIG_LIBOBJ_DIR(src)
 994
 995 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 996 AC_SYS_LARGEFILE
 997
 998
 999 ## If user specified a crt-dir, use that unconditionally.
1000 if test "X$CRT_DIR" = "X"; then
1001
1002   case "$canonical" in
1003     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1004     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1005     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1006     ## For anything else (eg /usr/lib32), it is up the user to specify
1007     ## the location (bug#5655).
1008     ## Test for crtn.o, not just the directory, because sometimes the
1009     ## directory exists but does not have the relevant files (bug#1287).
1010     ## FIXME better to test for binary compatibility somehow.
1011     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1012     ;;
1013
1014     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1015   esac
1016
1017   case "$opsys" in
1018     hpux10-20) CRT_DIR=/lib ;;
1019   esac
1020
1021   ## Default is /usr/lib.
1022   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1023
1024 else
1025
1026   ## Some platforms don't use any of these files, so it is not
1027   ## appropriate to put this test outside the if block.
1028   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1029     AC_MSG_ERROR([crt*.o not found in specified location.])
1030
1031 fi
1032
1033 AC_SUBST(CRT_DIR)
1034
1035 LIB_MATH=-lm
1036 LIB_STANDARD=
1037 START_FILES=
1038
1039 case $opsys in
1040   cygwin )
1041     LIB_MATH=
1042     START_FILES='pre-crt0.o'
1043     ;;
1044   darwin )
1045     ## Adding -lm confuses the dynamic linker, so omit it.
1046     LIB_MATH=
1047     START_FILES='pre-crt0.o'
1048     ;;
1049   freebsd )
1050     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1051     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1052     ;;
1053   gnu-linux | gnu-kfreebsd )
1054     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1055     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1056     ;;
1057   hpux10-20 | hpux11 )
1058     LIB_STANDARD=-lc
1059     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1060     ;;
1061   netbsd | openbsd )
1062     if test -f $CRT_DIR/crti.o; then
1063         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1064         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1065     else
1066         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1067         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1068     fi
1069     ;;
1070 esac
1071
1072 AC_SUBST(LIB_MATH)
1073 AC_SUBST(START_FILES)
1074
1075 dnl This function definition taken from Gnome 2.0
1076 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1077 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1078 dnl also defines GSTUFF_PKG_ERRORS on error
1079 AC_DEFUN([PKG_CHECK_MODULES], [
1080   succeeded=no
1081
1082   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1083
1084   if test "$PKG_CONFIG" = "no" ; then
1085      ifelse([$4], , [AC_MSG_ERROR([
1086       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1087   else
1088      PKG_CONFIG_MIN_VERSION=0.9.0
1089      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1090         AC_MSG_CHECKING(for $2)
1091
1092         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1093             AC_MSG_RESULT(yes)
1094             succeeded=yes
1095
1096             AC_MSG_CHECKING($1_CFLAGS)
1097             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1098             AC_MSG_RESULT($$1_CFLAGS)
1099
1100             AC_MSG_CHECKING($1_LIBS)
1101             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1102             AC_MSG_RESULT($$1_LIBS)
1103         else
1104             AC_MSG_RESULT(no)
1105             $1_CFLAGS=""
1106             $1_LIBS=""
1107             ## If we have a custom action on failure, don't print errors, but
1108             ## do set a variable so people can do so.
1109             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1110             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1111         fi
1112
1113         AC_SUBST($1_CFLAGS)
1114         AC_SUBST($1_LIBS)
1115      else
1116         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1117         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1118      fi
1119   fi
1120
1121   if test $succeeded = yes; then
1122      ifelse([$3], , :, [$3])
1123   else
1124      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1125   fi
1126 ])
1127
1128
1129 if test "${with_sound}" != "no"; then
1130   # Sound support for GNU/Linux and the free BSDs.
1131   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1132     have_sound_header=yes)
1133   # Emulation library used on NetBSD.
1134   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1135   AC_SUBST(LIBSOUND)
1136
1137   ALSA_REQUIRED=1.0.0
1138   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1139   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1140   if test $HAVE_ALSA = yes; then
1141     SAVE_CFLAGS="$CFLAGS"
1142     SAVE_LDFLAGS="$LDFLAGS"
1143     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1144     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1145     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1146                     emacs_alsa_normal=yes,
1147                     emacs_alsa_normal=no)
1148     if test "$emacs_alsa_normal" != yes; then
1149       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1150                      [snd_lib_error_set_handler (0);],
1151                      emacs_alsa_subdir=yes,
1152                      emacs_alsa_subdir=no)
1153       if test "$emacs_alsa_subdir" != yes; then
1154         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1155       fi
1156       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1157     fi
1158
1159     CFLAGS="$SAVE_CFLAGS"
1160     LDFLAGS="$SAVE_LDFLAGS"
1161     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1162     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1163     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1164   fi
1165
1166   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1167   dnl compiles only on the specified platforms.  For others, it
1168   dnl probably doesn't make sense to try.
1169   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1170      case "$opsys" in
1171        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1172        gnu-linux|freebsd|netbsd)
1173          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1174          ;;
1175      esac
1176   fi
1177
1178   AC_SUBST(CFLAGS_SOUND)
1179 fi
1180
1181 dnl checks for header files
1182 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1183   linux/version.h sys/systeminfo.h limits.h \
1184   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1185   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1186   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1187
1188 AC_MSG_CHECKING(if personality LINUX32 can be set)
1189 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1190                emacs_cv_personality_linux32=yes,
1191                emacs_cv_personality_linux32=no)
1192 AC_MSG_RESULT($emacs_cv_personality_linux32)
1193
1194 if test $emacs_cv_personality_linux32 = yes; then
1195   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1196             [Define to 1 if personality LINUX32 can be set.])
1197 fi
1198
1199 dnl On Solaris 8 there's a compilation warning for term.h because
1200 dnl it doesn't define `bool'.
1201 AC_CHECK_HEADERS(term.h, , , -)
1202 AC_HEADER_STDC
1203 AC_HEADER_TIME
1204 AC_CHECK_DECLS([sys_siglist])
1205 if test $ac_cv_have_decl_sys_siglist != yes; then
1206   # For Tru64, at least:
1207   AC_CHECK_DECLS([__sys_siglist])
1208   if test $ac_cv_have_decl___sys_siglist = yes; then
1209     AC_DEFINE(sys_siglist, __sys_siglist,
1210               [Define to any substitute for sys_siglist.])
1211   fi
1212 fi
1213 AC_HEADER_SYS_WAIT
1214
1215 dnl Some systems have utime.h but don't declare the struct anyplace.
1216 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1217 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1218 #include <sys/time.h>
1219 #include <time.h>
1220 #else
1221 #ifdef HAVE_SYS_TIME_H
1222 #include <sys/time.h>
1223 #else
1224 #include <time.h>
1225 #endif
1226 #endif
1227 #ifdef HAVE_UTIME_H
1228 #include <utime.h>
1229 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1230   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1231 if test $emacs_cv_struct_utimbuf = yes; then
1232   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1233 fi
1234
1235 dnl checks for typedefs
1236 AC_TYPE_SIGNAL
1237
1238 dnl Check for speed_t typedef.
1239 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1240   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1241     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1242 if test $emacs_cv_speed_t = yes; then
1243   AC_DEFINE(HAVE_SPEED_T, 1,
1244            [Define to 1 if `speed_t' is declared by <termios.h>.])
1245 fi
1246
1247 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1248 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1249 #include <sys/time.h>
1250 #include <time.h>
1251 #else
1252 #ifdef HAVE_SYS_TIME_H
1253 #include <sys/time.h>
1254 #else
1255 #include <time.h>
1256 #endif
1257 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1258   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1259 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1260 if test $emacs_cv_struct_timeval = yes; then
1261   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1262 fi
1263
1264 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1265 AC_TRY_COMPILE([#include <math.h>],
1266 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1267   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1268 HAVE_EXCEPTION=$emacs_cv_struct_exception
1269 if test $emacs_cv_struct_exception != yes; then
1270   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1271 fi
1272
1273 AC_CHECK_HEADERS(sys/socket.h)
1274 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1275 #if HAVE_SYS_SOCKET_H
1276 #include <sys/socket.h>
1277 #endif])
1278
1279 dnl checks for structure members
1280 AC_STRUCT_TM
1281 AC_STRUCT_TIMEZONE
1282 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1283                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1284                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1285                 [#include <time.h>])
1286 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1287                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1288                   struct ifreq.ifr_addr], , ,
1289                  [AC_INCLUDES_DEFAULT
1290 #if HAVE_SYS_SOCKET_H
1291 #include <sys/socket.h>
1292 #endif
1293 #if HAVE_NET_IF_H
1294 #include <net/if.h>
1295 #endif])
1296
1297 dnl checks for compiler characteristics
1298
1299 dnl Testing __STDC__ to determine prototype support isn't good enough.
1300 dnl DEC C, for instance, doesn't define it with default options, and
1301 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1302 dnl and void *.
1303 AC_C_PROTOTYPES
1304 AC_C_VOLATILE
1305 AC_C_CONST
1306 dnl This isn't useful because we can't turn on use of `inline' unless
1307 dnl the compiler groks `extern inline'.
1308 dnl AC_C_INLINE
1309 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1310   [AC_TRY_COMPILE(, [void * foo;],
1311                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1312 if test $emacs_cv_void_star = yes; then
1313   AC_DEFINE(POINTER_TYPE, void)
1314 else
1315   AC_DEFINE(POINTER_TYPE, char)
1316 fi
1317 AH_TEMPLATE(POINTER_TYPE,
1318             [Define as `void' if your compiler accepts `void *'; otherwise
1319              define as `char'.])dnl
1320
1321 dnl Check for endianess
1322 AC_C_BIGENDIAN
1323
1324 dnl check for Make feature
1325 AC_PROG_MAKE_SET
1326
1327 DEPFLAGS=
1328 MKDEPDIR=":"
1329 deps_frag=deps.mk
1330 dnl check for GNU Make if we have GCC and autodepend is on.
1331 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1332    AC_MSG_CHECKING([whether we are using GNU Make])
1333    HAVE_GNU_MAKE=no
1334    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1335    if test "x$testval" != x; then
1336       HAVE_GNU_MAKE=yes
1337    else
1338       ac_enable_autodepend=no
1339    fi
1340    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1341    if test $HAVE_GNU_MAKE = yes; then
1342       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1343       SAVE_CFLAGS="$CFLAGS"
1344       CFLAGS="$CFLAGS -MMD -MF deps.d"
1345       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1346       CFLAGS="$SAVE_CFLAGS"
1347       test -f deps.d || ac_enable_autodepend=no
1348       rm -rf deps.d
1349       AC_MSG_RESULT([$ac_enable_autodepend])
1350    fi
1351    if test $ac_enable_autodepend = yes; then
1352       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1353       ## In parallel builds, another make might create depdir between
1354       ## the first test and mkdir, so stick another test on the end.
1355       ## Or use mkinstalldirs?  mkdir -p is not portable.
1356       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1357       deps_frag=autodeps.mk
1358    fi
1359 fi
1360 deps_frag=$srcdir/src/$deps_frag
1361 AC_SUBST(MKDEPDIR)
1362 AC_SUBST(DEPFLAGS)
1363 AC_SUBST_FILE(deps_frag)
1364
1365
1366 dnl checks for operating system services
1367 AC_SYS_LONG_FILE_NAMES
1368
1369 #### Choose a window system.
1370
1371 AC_PATH_X
1372 if test "$no_x" = yes; then
1373   window_system=none
1374 else
1375   window_system=x11
1376 fi
1377
1378 ## Workaround for bug in autoconf <= 2.62.
1379 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1380 ## No need to do anything special for these standard directories.
1381 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1382
1383    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1384
1385 fi
1386
1387 LD_SWITCH_X_SITE_AUX=
1388 LD_SWITCH_X_SITE_AUX_RPATH=
1389 if test "${x_libraries}" != NONE; then
1390   if test -n "${x_libraries}"; then
1391     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1392     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1393     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1394   fi
1395   x_default_search_path=""
1396   x_search_path=${x_libraries}
1397   if test -z "${x_search_path}"; then
1398     x_search_path=/usr/lib
1399   fi
1400   for x_library in `echo ${x_search_path}: | \
1401                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1402     x_search_path="\
1403 ${x_library}/X11/%L/%T/%N%C%S:\
1404 ${x_library}/X11/%l/%T/%N%C%S:\
1405 ${x_library}/X11/%T/%N%C%S:\
1406 ${x_library}/X11/%L/%T/%N%S:\
1407 ${x_library}/X11/%l/%T/%N%S:\
1408 ${x_library}/X11/%T/%N%S"
1409     if test x"${x_default_search_path}" = x; then
1410       x_default_search_path=${x_search_path}
1411     else
1412       x_default_search_path="${x_search_path}:${x_default_search_path}"
1413     fi
1414   done
1415 fi
1416 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1417 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1418
1419 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1420   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1421 fi
1422
1423 if test x"${x_includes}" = x; then
1424   bitmapdir=/usr/include/X11/bitmaps
1425 else
1426   # accumulate include directories that have X11 bitmap subdirectories
1427   bmd_acc="dummyval"
1428   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1429     if test -d "${bmd}/X11/bitmaps"; then
1430       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1431     fi
1432     if test -d "${bmd}/bitmaps"; then
1433       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1434     fi
1435   done
1436   if test ${bmd_acc} != "dummyval"; then
1437     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1438   fi
1439 fi
1440
1441 HAVE_NS=no
1442 NS_IMPL_COCOA=no
1443 NS_IMPL_GNUSTEP=no
1444 tmp_CPPFLAGS="$CPPFLAGS"
1445 tmp_CFLAGS="$CFLAGS"
1446 CPPFLAGS="$CPPFLAGS -x objective-c"
1447 CFLAGS="$CFLAGS -x objective-c"
1448 TEMACS_LDFLAGS2="\${LDFLAGS}"
1449 dnl I don't think it's especially important, but src/Makefile.in
1450 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1451 dnl trailing "/" to it, so now we do it here.
1452 if test "${with_ns}" != no; then
1453   if test "${opsys}" = darwin; then
1454      NS_IMPL_COCOA=yes
1455      ns_appdir=`pwd`/nextstep/Emacs.app
1456      ns_appbindir=${ns_appdir}/Contents/MacOS/
1457      ns_appresdir=${ns_appdir}/Contents/Resources
1458      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1459   elif test -f $GNUSTEP_CONFIG_FILE; then
1460      NS_IMPL_GNUSTEP=yes
1461      ns_appdir=`pwd`/nextstep/Emacs.app
1462      ns_appbindir=${ns_appdir}/
1463      ns_appresdir=${ns_appdir}/Resources
1464      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1465      dnl FIXME sourcing this several times in subshells seems inefficient.
1466      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1467      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1468      dnl I seemed to need these as well with GNUstep-startup 0.25.
1469      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1470      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1471      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1472        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1473      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1474        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1475      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1476      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1477      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1478      LIB_STANDARD=
1479      START_FILES=
1480      TEMACS_LDFLAGS2=
1481   fi
1482   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1483                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1484   files are missing or cannot be compiled.])])
1485   NS_HAVE_NSINTEGER=yes
1486   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1487                                      [NSInteger i;])],
1488                     ns_have_nsinteger=yes,
1489                     ns_have_nsinteger=no)
1490   if test $ns_have_nsinteger = no; then
1491     NS_HAVE_NSINTEGER=no
1492   fi
1493 fi
1494 AC_SUBST(TEMACS_LDFLAGS2)
1495
1496 ns_frag=/dev/null
1497 NS_OBJ=
1498 NS_SUPPORT=
1499 if test "${HAVE_NS}" = yes; then
1500   window_system=nextstep
1501   with_xft=no
1502   # set up packaging dirs
1503   exec_prefix=${ns_appbindir}
1504   libexecdir=${ns_appbindir}/libexec
1505   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1506      prefix=${ns_appresdir}
1507   fi
1508   ns_frag=$srcdir/src/ns.mk
1509   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1510   NS_SUPPORT="\${lispsource}/emacs-lisp/easymenu.elc \${lispsource}/term/ns-win.elc"
1511 fi
1512 CFLAGS="$tmp_CFLAGS"
1513 CPPFLAGS="$tmp_CPPFLAGS"
1514 AC_SUBST(NS_OBJ)
1515 AC_SUBST(NS_SUPPORT)
1516 AC_SUBST(LIB_STANDARD)
1517 AC_SUBST_FILE(ns_frag)
1518
1519 case "${window_system}" in
1520   x11 )
1521     HAVE_X_WINDOWS=yes
1522     HAVE_X11=yes
1523     case "${with_x_toolkit}" in
1524       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1525       motif ) USE_X_TOOLKIT=MOTIF ;;
1526       gtk ) with_gtk=yes
1527 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1528 dnl USE_X_TOOLKIT is set.
1529             USE_X_TOOLKIT=none ;;
1530       gtk3 ) with_gtk3=yes
1531              USE_X_TOOLKIT=none ;;
1532       no ) USE_X_TOOLKIT=none ;;
1533 dnl If user did not say whether to use a toolkit, make this decision later:
1534 dnl use the toolkit if we have gtk, or X11R5 or newer.
1535       * ) USE_X_TOOLKIT=maybe ;;
1536     esac
1537   ;;
1538   nextstep | none )
1539     HAVE_X_WINDOWS=no
1540     HAVE_X11=no
1541     USE_X_TOOLKIT=none
1542   ;;
1543 esac
1544
1545 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1546    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1547    if test "$HAVE_XSERVER" = true ||
1548       test -n "$DISPLAY" ||
1549       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1550         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1551 were found.  You should install the relevant development files for X
1552 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1553 sure you have development files for image handling, i.e.
1554 tiff, gif, jpeg, png and xpm.
1555 If you are sure you want Emacs compiled without X window support, pass
1556   --without-x
1557 to configure.])
1558    fi
1559 fi
1560
1561 ### If we're using X11, we should use the X menu package.
1562 HAVE_MENUS=no
1563 case ${HAVE_X11} in
1564   yes ) HAVE_MENUS=yes ;;
1565 esac
1566
1567 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1568 # Assume not, until told otherwise.
1569 GNU_MALLOC=yes
1570 doug_lea_malloc=yes
1571 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1572 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1573 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1574                emacs_cv_var___after_morecore_hook,
1575 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1576   emacs_cv_var___after_morecore_hook=yes,
1577   emacs_cv_var___after_morecore_hook=no)])
1578 if test $emacs_cv_var___after_morecore_hook = no; then
1579   doug_lea_malloc=no
1580 fi
1581
1582
1583 dnl See comments in aix4-2.h about maybe using system malloc there.
1584 system_malloc=no
1585 case "$opsys" in
1586   ## darwin ld insists on the use of malloc routines in the System framework.
1587   darwin|sol2-10) system_malloc=yes ;;
1588 esac
1589
1590 if test "${system_malloc}" = "yes"; then
1591   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1592   GNU_MALLOC=no
1593   GNU_MALLOC_reason="
1594     (The GNU allocators don't work with this system configuration.)"
1595   GMALLOC_OBJ=
1596   VMLIMIT_OBJ=
1597 else
1598   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1599   VMLIMIT_OBJ=vm-limit.o
1600 fi
1601 AC_SUBST(GMALLOC_OBJ)
1602 AC_SUBST(VMLIMIT_OBJ)
1603
1604 if test "$doug_lea_malloc" = "yes" ; then
1605   if test "$GNU_MALLOC" = yes ; then
1606     GNU_MALLOC_reason="
1607       (Using Doug Lea's new malloc from the GNU C Library.)"
1608   fi
1609   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1610             [Define to 1 if you are using the GNU C Library.])
1611
1612   ## Use mmap directly for allocating larger buffers.
1613   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1614   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1615   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1616   case "$opsys" in
1617     gnu*) REL_ALLOC=no ;;
1618   esac
1619 fi
1620
1621 if test x"${REL_ALLOC}" = x; then
1622   REL_ALLOC=${GNU_MALLOC}
1623 fi
1624
1625 use_mmap_for_buffers=no
1626 case "$opsys" in
1627   freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1628 esac
1629
1630 AC_FUNC_MMAP
1631 if test $use_mmap_for_buffers = yes; then
1632   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1633   REL_ALLOC=no
1634 fi
1635
1636 LIBS="$LIBS_SYSTEM $LIBS"
1637
1638 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1639 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1640 AC_CHECK_LIB(dnet, dnet_ntoa)
1641 dnl This causes -lresolv to get used in subsequent tests,
1642 dnl which causes failures on some systems such as HPUX 9.
1643 dnl AC_CHECK_LIB(resolv, gethostbyname)
1644
1645 dnl FIXME replace main with a function we actually want from this library.
1646 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1647
1648 AC_CHECK_LIB(pthreads, cma_open)
1649
1650 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1651 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1652 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1653 ## added to LIBS in configure would never contain the pthreads part,
1654 ## but the value used in Makefiles might.  FIXME?
1655 ##
1656 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1657 ## be harmless on older versions of X where it happens to exist.
1658 test "$opsys" = "aix4-2" && \
1659   test $ac_cv_lib_pthreads_cma_open = yes && \
1660   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1661
1662 dnl Check for need for bigtoc support on IBM AIX
1663
1664 case ${host_os} in
1665 aix*)
1666   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1667     case $GCC in
1668     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1669     *) gdb_cv_bigtoc=-bbigtoc ;;
1670     esac
1671
1672     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1673     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1674   ])
1675   ;;
1676 esac
1677
1678 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1679 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1680 # REAL_CPPFLAGS later on.
1681
1682 REAL_CFLAGS="$CFLAGS"
1683 REAL_CPPFLAGS="$CPPFLAGS"
1684
1685 if test "${HAVE_X11}" = "yes"; then
1686   DEFS="$C_SWITCH_X_SITE $DEFS"
1687   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1688   LIBS="-lX11 $LIBS"
1689   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1690   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1691
1692   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1693   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1694   # but it's more convenient here to set LD_RUN_PATH
1695   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1696   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1697     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1698     export LD_RUN_PATH
1699   fi
1700
1701   if test "${opsys}" = "gnu-linux"; then
1702     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1703     AC_TRY_LINK([],
1704      [XOpenDisplay ("foo");],
1705      [xlinux_first_failure=no],
1706      [xlinux_first_failure=yes])
1707     if test "${xlinux_first_failure}" = "yes"; then
1708       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1709       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1710       OLD_CPPFLAGS="$CPPFLAGS"
1711       OLD_LIBS="$LIBS"
1712       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1713       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1714       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1715       LIBS="$LIBS -b i486-linuxaout"
1716       AC_TRY_LINK([],
1717        [XOpenDisplay ("foo");],
1718        [xlinux_second_failure=no],
1719        [xlinux_second_failure=yes])
1720       if test "${xlinux_second_failure}" = "yes"; then
1721         # If we get the same failure with -b, there is no use adding -b.
1722         # So take it out.  This plays safe.
1723         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1724         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1725         CPPFLAGS="$OLD_CPPFLAGS"
1726         LIBS="$OLD_LIBS"
1727         AC_MSG_RESULT(no)
1728       else
1729         AC_MSG_RESULT(yes)
1730       fi
1731     else
1732       AC_MSG_RESULT(no)
1733     fi
1734   fi
1735
1736   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1737   # header files included from there.
1738   AC_MSG_CHECKING(for Xkb)
1739   AC_TRY_LINK([#include <X11/Xlib.h>
1740 #include <X11/XKBlib.h>],
1741         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1742         emacs_xkb=yes, emacs_xkb=no)
1743   AC_MSG_RESULT($emacs_xkb)
1744   if test $emacs_xkb = yes; then
1745     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1746   fi
1747
1748   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1749 XScreenNumberOfScreen XSetWMProtocols)
1750 fi
1751
1752 if test "${window_system}" = "x11"; then
1753   AC_MSG_CHECKING(X11 version 6)
1754   AC_CACHE_VAL(emacs_cv_x11_version_6,
1755   [AC_TRY_LINK([#include <X11/Xlib.h>],
1756 [#if XlibSpecificationRelease < 6
1757 fail;
1758 #endif
1759 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1760   if test $emacs_cv_x11_version_6 = yes; then
1761     AC_MSG_RESULT(6 or newer)
1762     AC_DEFINE(HAVE_X11R6, 1,
1763               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1764     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1765     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1766     ## XIM support.
1767     case "$opsys" in
1768       sol2-*) : ;;
1769       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1770            [Define if you have usable X11R6-style XIM support.])
1771          ;;
1772     esac
1773   else
1774     AC_MSG_RESULT(before 6)
1775   fi
1776 fi
1777
1778
1779 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1780 HAVE_RSVG=no
1781 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1782   if test "${with_rsvg}" != "no"; then
1783     RSVG_REQUIRED=2.11.0
1784     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1785
1786     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1787     AC_SUBST(RSVG_CFLAGS)
1788     AC_SUBST(RSVG_LIBS)
1789
1790     if test $HAVE_RSVG = yes; then
1791       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1792       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1793       LIBS="$RSVG_LIBS $LIBS"
1794     fi
1795   fi
1796 fi
1797
1798 HAVE_IMAGEMAGICK=no
1799 if test "${HAVE_X11}" = "yes"; then
1800   if test "${with_imagemagick}" != "no"; then
1801     IMAGEMAGICK_MODULE="Wand"
1802     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1803     AC_SUBST(IMAGEMAGICK_CFLAGS)
1804     AC_SUBST(IMAGEMAGICK_LIBS)
1805
1806     if test $HAVE_IMAGEMAGICK = yes; then
1807       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1808       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1809       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1810       AC_CHECK_FUNCS(MagickExportImagePixels)
1811     fi
1812   fi
1813 fi
1814
1815
1816 HAVE_GTK=no
1817 if test "${with_gtk3}" = "yes"; then
1818   GLIB_REQUIRED=2.6
1819   GTK_REQUIRED=2.90
1820   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1821
1822   dnl Checks for libraries.
1823   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1824   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1825      AC_MSG_ERROR($GTK_PKG_ERRORS)
1826   fi
1827 fi
1828
1829 if test "$pkg_check_gtk" != "yes"; then
1830   HAVE_GTK=no
1831 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1832   GLIB_REQUIRED=2.6
1833   GTK_REQUIRED=2.6
1834   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1835
1836   dnl Checks for libraries.
1837   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1838   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1839      AC_MSG_ERROR($GTK_PKG_ERRORS)
1840   fi
1841 fi
1842 fi
1843
1844 GTK_OBJ=
1845 if test x"$pkg_check_gtk" = xyes; then
1846
1847   AC_SUBST(GTK_CFLAGS)
1848   AC_SUBST(GTK_LIBS)
1849   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1850   CFLAGS="$CFLAGS $GTK_CFLAGS"
1851   LIBS="$GTK_LIBS $LIBS"
1852   dnl Try to compile a simple GTK program.
1853   GTK_COMPILES=no
1854   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1855   if test "${GTK_COMPILES}" != "yes"; then
1856     if test "$USE_X_TOOLKIT" != "maybe"; then
1857       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1858     fi
1859   else
1860     HAVE_GTK=yes
1861     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1862     GTK_OBJ=gtkutil.o
1863     USE_X_TOOLKIT=none
1864     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1865       :
1866     else
1867       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1868        closing open displays.  This is no problem if you just use
1869        one display, but if you use more than one and close one of them
1870        Emacs may crash.]])
1871       sleep 3
1872     fi
1873   fi
1874
1875 fi
1876 AC_SUBST(GTK_OBJ)
1877
1878
1879 if test "${HAVE_GTK}" = "yes"; then
1880
1881   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1882   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1883   if test "$with_toolkit_scroll_bars" != no; then
1884     with_toolkit_scroll_bars=yes
1885   fi
1886
1887   dnl  Check if we have the old file selection dialog declared and
1888   dnl  in the link library.  In 2.x it may be in the library,
1889   dnl  but not declared if deprecated featured has been selected out.
1890   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1891   HAVE_GTK_FILE_SELECTION=no
1892   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1893                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1894 #include <gtk/gtk.h>])
1895   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1896     AC_CHECK_FUNCS(gtk_file_selection_new)
1897   fi
1898
1899   dnl Check if pthreads are available.  Emacs only needs this when using
1900   dnl gtk_file_chooser under Gnome.
1901     HAVE_GTK_AND_PTHREAD=no
1902     AC_CHECK_HEADERS(pthread.h)
1903     if test "$ac_cv_header_pthread_h"; then
1904       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1905     fi
1906     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1907       case "${canonical}" in
1908         *-hpux*) ;;
1909         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1910       esac
1911       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1912                [Define to 1 if you have GTK and pthread (-lpthread).])
1913     fi
1914
1915   dnl Check for functions introduced in 2.14 and later.
1916   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1917                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1918                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1919                  gtk_orientable_set_orientation)
1920
1921 fi
1922
1923 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1924 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1925 dnl also not configured.
1926 HAVE_DBUS=no
1927 DBUS_OBJ=
1928 if test "${with_dbus}" = "yes"; then
1929    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1930    if test "$HAVE_DBUS" = yes; then
1931      LIBS="$LIBS $DBUS_LIBS"
1932      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1933      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1934      DBUS_OBJ=dbusbind.o
1935    fi
1936 fi
1937 AC_SUBST(DBUS_OBJ)
1938
1939 dnl GConf has been tested under GNU/Linux only.
1940 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1941 HAVE_GCONF=no
1942 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1943    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1944    if test "$HAVE_GCONF" = yes; then
1945       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1946       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1947       AC_CHECK_FUNCS([g_type_init])
1948    fi
1949 fi
1950
1951 dnl SELinux is available for GNU/Linux only.
1952 HAVE_LIBSELINUX=no
1953 LIBSELINUX_LIBS=
1954 if test "${with_selinux}" = "yes"; then
1955    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1956    if test "$HAVE_LIBSELINUX" = yes; then
1957       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1958       LIBSELINUX_LIBS=-lselinux
1959    fi
1960 fi
1961 AC_SUBST(LIBSELINUX_LIBS)
1962
1963 HAVE_GNUTLS=no
1964 if test "${with_gnutls}" = "yes" ; then
1965   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.2.4], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
1966   if test "${HAVE_GNUTLS}" = "yes"; then
1967     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
1968   fi
1969 fi
1970 AC_SUBST(LIBGNUTLS_LIBS)
1971 AC_SUBST(LIBGNUTLS_CFLAGS)
1972
1973 dnl Do not put whitespace before the #include statements below.
1974 dnl Older compilers (eg sunos4 cc) choke on it.
1975 HAVE_XAW3D=no
1976 LUCID_LIBW=
1977 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1978   if test "$with_xaw3d" != no; then
1979     AC_MSG_CHECKING(for xaw3d)
1980     AC_CACHE_VAL(emacs_cv_xaw3d,
1981     [AC_TRY_LINK([
1982 #include <X11/Intrinsic.h>
1983 #include <X11/Xaw3d/Simple.h>],
1984       [],
1985       emacs_cv_xaw3d=yes,
1986       emacs_cv_xaw3d=no)])
1987   else
1988     emacs_cv_xaw3d=no
1989   fi
1990   if test $emacs_cv_xaw3d = yes; then
1991     AC_MSG_RESULT([yes; using Lucid toolkit])
1992     USE_X_TOOLKIT=LUCID
1993     HAVE_XAW3D=yes
1994     LUCID_LIBW=-lXaw3d
1995     AC_DEFINE(HAVE_XAW3D, 1,
1996               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1997   else
1998     AC_MSG_RESULT(no)
1999     AC_MSG_CHECKING(for libXaw)
2000     AC_CACHE_VAL(emacs_cv_xaw,
2001     [AC_TRY_LINK([
2002 #include <X11/Intrinsic.h>
2003 #include <X11/Xaw/Simple.h>],
2004       [],
2005       emacs_cv_xaw=yes,
2006       emacs_cv_xaw=no)])
2007     if test $emacs_cv_xaw = yes; then
2008       AC_MSG_RESULT([yes; using Lucid toolkit])
2009       USE_X_TOOLKIT=LUCID
2010       LUCID_LIBW=-lXaw
2011     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2012       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2013     else
2014       AC_MSG_RESULT([no; do not use toolkit by default])
2015       USE_X_TOOLKIT=none
2016     fi
2017   fi
2018 fi
2019
2020 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2021
2022 LIBXTR6=
2023 if test "${USE_X_TOOLKIT}" != "none"; then
2024   AC_MSG_CHECKING(X11 toolkit version)
2025   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2026   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2027 [#if XtSpecificationRelease < 6
2028 fail;
2029 #endif
2030 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2031   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2032   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2033     AC_MSG_RESULT(6 or newer)
2034     AC_DEFINE(HAVE_X11XTR6, 1,
2035               [Define to 1 if you have the X11R6 or newer version of Xt.])
2036     LIBXTR6="-lSM -lICE"
2037     case "$opsys" in
2038       ## Use libw.a along with X11R6 Xt.
2039       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2040     esac
2041   else
2042     AC_MSG_RESULT(before 6)
2043   fi
2044
2045 dnl If using toolkit, check whether libXmu.a exists.
2046 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2047   OLDLIBS="$LIBS"
2048   if test x$HAVE_X11XTR6 = xyes; then
2049     LIBS="-lXt -lSM -lICE $LIBS"
2050   else
2051     LIBS="-lXt $LIBS"
2052   fi
2053   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2054   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2055 fi
2056 AC_SUBST(LIBXTR6)
2057
2058 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2059 dnl Why not just test for libxmu in the normal way?
2060 LIBXMU=-lXmu
2061 case $opsys in
2062   ## These systems don't supply Xmu.
2063   hpux* | aix4-2 )
2064     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2065     ;;
2066 esac
2067 AC_SUBST(LIBXMU)
2068
2069 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2070 if test "${HAVE_X11}" = "yes"; then
2071   if test "${USE_X_TOOLKIT}" != "none"; then
2072     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2073   fi
2074 fi
2075
2076 LIBXP=
2077 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2078   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2079   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2080     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2081 int x = 5;
2082 #else
2083 Motif version prior to 2.1.
2084 #endif],
2085     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2086   if test $emacs_cv_motif_version_2_1 = yes; then
2087     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2088   else
2089     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2090     # We put this in CFLAGS temporarily to precede other -I options
2091     # that might be in CFLAGS temporarily.
2092     # We put this in CPPFLAGS where it precedes the other -I options.
2093     OLD_CPPFLAGS=$CPPFLAGS
2094     OLD_CFLAGS=$CFLAGS
2095     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2096     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2097     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2098       [int x = 5;],
2099       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2100     if test $emacs_cv_lesstif = yes; then
2101       # Make sure this -I option remains in CPPFLAGS after it is set
2102       # back to REAL_CPPFLAGS.
2103       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2104       # have those other -I options anyway.  Ultimately, having this
2105       # directory ultimately in CPPFLAGS will be enough.
2106       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2107       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2108     else
2109       CFLAGS=$OLD_CFLAGS
2110       CPPFLAGS=$OLD_CPPFLAGS
2111     fi
2112   fi
2113 fi
2114
2115 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2116 dnl using Motif or Xaw3d is available, and unless
2117 dnl --with-toolkit-scroll-bars=no was specified.
2118
2119 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2120             [Define to 1 if we should use toolkit scroll bars.])dnl
2121 USE_TOOLKIT_SCROLL_BARS=no
2122 if test "${with_toolkit_scroll_bars}" != "no"; then
2123   if test "${USE_X_TOOLKIT}" != "none"; then
2124     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2125       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2126       HAVE_XAW3D=no
2127       USE_TOOLKIT_SCROLL_BARS=yes
2128     elif test "${HAVE_XAW3D}" = "yes"; then
2129       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2130       USE_TOOLKIT_SCROLL_BARS=yes
2131     fi
2132   elif test "${HAVE_GTK}" = "yes"; then
2133     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2134     USE_TOOLKIT_SCROLL_BARS=yes
2135   elif test "${HAVE_NS}" = "yes"; then
2136     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2137     USE_TOOLKIT_SCROLL_BARS=yes
2138   fi
2139 fi
2140
2141 dnl See if XIM is available.
2142 AC_TRY_COMPILE([
2143           #include <X11/Xlib.h>
2144           #include <X11/Xresource.h>],
2145          [XIMProc  callback;],
2146          [HAVE_XIM=yes
2147          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2148          HAVE_XIM=no)
2149
2150 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2151
2152 if test "${with_xim}" != "no"; then
2153   AC_DEFINE(USE_XIM, 1,
2154             [Define to 1 if we should use XIM, if it is available.])
2155 fi
2156
2157
2158 if test "${HAVE_XIM}" != "no"; then
2159   late_CFLAGS=$CFLAGS
2160   if test "$GCC" = yes; then
2161     CFLAGS="$CFLAGS --pedantic-errors"
2162   fi
2163   AC_TRY_COMPILE([
2164 #include <X11/Xlib.h>
2165 #include <X11/Xresource.h>],
2166 [Display *display;
2167 XrmDatabase db;
2168 char *res_name;
2169 char *res_class;
2170 XIMProc  callback;
2171 XPointer *client_data;
2172 #ifndef __GNUC__
2173 /* If we're not using GCC, it's probably not XFree86, and this is
2174    probably right, but we can't use something like --pedantic-errors.  */
2175 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2176                                            char*, XIMProc, XPointer*);
2177 #endif
2178 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2179    client_data);],
2180     [emacs_cv_arg6_star=yes])
2181   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2182          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2183 either XPointer or XPointer*.])dnl
2184   if test "$emacs_cv_arg6_star" = yes; then
2185     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2186   else
2187     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2188   fi
2189   CFLAGS=$late_CFLAGS
2190 fi
2191
2192 ### Start of font-backend (under any platform) section.
2193 # (nothing here yet -- this is a placeholder)
2194 ### End of font-backend (under any platform) section.
2195
2196 ### Start of font-backend (under X11) section.
2197 if test "${HAVE_X11}" = "yes"; then
2198    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2199
2200    ## Use -lXft if available, unless `--with-xft=no'.
2201    HAVE_XFT=maybe
2202     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2203       with_xft="no";
2204     fi
2205     if test "x${with_xft}" != "xno"; then
2206
2207       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2208       ## Because xftfont.c uses XRenderQueryExtension, we also
2209       ## need to link to -lXrender.
2210       HAVE_XRENDER=no
2211       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2212       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2213         OLD_CPPFLAGS="$CPPFLAGS"
2214         OLD_CFLAGS="$CFLAGS"
2215         OLD_LIBS="$LIBS"
2216         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2217         CFLAGS="$CFLAGS $XFT_CFLAGS"
2218         XFT_LIBS="-lXrender $XFT_LIBS"
2219         LIBS="$XFT_LIBS $LIBS"
2220         AC_CHECK_HEADER(X11/Xft/Xft.h,
2221           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2222
2223         if test "${HAVE_XFT}" = "yes"; then
2224           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2225             AC_SUBST(XFT_LIBS)
2226           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2227         else
2228           CPPFLAGS="$OLD_CPPFLAGS"
2229           CFLAGS="$OLD_CFLAGS"
2230           LIBS="$OLD_LIBS"
2231         fi                        # "${HAVE_XFT}" = "yes"
2232       fi                          # "$HAVE_XFT" != no
2233     fi                            # "x${with_xft}" != "xno"
2234
2235     dnl For the "Does Emacs use" message at the end.
2236     if test "$HAVE_XFT" != "yes"; then
2237        HAVE_XFT=no
2238     fi
2239
2240
2241     HAVE_FREETYPE=no
2242     ## We used to allow building with FreeType and without Xft.
2243     ## However, the ftx font backend driver is not in good shape.
2244     if test "${HAVE_XFT}" = "yes"; then
2245       dnl As we use Xft, we anyway use freetype.
2246       dnl There's no need for additional CFLAGS and LIBS.
2247       HAVE_FREETYPE=yes
2248       FONTCONFIG_CFLAGS=
2249       FONTCONFIG_LIBS=
2250     fi
2251
2252     HAVE_LIBOTF=no
2253     if test "${HAVE_FREETYPE}" = "yes"; then
2254       AC_DEFINE(HAVE_FREETYPE, 1,
2255                 [Define to 1 if using the freetype and fontconfig libraries.])
2256       if test "${with_libotf}" != "no"; then
2257         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2258                           HAVE_LIBOTF=no)
2259         if test "$HAVE_LIBOTF" = "yes"; then
2260           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2261           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2262                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2263                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2264           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2265             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2266                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2267           fi
2268         fi
2269       fi
2270     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2271     dnl Does the new font backend require it, or can it work without it?
2272     fi
2273
2274     HAVE_M17N_FLT=no
2275     if test "${HAVE_LIBOTF}" = yes; then
2276       if test "${with_m17n_flt}" != "no"; then
2277         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2278         if test "$HAVE_M17N_FLT" = "yes"; then
2279           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2280         fi
2281       fi
2282     fi
2283 else
2284     HAVE_XFT=no
2285     HAVE_FREETYPE=no
2286     HAVE_LIBOTF=no
2287     HAVE_M17N_FLT=no
2288 fi
2289
2290 ### End of font-backend (under X11) section.
2291
2292 AC_SUBST(FREETYPE_CFLAGS)
2293 AC_SUBST(FREETYPE_LIBS)
2294 AC_SUBST(FONTCONFIG_CFLAGS)
2295 AC_SUBST(FONTCONFIG_LIBS)
2296 AC_SUBST(LIBOTF_CFLAGS)
2297 AC_SUBST(LIBOTF_LIBS)
2298 AC_SUBST(M17N_FLT_CFLAGS)
2299 AC_SUBST(M17N_FLT_LIBS)
2300
2301 ### Use -lXpm if available, unless `--with-xpm=no'.
2302 HAVE_XPM=no
2303 LIBXPM=
2304 if test "${HAVE_X11}" = "yes"; then
2305   if test "${with_xpm}" != "no"; then
2306     AC_CHECK_HEADER(X11/xpm.h,
2307       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2308     if test "${HAVE_XPM}" = "yes"; then
2309       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2310       AC_EGREP_CPP(no_return_alloc_pixels,
2311       [#include "X11/xpm.h"
2312 #ifndef XpmReturnAllocPixels
2313 no_return_alloc_pixels
2314 #endif
2315       ], HAVE_XPM=no, HAVE_XPM=yes)
2316
2317       if test "${HAVE_XPM}" = "yes"; then
2318         AC_MSG_RESULT(yes)
2319       else
2320         AC_MSG_RESULT(no)
2321       fi
2322     fi
2323   fi
2324
2325   if test "${HAVE_XPM}" = "yes"; then
2326     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2327     LIBXPM=-lXpm
2328   fi
2329 fi
2330 AC_SUBST(LIBXPM)
2331
2332 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2333 HAVE_JPEG=no
2334 LIBJPEG=
2335 if test "${HAVE_X11}" = "yes"; then
2336   if test "${with_jpeg}" != "no"; then
2337     dnl Checking for jpeglib.h can lose because of a redefinition of
2338     dnl  HAVE_STDLIB_H.
2339     AC_CHECK_HEADER(jerror.h,
2340       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2341   fi
2342
2343   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2344   if test "${HAVE_JPEG}" = "yes"; then
2345     AC_DEFINE(HAVE_JPEG)
2346     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2347         [#include <jpeglib.h>
2348          version=JPEG_LIB_VERSION
2349 ],
2350         [AC_DEFINE(HAVE_JPEG)],
2351         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2352         HAVE_JPEG=no])
2353   fi
2354   if test "${HAVE_JPEG}" = "yes"; then
2355     LIBJPEG=-ljpeg
2356   fi
2357 fi
2358 AC_SUBST(LIBJPEG)
2359
2360 ### Use -lpng if available, unless `--with-png=no'.
2361 HAVE_PNG=no
2362 LIBPNG=
2363 if test "${HAVE_X11}" = "yes"; then
2364   if test "${with_png}" != "no"; then
2365     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2366     # in /usr/include/libpng.
2367     AC_CHECK_HEADERS(png.h libpng/png.h)
2368     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2369       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2370     fi
2371   fi
2372
2373   if test "${HAVE_PNG}" = "yes"; then
2374     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2375     LIBPNG="-lpng -lz -lm"
2376   fi
2377 fi
2378 AC_SUBST(LIBPNG)
2379
2380 ### Use -ltiff if available, unless `--with-tiff=no'.
2381 HAVE_TIFF=no
2382 LIBTIFF=
2383 if test "${HAVE_X11}" = "yes"; then
2384   if test "${with_tiff}" != "no"; then
2385     AC_CHECK_HEADER(tiffio.h,
2386       [tifflibs="-lz -lm"
2387       # At least one tiff package requires the jpeg library.
2388       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2389       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2390   fi
2391
2392   if test "${HAVE_TIFF}" = "yes"; then
2393     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2394     dnl FIXME -lz -lm, as per libpng?
2395     LIBTIFF=-ltiff
2396   fi
2397 fi
2398 AC_SUBST(LIBTIFF)
2399
2400 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2401 HAVE_GIF=no
2402 LIBGIF=
2403 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2404   AC_CHECK_HEADER(gif_lib.h,
2405 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2406 # Earlier versions can crash Emacs.
2407     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2408
2409   if test "$HAVE_GIF" = yes; then
2410     LIBGIF=-lgif
2411   elif test "$HAVE_GIF" = maybe; then
2412 # If gif_lib.h but no libgif, try libungif.
2413     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2414     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2415   fi
2416
2417   if test "${HAVE_GIF}" = "yes"; then
2418     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2419   fi
2420 fi
2421 AC_SUBST(LIBGIF)
2422
2423 dnl Check for required libraries.
2424 if test "${HAVE_X11}" = "yes"; then
2425   MISSING=""
2426   WITH_NO=""
2427   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2428     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2429   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2430     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2431   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2432     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2433   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2434     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2435   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2436     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2437
2438   if test "X${MISSING}" != X; then
2439     AC_MSG_ERROR([The following required libraries were not found:
2440     $MISSING
2441 Maybe some development libraries/packages are missing?
2442 If you don't want to link with them give
2443     $WITH_NO
2444 as options to configure])
2445   fi
2446 fi
2447
2448 ### Use -lgpm if available, unless `--with-gpm=no'.
2449 HAVE_GPM=no
2450 LIBGPM=
2451 MOUSE_SUPPORT=
2452 if test "${with_gpm}" != "no"; then
2453   AC_CHECK_HEADER(gpm.h,
2454     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2455
2456   if test "${HAVE_GPM}" = "yes"; then
2457     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2458     LIBGPM=-lgpm
2459     ## May be reset below.
2460     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2461   fi
2462 fi
2463 AC_SUBST(LIBGPM)
2464
2465 dnl Check for malloc/malloc.h on darwin
2466 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2467
2468 C_SWITCH_X_SYSTEM=
2469 ### Use NeXTstep API to implement GUI.
2470 if test "${HAVE_NS}" = "yes"; then
2471   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2472   if test "${NS_IMPL_COCOA}" = "yes"; then
2473     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2474     GNU_OBJC_CFLAGS=
2475   fi
2476   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2477     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2478     # See also .m.o rule in Makefile.in */
2479     # FIXME: are all these flags really needed?  Document here why.  */
2480     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2481     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2482   fi
2483   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2484     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2485   fi
2486   # We also have mouse menus.
2487   HAVE_MENUS=yes
2488   OTHER_FILES=ns-app
2489 fi
2490
2491
2492 ### Use session management (-lSM -lICE) if available
2493 HAVE_X_SM=no
2494 LIBXSM=
2495 if test "${HAVE_X11}" = "yes"; then
2496   AC_CHECK_HEADER(X11/SM/SMlib.h,
2497     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2498
2499   if test "${HAVE_X_SM}" = "yes"; then
2500     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2501     LIBXSM="-lSM -lICE"
2502     case "$LIBS" in
2503       *-lSM*) ;;
2504       *)      LIBS="$LIBXSM $LIBS" ;;
2505     esac
2506   fi
2507 fi
2508 AC_SUBST(LIBXSM)
2509
2510 ### Use libxml (-lxml2) if available
2511 if test "${with_xml2}" != "no"; then
2512   ### I'm not sure what the version number should be, so I just guessed.
2513   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.2.0, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2514   if test "${HAVE_LIBXML2}" = "yes"; then
2515     LIBS="$LIBXML2_LIBS $LIBS"
2516     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2517     if test "${HAVE_LIBXML2}" = "yes"; then
2518       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2519     else
2520       LIBXML2_LIBS=""
2521       LIBXML2_CFLAGS=""
2522     fi
2523   fi
2524 fi
2525 AC_SUBST(LIBXML2_LIBS)
2526 AC_SUBST(LIBXML2_CFLAGS)
2527
2528 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2529 AC_CACHE_CHECK(whether netdb declares h_errno,
2530                emacs_cv_netdb_declares_h_errno,
2531 [AC_TRY_LINK([#include <netdb.h>],
2532   [return h_errno;],
2533   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2534 if test $emacs_cv_netdb_declares_h_errno = yes; then
2535   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2536 fi
2537
2538 AC_FUNC_ALLOCA
2539
2540 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2541 dnl FIXME is there an autoconf test that does the right thing, without
2542 dnl needing to call A_M_E afterwards?
2543 if test x"$ac_cv_func_alloca_works" != xyes; then
2544    AC_MSG_ERROR( [a system implementation of alloca is required] )
2545 fi
2546
2547 # fmod, logb, and frexp are found in -lm on most systems.
2548 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2549 AC_CHECK_LIB(m, sqrt)
2550
2551 # Check for mail-locking functions in a "mail" library.  Probably this should
2552 # have the same check as for liblockfile below.
2553 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2554 if test $have_mail = yes; then
2555   LIBS_MAIL=-lmail
2556   LIBS="$LIBS_MAIL $LIBS"
2557   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2558 else
2559   LIBS_MAIL=
2560 fi
2561 dnl Debian, at least:
2562 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2563 if test $have_lockfile = yes; then
2564    LIBS_MAIL=-llockfile
2565    LIBS="$LIBS_MAIL $LIBS"
2566    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2567 else
2568 # If we have the shared liblockfile, assume we must use it for mail
2569 # locking (e.g. Debian).  If we couldn't link against liblockfile
2570 # (no liblockfile.a installed), ensure that we don't need to.
2571   dnl This works for files generally, not just executables.
2572   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2573   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2574                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2575   if test $ac_cv_prog_liblockfile = yes; then
2576     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2577 This probably means that movemail could lose mail.
2578 There may be a `development' package to install containing liblockfile.])
2579   fi
2580 fi
2581 AC_CHECK_FUNCS(touchlock)
2582 AC_CHECK_HEADERS(maillock.h)
2583 AC_SUBST(LIBS_MAIL)
2584
2585 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2586 ## interlock access to the mail spool.  The alternative is a lock file named
2587 ## /usr/spool/mail/$USER.lock.
2588 mail_lock=no
2589 case "$opsys" in
2590   aix4-2) mail_lock="lockf" ;;
2591
2592   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2593
2594   ## On GNU/Linux systems, both methods are used by various mail programs.
2595   ## I assume most people are using newer mailers that have heard of flock.
2596   ## Change this if you need to.
2597   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2598   ## configure gets the right answers, and that means *NOT* using flock.
2599   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2600   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2601   ## Debian maintainer hasn't provided a clean fix for Emacs.
2602   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2603   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2604   ## correct logic.  -- fx
2605   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2606   ## liblockfile is a Free Software replacement for libmail, used on
2607   ## Debian systems and elsewhere. -rfr.
2608   gnu-*)
2609     mail_lock="flock"
2610     if test $have_mail = yes || test $have_lockfile = yes; then
2611       test $ac_cv_header_maillock_h = yes && mail_lock=no
2612     fi
2613     ;;
2614 esac
2615
2616 BLESSMAIL_TARGET=
2617 case "$mail_lock" in
2618   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2619
2620   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2621
2622   *) BLESSMAIL_TARGET="need-blessmail" ;;
2623 esac
2624 AC_SUBST(BLESSMAIL_TARGET)
2625
2626
2627 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2628 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2629 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2630 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2631 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2632 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm strchr strrchr \
2633 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2634 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2635 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2636 cfmakeraw cfsetspeed isnan copysign __executable_start)
2637
2638 dnl Cannot use AC_CHECK_FUNCS
2639 AC_CACHE_CHECK([for __builtin_unwind_init],
2640                emacs_cv_func___builtin_unwind_init,
2641 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2642                 emacs_cv_func___builtin_unwind_init=yes,
2643                 emacs_cv_func___builtin_unwind_init=no)])
2644 if test $emacs_cv_func___builtin_unwind_init = yes; then
2645   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2646             [Define to 1 if you have the `__builtin_unwind_init' function.])
2647 fi
2648
2649 AC_CHECK_HEADERS(sys/un.h)
2650
2651 AC_FUNC_MKTIME
2652 if test "$ac_cv_func_working_mktime" = no; then
2653   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2654 fi
2655
2656 AC_FUNC_GETLOADAVG
2657
2658 AC_FUNC_FSEEKO
2659
2660 # Configure getopt.
2661 m4_include([m4/getopt.m4])
2662 gl_GETOPT_IFELSE([
2663   gl_GETOPT_SUBSTITUTE_HEADER
2664   gl_PREREQ_GETOPT
2665   GETOPTOBJS='getopt.o getopt1.o'
2666 ])
2667 AC_SUBST(GETOPTOBJS)
2668
2669 AC_FUNC_GETPGRP
2670
2671 AC_FUNC_STRFTIME
2672
2673 # UNIX98 PTYs.
2674 AC_CHECK_FUNCS(grantpt)
2675
2676 # PTY-related GNU extensions.
2677 AC_CHECK_FUNCS(getpt)
2678
2679 # Check this now, so that we will NOT find the above functions in ncurses.
2680 # That is because we have not set up to link ncurses in lib-src.
2681 # It's better to believe a function is not available
2682 # than to expect to find it in ncurses.
2683 # Also we need tputs and friends to be able to build at all.
2684 have_tputs_et_al=true
2685 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2686 if test "$have_tputs_et_al" != true; then
2687   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2688 Maybe some development libraries/packages are missing?  Try installing
2689 libncurses-dev(el), libterminfo-dev(el) or similar.])
2690 fi
2691 # Must define this when any termcap library is found.
2692 AC_DEFINE(HAVE_LIBNCURSES, 1,
2693           [Define to 1 if you have the `ncurses' library (-lncurses).])
2694 ## FIXME This was the cpp logic, but I am not sure it is right.
2695 ## The above test has not necessarily found libncurses.
2696 HAVE_LIBNCURSES=yes
2697
2698 ## Use terminfo instead of termcap?
2699 ## Note only system files NOT using terminfo are:
2700 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2701 ## darwin|gnu without ncurses.
2702 TERMINFO=no
2703 LIBS_TERMCAP=
2704 case "$opsys" in
2705   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2706   ## hpux10-20: Use the system provided termcap(3) library.
2707   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2708   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2709   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2710
2711   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2712   ##  The ncurses library has been moved out of the System framework in
2713   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2714   ##  option to use it.
2715   darwin|gnu*)
2716     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2717     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2718       TERMINFO=yes
2719       LIBS_TERMCAP="-lncurses"
2720     fi
2721     ;;
2722
2723   freebsd)
2724     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2725     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2726     [AC_TRY_LINK([#include <osreldate.h>],
2727 [#if __FreeBSD_version < 400000
2728 fail;
2729 #endif
2730 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2731
2732     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2733
2734     if test $emacs_cv_freebsd_terminfo = yes; then
2735       TERMINFO=yes
2736       LIBS_TERMCAP="-lncurses"
2737     else
2738       LIBS_TERMCAP="-ltermcap"
2739     fi
2740     ;;
2741
2742   netbsd)
2743     if test $ac_cv_search_tputs = -lterminfo; then
2744       TERMINFO=yes
2745       LIBS_TERMCAP="-lterminfo"
2746     else
2747       LIBS_TERMCAP="-ltermcap"
2748     fi
2749     ;;
2750
2751 esac
2752
2753 case "$opsys" in
2754   ## hpux: Make sure we get select from libc rather than from libcurses
2755   ##  because libcurses on HPUX 10.10 has a broken version of select.
2756   ##  We used to use -lc -lcurses, but this may be cleaner.
2757   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2758
2759   openbsd) LIBS_TERMCAP="-lncurses" ;;
2760
2761   ## Must use system termcap, if we use any termcap.  It does special things.
2762   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2763 esac
2764
2765 TERMCAP_OBJ=tparam.o
2766 if test $TERMINFO = yes; then
2767   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2768
2769   ## Default used to be -ltermcap.  Add a case above if need something else.
2770   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2771
2772   TERMCAP_OBJ=terminfo.o
2773 fi
2774 AC_SUBST(LIBS_TERMCAP)
2775 AC_SUBST(TERMCAP_OBJ)
2776
2777
2778 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2779 resolv=no
2780 AC_TRY_LINK([#include <netinet/in.h>
2781 #include <arpa/nameser.h>
2782 #include <resolv.h>],
2783     [return res_init();],
2784     have_res_init=yes, have_res_init=no)
2785 if test "$have_res_init" = no; then
2786   OLIBS="$LIBS"
2787   LIBS="$LIBS -lresolv"
2788   AC_MSG_CHECKING(for res_init with -lresolv)
2789   AC_TRY_LINK([#include <netinet/in.h>
2790 #include <arpa/nameser.h>
2791 #include <resolv.h>],
2792     [return res_init();],
2793     have_res_init=yes, have_res_init=no)
2794   AC_MSG_RESULT($have_res_init)
2795   if test "$have_res_init" = yes ; then
2796     resolv=yes
2797   fi
2798   LIBS="$OLIBS"
2799 fi
2800
2801 if test "$have_res_init" = yes; then
2802   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2803 fi
2804
2805 # Do we need the Hesiod library to provide the support routines?
2806 LIBHESIOD=
2807 if test "$with_hesiod" != no ; then
2808   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2809   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2810      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2811                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2812   if test "$resolv" = yes ; then
2813     RESOLVLIB=-lresolv
2814   else
2815     RESOLVLIB=
2816   fi
2817   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2818         hesiod=yes, :, $RESOLVLIB)])
2819
2820   if test x"$hesiod" = xyes; then
2821     AC_DEFINE(HAVE_LIBHESIOD, 1,
2822               [Define to 1 if you have the hesiod library (-lhesiod).])
2823     LIBHESIOD=-lhesiod
2824   fi
2825 fi
2826 AC_SUBST(LIBHESIOD)
2827
2828 # Do we need libresolv (due to res_init or Hesiod)?
2829 if test "$resolv" = yes ; then
2830   AC_DEFINE(HAVE_LIBRESOLV, 1,
2831             [Define to 1 if you have the resolv library (-lresolv).])
2832   LIBRESOLV=-lresolv
2833 else
2834   LIBRESOLV=
2835 fi
2836 AC_SUBST(LIBRESOLV)
2837
2838 # These tell us which Kerberos-related libraries to use.
2839 COM_ERRLIB=
2840 CRYPTOLIB=
2841 KRB5LIB=
2842 DESLIB=
2843 KRB4LIB=
2844
2845 if test "${with_kerberos}" != no; then
2846   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2847   if test $have_com_err = yes; then
2848     COM_ERRLIB=-lcom_err
2849     LIBS="$COM_ERRLIB $LIBS"
2850     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2851   fi
2852   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2853   if test $have_crypto = yes; then
2854     CRYPTOLIB=-lcrypto
2855     LIBS="$CRYPTOLIB $LIBS"
2856     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2857   fi
2858   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2859   if test $have_k5crypto = yes; then
2860     CRYPTOLIB=-lk5crypto
2861     LIBS="$CRYPTOLIB $LIBS"
2862     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2863   fi
2864   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2865   if test $have_krb5=yes; then
2866     KRB5LIB=-lkrb5
2867     LIBS="$KRB5LIB $LIBS"
2868     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2869   fi
2870   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2871   if test "${with_kerberos5}" = no; then
2872     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2873     if test $have_des425 = yes; then
2874       DESLIB=-ldes425
2875       LIBS="$DESLIB $LIBS"
2876       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2877     else
2878       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2879       if test $have_des = yes; then
2880         DESLIB=-ldes
2881         LIBS="$DESLIB $LIBS"
2882         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2883       fi
2884     fi
2885     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2886     if test $have_krb4 = yes; then
2887       KRB4LIB=-lkrb4
2888       LIBS="$KRB4LIB $LIBS"
2889       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2890     else
2891       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2892       if test $have_krb = yes; then
2893         KRB4LIB=-lkrb
2894         LIBS="$KRB4LIB $LIBS"
2895         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2896       fi
2897     fi
2898   fi
2899
2900   if test "${with_kerberos5}" != no; then
2901     AC_CHECK_HEADERS(krb5.h,
2902       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2903                         [#include <krb5.h>])])
2904   else
2905     AC_CHECK_HEADERS(des.h,,
2906                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2907                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2908     AC_CHECK_HEADERS(krb.h,,
2909                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2910                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2911   fi
2912   AC_CHECK_HEADERS(com_err.h)
2913 fi
2914
2915 AC_SUBST(COM_ERRLIB)
2916 AC_SUBST(CRYPTOLIB)
2917 AC_SUBST(KRB5LIB)
2918 AC_SUBST(DESLIB)
2919 AC_SUBST(KRB4LIB)
2920
2921 # Solaris requires -lintl if you want strerror (which calls dgettext)
2922 # to return localized messages.
2923 AC_CHECK_LIB(intl, dgettext)
2924
2925 AC_MSG_CHECKING(whether localtime caches TZ)
2926 AC_CACHE_VAL(emacs_cv_localtime_cache,
2927 [if test x$ac_cv_func_tzset = xyes; then
2928 AC_TRY_RUN([#include <time.h>
2929 char TZ_GMT0[] = "TZ=GMT0";
2930 char TZ_PST8[] = "TZ=PST8";
2931 main()
2932 {
2933   time_t now = time ((time_t *) 0);
2934   int hour_GMT0, hour_unset;
2935   if (putenv (TZ_GMT0) != 0)
2936     exit (1);
2937   hour_GMT0 = localtime (&now)->tm_hour;
2938   unsetenv("TZ");
2939   hour_unset = localtime (&now)->tm_hour;
2940   if (putenv (TZ_PST8) != 0)
2941     exit (1);
2942   if (localtime (&now)->tm_hour == hour_GMT0)
2943     exit (1);
2944   unsetenv("TZ");
2945   if (localtime (&now)->tm_hour != hour_unset)
2946     exit (1);
2947   exit (0);
2948 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2949 [# If we have tzset, assume the worst when cross-compiling.
2950 emacs_cv_localtime_cache=yes])
2951 else
2952         # If we lack tzset, report that localtime does not cache TZ,
2953         # since we can't invalidate the cache if we don't have tzset.
2954         emacs_cv_localtime_cache=no
2955 fi])dnl
2956 AC_MSG_RESULT($emacs_cv_localtime_cache)
2957 if test $emacs_cv_localtime_cache = yes; then
2958   AC_DEFINE(LOCALTIME_CACHE, 1,
2959             [Define to 1 if localtime caches TZ.])
2960 fi
2961
2962 if test "x$HAVE_TIMEVAL" = xyes; then
2963   AC_CHECK_FUNCS(gettimeofday)
2964   if test $ac_cv_func_gettimeofday = yes; then
2965     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2966                    emacs_cv_gettimeofday_two_arguments,
2967     [AC_TRY_COMPILE([
2968 #ifdef TIME_WITH_SYS_TIME
2969 #include <sys/time.h>
2970 #include <time.h>
2971 #else
2972 #ifdef HAVE_SYS_TIME_H
2973 #include <sys/time.h>
2974 #else
2975 #include <time.h>
2976 #endif
2977 #endif],
2978       [struct timeval time;
2979        gettimeofday (&time, 0);],
2980       emacs_cv_gettimeofday_two_arguments=yes,
2981       emacs_cv_gettimeofday_two_arguments=no)])
2982     if test $emacs_cv_gettimeofday_two_arguments = no; then
2983       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2984                 [Define to 1 if gettimeofday accepts only one argument.])
2985     fi
2986   fi
2987 fi
2988
2989 ok_so_far=yes
2990 AC_CHECK_FUNC(socket, , ok_so_far=no)
2991 if test $ok_so_far = yes; then
2992   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2993 fi
2994 if test $ok_so_far = yes; then
2995   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2996 fi
2997 if test $ok_so_far = yes; then
2998 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2999   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3000             [Define to 1 if you have inet sockets.])
3001 fi
3002
3003 if test -f /usr/lpp/X11/bin/smt.exp; then
3004   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3005             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3006 fi
3007
3008 AC_MSG_CHECKING(whether system supports dynamic ptys)
3009 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3010   AC_MSG_RESULT(yes)
3011   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3012 else
3013   AC_MSG_RESULT(no)
3014 fi
3015
3016 AC_FUNC_FORK
3017
3018 dnl Adapted from Haible's version.
3019 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3020   [AC_TRY_LINK([#include <langinfo.h>],
3021     [char* cs = nl_langinfo(CODESET);],
3022     emacs_cv_langinfo_codeset=yes,
3023     emacs_cv_langinfo_codeset=no)
3024   ])
3025 if test $emacs_cv_langinfo_codeset = yes; then
3026   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3027     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3028 fi
3029
3030 AC_CHECK_TYPES(size_t)
3031
3032 AC_TYPE_MBSTATE_T
3033
3034 dnl Restrict could probably be used effectively other than in regex.c.
3035 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
3036   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
3037                   emacs_cv_c_restrict=yes,
3038                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
3039                                   emacs_cv_c_restrict=__restrict,
3040                                   emacs_cv_c_restrict=no)])])
3041 case "$emacs_cv_c_restrict" in
3042   yes) emacs_restrict=restrict;;
3043   no) emacs_restrict="";;
3044   *) emacs_restrict="$emacs_cv_c_restrict";;
3045 esac
3046 if test "$emacs_restrict" != __restrict; then
3047   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
3048     [Define to compiler's equivalent of C99 restrict keyword.
3049      Don't define if equivalent is `__restrict'.])
3050 fi
3051
3052 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3053   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3054                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3055 if test "$emacs_cv_c_restrict_arr" = yes; then
3056   AC_DEFINE(__restrict_arr, __restrict,
3057     [Define to compiler's equivalent of C99 restrict keyword in array
3058      declarations.  Define as empty for no equivalent.])
3059 fi
3060
3061 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3062 dnl how the tty code is related to POSIX and/or other versions of termios.
3063 dnl The following looks like a useful start.
3064 dnl
3065 dnl AC_SYS_POSIX_TERMIOS
3066 dnl if test $ac_cv_sys_posix_termios = yes; then
3067 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3068 dnl                                and macros for terminal control.])
3069 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3070 dnl fi
3071
3072 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3073
3074 # Set up the CFLAGS for real compilation, so we can substitute it.
3075 CFLAGS="$REAL_CFLAGS"
3076 CPPFLAGS="$REAL_CPPFLAGS"
3077
3078 ## Hack to detect a buggy GCC version.
3079 if test "x$GCC" = xyes \
3080    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3081    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3082    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3083    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3084 fi
3085
3086 #### Find out which version of Emacs this is.
3087 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3088          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3089 if test x"${version}" = x; then
3090   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3091 fi
3092 if test x"${version}" != x"$PACKAGE_VERSION"; then
3093   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3094 fi
3095
3096 ### Specify what sort of things we'll be editing into Makefile and config.h.
3097 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3098 AC_SUBST(version)
3099 AC_SUBST(configuration)
3100 ## Unused?
3101 AC_SUBST(canonical)
3102 AC_SUBST(srcdir)
3103 AC_SUBST(prefix)
3104 AC_SUBST(exec_prefix)
3105 AC_SUBST(bindir)
3106 AC_SUBST(datadir)
3107 AC_SUBST(sharedstatedir)
3108 AC_SUBST(libexecdir)
3109 AC_SUBST(mandir)
3110 AC_SUBST(infodir)
3111 AC_SUBST(lispdir)
3112 AC_SUBST(locallisppath)
3113 AC_SUBST(lisppath)
3114 AC_SUBST(x_default_search_path)
3115 AC_SUBST(etcdir)
3116 AC_SUBST(archlibdir)
3117 AC_SUBST(docdir)
3118 AC_SUBST(bitmapdir)
3119 AC_SUBST(gamedir)
3120 AC_SUBST(gameuser)
3121 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3122 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3123 ## end of LIBX_BASE, but nothing ever set it.
3124 AC_SUBST(LD_SWITCH_X_SITE)
3125 AC_SUBST(C_SWITCH_X_SITE)
3126 AC_SUBST(C_SWITCH_X_SYSTEM)
3127 AC_SUBST(CFLAGS)
3128 ## Used in lwlib/Makefile.in.
3129 AC_SUBST(X_TOOLKIT_TYPE)
3130 if test -n "${machfile}"; then
3131   M_FILE="\$(srcdir)/${machfile}"
3132 else
3133   M_FILE=
3134 fi
3135 S_FILE="\$(srcdir)/${opsysfile}"
3136 AC_SUBST(M_FILE)
3137 AC_SUBST(S_FILE)
3138 AC_SUBST(GETLOADAVG_LIBS)
3139 AC_SUBST(ns_appdir)
3140 AC_SUBST(ns_appbindir)
3141 AC_SUBST(ns_appresdir)
3142 AC_SUBST(ns_appsrc)
3143 AC_SUBST(GNU_OBJC_CFLAGS)
3144 AC_SUBST(OTHER_FILES)
3145
3146 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3147                    [Define to the canonical Emacs configuration name.])
3148 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3149                    [Define to the options passed to configure.])
3150 if test -n "$machfile"; then
3151   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3152                      [Define to the used machine dependent file.])
3153 fi
3154 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3155                    [Define to the used os dependent file.])
3156
3157 XMENU_OBJ=
3158 XOBJ=
3159 FONT_OBJ=
3160 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3161   AC_DEFINE(HAVE_X_WINDOWS, 1,
3162             [Define to 1 if you want to use the X window system.])
3163   XMENU_OBJ=xmenu.o
3164   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3165   FONT_OBJ=xfont.o
3166   if test "$HAVE_XFT" = "yes"; then
3167     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3168   elif test "$HAVE_FREETYPE" = "yes"; then
3169     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3170   fi
3171   AC_SUBST(FONT_OBJ)
3172 fi
3173 AC_SUBST(XMENU_OBJ)
3174 AC_SUBST(XOBJ)
3175 AC_SUBST(FONT_OBJ)
3176
3177 WIDGET_OBJ=
3178 MOTIF_LIBW=
3179 if test "${USE_X_TOOLKIT}" != "none" ; then
3180   WIDGET_OBJ=widget.o
3181   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3182   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3183     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3184   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3185     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3186     MOTIF_LIBW=-lXm
3187     case "$opsys" in
3188       gnu-linux)
3189         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3190         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3191         ;;
3192
3193       unixware)
3194         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3195         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3196         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3197         ;;
3198
3199       aix4-2)
3200         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3201         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3202         ;;
3203     esac
3204     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3205   fi
3206 fi
3207 AC_SUBST(WIDGET_OBJ)
3208
3209 TOOLKIT_LIBW=
3210 case "$USE_X_TOOLKIT" in
3211   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3212   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3213   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3214 esac
3215 AC_SUBST(TOOLKIT_LIBW)
3216
3217 if test "$USE_X_TOOLKIT" = "none"; then
3218   LIBXT_OTHER="\$(LIBXSM)"
3219   OLDXMENU_TARGET="really-oldXMenu"
3220 else
3221   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3222   OLDXMENU_TARGET="really-lwlib"
3223 fi
3224 AC_SUBST(LIBXT_OTHER)
3225
3226 ## The X Menu stuff is present in the X10 distribution, but missing
3227 ## from X11.  If we have X10, just use the installed library;
3228 ## otherwise, use our own copy.
3229 if test "${HAVE_X11}" = "yes" ; then
3230   AC_DEFINE(HAVE_X11, 1,
3231             [Define to 1 if you want to use version 11 of X windows.
3232              Otherwise, Emacs expects to use version 10.])
3233
3234   if test "$USE_X_TOOLKIT" = "none"; then
3235     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3236   else
3237     OLDXMENU="\${lwlibdir}/liblw.a"
3238   fi
3239   LIBXMENU="\$(OLDXMENU)"
3240   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3241   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3242 else
3243   ## For a syntactically valid Makefile; not actually used for anything.
3244   ## See comments in src/Makefile.in.
3245   OLDXMENU=nothing
3246   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3247   if test "${HAVE_X_WINDOWS}" = "yes"; then
3248     LIBXMENU="-lXMenu"
3249   else
3250     LIBXMENU=
3251   fi
3252   LIBX_OTHER=
3253   OLDXMENU_DEPS=
3254 fi
3255
3256 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3257   OLDXMENU_TARGET=
3258   OLDXMENU=nothing
3259   LIBXMENU=
3260   OLDXMENU_DEPS=
3261 fi
3262
3263 AC_SUBST(OLDXMENU_TARGET)
3264 AC_SUBST(OLDXMENU)
3265 AC_SUBST(LIBXMENU)
3266 AC_SUBST(LIBX_OTHER)
3267 AC_SUBST(OLDXMENU_DEPS)
3268
3269 if test "${HAVE_MENUS}" = "yes" ; then
3270   AC_DEFINE(HAVE_MENUS, 1,
3271             [Define to 1 if you have mouse menus.
3272              (This is automatic if you use X, but the option to specify it remains.)
3273              It is also defined with other window systems that support xmenu.c.])
3274 fi
3275
3276 if test "${GNU_MALLOC}" = "yes" ; then
3277   AC_DEFINE(GNU_MALLOC, 1,
3278             [Define to 1 if you want to use the GNU memory allocator.])
3279 fi
3280
3281 RALLOC_OBJ=
3282 if test "${REL_ALLOC}" = "yes" ; then
3283   AC_DEFINE(REL_ALLOC, 1,
3284             [Define REL_ALLOC if you want to use the relocating allocator for
3285              buffer space.])
3286
3287   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3288 fi
3289 AC_SUBST(RALLOC_OBJ)
3290
3291 if test "$opsys" = "cygwin"; then
3292   CYGWIN_OBJ="sheap.o"
3293   ## Cygwin differs because of its unexec().
3294   PRE_ALLOC_OBJ=
3295   POST_ALLOC_OBJ=lastfile.o
3296 else
3297   CYGWIN_OBJ=
3298   PRE_ALLOC_OBJ=lastfile.o
3299   POST_ALLOC_OBJ=
3300 fi
3301 AC_SUBST(CYGWIN_OBJ)
3302 AC_SUBST(PRE_ALLOC_OBJ)
3303 AC_SUBST(POST_ALLOC_OBJ)
3304
3305
3306 case "$opsys" in
3307   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3308
3309   darwin)
3310    ## The -headerpad option tells ld (see man page) to leave room at the
3311    ## end of the header for adding load commands.  Needed for dumping.
3312    ## 0x690 is the total size of 30 segment load commands (at 56
3313    ## each); under Cocoa 31 commands are required.
3314    if test "$HAVE_NS" = "yes"; then
3315      libs_nsgui="-framework AppKit"
3316      headerpad_extra=6C8
3317    else
3318      libs_nsgui=
3319      headerpad_extra=690
3320    fi
3321    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3322
3323    ## This is here because src/Makefile.in did some extra fiddling around
3324    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3325    ##   #ifndef LD_SWITCH_SYSTEM
3326    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3327    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3328    ## not using gcc, darwin system not on an alpha (ie darwin, since
3329    ## darwin + alpha does not occur).
3330    ## Because this was done in src/Makefile.in, the resulting part of
3331    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3332    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3333    ## rather than LD_SWITCH_SYSTEM.
3334    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3335      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3336    ;;
3337
3338   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3339   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3340   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3341   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3342   ## had different values in configure (in ac_link) and src/Makefile.in.
3343   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3344   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3345
3346   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3347 esac
3348
3349 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3350   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3351 fi
3352
3353 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3354
3355
3356 LD_FIRSTFLAG=
3357 ORDINARY_LINK=
3358 case "$opsys" in
3359   ## gnu: GNU needs its own crt0.
3360   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3361
3362   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3363   ## library search parth, i.e. it won't search /usr/lib for libc and
3364   ## friends.  Using -nostartfiles instead avoids this problem, and
3365   ## will also work on earlier NetBSD releases.
3366   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3367
3368   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3369   ##   MkLinux/LinuxPPC needs this.
3370   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3371   gnu-*)
3372     case "$machine" in
3373       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3374     esac
3375     ;;
3376 esac
3377
3378
3379 if test "x$ORDINARY_LINK" = "xyes"; then
3380
3381   LD_FIRSTFLAG=""
3382   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3383
3384 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3385 ## freebsd, gnu-* not on macppc|ibms390x.
3386 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3387
3388   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3389   ## places that are difficult to figure out at make time.  Fortunately,
3390   ## these same versions allow you to pass arbitrary flags on to the
3391   ## linker, so there is no reason not to use it as a linker.
3392   ##
3393   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3394   ## searching for libraries in its internal directories, so we have to
3395   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3396   LD_FIRSTFLAG="-nostdlib"
3397 fi
3398
3399 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3400 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3401
3402 AC_SUBST(LD_FIRSTFLAG)
3403
3404
3405 ## FIXME? The logic here is not precisely the same as that above.
3406 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3407 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3408 LIB_GCC=
3409 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3410
3411   case "$opsys" in
3412     freebsd|netbsd|openbsd) LIB_GCC= ;;
3413
3414     gnu-*)
3415       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3416       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3417       case $host_cpu in
3418       arm*)
3419         LIB_GCC="-lgcc_s"
3420         ;;
3421       *)
3422         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3423         ## immediately undefine it again and redefine it to empty.
3424         ## Was the C_SWITCH_X_SITE part really necessary?
3425 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3426         LIB_GCC=
3427         ;;
3428       esac
3429       ;;
3430
3431     ## Ask GCC where to find libgcc.a.
3432     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3433   esac
3434 fi                              dnl if $GCC
3435 AC_SUBST(LIB_GCC)
3436
3437
3438 TOOLTIP_SUPPORT=
3439 WINDOW_SUPPORT=
3440 ## If we're using X11/GNUstep, define some consequences.
3441 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3442   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3443   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3444   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3445   TOOLTIP_SUPPORT="\${lispsource}/mouse.elc"
3446
3447   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3448   test "$HAVE_X_WINDOWS" = "yes" && \
3449     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3450
3451 fi
3452 AC_SUBST(MOUSE_SUPPORT)
3453 AC_SUBST(TOOLTIP_SUPPORT)
3454 AC_SUBST(WINDOW_SUPPORT)
3455
3456
3457 AH_TOP([/* GNU Emacs site configuration template file.
3458    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3459      2006, 2007, 2008, 2009, 2010, 2011  Free Software Foundation, Inc.
3460
3461 This file is part of GNU Emacs.
3462
3463 GNU Emacs is free software: you can redistribute it and/or modify
3464 it under the terms of the GNU General Public License as published by
3465 the Free Software Foundation, either version 3 of the License, or
3466 (at your option) any later version.
3467
3468 GNU Emacs is distributed in the hope that it will be useful,
3469 but WITHOUT ANY WARRANTY; without even the implied warranty of
3470 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3471 GNU General Public License for more details.
3472
3473 You should have received a copy of the GNU General Public License
3474 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3475
3476
3477 /* No code in Emacs #includes config.h twice, but some bits of code
3478    intended to work with other packages as well (like gmalloc.c)
3479    think they can include it as many times as they like.  */
3480 #ifndef EMACS_CONFIG_H
3481 #define EMACS_CONFIG_H
3482 ])dnl
3483
3484 AH_BOTTOM([
3485 /* Define AMPERSAND_FULL_NAME if you use the convention
3486    that & in the full name stands for the login id.  */
3487 /* Turned on June 1996 supposing nobody will mind it.  */
3488 #define AMPERSAND_FULL_NAME
3489
3490 /* If using GNU, then support inline function declarations.  */
3491 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3492    generally, because even if non-gcc compilers accept `inline', they
3493    may reject `extern inline'.  */
3494 #if defined (__GNUC__)
3495 #define INLINE __inline__
3496 #else
3497 #define INLINE
3498 #endif
3499
3500 /* `subprocesses' should be defined if you want to
3501    have code for asynchronous subprocesses
3502    (as used in M-x compile and M-x shell).
3503    Only MSDOS does not support this (it overrides
3504    this in its config_opsysfile below).  */
3505
3506 #define subprocesses
3507
3508 /* Include the os and machine dependent files.  */
3509 #include config_opsysfile
3510 #ifdef config_machfile
3511 # include config_machfile
3512 #endif
3513
3514 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3515    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3516   (There is probably a better place to do this, but right now the
3517    Cocoa side does this in s/darwin.h and we cannot parallel this
3518    exactly since GNUstep is multi-OS.  */
3519 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3520 #  define SYSTEM_PURESIZE_EXTRA 30000
3521 #endif
3522
3523 /* SIGTYPE is the macro we actually use.  */
3524 #ifndef SIGTYPE
3525 #define SIGTYPE RETSIGTYPE
3526 #endif
3527
3528 #ifdef emacs /* Don't do this for lib-src.  */
3529 /* Tell regex.c to use a type compatible with Emacs.  */
3530 #define RE_TRANSLATE_TYPE Lisp_Object
3531 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3532 #ifdef make_number
3533 /* If make_number is a macro, use it.  */
3534 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3535 #else
3536 /* If make_number is a function, avoid it.  */
3537 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3538 #endif
3539 #endif
3540
3541 /* Avoid link-time collision with system mktime if we will use our own.  */
3542 #if ! HAVE_MKTIME || BROKEN_MKTIME
3543 #define mktime emacs_mktime
3544 #endif
3545
3546 #define my_strftime nstrftime   /* for strftime.c */
3547
3548 /* These default definitions are good for almost all machines.
3549    The exceptions override them in m/MACHINE.h.  */
3550
3551 #ifndef BITS_PER_CHAR
3552 #define BITS_PER_CHAR 8
3553 #endif
3554
3555 #ifndef BITS_PER_SHORT
3556 #define BITS_PER_SHORT 16
3557 #endif
3558
3559 /* Note that lisp.h uses this in a preprocessor conditional, so it
3560    would not work to use sizeof.  That being so, we do all of them
3561    without sizeof, for uniformity's sake.  */
3562 #ifndef BITS_PER_INT
3563 #define BITS_PER_INT 32
3564 #endif
3565
3566 #ifndef BITS_PER_LONG
3567 #ifdef _LP64
3568 #define BITS_PER_LONG 64
3569 #else
3570 #define BITS_PER_LONG 32
3571 #endif
3572 #endif
3573
3574 /* Define if the compiler supports function prototypes.  It may do so but
3575    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3576 #undef PROTOTYPES
3577
3578 #include <string.h>
3579 #include <stdlib.h>
3580
3581 #ifdef HAVE_ALLOCA_H
3582 # include <alloca.h>
3583 #elif defined __GNUC__
3584 # define alloca __builtin_alloca
3585 #elif defined _AIX
3586 # define alloca __alloca
3587 #else
3588 # include <stddef.h>
3589 # ifdef  __cplusplus
3590 extern "C"
3591 # endif
3592 void *alloca (size_t);
3593 #endif
3594
3595 #ifndef HAVE_SIZE_T
3596 typedef unsigned size_t;
3597 #endif
3598
3599 #ifndef HAVE_STRCHR
3600 #define strchr(a, b) index (a, b)
3601 #endif
3602
3603 #ifndef HAVE_STRRCHR
3604 #define strrchr(a, b) rindex (a, b)
3605 #endif
3606
3607 #if defined __GNUC__ && (__GNUC__ > 2 \
3608                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3609 #define NO_RETURN       __attribute__ ((__noreturn__))
3610 #else
3611 #define NO_RETURN       /* nothing */
3612 #endif
3613
3614 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3615 #define NO_INLINE __attribute__((noinline))
3616 #else
3617 #define NO_INLINE
3618 #endif
3619
3620 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3621 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3622 #else
3623 #define EXTERNALLY_VISIBLE
3624 #endif
3625
3626 /* Some versions of GNU/Linux define noinline in their headers.  */
3627 #ifdef noinline
3628 #undef noinline
3629 #endif
3630
3631 /* These won't be used automatically yet.  We also need to know, at least,
3632    that the stack is continuous.  */
3633 #ifdef __GNUC__
3634 #  ifndef GC_SETJMP_WORKS
3635   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3636 #    define GC_SETJMP_WORKS 1
3637 #  endif
3638 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3639 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3640 #  endif
3641 #endif
3642
3643 #endif /* EMACS_CONFIG_H */
3644
3645 /*
3646 Local Variables:
3647 mode: c
3648 End:
3649 */
3650 ])dnl
3651
3652 #### Report on what we decided to do.
3653 #### Report GTK as a toolkit, even if it doesn't use Xt.
3654 #### It makes printing result more understandable as using GTK sets
3655 #### toolkit_scroll_bars to yes by default.
3656 if test "${HAVE_GTK}" = "yes"; then
3657   USE_X_TOOLKIT=GTK
3658 fi
3659
3660 and_machfile=
3661 if test -n "$machfile"; then
3662   and_machfile=" and \`${machfile}'"
3663 fi
3664
3665 echo "
3666 Configured for \`${canonical}'.
3667
3668   Where should the build process find the source code?    ${srcdir}
3669   What operating system and machine description files should Emacs use?
3670         \`${opsysfile}'${and_machfile}
3671   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3672   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3673   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3674   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3675   What window system should Emacs use?                    ${window_system}
3676   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3677
3678 if test -n "${x_includes}"; then
3679 echo "  Where do we find X Windows header files?                ${x_includes}"
3680 else
3681 echo "  Where do we find X Windows header files?                Standard dirs"
3682 fi
3683 if test -n "${x_libraries}"; then
3684 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3685 else
3686 echo "  Where do we find X Windows libraries?                   Standard dirs"
3687 fi
3688
3689 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3690 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3691 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3692 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3693 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3694 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3695 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3696 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3697
3698 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3699 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3700 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3701 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3702 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3703 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3704
3705 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3706 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3707 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3708 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3709
3710 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3711 echo
3712
3713 if test $USE_XASSERTS = yes; then
3714    echo "  Compiling with asserts turned on."
3715    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3716 fi
3717
3718 echo
3719
3720 if test "$HAVE_NS" = "yes"; then
3721    echo
3722    echo "You must run \"make install\" in order to test the built application.
3723 The installed application will go to nextstep/Emacs.app and can be
3724 run or moved from there."
3725    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3726       echo "The application will be fully self-contained."
3727     else
3728       echo "The lisp resources for the application will be installed under ${prefix}.
3729 You may need to run \"make install\" with sudo.  The application will fail
3730 to run if these resources are not installed."
3731    fi
3732    echo
3733 fi
3734
3735
3736 # Remove any trailing slashes in these variables.
3737 [test "${prefix}" != NONE &&
3738   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3739 test "${exec_prefix}" != NONE &&
3740   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3741
3742 dnl You might wonder (I did) why epaths.h is generated by running make,
3743 dnl rather than just letting configure generate it from epaths.in.
3744 dnl One reason is that the various paths are not fully expanded (see above);
3745 dnl eg gamedir=${prefix}/var/games/emacs.
3746 dnl Secondly, the GNU Coding standards require that one should be able
3747 dnl to run `make prefix=/some/where/else' and override the values set
3748 dnl by configure.  This also explains the `move-if-change' test and
3749 dnl the use of force in the `epaths-force' rule in Makefile.in.
3750 AC_OUTPUT(Makefile lib-src/Makefile oldXMenu/Makefile \
3751         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3752         doc/lispref/Makefile src/Makefile \
3753         lwlib/Makefile lisp/Makefile leim/Makefile test/automated/Makefile, [
3754
3755 ### Make the necessary directories, if they don't exist.
3756 for dir in etc lisp ; do
3757   test -d ${dir} || mkdir ${dir}
3758 done
3759
3760 echo creating src/epaths.h
3761 ${MAKE-make} epaths-force
3762
3763 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3764   echo creating src/.gdbinit
3765   echo source $srcdir/src/.gdbinit > src/.gdbinit
3766 fi
3767
3768 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3769