lisp/window.el

   1 ;;; window.el --- GNU Emacs window commands aside from those written in C.
   2
   3 ;;; Copyright (C) 1985, 1989, 1992, 1993, 1994 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Code:
  24
  25 (defun count-windows (&optional minibuf)
  26    "Returns the number of visible windows.
  27 Optional arg NO-MINI non-nil means don't count the minibuffer
  28 even if it is active."
  29    (let ((count 0))
  30      (walk-windows (function (lambda (w)
  31                                (setq count (+ count 1))))
  32                    minibuf)
  33      count))
  34
  35 (defun balance-windows ()
  36   "Makes all visible windows the same height (approximately)."
  37   (interactive)
  38   (let ((count -1) levels newsizes size)
  39     ;; Find all the different vpos's at which windows start,
  40     ;; then count them.  But ignore levels that differ by only 1.
  41     (save-window-excursion
  42       (let (tops (prev-top -2))
  43         (walk-windows (function (lambda (w)
  44                                   (setq tops (cons (nth 1 (window-edges w))
  45                                                    tops))))
  46                       'nomini)
  47         (setq tops (sort tops '<))
  48         (while tops
  49           (if (> (car tops) (1+ prev-top))
  50               (setq prev-top (car tops)
  51                     count (1+ count)))
  52           (setq levels (cons (cons (car tops) count) levels))
  53           (setq tops (cdr tops)))
  54         (setq count (1+ count))))
  55     ;; Subdivide the frame into that many vertical levels.
  56     (setq size (/ (frame-height) count))
  57     (walk-windows (function
  58                    (lambda (w)
  59                      (select-window w)
  60                      (let ((newtop (cdr (assq (nth 1 (window-edges))
  61                                               levels)))
  62                            (newbot (or (cdr (assq (+ (window-height)
  63                                                      (nth 1 (window-edges)))
  64                                                   levels))
  65                                        count)))
  66                        (setq newsizes
  67                              (cons (cons w (* size (- newbot newtop)))
  68                                    newsizes))))))
  69     (walk-windows (function (lambda (w)
  70                               (select-window w)
  71                               (let ((newsize (cdr (assq w newsizes))))
  72                                 (enlarge-window (- newsize
  73                                                    (window-height))))))
  74                   'nomini)))
  75
  76 ;;; I think this should be the default; I think people will prefer it--rms.
  77 (defvar split-window-keep-point t
  78   "*If non-nil, split windows keeps the original point in both children.
  79 This is often more convenient for editing.
  80 If nil, adjust point in each of the two windows to minimize redisplay.
  81 This is convenient on slow terminals, but point can move strangely.")
  82
  83 (defun split-window-vertically (&optional arg)
  84   "Split current window into two windows, one above the other.
  85 The uppermost window gets ARG lines and the other gets the rest.
  86 Negative arg means select the size of the lowermost window instead.
  87 With no argument, split equally or close to it.
  88 Both windows display the same buffer now current.
  89
  90 If the variable split-window-keep-point is non-nil, both new windows
  91 will get the same value of point as the current window.  This is often
  92 more convenient for editing.
  93
  94 Otherwise, we chose window starts so as to minimize the amount of
  95 redisplay; this is convenient on slow terminals.  The new selected
  96 window is the one that the current value of point appears in.  The
  97 value of point can change if the text around point is hidden by the
  98 new mode line."
  99   (interactive "P")
 100   (let ((old-w (selected-window))
 101         (old-point (point))
 102         (size (and arg (prefix-numeric-value arg)))
 103         new-w bottom switch)
 104     (and size (< size 0) (setq size (+ (window-height) size)))
 105     (setq new-w (split-window nil size))
 106     (or split-window-keep-point
 107         (progn
 108           (save-excursion
 109             (set-buffer (window-buffer))
 110             (goto-char (window-start))
 111             (vertical-motion (window-height))
 112             (set-window-start new-w (point))
 113             (if (> (point) (window-point new-w))
 114                 (set-window-point new-w (point)))
 115             (vertical-motion -1)
 116             (setq bottom (point)))
 117           (if (<= bottom (point))
 118               (set-window-point old-w (1- bottom)))
 119           (if (< (window-start new-w) old-point)
 120               (progn
 121                 (set-window-point new-w old-point)
 122                 (select-window new-w)))))
 123     new-w))
 124
 125 (defun split-window-horizontally (&optional arg)
 126   "Split current window into two windows side by side.
 127 This window becomes the leftmost of the two, and gets
 128 ARG columns.  No arg means split equally."
 129   (interactive "P")
 130   (split-window nil (and arg (prefix-numeric-value arg)) t))
 131
 132 (defun enlarge-window-horizontally (arg)
 133   "Make current window ARG columns wider."
 134   (interactive "p")
 135   (enlarge-window arg t))
 136
 137 (defun shrink-window-horizontally (arg)
 138   "Make current window ARG columns narrower."
 139   (interactive "p")
 140   (shrink-window arg t))
 141
 142 (defun shrink-window-if-larger-than-buffer (&optional window)
 143   "Shrink the WINDOW to be as small as possible to display its contents.
 144 Do nothing if the buffer contains more lines than the present window height,
 145 or if some of the window's contents are scrolled out of view,
 146 or if the window is not the full width of the frame,
 147 or if the window is the only window of its frame."
 148   (interactive)
 149   (save-excursion
 150     (set-buffer (window-buffer window))
 151     (let ((w (selected-window)) ;save-window-excursion can't win
 152           (buffer-file-name buffer-file-name)
 153           (p (point))
 154           (n 0)
 155           (ignore-final-newline
 156            ;; If buffer ends with a newline, ignore it when counting height
 157            ;; unless point is after it.
 158            (and (not (eobp))
 159                 (eq ?\n (char-after (1- (point-max))))))
 160           (window-min-height 0)
 161           (buffer-read-only nil)
 162           (modified (buffer-modified-p))
 163           (buffer (current-buffer))
 164           (mini (cdr (assq 'minibuffer (frame-parameters))))
 165           (edges (window-edges (selected-window))))
 166       (if (and (< 1 (count-windows))
 167                (= (window-width) (screen-width))
 168                (pos-visible-in-window-p (point-min) window)
 169                (or (not mini)
 170                    (< (nth 3 edges)
 171                       (nth 1 (window-edges mini)))
 172                    (> (nth 1 edges)
 173                       (cdr (assq 'menu-bar-lines (frame-parameters))))))
 174           (unwind-protect
 175               (progn
 176                 (select-window (or window w))
 177                 (goto-char (point-min))
 178                 (while (pos-visible-in-window-p
 179                         (- (point-max)
 180                            (if ignore-final-newline 1 0)))
 181                   ;; defeat file locking... don't try this at home, kids!
 182                   (setq buffer-file-name nil)
 183                   (insert ?\n) (setq n (1+ n)))
 184                 (if (> n 0) (shrink-window (1- n))))
 185             (delete-region (point-min) (point))
 186             (set-buffer-modified-p modified)
 187             (goto-char p)
 188             (select-window w)
 189             ;; Make sure we unbind buffer-read-only
 190             ;; with the proper current buffer.
 191             (set-buffer buffer))))))
 192
 193 (define-key ctl-x-map "2" 'split-window-vertically)
 194 (define-key ctl-x-map "3" 'split-window-horizontally)
 195 (define-key ctl-x-map "}" 'enlarge-window-horizontally)
 196 (define-key ctl-x-map "{" 'shrink-window-horizontally)
 197 (define-key ctl-x-map "-" 'shrink-window-if-larger-than-buffer)
 198 (define-key ctl-x-map "+" 'balance-windows)
 199
 200 ;;; windows.el ends here