configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 leimdir='${datadir}/emacs/${version}/leim'
  41 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  42 '${datadir}/emacs/site-lisp'
  43 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  44 etcdir='${datadir}/emacs/${version}/etc'
  45 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  46 docdir='${datadir}/emacs/${version}/etc'
  47 gamedir='${localstatedir}/games/emacs'
  48
  49 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  50 dnl Create a new --with option that defaults to being disabled.
  51 dnl NAME is the base name of the option.  The shell variable with_NAME
  52 dnl   will be set to either the user's value (if the option is
  53 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  54 dnl   option is not specified).  Note that the shell variable name is
  55 dnl   constructed as autoconf does, by replacing non-alphanumeric
  56 dnl   characters with "_".
  57 dnl HELP-STRING is the help text for the option.
  58 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  59   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  60     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  61 ])dnl
  62
  63 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  64 dnl Create a new --with option that defaults to being enabled.  NAME
  65 dnl   is the base name of the option.  The shell variable with_NAME
  66 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  67 dnl   'yes' (if the option is not specified).  Note that the shell
  68 dnl   variable name is constructed as autoconf does, by replacing
  69 dnl   non-alphanumeric characters with "_".
  70 dnl HELP-STRING is the help text for the option.
  71 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  72   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  73    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  74 ])dnl
  75
  76 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  77 if test "$with_pop" = yes; then
  78    AC_DEFINE(MAIL_USE_POP)
  79 fi
  80 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  81
  82 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  83 if test "$with_kerberos" != no; then
  84    AC_DEFINE(KERBEROS)
  85 fi
  86 AH_TEMPLATE(KERBEROS,
  87             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  88
  89 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  90 if test "${with_kerberos5}" != no; then
  91   if test "${with_kerberos}" = no; then
  92     with_kerberos=yes
  93     AC_DEFINE(KERBEROS)
  94   fi
  95   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  96 fi
  97
  98 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  99 dnl FIXME hesiod support may not be present, so it seems like an error
 100 dnl to define, or at least use, this unconditionally.
 101 if test "$with_hesiod" != no; then
 102   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 106 if test "$with_mmdf" != no; then
 107    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 108 fi
 109
 110 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 111 if test "$with_mail_unlink" != no; then
 112    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 113 fi
 114
 115 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 116     [string giving default POP mail host])],
 117     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 118
 119 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 120
 121 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 122 if test "$with_sync_input" = yes; then
 123    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 124 fi
 125
 126 dnl FIXME currently it is not the last.
 127 dnl This should be the last --with option, because --with-x is
 128 dnl added later on when we find the path of X, and it's best to
 129 dnl keep them together visually.
 130 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 131  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 132 [         case "${withval}" in
 133             y | ye | yes )      val=gtk ;;
 134             n | no )            val=no  ;;
 135             l | lu | luc | luci | lucid )       val=lucid ;;
 136             a | at | ath | athe | athen | athena )      val=athena ;;
 137             m | mo | mot | moti | motif )       val=motif ;;
 138             g | gt | gtk  )     val=gtk ;;
 139             gtk3  )     val=gtk3 ;;
 140             * )
 141 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 142 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 143 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 144             ;;
 145           esac
 146           with_x_toolkit=$val
 147 ])
 148
 149 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 150 if test "$with_wide_int" = yes; then
 151   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 152 fi
 153
 154 dnl _ON results in a '--without' option in the --help output, so
 155 dnl the help text should refer to "don't compile", etc.
 156 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 157 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 158 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 159 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 160 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 161 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 162 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 163 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 164
 165 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 166 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 167 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 168
 169 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 170 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 171 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 172 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 173
 174 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 175 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 176 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 177 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 178 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 179 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 180
 181 ## For the times when you want to build Emacs but don't have
 182 ## a suitable makeinfo, and can live without the manuals.
 183 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 184 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 185
 186 ## Makefile.in needs the cache file name.
 187 AC_SUBST(cache_file)
 188
 189 ## This is an option because I do not know if all info/man support
 190 ## compressed files, nor how to test if they do so.
 191 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 192 if test $with_compress_info = yes; then
 193    GZIP_INFO=yes
 194 else
 195    GZIP_INFO=
 196 fi
 197 AC_SUBST(GZIP_INFO)
 198
 199 AC_ARG_WITH([pkg-config-prog],dnl
 200 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 201                   [path to pkg-config for finding GTK and librsvg])])
 202 if test "X${with_pkg_config_prog}" != X; then
 203    if test "${with_pkg_config_prog}" != yes; then
 204       PKG_CONFIG="${with_pkg_config_prog}"
 205    fi
 206 fi
 207
 208 CRT_DIR=
 209 AC_ARG_WITH([crt-dir],dnl
 210 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 211 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 212 CRT_DIR="${with_crt_dir}"
 213
 214 AC_ARG_WITH(gameuser,dnl
 215 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 216 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 217   && gameuser="${with_gameuser}"
 218 test "X$gameuser" = X && gameuser=games
 219
 220 AC_ARG_WITH([gnustep-conf],dnl
 221 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 222 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 223   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 224 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 225      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 226
 227 AC_ARG_ENABLE(ns-self-contained,
 228 [AS_HELP_STRING([--disable-ns-self-contained],
 229                 [disable self contained build under NeXTstep])],
 230    EN_NS_SELF_CONTAINED=$enableval,
 231    EN_NS_SELF_CONTAINED=yes)
 232
 233 AC_ARG_ENABLE(asserts,
 234 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 235       USE_XASSERTS=$enableval,
 236       USE_XASSERTS=no)
 237
 238 AC_ARG_ENABLE(locallisppath,
 239 [AS_HELP_STRING([--enable-locallisppath=PATH],
 240                 [directories Emacs should search for lisp files specific
 241                  to this site])],
 242 if test "${enableval}" = "no"; then
 243   locallisppath=
 244 elif test "${enableval}" != "yes"; then
 245   locallisppath=${enableval}
 246 fi)
 247
 248 AC_ARG_ENABLE(checking,
 249 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 250                 [enable expensive run-time checks.  With LIST,
 251                  enable only specific categories of checks.
 252                  Categories are: all,yes,no.
 253                  Flags are: stringbytes, stringoverrun, stringfreelist,
 254                  xmallocoverrun, conslist])],
 255 [ac_checking_flags="${enableval}"],[])
 256 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 257 for check in $ac_checking_flags
 258 do
 259         case $check in
 260         # these set all the flags to specific states
 261         yes)            ac_enable_checking=1 ;;
 262         no)             ac_enable_checking= ;
 263                         ac_gc_check_stringbytes= ;
 264                         ac_gc_check_string_overrun= ;
 265                         ac_gc_check_string_free_list= ;
 266                         ac_xmalloc_overrun= ;
 267                         ac_gc_check_cons_list= ;;
 268         all)            ac_enable_checking=1 ;
 269                         ac_gc_check_stringbytes=1 ;
 270                         ac_gc_check_string_overrun=1 ;
 271                         ac_gc_check_string_free_list=1 ;
 272                         ac_xmalloc_overrun=1 ;
 273                         ac_gc_check_cons_list=1 ;;
 274         # these enable particular checks
 275         stringbytes)    ac_gc_check_stringbytes=1 ;;
 276         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 277         stringfreelist) ac_gc_check_string_free_list=1 ;;
 278         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 279         conslist)       ac_gc_check_cons_list=1 ;;
 280         *)      AC_MSG_ERROR(unknown check category $check) ;;
 281         esac
 282 done
 283 IFS="$ac_save_IFS"
 284
 285 if test x$ac_enable_checking != x ; then
 286   AC_DEFINE(ENABLE_CHECKING, 1,
 287 [Enable expensive run-time checking of data types?])
 288 fi
 289 if test x$ac_gc_check_stringbytes != x ; then
 290   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 291 [Define this temporarily to hunt a bug.  If defined, the size of
 292    strings is redundantly recorded in sdata structures so that it can
 293    be compared to the sizes recorded in Lisp strings.])
 294 fi
 295 if test x$ac_gc_check_string_overrun != x ; then
 296   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 297 [Define this to check for short string overrun.])
 298 fi
 299 if test x$ac_gc_check_string_free_list != x ; then
 300   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 301 [Define this to check the string free list.])
 302 fi
 303 if test x$ac_xmalloc_overrun != x ; then
 304   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 305 [Define this to check for malloc buffer overrun.])
 306 fi
 307 if test x$ac_gc_check_cons_list != x ; then
 308   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 309 [Define this to check for errors in cons list.])
 310 fi
 311
 312 AC_ARG_ENABLE(use-lisp-union-type,
 313 [AS_HELP_STRING([--enable-use-lisp-union-type],
 314                 [use a union for the Lisp_Object data type.
 315                 This is only useful for development for catching certain types of bugs.])],
 316 if test "${enableval}" != "no"; then
 317    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 318    [Define this to use a lisp union for the Lisp_Object data type.])
 319 fi)
 320
 321
 322 AC_ARG_ENABLE(profiling,
 323 [AS_HELP_STRING([--enable-profiling],
 324                 [build emacs with profiling support.
 325                  This might not work on all platforms])],
 326 [ac_enable_profiling="${enableval}"],[])
 327 if test x$ac_enable_profiling != x ; then
 328    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 329 else
 330    PROFILING_CFLAGS=
 331 fi
 332 AC_SUBST(PROFILING_CFLAGS)
 333
 334 AC_ARG_ENABLE(autodepend,
 335 [AS_HELP_STRING([--enable-autodepend],
 336                 [automatically generate dependencies to .h-files.
 337                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 338                  found])],
 339 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 340
 341 #### Make srcdir absolute, if it isn't already.  It's important to
 342 #### avoid running the path through pwd unnecessarily, since pwd can
 343 #### give you automounter prefixes, which can go away.  We do all this
 344 #### so Emacs can find its files when run uninstalled.
 345 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 346 unset CDPATH
 347 case "${srcdir}" in
 348   /* ) ;;
 349   . )
 350     ## We may be able to use the $PWD environment variable to make this
 351     ## absolute.  But sometimes PWD is inaccurate.
 352     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 353     ## but that tested only for a well-formed and valid PWD,
 354     ## it did not object when PWD was well-formed and valid but just wrong.
 355     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 356     then
 357       srcdir="$PWD"
 358     else
 359       srcdir="`(cd ${srcdir}; pwd)`"
 360     fi
 361   ;;
 362   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 363 esac
 364
 365 #### Given the configuration name, set opsysfile to the
 366 #### name of s/*.h file we should use.
 367
 368 ### Canonicalize the configuration name.
 369
 370 AC_CANONICAL_HOST
 371 canonical=$host
 372 configuration=${host_alias-${build_alias-$host}}
 373
 374 dnl This used to use changequote, but, apart from `changequote is evil'
 375 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 376 dnl the great gob of text.  Thus it's not processed for possible expansion.
 377 dnl Just make sure the brackets remain balanced.
 378 dnl
 379 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 380 dnl indicated by comments.
 381 dnl quotation begins
 382 [
 383
 384 ### If you add support for a new configuration, add code to this
 385 ### switch statement to recognize your configuration name and select
 386 ### the appropriate operating system file.
 387
 388 ### You would hope that you could choose an s/*.h
 389 ### file based on the operating system portion.  However, it turns out
 390 ### that each s/*.h file is pretty manufacturer-specific.
 391 ### So we basically have to have a special case for each
 392 ### configuration name.
 393 ###
 394 ### As far as handling version numbers on operating systems is
 395 ### concerned, make sure things will fail in a fixable way.  If
 396 ### /etc/MACHINES doesn't say anything about version numbers, be
 397 ### prepared to handle anything reasonably.  If version numbers
 398 ### matter, be sure /etc/MACHINES says something about it.
 399
 400 opsys='' unported=no
 401 case "${canonical}" in
 402
 403   ## GNU/Linux and similar ports
 404   *-*-linux* )
 405     opsys=gnu-linux
 406   ;;
 407
 408   ## FreeBSD ports
 409   *-*-freebsd* )
 410     opsys=freebsd
 411   ;;
 412
 413   ## FreeBSD kernel + glibc based userland
 414   *-*-kfreebsd*gnu* )
 415     opsys=gnu-kfreebsd
 416   ;;
 417
 418   ## NetBSD ports
 419   *-*-netbsd* )
 420     opsys=netbsd
 421   ;;
 422
 423   ## OpenBSD ports
 424   *-*-openbsd* )
 425     opsys=openbsd
 426   ;;
 427
 428   ## Apple Darwin / Mac OS X
 429   *-apple-darwin* )
 430     case "${canonical}" in
 431       i[3456]86-* )  ;;
 432       powerpc-* )    ;;
 433       x86_64-* )     ;;
 434       * )            unported=yes ;;
 435     esac
 436     opsys=darwin
 437     ## Use fink packages if available.
 438     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 439 ##    if test -d /sw/include && test -d /sw/lib; then
 440 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 441 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 442 ##    fi
 443   ;;
 444
 445   ## HP 9000 series 700 and 800, running HP/UX
 446   hppa*-hp-hpux10.2* )
 447     opsys=hpux10-20
 448   ;;
 449   hppa*-hp-hpux1[1-9]* )
 450     opsys=hpux11
 451     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 452   ;;
 453
 454   ## IBM machines
 455   rs6000-ibm-aix4.[23]* )
 456     opsys=aix4-2
 457   ;;
 458   powerpc-ibm-aix4.[23]*  )
 459     opsys=aix4-2
 460   ;;
 461   rs6000-ibm-aix[56]* )
 462     opsys=aix4-2
 463   ;;
 464   powerpc-ibm-aix[56]*  )
 465     opsys=aix4-2
 466   ;;
 467
 468   ## Silicon Graphics machines
 469   ## Iris 4D
 470   mips-sgi-irix6.5 )
 471     opsys=irix6-5
 472     # Without defining _LANGUAGE_C, things get masked out in the headers
 473     # so that, for instance, grepping for `free' in stdlib.h fails and
 474     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 475     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 476   ;;
 477
 478   ## Suns
 479   *-sun-solaris* \
 480     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 481     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 482     case "${canonical}" in
 483       i[3456]86-*-* )   ;;
 484       amd64-*-*|x86_64-*-*) ;;
 485       sparc* )          ;;
 486       * )               unported=yes ;;
 487     esac
 488     case "${canonical}" in
 489       *-sunos5.6* | *-solaris2.6* )
 490                 opsys=sol2-6
 491                 RANLIB="ar -ts"
 492                 ;;
 493       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 494                 opsys=sol2-6
 495                 emacs_check_sunpro_c=yes
 496                 ;;
 497       *-sunos5* | *-solaris* )
 498                 opsys=sol2-10
 499                 emacs_check_sunpro_c=yes
 500                 ;;
 501     esac
 502     ## Watch out for a compiler that we know will not work.
 503     case "${canonical}" in
 504      *-solaris* | *-sunos5* )
 505                 if [ "x$CC" = x/usr/ucb/cc ]; then
 506                   ## /usr/ucb/cc doesn't work;
 507                   ## we should find some other compiler that does work.
 508                   unset CC
 509                 fi
 510                 ;;
 511       *) ;;
 512     esac
 513   ;;
 514
 515   ## Intel 386 machines where we don't care about the manufacturer.
 516   i[3456]86-*-* )
 517     case "${canonical}" in
 518       *-cygwin )                opsys=cygwin ;;
 519       *-darwin* )               opsys=darwin ;;
 520       *-sysv4.2uw* )            opsys=unixware ;;
 521       *-sysv5uw* )              opsys=unixware ;;
 522       *-sysv5OpenUNIX* )        opsys=unixware ;;
 523       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 524     esac
 525   ;;
 526
 527   * )
 528     unported=yes
 529   ;;
 530 esac
 531
 532 ### If the code above didn't choose an operating system, just choose
 533 ### an operating system based on the configuration name.  You really
 534 ### only want to use this when you have no idea what the right
 535 ### operating system is; if you know what operating systems a machine
 536 ### runs, it's cleaner to make it explicit in the case statement
 537 ### above.
 538 if test x"${opsys}" = x; then
 539   case "${canonical}" in
 540     *-gnu* )                            opsys=gnu ;;
 541     * )
 542       unported=yes
 543     ;;
 544   esac
 545 fi
 546
 547 ]
 548 dnl quotation ends
 549
 550 if test $unported = yes; then
 551   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 552 Check `etc/MACHINES' for recognized configuration names.])
 553 fi
 554
 555 opsysfile="s/${opsys}.h"
 556
 557
 558 #### Choose a compiler.
 559
 560 dnl Sets GCC=yes if using gcc.
 561 AC_PROG_CC
 562 AM_PROG_CC_C_O
 563
 564 if test x$GCC = xyes; then
 565   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 566 else
 567   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 568 fi
 569
 570 # Initialize gnulib right after choosing the compiler.
 571 gl_EARLY
 572
 573 AC_ARG_ENABLE([gcc-warnings],
 574   [AS_HELP_STRING([--enable-gcc-warnings],
 575                   [turn on lots of GCC warnings (for developers)])],
 576   [case $enableval in
 577      yes|no) ;;
 578      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 579    esac
 580    gl_gcc_warnings=$enableval],
 581   [gl_gcc_warnings=no]
 582 )
 583
 584 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 585 # ------------------------------------------------
 586 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 587 # Otherwise, run RUN-IF-NOT-FOUND.
 588 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 589   [AC_PREPROC_IFELSE(
 590     [AC_LANG_PROGRAM(
 591       [[
 592 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 593 /* ok */
 594 #else
 595 # error "your version of gcc is older than $1.$2"
 596 #endif
 597       ]]),
 598     ], [$3], [$4])
 599   ]
 600 )
 601
 602 # When compiling with GCC, prefer -isystem to -I when including system
 603 # include files, to avoid generating useless diagnostics for the files.
 604 if test "$gl_gcc_warnings" != yes; then
 605   isystem='-I'
 606 else
 607   isystem='-isystem '
 608
 609   # This, $nw, is the list of warnings we disable.
 610   nw=
 611
 612   case $with_x_toolkit in
 613     lucid | athena | motif)
 614        # Old toolkits mishandle 'const'.
 615        nw="$nw -Wwrite-strings"
 616        ;;
 617     *)
 618        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 619        ;;
 620   esac
 621   AC_SUBST([WERROR_CFLAGS])
 622
 623   nw="$nw -Waggregate-return"       # anachronistic
 624   nw="$nw -Wlong-long"              # C90 is anachronistic
 625   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 626   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 627   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 628   nw="$nw -Wcast-qual"              # Too many warnings for now
 629   nw="$nw -Wconversion"             # Too many warnings for now
 630   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 631   nw="$nw -Wsign-conversion"        # Too many warnings for now
 632   nw="$nw -Woverlength-strings"     # Not a problem these days
 633   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 634   nw="$nw -Wpadded"                 # Our structs are not padded
 635   nw="$nw -Wredundant-decls"        # We regularly (re)declare getenv etc.
 636   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 637   nw="$nw -Wformat-nonliteral"      # Emacs does this a lot
 638   nw="$nw -Wvla"                    # warnings in gettext.h
 639   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 640   nw="$nw -Wswitch-enum"            # Too many warnings for now
 641   nw="$nw -Wswitch-default"         # Too many warnings for now
 642   nw="$nw -Wfloat-equal"            # e.g., ftoastr.c
 643   nw="$nw -Winline"                 # e.g., dispnew.c's inlining of row_equal_p
 644
 645   # Emacs doesn't care about shadowing; see
 646   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 647   nw="$nw -Wshadow"
 648
 649   # The following lines should be removable at some point.
 650   nw="$nw -Wstack-protector"
 651   nw="$nw -Wstrict-overflow"
 652   nw="$nw -Wsuggest-attribute=const"
 653   nw="$nw -Wsuggest-attribute=pure"
 654
 655   gl_MANYWARN_ALL_GCC([ws])
 656   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 657   for w in $ws; do
 658     gl_WARN_ADD([$w])
 659   done
 660   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 661   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 662   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 663   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 664   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 665   gl_WARN_ADD([-Wno-format-nonliteral])
 666
 667   # In spite of excluding -Wlogical-op above, it is enabled, as of
 668   # gcc 4.5.0 20090517.
 669   gl_WARN_ADD([-Wno-logical-op])
 670
 671   gl_WARN_ADD([-fdiagnostics-show-option])
 672   gl_WARN_ADD([-funit-at-a-time])
 673
 674   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 675   AC_DEFINE([_FORTIFY_SOURCE], [2],
 676     [enable compile-time and run-time bounds-checking, and some warnings])
 677   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 678
 679   # We use a slightly smaller set of warning options for lib/.
 680   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 681   nw=
 682   nw="$nw -Wunused-macros"
 683
 684   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 685   AC_SUBST([GNULIB_WARN_CFLAGS])
 686 fi
 687
 688
 689
 690 dnl Some other nice autoconf tests.
 691 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 692 dnl AC_PROG_INSTALL
 693 dnl AC_PROG_MKDIR_P
 694 dnl if test "x$RANLIB" = x; then
 695 dnl   AC_PROG_RANLIB
 696 dnl fi
 697
 698 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 699   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 700 dnl Don't use GZIP, which is used by gzip for additional parameters.
 701 AC_PATH_PROG(GZIP_PROG, gzip)
 702 AC_PATH_PROG(PAXCTL, paxctl,,
 703   [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 704
 705
 706 ## Need makeinfo >= 4.7 (?) to build the manuals.
 707 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 708 dnl By this stage, configure has already checked for egrep and set EGREP,
 709 dnl or exited with an error if no egrep was found.
 710 if test "$MAKEINFO" != "no" && \
 711   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 712    MAKEINFO=no
 713 fi
 714
 715 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 716 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 717 ## therefore in the category of "special tools" not normally required, which
 718 ## configure does not have to check for (eg autoconf itself).
 719 ## In a Bazaar checkout on the other hand, the manuals are not included.
 720 ## So makeinfo is a requirement to build from Bazaar, and configure
 721 ## should test for it as it does for any other build requirement.
 722 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 723 ## with pre-built manuals, from a Bazaar checkout.
 724 HAVE_MAKEINFO=yes
 725
 726 if test "$MAKEINFO" = "no"; then
 727   MAKEINFO=makeinfo
 728   if test "x${with_makeinfo}" = "xno"; then
 729     HAVE_MAKEINFO=no
 730   elif test ! -e $srcdir/info/emacs; then
 731     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 732 source tree does not seem to have pre-built manuals in the `info' directory.
 733 Either install a suitable version of makeinfo, or re-run configure
 734 with the `--without-makeinfo' option to build without the manuals.] )
 735   fi
 736 fi
 737 AC_SUBST(HAVE_MAKEINFO)
 738
 739 dnl Just so that there is only a single place we need to edit.
 740 INFO_EXT=.info
 741 INFO_OPTS=--no-split
 742 AC_SUBST(INFO_EXT)
 743 AC_SUBST(INFO_OPTS)
 744
 745 dnl Add our options to ac_link now, after it is set up.
 746
 747 if test x$GCC = xyes; then
 748   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 749     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 750 else
 751   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 752     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 753 fi
 754
 755 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 756 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 757 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 758 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 759 dnl if not built to support GNU ld.
 760
 761 late_LDFLAGS=$LDFLAGS
 762 if test x$GCC = xyes; then
 763   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 764 else
 765   LDFLAGS="$LDFLAGS -znocombreloc"
 766 fi
 767
 768 AC_MSG_CHECKING([for -znocombreloc])
 769 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 770   [AC_MSG_RESULT(yes)],
 771   LDFLAGS=$late_LDFLAGS
 772   [AC_MSG_RESULT(no)])
 773
 774
 775 dnl The function dump-emacs will not be defined and temacs will do
 776 dnl (load "loadup") automatically unless told otherwise.
 777 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 778 case "$opsys" in
 779   your-opsys-here) CANNOT_DUMP=yes ;;
 780 esac
 781
 782 test "$CANNOT_DUMP" = "yes" && \
 783   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 784
 785 AC_SUBST(CANNOT_DUMP)
 786
 787
 788 UNEXEC_OBJ=unexelf.o
 789 case "$opsys" in
 790   # MSDOS uses unexcoff.o
 791   # MSWindows uses unexw32.o
 792   aix4-2)
 793    UNEXEC_OBJ=unexaix.o
 794    ;;
 795   cygwin)
 796    UNEXEC_OBJ=unexcw.o
 797    ;;
 798   darwin)
 799    UNEXEC_OBJ=unexmacosx.o
 800    ;;
 801   hpux10-20 | hpux11)
 802    UNEXEC_OBJ=unexhp9k800.o
 803    ;;
 804   sol2-10)
 805    # Use the Solaris dldump() function, called from unexsol.c, to dump
 806    # emacs, instead of the generic ELF dump code found in unexelf.c.
 807    # The resulting binary has a complete symbol table, and is better
 808    # for debugging and other observability tools (debuggers, pstack, etc).
 809    #
 810    # If you encounter a problem using dldump(), please consider sending
 811    # a message to the OpenSolaris tools-linking mailing list:
 812    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 813    #
 814    # It is likely that dldump() works with older Solaris too, but this has
 815    # not been tested, so for now this change is for Solaris 10 or newer.
 816    UNEXEC_OBJ=unexsol.o
 817    ;;
 818 esac
 819
 820 LD_SWITCH_SYSTEM=
 821 case "$opsys" in
 822   freebsd)
 823    ## Let `ld' find image libs and similar things in /usr/local/lib.
 824    ## The system compiler, GCC, has apparently been modified to not
 825    ## look there, contrary to what a stock GCC would do.
 826 ### It's not our place to do this.  See bug#10313#17.
 827 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 828       :
 829    ;;
 830
 831   gnu-linux)
 832    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 833    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 834    ;;
 835
 836   netbsd)
 837 ### It's not our place to do this.  See bug#10313#17.
 838 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 839       :
 840    ;;
 841
 842   openbsd)
 843    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 844    ## otherwise Emacs dumps core on elf systems.
 845    LD_SWITCH_SYSTEM="-Z"
 846    ;;
 847 esac
 848 AC_SUBST(LD_SWITCH_SYSTEM)
 849
 850 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 851
 852 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 853 ## which has not been defined yet.  When this was handled with cpp,
 854 ## it was expanded to null when configure sourced the s/*.h file.
 855 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 856 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 857 ## (or somesuch), but because it is supposed to go at the _front_
 858 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 859 ## Compare with the gnu-linux case below, which added to the end
 860 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 861 ## LD_SWITCH_SYSTEM_TEMACS.
 862 case "$opsys" in
 863   netbsd|openbsd)
 864    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 865 esac
 866
 867
 868 C_SWITCH_MACHINE=
 869 case $canonical in
 870  alpha*)
 871   AC_CHECK_DECL([__ELF__])
 872   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 873     ## With ELF, make sure that all common symbols get allocated to in the
 874     ## data section.  Otherwise, the dump of temacs may miss variables in
 875     ## the shared library that have been initialized.  For example, with
 876     ## GNU libc, __malloc_initialized would normally be resolved to the
 877     ## shared library's .bss section, which is fatal.
 878     if test "x$GCC" = "xyes"; then
 879       C_SWITCH_MACHINE="-fno-common"
 880     else
 881       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 882     fi
 883   else
 884     UNEXEC_OBJ=unexalpha.o
 885   fi
 886   ;;
 887 esac
 888 AC_SUBST(C_SWITCH_MACHINE)
 889
 890 AC_SUBST(UNEXEC_OBJ)
 891
 892 C_SWITCH_SYSTEM=
 893 ## Some programs in src produce warnings saying certain subprograms
 894 ## are too complex and need a MAXMEM value greater than 2000 for
 895 ## additional optimization.  --nils@exp-math.uni-essen.de
 896 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 897   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 898 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 899 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 900 AC_SUBST(C_SWITCH_SYSTEM)
 901
 902
 903 LIBS_SYSTEM=
 904 case "$opsys" in
 905   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 906   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 907
 908   freebsd) LIBS_SYSTEM="-lutil" ;;
 909
 910   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 911
 912   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 913
 914   ## Motif needs -lgen.
 915   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 916 esac
 917 AC_SUBST(LIBS_SYSTEM)
 918
 919
 920 ### Make sure subsequent tests use flags consistent with the build flags.
 921
 922 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 923   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 924 else
 925   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 926 fi
 927
 928 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 929 AC_DEFUN([AC_TYPE_SIZE_T])
 930 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
 931 AC_DEFUN([AC_TYPE_UID_T])
 932
 933
 934 LIB_MATH=-lm
 935 LIB_STANDARD=
 936 START_FILES=
 937 dnl Current possibilities handled by sed (aix4-2 -> aix,
 938 dnl gnu-linux -> gnu/linux, etc.):
 939 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
 940 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
 941 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
 942
 943 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
 944 case $opsys in
 945   cygwin )
 946     LIB_MATH=
 947     START_FILES='pre-crt0.o'
 948     ;;
 949   darwin )
 950     ## Adding -lm confuses the dynamic linker, so omit it.
 951     LIB_MATH=
 952     START_FILES='pre-crt0.o'
 953     ;;
 954   freebsd )
 955     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
 956     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
 957     SYSTEM_TYPE=berkeley-unix
 958     ;;
 959   gnu-linux | gnu-kfreebsd )
 960     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
 961     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
 962     ;;
 963   hpux10-20 | hpux11 )
 964     LIB_STANDARD=-lc
 965     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
 966     ;;
 967   dnl NB this may be adjusted below.
 968   netbsd | openbsd )
 969     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
 970     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
 971     SYSTEM_TYPE=berkeley-unix
 972     ;;
 973
 974   sol2* | unixware )
 975     SYSTEM_TYPE=usg-unix-v
 976     ;;
 977
 978 esac
 979
 980 AC_SUBST(LIB_MATH)
 981 AC_SUBST(START_FILES)
 982 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
 983   [The type of system you are compiling for; sets `system-type'.])
 984
 985 dnl Not all platforms use crtn.o files.  Check if the current one does.
 986 crt_files=
 987
 988 for file in x $LIB_STANDARD $START_FILES; do
 989   case "$file" in
 990     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
 991   esac
 992 done
 993
 994 if test "x$crt_files" != x; then
 995
 996   ## If user specified a crt-dir, use that unconditionally.
 997   crt_gcc=no
 998
 999   if test "X$CRT_DIR" = "X"; then
1000
1001     CRT_DIR=/usr/lib            # default
1002
1003     case "$canonical" in
1004       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1005       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1006       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1007       ## For anything else (eg /usr/lib32), it is up the user to specify
1008       ## the location (bug#5655).
1009       ## Test for crtn.o, not just the directory, because sometimes the
1010       ## directory exists but does not have the relevant files (bug#1287).
1011       ## FIXME better to test for binary compatibility somehow.
1012       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1013       ;;
1014
1015       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1016     esac
1017
1018     case "$opsys" in
1019       hpux10-20) CRT_DIR=/lib ;;
1020     esac
1021
1022     test "x${GCC}" = xyes && crt_gcc=yes
1023
1024   fi                            # CRT_DIR = ""
1025
1026   crt_missing=
1027
1028   for file in $crt_files; do
1029
1030     ## If we're using gcc, try to determine it automatically by asking
1031     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1032     ## system-dependent default from above.]
1033     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1034
1035        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1036        case "$crt_file" in
1037          */*)
1038            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1039            ;;
1040        esac
1041     fi
1042
1043     dnl We expect all the files to be in a single directory, so after the
1044     dnl first there is no point asking gcc.
1045     crt_gcc=no
1046
1047     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1048   done                          # $crt_files
1049
1050   test "x$crt_missing" = x || \
1051     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1052 Try using the --with-crt-dir option.])
1053
1054 fi                              # crt_files != ""
1055
1056 AC_SUBST(CRT_DIR)
1057
1058 case $opsys in
1059   netbsd | openbsd )
1060     if test -f $CRT_DIR/crti.o; then
1061
1062         test -f $CRT_DIR/crtn.o || \
1063           AC_MSG_ERROR([Required file not found: crtn.o])
1064
1065         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1066         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1067     fi
1068     ;;
1069 esac
1070
1071
1072 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1073
1074 dnl This function definition taken from Gnome 2.0
1075 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1076 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1077 dnl also defines GSTUFF_PKG_ERRORS on error
1078 AC_DEFUN([PKG_CHECK_MODULES], [
1079   succeeded=no
1080
1081   if test "$PKG_CONFIG" = "no" ; then
1082      ifelse([$4], , [AC_MSG_ERROR([
1083       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1084   else
1085      PKG_CONFIG_MIN_VERSION=0.9.0
1086      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1087         AC_MSG_CHECKING(for $2)
1088
1089         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1090            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1091            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1092             edit_cflags="
1093               s,///*,/,g
1094               s/^/ /
1095               s/ -I/ $isystem/g
1096               s/^ //
1097             "
1098             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1099             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1100             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1101             succeeded=yes
1102         else
1103             AC_MSG_RESULT(no)
1104             $1_CFLAGS=""
1105             $1_LIBS=""
1106             ## If we have a custom action on failure, don't print errors, but
1107             ## do set a variable so people can do so.
1108             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1109             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1110         fi
1111
1112         AC_SUBST($1_CFLAGS)
1113         AC_SUBST($1_LIBS)
1114      else
1115         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1116         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1117      fi
1118   fi
1119
1120   if test $succeeded = yes; then
1121      ifelse([$3], , :, [$3])
1122   else
1123      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1124   fi
1125 ])
1126
1127
1128 if test "${with_sound}" != "no"; then
1129   # Sound support for GNU/Linux and the free BSDs.
1130   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1131     have_sound_header=yes)
1132   # Emulation library used on NetBSD.
1133   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1134   AC_SUBST(LIBSOUND)
1135
1136   ALSA_REQUIRED=1.0.0
1137   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1138   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1139   if test $HAVE_ALSA = yes; then
1140     SAVE_CFLAGS="$CFLAGS"
1141     SAVE_LIBS="$LIBS"
1142     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1143     LIBS="$ALSA_LIBS $LIBS"
1144     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1145                     emacs_alsa_normal=yes,
1146                     emacs_alsa_normal=no)
1147     if test "$emacs_alsa_normal" != yes; then
1148       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1149                      [[snd_lib_error_set_handler (0);]])],
1150                      emacs_alsa_subdir=yes,
1151                      emacs_alsa_subdir=no)
1152       if test "$emacs_alsa_subdir" != yes; then
1153         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1154       fi
1155       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1156     fi
1157
1158     CFLAGS="$SAVE_CFLAGS"
1159     LIBS="$SAVE_LIBS"
1160     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1161     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1162     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1163   fi
1164
1165   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1166   dnl compiles only on the specified platforms.  For others, it
1167   dnl probably doesn't make sense to try.
1168   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1169      case "$opsys" in
1170        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1171        gnu-linux|freebsd|netbsd)
1172          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1173          ;;
1174      esac
1175   fi
1176
1177   AC_SUBST(CFLAGS_SOUND)
1178 fi
1179
1180 dnl checks for header files
1181 AC_CHECK_HEADERS_ONCE(
1182   sys/select.h sys/time.h utime.h
1183   linux/version.h sys/systeminfo.h
1184   stdio_ext.h fcntl.h coff.h pty.h
1185   sys/vlimit.h sys/resource.h
1186   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1187
1188 AC_MSG_CHECKING(if personality LINUX32 can be set)
1189 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1190                emacs_cv_personality_linux32=yes,
1191                emacs_cv_personality_linux32=no)
1192 AC_MSG_RESULT($emacs_cv_personality_linux32)
1193
1194 if test $emacs_cv_personality_linux32 = yes; then
1195   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1196             [Define to 1 if personality LINUX32 can be set.])
1197 fi
1198
1199 dnl On Solaris 8 there's a compilation warning for term.h because
1200 dnl it doesn't define `bool'.
1201 AC_CHECK_HEADERS(term.h, , , -)
1202 AC_HEADER_TIME
1203 AC_CHECK_DECLS([sys_siglist])
1204 if test $ac_cv_have_decl_sys_siglist != yes; then
1205   # For Tru64, at least:
1206   AC_CHECK_DECLS([__sys_siglist])
1207   if test $ac_cv_have_decl___sys_siglist = yes; then
1208     AC_DEFINE(sys_siglist, __sys_siglist,
1209               [Define to any substitute for sys_siglist.])
1210   fi
1211 fi
1212 AC_HEADER_SYS_WAIT
1213
1214 dnl Some systems have utime.h but don't declare the struct anyplace.
1215 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1216 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1217 #include <sys/time.h>
1218 #include <time.h>
1219 #else
1220 #ifdef HAVE_SYS_TIME_H
1221 #include <sys/time.h>
1222 #else
1223 #include <time.h>
1224 #endif
1225 #endif
1226 #ifdef HAVE_UTIME_H
1227 #include <utime.h>
1228 #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])],
1229   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1230 if test $emacs_cv_struct_utimbuf = yes; then
1231   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1232 fi
1233
1234 dnl Check for speed_t typedef.
1235 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1236   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1237     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1238 if test $emacs_cv_speed_t = yes; then
1239   AC_DEFINE(HAVE_SPEED_T, 1,
1240            [Define to 1 if `speed_t' is declared by <termios.h>.])
1241 fi
1242
1243 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1244 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1245 #include <sys/time.h>
1246 #include <time.h>
1247 #else
1248 #ifdef HAVE_SYS_TIME_H
1249 #include <sys/time.h>
1250 #else
1251 #include <time.h>
1252 #endif
1253 #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
1254   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1255 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1256 if test $emacs_cv_struct_timeval = yes; then
1257   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1258 fi
1259
1260 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1261 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1262 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1263   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1264 HAVE_EXCEPTION=$emacs_cv_struct_exception
1265 if test $emacs_cv_struct_exception != yes; then
1266   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1267 fi
1268
1269 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1270 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1271 #if HAVE_SYS_SOCKET_H
1272 #include <sys/socket.h>
1273 #endif])
1274 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1275 #if HAVE_SYS_SOCKET_H
1276 #include <sys/socket.h>
1277 #endif])
1278 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1279 #if HAVE_SYS_SOCKET_H
1280 #include <sys/socket.h>
1281 #endif])
1282 AC_CHECK_FUNCS(getifaddrs freeifaddrs)
1283
1284 dnl checks for structure members
1285 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1286                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1287                   struct ifreq.ifr_addr,
1288                   struct ifreq.ifr_addr.sa_len], , ,
1289                  [AC_INCLUDES_DEFAULT
1290 #if HAVE_SYS_SOCKET_H
1291 #include <sys/socket.h>
1292 #endif
1293 #if HAVE_NET_IF_H
1294 #include <net/if.h>
1295 #endif])
1296
1297 dnl Check for endianness.
1298 dnl AC_C_BIGENDIAN is done by gnulib.
1299
1300 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1301   [emacs_cv_attribute_aligned],
1302   [AC_COMPILE_IFELSE(
1303      [AC_LANG_PROGRAM(
1304         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1305         [[]])],
1306      [emacs_cv_attribute_aligned=yes],
1307      [emacs_cv_attribute_aligned=no])])
1308 if test $emacs_cv_attribute_aligned = yes; then
1309   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1310     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1311 fi
1312
1313 dnl check for Make feature
1314 dnl AC_PROG_MAKE_SET is done by Automake.
1315
1316 DEPFLAGS=
1317 MKDEPDIR=":"
1318 deps_frag=deps.mk
1319 dnl check for GNU Make if we have GCC and autodepend is on.
1320 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1321    AC_MSG_CHECKING([whether we are using GNU Make])
1322    HAVE_GNU_MAKE=no
1323    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1324    if test "x$testval" != x; then
1325       HAVE_GNU_MAKE=yes
1326    else
1327       ac_enable_autodepend=no
1328    fi
1329    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1330    if test $HAVE_GNU_MAKE = yes; then
1331       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1332       SAVE_CFLAGS="$CFLAGS"
1333       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1334       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1335       CFLAGS="$SAVE_CFLAGS"
1336       test -f deps.d || ac_enable_autodepend=no
1337       rm -rf deps.d
1338       AC_MSG_RESULT([$ac_enable_autodepend])
1339    fi
1340    if test $ac_enable_autodepend = yes; then
1341       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1342       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1343       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1344       deps_frag=autodeps.mk
1345    fi
1346 fi
1347 deps_frag=$srcdir/src/$deps_frag
1348 AC_SUBST(MKDEPDIR)
1349 AC_SUBST(DEPFLAGS)
1350 AC_SUBST_FILE(deps_frag)
1351
1352
1353 lisp_frag=$srcdir/src/lisp.mk
1354 AC_SUBST_FILE(lisp_frag)
1355
1356
1357 dnl checks for operating system services
1358 AC_SYS_LONG_FILE_NAMES
1359
1360 #### Choose a window system.
1361
1362 AC_PATH_X
1363 if test "$no_x" = yes; then
1364   window_system=none
1365 else
1366   window_system=x11
1367 fi
1368
1369 LD_SWITCH_X_SITE_RPATH=
1370 if test "${x_libraries}" != NONE; then
1371   if test -n "${x_libraries}"; then
1372     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1373     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1374   fi
1375   x_default_search_path=""
1376   x_search_path=${x_libraries}
1377   if test -z "${x_search_path}"; then
1378     x_search_path=/usr/lib
1379   fi
1380   for x_library in `echo ${x_search_path}: | \
1381                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1382     x_search_path="\
1383 ${x_library}/X11/%L/%T/%N%C%S:\
1384 ${x_library}/X11/%l/%T/%N%C%S:\
1385 ${x_library}/X11/%T/%N%C%S:\
1386 ${x_library}/X11/%L/%T/%N%S:\
1387 ${x_library}/X11/%l/%T/%N%S:\
1388 ${x_library}/X11/%T/%N%S"
1389     if test x"${x_default_search_path}" = x; then
1390       x_default_search_path=${x_search_path}
1391     else
1392       x_default_search_path="${x_search_path}:${x_default_search_path}"
1393     fi
1394   done
1395 fi
1396 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1397
1398 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1399   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1400 fi
1401
1402 if test x"${x_includes}" = x; then
1403   bitmapdir=/usr/include/X11/bitmaps
1404 else
1405   # accumulate include directories that have X11 bitmap subdirectories
1406   bmd_acc="dummyval"
1407   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1408     if test -d "${bmd}/X11/bitmaps"; then
1409       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1410     fi
1411     if test -d "${bmd}/bitmaps"; then
1412       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1413     fi
1414   done
1415   if test ${bmd_acc} != "dummyval"; then
1416     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1417   fi
1418 fi
1419
1420 HAVE_NS=no
1421 NS_IMPL_COCOA=no
1422 NS_IMPL_GNUSTEP=no
1423 tmp_CPPFLAGS="$CPPFLAGS"
1424 tmp_CFLAGS="$CFLAGS"
1425 CPPFLAGS="$CPPFLAGS -x objective-c"
1426 CFLAGS="$CFLAGS -x objective-c"
1427 TEMACS_LDFLAGS2="\${LDFLAGS}"
1428 GNU_OBJC_CFLAGS=
1429 if test "${with_ns}" != no; then
1430   if test "${opsys}" = darwin; then
1431      NS_IMPL_COCOA=yes
1432      ns_appdir=`pwd`/nextstep/Emacs.app
1433      ns_appbindir=${ns_appdir}/Contents/MacOS
1434      ns_appresdir=${ns_appdir}/Contents/Resources
1435      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1436   elif test -f $GNUSTEP_CONFIG_FILE; then
1437      NS_IMPL_GNUSTEP=yes
1438      ns_appdir=`pwd`/nextstep/Emacs.app
1439      ns_appbindir=${ns_appdir}
1440      ns_appresdir=${ns_appdir}/Resources
1441      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1442      dnl FIXME sourcing this several times in subshells seems inefficient.
1443      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1444      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1445      dnl I seemed to need these as well with GNUstep-startup 0.25.
1446      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1447      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1448      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1449        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1450      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1451        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1452      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1453      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1454      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1455      LIB_STANDARD=
1456      START_FILES=
1457      TEMACS_LDFLAGS2=
1458      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1459      dnl If they had chosen to either define it or not, we could have
1460      dnl just used AC_CHECK_DECL here.
1461      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1462        emacs_cv_objc_exceptions,
1463 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1464 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1465 1;
1466 #else
1467 fail;
1468 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1469      if test $emacs_cv_objc_exceptions = yes; then
1470        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1471        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1472          [Define if GNUstep uses ObjC exceptions.])
1473        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1474      fi
1475   fi
1476
1477   dnl This is only used while we test the NS headers, it gets reset below.
1478   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1479
1480   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1481                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1482   files are missing or cannot be compiled.])])
1483   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1484                                      [NSInteger i;])],
1485                     ns_have_nsinteger=yes,
1486                     ns_have_nsinteger=no)
1487   if test $ns_have_nsinteger = yes; then
1488     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1489   fi
1490 fi
1491 AC_SUBST(TEMACS_LDFLAGS2)
1492
1493 INSTALL_ARCH_INDEP_EXTRA=install-etc
1494 ns_self_contained=no
1495 ns_frag=/dev/null
1496 NS_OBJ=
1497 NS_OBJC_OBJ=
1498 if test "${HAVE_NS}" = yes; then
1499   if test "$with_toolkit_scroll_bars" = "no"; then
1500     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1501   fi
1502
1503   window_system=nextstep
1504   with_xft=no
1505   # set up packaging dirs
1506   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1507      ns_self_contained=yes
1508      prefix=${ns_appresdir}
1509      exec_prefix=${ns_appbindir}
1510      dnl This one isn't really used, only archlibdir is.
1511      libexecdir="\${ns_appbindir}/libexec"
1512      archlibdir="\${ns_appbindir}/libexec"
1513      docdir="\${ns_appresdir}/etc"
1514      etcdir="\${ns_appresdir}/etc"
1515      dnl FIXME maybe set datarootdir instead.
1516      dnl That would also get applications, icons, man.
1517      infodir="\${ns_appresdir}/info"
1518      mandir="\${ns_appresdir}/man"
1519      lispdir="\${ns_appresdir}/lisp"
1520      leimdir="\${ns_appresdir}/leim"
1521      INSTALL_ARCH_INDEP_EXTRA=
1522   fi
1523   ns_frag=$srcdir/src/ns.mk
1524   NS_OBJ="fontset.o fringe.o image.o"
1525   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1526 fi
1527 CFLAGS="$tmp_CFLAGS"
1528 CPPFLAGS="$tmp_CPPFLAGS"
1529 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1530 AC_SUBST(ns_self_contained)
1531 AC_SUBST(NS_OBJ)
1532 AC_SUBST(NS_OBJC_OBJ)
1533 AC_SUBST(LIB_STANDARD)
1534 AC_SUBST_FILE(ns_frag)
1535
1536 case "${window_system}" in
1537   x11 )
1538     HAVE_X_WINDOWS=yes
1539     HAVE_X11=yes
1540     case "${with_x_toolkit}" in
1541       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1542       motif ) USE_X_TOOLKIT=MOTIF ;;
1543       gtk ) with_gtk=yes
1544 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1545 dnl USE_X_TOOLKIT is set.
1546             USE_X_TOOLKIT=none ;;
1547       gtk3 ) with_gtk3=yes
1548              USE_X_TOOLKIT=none ;;
1549       no ) USE_X_TOOLKIT=none ;;
1550 dnl If user did not say whether to use a toolkit, make this decision later:
1551 dnl use the toolkit if we have gtk, or X11R5 or newer.
1552       * ) USE_X_TOOLKIT=maybe ;;
1553     esac
1554   ;;
1555   nextstep | none )
1556     HAVE_X_WINDOWS=no
1557     HAVE_X11=no
1558     USE_X_TOOLKIT=none
1559   ;;
1560 esac
1561
1562 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1563    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1564    if test "$HAVE_XSERVER" = true ||
1565       test -n "$DISPLAY" ||
1566       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1567         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1568 were found.  You should install the relevant development files for X
1569 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1570 sure you have development files for image handling, i.e.
1571 tiff, gif, jpeg, png and xpm.
1572 If you are sure you want Emacs compiled without X window support, pass
1573   --without-x
1574 to configure.])
1575    fi
1576 fi
1577
1578 ### If we're using X11, we should use the X menu package.
1579 HAVE_MENUS=no
1580 case ${HAVE_X11} in
1581   yes ) HAVE_MENUS=yes ;;
1582 esac
1583
1584 # Does the opsystem file prohibit the use of the GNU malloc?
1585 # Assume not, until told otherwise.
1586 GNU_MALLOC=yes
1587
1588 AC_CACHE_CHECK(
1589   [whether malloc is Doug Lea style],
1590   [emacs_cv_var_doug_lea_malloc],
1591   [AC_LINK_IFELSE(
1592      [AC_LANG_PROGRAM(
1593         [[#include <malloc.h>
1594           static void hook (void) {}]],
1595         [[malloc_set_state (malloc_get_state ());
1596           __after_morecore_hook = hook;
1597           __malloc_initialize_hook = hook;]])],
1598      [emacs_cv_var_doug_lea_malloc=yes],
1599      [emacs_cv_var_doug_lea_malloc=no])])
1600 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1601
1602
1603 dnl See comments in aix4-2.h about maybe using system malloc there.
1604 system_malloc=no
1605 case "$opsys" in
1606   ## darwin ld insists on the use of malloc routines in the System framework.
1607   darwin|sol2-10) system_malloc=yes ;;
1608 esac
1609
1610 if test "${system_malloc}" = "yes"; then
1611   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1612   GNU_MALLOC=no
1613   GNU_MALLOC_reason="
1614     (The GNU allocators don't work with this system configuration.)"
1615   GMALLOC_OBJ=
1616   VMLIMIT_OBJ=
1617 else
1618   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1619   VMLIMIT_OBJ=vm-limit.o
1620 fi
1621 AC_SUBST(GMALLOC_OBJ)
1622 AC_SUBST(VMLIMIT_OBJ)
1623
1624 if test "$doug_lea_malloc" = "yes" ; then
1625   if test "$GNU_MALLOC" = yes ; then
1626     GNU_MALLOC_reason="
1627       (Using Doug Lea's new malloc from the GNU C Library.)"
1628   fi
1629   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1630             [Define to 1 if you are using the GNU C Library.])
1631
1632   ## Use mmap directly for allocating larger buffers.
1633   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1634   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1635   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1636   case "$opsys" in
1637     gnu*) REL_ALLOC=no ;;
1638   esac
1639 fi
1640
1641 if test x"${REL_ALLOC}" = x; then
1642   REL_ALLOC=${GNU_MALLOC}
1643 fi
1644
1645 use_mmap_for_buffers=no
1646 case "$opsys" in
1647   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1648 esac
1649
1650 AC_FUNC_MMAP
1651 if test $use_mmap_for_buffers = yes; then
1652   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1653   REL_ALLOC=no
1654 fi
1655
1656 LIBS="$LIBS_SYSTEM $LIBS"
1657
1658 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1659 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1660 AC_CHECK_LIB(dnet, dnet_ntoa)
1661 dnl This causes -lresolv to get used in subsequent tests,
1662 dnl which causes failures on some systems such as HPUX 9.
1663 dnl AC_CHECK_LIB(resolv, gethostbyname)
1664
1665 dnl FIXME replace main with a function we actually want from this library.
1666 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1667
1668 dnl Check if pthreads is available.
1669 LIB_PTHREAD=
1670 AC_CHECK_HEADERS_ONCE(pthread.h)
1671 if test "$ac_cv_header_pthread_h"; then
1672   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1673   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1674   dnl testing for pthread_self if Emacs uses gmalloc.c.
1675   if test "$GMALLOC_OBJ" = gmalloc.o; then
1676     emacs_pthread_function=pthread_atfork
1677   else
1678     emacs_pthread_function=pthread_self
1679   fi
1680   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1681 fi
1682 if test "$HAVE_PTHREAD" = yes; then
1683   case "${canonical}" in
1684     *-hpux*) ;;
1685     *) LIB_PTHREAD="-lpthread"
1686        LIBS="$LIB_PTHREAD $LIBS" ;;
1687   esac
1688   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1689 fi
1690 AC_SUBST([LIB_PTHREAD])
1691
1692 AC_CHECK_LIB(pthreads, cma_open)
1693
1694 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1695 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1696 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1697 ## added to LIBS in configure would never contain the pthreads part,
1698 ## but the value used in Makefiles might.  FIXME?
1699 ##
1700 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1701 ## be harmless on older versions of X where it happens to exist.
1702 test "$opsys" = "aix4-2" && \
1703   test $ac_cv_lib_pthreads_cma_open = yes && \
1704   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1705
1706 dnl Check for need for bigtoc support on IBM AIX
1707
1708 case ${host_os} in
1709 aix*)
1710   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1711     case $GCC in
1712     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1713     *) gdb_cv_bigtoc=-bbigtoc ;;
1714     esac
1715
1716     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1717     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1718   ])
1719   ;;
1720 esac
1721
1722 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1723 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1724 # REAL_CPPFLAGS later on.
1725
1726 REAL_CFLAGS="$CFLAGS"
1727 REAL_CPPFLAGS="$CPPFLAGS"
1728
1729 if test "${HAVE_X11}" = "yes"; then
1730   DEFS="$C_SWITCH_X_SITE $DEFS"
1731   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1732   LIBS="-lX11 $LIBS"
1733   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1734   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1735
1736   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1737   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1738   # but it's more convenient here to set LD_RUN_PATH since this
1739   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1740   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1741     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1742     export LD_RUN_PATH
1743   fi
1744
1745   if test "${opsys}" = "gnu-linux"; then
1746     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1747     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1748      [[XOpenDisplay ("foo");]])],
1749      [xgnu_linux_first_failure=no],
1750      [xgnu_linux_first_failure=yes])
1751     if test "${xgnu_linux_first_failure}" = "yes"; then
1752       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1753       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1754       OLD_CPPFLAGS="$CPPFLAGS"
1755       OLD_LIBS="$LIBS"
1756       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1757       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1758       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1759       LIBS="$LIBS -b i486-linuxaout"
1760       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1761        [[XOpenDisplay ("foo");]])],
1762        [xgnu_linux_second_failure=no],
1763        [xgnu_linux_second_failure=yes])
1764       if test "${xgnu_linux_second_failure}" = "yes"; then
1765         # If we get the same failure with -b, there is no use adding -b.
1766         # So take it out.  This plays safe.
1767         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1768         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1769         CPPFLAGS="$OLD_CPPFLAGS"
1770         LIBS="$OLD_LIBS"
1771         AC_MSG_RESULT(no)
1772       else
1773         AC_MSG_RESULT(yes)
1774       fi
1775     else
1776       AC_MSG_RESULT(no)
1777     fi
1778   fi
1779
1780   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1781   # header files included from there.
1782   AC_MSG_CHECKING(for Xkb)
1783   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1784 #include <X11/XKBlib.h>]],
1785         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1786         emacs_xkb=yes, emacs_xkb=no)
1787   AC_MSG_RESULT($emacs_xkb)
1788   if test $emacs_xkb = yes; then
1789     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1790   fi
1791
1792   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1793 XScreenNumberOfScreen)
1794 fi
1795
1796 if test "${window_system}" = "x11"; then
1797   AC_MSG_CHECKING(X11 version 6)
1798   AC_CACHE_VAL(emacs_cv_x11_version_6,
1799   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1800 [[#if XlibSpecificationRelease < 6
1801 fail;
1802 #endif
1803 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1804   if test $emacs_cv_x11_version_6 = yes; then
1805     AC_MSG_RESULT(6 or newer)
1806     AC_DEFINE(HAVE_X11R6, 1,
1807               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1808     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1809     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1810     ## XIM support.
1811     case "$opsys" in
1812       sol2-*) : ;;
1813       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1814            [Define if you have usable X11R6-style XIM support.])
1815          ;;
1816     esac
1817   else
1818     AC_MSG_RESULT(before 6)
1819   fi
1820 fi
1821
1822
1823 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1824 HAVE_RSVG=no
1825 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1826   if test "${with_rsvg}" != "no"; then
1827     RSVG_REQUIRED=2.11.0
1828     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1829
1830     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1831     AC_SUBST(RSVG_CFLAGS)
1832     AC_SUBST(RSVG_LIBS)
1833
1834     if test $HAVE_RSVG = yes; then
1835       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1836       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1837       LIBS="$RSVG_LIBS $LIBS"
1838     fi
1839   fi
1840 fi
1841
1842 HAVE_IMAGEMAGICK=no
1843 if test "${HAVE_X11}" = "yes"; then
1844   if test "${with_imagemagick}" != "no"; then
1845     ## 6.2.8 is the earliest version known to work, but earlier versions
1846     ## might work - let us know if you find one.
1847     ## 6.0.7 does not work.  See bug#7955.
1848     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1849     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1850     AC_SUBST(IMAGEMAGICK_CFLAGS)
1851     AC_SUBST(IMAGEMAGICK_LIBS)
1852
1853     if test $HAVE_IMAGEMAGICK = yes; then
1854       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1855       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1856       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1857       AC_CHECK_FUNCS(MagickExportImagePixels)
1858       AC_CHECK_FUNCS(MagickMergeImageLayers)
1859     fi
1860   fi
1861 fi
1862
1863
1864 HAVE_GTK=no
1865 GTK_OBJ=
1866 if test "${with_gtk3}" = "yes"; then
1867   GLIB_REQUIRED=2.28
1868   GTK_REQUIRED=3.0
1869   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1870
1871   dnl Checks for libraries.
1872   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1873   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1874      AC_MSG_ERROR($GTK_PKG_ERRORS)
1875   fi
1876   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1877   GTK_OBJ=emacsgtkfixed.o
1878 fi
1879
1880 if test "$pkg_check_gtk" != "yes"; then
1881   HAVE_GTK=no
1882 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1883   GLIB_REQUIRED=2.10
1884   GTK_REQUIRED=2.10
1885   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1886
1887   dnl Checks for libraries.
1888   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1889   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1890      AC_MSG_ERROR($GTK_PKG_ERRORS)
1891   fi
1892 fi
1893 fi
1894
1895 if test x"$pkg_check_gtk" = xyes; then
1896
1897   AC_SUBST(GTK_CFLAGS)
1898   AC_SUBST(GTK_LIBS)
1899   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1900   CFLAGS="$CFLAGS $GTK_CFLAGS"
1901   LIBS="$GTK_LIBS $LIBS"
1902   dnl Try to compile a simple GTK program.
1903   GTK_COMPILES=no
1904   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1905   if test "${GTK_COMPILES}" != "yes"; then
1906     if test "$USE_X_TOOLKIT" != "maybe"; then
1907       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1908     fi
1909   else
1910     HAVE_GTK=yes
1911     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1912     GTK_OBJ="gtkutil.o $GTK_OBJ"
1913     USE_X_TOOLKIT=none
1914     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1915       :
1916     else
1917       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1918        closing open displays.  This is no problem if you just use
1919        one display, but if you use more than one and close one of them
1920        Emacs may crash.]])
1921       sleep 3
1922     fi
1923   fi
1924
1925 fi
1926 AC_SUBST(GTK_OBJ)
1927
1928
1929 if test "${HAVE_GTK}" = "yes"; then
1930
1931   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1932   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1933   if test "$with_toolkit_scroll_bars" != no; then
1934     with_toolkit_scroll_bars=yes
1935   fi
1936
1937   dnl  Check if we have the old file selection dialog declared and
1938   dnl  in the link library.  In 2.x it may be in the library,
1939   dnl  but not declared if deprecated featured has been selected out.
1940   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1941   HAVE_GTK_FILE_SELECTION=no
1942   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1943                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1944 #include <gtk/gtk.h>])
1945   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1946     AC_CHECK_FUNCS(gtk_file_selection_new)
1947   fi
1948
1949
1950   dnl Check for functions introduced in 2.14 and later.
1951   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1952                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1953                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1954                  gtk_orientable_set_orientation \
1955                  gtk_window_set_has_resize_grip)
1956 fi
1957
1958 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1959 dnl other platforms.
1960 HAVE_DBUS=no
1961 DBUS_OBJ=
1962 if test "${with_dbus}" = "yes"; then
1963    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1964    if test "$HAVE_DBUS" = yes; then
1965      LIBS="$LIBS $DBUS_LIBS"
1966      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1967      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
1968      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
1969      dnl D-Bus 1.5.12.
1970      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
1971                     dbus_type_is_valid \
1972                     dbus_validate_bus_name \
1973                     dbus_validate_path \
1974                     dbus_validate_interface \
1975                     dbus_validate_member)
1976      DBUS_OBJ=dbusbind.o
1977    fi
1978 fi
1979 AC_SUBST(DBUS_OBJ)
1980
1981 dnl GSettings has been tested under GNU/Linux only.
1982 HAVE_GSETTINGS=no
1983 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
1984    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
1985    if test "$HAVE_GSETTINGS" = "yes"; then
1986       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
1987       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
1988       SETTINGS_LIBS="$GSETTINGS_LIBS"
1989    fi
1990 fi
1991
1992 dnl GConf has been tested under GNU/Linux only.
1993 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1994 HAVE_GCONF=no
1995 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1996    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1997    if test "$HAVE_GCONF" = yes; then
1998       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1999       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2000       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2001       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2002    fi
2003 fi
2004
2005 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2006     SAVE_CFLAGS="$CFLAGS"
2007     SAVE_LIBS="$LIBS"
2008     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2009     LIBS="$SETTINGS_LIBS $LIBS"
2010     AC_CHECK_FUNCS([g_type_init])
2011     CFLAGS="$SAVE_CFLAGS"
2012     LIBS="$SAVE_LIBS"
2013 fi
2014 AC_SUBST(SETTINGS_CFLAGS)
2015 AC_SUBST(SETTINGS_LIBS)
2016
2017
2018 dnl SELinux is available for GNU/Linux only.
2019 HAVE_LIBSELINUX=no
2020 LIBSELINUX_LIBS=
2021 if test "${with_selinux}" = "yes"; then
2022    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2023    if test "$HAVE_LIBSELINUX" = yes; then
2024       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2025       LIBSELINUX_LIBS=-lselinux
2026    fi
2027 fi
2028 AC_SUBST(LIBSELINUX_LIBS)
2029
2030 HAVE_GNUTLS=no
2031 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2032 if test "${with_gnutls}" = "yes" ; then
2033   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2034   if test "${HAVE_GNUTLS}" = "yes"; then
2035     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2036   fi
2037
2038   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2039   LIBS="$LIBGNUTLS_LIBS $LIBS"
2040   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2041
2042   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2043     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2044   fi
2045 fi
2046
2047 AC_SUBST(LIBGNUTLS_LIBS)
2048 AC_SUBST(LIBGNUTLS_CFLAGS)
2049
2050 dnl Do not put whitespace before the #include statements below.
2051 dnl Older compilers (eg sunos4 cc) choke on it.
2052 HAVE_XAW3D=no
2053 LUCID_LIBW=
2054 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2055   if test "$with_xaw3d" != no; then
2056     AC_MSG_CHECKING(for xaw3d)
2057     AC_CACHE_VAL(emacs_cv_xaw3d,
2058     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2059 #include <X11/Intrinsic.h>
2060 #include <X11/Xaw3d/Simple.h>]],
2061       [[]])],
2062       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2063                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2064       emacs_cv_xaw3d=no)])
2065   else
2066     emacs_cv_xaw3d=no
2067   fi
2068   if test $emacs_cv_xaw3d = yes; then
2069     AC_MSG_RESULT([yes; using Lucid toolkit])
2070     USE_X_TOOLKIT=LUCID
2071     HAVE_XAW3D=yes
2072     LUCID_LIBW=-lXaw3d
2073     AC_DEFINE(HAVE_XAW3D, 1,
2074               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2075   else
2076     AC_MSG_RESULT(no)
2077     AC_MSG_CHECKING(for libXaw)
2078     AC_CACHE_VAL(emacs_cv_xaw,
2079     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2080 #include <X11/Intrinsic.h>
2081 #include <X11/Xaw/Simple.h>]],
2082       [[]])],
2083       emacs_cv_xaw=yes,
2084       emacs_cv_xaw=no)])
2085     if test $emacs_cv_xaw = yes; then
2086       AC_MSG_RESULT([yes; using Lucid toolkit])
2087       USE_X_TOOLKIT=LUCID
2088       LUCID_LIBW=-lXaw
2089     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2090       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2091     else
2092       AC_MSG_ERROR([No X toolkit could be found.
2093 If you are sure you want Emacs compiled without an X toolkit, pass
2094   --with-x-toolkit=no
2095 to configure.  Otherwise, install the development libraries for the toolkit
2096 that you want to use (e.g. Gtk+) and re-run configure.])
2097     fi
2098   fi
2099 fi
2100
2101 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2102
2103 LIBXTR6=
2104 if test "${USE_X_TOOLKIT}" != "none"; then
2105   AC_MSG_CHECKING(X11 toolkit version)
2106   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2107   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2108 [[#if XtSpecificationRelease < 6
2109 fail;
2110 #endif
2111 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2112   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2113   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2114     AC_MSG_RESULT(6 or newer)
2115     AC_DEFINE(HAVE_X11XTR6, 1,
2116               [Define to 1 if you have the X11R6 or newer version of Xt.])
2117     LIBXTR6="-lSM -lICE"
2118     case "$opsys" in
2119       ## Use libw.a along with X11R6 Xt.
2120       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2121     esac
2122   else
2123     AC_MSG_RESULT(before 6)
2124   fi
2125
2126 dnl If using toolkit, check whether libXmu.a exists.
2127 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2128   OLDLIBS="$LIBS"
2129   if test x$HAVE_X11XTR6 = xyes; then
2130     LIBS="-lXt -lSM -lICE $LIBS"
2131   else
2132     LIBS="-lXt $LIBS"
2133   fi
2134   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2135   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2136 fi
2137 AC_SUBST(LIBXTR6)
2138
2139 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2140 dnl Why not just test for libxmu in the normal way?
2141 LIBXMU=-lXmu
2142 case $opsys in
2143   ## These systems don't supply Xmu.
2144   hpux* | aix4-2 )
2145     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2146     ;;
2147 esac
2148 AC_SUBST(LIBXMU)
2149
2150 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2151 if test "${HAVE_X11}" = "yes"; then
2152   if test "${USE_X_TOOLKIT}" != "none"; then
2153     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2154   fi
2155 fi
2156
2157 LIBXP=
2158 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2159   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2160   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2161     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2162 int x = 5;
2163 #else
2164 Motif version prior to 2.1.
2165 #endif]])],
2166     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2167   if test $emacs_cv_motif_version_2_1 = yes; then
2168     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2169   else
2170     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2171     # We put this in CFLAGS temporarily to precede other -I options
2172     # that might be in CFLAGS temporarily.
2173     # We put this in CPPFLAGS where it precedes the other -I options.
2174     OLD_CPPFLAGS=$CPPFLAGS
2175     OLD_CFLAGS=$CFLAGS
2176     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2177     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2178     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2179       [[int x = 5;]])],
2180       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2181     if test $emacs_cv_lesstif = yes; then
2182       # Make sure this -I option remains in CPPFLAGS after it is set
2183       # back to REAL_CPPFLAGS.
2184       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2185       # have those other -I options anyway.  Ultimately, having this
2186       # directory ultimately in CPPFLAGS will be enough.
2187       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2188       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2189     else
2190       CFLAGS=$OLD_CFLAGS
2191       CPPFLAGS=$OLD_CPPFLAGS
2192     fi
2193   fi
2194   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2195     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2196 fi
2197
2198 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2199 dnl using Motif or Xaw3d is available, and unless
2200 dnl --with-toolkit-scroll-bars=no was specified.
2201
2202 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2203             [Define to 1 if we should use toolkit scroll bars.])dnl
2204 USE_TOOLKIT_SCROLL_BARS=no
2205 if test "${with_toolkit_scroll_bars}" != "no"; then
2206   if test "${USE_X_TOOLKIT}" != "none"; then
2207     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2208       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2209       HAVE_XAW3D=no
2210       USE_TOOLKIT_SCROLL_BARS=yes
2211     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2212       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2213       USE_TOOLKIT_SCROLL_BARS=yes
2214     fi
2215   elif test "${HAVE_GTK}" = "yes"; then
2216     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2217     USE_TOOLKIT_SCROLL_BARS=yes
2218   elif test "${HAVE_NS}" = "yes"; then
2219     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2220     USE_TOOLKIT_SCROLL_BARS=yes
2221   fi
2222 fi
2223
2224 dnl See if XIM is available.
2225 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2226           #include <X11/Xlib.h>
2227           #include <X11/Xresource.h>]],
2228          [[XIMProc  callback;]])],
2229          [HAVE_XIM=yes
2230          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2231          HAVE_XIM=no)
2232
2233 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2234
2235 if test "${with_xim}" != "no"; then
2236   AC_DEFINE(USE_XIM, 1,
2237             [Define to 1 if we should use XIM, if it is available.])
2238 fi
2239
2240
2241 if test "${HAVE_XIM}" != "no"; then
2242   late_CFLAGS=$CFLAGS
2243   if test "$GCC" = yes; then
2244     CFLAGS="$CFLAGS --pedantic-errors"
2245   fi
2246   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2247 #include <X11/Xlib.h>
2248 #include <X11/Xresource.h>]],
2249 [[Display *display;
2250 XrmDatabase db;
2251 char *res_name;
2252 char *res_class;
2253 XIMProc  callback;
2254 XPointer *client_data;
2255 #ifndef __GNUC__
2256 /* If we're not using GCC, it's probably not XFree86, and this is
2257    probably right, but we can't use something like --pedantic-errors.  */
2258 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2259                                            char*, XIMProc, XPointer*);
2260 #endif
2261 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2262    client_data);]])],
2263     [emacs_cv_arg6_star=yes])
2264   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2265          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2266 either XPointer or XPointer*.])dnl
2267   if test "$emacs_cv_arg6_star" = yes; then
2268     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2269   else
2270     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2271   fi
2272   CFLAGS=$late_CFLAGS
2273 fi
2274
2275 ### Start of font-backend (under any platform) section.
2276 # (nothing here yet -- this is a placeholder)
2277 ### End of font-backend (under any platform) section.
2278
2279 ### Start of font-backend (under X11) section.
2280 if test "${HAVE_X11}" = "yes"; then
2281    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2282
2283    ## Use -lXft if available, unless `--with-xft=no'.
2284    HAVE_XFT=maybe
2285     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2286       with_xft="no";
2287     fi
2288     if test "x${with_xft}" != "xno"; then
2289
2290       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2291       ## Because xftfont.c uses XRenderQueryExtension, we also
2292       ## need to link to -lXrender.
2293       HAVE_XRENDER=no
2294       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2295       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2296         OLD_CPPFLAGS="$CPPFLAGS"
2297         OLD_CFLAGS="$CFLAGS"
2298         OLD_LIBS="$LIBS"
2299         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2300         CFLAGS="$CFLAGS $XFT_CFLAGS"
2301         XFT_LIBS="-lXrender $XFT_LIBS"
2302         LIBS="$XFT_LIBS $LIBS"
2303         AC_CHECK_HEADER(X11/Xft/Xft.h,
2304           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2305
2306         if test "${HAVE_XFT}" = "yes"; then
2307           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2308             AC_SUBST(XFT_LIBS)
2309           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2310         else
2311           CPPFLAGS="$OLD_CPPFLAGS"
2312           CFLAGS="$OLD_CFLAGS"
2313           LIBS="$OLD_LIBS"
2314         fi                        # "${HAVE_XFT}" = "yes"
2315       fi                          # "$HAVE_XFT" != no
2316     fi                            # "x${with_xft}" != "xno"
2317
2318     ## We used to allow building with FreeType and without Xft.
2319     ## However, the ftx font backend driver is not in good shape.
2320     if test "$HAVE_XFT" != "yes"; then
2321        dnl For the "Does Emacs use" message at the end.
2322        HAVE_XFT=no
2323        HAVE_FREETYPE=no
2324     else
2325        dnl Strict linkers fail with
2326        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2327        dnl if -lfreetype is not specified.
2328        dnl The following is needed to set FREETYPE_LIBS.
2329        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2330                          HAVE_FREETYPE=no)
2331
2332        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2333     fi
2334
2335     HAVE_LIBOTF=no
2336     if test "${HAVE_FREETYPE}" = "yes"; then
2337       AC_DEFINE(HAVE_FREETYPE, 1,
2338                 [Define to 1 if using the freetype and fontconfig libraries.])
2339       if test "${with_libotf}" != "no"; then
2340         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2341                           HAVE_LIBOTF=no)
2342         if test "$HAVE_LIBOTF" = "yes"; then
2343           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2344           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2345                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2346                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2347           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2348             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2349                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2350           fi
2351         fi
2352       fi
2353     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2354     dnl Does the new font backend require it, or can it work without it?
2355     fi
2356
2357     HAVE_M17N_FLT=no
2358     if test "${HAVE_LIBOTF}" = yes; then
2359       if test "${with_m17n_flt}" != "no"; then
2360         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2361         if test "$HAVE_M17N_FLT" = "yes"; then
2362           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2363         fi
2364       fi
2365     fi
2366 else
2367     HAVE_XFT=no
2368     HAVE_FREETYPE=no
2369     HAVE_LIBOTF=no
2370     HAVE_M17N_FLT=no
2371 fi
2372
2373 ### End of font-backend (under X11) section.
2374
2375 AC_SUBST(FREETYPE_CFLAGS)
2376 AC_SUBST(FREETYPE_LIBS)
2377 AC_SUBST(FONTCONFIG_CFLAGS)
2378 AC_SUBST(FONTCONFIG_LIBS)
2379 AC_SUBST(LIBOTF_CFLAGS)
2380 AC_SUBST(LIBOTF_LIBS)
2381 AC_SUBST(M17N_FLT_CFLAGS)
2382 AC_SUBST(M17N_FLT_LIBS)
2383
2384 ### Use -lXpm if available, unless `--with-xpm=no'.
2385 HAVE_XPM=no
2386 LIBXPM=
2387 if test "${HAVE_X11}" = "yes"; then
2388   if test "${with_xpm}" != "no"; then
2389     AC_CHECK_HEADER(X11/xpm.h,
2390       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2391     if test "${HAVE_XPM}" = "yes"; then
2392       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2393       AC_EGREP_CPP(no_return_alloc_pixels,
2394       [#include "X11/xpm.h"
2395 #ifndef XpmReturnAllocPixels
2396 no_return_alloc_pixels
2397 #endif
2398       ], HAVE_XPM=no, HAVE_XPM=yes)
2399
2400       if test "${HAVE_XPM}" = "yes"; then
2401         AC_MSG_RESULT(yes)
2402       else
2403         AC_MSG_RESULT(no)
2404       fi
2405     fi
2406   fi
2407
2408   if test "${HAVE_XPM}" = "yes"; then
2409     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2410     LIBXPM=-lXpm
2411   fi
2412 fi
2413 AC_SUBST(LIBXPM)
2414
2415 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2416 HAVE_JPEG=no
2417 LIBJPEG=
2418 if test "${HAVE_X11}" = "yes"; then
2419   if test "${with_jpeg}" != "no"; then
2420     dnl Checking for jpeglib.h can lose because of a redefinition of
2421     dnl  HAVE_STDLIB_H.
2422     AC_CHECK_HEADER(jerror.h,
2423       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2424   fi
2425
2426   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2427   if test "${HAVE_JPEG}" = "yes"; then
2428     AC_DEFINE(HAVE_JPEG)
2429     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2430         [#include <jpeglib.h>
2431          version=JPEG_LIB_VERSION
2432 ],
2433         [AC_DEFINE(HAVE_JPEG)],
2434         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2435         HAVE_JPEG=no])
2436   fi
2437   if test "${HAVE_JPEG}" = "yes"; then
2438     LIBJPEG=-ljpeg
2439   fi
2440 fi
2441 AC_SUBST(LIBJPEG)
2442
2443 ### Use -lpng if available, unless `--with-png=no'.
2444 HAVE_PNG=no
2445 LIBPNG=
2446 if test "${HAVE_X11}" = "yes"; then
2447   if test "${with_png}" != "no"; then
2448     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2449     # in /usr/include/libpng.
2450     AC_CHECK_HEADERS(png.h libpng/png.h)
2451     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2452       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2453     fi
2454   fi
2455
2456   if test "${HAVE_PNG}" = "yes"; then
2457     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2458     LIBPNG="-lpng -lz -lm"
2459   fi
2460 fi
2461 AC_SUBST(LIBPNG)
2462
2463 ### Use -ltiff if available, unless `--with-tiff=no'.
2464 HAVE_TIFF=no
2465 LIBTIFF=
2466 if test "${HAVE_X11}" = "yes"; then
2467   if test "${with_tiff}" != "no"; then
2468     AC_CHECK_HEADER(tiffio.h,
2469       [tifflibs="-lz -lm"
2470       # At least one tiff package requires the jpeg library.
2471       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2472       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2473   fi
2474
2475   if test "${HAVE_TIFF}" = "yes"; then
2476     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2477     dnl FIXME -lz -lm, as per libpng?
2478     LIBTIFF=-ltiff
2479   fi
2480 fi
2481 AC_SUBST(LIBTIFF)
2482
2483 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2484 HAVE_GIF=no
2485 LIBGIF=
2486 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2487   AC_CHECK_HEADER(gif_lib.h,
2488 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2489 # Earlier versions can crash Emacs.
2490     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2491
2492   if test "$HAVE_GIF" = yes; then
2493     LIBGIF=-lgif
2494   elif test "$HAVE_GIF" = maybe; then
2495 # If gif_lib.h but no libgif, try libungif.
2496     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2497     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2498   fi
2499
2500   if test "${HAVE_GIF}" = "yes"; then
2501     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2502   fi
2503 fi
2504 AC_SUBST(LIBGIF)
2505
2506 dnl Check for required libraries.
2507 if test "${HAVE_X11}" = "yes"; then
2508   MISSING=""
2509   WITH_NO=""
2510   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2511     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2512   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2513     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2514   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2515     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2516   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2517     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2518   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2519     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2520
2521   if test "X${MISSING}" != X; then
2522     AC_MSG_ERROR([The following required libraries were not found:
2523     $MISSING
2524 Maybe some development libraries/packages are missing?
2525 If you don't want to link with them give
2526     $WITH_NO
2527 as options to configure])
2528   fi
2529 fi
2530
2531 ### Use -lgpm if available, unless `--with-gpm=no'.
2532 HAVE_GPM=no
2533 LIBGPM=
2534 if test "${with_gpm}" != "no"; then
2535   AC_CHECK_HEADER(gpm.h,
2536     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2537
2538   if test "${HAVE_GPM}" = "yes"; then
2539     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2540     LIBGPM=-lgpm
2541   fi
2542 fi
2543 AC_SUBST(LIBGPM)
2544
2545 dnl Check for malloc/malloc.h on darwin
2546 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2547
2548 GNUSTEP_CFLAGS=
2549 ### Use NeXTstep API to implement GUI.
2550 if test "${HAVE_NS}" = "yes"; then
2551   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2552   if test "${NS_IMPL_COCOA}" = "yes"; then
2553     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2554   fi
2555   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2556     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2557     # See also .m.o rule in Makefile.in */
2558     # FIXME: are all these flags really needed?  Document here why.  */
2559     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2560     ## Extra CFLAGS applied to src/*.m files.
2561     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2562   fi
2563   # We also have mouse menus.
2564   HAVE_MENUS=yes
2565   OTHER_FILES=ns-app
2566 fi
2567
2568
2569 ### Use session management (-lSM -lICE) if available
2570 HAVE_X_SM=no
2571 LIBXSM=
2572 if test "${HAVE_X11}" = "yes"; then
2573   AC_CHECK_HEADER(X11/SM/SMlib.h,
2574     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2575
2576   if test "${HAVE_X_SM}" = "yes"; then
2577     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2578     LIBXSM="-lSM -lICE"
2579     case "$LIBS" in
2580       *-lSM*) ;;
2581       *)      LIBS="$LIBXSM $LIBS" ;;
2582     esac
2583   fi
2584 fi
2585 AC_SUBST(LIBXSM)
2586
2587 ### Use libxml (-lxml2) if available
2588 HAVE_LIBXML2=no
2589 if test "${with_xml2}" != "no"; then
2590   ### I'm not sure what the version number should be, so I just guessed.
2591   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2592   if test "${HAVE_LIBXML2}" = "yes"; then
2593     LIBS="$LIBXML2_LIBS $LIBS"
2594     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2595     if test "${HAVE_LIBXML2}" = "yes"; then
2596       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2597     else
2598       LIBXML2_LIBS=""
2599       LIBXML2_CFLAGS=""
2600     fi
2601   fi
2602 fi
2603 AC_SUBST(LIBXML2_LIBS)
2604 AC_SUBST(LIBXML2_CFLAGS)
2605
2606 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2607 AC_CACHE_CHECK(whether netdb declares h_errno,
2608                emacs_cv_netdb_declares_h_errno,
2609 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2610   [[return h_errno;]])],
2611   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2612 if test $emacs_cv_netdb_declares_h_errno = yes; then
2613   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2614 fi
2615
2616 # fmod, logb, and frexp are found in -lm on most systems.
2617 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2618 AC_CHECK_LIB(m, sqrt)
2619
2620 # Check for mail-locking functions in a "mail" library.  Probably this should
2621 # have the same check as for liblockfile below.
2622 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2623 if test $have_mail = yes; then
2624   LIBS_MAIL=-lmail
2625   LIBS="$LIBS_MAIL $LIBS"
2626   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2627 else
2628   LIBS_MAIL=
2629 fi
2630 dnl Debian, at least:
2631 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2632 if test $have_lockfile = yes; then
2633    LIBS_MAIL=-llockfile
2634    LIBS="$LIBS_MAIL $LIBS"
2635    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2636 else
2637 # If we have the shared liblockfile, assume we must use it for mail
2638 # locking (e.g. Debian).  If we couldn't link against liblockfile
2639 # (no liblockfile.a installed), ensure that we don't need to.
2640   dnl This works for files generally, not just executables.
2641   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2642   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2643                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2644   if test $ac_cv_prog_liblockfile = yes; then
2645     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2646 This probably means that movemail could lose mail.
2647 There may be a `development' package to install containing liblockfile.])
2648   fi
2649 fi
2650 AC_CHECK_FUNCS(touchlock)
2651 AC_CHECK_HEADERS_ONCE(maillock.h)
2652 AC_SUBST(LIBS_MAIL)
2653
2654 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2655 ## interlock access to the mail spool.  The alternative is a lock file named
2656 ## /usr/spool/mail/$USER.lock.
2657 mail_lock=no
2658 case "$opsys" in
2659   aix4-2) mail_lock="lockf" ;;
2660
2661   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2662
2663   ## On GNU/Linux systems, both methods are used by various mail programs.
2664   ## I assume most people are using newer mailers that have heard of flock.
2665   ## Change this if you need to.
2666   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2667   ## configure gets the right answers, and that means *NOT* using flock.
2668   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2669   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2670   ## Debian maintainer hasn't provided a clean fix for Emacs.
2671   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2672   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2673   ## correct logic.  -- fx
2674   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2675   ## liblockfile is a Free Software replacement for libmail, used on
2676   ## Debian systems and elsewhere. -rfr.
2677   gnu-*)
2678     mail_lock="flock"
2679     if test $have_mail = yes || test $have_lockfile = yes; then
2680       test $ac_cv_header_maillock_h = yes && mail_lock=no
2681     fi
2682     ;;
2683 esac
2684
2685 BLESSMAIL_TARGET=
2686 case "$mail_lock" in
2687   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2688
2689   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2690
2691   *) BLESSMAIL_TARGET="need-blessmail" ;;
2692 esac
2693 AC_SUBST(BLESSMAIL_TARGET)
2694
2695
2696 AC_CHECK_FUNCS(gethostname \
2697 rename closedir mkdir rmdir getrusage get_current_dir_name \
2698 random lrand48 logb frexp fmod rint cbrt setsid \
2699 strerror fpathconf select euidaccess getpagesize setlocale \
2700 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2701 __fpending strsignal setitimer \
2702 sendto recvfrom getsockname getpeername \
2703 gai_strerror mkstemp getline getdelim fsync sync \
2704 difftime posix_memalign \
2705 getpwent endpwent getgrent endgrent \
2706 cfmakeraw cfsetspeed copysign __executable_start)
2707
2708 dnl Cannot use AC_CHECK_FUNCS
2709 AC_CACHE_CHECK([for __builtin_unwind_init],
2710                emacs_cv_func___builtin_unwind_init,
2711 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2712                 emacs_cv_func___builtin_unwind_init=yes,
2713                 emacs_cv_func___builtin_unwind_init=no)])
2714 if test $emacs_cv_func___builtin_unwind_init = yes; then
2715   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2716             [Define to 1 if you have the `__builtin_unwind_init' function.])
2717 fi
2718
2719 AC_CHECK_HEADERS_ONCE(sys/un.h)
2720
2721 AC_FUNC_FSEEKO
2722
2723 AC_FUNC_GETPGRP
2724
2725 # UNIX98 PTYs.
2726 AC_CHECK_FUNCS(grantpt)
2727
2728 # PTY-related GNU extensions.
2729 AC_CHECK_FUNCS(getpt)
2730
2731 # Check this now, so that we will NOT find the above functions in ncurses.
2732 # That is because we have not set up to link ncurses in lib-src.
2733 # It's better to believe a function is not available
2734 # than to expect to find it in ncurses.
2735 # Also we need tputs and friends to be able to build at all.
2736 AC_MSG_CHECKING([for library containing tputs])
2737 # Run a test program that contains a call to tputs, a call that is
2738 # never executed.  This tests whether a pre-'main' dynamic linker
2739 # works with the library.  It's too much trouble to actually call
2740 # tputs in the test program, due to portability hassles.  When
2741 # cross-compiling, assume the test program will run if it links.
2742 AC_DEFUN([tputs_link_source], [
2743   AC_LANG_SOURCE(
2744      [[extern void tputs (const char *, int, int (*)(int));
2745        int main (int argc, char **argv)
2746        {
2747           if (argc == 10000)
2748             tputs (argv[0], 0, 0);
2749           return 0;
2750        }]])
2751 ])
2752 # Maybe curses should be tried earlier?
2753 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2754 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2755   OLIBS=$LIBS
2756   if test -z "$tputs_library"; then
2757     LIBS_TERMCAP=
2758     msg='none required'
2759   else
2760     LIBS_TERMCAP=-l$tputs_library
2761     msg=$LIBS_TERMCAP
2762     LIBS="$LIBS_TERMCAP $LIBS"
2763   fi
2764   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2765     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2766   LIBS=$OLIBS
2767   if test "X$msg" != Xno; then
2768     break
2769   fi
2770 done
2771 AC_MSG_RESULT([$msg])
2772 if test "X$msg" = Xno; then
2773   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2774 The following libraries were tried (in order):
2775   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2776 Please try installing whichever of these libraries is most appropriate
2777 for your system, together with its header files.
2778 For example, a libncurses-dev(el) or similar package.])
2779 fi
2780
2781 ## Use termcap instead of terminfo?
2782 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2783 TERMINFO=yes
2784 ## FIXME?  In the cases below where we unconditionally set
2785 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2786 ## if that was found above to have tputs.
2787 ## Should we use the gnu* logic everywhere?
2788 case "$opsys" in
2789   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2790   ##  The ncurses library has been moved out of the System framework in
2791   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2792   ##  option to use it.
2793   darwin) LIBS_TERMCAP="-lncurses" ;;
2794
2795   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2796
2797   freebsd)
2798     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2799     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2800     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2801 [[#if __FreeBSD_version < 400000
2802 fail;
2803 #endif
2804 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2805
2806     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2807
2808     if test $emacs_cv_freebsd_terminfo = yes; then
2809       LIBS_TERMCAP="-lncurses"
2810     else
2811       TERMINFO=no
2812       LIBS_TERMCAP="-ltermcap"
2813     fi
2814     ;;
2815
2816   netbsd)
2817     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2818       TERMINFO=no
2819       LIBS_TERMCAP="-ltermcap"
2820     fi
2821     ;;
2822
2823   openbsd) LIBS_TERMCAP="-lncurses" ;;
2824
2825   ## hpux: Make sure we get select from libc rather than from libcurses
2826   ##  because libcurses on HPUX 10.10 has a broken version of select.
2827   ##  We used to use -lc -lcurses, but this may be cleaner.
2828   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2829   # set that way, now it uses the default).  Isn't this a contradiction?
2830   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2831
2832 esac
2833
2834 TERMCAP_OBJ=tparam.o
2835 if test $TERMINFO = yes; then
2836   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2837   TERMCAP_OBJ=terminfo.o
2838 fi
2839 AC_SUBST(LIBS_TERMCAP)
2840 AC_SUBST(TERMCAP_OBJ)
2841
2842
2843 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2844 resolv=no
2845 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2846 #include <arpa/nameser.h>
2847 #include <resolv.h>]],
2848     [[return res_init();]])],
2849     have_res_init=yes, have_res_init=no)
2850 if test "$have_res_init" = no; then
2851   OLIBS="$LIBS"
2852   LIBS="$LIBS -lresolv"
2853   AC_MSG_CHECKING(for res_init with -lresolv)
2854   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2855 #include <arpa/nameser.h>
2856 #include <resolv.h>]],
2857     [[return res_init();]])],
2858     have_res_init=yes, have_res_init=no)
2859   AC_MSG_RESULT($have_res_init)
2860   if test "$have_res_init" = yes ; then
2861     resolv=yes
2862   fi
2863   LIBS="$OLIBS"
2864 fi
2865
2866 if test "$have_res_init" = yes; then
2867   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2868 fi
2869
2870 # Do we need the Hesiod library to provide the support routines?
2871 LIBHESIOD=
2872 if test "$with_hesiod" != no ; then
2873   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2874   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2875      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2876                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2877   if test "$resolv" = yes ; then
2878     RESOLVLIB=-lresolv
2879   else
2880     RESOLVLIB=
2881   fi
2882   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2883         hesiod=yes, :, $RESOLVLIB)])
2884
2885   if test x"$hesiod" = xyes; then
2886     AC_DEFINE(HAVE_LIBHESIOD, 1,
2887               [Define to 1 if you have the hesiod library (-lhesiod).])
2888     LIBHESIOD=-lhesiod
2889   fi
2890 fi
2891 AC_SUBST(LIBHESIOD)
2892
2893 # Do we need libresolv (due to res_init or Hesiod)?
2894 if test "$resolv" = yes ; then
2895   AC_DEFINE(HAVE_LIBRESOLV, 1,
2896             [Define to 1 if you have the resolv library (-lresolv).])
2897   LIBRESOLV=-lresolv
2898 else
2899   LIBRESOLV=
2900 fi
2901 AC_SUBST(LIBRESOLV)
2902
2903 # These tell us which Kerberos-related libraries to use.
2904 COM_ERRLIB=
2905 CRYPTOLIB=
2906 KRB5LIB=
2907 DESLIB=
2908 KRB4LIB=
2909
2910 if test "${with_kerberos}" != no; then
2911   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2912   if test $have_com_err = yes; then
2913     COM_ERRLIB=-lcom_err
2914     LIBS="$COM_ERRLIB $LIBS"
2915     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2916   fi
2917   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2918   if test $have_crypto = yes; then
2919     CRYPTOLIB=-lcrypto
2920     LIBS="$CRYPTOLIB $LIBS"
2921     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2922   fi
2923   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2924   if test $have_k5crypto = yes; then
2925     CRYPTOLIB=-lk5crypto
2926     LIBS="$CRYPTOLIB $LIBS"
2927     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2928   fi
2929   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2930   if test $have_krb5=yes; then
2931     KRB5LIB=-lkrb5
2932     LIBS="$KRB5LIB $LIBS"
2933     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2934   fi
2935   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2936   if test "${with_kerberos5}" = no; then
2937     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2938     if test $have_des425 = yes; then
2939       DESLIB=-ldes425
2940       LIBS="$DESLIB $LIBS"
2941       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2942     else
2943       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2944       if test $have_des = yes; then
2945         DESLIB=-ldes
2946         LIBS="$DESLIB $LIBS"
2947         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2948       fi
2949     fi
2950     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2951     if test $have_krb4 = yes; then
2952       KRB4LIB=-lkrb4
2953       LIBS="$KRB4LIB $LIBS"
2954       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2955     else
2956       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2957       if test $have_krb = yes; then
2958         KRB4LIB=-lkrb
2959         LIBS="$KRB4LIB $LIBS"
2960         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2961       fi
2962     fi
2963   fi
2964
2965   if test "${with_kerberos5}" != no; then
2966     AC_CHECK_HEADERS(krb5.h,
2967       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2968                         [#include <krb5.h>])])
2969   else
2970     AC_CHECK_HEADERS(des.h,,
2971                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2972                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2973     AC_CHECK_HEADERS(krb.h,,
2974                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2975                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2976   fi
2977   AC_CHECK_HEADERS(com_err.h)
2978 fi
2979
2980 AC_SUBST(COM_ERRLIB)
2981 AC_SUBST(CRYPTOLIB)
2982 AC_SUBST(KRB5LIB)
2983 AC_SUBST(DESLIB)
2984 AC_SUBST(KRB4LIB)
2985
2986 AC_CHECK_FUNCS_ONCE(tzset)
2987 AC_MSG_CHECKING(whether localtime caches TZ)
2988 AC_CACHE_VAL(emacs_cv_localtime_cache,
2989 [if test x$ac_cv_func_tzset = xyes; then
2990 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
2991 char TZ_GMT0[] = "TZ=GMT0";
2992 char TZ_PST8[] = "TZ=PST8";
2993 main()
2994 {
2995   time_t now = time ((time_t *) 0);
2996   int hour_GMT0, hour_unset;
2997   if (putenv (TZ_GMT0) != 0)
2998     exit (1);
2999   hour_GMT0 = localtime (&now)->tm_hour;
3000   unsetenv("TZ");
3001   hour_unset = localtime (&now)->tm_hour;
3002   if (putenv (TZ_PST8) != 0)
3003     exit (1);
3004   if (localtime (&now)->tm_hour == hour_GMT0)
3005     exit (1);
3006   unsetenv("TZ");
3007   if (localtime (&now)->tm_hour != hour_unset)
3008     exit (1);
3009   exit (0);
3010 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3011 [# If we have tzset, assume the worst when cross-compiling.
3012 emacs_cv_localtime_cache=yes])
3013 else
3014         # If we lack tzset, report that localtime does not cache TZ,
3015         # since we can't invalidate the cache if we don't have tzset.
3016         emacs_cv_localtime_cache=no
3017 fi])dnl
3018 AC_MSG_RESULT($emacs_cv_localtime_cache)
3019 if test $emacs_cv_localtime_cache = yes; then
3020   AC_DEFINE(LOCALTIME_CACHE, 1,
3021             [Define to 1 if localtime caches TZ.])
3022 fi
3023
3024 if test "x$HAVE_TIMEVAL" = xyes; then
3025   AC_CHECK_FUNCS(gettimeofday)
3026   if test $ac_cv_func_gettimeofday = yes; then
3027     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
3028                    emacs_cv_gettimeofday_two_arguments,
3029     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3030 #ifdef TIME_WITH_SYS_TIME
3031 #include <sys/time.h>
3032 #include <time.h>
3033 #else
3034 #ifdef HAVE_SYS_TIME_H
3035 #include <sys/time.h>
3036 #else
3037 #include <time.h>
3038 #endif
3039 #endif]],
3040       [[struct timeval time;
3041        gettimeofday (&time, 0);]])],
3042       emacs_cv_gettimeofday_two_arguments=yes,
3043       emacs_cv_gettimeofday_two_arguments=no)])
3044     if test $emacs_cv_gettimeofday_two_arguments = no; then
3045       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3046                 [Define to 1 if gettimeofday accepts only one argument.])
3047     fi
3048   fi
3049 fi
3050
3051 ok_so_far=yes
3052 AC_CHECK_FUNC(socket, , ok_so_far=no)
3053 if test $ok_so_far = yes; then
3054   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3055 fi
3056 if test $ok_so_far = yes; then
3057   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3058 fi
3059 if test $ok_so_far = yes; then
3060 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3061   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3062             [Define to 1 if you have inet sockets.])
3063 fi
3064
3065 if test -f /usr/lpp/X11/bin/smt.exp; then
3066   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3067             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3068 fi
3069
3070 AC_MSG_CHECKING(whether system supports dynamic ptys)
3071 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3072   AC_MSG_RESULT(yes)
3073   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3074 else
3075   AC_MSG_RESULT(no)
3076 fi
3077
3078 AC_FUNC_FORK
3079
3080 AC_CHECK_FUNCS(snprintf)
3081
3082 dnl Adapted from Haible's version.
3083 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3084   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3085     [[char* cs = nl_langinfo(CODESET);]])],
3086     emacs_cv_langinfo_codeset=yes,
3087     emacs_cv_langinfo_codeset=no)
3088   ])
3089 if test $emacs_cv_langinfo_codeset = yes; then
3090   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3091     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3092 fi
3093
3094 AC_TYPE_MBSTATE_T
3095
3096 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3097   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3098                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3099 if test "$emacs_cv_c_restrict_arr" = yes; then
3100   AC_DEFINE(__restrict_arr, __restrict,
3101     [Define to compiler's equivalent of C99 restrict keyword in array
3102      declarations.  Define as empty for no equivalent.])
3103 fi
3104
3105 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3106 dnl how the tty code is related to POSIX and/or other versions of termios.
3107 dnl The following looks like a useful start.
3108 dnl
3109 dnl AC_SYS_POSIX_TERMIOS
3110 dnl if test $ac_cv_sys_posix_termios = yes; then
3111 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3112 dnl                                and macros for terminal control.])
3113 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3114 dnl fi
3115
3116 # Set up the CFLAGS for real compilation, so we can substitute it.
3117 CFLAGS="$REAL_CFLAGS"
3118 CPPFLAGS="$REAL_CPPFLAGS"
3119
3120 ## Hack to detect a buggy GCC version.
3121 if test "x$GCC" = xyes \
3122    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3123    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3124    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3125    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3126 fi
3127
3128 version=$PACKAGE_VERSION
3129
3130 ### Specify what sort of things we'll be editing into Makefile and config.h.
3131 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3132 AC_SUBST(version)
3133 AC_SUBST(configuration)
3134 ## Unused?
3135 AC_SUBST(canonical)
3136 AC_SUBST(srcdir)
3137 AC_SUBST(prefix)
3138 AC_SUBST(exec_prefix)
3139 AC_SUBST(bindir)
3140 AC_SUBST(datadir)
3141 AC_SUBST(sharedstatedir)
3142 AC_SUBST(libexecdir)
3143 AC_SUBST(mandir)
3144 AC_SUBST(infodir)
3145 AC_SUBST(lispdir)
3146 AC_SUBST(leimdir)
3147 AC_SUBST(locallisppath)
3148 AC_SUBST(lisppath)
3149 AC_SUBST(x_default_search_path)
3150 AC_SUBST(etcdir)
3151 AC_SUBST(archlibdir)
3152 AC_SUBST(docdir)
3153 AC_SUBST(bitmapdir)
3154 AC_SUBST(gamedir)
3155 AC_SUBST(gameuser)
3156 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3157 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3158 ## end of LIBX_BASE, but nothing ever set it.
3159 AC_SUBST(LD_SWITCH_X_SITE)
3160 AC_SUBST(C_SWITCH_X_SITE)
3161 AC_SUBST(GNUSTEP_CFLAGS)
3162 AC_SUBST(CFLAGS)
3163 ## Used in lwlib/Makefile.in.
3164 AC_SUBST(X_TOOLKIT_TYPE)
3165 if test -n "${opsysfile}"; then
3166   S_FILE="\$(srcdir)/${opsysfile}"
3167 else
3168   S_FILE=
3169 fi
3170 AC_SUBST(S_FILE)
3171 AC_SUBST(ns_appdir)
3172 AC_SUBST(ns_appbindir)
3173 AC_SUBST(ns_appresdir)
3174 AC_SUBST(ns_appsrc)
3175 AC_SUBST(GNU_OBJC_CFLAGS)
3176 AC_SUBST(OTHER_FILES)
3177
3178 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3179                    [Define to the canonical Emacs configuration name.])
3180 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3181                    [Define to the options passed to configure.])
3182 if test -n "$opsysfile"; then
3183   AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3184                      [Define to the used os dependent file.])
3185 fi
3186
3187 XMENU_OBJ=
3188 XOBJ=
3189 FONT_OBJ=
3190 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3191   AC_DEFINE(HAVE_X_WINDOWS, 1,
3192             [Define to 1 if you want to use the X window system.])
3193   XMENU_OBJ=xmenu.o
3194   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3195   FONT_OBJ=xfont.o
3196   if test "$HAVE_XFT" = "yes"; then
3197     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3198   elif test "$HAVE_FREETYPE" = "yes"; then
3199     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3200   fi
3201   AC_SUBST(FONT_OBJ)
3202 fi
3203 AC_SUBST(XMENU_OBJ)
3204 AC_SUBST(XOBJ)
3205 AC_SUBST(FONT_OBJ)
3206
3207 WIDGET_OBJ=
3208 MOTIF_LIBW=
3209 if test "${USE_X_TOOLKIT}" != "none" ; then
3210   WIDGET_OBJ=widget.o
3211   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3212   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3213     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3214   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3215     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3216     MOTIF_LIBW=-lXm
3217     case "$opsys" in
3218       gnu-linux)
3219         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3220         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3221         ;;
3222
3223       unixware)
3224         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3225         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3226         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3227         ;;
3228
3229       aix4-2)
3230         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3231         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3232         ;;
3233     esac
3234     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3235   fi
3236 fi
3237 AC_SUBST(WIDGET_OBJ)
3238
3239 TOOLKIT_LIBW=
3240 case "$USE_X_TOOLKIT" in
3241   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3242   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3243   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3244 esac
3245 AC_SUBST(TOOLKIT_LIBW)
3246
3247 if test "$USE_X_TOOLKIT" = "none"; then
3248   LIBXT_OTHER="\$(LIBXSM)"
3249   OLDXMENU_TARGET="really-oldXMenu"
3250 else
3251   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3252   OLDXMENU_TARGET="really-lwlib"
3253 fi
3254 AC_SUBST(LIBXT_OTHER)
3255
3256 ## The X Menu stuff is present in the X10 distribution, but missing
3257 ## from X11.  If we have X10, just use the installed library;
3258 ## otherwise, use our own copy.
3259 if test "${HAVE_X11}" = "yes" ; then
3260   AC_DEFINE(HAVE_X11, 1,
3261             [Define to 1 if you want to use version 11 of X windows.
3262              Otherwise, Emacs expects to use version 10.])
3263
3264   if test "$USE_X_TOOLKIT" = "none"; then
3265     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3266   else
3267     OLDXMENU="\${lwlibdir}/liblw.a"
3268   fi
3269   LIBXMENU="\$(OLDXMENU)"
3270   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3271   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3272 else
3273   ## For a syntactically valid Makefile; not actually used for anything.
3274   ## See comments in src/Makefile.in.
3275   OLDXMENU=nothing
3276   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3277   if test "${HAVE_X_WINDOWS}" = "yes"; then
3278     LIBXMENU="-lXMenu"
3279   else
3280     LIBXMENU=
3281   fi
3282   LIBX_OTHER=
3283   OLDXMENU_DEPS=
3284 fi
3285
3286 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3287   OLDXMENU_TARGET=
3288   OLDXMENU=nothing
3289   LIBXMENU=
3290   OLDXMENU_DEPS=
3291 fi
3292
3293 AC_SUBST(OLDXMENU_TARGET)
3294 AC_SUBST(OLDXMENU)
3295 AC_SUBST(LIBXMENU)
3296 AC_SUBST(LIBX_OTHER)
3297 AC_SUBST(OLDXMENU_DEPS)
3298
3299 if test "${HAVE_MENUS}" = "yes" ; then
3300   AC_DEFINE(HAVE_MENUS, 1,
3301             [Define to 1 if you have mouse menus.
3302              (This is automatic if you use X, but the option to specify it remains.)
3303              It is also defined with other window systems that support xmenu.c.])
3304 fi
3305
3306 if test "${GNU_MALLOC}" = "yes" ; then
3307   AC_DEFINE(GNU_MALLOC, 1,
3308             [Define to 1 if you want to use the GNU memory allocator.])
3309 fi
3310
3311 RALLOC_OBJ=
3312 if test "${REL_ALLOC}" = "yes" ; then
3313   AC_DEFINE(REL_ALLOC, 1,
3314             [Define REL_ALLOC if you want to use the relocating allocator for
3315              buffer space.])
3316
3317   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3318 fi
3319 AC_SUBST(RALLOC_OBJ)
3320
3321 if test "$opsys" = "cygwin"; then
3322   CYGWIN_OBJ="sheap.o"
3323   ## Cygwin differs because of its unexec().
3324   PRE_ALLOC_OBJ=
3325   POST_ALLOC_OBJ=lastfile.o
3326 else
3327   CYGWIN_OBJ=
3328   PRE_ALLOC_OBJ=lastfile.o
3329   POST_ALLOC_OBJ=
3330 fi
3331 AC_SUBST(CYGWIN_OBJ)
3332 AC_SUBST(PRE_ALLOC_OBJ)
3333 AC_SUBST(POST_ALLOC_OBJ)
3334
3335 # Configure gnulib here, now that we know LIBS.
3336 gl_ASSERT_NO_GNULIB_POSIXCHECK
3337 gl_ASSERT_NO_GNULIB_TESTS
3338 gl_INIT
3339
3340 case "$opsys" in
3341   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3342
3343   darwin)
3344    ## The -headerpad option tells ld (see man page) to leave room at the
3345    ## end of the header for adding load commands.  Needed for dumping.
3346    ## 0x690 is the total size of 30 segment load commands (at 56
3347    ## each); under Cocoa 31 commands are required.
3348    if test "$HAVE_NS" = "yes"; then
3349      libs_nsgui="-framework AppKit"
3350      headerpad_extra=6C8
3351    else
3352      libs_nsgui=
3353      headerpad_extra=690
3354    fi
3355    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3356
3357    ## This is here because src/Makefile.in did some extra fiddling around
3358    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3359    ##   #ifndef LD_SWITCH_SYSTEM
3360    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3361    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3362    ## not using gcc, darwin.
3363    ## Because this was done in src/Makefile.in, the resulting part of
3364    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3365    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3366    ## rather than LD_SWITCH_SYSTEM.
3367    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3368      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3369    ;;
3370
3371   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
3372   ## find X at run-time.
3373   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
3374   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
3375   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3376   ## had different values in configure (in ac_link) and src/Makefile.in.
3377   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3378   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
3379
3380   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3381 esac
3382
3383 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3384   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3385 fi
3386
3387 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3388
3389
3390 LD_FIRSTFLAG=
3391 ORDINARY_LINK=
3392 case "$opsys" in
3393   ## gnu: GNU needs its own crt0.
3394   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3395
3396   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3397   ## library search parth, i.e. it won't search /usr/lib for libc and
3398   ## friends.  Using -nostartfiles instead avoids this problem, and
3399   ## will also work on earlier NetBSD releases.
3400   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3401
3402   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3403   ##   MkLinux/LinuxPPC needs this.
3404   ## s390x-* only supports opsys = gnu-linux so it can be added here.
3405   gnu-*)
3406     case "$canonical" in
3407       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
3408     esac
3409     ;;
3410 esac
3411
3412
3413 if test "x$ORDINARY_LINK" = "xyes"; then
3414
3415   LD_FIRSTFLAG=""
3416   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3417
3418 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3419 ## freebsd, gnu-* not on powerpc*|s390x*.
3420 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3421
3422   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3423   ## places that are difficult to figure out at make time.  Fortunately,
3424   ## these same versions allow you to pass arbitrary flags on to the
3425   ## linker, so there is no reason not to use it as a linker.
3426   ##
3427   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3428   ## searching for libraries in its internal directories, so we have to
3429   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3430   LD_FIRSTFLAG="-nostdlib"
3431 fi
3432
3433 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3434 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3435
3436 AC_SUBST(LD_FIRSTFLAG)
3437
3438
3439 ## FIXME? The logic here is not precisely the same as that above.
3440 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3441 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3442 LIB_GCC=
3443 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3444
3445   case "$opsys" in
3446     freebsd|netbsd|openbsd) LIB_GCC= ;;
3447
3448     gnu-*)
3449       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3450       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3451       case $host_cpu in
3452       arm*)
3453         LIB_GCC="-lgcc_s"
3454         ;;
3455       *)
3456         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3457         ## immediately undefine it again and redefine it to empty.
3458         ## Was the C_SWITCH_X_SITE part really necessary?
3459 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3460         LIB_GCC=
3461         ;;
3462       esac
3463       ;;
3464
3465     ## Ask GCC where to find libgcc.a.
3466     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3467   esac
3468 fi                              dnl if $GCC
3469 AC_SUBST(LIB_GCC)
3470
3471
3472 ## If we're using X11/GNUstep, define some consequences.
3473 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3474   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3475   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3476 fi
3477
3478
3479 AH_TOP([/* GNU Emacs site configuration template file.
3480
3481 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
3482   Free Software Foundation, Inc.
3483
3484 This file is part of GNU Emacs.
3485
3486 GNU Emacs is free software: you can redistribute it and/or modify
3487 it under the terms of the GNU General Public License as published by
3488 the Free Software Foundation, either version 3 of the License, or
3489 (at your option) any later version.
3490
3491 GNU Emacs is distributed in the hope that it will be useful,
3492 but WITHOUT ANY WARRANTY; without even the implied warranty of
3493 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3494 GNU General Public License for more details.
3495
3496 You should have received a copy of the GNU General Public License
3497 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3498
3499
3500 /* No code in Emacs #includes config.h twice, but some bits of code
3501    intended to work with other packages as well (like gmalloc.c)
3502    think they can include it as many times as they like.  */
3503 #ifndef EMACS_CONFIG_H
3504 #define EMACS_CONFIG_H
3505 ])dnl
3506
3507 AH_BOTTOM([
3508 /* On AIX 3 this must be included before any other include file.  */
3509 #include <alloca.h>
3510 #if ! HAVE_ALLOCA
3511 # error "alloca not available on this machine"
3512 #endif
3513
3514 /* Define AMPERSAND_FULL_NAME if you use the convention
3515    that & in the full name stands for the login id.  */
3516 /* Turned on June 1996 supposing nobody will mind it.  */
3517 #define AMPERSAND_FULL_NAME
3518
3519 /* `subprocesses' should be defined if you want to
3520    have code for asynchronous subprocesses
3521    (as used in M-x compile and M-x shell).
3522    Only MSDOS does not support this (it overrides
3523    this in its config_opsysfile below).  */
3524
3525 #define subprocesses
3526
3527 /* Include the os dependent file.  */
3528 #ifdef config_opsysfile
3529 # include config_opsysfile
3530 #endif
3531
3532 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3533    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3534   (There is probably a better place to do this, but right now the
3535    Cocoa side does this in s/darwin.h and we cannot parallel this
3536    exactly since GNUstep is multi-OS.  */
3537 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3538 #  define SYSTEM_PURESIZE_EXTRA 30000
3539 #endif
3540
3541 #ifdef emacs /* Don't do this for lib-src.  */
3542 /* Tell regex.c to use a type compatible with Emacs.  */
3543 #define RE_TRANSLATE_TYPE Lisp_Object
3544 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3545 #ifdef make_number
3546 /* If make_number is a macro, use it.  */
3547 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3548 #else
3549 /* If make_number is a function, avoid it.  */
3550 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3551 #endif
3552 #endif
3553
3554 #include <string.h>
3555 #include <stdlib.h>
3556
3557 #if defined __GNUC__ && (__GNUC__ > 2 \
3558                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3559 #define NO_RETURN       __attribute__ ((__noreturn__))
3560 #else
3561 #define NO_RETURN       /* nothing */
3562 #endif
3563
3564 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3565 #define NO_INLINE __attribute__((noinline))
3566 #else
3567 #define NO_INLINE
3568 #endif
3569
3570 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3571 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3572 #else
3573 #define EXTERNALLY_VISIBLE
3574 #endif
3575
3576 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3577 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3578 #else
3579 # define ATTRIBUTE_FORMAT(spec) /* empty */
3580 #endif
3581
3582 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3583 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3584    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3585 #else
3586 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3587    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3588 #endif
3589
3590 /* Some versions of GNU/Linux define noinline in their headers.  */
3591 #ifdef noinline
3592 #undef noinline
3593 #endif
3594
3595 /* These won't be used automatically yet.  We also need to know, at least,
3596    that the stack is continuous.  */
3597 #ifdef __GNUC__
3598 #  ifndef GC_SETJMP_WORKS
3599   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3600 #    define GC_SETJMP_WORKS 1
3601 #  endif
3602 #endif
3603
3604 #endif /* EMACS_CONFIG_H */
3605
3606 /*
3607 Local Variables:
3608 mode: c
3609 End:
3610 */
3611 ])dnl
3612
3613 #### Report on what we decided to do.
3614 #### Report GTK as a toolkit, even if it doesn't use Xt.
3615 #### It makes printing result more understandable as using GTK sets
3616 #### toolkit_scroll_bars to yes by default.
3617 if test "${HAVE_GTK}" = "yes"; then
3618   USE_X_TOOLKIT=GTK
3619 fi
3620
3621 echo "
3622 Configured for \`${canonical}'.
3623
3624   Where should the build process find the source code?    ${srcdir}
3625   What operating system file should Emacs use?           \`${opsysfile-none}'
3626   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3627   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3628   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3629   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3630   What window system should Emacs use?                    ${window_system}
3631   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3632
3633 if test -n "${x_includes}"; then
3634 echo "  Where do we find X Windows header files?                ${x_includes}"
3635 else
3636 echo "  Where do we find X Windows header files?                Standard dirs"
3637 fi
3638 if test -n "${x_libraries}"; then
3639 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3640 else
3641 echo "  Where do we find X Windows libraries?                   Standard dirs"
3642 fi
3643
3644 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3645 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3646 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3647 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3648 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3649 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3650 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3651 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3652
3653 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3654 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3655 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3656 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3657 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3658 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3659 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3660
3661 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3662 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3663 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3664 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3665
3666 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3667 echo
3668
3669 if test -n "${EMACSDATA}"; then
3670    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
3671 fi
3672 if test -n "${EMACSDOC}"; then
3673    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
3674 fi
3675
3676 if test $USE_XASSERTS = yes; then
3677    echo "  Compiling with asserts turned on."
3678    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3679 fi
3680
3681 echo
3682
3683 if test "$HAVE_NS" = "yes"; then
3684    echo
3685    echo "You must run \"${MAKE-make} install\" in order to test the built application.
3686 The installed application will go to nextstep/Emacs.app and can be
3687 run or moved from there."
3688    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3689       echo "The application will be fully self-contained."
3690     else
3691       echo "The lisp resources for the application will be installed under ${prefix}.
3692 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
3693 to run if these resources are not installed."
3694    fi
3695    echo
3696 fi
3697
3698 if test "${opsys}" = "cygwin"; then
3699   case `uname -r` in
3700     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
3701            echo
3702            ;;
3703   esac
3704 fi
3705
3706 # Remove any trailing slashes in these variables.
3707 [test "${prefix}" != NONE &&
3708   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3709 test "${exec_prefix}" != NONE &&
3710   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3711
3712 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3713 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3714 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3715 dnl (else you get "no `Makefile.am' found for any configure output").
3716 dnl This will work, but you get a config.status that is not quite right
3717 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3718 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3719 dnl it seems better to just live with the duplication.
3720 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3721
3722 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3723        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3724        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3725        leim/Makefile])
3726
3727 dnl test/ is not present in release tarfiles.
3728 opt_makefile=test/automated/Makefile
3729
3730 if test -f $srcdir/${opt_makefile}.in; then
3731   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3732   dnl Again, it's best not to use a variable.  Though you can add
3733   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3734   AC_CONFIG_FILES([test/automated/Makefile])
3735 fi
3736
3737
3738 dnl admin/ may or may not be present.
3739 opt_makefile=admin/unidata/Makefile
3740
3741 if test -f $srcdir/${opt_makefile}.in; then
3742   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3743   AC_CONFIG_FILES([admin/unidata/Makefile])
3744 fi
3745
3746
3747 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3748
3749 AC_SUBST(SUBDIR_MAKEFILES_IN)
3750
3751 dnl Make the necessary directories, if they don't exist.
3752 AC_CONFIG_COMMANDS([mkdirs], [
3753 for dir in etc lisp ; do
3754   test -d ${dir} || mkdir ${dir}
3755 done
3756 ])
3757
3758 dnl You might wonder (I did) why epaths.h is generated by running make,
3759 dnl rather than just letting configure generate it from epaths.in.
3760 dnl One reason is that the various paths are not fully expanded (see above);
3761 dnl eg gamedir=${prefix}/var/games/emacs.
3762 dnl Secondly, the GNU Coding standards require that one should be able
3763 dnl to run `make prefix=/some/where/else' and override the values set
3764 dnl by configure.  This also explains the `move-if-change' test and
3765 dnl the use of force in the `epaths-force' rule in Makefile.in.
3766 AC_CONFIG_COMMANDS([epaths], [
3767 echo creating src/epaths.h
3768 ${MAKE-make} epaths-force
3769 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
3770
3771 AC_CONFIG_COMMANDS([gdbinit], [
3772 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3773   echo creating src/.gdbinit
3774   echo source $srcdir/src/.gdbinit > src/.gdbinit
3775 fi
3776 ])
3777
3778 AC_OUTPUT
3779
3780 dnl configure.in ends here