lisp/complete.el

   1 ;;; complete.el --- partial completion mechanism plus other goodies
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993, 1999, 2000, 2002, 2003, 2004,
   4 ;;   2005 Free Software Foundation, Inc.
   5
   6 ;; Author: Dave Gillespie <daveg@synaptics.com>
   7 ;; Keywords: abbrev convenience
   8 ;; Special thanks to Hallvard Furuseth for his many ideas and contributions.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Extended completion for the Emacs minibuffer.
  30 ;;
  31 ;; The basic idea is that the command name or other completable text is
  32 ;; divided into words and each word is completed separately, so that
  33 ;; "M-x p-b" expands to "M-x print-buffer".  If the entry is ambiguous
  34 ;; each word is completed as much as possible and then the cursor is
  35 ;; left at the first position where typing another letter will resolve
  36 ;; the ambiguity.
  37 ;;
  38 ;; Word separators for this purpose are hyphen, space, and period.
  39 ;; These would most likely occur in command names, Info menu items,
  40 ;; and file names, respectively.  But all word separators are treated
  41 ;; alike at all times.
  42 ;;
  43 ;; This completion package replaces the old-style completer's key
  44 ;; bindings for TAB, SPC, RET, and `?'.  The old completer is still
  45 ;; available on the Meta versions of those keys.  If you set
  46 ;; PC-meta-flag to nil, the old completion keys will be left alone
  47 ;; and the partial completer will use the Meta versions of the keys.
  48
  49
  50 ;; Usage:  M-x partial-completion-mode.  During completable minibuffer entry,
  51 ;;
  52 ;;     TAB    means to do a partial completion;
  53 ;;     SPC    means to do a partial complete-word;
  54 ;;     RET    means to do a partial complete-and-exit;
  55 ;;     ?      means to do a partial completion-help.
  56 ;;
  57 ;; If you set PC-meta-flag to nil, then TAB, SPC, RET, and ? perform
  58 ;; original Emacs completions, and M-TAB etc. do partial completion.
  59 ;; To do this, put the command,
  60 ;;
  61 ;;       (setq PC-meta-flag nil)
  62 ;;
  63 ;; in your .emacs file.  To load partial completion automatically, put
  64 ;;
  65 ;;       (partial-completion-mode t)
  66 ;;
  67 ;; in your .emacs file, too.  Things will be faster if you byte-compile
  68 ;; this file when you install it.
  69 ;;
  70 ;; As an extra feature, in cases where RET would not normally
  71 ;; complete (such as `C-x b'), the M-RET key will always do a partial
  72 ;; complete-and-exit.  Thus `C-x b f.c RET' will select or create a
  73 ;; buffer called "f.c", but `C-x b f.c M-RET' will select the existing
  74 ;; buffer whose name matches that pattern (perhaps "filing.c").
  75 ;; (PC-meta-flag does not affect this behavior; M-RET used to be
  76 ;; undefined in this situation.)
  77 ;;
  78 ;; The regular M-TAB (lisp-complete-symbol) command also supports
  79 ;; partial completion in this package.
  80
  81 ;; In addition, this package includes a feature for accessing include
  82 ;; files.  For example, `C-x C-f <sys/time.h> RET' reads the file
  83 ;; /usr/include/sys/time.h.  The variable PC-include-file-path is a
  84 ;; list of directories in which to search for include files.  Completion
  85 ;; is supported in include file names.
  86
  87
  88 ;;; Code:
  89
  90 (defgroup partial-completion nil
  91   "Partial Completion of items."
  92   :prefix "pc-"
  93   :group 'minibuffer
  94   :group 'convenience)
  95
  96 (defcustom PC-first-char 'find-file
  97   "*Control how the first character of a string is to be interpreted.
  98 If nil, the first character of a string is not taken literally if it is a word
  99 delimiter, so that \".e\" matches \"*.e*\".
 100 If t, the first character of a string is always taken literally even if it is a
 101 word delimiter, so that \".e\" matches \".e*\".
 102 If non-nil and non-t, the first character is taken literally only for file name
 103 completion."
 104   :type '(choice (const :tag "delimiter" nil)
 105                  (const :tag "literal" t)
 106                  (other :tag "find-file" find-file))
 107   :group 'partial-completion)
 108
 109 (defcustom PC-meta-flag t
 110   "*If non-nil, TAB means PC completion and M-TAB means normal completion.
 111 Otherwise, TAB means normal completion and M-TAB means Partial Completion."
 112   :type 'boolean
 113   :group 'partial-completion)
 114
 115 (defcustom PC-word-delimiters "-_. "
 116   "*A string of characters treated as word delimiters for completion.
 117 Some arcane rules:
 118 If `]' is in this string, it must come first.
 119 If `^' is in this string, it must not come first.
 120 If `-' is in this string, it must come first or right after `]'.
 121 In other words, if S is this string, then `[S]' must be a valid Emacs regular
 122 expression (not containing character ranges like `a-z')."
 123   :type 'string
 124   :group 'partial-completion)
 125
 126 (defcustom PC-include-file-path '("/usr/include" "/usr/local/include")
 127   "*A list of directories in which to look for include files.
 128 If nil, means use the colon-separated path in the variable $INCPATH instead."
 129   :type '(repeat directory)
 130   :group 'partial-completion)
 131
 132 (defcustom PC-disable-includes nil
 133   "*If non-nil, include-file support in \\[find-file] is disabled."
 134   :type 'boolean
 135   :group 'partial-completion)
 136
 137 (defvar PC-default-bindings t
 138   "If non-nil, default partial completion key bindings are suppressed.")
 139
 140 (defvar PC-env-vars-alist nil
 141   "A list of the environment variable names and values.")
 142
 143 \f
 144 (defvar PC-old-read-file-name-internal nil)
 145
 146 (defun PC-bindings (bind)
 147   (let ((completion-map minibuffer-local-completion-map)
 148         (must-match-map minibuffer-local-must-match-map))
 149     (cond ((not bind)
 150            ;; These bindings are the default bindings.  It would be better to
 151            ;; restore the previous bindings.
 152            (define-key completion-map "\t"      'minibuffer-complete)
 153            (define-key completion-map " "       'minibuffer-complete-word)
 154            (define-key completion-map "?"       'minibuffer-completion-help)
 155
 156            (define-key must-match-map "\t"      'minibuffer-complete)
 157            (define-key must-match-map " "       'minibuffer-complete-word)
 158            (define-key must-match-map "\r"      'minibuffer-complete-and-exit)
 159            (define-key must-match-map "\n"      'minibuffer-complete-and-exit)
 160            (define-key must-match-map "?"       'minibuffer-completion-help)
 161
 162            (define-key global-map "\e\t"        'complete-symbol))
 163           (PC-default-bindings
 164            (define-key completion-map "\t"      'PC-complete)
 165            (define-key completion-map " "       'PC-complete-word)
 166            (define-key completion-map "?"       'PC-completion-help)
 167
 168            (define-key completion-map "\e\t"    'PC-complete)
 169            (define-key completion-map "\e "     'PC-complete-word)
 170            (define-key completion-map "\e\r"    'PC-force-complete-and-exit)
 171            (define-key completion-map "\e\n"    'PC-force-complete-and-exit)
 172            (define-key completion-map "\e?"     'PC-completion-help)
 173
 174            (define-key must-match-map "\t"      'PC-complete)
 175            (define-key must-match-map " "       'PC-complete-word)
 176            (define-key must-match-map "\r"      'PC-complete-and-exit)
 177            (define-key must-match-map "\n"      'PC-complete-and-exit)
 178            (define-key must-match-map "?"       'PC-completion-help)
 179
 180            (define-key must-match-map "\e\t"    'PC-complete)
 181            (define-key must-match-map "\e "     'PC-complete-word)
 182            (define-key must-match-map "\e\r"    'PC-complete-and-exit)
 183            (define-key must-match-map "\e\n"    'PC-complete-and-exit)
 184            (define-key must-match-map "\e?"     'PC-completion-help)
 185
 186            (define-key global-map "\e\t"        'PC-lisp-complete-symbol)))))
 187
 188 ;;;###autoload
 189 (define-minor-mode partial-completion-mode
 190   "Toggle Partial Completion mode.
 191 With prefix ARG, turn Partial Completion mode on if ARG is positive.
 192
 193 When Partial Completion mode is enabled, TAB (or M-TAB if `PC-meta-flag' is
 194 nil) is enhanced so that if some string is divided into words and each word is
 195 delimited by a character in `PC-word-delimiters', partial words are completed
 196 as much as possible and `*' characters are treated likewise in file names.
 197
 198 For example, M-x p-c-m expands to M-x partial-completion-mode since no other
 199 command begins with that sequence of characters, and
 200 \\[find-file] f_b.c TAB might complete to foo_bar.c if that file existed and no
 201 other file in that directory begin with that sequence of characters.
 202
 203 Unless `PC-disable-includes' is non-nil, the `<...>' sequence is interpreted
 204 specially in \\[find-file].  For example,
 205 \\[find-file] <sys/time.h> RET finds the file `/usr/include/sys/time.h'.
 206 See also the variable `PC-include-file-path'.
 207
 208 Partial Completion mode extends the meaning of `completion-auto-help' (which
 209 see) so that if it is neither nil nor t, Emacs will show the  *Completions*
 210 buffer only on the second attempt to complete.  I.e. if TAB finds nothing
 211 to complete, the first TAB will just say \"Next char not unique\" without
 212 bringing up the *Completions* buffer, and the second TAB will then bring up
 213 the *Completions* buffer."
 214   :global t :group 'partial-completion
 215   ;; Deal with key bindings...
 216   (PC-bindings partial-completion-mode)
 217   ;; Deal with include file feature...
 218   (cond ((not partial-completion-mode)
 219          (remove-hook 'find-file-not-found-hooks 'PC-look-for-include-file))
 220         ((not PC-disable-includes)
 221          (add-hook 'find-file-not-found-hooks 'PC-look-for-include-file)))
 222   ;; ... with some underhand redefining.
 223   (cond ((and (not partial-completion-mode)
 224               (functionp PC-old-read-file-name-internal))
 225          (fset 'read-file-name-internal PC-old-read-file-name-internal))
 226         ((and (not PC-disable-includes) (not PC-old-read-file-name-internal))
 227          (setq PC-old-read-file-name-internal
 228                (symbol-function 'read-file-name-internal))
 229          (fset 'read-file-name-internal
 230                'PC-read-include-file-name-internal)))
 231     (when (and partial-completion-mode (null PC-env-vars-alist))
 232       (setq PC-env-vars-alist
 233             (mapcar (lambda (string)
 234                       (let ((d (string-match "=" string)))
 235                         (cons (concat "$" (substring string 0 d))
 236                               (and d (substring string (1+ d))))))
 237                     process-environment))))
 238
 239 \f
 240 (defun PC-complete ()
 241   "Like minibuffer-complete, but allows \"b--di\"-style abbreviations.
 242 For example, \"M-x b--di\" would match `byte-recompile-directory', or any
 243 name which consists of three or more words, the first beginning with \"b\"
 244 and the third beginning with \"di\".
 245
 246 The pattern \"b--d\" is ambiguous for `byte-recompile-directory' and
 247 `beginning-of-defun', so this would produce a list of completions
 248 just like when normal Emacs completions are ambiguous.
 249
 250 Word-delimiters for the purposes of Partial Completion are \"-\", \"_\",
 251 \".\", and SPC."
 252   (interactive)
 253   (if (PC-was-meta-key)
 254       (minibuffer-complete)
 255     ;; If the previous command was not this one,
 256     ;; never scroll, always retry completion.
 257     (or (eq last-command this-command)
 258         (setq minibuffer-scroll-window nil))
 259     (let ((window minibuffer-scroll-window))
 260       ;; If there's a fresh completion window with a live buffer,
 261       ;; and this command is repeated, scroll that window.
 262       (if (and window (window-buffer window)
 263                (buffer-name (window-buffer window)))
 264           (save-excursion
 265             (set-buffer (window-buffer window))
 266             (if (pos-visible-in-window-p (point-max) window)
 267                 (set-window-start window (point-min) nil)
 268               (scroll-other-window)))
 269         (PC-do-completion nil)))))
 270
 271
 272 (defun PC-complete-word ()
 273   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 274 See `PC-complete' for details.
 275 This can be bound to other keys, like `-' and `.', if you wish."
 276   (interactive)
 277   (if (eq (PC-was-meta-key) PC-meta-flag)
 278       (if (eq last-command-char ? )
 279           (minibuffer-complete-word)
 280         (self-insert-command 1))
 281     (self-insert-command 1)
 282     (if (eobp)
 283         (PC-do-completion 'word))))
 284
 285
 286 (defun PC-complete-space ()
 287   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 288 See `PC-complete' for details.
 289 This is suitable for binding to other keys which should act just like SPC."
 290   (interactive)
 291   (if (eq (PC-was-meta-key) PC-meta-flag)
 292       (minibuffer-complete-word)
 293     (insert " ")
 294     (if (eobp)
 295         (PC-do-completion 'word))))
 296
 297
 298 (defun PC-complete-and-exit ()
 299   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 300 See `PC-complete' for details."
 301   (interactive)
 302   (if (eq (PC-was-meta-key) PC-meta-flag)
 303       (minibuffer-complete-and-exit)
 304     (PC-do-complete-and-exit)))
 305
 306 (defun PC-force-complete-and-exit ()
 307   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 308 See `PC-complete' for details."
 309   (interactive)
 310   (let ((minibuffer-completion-confirm nil))
 311     (PC-do-complete-and-exit)))
 312
 313 (defun PC-do-complete-and-exit ()
 314   (if (= (point-max) (minibuffer-prompt-end))  ; Duplicate the "bug" that Info-menu relies on...
 315       (exit-minibuffer)
 316     (let ((flag (PC-do-completion 'exit)))
 317       (and flag
 318            (if (or (eq flag 'complete)
 319                    (not minibuffer-completion-confirm))
 320                (exit-minibuffer)
 321              (PC-temp-minibuffer-message " [Confirm]"))))))
 322
 323
 324 (defun PC-completion-help ()
 325   "Like `minibuffer-completion-help', but allows \"b--di\"-style abbreviations.
 326 See `PC-complete' for details."
 327   (interactive)
 328   (if (eq (PC-was-meta-key) PC-meta-flag)
 329       (minibuffer-completion-help)
 330     (PC-do-completion 'help)))
 331
 332 (defun PC-was-meta-key ()
 333   (or (/= (length (this-command-keys)) 1)
 334       (let ((key (aref (this-command-keys) 0)))
 335         (if (integerp key)
 336             (>= key 128)
 337           (not (null (memq 'meta (event-modifiers key))))))))
 338
 339
 340 (defvar PC-ignored-extensions 'empty-cache)
 341 (defvar PC-delims 'empty-cache)
 342 (defvar PC-ignored-regexp nil)
 343 (defvar PC-word-failed-flag nil)
 344 (defvar PC-delim-regex nil)
 345 (defvar PC-ndelims-regex nil)
 346 (defvar PC-delims-list nil)
 347
 348 (defvar PC-completion-as-file-name-predicate
 349   (function
 350    (lambda ()
 351      (memq minibuffer-completion-table
 352            '(read-file-name-internal read-directory-name-internal))))
 353    "A function testing whether a minibuffer completion now will work filename-style.
 354 The function takes no arguments, and typically looks at the value
 355 of `minibuffer-completion-table' and the minibuffer contents.")
 356
 357 (defun PC-do-completion (&optional mode beg end)
 358   (or beg (setq beg (minibuffer-prompt-end)))
 359   (or end (setq end (point-max)))
 360   (let* ((table minibuffer-completion-table)
 361          (pred minibuffer-completion-predicate)
 362          (filename (funcall PC-completion-as-file-name-predicate))
 363          (dirname nil)
 364          (dirlength 0)
 365          (str (buffer-substring beg end))
 366          (incname (and filename (string-match "<\\([^\"<>]*\\)>?$" str)))
 367          (ambig nil)
 368          basestr
 369          env-on
 370          regex
 371          p offset
 372          (poss nil)
 373          helpposs
 374          (case-fold-search completion-ignore-case))
 375
 376     ;; Check if buffer contents can already be considered complete
 377     (if (and (eq mode 'exit)
 378              (test-completion str table pred))
 379         'complete
 380
 381       ;; Do substitutions in directory names
 382       (and filename
 383            (setq basestr (or (file-name-directory str) ""))
 384            (setq dirlength (length basestr))
 385            ;; Do substitutions in directory names
 386            (setq p (substitute-in-file-name basestr))
 387            (not (string-equal basestr p))
 388            (setq str (concat p (file-name-nondirectory str)))
 389            (progn
 390              (delete-region beg end)
 391              (insert str)
 392              (setq end (+ beg (length str)))))
 393
 394       ;; Prepare various delimiter strings
 395       (or (equal PC-word-delimiters PC-delims)
 396           (setq PC-delims PC-word-delimiters
 397                 PC-delim-regex (concat "[" PC-delims "]")
 398                 PC-ndelims-regex (concat "[^" PC-delims "]*")
 399                 PC-delims-list (append PC-delims nil)))
 400
 401       ;; Add wildcards if necessary
 402       (and filename
 403            (let ((dir (file-name-directory str))
 404                  (file (file-name-nondirectory str))
 405                  ;; The base dir for file-completion is passed in `predicate'.
 406                  (default-directory (expand-file-name pred)))
 407              (while (and (stringp dir) (not (file-directory-p dir)))
 408                (setq dir (directory-file-name dir))
 409                (setq file (concat (replace-regexp-in-string
 410                                    PC-delim-regex "*\\&"
 411                                    (file-name-nondirectory dir))
 412                                   "*/" file))
 413                (setq dir (file-name-directory dir)))
 414              (setq str (concat dir file))))
 415
 416       ;; Look for wildcard expansions in directory name
 417       (and filename
 418            (string-match "\\*.*/" str)
 419            (let ((pat str)
 420                  ;; The base dir for file-completion is passed in `predicate'.
 421                  (default-directory (expand-file-name pred))
 422                  files)
 423              (setq p (1+ (string-match "/[^/]*\\'" pat)))
 424              (while (setq p (string-match PC-delim-regex pat p))
 425                (setq pat (concat (substring pat 0 p)
 426                                  "*"
 427                                  (substring pat p))
 428                      p (+ p 2)))
 429              (setq files (PC-expand-many-files (concat pat "*")))
 430              (if files
 431                  (let ((dir (file-name-directory (car files)))
 432                        (p files))
 433                    (while (and (setq p (cdr p))
 434                                (equal dir (file-name-directory (car p)))))
 435                    (if p
 436                        (setq filename nil table nil pred nil
 437                              ambig t)
 438                      (delete-region beg end)
 439                      (setq str (concat dir (file-name-nondirectory str)))
 440                      (insert str)
 441                      (setq end (+ beg (length str)))))
 442                (setq filename nil table nil pred nil))))
 443
 444       ;; Strip directory name if appropriate
 445       (if filename
 446           (if incname
 447               (setq basestr (substring str incname)
 448                     dirname (substring str 0 incname))
 449             (setq basestr (file-name-nondirectory str)
 450                   dirname (file-name-directory str))
 451             ;; Make sure str is consistent with its directory and basename
 452             ;; parts.  This is important on DOZe'NT systems when str only
 453             ;; includes a drive letter, like in "d:".
 454             (setq str (concat dirname basestr)))
 455         (setq basestr str))
 456
 457       ;; Convert search pattern to a standard regular expression
 458       (setq regex (regexp-quote basestr)
 459             offset (if (and (> (length regex) 0)
 460                             (not (eq (aref basestr 0) ?\*))
 461                             (or (eq PC-first-char t)
 462                                 (and PC-first-char filename))) 1 0)
 463             p offset)
 464       (while (setq p (string-match PC-delim-regex regex p))
 465         (if (eq (aref regex p) ? )
 466             (setq regex (concat (substring regex 0 p)
 467                                 PC-ndelims-regex
 468                                 PC-delim-regex
 469                                 (substring regex (1+ p)))
 470                   p (+ p (length PC-ndelims-regex) (length PC-delim-regex)))
 471           (let ((bump (if (memq (aref regex p)
 472                                 '(?$ ?^ ?\. ?* ?+ ?? ?[ ?] ?\\))
 473                           -1 0)))
 474             (setq regex (concat (substring regex 0 (+ p bump))
 475                                 PC-ndelims-regex
 476                                 (substring regex (+ p bump)))
 477                   p (+ p (length PC-ndelims-regex) 1)))))
 478       (setq p 0)
 479       (if filename
 480           (while (setq p (string-match "\\\\\\*" regex p))
 481             (setq regex (concat (substring regex 0 p)
 482                                 "[^/]*"
 483                                 (substring regex (+ p 2))))))
 484       ;;(setq the-regex regex)
 485       (setq regex (concat "\\`" regex))
 486
 487       (and (> (length basestr) 0)
 488            (= (aref basestr 0) ?$)
 489            (setq env-on t
 490                  table PC-env-vars-alist
 491                  pred nil))
 492
 493       ;; Find an initial list of possible completions
 494       (if (not (setq p (string-match (concat PC-delim-regex
 495                                              (if filename "\\|\\*" ""))
 496                                      str
 497                                      (+ (length dirname) offset))))
 498
 499           ;; Minibuffer contains no hyphens -- simple case!
 500           (setq poss (all-completions (if env-on
 501                                           basestr str)
 502                                       table
 503                                       pred))
 504
 505         ;; Use all-completions to do an initial cull.  This is a big win,
 506         ;; since all-completions is written in C!
 507         (let ((compl (all-completions (if env-on
 508                                           (file-name-nondirectory (substring str 0 p))
 509                                         (substring str 0 p))
 510                                         table
 511                                         pred)))
 512           (setq p compl)
 513           (while p
 514             (and (string-match regex (car p))
 515                  (progn
 516                    (set-text-properties 0 (length (car p)) '() (car p))
 517                    (setq poss (cons (car p) poss))))
 518             (setq p (cdr p)))))
 519
 520       ;; Now we have a list of possible completions
 521       (cond
 522
 523        ;; No valid completions found
 524        ((null poss)
 525         (if (and (eq mode 'word)
 526                  (not PC-word-failed-flag))
 527             (let ((PC-word-failed-flag t))
 528               (delete-backward-char 1)
 529               (PC-do-completion 'word))
 530           (beep)
 531           (PC-temp-minibuffer-message (if ambig
 532                                           " [Ambiguous dir name]"
 533                                         (if (eq mode 'help)
 534                                             " [No completions]"
 535                                           " [No match]")))
 536           nil))
 537
 538        ;; More than one valid completion found
 539        ((or (cdr (setq helpposs poss))
 540             (memq mode '(help word)))
 541
 542         ;; Handle completion-ignored-extensions
 543         (and filename
 544              (not (eq mode 'help))
 545              (let ((p2 poss))
 546
 547                ;; Build a regular expression representing the extensions list
 548                (or (equal completion-ignored-extensions PC-ignored-extensions)
 549                    (setq PC-ignored-regexp
 550                          (concat "\\("
 551                                  (mapconcat
 552                                   'regexp-quote
 553                                   (setq PC-ignored-extensions
 554                                         completion-ignored-extensions)
 555                                   "\\|")
 556                                  "\\)\\'")))
 557
 558                ;; Check if there are any without an ignored extension.
 559                ;; Also ignore `.' and `..'.
 560                (setq p nil)
 561                (while p2
 562                  (or (string-match PC-ignored-regexp (car p2))
 563                      (string-match "\\(\\`\\|/\\)[.][.]?/?\\'" (car p2))
 564                      (setq p (cons (car p2) p)))
 565                  (setq p2 (cdr p2)))
 566
 567                ;; If there are "good" names, use them
 568                (and p (setq poss p))))
 569
 570         ;; Is the actual string one of the possible completions?
 571         (setq p (and (not (eq mode 'help)) poss))
 572         (while (and p
 573                     (not (string-equal (car p) basestr)))
 574           (setq p (cdr p)))
 575         (and p (null mode)
 576              (PC-temp-minibuffer-message " [Complete, but not unique]"))
 577         (if (and p
 578                  (not (and (null mode)
 579                            (eq this-command last-command))))
 580             t
 581
 582           ;; If ambiguous, try for a partial completion
 583           (let ((improved nil)
 584                 prefix
 585                 (pt nil)
 586                 (skip "\\`"))
 587
 588             ;; Check if next few letters are the same in all cases
 589             (if (and (not (eq mode 'help))
 590                      (setq prefix (try-completion "" (mapcar 'list poss))))
 591                 (let ((first t) i)
 592                   (if (eq mode 'word)
 593                       (setq prefix (PC-chop-word prefix basestr)))
 594                   (goto-char (+ beg (length dirname)))
 595                   (while (and (progn
 596                                 (setq i 0)
 597                                 (while (< i (length prefix))
 598                                   (if (and (< (point) end)
 599                                            (eq (aref prefix i)
 600                                                (following-char)))
 601                                       (forward-char 1)
 602                                     (if (and (< (point) end)
 603                                              (or (and (looking-at " ")
 604                                                       (memq (aref prefix i)
 605                                                             PC-delims-list))
 606                                                  (eq (downcase (aref prefix i))
 607                                                      (downcase
 608                                                       (following-char)))))
 609                                         (progn
 610                                           (delete-char 1)
 611                                           (setq end (1- end)))
 612                                       (and filename (looking-at "\\*")
 613                                            (progn
 614                                              (delete-char 1)
 615                                              (setq end (1- end))))
 616                                       (setq improved t))
 617                                     (insert (substring prefix i (1+ i)))
 618                                     (setq end (1+ end)))
 619                                   (setq i (1+ i)))
 620                                 (or pt (equal (point) beg)
 621                                     (setq pt (point)))
 622                                 (looking-at PC-delim-regex))
 623                               (setq skip (concat skip
 624                                                  (regexp-quote prefix)
 625                                                  PC-ndelims-regex)
 626                                     prefix (try-completion
 627                                             ""
 628                                             (mapcar
 629                                              (function
 630                                               (lambda (x)
 631                                                 (list
 632                                                  (and (string-match skip x)
 633                                                       (substring
 634                                                        x
 635                                                        (match-end 0))))))
 636                                              poss)))
 637                               (or (> i 0) (> (length prefix) 0))
 638                               (or (not (eq mode 'word))
 639                                   (and first (> (length prefix) 0)
 640                                        (setq first nil
 641                                              prefix (substring prefix 0 1))))))
 642                   (goto-char (if (eq mode 'word) end
 643                                (or pt beg)))))
 644
 645             (if (and (eq mode 'word)
 646                      (not PC-word-failed-flag))
 647
 648                 (if improved
 649
 650                     ;; We changed it... would it be complete without the space?
 651                     (if (test-completion (buffer-substring 1 (1- end))
 652                                           table pred)
 653                         (delete-region (1- end) end)))
 654
 655               (if improved
 656
 657                   ;; We changed it... enough to be complete?
 658                   (and (eq mode 'exit)
 659                        (test-completion (field-string) table pred))
 660
 661                 ;; If totally ambiguous, display a list of completions
 662                 (if (or (eq completion-auto-help t)
 663                         (and completion-auto-help
 664                              (eq last-command this-command))
 665                         (eq mode 'help))
 666                     (with-output-to-temp-buffer "*Completions*"
 667                       (display-completion-list (sort helpposs 'string-lessp))
 668                       (save-excursion
 669                         (set-buffer standard-output)
 670                         ;; Record which part of the buffer we are completing
 671                         ;; so that choosing a completion from the list
 672                         ;; knows how much old text to replace.
 673                         (setq completion-base-size dirlength)))
 674                   (PC-temp-minibuffer-message " [Next char not unique]"))
 675                 nil)))))
 676
 677        ;; Only one possible completion
 678        (t
 679         (if (and (equal basestr (car poss))
 680                  (not (and env-on filename)))
 681             (if (null mode)
 682                 (PC-temp-minibuffer-message " [Sole completion]"))
 683           (delete-region beg end)
 684           (insert (format "%s"
 685                           (if filename
 686                               (substitute-in-file-name (concat dirname (car poss)))
 687                             (car poss)))))
 688         t)))))
 689
 690 (defun PC-chop-word (new old)
 691   (let ((i -1)
 692         (j -1))
 693     (while (and (setq i (string-match PC-delim-regex old (1+ i)))
 694                 (setq j (string-match PC-delim-regex new (1+ j)))))
 695     (if (and j
 696              (or (not PC-word-failed-flag)
 697                  (setq j (string-match PC-delim-regex new (1+ j)))))
 698         (substring new 0 (1+ j))
 699       new)))
 700
 701 (defvar PC-not-minibuffer nil)
 702
 703 (defun PC-temp-minibuffer-message (message)
 704   "A Lisp version of `temp_minibuffer_message' from minibuf.c."
 705   (cond (PC-not-minibuffer
 706          (message message)
 707          (sit-for 2)
 708          (message ""))
 709         ((fboundp 'temp-minibuffer-message)
 710          (temp-minibuffer-message message))
 711         (t
 712          (let ((point-max (point-max)))
 713            (save-excursion
 714              (goto-char point-max)
 715              (insert message))
 716            (let ((inhibit-quit t))
 717              (sit-for 2)
 718              (delete-region point-max (point-max))
 719              (when quit-flag
 720                (setq quit-flag nil
 721                      unread-command-events '(7))))))))
 722
 723
 724 (defun PC-lisp-complete-symbol ()
 725   "Perform completion on Lisp symbol preceding point.
 726 That symbol is compared against the symbols that exist
 727 and any additional characters determined by what is there
 728 are inserted.
 729 If the symbol starts just after an open-parenthesis,
 730 only symbols with function definitions are considered.
 731 Otherwise, all symbols with function definitions, values
 732 or properties are considered."
 733   (interactive)
 734   (let* ((end (point))
 735          (buffer-syntax (syntax-table))
 736          (beg (unwind-protect
 737                   (save-excursion
 738                     (if lisp-mode-syntax-table
 739                         (set-syntax-table lisp-mode-syntax-table))
 740                     (backward-sexp 1)
 741                     (while (= (char-syntax (following-char)) ?\')
 742                       (forward-char 1))
 743                     (point))
 744                 (set-syntax-table buffer-syntax)))
 745          (minibuffer-completion-table obarray)
 746          (minibuffer-completion-predicate
 747           (if (eq (char-after (1- beg)) ?\()
 748               'fboundp
 749             (function (lambda (sym)
 750                         (or (boundp sym) (fboundp sym)
 751                             (symbol-plist sym))))))
 752          (PC-not-minibuffer t))
 753     (PC-do-completion nil beg end)))
 754
 755 (defun PC-complete-as-file-name ()
 756    "Perform completion on file names preceding point.
 757  Environment vars are converted to their values."
 758    (interactive)
 759    (let* ((end (point))
 760           (beg (if (re-search-backward "[^\\][ \t\n\"\`\'][^ \t\n\"\`\']"
 761                                        (point-min) t)
 762                    (+ (point) 2)
 763                    (point-min)))
 764           (minibuffer-completion-table 'read-file-name-internal)
 765           (minibuffer-completion-predicate "")
 766           (PC-not-minibuffer t))
 767      (goto-char end)
 768      (PC-do-completion nil beg end)))
 769
 770 ;;; Use the shell to do globbing.
 771 ;;; This could now use file-expand-wildcards instead.
 772
 773 (defun PC-expand-many-files (name)
 774   (save-excursion
 775     (set-buffer (generate-new-buffer " *Glob Output*"))
 776     (erase-buffer)
 777     (shell-command (concat "echo " name) t)
 778     (goto-char (point-min))
 779     (if (looking-at ".*No match")
 780         nil
 781       (insert "(\"")
 782       (while (search-forward " " nil t)
 783         (delete-backward-char 1)
 784         (insert "\" \""))
 785       (goto-char (point-max))
 786       (delete-backward-char 1)
 787       (insert "\")")
 788       (goto-char (point-min))
 789       (let ((files (read (current-buffer))) (p nil))
 790         (kill-buffer (current-buffer))
 791         (or (equal completion-ignored-extensions PC-ignored-extensions)
 792             (setq PC-ignored-regexp
 793                   (concat "\\("
 794                           (mapconcat
 795                            'regexp-quote
 796                            (setq PC-ignored-extensions
 797                                  completion-ignored-extensions)
 798                            "\\|")
 799                           "\\)\\'")))
 800         (setq p nil)
 801         (while files
 802           (or (string-match PC-ignored-regexp (car files))
 803               (setq p (cons (car files) p)))
 804           (setq files (cdr files)))
 805         p))))
 806
 807 ;;; Facilities for loading C header files.  This is independent from the
 808 ;;; main completion code.  See also the variable `PC-include-file-path'
 809 ;;; at top of this file.
 810
 811 (defun PC-look-for-include-file ()
 812   (if (string-match "[\"<]\\([^\"<>]*\\)[\">]?$" (buffer-file-name))
 813       (let ((name (substring (buffer-file-name)
 814                              (match-beginning 1) (match-end 1)))
 815             (punc (aref (buffer-file-name) (match-beginning 0)))
 816             (path nil)
 817             new-buf)
 818         (kill-buffer (current-buffer))
 819         (if (equal name "")
 820             (save-excursion
 821               (set-buffer (car (buffer-list)))
 822               (save-excursion
 823                 (beginning-of-line)
 824                 (if (looking-at
 825                      "[ \t]*#[ \t]*include[ \t]+[<\"]\\(.+\\)[>\"][ \t]*[\n/]")
 826                     (setq name (buffer-substring (match-beginning 1)
 827                                                  (match-end 1))
 828                           punc (char-after (1- (match-beginning 1))))
 829                   ;; Suggested by Frank Siebenlist:
 830                   (if (or (looking-at
 831                            "[ \t]*([ \t]*load[ \t]+\"\\([^\"]+\\)\"")
 832                           (looking-at
 833                            "[ \t]*([ \t]*load-library[ \t]+\"\\([^\"]+\\)\"")
 834                           (looking-at
 835                            "[ \t]*([ \t]*require[ \t]+'\\([^\t )]+\\)[\t )]"))
 836                       (progn
 837                         (setq name (buffer-substring (match-beginning 1)
 838                                                      (match-end 1))
 839                               punc ?\<
 840                               path load-path)
 841                         (if (string-match "\\.elc$" name)
 842                             (setq name (substring name 0 -1))
 843                           (or (string-match "\\.el$" name)
 844                               (setq name (concat name ".el")))))
 845                     (error "Not on an #include line"))))))
 846         (or (string-match "\\.[[:alnum:]]+$" name)
 847             (setq name (concat name ".h")))
 848         (if (eq punc ?\<)
 849             (let ((path (or path (PC-include-file-path))))
 850               (while (and path
 851                           (not (file-exists-p
 852                                 (concat (file-name-as-directory (car path))
 853                                         name))))
 854                 (setq path (cdr path)))
 855               (if path
 856                   (setq name (concat (file-name-as-directory (car path)) name))
 857                 (error "No such include file: <%s>" name)))
 858           (let ((dir (save-excursion
 859                        (set-buffer (car (buffer-list)))
 860                        default-directory)))
 861             (if (file-exists-p (concat dir name))
 862                 (setq name (concat dir name))
 863               (error "No such include file: `%s'" name))))
 864         (setq new-buf (get-file-buffer name))
 865         (if new-buf
 866             ;; no need to verify last-modified time for this!
 867             (set-buffer new-buf)
 868           (setq new-buf (create-file-buffer name))
 869           (set-buffer new-buf)
 870           (erase-buffer)
 871           (insert-file-contents name t))
 872         ;; Returning non-nil with the new buffer current
 873         ;; is sufficient to tell find-file to use it.
 874         t)
 875     nil))
 876
 877 (defun PC-include-file-path ()
 878   (or PC-include-file-path
 879       (let ((env (getenv "INCPATH"))
 880             (path nil)
 881             pos)
 882         (or env (error "No include file path specified"))
 883         (while (setq pos (string-match ":[^:]+$" env))
 884           (setq path (cons (substring env (1+ pos)) path)
 885                 env (substring env 0 pos)))
 886         path)))
 887
 888 ;;; This is adapted from lib-complete.el, by Mike Williams.
 889 (defun PC-include-file-all-completions (file search-path &optional full)
 890   "Return all completions for FILE in any directory on SEARCH-PATH.
 891 If optional third argument FULL is non-nil, returned pathnames should be
 892 absolute rather than relative to some directory on the SEARCH-PATH."
 893   (setq search-path
 894         (mapcar (lambda (dir)
 895                   (if dir (file-name-as-directory dir) default-directory))
 896                 search-path))
 897   (if (file-name-absolute-p file)
 898       ;; It's an absolute file name, so don't need search-path
 899       (progn
 900         (setq file (expand-file-name file))
 901         (file-name-all-completions
 902          (file-name-nondirectory file) (file-name-directory file)))
 903     (let ((subdir (file-name-directory file))
 904           (ndfile (file-name-nondirectory file))
 905           file-lists)
 906       ;; Append subdirectory part to each element of search-path
 907       (if subdir
 908           (setq search-path
 909                 (mapcar (lambda (dir) (concat dir subdir))
 910                         search-path)
 911                 file ))
 912       ;; Make list of completions in each directory on search-path
 913       (while search-path
 914         (let* ((dir (car search-path))
 915                (subdir (if full dir subdir)))
 916           (if (file-directory-p dir)
 917               (progn
 918                 (setq file-lists
 919                       (cons
 920                        (mapcar (lambda (file) (concat subdir file))
 921                                (file-name-all-completions ndfile
 922                                                           (car search-path)))
 923                        file-lists))))
 924           (setq search-path (cdr search-path))))
 925       ;; Compress out duplicates while building complete list (slloooow!)
 926       (let ((sorted (sort (apply 'nconc file-lists)
 927                           (lambda (x y) (not (string-lessp x y)))))
 928             compressed)
 929         (while sorted
 930           (if (equal (car sorted) (car compressed)) nil
 931             (setq compressed (cons (car sorted) compressed)))
 932           (setq sorted (cdr sorted)))
 933         compressed))))
 934
 935 (defun PC-read-include-file-name-internal (string dir action)
 936   (if (string-match "<\\([^\"<>]*\\)>?$" string)
 937       (let* ((name (substring string (match-beginning 1) (match-end 1)))
 938              (str2 (substring string (match-beginning 0)))
 939              (completion-table
 940               (mapcar (function (lambda (x) (list (format "<%s>" x))))
 941                       (PC-include-file-all-completions
 942                        name (PC-include-file-path)))))
 943         (cond
 944          ((not completion-table) nil)
 945          ((eq action nil) (try-completion str2 completion-table nil))
 946          ((eq action t) (all-completions str2 completion-table nil))
 947          ((eq action 'lambda) (test-completion str2 completion-table nil))))
 948     (funcall PC-old-read-file-name-internal string dir action)))
 949 \f
 950
 951 (provide 'complete)
 952
 953 ;; arch-tag: fc7e2768-ff44-4e22-b579-4d825b968458
 954 ;;; complete.el ends here