lisp/iswitchb.el

   1 ;;; iswitchb.el --- switch between buffers using substrings
   2
   3 ;; Copyright (C) 1996, 1997, 2000, 2001  Free Software Foundation, Inc.
   4
   5 ;; Author: Stephen Eglen <stephen@gnu.org>
   6 ;; Maintainer: Stephen Eglen <stephen@gnu.org>
   7 ;; Keywords: completion convenience
   8 ;; location: http://www.anc.ed.ac.uk/~stephen/emacs/
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Installation:
  30 ;; To get the functions in this package bound to keys, use
  31 ;; M-x iswitchb-mode or customize the option `iswitchb-mode'.
  32
  33 ;; As you type in a substring, the list of buffers currently matching
  34 ;; the substring is displayed as you type.  The list is ordered so
  35 ;; that the most recent buffers visited come at the start of the list.
  36 ;; The buffer at the start of the list will be the one visited when
  37 ;; you press return.  By typing more of the substring, the list is
  38 ;; narrowed down so that gradually the buffer you want will be at the
  39 ;; top of the list.  Alternatively, you can use C-s and C-r to rotate
  40 ;; buffer names in the list until the one you want is at the top of
  41 ;; the list.  Completion is also available so that you can see what is
  42 ;; common to all of the matching buffers as you type.
  43
  44 ;; This code is similar to a couple of other packages.  Michael R Cook
  45 ;; <cook@sightpath.com> wrote a similar buffer switching package, but
  46 ;; does exact matching rather than substring matching on buffer names.
  47 ;; I also modified a couple of functions from icomplete.el to provide
  48 ;; the completion feedback in the minibuffer.
  49
  50 ;;; Example
  51
  52 ;; If I have two buffers called "123456" and "123", with "123456" the
  53 ;; most recent, when I use iswitchb, I first of all get presented with
  54 ;; the list of all the buffers
  55 ;;
  56 ;;       iswitch  {123456,123}
  57 ;;
  58 ;; If I then press 2:
  59 ;;       iswitch 2[3]{123456,123}
  60 ;;
  61 ;; The list in {} are the matching buffers, most recent first (buffers
  62 ;; visible in the current frame are put at the end of the list by
  63 ;; default).  At any time I can select the item at the head of the
  64 ;; list by pressing RET.  I can also bring the put the first element
  65 ;; at the end of the list by pressing C-s, or put the last element at
  66 ;; the head of the list by pressing C-r.  The item in [] indicates
  67 ;; what can be added to my input by pressing TAB.  In this case, I
  68 ;; will get "3" added to my input.  So, press TAB:
  69 ;;       iswitch 23{123456,123}
  70 ;;
  71 ;; At this point, I still have two matching buffers.
  72 ;; If I want the first buffer in the list, I simply press RET.  If I
  73 ;; wanted the second in the list, I could press C-s to move it to the
  74 ;; top of the list and then RET to select it.
  75 ;;
  76 ;; However, if I type 4, I only have one match left:
  77 ;;       iswitch 234[123456] [Matched]
  78 ;;
  79 ;; Since there is only one matching buffer left, it is given in [] and we
  80 ;; see the text [Matched] afterwards.  I can now press TAB or RET to go
  81 ;; to that buffer.
  82 ;;
  83 ;; If however, I now type "a":
  84 ;;       iswitch 234a [No match]
  85 ;; There are no matching buffers.  If I press RET or TAB, I can be
  86 ;; prompted to create a new buffer called "234a".
  87 ;;
  88 ;; Of course, where this function comes in really useful is when you
  89 ;; can specify the buffer using only a few keystrokes.  In the above
  90 ;; example, the quickest way to get to the "123456" buffer would be
  91 ;; just to type 4 and then RET (assuming there isn't any newer buffer
  92 ;; with 4 in its name).
  93
  94 ;; To see a full list of all matching buffers in a separate buffer,
  95 ;; hit ? or press TAB when there are no further completions to the
  96 ;; substring.  Repeated TAB presses will scroll you through this
  97 ;; separate buffer.
  98
  99 ;; The buffer at the head of the list can be killed by pressing C-k.
 100 ;; If the buffer needs saving, you will be queried before the buffer
 101 ;; is killed.
 102
 103 ;; If you find that the file you are after is not in a buffer, you can
 104 ;; press C-x C-f to immediately drop into find-file.
 105
 106 ;; See the doc string of iswitchb for full keybindings and features.
 107 ;; (describe-function 'iswitchb)
 108
 109 ;; Case matching: The case of strings when matching can be ignored or
 110 ;; used depending on the value of iswitchb-case (default is the same
 111 ;; as case-fold-search, normally t).  Imagine you have the following
 112 ;; buffers:
 113 ;;
 114 ;; INBOX *info* *scratch*
 115 ;;
 116 ;; Then these will be the matching buffers, depending on how you type
 117 ;; the two letters `in' and the value of iswitchb-case:
 118 ;;
 119 ;; iswitchb-case   user input  | matching buffers
 120 ;; ----------------------------------------------
 121 ;; nil             in          | *info*
 122 ;; t               in          | INBOX, *info*
 123 ;; t               IN          | INBOX
 124 ;; t               In          | [No match]
 125
 126 ;;; Customisation
 127
 128 ;; See the User Variables section below for easy ways to change the
 129 ;; functionality of the program.  These are accessible using the
 130 ;; custom package.
 131 ;; To modify the keybindings, use something like:
 132 ;;
 133 ;;(add-hook 'iswitchb-mode-hook 'iswitchb-my-keys)
 134 ;;(defun iswitchb-my-keys ()
 135 ;;  "Add my keybindings for iswitchb."
 136 ;;  (define-key iswitchb-mode-map " " 'iswitchb-next-match))
 137 ;;
 138 ;; Seeing all the matching buffers
 139 ;;
 140 ;; If you have many matching buffers, they may not all fit onto one
 141 ;; line of the minibuffer.  In Emacs 21, the variable
 142 ;; `resize-mini-windows' controls how many lines of the minibuffer can
 143 ;; be seen.  For older versions of emacs, you can use
 144 ;; `resize-minibuffer-mode'.  You can also limit iswitchb so that it
 145 ;; only shows a certain number of lines -- see the documentation for
 146 ;; `iswitchb-minibuffer-setup-hook'.
 147
 148 ;; Changing the list of buffers
 149
 150 ;; By default, the list of current buffers is most recent first,
 151 ;; oldest last, with the exception that the buffers visible in the
 152 ;; current frame are put at the end of the list.  A hook exists to
 153 ;; allow other functions to order the list.  For example, if you add:
 154 ;;
 155 ;; (add-hook 'iswitchb-make-buflist-hook 'iswitchb-summaries-to-end)
 156 ;;
 157 ;; then all buffers matching "Summary" are moved to the end of the
 158 ;; list.  (I find this handy for keeping the INBOX Summary and so on
 159 ;; out of the way.)  It also moves buffers matching "output\*$" to the
 160 ;; end of the list (these are created by AUC TeX when compiling.)
 161 ;; Other functions could be made available which alter the list of
 162 ;; matching buffers (either deleting or rearranging elements.)
 163
 164 ;; Font-Lock
 165
 166 ;; If you have font-lock loaded, the first matching buffer is
 167 ;; highlighted.  To switch this off, set (setq iswitchb-use-fonts nil)
 168 ;; I don't use font-lock that much, so I've hardcoded the faces.  If
 169 ;; this is too harsh, let me know.  Colouring of the matching buffer
 170 ;; name was suggested by Carsten Dominik (dominik@strw.leidenuniv.nl)
 171
 172 ;; Replacement for read-buffer
 173
 174 ;; iswitchb-read-buffer has been written to be a drop in replacement
 175 ;; for the normal buffer selection routine `read-buffer'.  To use
 176 ;; iswitch for all buffer selections in Emacs, add:
 177 ;; (setq read-buffer-function 'iswitchb-read-buffer)
 178 ;; (This variable was introduced in Emacs 20.3.)
 179 ;; XEmacs users can get the same behaviour by doing:
 180 ;; (defalias 'read-buffer 'iswitchb-read-buffer)
 181 ;; since `read-buffer' is defined in lisp.
 182
 183 ;; Using iswitchb for other completion tasks.
 184
 185 ;; Kin Cho (kin@neoscale.com sent the following suggestion to use
 186 ;; iswitchb for other completion tasks.
 187 ;;
 188 ;; (defun my-icompleting-read (prompt choices)
 189 ;;   "Use iswitch as a completing-read replacement to choose from
 190 ;; choices.  PROMPT is a string to prompt with.  CHOICES is a list of
 191 ;; strings to choose from."
 192 ;;   (let ((iswitchb-make-buflist-hook
 193 ;;          (lambda ()
 194 ;;            (setq iswitchb-temp-buflist choices))))
 195 ;;     (iswitchb-read-buffer prompt)))
 196 ;;
 197 ;; example:
 198 ;; (my-icompleting-read "Which fruit? " '
 199 ;;                   ("apple" "pineapple" "pear" "bananas" "oranges") )
 200
 201 ;; Other lisp packages extend iswitchb behaviour to other tasks.  See
 202 ;; ido.el (by Kim Storm) and mcomplete.el (Yuji Minejima).
 203
 204 ;; Window managers: Switching frames/focus follows mouse; Sawfish.
 205
 206 ;; If you switch to a buffer that is visible in another frame,
 207 ;; iswitchb can switch focus to that frame.  If your window manager
 208 ;; uses "click to focus" policy for window selection, you should also
 209 ;; set focus-follows-mouse to nil.
 210
 211 ;; iswitch functionality has also been implemented for switching
 212 ;; between windows in the Sawfish window manager.
 213
 214 ;; Regexp matching
 215
 216 ;; There is limited provision for regexp matching within iswitchb,
 217 ;; enabled through `iswitchb-regexp'.  This allows you to type `c$'
 218 ;; for example and see all buffer names ending in `c'.  This facility
 219 ;; is quite limited though in two respects.  First, you can't
 220 ;; currently type in expressions like `[0-9]' directly -- you have to
 221 ;; type them in when iswitchb-regexp is nil and then toggle on the
 222 ;; regexp functionality.  Likewise, don't enter an expression
 223 ;; containing `\' in regexp mode.  If you try, iswitchb gets confused,
 224 ;; so just hit C-g and try again.  Secondly, no completion mechanism
 225 ;; is currently offered when regexp searching.
 226
 227 ;;; TODO
 228
 229 ;;; Acknowledgements
 230
 231 ;; Thanks to Jari Aalto <jari.aalto@poboxes.com> for help with the
 232 ;; first version of this package, iswitch-buffer.  Thanks also to many
 233 ;; others for testing earlier versions.
 234
 235 ;;; Code:
 236
 237 ;; CL needed for cadr and last
 238 (if (not (and (fboundp 'cadr)
 239               (fboundp 'last)))
 240     (require 'cl))
 241
 242 ;; Set up the custom library.
 243 ;; taken from http://www.dina.kvl.dk/~abraham/custom/
 244 (eval-and-compile
 245   (condition-case ()
 246       (require 'custom)
 247     (error nil))
 248   (if (and (featurep 'custom) (fboundp 'custom-declare-variable))
 249       nil ;; We've got what we needed
 250     ;; We have the old custom-library, hack around it!
 251     (defmacro defgroup (&rest args)
 252       nil)
 253     (defmacro defcustom (var value doc &rest args)
 254       `(defvar ,var ,value ,doc))))
 255
 256 ;;; User Variables
 257 ;;
 258 ;; These are some things you might want to change.
 259
 260 (defgroup iswitchb nil
 261   "Switch between buffers using substrings."
 262   :group 'convenience
 263   :group 'completion
 264   :link '(emacs-commentary-link :tag "Commentary" "iswitchb.el")
 265   :link '(url-link "http://www.anc.ed.ac.uk/~stephen/emacs/")
 266   :link '(emacs-library-link :tag "Lisp File" "iswitchb.el"))
 267
 268 (defcustom iswitchb-case case-fold-search
 269   "*Non-nil if searching of buffer names should ignore case.
 270 If this is non-nil but the user input has any upper case letters, matching
 271 is temporarily case sensitive."
 272   :type 'boolean
 273   :group 'iswitchb)
 274
 275 (defcustom iswitchb-buffer-ignore
 276   '("^ ")
 277   "*List of regexps or functions matching buffer names to ignore.
 278 For example, traditional behavior is not to list buffers whose names begin
 279 with a space, for which the regexp is `^ '.  See the source file for
 280 example functions that filter buffernames."
 281   :type '(repeat regexp)
 282   :group 'iswitchb)
 283
 284 (defcustom iswitchb-cannot-complete-hook 'iswitchb-completion-help
 285   "*Hook run when `iswitchb-complete' can't complete any more.
 286 The most useful values are `iswitchb-completion-help', which pops up a
 287 window with completion alternatives, or `iswitchb-next-match' or
 288 `iswitchb-prev-match', which cycle the buffer list."
 289   :type 'hook
 290   :group 'iswitchb)
 291
 292 ;;; Examples for setting the value of iswitchb-buffer-ignore
 293 ;(defun iswitchb-ignore-c-mode (name)
 294 ;  "Ignore all c mode buffers -- example function for iswitchb."
 295 ;  (save-excursion
 296 ;    (set-buffer name)
 297 ;    (string-match "^C$" mode-name)))
 298
 299 ;(setq iswitchb-buffer-ignore '("^ " iswitchb-ignore-c-mode))
 300 ;(setq iswitchb-buffer-ignore '("^ " "\\.c$" "\\.h$"))
 301
 302 (defcustom iswitchb-default-method  'always-frame
 303     "*How to switch to new buffer when using `iswitchb-buffer'.
 304 Possible values:
 305 `samewindow'    Show new buffer in same window
 306 `otherwindow'   Show new buffer in another window (same frame)
 307 `display'       Display buffer in another window without switching to it
 308 `otherframe'    Show new buffer in another frame
 309 `maybe-frame'   If a buffer is visible in another frame, prompt to ask if you
 310                 you want to see the buffer in the same window of the current
 311                 frame or in the other frame.
 312 `always-frame'  If a buffer is visible in another frame, raise that
 313                 frame.  Otherwise, visit the buffer in the same window."
 314     :type '(choice (const samewindow)
 315                    (const otherwindow)
 316                    (const display)
 317                    (const otherframe)
 318                    (const maybe-frame)
 319                    (const always-frame))
 320     :group 'iswitchb)
 321
 322 (defcustom iswitchb-regexp nil
 323   "*Non-nil means that `iswitchb' will do regexp matching.
 324 Value can be toggled within `iswitchb' using `iswitchb-toggle-regexp'."
 325   :type 'boolean
 326   :group 'iswitchb)
 327
 328 (defcustom iswitchb-newbuffer t
 329   "*Non-nil means create new buffer if no buffer matches substring.
 330 See also `iswitchb-prompt-newbuffer'."
 331   :type 'boolean
 332   :group 'iswitchb)
 333
 334 (defcustom iswitchb-prompt-newbuffer t
 335   "*Non-nil means prompt user to confirm before creating new buffer.
 336 See also `iswitchb-newbuffer'."
 337   :type 'boolean
 338   :group 'iswitchb)
 339
 340 (defcustom iswitchb-use-fonts t
 341   "*Non-nil means use font-lock fonts for showing first match."
 342   :type 'boolean
 343   :group 'iswitchb)
 344
 345 (defcustom iswitchb-use-frame-buffer-list nil
 346   "*Non-nil means use the currently selected frame's buffer list."
 347   :type 'boolean
 348   :group 'iswitchb)
 349
 350 (defcustom iswitchb-make-buflist-hook  nil
 351   "Hook to run when list of matching buffers is created."
 352   :type 'hook
 353   :group 'iswitchb)
 354
 355 (defvar iswitchb-all-frames 'visible
 356   "*Argument to pass to `walk-windows' when finding visible buffers.
 357 See documentation of `walk-windows' for useful values.")
 358
 359 (defcustom iswitchb-minibuffer-setup-hook nil
 360   "Iswitchb-specific customization of minibuffer setup.
 361
 362 This hook is run during minibuffer setup iff `iswitchb' will be active.
 363 It is intended for use in customizing iswitchb for interoperation
 364 with other packages."
 365 ;;;   For instance:
 366
 367 ;;;   \(add-hook 'iswitchb-minibuffer-setup-hook
 368 ;;;         \(function
 369 ;;;          \(lambda ()
 370 ;;;            \(make-local-variable 'resize-minibuffer-window-max-height)
 371 ;;;            \(setq resize-minibuffer-window-max-height 3))))
 372
 373 ;;; will constrain rsz-mini to a maximum minibuffer height of 3 lines when
 374 ;;; iswitchb is running.  Copied from `icomplete-minibuffer-setup-hook'."
 375   :type 'hook
 376   :group 'iswitchb)
 377
 378 ;; Do we need the variable iswitchb-use-mycompletion?
 379
 380 ;;; Internal Variables
 381
 382 (defvar iswitchb-method nil
 383   "Stores the method for viewing the selected buffer.
 384 Its value is one of `samewindow', `otherwindow', `display', `otherframe',
 385 `maybe-frame' or `always-frame'.  See `iswitchb-default-method' for
 386 details of values.")
 387
 388 (defvar iswitchb-eoinput 1
 389   "Point where minibuffer input ends and completion info begins.
 390 Copied from `icomplete-eoinput'.")
 391 (make-variable-buffer-local 'iswitchb-eoinput)
 392
 393 (defvar iswitchb-buflist nil
 394   "Stores the current list of buffers that will be searched through.
 395 The list is ordered, so that the most recent buffers come first,
 396 although by default, the buffers visible in the current frame are put
 397 at the end of the list.  Created by `iswitchb-make-buflist'.")
 398
 399 ;; todo -- is this necessary?
 400
 401 (defvar iswitchb-use-mycompletion nil
 402   "Non-nil means use `iswitchb-buffer' completion feedback.
 403 Should only be set to t by iswitchb functions, so that it doesn't
 404 interfere with other minibuffer usage.")
 405
 406 (defvar iswitchb-change-word-sub nil
 407   "Private variable used by `iswitchb-word-matching-substring'.")
 408
 409 (defvar iswitchb-common-match-string  nil
 410   "Stores the string that is common to all matching buffers.")
 411
 412 (defvar iswitchb-rescan nil
 413   "Non-nil means we need to regenerate the list of matching buffers.")
 414
 415 (defvar iswitchb-text nil
 416   "Stores the users string as it is typed in.")
 417
 418 (defvar iswitchb-matches nil
 419   "List of buffers currently matching `iswitchb-text'.")
 420
 421 (defvar iswitchb-mode-map
 422   (let ((map (make-sparse-keymap)))
 423     (set-keymap-parent map minibuffer-local-map)
 424     (define-key map "?" 'iswitchb-completion-help)
 425     (define-key map "\C-s" 'iswitchb-next-match)
 426     (define-key map "\C-r" 'iswitchb-prev-match)
 427     (define-key map "\t" 'iswitchb-complete)
 428     (define-key map "\C-j" 'iswitchb-select-buffer-text)
 429     (define-key map "\C-t" 'iswitchb-toggle-regexp)
 430     (define-key map "\C-x\C-f" 'iswitchb-find-file)
 431     (define-key map "\C-c" 'iswitchb-toggle-case)
 432     (define-key map "\C-k" 'iswitchb-kill-buffer)
 433     (define-key map "\C-m" 'iswitchb-exit-minibuffer)
 434     map)
 435   "Minibuffer keymap for `iswitchb-buffer'.")
 436
 437 (defvar iswitchb-global-map
 438   (let ((map (make-sparse-keymap)))
 439     (substitute-key-definition 'switch-to-buffer ; normally C-x b
 440                                'iswitchb-buffer map global-map)
 441     (substitute-key-definition 'switch-to-buffer-other-window ; C-x 4 b
 442                                'iswitchb-buffer-other-window map global-map)
 443     (substitute-key-definition 'switch-to-buffer-other-frame ; C-x 5 b
 444                                'iswitchb-buffer-other-frame map global-map)
 445     (substitute-key-definition 'display-buffer ; C-x 4 C-o
 446                                'iswitchb-display-buffer map global-map)
 447     map)
 448   "Global keymap for `iswtichb-mode'.")
 449
 450 (defvar iswitchb-history nil
 451   "History of buffers selected using `iswitchb-buffer'.")
 452
 453 (defvar iswitchb-exit nil
 454   "Flag to monitor how `iswitchb-buffer' exits.
 455 If equal to `takeprompt', we use the prompt as the buffer name to be
 456 selected.")
 457
 458 (defvar iswitchb-buffer-ignore-orig nil
 459   "Stores original value of `iswitchb-buffer-ignore'.")
 460
 461 (defvar iswitchb-xemacs  (string-match "XEmacs" (emacs-version))
 462   "Non-nil if we are running XEmacs.  Otherwise, assume we are running Emacs.")
 463
 464 (defvar iswitchb-default nil
 465   "Default buffer for iswitchb.")
 466
 467 ;; The following variables are needed to keep the byte compiler quiet.
 468 (defvar iswitchb-require-match nil
 469   "Non-nil if matching buffer must be selected.")
 470
 471 (defvar iswitchb-temp-buflist nil
 472   "Stores a temporary version of the buffer list being created.")
 473
 474 (defvar iswitchb-bufs-in-frame nil
 475   "List of the buffers visible in the current frame.")
 476
 477 (defvar iswitchb-minibuf-depth nil
 478   "Value we expect to be returned by `minibuffer-depth' in the minibuffer.")
 479
 480 ;;; FUNCTIONS
 481
 482 ;;; ISWITCHB KEYMAP
 483 (defun iswitchb-define-mode-map ()
 484   "Set up the keymap for `iswitchb-buffer'.
 485 This is obsolete.  Use \\[iswitchb-mode] or customize the
 486 variable `iswitchb-mode'."
 487   (interactive)
 488   (let (map)
 489     ;; generated every time so that it can inherit new functions.
 490     ;;(or iswitchb-mode-map
 491
 492     (setq map (copy-keymap minibuffer-local-map))
 493     (define-key map "?" 'iswitchb-completion-help)
 494     (define-key map "\C-s" 'iswitchb-next-match)
 495     (define-key map "\C-r" 'iswitchb-prev-match)
 496     (define-key map "\t" 'iswitchb-complete)
 497     (define-key map "\C-j" 'iswitchb-select-buffer-text)
 498     (define-key map "\C-t" 'iswitchb-toggle-regexp)
 499     (define-key map "\C-x\C-f" 'iswitchb-find-file)
 500     ;;(define-key map "\C-a" 'iswitchb-toggle-ignore)
 501     (define-key map "\C-c" 'iswitchb-toggle-case)
 502     (define-key map "\C-k" 'iswitchb-kill-buffer)
 503     (define-key map "\C-m" 'iswitchb-exit-minibuffer)
 504     (setq iswitchb-mode-map map)
 505     (run-hooks 'iswitchb-define-mode-map-hook)))
 506
 507 ;;; MAIN FUNCTION
 508 (defun iswitchb ()
 509   "Switch to buffer matching a substring.
 510 As you type in a string, all of the buffers matching the string are
 511 displayed.  When you have found the buffer you want, it can then be
 512 selected.  As you type, most keys have their normal keybindings,
 513 except for the following:
 514 \\<iswitchb-mode-map>
 515
 516 RET Select the buffer at the front of the list of matches.  If the
 517 list is empty, possibly prompt to create new buffer.
 518
 519 \\[iswitchb-select-buffer-text] Select the current prompt as the buffer.
 520 If no buffer is found, prompt for a new one.
 521
 522 \\[iswitchb-next-match] Put the first element at the end of the list.
 523 \\[iswitchb-prev-match] Put the last element at the start of the list.
 524 \\[iswitchb-complete] Complete a common suffix to the current string that
 525 matches all buffers.  If there is only one match, select that buffer.
 526 If there is no common suffix, show a list of all matching buffers
 527 in a separate window.
 528 \\[iswitchb-toggle-regexp] Toggle regexp searching.
 529 \\[iswitchb-toggle-case] Toggle case-sensitive searching of buffer names.
 530 \\[iswitchb-completion-help] Show list of matching buffers in separate window.
 531 \\[iswitchb-find-file] Exit iswitchb and drop into `find-file'.
 532 \\[iswitchb-kill-buffer] Kill buffer at head of buffer list."
 533   ;;\\[iswitchb-toggle-ignore] Toggle ignoring certain buffers (see \
 534   ;;`iswitchb-buffer-ignore')
 535
 536   (let* ((prompt "iswitch ")
 537          (buf (iswitchb-read-buffer prompt)))
 538
 539     ;;(message "chosen text %s" iswitchb-final-text)
 540     ;; Choose the buffer name: either the text typed in, or the head
 541     ;; of the list of matches
 542
 543     (cond ( (eq iswitchb-exit 'findfile)
 544             (call-interactively 'find-file))
 545
 546           (t
 547            ;; View the buffer
 548            ;;(message "go to buf %s" buf)
 549            ;; Check buf is non-nil.
 550            (if buf
 551                (if (get-buffer buf)
 552                    ;; buffer exists, so view it and then exit
 553                    (iswitchb-visit-buffer buf)
 554                  ;; else buffer doesn't exist
 555                  (iswitchb-possible-new-buffer buf)))
 556            ))))
 557
 558 ;;;###autoload
 559 (defun iswitchb-read-buffer (prompt &optional default require-match)
 560   "Replacement for the built-in `read-buffer'.
 561 Return the name of a buffer selected.
 562 PROMPT is the prompt to give to the user.  DEFAULT if given is the default
 563 buffer to be selected, which will go to the front of the list.
 564 If REQUIRE-MATCH is non-nil, an existing-buffer must be selected."
 565   (let
 566       (
 567        buf-sel
 568        iswitchb-final-text
 569        (icomplete-mode nil) ;; prevent icomplete starting up
 570        ;; can only use fonts if they have been bound.
 571        (iswitchb-use-fonts (and iswitchb-use-fonts
 572                                 (boundp 'font-lock-comment-face)
 573                                 (boundp 'font-lock-function-name-face))))
 574
 575     (iswitchb-define-mode-map)
 576     (setq iswitchb-exit nil)
 577     (setq iswitchb-rescan t)
 578     (setq iswitchb-text "")
 579     (setq iswitchb-default
 580           (if (bufferp default)
 581               (buffer-name default)
 582             default))
 583     (iswitchb-make-buflist iswitchb-default)
 584     (iswitchb-set-matches)
 585     (let
 586         ((minibuffer-local-completion-map iswitchb-mode-map)
 587          (iswitchb-prepost-hooks t)
 588          ;; Record the minibuffer depth that we expect to find once
 589          ;; the minibuffer is set up and iswitchb-entryfn-p is called.
 590          (iswitchb-minibuf-depth (1+ (minibuffer-depth)))
 591          (iswitchb-require-match require-match))
 592       ;; prompt the user for the buffer name
 593       (setq iswitchb-final-text (completing-read
 594                                  prompt ;the prompt
 595                                  '(("dummy" . 1)) ;table
 596                                  nil    ;predicate
 597                                  nil    ;require-match [handled elsewhere]
 598                                  nil    ;initial-contents
 599                                  'iswitchb-history)))
 600     (if (get-buffer iswitchb-final-text)
 601         ;; This happens for example if the buffer was chosen with the mouse.
 602         (setq iswitchb-matches (list iswitchb-final-text)))
 603
 604     ;; Handling the require-match must be done in a better way.
 605     (if (and require-match (not (iswitchb-existing-buffer-p)))
 606         (error "Must specify valid buffer"))
 607
 608     (if (or
 609          (eq iswitchb-exit 'takeprompt)
 610          (null iswitchb-matches))
 611         (setq buf-sel iswitchb-final-text)
 612       ;; else take head of list
 613       (setq buf-sel (car iswitchb-matches)))
 614
 615     ;; Or possibly choose the default buffer
 616     (if  (equal iswitchb-final-text "")
 617         (setq buf-sel
 618               (car iswitchb-matches)))
 619
 620     buf-sel))
 621
 622 (defun iswitchb-existing-buffer-p ()
 623   "Return non-nil if there is a matching buffer."
 624   (not (null iswitchb-matches)))
 625
 626 ;;; COMPLETION CODE
 627
 628 (defun iswitchb-set-common-completion  ()
 629   "Find common completion of `iswitchb-text' in `iswitchb-matches'.
 630 The result is stored in `iswitchb-common-match-string'."
 631
 632   (let* (val)
 633     (setq  iswitchb-common-match-string nil)
 634     (if (and iswitchb-matches
 635              (not iswitchb-regexp) ;; testing
 636              (stringp iswitchb-text)
 637              (> (length iswitchb-text) 0))
 638         (if (setq val (iswitchb-find-common-substring
 639                        iswitchb-matches iswitchb-text))
 640             (setq iswitchb-common-match-string val)))
 641     val))
 642
 643 (defun iswitchb-complete ()
 644   "Try and complete the current pattern amongst the buffer names."
 645   (interactive)
 646   (let (res)
 647     (cond ((not  iswitchb-matches)
 648            (run-hooks 'iswitchb-cannot-complete-hook))
 649
 650           ((= 1 (length iswitchb-matches))
 651            ;; only one choice, so select it.
 652            (exit-minibuffer))
 653
 654           (t
 655            ;; else there could be some completions
 656            (setq res iswitchb-common-match-string)
 657            (if (and (not (memq res '(t nil)))
 658                     (not (equal res iswitchb-text)))
 659                ;; found something to complete, so put it in the minibuffer.
 660                (progn
 661                  (setq iswitchb-rescan nil)
 662                  (delete-region (minibuffer-prompt-end) (point))
 663                  (insert  res))
 664              ;; else nothing to complete
 665              (run-hooks 'iswitchb-cannot-complete-hook)
 666              )))))
 667
 668 ;;; TOGGLE FUNCTIONS
 669
 670 (defun iswitchb-toggle-case ()
 671   "Toggle the value of variable `iswitchb-case'."
 672   (interactive)
 673   (setq iswitchb-case (not iswitchb-case))
 674   ;; ask for list to be regenerated.
 675   (setq iswitchb-rescan t))
 676
 677 (defun iswitchb-toggle-regexp ()
 678   "Toggle the value of `iswitchb-regexp'."
 679   (interactive)
 680   (setq iswitchb-regexp (not iswitchb-regexp))
 681   ;; ask for list to be regenerated.
 682   (setq iswitchb-rescan t))
 683
 684 (defun iswitchb-toggle-ignore ()
 685   "Toggle ignoring buffers specified with `iswitchb-buffer-ignore'."
 686   (interactive)
 687   (if iswitchb-buffer-ignore
 688       (progn
 689         (setq iswitchb-buffer-ignore-orig iswitchb-buffer-ignore)
 690         (setq iswitchb-buffer-ignore nil))
 691     ;; else
 692     (setq iswitchb-buffer-ignore iswitchb-buffer-ignore-orig))
 693   (iswitchb-make-buflist iswitchb-default)
 694   ;; ask for list to be regenerated.
 695   (setq iswitchb-rescan t))
 696
 697 (defun iswitchb-exit-minibuffer ()
 698   "Exit minibuffer, but make sure we have a match if one is needed."
 699   (interactive)
 700   (if (or (not iswitchb-require-match)
 701            (iswitchb-existing-buffer-p))
 702       (throw 'exit nil)))
 703
 704 (defun iswitchb-select-buffer-text ()
 705   "Select the buffer named by the prompt.
 706 If no buffer exactly matching the prompt exists, maybe create a new one."
 707   (interactive)
 708   (setq iswitchb-exit 'takeprompt)
 709   (exit-minibuffer))
 710
 711 (defun iswitchb-find-file ()
 712   "Drop into `find-file' from buffer switching."
 713   (interactive)
 714   (setq iswitchb-exit 'findfile)
 715   (exit-minibuffer))
 716
 717 (defun iswitchb-next-match ()
 718   "Put first element of `iswitchb-matches' at the end of the list."
 719   (interactive)
 720   (let ((next  (cadr iswitchb-matches)))
 721     (setq iswitchb-buflist (iswitchb-chop iswitchb-buflist next))
 722     (setq iswitchb-rescan t)))
 723
 724 (defun iswitchb-prev-match ()
 725   "Put last element of `iswitchb-matches' at the front of the list."
 726   (interactive)
 727   (let ((prev  (car (last iswitchb-matches))))
 728     (setq iswitchb-buflist (iswitchb-chop iswitchb-buflist prev))
 729     (setq iswitchb-rescan t)))
 730
 731 (defun iswitchb-chop (list elem)
 732   "Remove all elements before ELEM and put them at the end of LIST."
 733   (let ((ret nil)
 734         (next nil)
 735         (sofar nil))
 736     (while (not ret)
 737       (setq next (car list))
 738       (if (equal next elem)
 739           (setq ret (append list (nreverse sofar)))
 740         ;; else
 741         (progn
 742           (setq list (cdr list))
 743           (setq sofar (cons next sofar)))))
 744     ret))
 745
 746 ;;; CREATE LIST OF ALL CURRENT BUFFERS
 747
 748 (defun iswitchb-make-buflist (default)
 749   "Set `iswitchb-buflist' to the current list of buffers.
 750 Currently visible buffers are put at the end of the list.
 751 The hook `iswitchb-make-buflist-hook' is run after the list has been
 752 created to allow the user to further modify the order of the buffer names
 753 in this list.  If DEFAULT is non-nil, and corresponds to an existing buffer,
 754 it is put to the start of the list."
 755   (setq iswitchb-buflist
 756         (let* ((iswitchb-current-buffers (iswitchb-get-buffers-in-frames))
 757                (iswitchb-temp-buflist
 758                 (delq nil
 759                       (mapcar
 760                        (lambda (x)
 761                          (let ((b-name (buffer-name x)))
 762                            (if (not
 763                                 (or
 764                                  (iswitchb-ignore-buffername-p b-name)
 765                                  (memq b-name iswitchb-current-buffers)))
 766                                b-name)))
 767                        (buffer-list (and iswitchb-use-frame-buffer-list
 768                                          (selected-frame)))))))
 769           (setq iswitchb-temp-buflist
 770                 (nconc iswitchb-temp-buflist iswitchb-current-buffers))
 771           (run-hooks 'iswitchb-make-buflist-hook)
 772          ;; Should this be after the hooks, or should the hooks be the
 773           ;; final thing to be run?
 774           (if default
 775               (progn
 776                 (setq iswitchb-temp-buflist
 777                       (delete default iswitchb-temp-buflist))
 778                 (setq iswitchb-temp-buflist
 779                       (cons default iswitchb-temp-buflist))))
 780           iswitchb-temp-buflist)))
 781
 782 (defun iswitchb-to-end (lst)
 783   "Move the elements from LST to the end of `iswitchb-temp-buflist'."
 784   (mapcar
 785    (lambda (elem)
 786      (setq iswitchb-temp-buflist (delq elem iswitchb-temp-buflist)))
 787    lst)
 788   (setq iswitchb-temp-buflist (nconc iswitchb-temp-buflist lst)))
 789
 790 (defun iswitchb-get-buffers-in-frames (&optional current)
 791   "Return the list of buffers that are visible in the current frame.
 792 If optional argument CURRENT is given, restrict searching to the
 793 current frame, rather than all frames, regardless of value of
 794 `iswitchb-all-frames'."
 795   (let ((iswitchb-bufs-in-frame nil))
 796     (walk-windows 'iswitchb-get-bufname nil
 797                   (if current
 798                       nil
 799                     iswitchb-all-frames))
 800     iswitchb-bufs-in-frame))
 801
 802 (defun iswitchb-get-bufname (win)
 803   "Used by `iswitchb-get-buffers-in-frames' to walk through all windows."
 804   (let ((buf (buffer-name (window-buffer win))))
 805         (if (not (member buf iswitchb-bufs-in-frame))
 806             ;; Only add buf if it is not already in list.
 807             ;; This prevents same buf in two different windows being
 808             ;; put into the list twice.
 809             (setq iswitchb-bufs-in-frame
 810                   (cons buf iswitchb-bufs-in-frame)))))
 811
 812 ;;; FIND MATCHING BUFFERS
 813
 814 (defun iswitchb-set-matches ()
 815   "Set `iswitchb-matches' to the list of buffers matching prompt."
 816   (if iswitchb-rescan
 817       (setq iswitchb-matches
 818             (let* ((buflist iswitchb-buflist))
 819               (iswitchb-get-matched-buffers iswitchb-text iswitchb-regexp
 820                                             buflist)))))
 821
 822 (defun iswitchb-get-matched-buffers (regexp
 823                                      &optional string-format buffer-list)
 824   "Return buffers matching REGEXP.
 825 If STRING-FORMAT is nil, consider REGEXP as just a string.
 826 BUFFER-LIST can be list of buffers or list of strings."
 827   (let* ((case-fold-search  (iswitchb-case))
 828          ;; need reverse since we are building up list backwards
 829          (list              (reverse buffer-list))
 830          (do-string         (stringp (car list)))
 831          name
 832          ret)
 833     (mapcar
 834      (lambda (x)
 835
 836        (if do-string
 837            (setq name x)               ;We already have the name
 838          (setq name (buffer-name x)))
 839
 840        (cond
 841         ((and (or (and string-format (string-match regexp name))
 842                   (and (null string-format)
 843                        (string-match (regexp-quote regexp) name)))
 844
 845               (not (iswitchb-ignore-buffername-p name)))
 846          (setq ret (cons name ret))
 847           )))
 848      list)
 849     ret))
 850
 851 (defun iswitchb-ignore-buffername-p (bufname)
 852   "Return t if the buffer BUFNAME should be ignored."
 853   (let ((data       (match-data))
 854         (re-list    iswitchb-buffer-ignore)
 855         ignorep
 856         nextstr)
 857     (while re-list
 858       (setq nextstr (car re-list))
 859       (cond
 860        ((stringp nextstr)
 861         (if (string-match nextstr bufname)
 862             (progn
 863               (setq ignorep t)
 864               (setq re-list nil))))
 865        ((fboundp nextstr)
 866         (if (funcall nextstr bufname)
 867             (progn
 868               (setq ignorep t)
 869               (setq re-list nil)))))
 870       (setq re-list (cdr re-list)))
 871     (set-match-data data)
 872
 873     ;; return the result
 874     ignorep))
 875
 876 (defun iswitchb-word-matching-substring (word)
 877   "Return part of WORD before 1st match to `iswitchb-change-word-sub'.
 878 If `iswitchb-change-word-sub' cannot be found in WORD, return nil."
 879   (let ((case-fold-search (iswitchb-case)))
 880     (let ((m (string-match iswitchb-change-word-sub word)))
 881       (if m
 882           (substring word m)
 883         ;; else no match
 884         nil))))
 885
 886 (defun iswitchb-find-common-substring (lis subs)
 887   "Return common string following SUBS in each element of LIS."
 888   (let (res
 889         alist
 890         iswitchb-change-word-sub)
 891     (setq iswitchb-change-word-sub
 892           (if iswitchb-regexp
 893               subs
 894             (regexp-quote subs)))
 895     (setq res (mapcar 'iswitchb-word-matching-substring lis))
 896     (setq res (delq nil res)) ;; remove any nil elements (shouldn't happen)
 897     (setq alist (mapcar 'iswitchb-makealist res)) ;; could use an  OBARRAY
 898
 899     ;; try-completion returns t if there is an exact match.
 900     (let ((completion-ignore-case (iswitchb-case)))
 901
 902     (try-completion subs alist))))
 903
 904 (defun iswitchb-makealist (res)
 905   "Return dotted pair (RES . 1)."
 906   (cons res 1))
 907
 908 ;; from Wayne Mesard <wmesard@esd.sgi.com>
 909 (defun iswitchb-rotate-list (lis)
 910   "Destructively remove the last element from LIS.
 911 Return the modified list with the last element prepended to it."
 912   (if (<= (length lis) 1)
 913       lis
 914     (let ((las lis)
 915           (prev lis))
 916       (while (consp (cdr las))
 917         (setq prev las
 918               las (cdr las)))
 919       (setcdr prev nil)
 920       (cons (car las) lis))))
 921
 922 (defun iswitchb-completion-help ()
 923   "Show possible completions in a *Completions* buffer."
 924   ;; we could allow this buffer to be used to select match, but I think
 925   ;; choose-completion-string will need redefining, so it just inserts
 926   ;; choice with out any previous input.
 927   (interactive)
 928   (setq iswitchb-rescan nil)
 929   (let ((buf (current-buffer))
 930         (temp-buf "*Completions*")
 931         (win))
 932
 933     (if (eq last-command this-command)
 934         ;; scroll buffer
 935         (progn
 936           (set-buffer temp-buf)
 937           (setq win (get-buffer-window temp-buf))
 938           (if (pos-visible-in-window-p (point-max) win)
 939               (set-window-start win (point-min))
 940             (scroll-other-window))
 941           (set-buffer buf))
 942
 943       (with-output-to-temp-buffer temp-buf
 944         (if iswitchb-xemacs
 945
 946             ;; XEmacs extents are put on by default, doesn't seem to be
 947             ;; any way of switching them off.
 948             (display-completion-list (if iswitchb-matches
 949                                          iswitchb-matches
 950                                        iswitchb-buflist)
 951                                      :help-string "iswitchb "
 952                                      :activate-callback
 953                                      (lambda (x y z)
 954                                        (message "doesn't work yet, sorry!")))
 955           ;; else running Emacs
 956           (with-current-buffer standard-output
 957             (fundamental-mode))
 958           (display-completion-list (if iswitchb-matches
 959                                        iswitchb-matches
 960                                      iswitchb-buflist))
 961           )))))
 962
 963 ;;; KILL CURRENT BUFFER
 964
 965 (defun iswitchb-kill-buffer ()
 966   "Kill the buffer at the head of `iswitchb-matches'."
 967   (interactive)
 968   (let ( (enable-recursive-minibuffers t)
 969          buf)
 970
 971     (setq buf (car iswitchb-matches))
 972     ;; check to see if buf is non-nil.
 973     (if buf
 974         (progn
 975           (kill-buffer buf)
 976
 977           ;; Check if buffer exists.  XEmacs gnuserv.el makes alias
 978           ;; for kill-buffer which does not return t if buffer is
 979           ;; killed, so we can't rely on kill-buffer return value.
 980           (if (get-buffer buf)
 981               ;; buffer couldn't be killed.
 982               (setq iswitchb-rescan t)
 983             ;; else buffer was killed so remove name from list.
 984             (setq iswitchb-buflist  (delq buf iswitchb-buflist)))))))
 985
 986 ;;; VISIT CHOSEN BUFFER
 987 (defun iswitchb-visit-buffer (buffer)
 988   "Visit buffer named BUFFER according to `iswitchb-method'."
 989   (let* (win  newframe)
 990     (cond
 991      ((eq iswitchb-method 'samewindow)
 992       (switch-to-buffer buffer))
 993
 994      ((memq iswitchb-method '(always-frame maybe-frame))
 995       (cond
 996        ((and (setq win (iswitchb-window-buffer-p buffer))
 997              (or (eq iswitchb-method 'always-frame)
 998                  (y-or-n-p "Jump to frame? ")))
 999         (setq newframe (window-frame win))
1000         (if (not iswitchb-xemacs)
1001             (select-frame-set-input-focus newframe)
1002           (raise-frame newframe)
1003           (select-frame newframe)
1004           )
1005         (select-window win))
1006        (t
1007         ;;  No buffer in other frames...
1008         (switch-to-buffer buffer)
1009         )))
1010
1011      ((eq iswitchb-method 'otherwindow)
1012       (switch-to-buffer-other-window buffer))
1013
1014      ((eq iswitchb-method 'display)
1015       (display-buffer buffer))
1016
1017      ((eq iswitchb-method 'otherframe)
1018       (progn
1019         (switch-to-buffer-other-frame buffer)
1020         (if (not iswitchb-xemacs)
1021             (select-frame-set-input-focus (selected-frame)))
1022         )))))
1023
1024 (defun iswitchb-possible-new-buffer (buf)
1025   "Possibly create and visit a new buffer called BUF."
1026
1027   (let ((newbufcreated))
1028     (if (and iswitchb-newbuffer
1029              (or
1030               (not iswitchb-prompt-newbuffer)
1031
1032               (and iswitchb-prompt-newbuffer
1033                    (y-or-n-p
1034                     (format
1035                      "No buffer matching `%s', create one? "
1036                      buf)))))
1037         ;; then create a new buffer
1038         (progn
1039           (setq newbufcreated (get-buffer-create buf))
1040           (if (fboundp 'set-buffer-major-mode)
1041               (set-buffer-major-mode newbufcreated))
1042           (iswitchb-visit-buffer newbufcreated))
1043       ;; else wont create new buffer
1044       (message (format "no buffer matching `%s'" buf)))))
1045
1046 (defun iswitchb-window-buffer-p  (buffer)
1047   "Return window pointer if BUFFER is visible in another frame.
1048 If BUFFER is visible in the current frame, return nil."
1049   (interactive)
1050   (let ((blist (iswitchb-get-buffers-in-frames 'current)))
1051     ;;If the buffer is visible in current frame, return nil
1052     (if (memq buffer blist)
1053         nil
1054       ;;  maybe in other frame or icon
1055       (get-buffer-window buffer 0) ; better than 'visible
1056       )))
1057
1058 ;;;###autoload
1059 (defun iswitchb-default-keybindings ()
1060   "Set up default keybindings for `iswitchb-buffer'.
1061 Call this function to override the normal bindings.  This function also
1062 adds a hook to the minibuffer.
1063
1064 Obsolescent.  Use `iswitchb-mode'."
1065   (interactive)
1066   (add-hook 'minibuffer-setup-hook 'iswitchb-minibuffer-setup)
1067   (global-set-key "\C-xb" 'iswitchb-buffer)
1068   (global-set-key "\C-x4b" 'iswitchb-buffer-other-window)
1069   (global-set-key "\C-x4\C-o" 'iswitchb-display-buffer)
1070   (global-set-key "\C-x5b" 'iswitchb-buffer-other-frame))
1071
1072 ;;;###autoload
1073 (defun iswitchb-buffer ()
1074   "Switch to another buffer.
1075
1076 The buffer name is selected interactively by typing a substring.  The
1077 buffer is displayed according to `iswitchb-default-method' -- the
1078 default is to show it in the same window, unless it is already visible
1079 in another frame.
1080 For details of keybindings, do `\\[describe-function] iswitchb'."
1081   (interactive)
1082   (setq iswitchb-method iswitchb-default-method)
1083   (iswitchb))
1084
1085 ;;;###autoload
1086 (defun iswitchb-buffer-other-window ()
1087   "Switch to another buffer and show it in another window.
1088 The buffer name is selected interactively by typing a substring.
1089 For details of keybindings, do `\\[describe-function] iswitchb'."
1090   (interactive)
1091   (setq iswitchb-method 'otherwindow)
1092   (iswitchb))
1093
1094 ;;;###autoload
1095 (defun iswitchb-display-buffer ()
1096   "Display a buffer in another window but don't select it.
1097 The buffer name is selected interactively by typing a substring.
1098 For details of keybindings, do `\\[describe-function] iswitchb'."
1099   (interactive)
1100   (setq iswitchb-method 'display)
1101   (iswitchb))
1102
1103 ;;;###autoload
1104 (defun iswitchb-buffer-other-frame ()
1105   "Switch to another buffer and show it in another frame.
1106 The buffer name is selected interactively by typing a substring.
1107 For details of keybindings, do `\\[describe-function] iswitchb'."
1108   (interactive)
1109   (setq iswitchb-method 'otherframe)
1110   (iswitchb))
1111
1112 ;;; XEmacs hack for showing default buffer
1113
1114 ;; The first time we enter the minibuffer, Emacs puts up the default
1115 ;; buffer to switch to, but XEmacs doesn't -- presumably there is a
1116 ;; subtle difference in the two versions of post-command-hook.  The
1117 ;; default is shown for both whenever we delete all of our text
1118 ;; though, indicating its just a problem the first time we enter the
1119 ;; function.  To solve this, we use another entry hook for emacs to
1120 ;; show the default the first time we enter the minibuffer.
1121
1122 (defun iswitchb-init-XEmacs-trick ()
1123   "Display default buffer when first entering minibuffer.
1124 This is a hack for XEmacs, and should really be handled by `iswitchb-exhibit'."
1125   (if (iswitchb-entryfn-p)
1126       (progn
1127         (iswitchb-exhibit)
1128         (goto-char (point-min)))))
1129
1130 ;; add this hook for XEmacs only.
1131 (if iswitchb-xemacs
1132     (add-hook 'iswitchb-minibuffer-setup-hook
1133               'iswitchb-init-XEmacs-trick))
1134
1135 ;;; XEmacs / backspace key
1136 ;; For some reason, if the backspace key is pressed in XEmacs, the
1137 ;; line gets confused, so I've added a simple key definition to make
1138 ;; backspace act like the normal delete key.
1139
1140 (defun iswitchb-xemacs-backspacekey ()
1141   "Bind backspace to `backward-delete-char'."
1142   (define-key iswitchb-mode-map '[backspace] 'backward-delete-char)
1143   (define-key iswitchb-mode-map '[(meta backspace)] 'backward-kill-word))
1144
1145 (if iswitchb-xemacs
1146     (add-hook 'iswitchb-define-mode-map-hook
1147               'iswitchb-xemacs-backspacekey))
1148
1149 ;;; ICOMPLETE TYPE CODE
1150
1151 (defun iswitchb-exhibit ()
1152   "Find matching buffers and display a list in the minibuffer.
1153 Copied from `icomplete-exhibit' with two changes:
1154 1. It prints a default buffer name when there is no text yet entered.
1155 2. It calls my completion routine rather than the standard completion."
1156   (if iswitchb-use-mycompletion
1157       (let ((contents (buffer-substring (minibuffer-prompt-end) (point-max)))
1158             (buffer-undo-list t))
1159         (save-excursion
1160           (goto-char (point-max))
1161                                         ; Register the end of input, so we
1162                                         ; know where the extra stuff
1163                                         ; (match-status info) begins:
1164           (if (not (boundp 'iswitchb-eoinput))
1165               ;; In case it got wiped out by major mode business:
1166               (make-local-variable 'iswitchb-eoinput))
1167           (setq iswitchb-eoinput (point))
1168           ;; Update the list of matches
1169           (setq iswitchb-text contents)
1170           (iswitchb-set-matches)
1171           (setq iswitchb-rescan t)
1172           (iswitchb-set-common-completion)
1173
1174           ;; Insert the match-status information:
1175           (insert (iswitchb-completions
1176                    contents
1177                    minibuffer-completion-table
1178                    minibuffer-completion-predicate
1179                    (not minibuffer-completion-confirm)))))))
1180
1181 (defun iswitchb-completions (name candidates predicate require-match)
1182   "Return the string that is displayed after the user's text.
1183 Modified from `icomplete-completions'."
1184
1185   (let ((comps iswitchb-matches)
1186                                         ; "-determined" - only one candidate
1187         (open-bracket-determined (if require-match "(" "["))
1188         (close-bracket-determined (if require-match ")" "]"))
1189                                         ;"-prospects" - more than one candidate
1190         (open-bracket-prospects "{")
1191         (close-bracket-prospects "}")
1192         first)
1193
1194     (if (and iswitchb-use-fonts  comps)
1195         (progn
1196           (setq first (car comps))
1197           (setq first (format "%s" first))
1198           (put-text-property 0 (length first) 'face
1199                              (if (= (length comps) 1)
1200                                  'font-lock-comment-face
1201                                'font-lock-function-name-face)
1202                              first)
1203           (setq comps  (cons first (cdr comps)))))
1204
1205     (cond ((null comps) (format " %sNo match%s"
1206                                 open-bracket-determined
1207                                 close-bracket-determined))
1208
1209           ((null (cdr comps))           ;one match
1210            (concat (if (and (> (length (car comps))
1211                                (length name)))
1212                        (concat open-bracket-determined
1213                                ;; when there is one match, show the
1214                                ;; matching buffer name in full
1215                                (car comps)
1216                                close-bracket-determined)
1217                      "")
1218                    (if (not iswitchb-use-fonts) " [Matched]")))
1219           (t                            ;multiple matches
1220            (let* (
1221                   ;;(most (try-completion name candidates predicate))
1222                   (most nil)
1223                   (most-len (length most))
1224                   most-is-exact
1225                   first
1226                   (alternatives
1227                    (apply
1228                     (function concat)
1229                     (cdr (apply
1230                           (function nconc)
1231                           (mapcar '(lambda (com)
1232                                      (if (= (length com) most-len)
1233                                          ;; Most is one exact match,
1234                                          ;; note that and leave out
1235                                          ;; for later indication:
1236                                          (progn
1237                                            (setq most-is-exact t)
1238                                            ())
1239                                        (list ","
1240                                              (substring com
1241                                                         most-len))))
1242                                   comps))))))
1243
1244              (concat
1245
1246               ;; put in common completion item -- what you get by
1247               ;; pressing tab
1248               (if (> (length iswitchb-common-match-string) (length name))
1249                   (concat open-bracket-determined
1250                           (substring iswitchb-common-match-string
1251                                      (length name))
1252                           close-bracket-determined))
1253               ;; end of partial matches...
1254
1255               ;; think this bit can be ignored.
1256               (and (> most-len (length name))
1257                    (concat open-bracket-determined
1258                            (substring most (length name))
1259                            close-bracket-determined))
1260
1261               ;; list all alternatives
1262               open-bracket-prospects
1263               (if most-is-exact
1264                   (concat "," alternatives)
1265                 alternatives)
1266               close-bracket-prospects))))))
1267
1268 (defun iswitchb-minibuffer-setup ()
1269   "Set up minibuffer for `iswitchb-buffer'.
1270 Copied from `icomplete-minibuffer-setup-hook'."
1271   (when (iswitchb-entryfn-p)
1272     (set (make-local-variable 'iswitchb-use-mycompletion) t)
1273     (add-hook 'pre-command-hook 'iswitchb-pre-command nil t)
1274     (add-hook 'post-command-hook 'iswitchb-post-command nil t)
1275     (run-hooks 'iswitchb-minibuffer-setup-hook)))
1276
1277 (defun iswitchb-pre-command ()
1278   "Run before command in `iswitchb-buffer'."
1279   (iswitchb-tidy))
1280
1281 (defun iswitchb-post-command ()
1282   "Run after command in `iswitchb-buffer'."
1283   (iswitchb-exhibit))
1284
1285 (defun iswitchb-tidy ()
1286   "Remove completions display, if any, prior to new user input.
1287 Copied from `icomplete-tidy'."
1288
1289   (if (and (boundp 'iswitchb-eoinput)
1290            iswitchb-eoinput)
1291
1292       (if (> iswitchb-eoinput (point-max))
1293           ;; Oops, got rug pulled out from under us - reinit:
1294           (setq iswitchb-eoinput (point-max))
1295         (let ((buffer-undo-list buffer-undo-list )) ; prevent entry
1296           (delete-region iswitchb-eoinput (point-max))))
1297
1298     ;; Reestablish the local variable 'cause minibuffer-setup is weird:
1299     (make-local-variable 'iswitchb-eoinput)
1300     (setq iswitchb-eoinput 1)))
1301
1302 (defun iswitchb-entryfn-p ()
1303   "Return non-nil if we are using `iswitchb-buffer'."
1304   (eq iswitchb-minibuf-depth (minibuffer-depth)))
1305
1306 (defun iswitchb-summaries-to-end ()
1307   "Move the summaries to the end of the list.
1308 This is an example function which can be hooked on to
1309 `iswitchb-make-buflist-hook'.  Any buffer matching the regexps
1310 `Summary' or `output\*$'are put to the end of the list."
1311   (let ((summaries (delq nil
1312                          (mapcar
1313                           (lambda (x)
1314                             (if (string-match "Summary\\|output\\*$" x)
1315                                 x))
1316                           iswitchb-temp-buflist))))
1317     (iswitchb-to-end summaries)))
1318
1319 (defun iswitchb-case ()
1320   "Return non-nil iff we should ignore case when matching.
1321 See the variable `iswitchb-case' for details."
1322   (if iswitchb-case
1323       (if iswitchb-xemacs
1324           (isearch-no-upper-case-p iswitchb-text)
1325         (isearch-no-upper-case-p iswitchb-text t))))
1326
1327 ;;;###autoload
1328 (define-minor-mode iswitchb-mode
1329   "Toggle Iswitchb global minor mode.
1330 With arg, turn Iswitchb mode on if and only iff ARG is positive.
1331 This mode enables switching between buffers using substrings.  See
1332 `iswitchb' for details."
1333   nil nil iswitchb-global-map :global t :group 'iswitchb
1334   (if iswitchb-mode
1335       (add-hook 'minibuffer-setup-hook 'iswitchb-minibuffer-setup)
1336     (remove-hook 'minibuffer-setup-hook 'iswitchb-minibuffer-setup)))
1337
1338 (provide 'iswitchb)
1339
1340 ;;; iswitchb.el ends here