lisp/composite.el

   1 ;;; composite.el --- support character composition
   2
   3 ;; Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 ;;   2008
   5 ;;   National Institute of Advanced Industrial Science and Technology (AIST)
   6 ;;   Registration Number H14PRO021
   7
   8 ;; Keywords: mule, multilingual, character composition
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (defconst reference-point-alist
  30   '((tl . 0) (tc . 1) (tr . 2)
  31     (Bl . 3) (Bc . 4) (Br . 5)
  32     (bl . 6) (bc . 7) (br . 8)
  33     (cl . 9) (cc . 10) (cr . 11)
  34     (top-left . 0) (top-center . 1) (top-right . 2)
  35     (base-left . 3) (base-center . 4) (base-right . 5)
  36     (bottom-left . 6) (bottom-center . 7) (bottom-right . 8)
  37     (center-left . 9) (center-center . 10) (center-right . 11)
  38     ;; For backward compatibility...
  39     (ml . 3) (mc . 10) (mr . 5)
  40     (mid-left . 3) (mid-center . 10) (mid-right . 5))
  41   "Alist of symbols vs integer codes of glyph reference points.
  42 A glyph reference point symbol is to be used to specify a composition
  43 rule in COMPONENTS argument to such functions as `compose-region'.
  44
  45 Meanings of glyph reference point codes are as follows:
  46
  47     0----1----2 <---- ascent    0:tl or top-left
  48     |         |                 1:tc or top-center
  49     |         |                 2:tr or top-right
  50     |         |                 3:Bl or base-left     9:cl or center-left
  51     9   10   11 <---- center    4:Bc or base-center  10:cc or center-center
  52     |         |                 5:Br or base-right   11:cr or center-right
  53   --3----4----5-- <-- baseline  6:bl or bottom-left
  54     |         |                 7:bc or bottom-center
  55     6----7----8 <---- descent   8:br or bottom-right
  56
  57 Glyph reference point symbols are to be used to specify composition
  58 rule of the form \(GLOBAL-REF-POINT . NEW-REF-POINT), where
  59 GLOBAL-REF-POINT is a reference point in the overall glyphs already
  60 composed, and NEW-REF-POINT is a reference point in the new glyph to
  61 be added.
  62
  63 For instance, if GLOBAL-REF-POINT is `br' (bottom-right) and
  64 NEW-REF-POINT is `tc' (top-center), the overall glyph is updated as
  65 follows (the point `*' corresponds to both reference points):
  66
  67     +-------+--+ <--- new ascent
  68     |       |  |
  69     | global|  |
  70     | glyph |  |
  71  -- |       |  |-- <--- baseline \(doesn't change)
  72     +----+--*--+
  73     |    | new |
  74     |    |glyph|
  75     +----+-----+ <--- new descent
  76
  77 A composition rule may have the form \(GLOBAL-REF-POINT
  78 NEW-REF-POINT XOFF YOFF), where XOFF and YOFF specifies how much
  79 to shift NEW-REF-POINT from GLOBAL-REF-POINT.  In this case, XOFF
  80 and YOFF are integers in the range -100..100 representing the
  81 shifting percentage against the font size.")
  82
  83
  84 ;;;###autoload
  85 (defun encode-composition-rule (rule)
  86   "Encode composition rule RULE into an integer value.
  87 RULE is a cons of global and new reference point symbols
  88 \(see `reference-point-alist')."
  89
  90   ;; This must be compatible with C macro COMPOSITION_ENCODE_RULE
  91   ;; defined in composite.h.
  92
  93   (if (and (integerp rule) (< rule 144))
  94       ;; Already encoded.
  95       rule
  96     (if (consp rule)
  97         (let ((gref (car rule))
  98               (nref (cdr rule))
  99               xoff yoff)
 100           (if (consp nref)              ; (GREF NREF XOFF YOFF)
 101               (progn
 102                 (setq xoff (nth 1 nref)
 103                       yoff (nth 2 nref)
 104                       nref (car nref))
 105                 (or (and (>= xoff -100) (<= xoff 100)
 106                          (>= yoff -100) (<= yoff 100))
 107                     (error "Invalid composition rule: %s" rule))
 108                 (setq xoff (+ xoff 128) yoff (+ yoff 128)))
 109             ;; (GREF . NREF)
 110             (setq xoff 0 yoff 0))
 111           (or (integerp gref)
 112               (setq gref (cdr (assq gref reference-point-alist))))
 113           (or (integerp nref)
 114               (setq nref (cdr (assq nref reference-point-alist))))
 115           (or (and (>= gref 0) (< gref 12) (>= nref 0) (< nref 12))
 116               (error "Invalid composition rule: %S" rule))
 117           (logior (lsh xoff 16) (lsh yoff 8) (+ (* gref 12) nref)))
 118       (error "Invalid composition rule: %S" rule))))
 119
 120 ;; Decode encoded composition rule RULE-CODE.  The value is a cons of
 121 ;; global and new reference point symbols.
 122 ;; This must be compatible with C macro COMPOSITION_DECODE_RULE
 123 ;; defined in composite.h.
 124
 125 (defun decode-composition-rule (rule-code)
 126   (or (and (natnump rule-code) (< rule-code #x1000000))
 127       (error "Invalid encoded composition rule: %S" rule-code))
 128   (let ((xoff (lsh rule-code -16))
 129         (yoff (logand (lsh rule-code -8) #xFF))
 130         gref nref)
 131     (setq rule-code (logand rule-code #xFF)
 132           gref (car (rassq (/ rule-code 12) reference-point-alist))
 133           nref (car (rassq (% rule-code 12) reference-point-alist)))
 134     (or (and gref (symbolp gref) nref (symbolp nref))
 135         (error "Invalid composition rule code: %S" rule-code))
 136     (if (and (= xoff 0) (= yoff 0))
 137         (cons gref nref)
 138       (setq xoff (- xoff 128) yoff (- yoff 128))
 139       (list gref xoff yoff nref))))
 140
 141 ;; Encode composition rules in composition components COMPONENTS.  The
 142 ;; value is a copy of COMPONENTS, where composition rules (cons of
 143 ;; global and new glyph reference point symbols) are replaced with
 144 ;; encoded composition rules.  Optional 2nd argument NOCOPY non-nil
 145 ;; means don't make a copy but modify COMPONENTS directly.
 146
 147 (defun encode-composition-components (components &optional nocopy)
 148   (or nocopy
 149       (setq components (copy-sequence components)))
 150   (if (vectorp components)
 151       (let ((len (length components))
 152             (i 1))
 153         (while (< i len)
 154           (aset components i
 155                 (encode-composition-rule (aref components i)))
 156           (setq i (+ i 2))))
 157     (let ((tail (cdr components)))
 158       (while tail
 159         (setcar tail
 160                 (encode-composition-rule (car tail)))
 161         (setq tail (nthcdr 2 tail)))))
 162   components)
 163
 164 ;; Decode composition rule codes in composition components COMPONENTS.
 165 ;; The value is a copy of COMPONENTS, where composition rule codes are
 166 ;; replaced with composition rules (cons of global and new glyph
 167 ;; reference point symbols).  Optional 2nd argument NOCOPY non-nil
 168 ;; means don't make a copy but modify COMPONENTS directly.
 169 ;; It is assumed that COMPONENTS is a vector and is for rule-base
 170 ;; composition, thus (2N+1)th elements are rule codes.
 171
 172 (defun decode-composition-components (components &optional nocopy)
 173   (or nocopy
 174       (setq components (copy-sequence components)))
 175   (let ((len (length components))
 176         (i 1))
 177     (while (< i len)
 178       (aset components i
 179             (decode-composition-rule (aref components i)))
 180       (setq i (+ i 2))))
 181   components)
 182
 183 (defun compose-region (start end &optional components modification-func)
 184   "Compose characters in the current region.
 185
 186 Characters are composed relatively, i.e. composed by overstricking or
 187 stacking depending on ascent, descent and other properties.
 188
 189 When called from a program, expects these four arguments.
 190
 191 First two arguments START and END are positions (integers or markers)
 192 specifying the region.
 193
 194 Optional 3rd argument COMPONENTS, if non-nil, is a character, a string
 195 or a vector or list of integers and rules.
 196
 197 If it is a character, it is an alternate character to display instead
 198 of the text in the region.
 199
 200 If it is a string, the elements are alternate characters.  In
 201 this case, TAB element has a special meaning.  If the first
 202 characer is TAB, the glyphs are displayed with left padding space
 203 so that no pixel overlaps with the previous column.  If the last
 204 character is TAB, the glyphs are displayed with rigth padding
 205 space so that no pixel overlaps with the following column.
 206
 207 If it is a vector or list, it is a sequence of alternate characters and
 208 composition rules, where (2N)th elements are characters and (2N+1)th
 209 elements are composition rules to specify how to compose (2N+2)th
 210 elements with previously composed N glyphs.
 211
 212 A composition rule is a cons of global and new glyph reference point
 213 symbols.  See the documentation of `reference-point-alist' for more
 214 detail.
 215
 216 Optional 4th argument MODIFICATION-FUNC is a function to call to
 217 adjust the composition when it gets invalid because of a change of
 218 text in the composition."
 219   (interactive "r")
 220   (let ((modified-p (buffer-modified-p))
 221         (inhibit-read-only t))
 222     (if (or (vectorp components) (listp components))
 223         (setq components (encode-composition-components components)))
 224     (compose-region-internal start end components modification-func)
 225     (restore-buffer-modified-p modified-p)))
 226
 227 (defun decompose-region (start end)
 228   "Decompose text in the current region.
 229
 230 When called from a program, expects two arguments,
 231 positions (integers or markers) specifying the region."
 232   (interactive "r")
 233   (let ((modified-p (buffer-modified-p))
 234         (inhibit-read-only t))
 235     (remove-text-properties start end '(composition nil))
 236     (restore-buffer-modified-p modified-p)))
 237
 238 (defun compose-string (string &optional start end components modification-func)
 239   "Compose characters in string STRING.
 240
 241 The return value is STRING with the `composition' property put on all
 242 the characters in it.
 243
 244 Optional 2nd and 3rd arguments START and END specify the range of
 245 STRING to be composed.  They default to the beginning and the end of
 246 STRING respectively.
 247
 248 Optional 4th argument COMPONENTS, if non-nil, is a character or a
 249 sequence (vector, list, or string) of integers.  See the function
 250 `compose-region' for more detail.
 251
 252 Optional 5th argument MODIFICATION-FUNC is a function to call to
 253 adjust the composition when it gets invalid because of a change of
 254 text in the composition."
 255   (if (or (vectorp components) (listp components))
 256       (setq components (encode-composition-components components)))
 257   (or start (setq start 0))
 258   (or end (setq end (length string)))
 259   (compose-string-internal string start end components modification-func)
 260   string)
 261
 262 (defun decompose-string (string)
 263   "Return STRING where `composition' property is removed."
 264   (remove-text-properties 0 (length string) '(composition nil) string)
 265   string)
 266
 267 (defun compose-chars (&rest args)
 268   "Return a string from arguments in which all characters are composed.
 269 For relative composition, arguments are characters.
 270 For rule-based composition, Mth \(where M is odd) arguments are
 271 characters, and Nth \(where N is even) arguments are composition rules.
 272 A composition rule is a cons of glyph reference points of the form
 273 \(GLOBAL-REF-POINT . NEW-REF-POINT).  See the documentation of
 274 `reference-point-alist' for more detail."
 275   (let (str components)
 276     (if (consp (car (cdr args)))
 277         ;; Rule-base composition.
 278         (let ((len (length args))
 279               (tail (encode-composition-components args 'nocopy)))
 280
 281           (while tail
 282             (setq str (cons (car tail) str))
 283             (setq tail (nthcdr 2 tail)))
 284           (setq str (concat (nreverse str))
 285                 components args))
 286       ;; Relative composition.
 287       (setq str (concat args)))
 288     (compose-string-internal str 0 (length str) components)))
 289
 290 (defun find-composition (pos &optional limit string detail-p)
 291   "Return information about a composition at or nearest to buffer position POS.
 292
 293 If the character at POS has `composition' property, the value is a list
 294 of FROM, TO, and VALID-P.
 295
 296 FROM and TO specify the range of text that has the same `composition'
 297 property, VALID-P is non-nil if and only if this composition is valid.
 298
 299 If there's no composition at POS, and the optional 2nd argument LIMIT
 300 is non-nil, search for a composition toward LIMIT.
 301
 302 If no composition is found, return nil.
 303
 304 Optional 3rd argument STRING, if non-nil, is a string to look for a
 305 composition in; nil means the current buffer.
 306
 307 If a valid composition is found and the optional 4th argument DETAIL-P
 308 is non-nil, the return value is a list of FROM, TO, COMPONENTS,
 309 RELATIVE-P, MOD-FUNC, and WIDTH.
 310
 311 COMPONENTS is a vector of integers, the meaning depends on RELATIVE-P.
 312
 313 RELATIVE-P is t if the composition method is relative, else nil.
 314
 315 If RELATIVE-P is t, COMPONENTS is a vector of characters to be
 316 composed.  If RELATIVE-P is nil, COMPONENTS is a vector of characters
 317 and composition rules as described in `compose-region'.
 318
 319 MOD-FUNC is a modification function of the composition.
 320
 321 WIDTH is a number of columns the composition occupies on the screen."
 322   (let ((result (find-composition-internal pos limit string detail-p)))
 323     (if (and detail-p result (nth 2 result) (not (nth 3 result)))
 324         ;; This is a valid rule-base composition.
 325         (decode-composition-components (nth 2 result) 'nocopy))
 326     result))
 327
 328 \f
 329 (defun compose-chars-after (pos &optional limit object)
 330   "Compose characters in current buffer after position POS.
 331
 332 It looks up the char-table `composition-function-table' (which
 333 see) by a character at POS, and compose characters after POS
 334 according to the contents of `composition-function-table'.
 335
 336 Optional 2nd arg LIMIT, if non-nil, limits characters to compose.
 337
 338 Optional 3rd arg OBJECT, if non-nil, is a string that contains the
 339 text to compose.  In that case, POS and LIMIT index into the string.
 340
 341 This function is the default value of `compose-chars-after-function'."
 342   (let ((tail (aref composition-function-table (char-after pos)))
 343         (font-obj (and (display-multi-font-p)
 344                        (and (not (stringp object))
 345                             (font-at pos (selected-window)))))
 346         pattern func result)
 347     (or limit
 348         (setq limit (if (stringp object) (length object) (point-max))))
 349     (when (and font-obj tail)
 350       (save-match-data
 351         (save-excursion
 352           (while tail
 353             (if (functionp (car tail))
 354                 (setq pattern nil func (car tail))
 355               (setq pattern (car (car tail))
 356                     func (cdr (car tail))))
 357             (goto-char pos)
 358             (if pattern
 359                 (if (and (if (stringp object)
 360                              (eq (string-match pattern object) 0)
 361                            (looking-at pattern))
 362                          (<= (match-end 0) limit))
 363                     (setq result
 364                           (funcall func pos (match-end 0) font-obj object)))
 365               (setq result (funcall func pos limit font-obj  object)))
 366             (if result (setq tail nil))))))
 367     result))
 368
 369 (defun compose-last-chars (args)
 370   "Compose last characters.
 371 The argument is a parameterized event of the form
 372         \(compose-last-chars N COMPONENTS),
 373 where N is the number of characters before point to compose,
 374 COMPONENTS, if non-nil, is the same as the argument to `compose-region'
 375 \(which see).  If it is nil, `compose-chars-after' is called,
 376 and that function finds a proper rule to compose the target characters.
 377 This function is intended to be used from input methods.
 378 The global keymap binds special event `compose-last-chars' to this
 379 function.  Input method may generate an event (compose-last-chars N COMPONENTS)
 380 after a sequence of character events."
 381   (interactive "e")
 382   (let ((chars (nth 1 args)))
 383     (if (and (numberp chars)
 384              (>= (- (point) (point-min)) chars))
 385         (if (nth 2 args)
 386             (compose-region (- (point) chars) (point) (nth 2 args))
 387           (compose-chars-after (- (point) chars) (point))))))
 388
 389 (global-set-key [compose-last-chars] 'compose-last-chars)
 390
 391 \f
 392 ;;; Automatic character composition.
 393
 394 ;; Copied from font-lock.el.
 395 (eval-when-compile
 396   ;; Borrowed from lazy-lock.el.
 397   ;; We use this to preserve or protect things when modifying text properties.
 398   (defmacro save-buffer-state (varlist &rest body)
 399     "Bind variables according to VARLIST and eval BODY restoring buffer state."
 400     `(let* ,(append varlist
 401                     '((modified (buffer-modified-p)) (buffer-undo-list t)
 402                       (inhibit-read-only t) (inhibit-point-motion-hooks t)
 403                       (inhibit-modification-hooks t)
 404                       deactivate-mark buffer-file-name buffer-file-truename))
 405        ,@body
 406        (unless modified
 407          (restore-buffer-modified-p nil))))
 408   ;; Fixme: This makes bootstrapping fail with this error.
 409   ;;   Symbol's function definition is void: eval-defun
 410   ;;(def-edebug-spec save-buffer-state let)
 411   )
 412
 413 (put 'save-buffer-state 'lisp-indent-function 1)
 414
 415 ;; These macros must match with C macros LGSTRING_XXX and LGLYPH_XXX in font.h
 416 (defsubst lgstring-header (gstring) (aref gstring 0))
 417 (defsubst lgstring-set-header (gstring header) (aset gstring 0 header))
 418 (defsubst lgstring-font (gstring) (aref (lgstring-header gstring) 0))
 419 (defsubst lgstring-char (gstring i) (aref (lgstring-header gstring) (1+ i)))
 420 (defsubst lgstring-char-len (gstring) (1- (length (lgstring-header gstring))))
 421 (defsubst lgstring-shaped-p (gstring) (aref gstring 1))
 422 (defsubst lgstring-set-id (gstring id) (aset gstring 1 id))
 423 (defsubst lgstring-glyph (gstring i) (aref gstring (+ i 2)))
 424 (defsubst lgstring-glyph-len (gstring) (- (length gstring) 2))
 425 (defsubst lgstring-set-glyph (gstring i glyph) (aset gstring (+ i 2) glyph))
 426
 427 (defsubst lglyph-from (glyph) (aref glyph 0))
 428 (defsubst lglyph-to (glyph) (aref glyph 1))
 429 (defsubst lglyph-char (glyph) (aref glyph 2))
 430 (defsubst lglyph-code (glyph) (aref glyph 3))
 431 (defsubst lglyph-width (glyph) (aref glyph 4))
 432 (defsubst lglyph-lbearing (glyph) (aref glyph 5))
 433 (defsubst lglyph-rbearing (glyph) (aref glyph 6))
 434 (defsubst lglyph-ascent (glyph) (aref glyph 7))
 435 (defsubst lglyph-descent (glyph) (aref glyph 8))
 436 (defsubst lglyph-adjustment (glyph) (aref glyph 9))
 437
 438 (defsubst lglyph-set-from-to (glyph from to)
 439   (progn (aset glyph 0 from) (aset glyph 1 to)))
 440 (defsubst lglyph-set-char (glyph char) (aset glyph 2 char))
 441 (defsubst lglyph-set-width (glyph width) (aset glyph 4 width))
 442 (defsubst lglyph-set-adjustment (glyph &optional xoff yoff wadjust)
 443   (aset glyph 9 (vector (or xoff 0) (or yoff 0) (or wadjust 0))))
 444
 445 (defsubst lglyph-copy (glyph) (copy-sequence glyph))
 446
 447 (defun lgstring-insert-glyph (gstring idx glyph)
 448   (let ((nglyphs (lgstring-glyph-len gstring))
 449         (i idx) g)
 450     (while (and (< i nglyphs) (setq g (lgstring-glyph gstring i)))
 451       (setq i (1+ i)))
 452     (if (= i nglyphs)
 453         (setq gstring (vconcat gstring (vector glyph)))
 454       (if (< (1+ i) nglyphs)
 455           (lgstring-set-glyph gstring (1+ i) nil)))
 456     (while (> i idx)
 457       (lgstring-set-glyph gstring i (lgstring-glyph gstring (1- i)))
 458       (setq i (1- i)))
 459     (lgstring-set-glyph gstring i glyph)
 460     gstring))
 461
 462 (defun compose-glyph-string (gstring from to)
 463   (let ((glyph (lgstring-glyph gstring from))
 464         from-pos to-pos
 465         ascent descent lbearing rbearing)
 466     (setq from-pos (lglyph-from glyph)
 467           to-pos (lglyph-to (lgstring-glyph gstring (1- to))))
 468     (lglyph-set-from-to glyph from-pos to-pos)
 469     (setq from (1+ from))
 470     (while (and (< from to)
 471                 (setq glyph (lgstring-glyph gstring from)))
 472       (lglyph-set-from-to glyph from-pos to-pos)
 473       (let ((xoff (if (<= (lglyph-rbearing glyph) 0) 0
 474                     (- (lglyph-width glyph)))))
 475         (lglyph-set-adjustment glyph xoff 0 0))
 476       (setq from (1+ from)))
 477     gstring))
 478
 479 (defun compose-glyph-string-relative (gstring from to &optional gap)
 480   (let ((font-object (lgstring-font gstring))
 481         (glyph (lgstring-glyph gstring from))
 482         from-pos to-pos
 483         ascent descent lbearing rbearing)
 484     (if gap
 485         (setq gap (floor (* (font-get font-object :size) gap)))
 486       (setq gap 0))
 487     (setq from-pos (lglyph-from glyph)
 488           to-pos (lglyph-to (lgstring-glyph gstring (1- to)))
 489           ascent (lglyph-ascent glyph)
 490           descent (lglyph-descent glyph))
 491     (lglyph-set-from-to glyph from-pos to-pos)
 492     (setq from (1+ from))
 493     (while (< from to)
 494       (setq glyph (lgstring-glyph gstring from))
 495       (lglyph-set-from-to glyph from-pos to-pos)
 496       (let ((this-ascent (lglyph-ascent glyph))
 497             (this-descent (lglyph-descent glyph))
 498             xoff yoff wadjust)
 499         (setq xoff (if (<= (lglyph-rbearing glyph) 0) 0
 500                      (- (lglyph-width glyph))))
 501         (if (> this-ascent 0)
 502             (if (< this-descent 0)
 503                 (setq yoff (- 0 ascent gap this-descent)
 504                       ascent (+ ascent gap this-ascent this-descent))
 505               (setq yoff 0))
 506           (setq yoff (+ descent gap this-ascent)
 507                 descent (+ descent gap this-ascent this-descent)))
 508         (if (or (/= xoff 0) (/= yoff 0))
 509             (lglyph-set-adjustment glyph xoff yoff 0)))
 510       (setq from (1+ from)))
 511     gstring))
 512
 513 (defun compose-gstring-for-graphic (gstring)
 514   "Compose glyph-string GSTRING for graphic display.
 515 Non-spacing characters are composed with the preceding base
 516 character.  If the preceding character is not a base character,
 517 each non-spacing character is composed as a spacing character by
 518 a padding space before and/or after the character.
 519
 520 All non-spacing characters has this function in
 521 `composition-function-table' unless overwritten."
 522   (let* ((header (lgstring-header gstring))
 523          (nchars (lgstring-char-len gstring))
 524          (nglyphs (lgstring-glyph-len gstring))
 525          (glyph (lgstring-glyph gstring 0)))
 526     (cond
 527      ;; A non-spacing character not following a proper base character.
 528      ((= nchars 1)
 529       (let ((lbearing (lglyph-lbearing glyph))
 530             (rbearing (lglyph-rbearing glyph))
 531             (width (lglyph-width glyph))
 532             xoff wadjust)
 533         (if (< lbearing 0)
 534             (setq xoff (- lbearing))
 535           (setq xoff 0 lbearing 0))
 536         (if (< rbearing width)
 537             (setq rbearing width))
 538         (lglyph-set-adjustment glyph xoff 0 (- rbearing lbearing))
 539         gstring))
 540
 541      ;; This sequence doesn't start with a proper base character.
 542      ((memq (get-char-code-property (lgstring-char gstring 0)
 543                                     'general-category)
 544             '(Mn Mc Me Zs Zl Zp Cc Cf Cs))
 545       nil)
 546
 547      ;; A base character and the following non-spacing characters.
 548      (t
 549       (let ((gstr (font-shape-gstring gstring)))
 550         (if (and gstr
 551                  (> (lglyph-to (lgstring-glyph gstr 0)) 0))
 552             gstr
 553           ;; The shaper of the font couldn't shape the gstring.
 554           ;; Shape them according to canonical-combining-class.
 555           (lgstring-set-id gstring nil)
 556           (let* ((width (lglyph-width glyph))
 557                  (ascent (lglyph-ascent glyph))
 558                  (descent (lglyph-descent glyph))
 559                  (rbearing (lglyph-rbearing glyph))
 560                  (lbearing (lglyph-lbearing glyph))
 561                  (center (/ (+ lbearing rbearing) 2))
 562                  (gap (round (* (font-get (lgstring-font gstring) :size) 0.1)))
 563                  xoff yoff)
 564             (dotimes (i nchars)
 565               (setq glyph (lgstring-glyph gstring i))
 566               (when (> i 0)
 567                 (let* ((class (get-char-code-property
 568                                (lglyph-char glyph) 'canonical-combining-class))
 569                        (lb (lglyph-lbearing glyph))
 570                        (rb (lglyph-rbearing glyph))
 571                        (as (lglyph-ascent glyph))
 572                        (de (lglyph-descent glyph))
 573                        (ce (/ (+ lb rb) 2))
 574                        xoff yoff)
 575                   (if (and
 576                        class (>= class 200) (<= class 240)
 577                        (cond
 578                         ((= class 200)
 579                          (setq xoff (- lbearing ce)
 580                                yoff (if (> as 0) 0 (+ descent as))))
 581                         ((= class 202)
 582                          (if (> as 0) (setq as 0))
 583                          (setq xoff (- center ce)
 584                                yoff (if (> as 0) 0 (+ descent as))))
 585                         ((= class 204)
 586                          (if (> as 0) (setq as 0))
 587                          (setq xoff (- rbearing ce)
 588                                yoff (if (> as 0) 0 (+ descent as))))
 589                         ((= class 208)
 590                          (setq xoff (- lbearing rb)))
 591                         ((= class 210)
 592                          (setq xoff (- rbearing lb)))
 593                         ((= class 212)
 594                          (setq xoff (- lbearing ce)
 595                                yoff (if (>= de 0) 0 (- ascent de))))
 596                         ((= class 214)
 597                          (setq xoff (- center ce)
 598                                yoff (if (>= de 0) 0 (- ascent de))))
 599                         ((= class 216)
 600                          (setq xoff (- rbearing ce)
 601                                yoff (if (>= de 0) 0 (- ascent de))))
 602                         ((= class 218)
 603                          (setq xoff (- lbearing ce)
 604                                yoff (if (> as 0) 0 (+ descent as gap))))
 605                         ((= class 220)
 606                          (setq xoff (- center ce)
 607                                yoff (if (> as 0) 0 (+ descent as gap))))
 608                         ((= class 222)
 609                          (setq xoff (- rbearing ce)
 610                                yoff (if (> as 0) 0 (+ descent as gap))))
 611                         ((= class 224)
 612                          (setq xoff (- lbearing rb)))
 613                         ((= class 226)
 614                          (setq xoff (- rbearing lb)))
 615                         ((= class 228)
 616                          (setq xoff (- lbearing ce)
 617                                yoff (if (>= de 0) 0 (- ascent de gap))))
 618                         ((= class 230)
 619                          (setq xoff (- center ce)
 620                                yoff (if (>= de 0) 0 (- ascent de gap))))
 621                         ((= class 232)
 622                          (setq xoff (- rbearing ce)
 623                                yoff (if (>= de 0) 0 (- ascent de gap))))))
 624                       (lglyph-set-adjustment glyph (- xoff width) yoff))))))
 625           (let ((i 0))
 626             (while (and (< i nglyphs) (setq glyph (lgstring-glyph gstring i)))
 627               (lglyph-set-from-to glyph 0 (1- nchars))
 628               (setq i (1+ i))))
 629           gstring))))))
 630
 631 (let ((elt '(["\\C^\\c^+" 1 compose-gstring-for-graphic]
 632              [nil 0 compose-gstring-for-graphic])))
 633   (map-char-table
 634    #'(lambda (key val)
 635        (if (= val 0)
 636            (set-char-table-range composition-function-table key elt)))
 637    char-width-table))
 638
 639 (defun compose-gstring-for-terminal (gstring)
 640   "Compose glyph string GSTRING for terminal display.
 641 Non-spacing characters are composed with the preceding base
 642 character.  If the preceding character is not a base character,
 643 each non-spacing character is composed as a spacing character by
 644 a prepending a space before it."
 645   (let* ((header (lgstring-header gstring))
 646          (nchars (lgstring-char-len gstring))
 647          (nglyphs (lgstring-glyph-len gstring))
 648          (i 0)
 649          glyph)
 650     (while (and (< i nglyphs)
 651                 (setq glyph (lgstring-glyph gstring i)))
 652       (if (= (lglyph-width glyph) 0)
 653           (progn
 654             ;; Compose by prepending a space.
 655             (setq gstring (lgstring-insert-glyph gstring i (lglyph-copy glyph))
 656                   nglyphs (lgstring-glyph-len gstring))
 657             (lglyph-set-char (lgstring-glyph gstring i) 32)
 658             (setq i (+ 2)))
 659         (let ((from (lglyph-from glyph))
 660               (to (lglyph-to glyph))
 661               (j (1+ i)))
 662           (while (and (< j nglyphs)
 663                       (setq glyph (lgstring-glyph gstring j))
 664                       (= (lglyph-width glyph) 0))
 665             (setq to (lglyph-to glyph)
 666                   j (1+ j)))
 667           (while (< i j)
 668             (setq glyph (lgstring-glyph gstring i))
 669             (lglyph-set-from-to glyph from to)
 670             (setq i (1+ i))))))
 671     gstring))
 672
 673
 674 (defun auto-compose-chars (func from to font-object string)
 675   "Compose the characters at FROM by FUNC.
 676 FUNC is called with one argument GSTRING which is built for characters
 677 in the region FROM (inclusive) and TO (exclusive).
 678
 679 If the character are composed on a graphic display, FONT-OBJECT
 680 is a font to use.
 681
 682 Otherwise, FONT-OBJECT is nil, and the fucntion
 683 `compose-gstring-for-terminal' is used instead of FUNC.
 684
 685 If STRING is non-nil, it is a string, and FROM and TO are indices
 686 into the string.  In that case, compose characters in the string.
 687
 688 The value is a gstring containing information for shaping the characters.
 689
 690 This function is the default value of `auto-composition-function' (which see)."
 691   (let ((gstring (composition-get-gstring from to font-object string)))
 692     (if (lgstring-shaped-p gstring)
 693         gstring
 694       (or font-object
 695           (setq func 'compose-gstring-for-terminal))
 696       (funcall func gstring))))
 697
 698 (make-variable-buffer-local 'auto-composition-function)
 699
 700 ;;;###autoload
 701 (define-minor-mode auto-composition-mode
 702   "Toggle Auto Composition mode.
 703 With ARG, turn Auto Composition mode off if and only if ARG is a non-positive
 704 number; if ARG is nil, toggle Auto Composition mode; anything else turns Auto
 705 Composition on.
 706
 707 When Auto Composition is enabled, text characters are automatically composed
 708 by functions registered in `composition-function-table' (which see).
 709
 710 You can use `global-auto-composition-mode' to turn on
 711 Auto Composition mode in all buffers (this is the default)."
 712   nil nil nil
 713   (if noninteractive
 714       (setq auto-composition-mode nil))
 715   (cond (auto-composition-mode
 716          (add-hook 'after-change-functions 'auto-composition-after-change nil t)
 717          (setq auto-composition-function 'auto-compose-chars))
 718         (t
 719          (remove-hook 'after-change-functions 'auto-composition-after-change t)
 720          (setq auto-composition-function nil)))
 721   (save-buffer-state nil
 722     (save-restriction
 723       (widen)
 724       (remove-text-properties (point-min) (point-max) '(auto-composed nil))
 725       (decompose-region (point-min) (point-max)))))
 726
 727 (defun auto-composition-after-change (start end old-len)
 728   (save-buffer-state nil
 729     (if (< start (point-min))
 730         (setq start (point-min)))
 731     (if (> end (point-max))
 732         (setq end (point-max)))
 733     (when (and auto-composition-mode (not memory-full))
 734       (let (func1 func2)
 735         (when (and (> start (point-min))
 736                    (setq func2 (aref composition-function-table
 737                                      (char-after (1- start))))
 738                    (or (= start (point-max))
 739                        (not (setq func1 (aref composition-function-table
 740                                               (char-after start))))
 741                        (eq func1 func2)))
 742           (setq start (1- start)
 743                 func1 func2)
 744           (while (eq func1 func2)
 745             (if (> start (point-min))
 746                 (setq start (1- start)
 747                       func2 (aref composition-function-table
 748                                   (char-after start)))
 749               (setq func2 nil))))
 750         (when (and (< end (point-max))
 751                    (setq func2 (aref composition-function-table
 752                                      (char-after end)))
 753                    (or (= end (point-min))
 754                        (not (setq func1 (aref composition-function-table
 755                                               (char-after (1- end)))))
 756                        (eq func1 func2)))
 757           (setq end (1+ end)
 758                 func1 func2)
 759           (while (eq func1 func2)
 760             (if (< end (point-max))
 761                 (setq func2 (aref composition-function-table
 762                                   (char-after end))
 763                       end (1+ end))
 764               (setq func2 nil))))
 765         (if (< start end)
 766             (remove-text-properties start end '(auto-composed nil)))))))
 767
 768 (defun turn-on-auto-composition-if-enabled ()
 769   (if enable-multibyte-characters
 770       (auto-composition-mode 1)))
 771
 772 ;;;###autoload
 773 (define-global-minor-mode global-auto-composition-mode
 774   auto-composition-mode turn-on-auto-composition-if-enabled
 775   :extra-args (dummy)
 776   :initialize 'custom-initialize-safe-default
 777   :init-value (not noninteractive)
 778   :group 'auto-composition
 779   :version "23.1")
 780
 781 (defun toggle-auto-composition (&optional arg)
 782   "Change whether automatic character composition is enabled in this buffer.
 783 With arg, enable it if and only if arg is positive."
 784   (interactive "P")
 785   (let ((enable (if (null arg) (not auto-composition-function)
 786                   (> (prefix-numeric-value arg) 0))))
 787     (if enable
 788         (kill-local-variable 'auto-composition-function)
 789       (make-local-variable 'auto-composition-function)
 790       (setq auto-composition-function nil)
 791       (save-buffer-state nil
 792         (save-restriction
 793           (widen)
 794           (decompose-region (point-min) (point-max)))))
 795
 796     (save-buffer-state nil
 797       (save-restriction
 798         (widen)
 799         (remove-text-properties (point-min) (point-max)
 800                                 '(auto-composed nil))))))
 801
 802 (defun auto-compose-region (from to)
 803   "Force automatic character composition on the region FROM and TO."
 804   (save-excursion
 805     (if (get-text-property from 'auto-composed)
 806         (setq from (next-single-property-change from 'auto-composed nil to)))
 807     (goto-char from)
 808     (let ((modified-p (buffer-modified-p))
 809           (inhibit-read-only '(composition auto-composed))
 810           (stop (next-single-property-change (point) 'auto-composed nil to)))
 811       (while (< (point) to)
 812         (if (= (point) stop)
 813             (progn
 814               (goto-char (next-single-property-change (point)
 815                                                       'auto-composed nil to))
 816               (setq stop (next-single-property-change (point)
 817                                                       'auto-composed nil to)))
 818           (let ((func (aref composition-function-table (following-char)))
 819                 (font-obj (and (display-multi-font-p)
 820                                (font-at (point) (selected-window))))
 821                 (pos (point)))
 822             (if (and (functionp func) font-obj)
 823                 (goto-char (funcall func (point) to font-obj nil)))
 824             (if (<= (point) pos)
 825                 (forward-char 1)))))
 826       (put-text-property from to 'auto-composed t)
 827       (set-buffer-modified-p modified-p))))
 828
 829 \f
 830 ;; The following codes are only for backward compatibility with Emacs
 831 ;; 20.4 and earlier.
 832
 833 (defun decompose-composite-char (char &optional type with-composition-rule)
 834   "Convert CHAR to string.
 835
 836 If optional 2nd arg TYPE is non-nil, it is `string', `list', or
 837 `vector'.  In this case, CHAR is converted to string, list of CHAR, or
 838 vector of CHAR respectively.
 839 Optional 3rd arg WITH-COMPOSITION-RULE is ignored."
 840   (cond ((or (null type) (eq type 'string)) (char-to-string char))
 841         ((eq type 'list) (list char))
 842         (t (vector char))))
 843
 844 (make-obsolete 'decompose-composite-char 'char-to-string "21.1")
 845
 846 \f
 847
 848 ;; arch-tag: ee703d77-1723-45d4-a31f-e9f0f867aa33
 849 ;;; composite.el ends here