configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2011  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  49 dnl Create a new --with option that defaults to being disabled.
  50 dnl NAME is the base name of the option.  The shell variable with_NAME
  51 dnl   will be set to either the user's value (if the option is
  52 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  53 dnl   option is not specified).  Note that the shell variable name is
  54 dnl   constructed as autoconf does, by replacing non-alphanumeric
  55 dnl   characters with "_".
  56 dnl HELP-STRING is the help text for the option.
  57 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  58   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  59     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  60 ])dnl
  61
  62 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  63 dnl Create a new --with option that defaults to being enabled.  NAME
  64 dnl   is the base name of the option.  The shell variable with_NAME
  65 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  66 dnl   'yes' (if the option is not specified).  Note that the shell
  67 dnl   variable name is constructed as autoconf does, by replacing
  68 dnl   non-alphanumeric characters with "_".
  69 dnl HELP-STRING is the help text for the option.
  70 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  71   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  72    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  73 ])dnl
  74
  75 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  76 if test "$with_pop" = yes; then
  77    AC_DEFINE(MAIL_USE_POP)
  78 fi
  79 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  80
  81 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  82 if test "$with_kerberos" != no; then
  83    AC_DEFINE(KERBEROS)
  84 fi
  85 AH_TEMPLATE(KERBEROS,
  86             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  87
  88 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  89 if test "${with_kerberos5}" != no; then
  90   if test "${with_kerberos}" = no; then
  91     with_kerberos=yes
  92     AC_DEFINE(KERBEROS)
  93   fi
  94   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  95 fi
  96
  97 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  98 dnl FIXME hesiod support may not be present, so it seems like an error
  99 dnl to define, or at least use, this unconditionally.
 100 if test "$with_hesiod" != no; then
 101   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 102 fi
 103
 104 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 105 if test "$with_mmdf" != no; then
 106    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 107 fi
 108
 109 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 110 if test "$with_mail_unlink" != no; then
 111    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 112 fi
 113
 114 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 115     [string giving default POP mail host])],
 116     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 117
 118 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 119
 120 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 121 if test "$with_sync_input" = yes; then
 122    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 123 fi
 124
 125 dnl FIXME currently it is not the last.
 126 dnl This should be the last --with option, because --with-x is
 127 dnl added later on when we find the path of X, and it's best to
 128 dnl keep them together visually.
 129 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 130  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 131 [         case "${withval}" in
 132             y | ye | yes )      val=gtk ;;
 133             n | no )            val=no  ;;
 134             l | lu | luc | luci | lucid )       val=lucid ;;
 135             a | at | ath | athe | athen | athena )      val=athena ;;
 136             m | mo | mot | moti | motif )       val=motif ;;
 137             g | gt | gtk  )     val=gtk ;;
 138             gtk3  )     val=gtk3 ;;
 139             * )
 140 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 141 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 142 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 143             ;;
 144           esac
 145           with_x_toolkit=$val
 146 ])
 147
 148 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 149 if test "$with_wide_int" = yes; then
 150   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 151 fi
 152
 153 dnl _ON results in a '--without' option in the --help output, so
 154 dnl the help text should refer to "don't compile", etc.
 155 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 156 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 157 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 158 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 159 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 160 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 161 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 162 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 163
 164 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 165 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 166 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 167
 168 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 169 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 170 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 171 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 172
 173 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 174 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 175 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 176 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 177 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 178 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 179
 180 ## For the times when you want to build Emacs but don't have
 181 ## a suitable makeinfo, and can live without the manuals.
 182 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 183 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 184
 185 ## This is an option because I do not know if all info/man support
 186 ## compressed files, nor how to test if they do so.
 187 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 188 if test $with_compress_info = yes; then
 189    GZIP_INFO=yes
 190 else
 191    GZIP_INFO=
 192 fi
 193 AC_SUBST(GZIP_INFO)
 194
 195 AC_ARG_WITH([pkg-config-prog],dnl
 196 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 197                   [path to pkg-config for finding GTK and librsvg])])
 198 if test "X${with_pkg_config_prog}" != X; then
 199    if test "${with_pkg_config_prog}" != yes; then
 200       PKG_CONFIG="${with_pkg_config_prog}"
 201    fi
 202 fi
 203
 204 CRT_DIR=
 205 AC_ARG_WITH([crt-dir],dnl
 206 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 207 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 208 CRT_DIR="${with_crt_dir}"
 209
 210 AC_ARG_WITH(gameuser,dnl
 211 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 212 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 213   && gameuser="${with_gameuser}"
 214 test "X$gameuser" = X && gameuser=games
 215
 216 AC_ARG_WITH([gnustep-conf],dnl
 217 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 218 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 219   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 220 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 221      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 222
 223 AC_ARG_ENABLE(ns-self-contained,
 224 [AS_HELP_STRING([--disable-ns-self-contained],
 225                 [disable self contained build under NeXTstep])],
 226    EN_NS_SELF_CONTAINED=$enableval,
 227    EN_NS_SELF_CONTAINED=yes)
 228
 229 AC_ARG_ENABLE(asserts,
 230 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 231       USE_XASSERTS=$enableval,
 232       USE_XASSERTS=no)
 233
 234 AC_ARG_ENABLE(maintainer-mode,
 235 [AS_HELP_STRING([--disable-maintainer-mode],
 236                 [disable make rules and dependencies not useful (and sometimes
 237                  confusing) to the casual installer])],
 238       USE_MAINTAINER_MODE=$enableval,
 239       USE_MAINTAINER_MODE=yes)
 240 if test $USE_MAINTAINER_MODE = yes; then
 241   MAINT=
 242 else
 243   MAINT=#
 244 fi
 245 AC_SUBST(MAINT)
 246
 247 AC_ARG_ENABLE(locallisppath,
 248 [AS_HELP_STRING([--enable-locallisppath=PATH],
 249                 [directories Emacs should search for lisp files specific
 250                  to this site])],
 251 if test "${enableval}" = "no"; then
 252   locallisppath=
 253 elif test "${enableval}" != "yes"; then
 254   locallisppath=${enableval}
 255 fi)
 256
 257 AC_ARG_ENABLE(checking,
 258 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 259                 [enable expensive run-time checks.  With LIST,
 260                  enable only specific categories of checks.
 261                  Categories are: all,yes,no.
 262                  Flags are: stringbytes, stringoverrun, stringfreelist,
 263                  xmallocoverrun, conslist])],
 264 [ac_checking_flags="${enableval}"],[])
 265 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 266 for check in $ac_checking_flags
 267 do
 268         case $check in
 269         # these set all the flags to specific states
 270         yes)            ac_enable_checking=1 ;;
 271         no)             ac_enable_checking= ;
 272                         ac_gc_check_stringbytes= ;
 273                         ac_gc_check_string_overrun= ;
 274                         ac_gc_check_string_free_list= ;
 275                         ac_xmalloc_overrun= ;
 276                         ac_gc_check_cons_list= ;;
 277         all)            ac_enable_checking=1 ;
 278                         ac_gc_check_stringbytes=1 ;
 279                         ac_gc_check_string_overrun=1 ;
 280                         ac_gc_check_string_free_list=1 ;
 281                         ac_xmalloc_overrun=1 ;
 282                         ac_gc_check_cons_list=1 ;;
 283         # these enable particular checks
 284         stringbytes)    ac_gc_check_stringbytes=1 ;;
 285         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 286         stringfreelist) ac_gc_check_string_free_list=1 ;;
 287         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 288         conslist)       ac_gc_check_cons_list=1 ;;
 289         *)      AC_MSG_ERROR(unknown check category $check) ;;
 290         esac
 291 done
 292 IFS="$ac_save_IFS"
 293
 294 if test x$ac_enable_checking != x ; then
 295   AC_DEFINE(ENABLE_CHECKING, 1,
 296 [Enable expensive run-time checking of data types?])
 297 fi
 298 if test x$ac_gc_check_stringbytes != x ; then
 299   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 300 [Define this temporarily to hunt a bug.  If defined, the size of
 301    strings is redundantly recorded in sdata structures so that it can
 302    be compared to the sizes recorded in Lisp strings.])
 303 fi
 304 if test x$ac_gc_check_string_overrun != x ; then
 305   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 306 [Define this to check for short string overrun.])
 307 fi
 308 if test x$ac_gc_check_string_free_list != x ; then
 309   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 310 [Define this to check the string free list.])
 311 fi
 312 if test x$ac_xmalloc_overrun != x ; then
 313   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 314 [Define this to check for malloc buffer overrun.])
 315 fi
 316 if test x$ac_gc_check_cons_list != x ; then
 317   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 318 [Define this to check for errors in cons list.])
 319 fi
 320
 321 AC_ARG_ENABLE(use-lisp-union-type,
 322 [AS_HELP_STRING([--enable-use-lisp-union-type],
 323                 [use a union for the Lisp_Object data type.
 324                 This is only useful for development for catching certain types of bugs.])],
 325 if test "${enableval}" != "no"; then
 326    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 327    [Define this to use a lisp union for the Lisp_Object data type.])
 328 fi)
 329
 330
 331 AC_ARG_ENABLE(profiling,
 332 [AS_HELP_STRING([--enable-profiling],
 333                 [build emacs with profiling support.
 334                  This might not work on all platforms])],
 335 [ac_enable_profiling="${enableval}"],[])
 336 if test x$ac_enable_profiling != x ; then
 337    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 338 else
 339    PROFILING_CFLAGS=
 340 fi
 341 AC_SUBST(PROFILING_CFLAGS)
 342
 343 AC_ARG_ENABLE(autodepend,
 344 [AS_HELP_STRING([--enable-autodepend],
 345                 [automatically generate dependencies to .h-files.
 346                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 347                  found])],
 348 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 349
 350 #### Make srcdir absolute, if it isn't already.  It's important to
 351 #### avoid running the path through pwd unnecessarily, since pwd can
 352 #### give you automounter prefixes, which can go away.  We do all this
 353 #### so Emacs can find its files when run uninstalled.
 354 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 355 unset CDPATH
 356 case "${srcdir}" in
 357   /* ) ;;
 358   . )
 359     ## We may be able to use the $PWD environment variable to make this
 360     ## absolute.  But sometimes PWD is inaccurate.
 361     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 362     ## but that tested only for a well-formed and valid PWD,
 363     ## it did not object when PWD was well-formed and valid but just wrong.
 364     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 365     then
 366       srcdir="$PWD"
 367     else
 368       srcdir="`(cd ${srcdir}; pwd)`"
 369     fi
 370   ;;
 371   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 372 esac
 373
 374 #### Given the configuration name, set machfile and opsysfile to the
 375 #### names of the m/*.h and s/*.h files we should use.
 376
 377 ### Canonicalize the configuration name.
 378
 379 AC_CANONICAL_HOST
 380 canonical=$host
 381 configuration=${host_alias-${build_alias-$host}}
 382
 383 dnl This used to use changequote, but, apart from `changequote is evil'
 384 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 385 dnl the great gob of text.  Thus it's not processed for possible expansion.
 386 dnl Just make sure the brackets remain balanced.
 387 dnl
 388 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 389 dnl indicated by comments.
 390 dnl quotation begins
 391 [
 392
 393 ### If you add support for a new configuration, add code to this
 394 ### switch statement to recognize your configuration name and select
 395 ### the appropriate operating system and machine description files.
 396
 397 ### You would hope that you could choose an m/*.h file pretty much
 398 ### based on the machine portion of the configuration name, and an s/*.h
 399 ### file based on the operating system portion.  However, it turns out
 400 ### that each m/*.h file is pretty manufacturer-specific - for
 401 ### example mips.h is MIPS
 402 ### So we basically have to have a special case for each
 403 ### configuration name.
 404 ###
 405 ### As far as handling version numbers on operating systems is
 406 ### concerned, make sure things will fail in a fixable way.  If
 407 ### /etc/MACHINES doesn't say anything about version numbers, be
 408 ### prepared to handle anything reasonably.  If version numbers
 409 ### matter, be sure /etc/MACHINES says something about it.
 410
 411 machine='' opsys='' unported=no
 412 case "${canonical}" in
 413
 414   ## GNU/Linux ports
 415   *-*-linux-gnu*)
 416     opsys=gnu-linux
 417     case ${canonical} in
 418       alpha*)   machine=alpha ;;
 419       s390-*)   machine=ibms390 ;;
 420       s390x-*)  machine=ibms390x ;;
 421       powerpc*) machine=macppc ;;
 422       sparc*)   machine=sparc ;;
 423       ia64*)    machine=ia64 ;;
 424       m68k*)    machine=m68k ;;
 425       x86_64*)  machine=amdx86-64 ;;
 426     esac
 427   ;;
 428
 429   ## FreeBSD ports
 430   *-*-freebsd* )
 431     opsys=freebsd
 432     case "${canonical}" in
 433       alpha*)           machine=alpha ;;
 434       amd64-*|x86_64-*) machine=amdx86-64 ;;
 435       ia64-*)           machine=ia64 ;;
 436       i[3456]86-*)      machine=intel386 ;;
 437       powerpc-*)        machine=macppc ;;
 438       sparc-*)          machine=sparc ;;
 439       sparc64-*)        machine=sparc ;;
 440     esac
 441   ;;
 442
 443   ## FreeBSD kernel + glibc based userland
 444   *-*-kfreebsd*gnu* )
 445     opsys=gnu-kfreebsd
 446     case "${canonical}" in
 447       alpha*)           machine=alpha ;;
 448       amd64-*|x86_64-*) machine=amdx86-64 ;;
 449       ia64-*)           machine=ia64 ;;
 450       i[3456]86-*)      machine=intel386 ;;
 451       powerpc-*)        machine=macppc ;;
 452       sparc-*)          machine=sparc ;;
 453       sparc64-*)        machine=sparc ;;
 454     esac
 455   ;;
 456
 457   ## NetBSD ports
 458   *-*-netbsd* )
 459     opsys=netbsd
 460     case "${canonical}" in
 461       alpha*)      machine=alpha ;;
 462       x86_64-*)    machine=amdx86-64 ;;
 463       i[3456]86-*) machine=intel386 ;;
 464       m68k-*)      machine=m68k ;;
 465       powerpc-*)   machine=macppc ;;
 466       sparc*-)     machine=sparc ;;
 467       vax-*)       machine=vax ;;
 468     esac
 469   ;;
 470
 471   ## OpenBSD ports
 472   *-*-openbsd* )
 473     opsys=openbsd
 474     case "${canonical}" in
 475       alpha*)    machine=alpha ;;
 476       x86_64-*)  machine=amdx86-64 ;;
 477       i386-*)    machine=intel386 ;;
 478       powerpc-*) machine=macppc ;;
 479       sparc*)    machine=sparc ;;
 480       vax-*)     machine=vax ;;
 481     esac
 482   ;;
 483
 484   ## Apple Darwin / Mac OS X
 485   *-apple-darwin* )
 486     case "${canonical}" in
 487       i[3456]86-* )  machine=intel386 ;;
 488       powerpc-* )    machine=macppc ;;
 489       x86_64-* )     machine=amdx86-64 ;;
 490       * )            unported=yes ;;
 491     esac
 492     opsys=darwin
 493     # Define CPP as follows to make autoconf work correctly.
 494     CPP="${CC-cc} -E -no-cpp-precomp"
 495     # Use fink packages if available.
 496     if test -d /sw/include && test -d /sw/lib; then
 497       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 498       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 499       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 500     fi
 501   ;;
 502
 503   ## HP 9000 series 700 and 800, running HP/UX
 504   hppa*-hp-hpux10.2* )
 505     opsys=hpux10-20
 506   ;;
 507   hppa*-hp-hpux1[1-9]* )
 508     opsys=hpux11
 509     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 510   ;;
 511
 512   ia64*-hp-hpux1[1-9]* )
 513     machine=hp800 opsys=hpux11
 514     ## FIXME.  Peter O'Gorman reports that dumping using unexelf.o doesn't
 515     ## work either: http://debbugs.gnu.org/cgi/bugreport.cgi?bug=6811
 516     CANNOT_DUMP=yes
 517   ;;
 518
 519   hppa*-*-linux-gnu* )
 520     machine=hp800 opsys=gnu-linux
 521   ;;
 522
 523   ## IBM machines
 524   rs6000-ibm-aix4.[23]* )
 525     machine=ibmrs6000 opsys=aix4-2
 526   ;;
 527   powerpc-ibm-aix4.[23]*  )
 528     machine=ibmrs6000 opsys=aix4-2
 529   ;;
 530   rs6000-ibm-aix[56]* )
 531     machine=ibmrs6000 opsys=aix4-2
 532   ;;
 533   powerpc-ibm-aix[56]*  )
 534     machine=ibmrs6000 opsys=aix4-2
 535   ;;
 536
 537   ## Silicon Graphics machines
 538   ## Iris 4D
 539   mips-sgi-irix6.5 )
 540     opsys=irix6-5
 541     # Without defining _LANGUAGE_C, things get masked out in the headers
 542     # so that, for instance, grepping for `free' in stdlib.h fails and
 543     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 544     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 545     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 546   ;;
 547
 548   ## Suns
 549   *-sun-solaris* \
 550     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 551     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 552     case "${canonical}" in
 553       i[3456]86-*-* )     machine=intel386 ;;
 554       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 555       sparc* )          machine=sparc ;;
 556       * )               unported=yes ;;
 557     esac
 558     case "${canonical}" in
 559       *-sunos5.6* | *-solaris2.6* )
 560                 opsys=sol2-6
 561                 NON_GNU_CPP=/usr/ccs/lib/cpp
 562                 RANLIB="ar -ts"
 563                 ;;
 564       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 565                 opsys=sol2-6
 566                 emacs_check_sunpro_c=yes
 567                 NON_GNU_CPP=/usr/ccs/lib/cpp
 568                 ;;
 569       *-sunos5* | *-solaris* )
 570                 opsys=sol2-10
 571                 emacs_check_sunpro_c=yes
 572                 NON_GNU_CPP=/usr/ccs/lib/cpp
 573                 ;;
 574     esac
 575     ## Watch out for a compiler that we know will not work.
 576     case "${canonical}" in
 577      *-solaris* | *-sunos5* )
 578                 if [ "x$CC" = x/usr/ucb/cc ]; then
 579                   ## /usr/ucb/cc doesn't work;
 580                   ## we should find some other compiler that does work.
 581                   unset CC
 582                 fi
 583                 ;;
 584       *) ;;
 585     esac
 586   ;;
 587
 588   ## Intel 386 machines where we don't care about the manufacturer.
 589   i[3456]86-*-* )
 590     machine=intel386
 591     case "${canonical}" in
 592       *-cygwin )                opsys=cygwin ;;
 593       *-darwin* )               opsys=darwin
 594                                 CPP="${CC-cc} -E -no-cpp-precomp"
 595                                 ;;
 596       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 597       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 598       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 599       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 600     esac
 601   ;;
 602
 603   * )
 604     unported=yes
 605   ;;
 606 esac
 607
 608 ### If the code above didn't choose an operating system, just choose
 609 ### an operating system based on the configuration name.  You really
 610 ### only want to use this when you have no idea what the right
 611 ### operating system is; if you know what operating systems a machine
 612 ### runs, it's cleaner to make it explicit in the case statement
 613 ### above.
 614 if test x"${opsys}" = x; then
 615   case "${canonical}" in
 616     *-gnu* )                            opsys=gnu ;;
 617     * )
 618       unported=yes
 619     ;;
 620   esac
 621 fi
 622
 623 ]
 624 dnl quotation ends
 625
 626 if test $unported = yes; then
 627   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 628 Check `etc/MACHINES' for recognized configuration names.])
 629 fi
 630
 631 if test -n "$machine"; then
 632   machfile="m/${machine}.h"
 633 else
 634   machfile=
 635 fi
 636 opsysfile="s/${opsys}.h"
 637
 638
 639 #### Choose a compiler.
 640 test -n "$CC" && cc_specified=yes
 641
 642 # Save the value of CFLAGS that the user specified.
 643 SPECIFIED_CFLAGS="$CFLAGS"
 644
 645 dnl Sets GCC=yes if using gcc.
 646 AC_PROG_CC
 647 AM_PROG_CC_C_O
 648
 649 # Initialize gnulib right after verifying that the C compiler works.
 650 gl_EARLY
 651
 652 # On Suns, sometimes $CPP names a directory.
 653 if test -n "$CPP" && test -d "$CPP"; then
 654   CPP=
 655 fi
 656
 657 ## If not using gcc, and on Solaris, and no CPP specified, see if
 658 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 659 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 660  test x"$CPP" = x; then
 661   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 662   AC_CACHE_VAL(emacs_cv_sunpro_c,
 663   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
 664 [[#ifndef __SUNPRO_C
 665 fail;
 666 #endif
 667 ]])], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 668   AC_MSG_RESULT($emacs_cv_sunpro_c)
 669
 670   if test x"$emacs_cv_sunpro_c" = xyes; then
 671     NON_GNU_CPP="$CC -E -Xs"
 672   fi
 673 fi
 674
 675 #### Some systems specify a CPP to use unless we are using GCC.
 676 #### Now that we know whether we are using GCC, we can decide whether
 677 #### to use that one.
 678 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 679 then
 680   CPP="$NON_GNU_CPP"
 681 fi
 682
 683 #### Some systems specify a CC to use unless we are using GCC.
 684 #### Now that we know whether we are using GCC, we can decide whether
 685 #### to use that one.
 686 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 687   test x$cc_specified != xyes
 688 then
 689   CC="$NON_GNU_CC"
 690 fi
 691
 692 if test x$GCC = xyes; then
 693   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 694 else
 695   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 696 fi
 697
 698 ### Use -Wdeclaration-after-statement if the compiler supports it
 699 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 700 SAVE_CFLAGS="$CFLAGS"
 701 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 702 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 703 if test $has_option = yes; then
 704    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 705 fi
 706 AC_MSG_RESULT($has_option)
 707 CFLAGS="$SAVE_CFLAGS"
 708 unset has_option
 709 unset SAVE_CFLAGS
 710
 711 ### Use -Wold-style-definition if the compiler supports it
 712 # This can be removed when conversion to standard C is finished.
 713 AC_MSG_CHECKING([whether gcc understands -Wold-style-definition])
 714 SAVE_CFLAGS="$CFLAGS"
 715 CFLAGS="$CFLAGS -Wold-style-definition"
 716 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 717 if test $has_option = yes; then
 718    C_WARNINGS_SWITCH="-Wold-style-definition $C_WARNINGS_SWITCH"
 719 fi
 720 AC_MSG_RESULT($has_option)
 721 CFLAGS="$SAVE_CFLAGS"
 722 unset has_option
 723 unset SAVE_CFLAGS
 724
 725 ### Use -Wimplicit-function-declaration if the compiler supports it
 726 AC_MSG_CHECKING([whether gcc understands -Wimplicit-function-declaration])
 727 SAVE_CFLAGS="$CFLAGS"
 728 CFLAGS="$CFLAGS -Wimplicit-function-declaration"
 729 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], has_option=yes, has_option=no)
 730 if test $has_option = yes; then
 731    C_WARNINGS_SWITCH="-Wimplicit-function-declaration $C_WARNINGS_SWITCH"
 732 fi
 733 AC_MSG_RESULT($has_option)
 734 CFLAGS="$SAVE_CFLAGS"
 735 unset has_option
 736 unset SAVE_CFLAGS
 737
 738 AC_SUBST(C_WARNINGS_SWITCH)
 739
 740
 741 #### Some other nice autoconf tests.
 742
 743 dnl checks for programs
 744 AC_PROG_CPP
 745 AC_PROG_INSTALL
 746 if test "x$RANLIB" = x; then
 747   AC_PROG_RANLIB
 748 fi
 749
 750 ## Although we're running on an amd64 kernel, we're actually compiling for
 751 ## the x86 architecture.  The user should probably have provided an
 752 ## explicit --build to `configure', but if everything else than the kernel
 753 ## is running in i386 mode, we can help them out.
 754 if test "$machine" = "amdx86-64"; then
 755   AC_CHECK_DECL([i386])
 756   if test "$ac_cv_have_decl_i386" = "yes"; then
 757     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 758     machine=intel386
 759     machfile="m/${machine}.h"
 760   fi
 761 fi
 762
 763 AC_PATH_PROG(INSTALL_INFO, install-info)
 764 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 765 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 766 dnl Don't use GZIP, which is used by gzip for additional parameters.
 767 AC_PATH_PROG(GZIP_PROG, gzip)
 768
 769
 770 ## Need makeinfo >= 4.6 (?) to build the manuals.
 771 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 772 dnl By this stage, configure has already checked for egrep and set EGREP,
 773 dnl or exited with an error if no egrep was found.
 774 if test "$MAKEINFO" != "no" && \
 775   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 776    MAKEINFO=no
 777 fi
 778
 779 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 780 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 781 ## therefore in the category of "special tools" not normally required, which
 782 ## configure does not have to check for (eg autoconf itself).
 783 ## In a Bazaar checkout on the other hand, the manuals are not included.
 784 ## So makeinfo is a requirement to build from Bazaar, and configure
 785 ## should test for it as it does for any other build requirement.
 786 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 787 ## with pre-built manuals, from a Bazaar checkout.
 788 HAVE_MAKEINFO=yes
 789
 790 if test "$MAKEINFO" = "no"; then
 791   MAKEINFO=makeinfo
 792   if test "x${with_makeinfo}" = "xno"; then
 793     HAVE_MAKEINFO=no
 794   elif test ! -e $srcdir/info/emacs; then
 795     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 796 source tree does not seem to have pre-built manuals in the `info' directory.
 797 Either install a suitable version of makeinfo, or re-run configure
 798 with the `--without-makeinfo' option to build without the manuals.] )
 799   fi
 800 fi
 801 AC_SUBST(HAVE_MAKEINFO)
 802
 803 dnl Add our options to ac_link now, after it is set up.
 804
 805 if test x$GCC = xyes; then
 806   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 807     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 808 else
 809   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 810     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 811 fi
 812
 813 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 814 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 815 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 816 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 817 dnl if not built to support GNU ld.
 818
 819 late_LDFLAGS=$LDFLAGS
 820 if test x$GCC = xyes; then
 821   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 822 else
 823   LDFLAGS="$LDFLAGS -znocombreloc"
 824 fi
 825
 826 AC_MSG_CHECKING([for -znocombreloc])
 827 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 828   [AC_MSG_RESULT(yes)],
 829   LDFLAGS=$late_LDFLAGS
 830   [AC_MSG_RESULT(no)])
 831
 832
 833 # The value of CPP is a quoted variable reference, so we need to do this
 834 # to get its actual value...
 835 CPP=`eval "echo $CPP"`
 836
 837
 838 dnl The function dump-emacs will not be defined and temacs will do
 839 dnl (load "loadup") automatically unless told otherwise.
 840 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 841 case "$opsys" in
 842   your-opsys-here) CANNOT_DUMP=yes ;;
 843 esac
 844
 845 test "$CANNOT_DUMP" = "yes" && \
 846   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 847
 848 AC_SUBST(CANNOT_DUMP)
 849
 850
 851 UNEXEC_OBJ=unexelf.o
 852 case "$opsys" in
 853   # MSDOS uses unexcoff.o
 854   # MSWindows uses unexw32.o
 855   aix4-2)
 856    UNEXEC_OBJ=unexaix.o
 857    ;;
 858   cygwin)
 859    UNEXEC_OBJ=unexcw.o
 860    ;;
 861   darwin)
 862    UNEXEC_OBJ=unexmacosx.o
 863    ;;
 864   hpux10-20 | hpux11)
 865    UNEXEC_OBJ=unexhp9k800.o
 866    ;;
 867   sol2-10)
 868    # Use the Solaris dldump() function, called from unexsol.c, to dump
 869    # emacs, instead of the generic ELF dump code found in unexelf.c.
 870    # The resulting binary has a complete symbol table, and is better
 871    # for debugging and other observability tools (debuggers, pstack, etc).
 872    #
 873    # If you encounter a problem using dldump(), please consider sending
 874    # a message to the OpenSolaris tools-linking mailing list:
 875    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 876    #
 877    # It is likely that dldump() works with older Solaris too, but this has
 878    # not been tested, so for now this change is for Solaris 10 or newer.
 879    UNEXEC_OBJ=unexsol.o
 880    ;;
 881 esac
 882
 883 LD_SWITCH_SYSTEM=
 884 case "$opsys" in
 885   freebsd)
 886    ## Let `ld' find image libs and similar things in /usr/local/lib.
 887    ## The system compiler, GCC, has apparently been modified to not
 888    ## look there, contrary to what a stock GCC would do.
 889    LD_SWITCH_SYSTEM=-L/usr/local/lib
 890    ;;
 891
 892   gnu-linux)
 893    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 894    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 895    ;;
 896
 897   netbsd)
 898    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 899    ;;
 900
 901   openbsd)
 902    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 903    ## otherwise Emacs dumps core on elf systems.
 904    LD_SWITCH_SYSTEM="-Z"
 905    ;;
 906 esac
 907 AC_SUBST(LD_SWITCH_SYSTEM)
 908
 909 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 910
 911 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 912 ## which has not been defined yet.  When this was handled with cpp,
 913 ## it was expanded to null when configure sourced the s/*.h file.
 914 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 915 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 916 ## (or somesuch), but because it is supposed to go at the _front_
 917 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 918 ## Compare with the gnu-linux case below, which added to the end
 919 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 920 ## LD_SWITCH_SYSTEM_TEMACS.
 921 case "$opsys" in
 922   netbsd|openbsd)
 923    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 924    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 925 esac
 926
 927
 928 C_SWITCH_MACHINE=
 929 if test "$machine" = "alpha"; then
 930   AC_CHECK_DECL([__ELF__])
 931   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 932     ## With ELF, make sure that all common symbols get allocated to in the
 933     ## data section.  Otherwise, the dump of temacs may miss variables in
 934     ## the shared library that have been initialized.  For example, with
 935     ## GNU libc, __malloc_initialized would normally be resolved to the
 936     ## shared library's .bss section, which is fatal.
 937     if test "x$GCC" = "xyes"; then
 938       C_SWITCH_MACHINE="-fno-common"
 939     else
 940       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 941     fi
 942   else
 943     UNEXEC_OBJ=unexalpha.o
 944   fi
 945 fi
 946 AC_SUBST(C_SWITCH_MACHINE)
 947
 948 AC_SUBST(UNEXEC_OBJ)
 949
 950 C_SWITCH_SYSTEM=
 951 ## Some programs in src produce warnings saying certain subprograms
 952 ## are too complex and need a MAXMEM value greater than 2000 for
 953 ## additional optimization.  --nils@exp-math.uni-essen.de
 954 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 955   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 956 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 957 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 958 AC_SUBST(C_SWITCH_SYSTEM)
 959
 960
 961 LIBS_SYSTEM=
 962 case "$opsys" in
 963   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 964   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 965
 966   freebsd) LIBS_SYSTEM="-lutil" ;;
 967
 968   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 969
 970   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 971
 972   ## Motif needs -lgen.
 973   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 974 esac
 975 AC_SUBST(LIBS_SYSTEM)
 976
 977
 978 ### Make sure subsequent tests use flags consistent with the build flags.
 979
 980 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 981   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 982 else
 983   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 984 fi
 985
 986 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 987 AC_DEFUN([AC_TYPE_SIZE_T])
 988 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
 989 AC_DEFUN([AC_TYPE_UID_T])
 990
 991 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 992 AC_SYS_LARGEFILE
 993
 994
 995 LIB_MATH=-lm
 996 LIB_STANDARD=
 997 START_FILES=
 998
 999 case $opsys in
1000   cygwin )
1001     LIB_MATH=
1002     START_FILES='pre-crt0.o'
1003     ;;
1004   darwin )
1005     ## Adding -lm confuses the dynamic linker, so omit it.
1006     LIB_MATH=
1007     START_FILES='pre-crt0.o'
1008     ;;
1009   freebsd )
1010     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1011     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1012     ;;
1013   gnu-linux | gnu-kfreebsd )
1014     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1015     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1016     ;;
1017   hpux10-20 | hpux11 )
1018     LIB_STANDARD=-lc
1019     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1020     ;;
1021   netbsd | openbsd )
1022     if test -f $CRT_DIR/crti.o; then
1023         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1024         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1025     else
1026         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1027         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1028     fi
1029     ;;
1030 esac
1031
1032 AC_SUBST(LIB_MATH)
1033 AC_SUBST(START_FILES)
1034
1035 dnl Not all platforms use crtn.o files.  Check if the current one does.
1036 crt_files=
1037
1038 for file in x $LIB_STANDARD $START_FILES; do
1039   case "$file" in
1040     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1041   esac
1042 done
1043
1044 if test "x$crt_files" != x; then
1045
1046   ## If user specified a crt-dir, use that unconditionally.
1047   crt_gcc=no
1048
1049   if test "X$CRT_DIR" = "X"; then
1050
1051     CRT_DIR=/usr/lib            # default
1052
1053     case "$canonical" in
1054       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1055       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1056       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1057       ## For anything else (eg /usr/lib32), it is up the user to specify
1058       ## the location (bug#5655).
1059       ## Test for crtn.o, not just the directory, because sometimes the
1060       ## directory exists but does not have the relevant files (bug#1287).
1061       ## FIXME better to test for binary compatibility somehow.
1062       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1063       ;;
1064
1065       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1066     esac
1067
1068     case "$opsys" in
1069       hpux10-20) CRT_DIR=/lib ;;
1070     esac
1071
1072     test "x${GCC}" = xyes && crt_gcc=yes
1073
1074   fi                            # CRT_DIR = ""
1075
1076   crt_missing=
1077
1078   for file in $crt_files; do
1079
1080     ## If we're using gcc, try to determine it automatically by asking
1081     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1082     ## system-dependent default from above.]
1083     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1084
1085        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1086        case "$crt_file" in
1087          */*)
1088            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1089            ;;
1090        esac
1091     fi
1092
1093     dnl We expect all the files to be in a single directory, so after the
1094     dnl first there is no point asking gcc.
1095     crt_gcc=no
1096
1097     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1098   done                          # $crt_files
1099
1100   test "x$crt_missing" = x || \
1101     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1102 Try using the --with-crt-dir option.])
1103
1104 fi                              # crt_files != ""
1105
1106 AC_SUBST(CRT_DIR)
1107
1108
1109 dnl This function definition taken from Gnome 2.0
1110 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1111 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1112 dnl also defines GSTUFF_PKG_ERRORS on error
1113 AC_DEFUN([PKG_CHECK_MODULES], [
1114   succeeded=no
1115
1116   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1117
1118   if test "$PKG_CONFIG" = "no" ; then
1119      ifelse([$4], , [AC_MSG_ERROR([
1120       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1121   else
1122      PKG_CONFIG_MIN_VERSION=0.9.0
1123      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1124         AC_MSG_CHECKING(for $2)
1125
1126         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1127             AC_MSG_RESULT(yes)
1128             succeeded=yes
1129
1130             AC_MSG_CHECKING($1_CFLAGS)
1131             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1132             AC_MSG_RESULT($$1_CFLAGS)
1133
1134             AC_MSG_CHECKING($1_LIBS)
1135             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1136             AC_MSG_RESULT($$1_LIBS)
1137         else
1138             AC_MSG_RESULT(no)
1139             $1_CFLAGS=""
1140             $1_LIBS=""
1141             ## If we have a custom action on failure, don't print errors, but
1142             ## do set a variable so people can do so.
1143             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1144             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1145         fi
1146
1147         AC_SUBST($1_CFLAGS)
1148         AC_SUBST($1_LIBS)
1149      else
1150         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1151         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1152      fi
1153   fi
1154
1155   if test $succeeded = yes; then
1156      ifelse([$3], , :, [$3])
1157   else
1158      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1159   fi
1160 ])
1161
1162
1163 if test "${with_sound}" != "no"; then
1164   # Sound support for GNU/Linux and the free BSDs.
1165   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1166     have_sound_header=yes)
1167   # Emulation library used on NetBSD.
1168   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1169   AC_SUBST(LIBSOUND)
1170
1171   ALSA_REQUIRED=1.0.0
1172   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1173   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1174   if test $HAVE_ALSA = yes; then
1175     SAVE_CFLAGS="$CFLAGS"
1176     SAVE_LDFLAGS="$LDFLAGS"
1177     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1178     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1179     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1180                     emacs_alsa_normal=yes,
1181                     emacs_alsa_normal=no)
1182     if test "$emacs_alsa_normal" != yes; then
1183       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1184                      [[snd_lib_error_set_handler (0);]])],
1185                      emacs_alsa_subdir=yes,
1186                      emacs_alsa_subdir=no)
1187       if test "$emacs_alsa_subdir" != yes; then
1188         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1189       fi
1190       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1191     fi
1192
1193     CFLAGS="$SAVE_CFLAGS"
1194     LDFLAGS="$SAVE_LDFLAGS"
1195     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1196     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1197     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1198   fi
1199
1200   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1201   dnl compiles only on the specified platforms.  For others, it
1202   dnl probably doesn't make sense to try.
1203   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1204      case "$opsys" in
1205        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1206        gnu-linux|freebsd|netbsd)
1207          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1208          ;;
1209      esac
1210   fi
1211
1212   AC_SUBST(CFLAGS_SOUND)
1213 fi
1214
1215 dnl checks for header files
1216 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1217   linux/version.h sys/systeminfo.h limits.h \
1218   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1219   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1220   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1221
1222 AC_MSG_CHECKING(if personality LINUX32 can be set)
1223 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1224                emacs_cv_personality_linux32=yes,
1225                emacs_cv_personality_linux32=no)
1226 AC_MSG_RESULT($emacs_cv_personality_linux32)
1227
1228 if test $emacs_cv_personality_linux32 = yes; then
1229   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1230             [Define to 1 if personality LINUX32 can be set.])
1231 fi
1232
1233 dnl On Solaris 8 there's a compilation warning for term.h because
1234 dnl it doesn't define `bool'.
1235 AC_CHECK_HEADERS(term.h, , , -)
1236 AC_HEADER_STDC
1237 AC_HEADER_TIME
1238 AC_CHECK_DECLS([sys_siglist])
1239 if test $ac_cv_have_decl_sys_siglist != yes; then
1240   # For Tru64, at least:
1241   AC_CHECK_DECLS([__sys_siglist])
1242   if test $ac_cv_have_decl___sys_siglist = yes; then
1243     AC_DEFINE(sys_siglist, __sys_siglist,
1244               [Define to any substitute for sys_siglist.])
1245   fi
1246 fi
1247 AC_HEADER_SYS_WAIT
1248
1249 dnl Some systems have utime.h but don't declare the struct anyplace.
1250 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1251 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1252 #include <sys/time.h>
1253 #include <time.h>
1254 #else
1255 #ifdef HAVE_SYS_TIME_H
1256 #include <sys/time.h>
1257 #else
1258 #include <time.h>
1259 #endif
1260 #endif
1261 #ifdef HAVE_UTIME_H
1262 #include <utime.h>
1263 #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])],
1264   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1265 if test $emacs_cv_struct_utimbuf = yes; then
1266   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1267 fi
1268
1269 dnl Check for speed_t typedef.
1270 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1271   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1272     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1273 if test $emacs_cv_speed_t = yes; then
1274   AC_DEFINE(HAVE_SPEED_T, 1,
1275            [Define to 1 if `speed_t' is declared by <termios.h>.])
1276 fi
1277
1278 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1279 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1280 #include <sys/time.h>
1281 #include <time.h>
1282 #else
1283 #ifdef HAVE_SYS_TIME_H
1284 #include <sys/time.h>
1285 #else
1286 #include <time.h>
1287 #endif
1288 #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
1289   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1290 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1291 if test $emacs_cv_struct_timeval = yes; then
1292   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1293 fi
1294
1295 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1296 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1297 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1298   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1299 HAVE_EXCEPTION=$emacs_cv_struct_exception
1300 if test $emacs_cv_struct_exception != yes; then
1301   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1302 fi
1303
1304 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1305 #if HAVE_SYS_SOCKET_H
1306 #include <sys/socket.h>
1307 #endif])
1308
1309 dnl checks for structure members
1310 AC_STRUCT_TM
1311 AC_STRUCT_TIMEZONE
1312 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1313                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1314                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1315                 [#include <time.h>])
1316 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1317                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1318                   struct ifreq.ifr_addr], , ,
1319                  [AC_INCLUDES_DEFAULT
1320 #if HAVE_SYS_SOCKET_H
1321 #include <sys/socket.h>
1322 #endif
1323 #if HAVE_NET_IF_H
1324 #include <net/if.h>
1325 #endif])
1326
1327 dnl checks for compiler characteristics
1328
1329 dnl Testing __STDC__ to determine prototype support isn't good enough.
1330 dnl DEC C, for instance, doesn't define it with default options, and
1331 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1332 dnl and void *.
1333 AC_C_PROTOTYPES
1334 AC_C_VOLATILE
1335 AC_C_CONST
1336 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1337   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[void * foo;]])],
1338                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1339 if test $emacs_cv_void_star = yes; then
1340   AC_DEFINE(POINTER_TYPE, void)
1341 else
1342   AC_DEFINE(POINTER_TYPE, char)
1343 fi
1344 AH_TEMPLATE(POINTER_TYPE,
1345             [Define as `void' if your compiler accepts `void *'; otherwise
1346              define as `char'.])dnl
1347
1348 dnl Check for endianess
1349 AC_C_BIGENDIAN
1350
1351 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1352   [emacs_cv_attribute_aligned],
1353   [AC_COMPILE_IFELSE(
1354      [AC_LANG_PROGRAM(
1355         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1356         [[]])],
1357      [emacs_cv_attribute_aligned=yes],
1358      [emacs_cv_attribute_aligned=no])])
1359 if test $emacs_cv_attribute_aligned = yes; then
1360   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1361     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1362 fi
1363
1364 dnl check for Make feature
1365 AC_PROG_MAKE_SET
1366
1367 DEPFLAGS=
1368 MKDEPDIR=":"
1369 deps_frag=deps.mk
1370 dnl check for GNU Make if we have GCC and autodepend is on.
1371 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1372    AC_MSG_CHECKING([whether we are using GNU Make])
1373    HAVE_GNU_MAKE=no
1374    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1375    if test "x$testval" != x; then
1376       HAVE_GNU_MAKE=yes
1377    else
1378       ac_enable_autodepend=no
1379    fi
1380    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1381    if test $HAVE_GNU_MAKE = yes; then
1382       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1383       SAVE_CFLAGS="$CFLAGS"
1384       CFLAGS="$CFLAGS -MMD -MF deps.d"
1385       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1386       CFLAGS="$SAVE_CFLAGS"
1387       test -f deps.d || ac_enable_autodepend=no
1388       rm -rf deps.d
1389       AC_MSG_RESULT([$ac_enable_autodepend])
1390    fi
1391    if test $ac_enable_autodepend = yes; then
1392       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1393       ## In parallel builds, another make might create depdir between
1394       ## the first test and mkdir, so stick another test on the end.
1395       ## Or use install-sh -d?  mkdir -p is not portable.
1396       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1397       deps_frag=autodeps.mk
1398    fi
1399 fi
1400 deps_frag=$srcdir/src/$deps_frag
1401 AC_SUBST(MKDEPDIR)
1402 AC_SUBST(DEPFLAGS)
1403 AC_SUBST_FILE(deps_frag)
1404
1405
1406 lisp_frag=$srcdir/src/lisp.mk
1407 AC_SUBST_FILE(lisp_frag)
1408
1409
1410 dnl checks for operating system services
1411 AC_SYS_LONG_FILE_NAMES
1412
1413 #### Choose a window system.
1414
1415 AC_PATH_X
1416 if test "$no_x" = yes; then
1417   window_system=none
1418 else
1419   window_system=x11
1420 fi
1421
1422 ## Workaround for bug in autoconf <= 2.62.
1423 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1424 ## No need to do anything special for these standard directories.
1425 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1426
1427    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1428
1429 fi
1430
1431 LD_SWITCH_X_SITE_AUX=
1432 LD_SWITCH_X_SITE_AUX_RPATH=
1433 if test "${x_libraries}" != NONE; then
1434   if test -n "${x_libraries}"; then
1435     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1436     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1437     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1438   fi
1439   x_default_search_path=""
1440   x_search_path=${x_libraries}
1441   if test -z "${x_search_path}"; then
1442     x_search_path=/usr/lib
1443   fi
1444   for x_library in `echo ${x_search_path}: | \
1445                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1446     x_search_path="\
1447 ${x_library}/X11/%L/%T/%N%C%S:\
1448 ${x_library}/X11/%l/%T/%N%C%S:\
1449 ${x_library}/X11/%T/%N%C%S:\
1450 ${x_library}/X11/%L/%T/%N%S:\
1451 ${x_library}/X11/%l/%T/%N%S:\
1452 ${x_library}/X11/%T/%N%S"
1453     if test x"${x_default_search_path}" = x; then
1454       x_default_search_path=${x_search_path}
1455     else
1456       x_default_search_path="${x_search_path}:${x_default_search_path}"
1457     fi
1458   done
1459 fi
1460 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1461 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1462
1463 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1464   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1465 fi
1466
1467 if test x"${x_includes}" = x; then
1468   bitmapdir=/usr/include/X11/bitmaps
1469 else
1470   # accumulate include directories that have X11 bitmap subdirectories
1471   bmd_acc="dummyval"
1472   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1473     if test -d "${bmd}/X11/bitmaps"; then
1474       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1475     fi
1476     if test -d "${bmd}/bitmaps"; then
1477       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1478     fi
1479   done
1480   if test ${bmd_acc} != "dummyval"; then
1481     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1482   fi
1483 fi
1484
1485 HAVE_NS=no
1486 NS_IMPL_COCOA=no
1487 NS_IMPL_GNUSTEP=no
1488 tmp_CPPFLAGS="$CPPFLAGS"
1489 tmp_CFLAGS="$CFLAGS"
1490 CPPFLAGS="$CPPFLAGS -x objective-c"
1491 CFLAGS="$CFLAGS -x objective-c"
1492 TEMACS_LDFLAGS2="\${LDFLAGS}"
1493 dnl I don't think it's especially important, but src/Makefile.in
1494 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1495 dnl trailing "/" to it, so now we do it here.
1496 if test "${with_ns}" != no; then
1497   if test "${opsys}" = darwin; then
1498      NS_IMPL_COCOA=yes
1499      ns_appdir=`pwd`/nextstep/Emacs.app
1500      ns_appbindir=${ns_appdir}/Contents/MacOS/
1501      ns_appresdir=${ns_appdir}/Contents/Resources
1502      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1503   elif test -f $GNUSTEP_CONFIG_FILE; then
1504      NS_IMPL_GNUSTEP=yes
1505      ns_appdir=`pwd`/nextstep/Emacs.app
1506      ns_appbindir=${ns_appdir}/
1507      ns_appresdir=${ns_appdir}/Resources
1508      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1509      dnl FIXME sourcing this several times in subshells seems inefficient.
1510      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1511      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1512      dnl I seemed to need these as well with GNUstep-startup 0.25.
1513      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1514      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1515      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1516        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1517      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1518        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1519      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1520      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1521      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1522      LIB_STANDARD=
1523      START_FILES=
1524      TEMACS_LDFLAGS2=
1525   fi
1526   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1527                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1528   files are missing or cannot be compiled.])])
1529   NS_HAVE_NSINTEGER=yes
1530   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1531                                      [NSInteger i;])],
1532                     ns_have_nsinteger=yes,
1533                     ns_have_nsinteger=no)
1534   if test $ns_have_nsinteger = no; then
1535     NS_HAVE_NSINTEGER=no
1536   fi
1537 fi
1538 AC_SUBST(TEMACS_LDFLAGS2)
1539
1540 ns_frag=/dev/null
1541 NS_OBJ=
1542 NS_OBJC_OBJ=
1543 if test "${HAVE_NS}" = yes; then
1544   window_system=nextstep
1545   with_xft=no
1546   # set up packaging dirs
1547   exec_prefix=${ns_appbindir}
1548   libexecdir=${ns_appbindir}/libexec
1549   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1550      prefix=${ns_appresdir}
1551   fi
1552   ns_frag=$srcdir/src/ns.mk
1553   NS_OBJ="fontset.o fringe.o image.o"
1554   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1555 fi
1556 CFLAGS="$tmp_CFLAGS"
1557 CPPFLAGS="$tmp_CPPFLAGS"
1558 AC_SUBST(NS_OBJ)
1559 AC_SUBST(NS_OBJC_OBJ)
1560 AC_SUBST(LIB_STANDARD)
1561 AC_SUBST_FILE(ns_frag)
1562
1563 case "${window_system}" in
1564   x11 )
1565     HAVE_X_WINDOWS=yes
1566     HAVE_X11=yes
1567     case "${with_x_toolkit}" in
1568       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1569       motif ) USE_X_TOOLKIT=MOTIF ;;
1570       gtk ) with_gtk=yes
1571 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1572 dnl USE_X_TOOLKIT is set.
1573             USE_X_TOOLKIT=none ;;
1574       gtk3 ) with_gtk3=yes
1575              USE_X_TOOLKIT=none ;;
1576       no ) USE_X_TOOLKIT=none ;;
1577 dnl If user did not say whether to use a toolkit, make this decision later:
1578 dnl use the toolkit if we have gtk, or X11R5 or newer.
1579       * ) USE_X_TOOLKIT=maybe ;;
1580     esac
1581   ;;
1582   nextstep | none )
1583     HAVE_X_WINDOWS=no
1584     HAVE_X11=no
1585     USE_X_TOOLKIT=none
1586   ;;
1587 esac
1588
1589 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1590    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1591    if test "$HAVE_XSERVER" = true ||
1592       test -n "$DISPLAY" ||
1593       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1594         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1595 were found.  You should install the relevant development files for X
1596 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1597 sure you have development files for image handling, i.e.
1598 tiff, gif, jpeg, png and xpm.
1599 If you are sure you want Emacs compiled without X window support, pass
1600   --without-x
1601 to configure.])
1602    fi
1603 fi
1604
1605 ### If we're using X11, we should use the X menu package.
1606 HAVE_MENUS=no
1607 case ${HAVE_X11} in
1608   yes ) HAVE_MENUS=yes ;;
1609 esac
1610
1611 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1612 # Assume not, until told otherwise.
1613 GNU_MALLOC=yes
1614 doug_lea_malloc=yes
1615 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1616 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1617 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1618                emacs_cv_var___after_morecore_hook,
1619 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern void (* __after_morecore_hook)();]],[[__after_morecore_hook = 0]])],
1620   emacs_cv_var___after_morecore_hook=yes,
1621   emacs_cv_var___after_morecore_hook=no)])
1622 if test $emacs_cv_var___after_morecore_hook = no; then
1623   doug_lea_malloc=no
1624 fi
1625
1626
1627 dnl See comments in aix4-2.h about maybe using system malloc there.
1628 system_malloc=no
1629 case "$opsys" in
1630   ## darwin ld insists on the use of malloc routines in the System framework.
1631   darwin|sol2-10) system_malloc=yes ;;
1632 esac
1633
1634 if test "${system_malloc}" = "yes"; then
1635   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1636   GNU_MALLOC=no
1637   GNU_MALLOC_reason="
1638     (The GNU allocators don't work with this system configuration.)"
1639   GMALLOC_OBJ=
1640   VMLIMIT_OBJ=
1641 else
1642   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1643   VMLIMIT_OBJ=vm-limit.o
1644 fi
1645 AC_SUBST(GMALLOC_OBJ)
1646 AC_SUBST(VMLIMIT_OBJ)
1647
1648 if test "$doug_lea_malloc" = "yes" ; then
1649   if test "$GNU_MALLOC" = yes ; then
1650     GNU_MALLOC_reason="
1651       (Using Doug Lea's new malloc from the GNU C Library.)"
1652   fi
1653   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1654             [Define to 1 if you are using the GNU C Library.])
1655
1656   ## Use mmap directly for allocating larger buffers.
1657   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1658   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1659   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1660   case "$opsys" in
1661     gnu*) REL_ALLOC=no ;;
1662   esac
1663 fi
1664
1665 if test x"${REL_ALLOC}" = x; then
1666   REL_ALLOC=${GNU_MALLOC}
1667 fi
1668
1669 use_mmap_for_buffers=no
1670 case "$opsys" in
1671   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1672 esac
1673
1674 AC_FUNC_MMAP
1675 if test $use_mmap_for_buffers = yes; then
1676   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1677   REL_ALLOC=no
1678 fi
1679
1680 LIBS="$LIBS_SYSTEM $LIBS"
1681
1682 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1683 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1684 AC_CHECK_LIB(dnet, dnet_ntoa)
1685 dnl This causes -lresolv to get used in subsequent tests,
1686 dnl which causes failures on some systems such as HPUX 9.
1687 dnl AC_CHECK_LIB(resolv, gethostbyname)
1688
1689 dnl FIXME replace main with a function we actually want from this library.
1690 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1691
1692 AC_CHECK_LIB(pthreads, cma_open)
1693
1694 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1695 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1696 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1697 ## added to LIBS in configure would never contain the pthreads part,
1698 ## but the value used in Makefiles might.  FIXME?
1699 ##
1700 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1701 ## be harmless on older versions of X where it happens to exist.
1702 test "$opsys" = "aix4-2" && \
1703   test $ac_cv_lib_pthreads_cma_open = yes && \
1704   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1705
1706 dnl Check for need for bigtoc support on IBM AIX
1707
1708 case ${host_os} in
1709 aix*)
1710   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1711     case $GCC in
1712     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1713     *) gdb_cv_bigtoc=-bbigtoc ;;
1714     esac
1715
1716     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1717     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1718   ])
1719   ;;
1720 esac
1721
1722 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1723 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1724 # REAL_CPPFLAGS later on.
1725
1726 REAL_CFLAGS="$CFLAGS"
1727 REAL_CPPFLAGS="$CPPFLAGS"
1728
1729 if test "${HAVE_X11}" = "yes"; then
1730   DEFS="$C_SWITCH_X_SITE $DEFS"
1731   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1732   LIBS="-lX11 $LIBS"
1733   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1734   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1735
1736   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1737   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1738   # but it's more convenient here to set LD_RUN_PATH
1739   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1740   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1741     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1742     export LD_RUN_PATH
1743   fi
1744
1745   if test "${opsys}" = "gnu-linux"; then
1746     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1747     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1748      [[XOpenDisplay ("foo");]])],
1749      [xlinux_first_failure=no],
1750      [xlinux_first_failure=yes])
1751     if test "${xlinux_first_failure}" = "yes"; then
1752       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1753       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1754       OLD_CPPFLAGS="$CPPFLAGS"
1755       OLD_LIBS="$LIBS"
1756       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1757       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1758       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1759       LIBS="$LIBS -b i486-linuxaout"
1760       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1761        [[XOpenDisplay ("foo");]])],
1762        [xlinux_second_failure=no],
1763        [xlinux_second_failure=yes])
1764       if test "${xlinux_second_failure}" = "yes"; then
1765         # If we get the same failure with -b, there is no use adding -b.
1766         # So take it out.  This plays safe.
1767         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1768         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1769         CPPFLAGS="$OLD_CPPFLAGS"
1770         LIBS="$OLD_LIBS"
1771         AC_MSG_RESULT(no)
1772       else
1773         AC_MSG_RESULT(yes)
1774       fi
1775     else
1776       AC_MSG_RESULT(no)
1777     fi
1778   fi
1779
1780   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1781   # header files included from there.
1782   AC_MSG_CHECKING(for Xkb)
1783   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1784 #include <X11/XKBlib.h>]],
1785         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1786         emacs_xkb=yes, emacs_xkb=no)
1787   AC_MSG_RESULT($emacs_xkb)
1788   if test $emacs_xkb = yes; then
1789     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1790   fi
1791
1792   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1793 XScreenNumberOfScreen XSetWMProtocols)
1794 fi
1795
1796 if test "${window_system}" = "x11"; then
1797   AC_MSG_CHECKING(X11 version 6)
1798   AC_CACHE_VAL(emacs_cv_x11_version_6,
1799   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1800 [[#if XlibSpecificationRelease < 6
1801 fail;
1802 #endif
1803 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1804   if test $emacs_cv_x11_version_6 = yes; then
1805     AC_MSG_RESULT(6 or newer)
1806     AC_DEFINE(HAVE_X11R6, 1,
1807               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1808     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1809     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1810     ## XIM support.
1811     case "$opsys" in
1812       sol2-*) : ;;
1813       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1814            [Define if you have usable X11R6-style XIM support.])
1815          ;;
1816     esac
1817   else
1818     AC_MSG_RESULT(before 6)
1819   fi
1820 fi
1821
1822
1823 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1824 HAVE_RSVG=no
1825 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1826   if test "${with_rsvg}" != "no"; then
1827     RSVG_REQUIRED=2.11.0
1828     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1829
1830     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1831     AC_SUBST(RSVG_CFLAGS)
1832     AC_SUBST(RSVG_LIBS)
1833
1834     if test $HAVE_RSVG = yes; then
1835       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1836       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1837       LIBS="$RSVG_LIBS $LIBS"
1838     fi
1839   fi
1840 fi
1841
1842 HAVE_IMAGEMAGICK=no
1843 if test "${HAVE_X11}" = "yes"; then
1844   if test "${with_imagemagick}" != "no"; then
1845     ## 6.2.8 is the earliest version known to work, but earlier versions
1846     ## might work - let us know if you find one.
1847     ## 6.0.7 does not work.  See bug#7955.
1848     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1849     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1850     AC_SUBST(IMAGEMAGICK_CFLAGS)
1851     AC_SUBST(IMAGEMAGICK_LIBS)
1852
1853     if test $HAVE_IMAGEMAGICK = yes; then
1854       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1855       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1856       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1857       AC_CHECK_FUNCS(MagickExportImagePixels)
1858     fi
1859   fi
1860 fi
1861
1862
1863 HAVE_GTK=no
1864 GTK_OBJ=
1865 if test "${with_gtk3}" = "yes"; then
1866   GLIB_REQUIRED=2.28
1867   GTK_REQUIRED=3.0
1868   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1869
1870   dnl Checks for libraries.
1871   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1872   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1873      AC_MSG_ERROR($GTK_PKG_ERRORS)
1874   fi
1875   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1876   GTK_OBJ=emacsgtkfixed.o
1877 fi
1878
1879 if test "$pkg_check_gtk" != "yes"; then
1880   HAVE_GTK=no
1881 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1882   GLIB_REQUIRED=2.6
1883   GTK_REQUIRED=2.6
1884   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1885
1886   dnl Checks for libraries.
1887   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1888   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1889      AC_MSG_ERROR($GTK_PKG_ERRORS)
1890   fi
1891 fi
1892 fi
1893
1894 if test x"$pkg_check_gtk" = xyes; then
1895
1896   AC_SUBST(GTK_CFLAGS)
1897   AC_SUBST(GTK_LIBS)
1898   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1899   CFLAGS="$CFLAGS $GTK_CFLAGS"
1900   LIBS="$GTK_LIBS $LIBS"
1901   dnl Try to compile a simple GTK program.
1902   GTK_COMPILES=no
1903   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1904   if test "${GTK_COMPILES}" != "yes"; then
1905     if test "$USE_X_TOOLKIT" != "maybe"; then
1906       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1907     fi
1908   else
1909     HAVE_GTK=yes
1910     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1911     GTK_OBJ="gtkutil.o $GTK_OBJ"
1912     USE_X_TOOLKIT=none
1913     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1914       :
1915     else
1916       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1917        closing open displays.  This is no problem if you just use
1918        one display, but if you use more than one and close one of them
1919        Emacs may crash.]])
1920       sleep 3
1921     fi
1922   fi
1923
1924 fi
1925 AC_SUBST(GTK_OBJ)
1926
1927
1928 if test "${HAVE_GTK}" = "yes"; then
1929
1930   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1931   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1932   if test "$with_toolkit_scroll_bars" != no; then
1933     with_toolkit_scroll_bars=yes
1934   fi
1935
1936   dnl  Check if we have the old file selection dialog declared and
1937   dnl  in the link library.  In 2.x it may be in the library,
1938   dnl  but not declared if deprecated featured has been selected out.
1939   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1940   HAVE_GTK_FILE_SELECTION=no
1941   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1942                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1943 #include <gtk/gtk.h>])
1944   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1945     AC_CHECK_FUNCS(gtk_file_selection_new)
1946   fi
1947
1948   dnl Check if pthreads are available.  Emacs only needs this when using
1949   dnl gtk_file_chooser under Gnome.
1950     HAVE_GTK_AND_PTHREAD=no
1951     AC_CHECK_HEADERS(pthread.h)
1952     if test "$ac_cv_header_pthread_h"; then
1953       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1954     fi
1955     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1956       case "${canonical}" in
1957         *-hpux*) ;;
1958         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1959       esac
1960       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1961                [Define to 1 if you have GTK and pthread (-lpthread).])
1962     fi
1963
1964   dnl Check for functions introduced in 2.14 and later.
1965   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1966                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1967                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1968                  gtk_orientable_set_orientation)
1969
1970 fi
1971
1972 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1973 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1974 dnl also not configured.
1975 HAVE_DBUS=no
1976 DBUS_OBJ=
1977 if test "${with_dbus}" = "yes"; then
1978    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1979    if test "$HAVE_DBUS" = yes; then
1980      LIBS="$LIBS $DBUS_LIBS"
1981      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1982      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1983      DBUS_OBJ=dbusbind.o
1984    fi
1985 fi
1986 AC_SUBST(DBUS_OBJ)
1987
1988 dnl GSettings has been tested under GNU/Linux only.
1989 HAVE_GSETTINGS=no
1990 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
1991    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
1992    if test "$HAVE_GSETTINGS" = "yes"; then
1993       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
1994       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
1995       SETTINGS_LIBS="$GSETTINGS_LIBS"
1996    fi
1997 fi
1998
1999 dnl GConf has been tested under GNU/Linux only.
2000 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2001 HAVE_GCONF=no
2002 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2003    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2004    if test "$HAVE_GCONF" = yes; then
2005       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2006       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2007       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2008       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2009    fi
2010 fi
2011
2012 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2013     SAVE_CFLAGS="$CFLAGS"
2014     SAVE_LDFLAGS="$LDFLAGS"
2015     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2016     LDFLAGS="$SETTINGS_LIBS $LDFLAGS"
2017     AC_CHECK_FUNCS([g_type_init])
2018     CFLAGS="$SAVE_CFLAGS"
2019     LDFLAGS="$SAVE_LDFLAGS"
2020 fi
2021 AC_SUBST(SETTINGS_CFLAGS)
2022 AC_SUBST(SETTINGS_LIBS)
2023
2024
2025 dnl SELinux is available for GNU/Linux only.
2026 HAVE_LIBSELINUX=no
2027 LIBSELINUX_LIBS=
2028 if test "${with_selinux}" = "yes"; then
2029    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2030    if test "$HAVE_LIBSELINUX" = yes; then
2031       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2032       LIBSELINUX_LIBS=-lselinux
2033    fi
2034 fi
2035 AC_SUBST(LIBSELINUX_LIBS)
2036
2037 HAVE_GNUTLS=no
2038 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2039 if test "${with_gnutls}" = "yes" ; then
2040   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.0], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2041   if test "${HAVE_GNUTLS}" = "yes"; then
2042     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2043   fi
2044
2045   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2046   LIBS="$LIBGNUTLS_LIBS $LIBS"
2047   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2048
2049   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2050     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2051   fi
2052 fi
2053
2054 AC_SUBST(LIBGNUTLS_LIBS)
2055 AC_SUBST(LIBGNUTLS_CFLAGS)
2056
2057 dnl Do not put whitespace before the #include statements below.
2058 dnl Older compilers (eg sunos4 cc) choke on it.
2059 HAVE_XAW3D=no
2060 LUCID_LIBW=
2061 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2062   if test "$with_xaw3d" != no; then
2063     AC_MSG_CHECKING(for xaw3d)
2064     AC_CACHE_VAL(emacs_cv_xaw3d,
2065     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2066 #include <X11/Intrinsic.h>
2067 #include <X11/Xaw3d/Simple.h>]],
2068       [[]])],
2069       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2070                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2071       emacs_cv_xaw3d=no)])
2072   else
2073     emacs_cv_xaw3d=no
2074   fi
2075   if test $emacs_cv_xaw3d = yes; then
2076     AC_MSG_RESULT([yes; using Lucid toolkit])
2077     USE_X_TOOLKIT=LUCID
2078     HAVE_XAW3D=yes
2079     LUCID_LIBW=-lXaw3d
2080     AC_DEFINE(HAVE_XAW3D, 1,
2081               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2082   else
2083     AC_MSG_RESULT(no)
2084     AC_MSG_CHECKING(for libXaw)
2085     AC_CACHE_VAL(emacs_cv_xaw,
2086     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2087 #include <X11/Intrinsic.h>
2088 #include <X11/Xaw/Simple.h>]],
2089       [[]])],
2090       emacs_cv_xaw=yes,
2091       emacs_cv_xaw=no)])
2092     if test $emacs_cv_xaw = yes; then
2093       AC_MSG_RESULT([yes; using Lucid toolkit])
2094       USE_X_TOOLKIT=LUCID
2095       LUCID_LIBW=-lXaw
2096     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2097       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2098     else
2099       AC_MSG_ERROR([No X toolkit could be found.
2100 If you are sure you want Emacs compiled without an X toolkit, pass
2101   --with-x-toolkit=no
2102 to configure.  Otherwise, install the development libraries for the toolkit
2103 that you want to use (e.g. Gtk+) and re-run configure.])
2104     fi
2105   fi
2106 fi
2107
2108 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2109
2110 LIBXTR6=
2111 if test "${USE_X_TOOLKIT}" != "none"; then
2112   AC_MSG_CHECKING(X11 toolkit version)
2113   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2114   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2115 [[#if XtSpecificationRelease < 6
2116 fail;
2117 #endif
2118 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2119   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2120   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2121     AC_MSG_RESULT(6 or newer)
2122     AC_DEFINE(HAVE_X11XTR6, 1,
2123               [Define to 1 if you have the X11R6 or newer version of Xt.])
2124     LIBXTR6="-lSM -lICE"
2125     case "$opsys" in
2126       ## Use libw.a along with X11R6 Xt.
2127       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2128     esac
2129   else
2130     AC_MSG_RESULT(before 6)
2131   fi
2132
2133 dnl If using toolkit, check whether libXmu.a exists.
2134 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2135   OLDLIBS="$LIBS"
2136   if test x$HAVE_X11XTR6 = xyes; then
2137     LIBS="-lXt -lSM -lICE $LIBS"
2138   else
2139     LIBS="-lXt $LIBS"
2140   fi
2141   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2142   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2143 fi
2144 AC_SUBST(LIBXTR6)
2145
2146 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2147 dnl Why not just test for libxmu in the normal way?
2148 LIBXMU=-lXmu
2149 case $opsys in
2150   ## These systems don't supply Xmu.
2151   hpux* | aix4-2 )
2152     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2153     ;;
2154 esac
2155 AC_SUBST(LIBXMU)
2156
2157 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2158 if test "${HAVE_X11}" = "yes"; then
2159   if test "${USE_X_TOOLKIT}" != "none"; then
2160     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2161   fi
2162 fi
2163
2164 LIBXP=
2165 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2166   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2167   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2168     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2169 int x = 5;
2170 #else
2171 Motif version prior to 2.1.
2172 #endif]])],
2173     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2174   if test $emacs_cv_motif_version_2_1 = yes; then
2175     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2176   else
2177     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2178     # We put this in CFLAGS temporarily to precede other -I options
2179     # that might be in CFLAGS temporarily.
2180     # We put this in CPPFLAGS where it precedes the other -I options.
2181     OLD_CPPFLAGS=$CPPFLAGS
2182     OLD_CFLAGS=$CFLAGS
2183     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2184     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2185     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2186       [[int x = 5;]])],
2187       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2188     if test $emacs_cv_lesstif = yes; then
2189       # Make sure this -I option remains in CPPFLAGS after it is set
2190       # back to REAL_CPPFLAGS.
2191       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2192       # have those other -I options anyway.  Ultimately, having this
2193       # directory ultimately in CPPFLAGS will be enough.
2194       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2195       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2196     else
2197       CFLAGS=$OLD_CFLAGS
2198       CPPFLAGS=$OLD_CPPFLAGS
2199     fi
2200   fi
2201 fi
2202
2203 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2204 dnl using Motif or Xaw3d is available, and unless
2205 dnl --with-toolkit-scroll-bars=no was specified.
2206
2207 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2208             [Define to 1 if we should use toolkit scroll bars.])dnl
2209 USE_TOOLKIT_SCROLL_BARS=no
2210 if test "${with_toolkit_scroll_bars}" != "no"; then
2211   if test "${USE_X_TOOLKIT}" != "none"; then
2212     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2213       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2214       HAVE_XAW3D=no
2215       USE_TOOLKIT_SCROLL_BARS=yes
2216     elif test "${HAVE_XAW3D}" = "yes"; then
2217       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2218       USE_TOOLKIT_SCROLL_BARS=yes
2219     fi
2220   elif test "${HAVE_GTK}" = "yes"; then
2221     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2222     USE_TOOLKIT_SCROLL_BARS=yes
2223   elif test "${HAVE_NS}" = "yes"; then
2224     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2225     USE_TOOLKIT_SCROLL_BARS=yes
2226   fi
2227 fi
2228
2229 dnl See if XIM is available.
2230 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2231           #include <X11/Xlib.h>
2232           #include <X11/Xresource.h>]],
2233          [[XIMProc  callback;]])],
2234          [HAVE_XIM=yes
2235          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2236          HAVE_XIM=no)
2237
2238 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2239
2240 if test "${with_xim}" != "no"; then
2241   AC_DEFINE(USE_XIM, 1,
2242             [Define to 1 if we should use XIM, if it is available.])
2243 fi
2244
2245
2246 if test "${HAVE_XIM}" != "no"; then
2247   late_CFLAGS=$CFLAGS
2248   if test "$GCC" = yes; then
2249     CFLAGS="$CFLAGS --pedantic-errors"
2250   fi
2251   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2252 #include <X11/Xlib.h>
2253 #include <X11/Xresource.h>]],
2254 [[Display *display;
2255 XrmDatabase db;
2256 char *res_name;
2257 char *res_class;
2258 XIMProc  callback;
2259 XPointer *client_data;
2260 #ifndef __GNUC__
2261 /* If we're not using GCC, it's probably not XFree86, and this is
2262    probably right, but we can't use something like --pedantic-errors.  */
2263 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2264                                            char*, XIMProc, XPointer*);
2265 #endif
2266 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2267    client_data);]])],
2268     [emacs_cv_arg6_star=yes])
2269   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2270          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2271 either XPointer or XPointer*.])dnl
2272   if test "$emacs_cv_arg6_star" = yes; then
2273     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2274   else
2275     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2276   fi
2277   CFLAGS=$late_CFLAGS
2278 fi
2279
2280 ### Start of font-backend (under any platform) section.
2281 # (nothing here yet -- this is a placeholder)
2282 ### End of font-backend (under any platform) section.
2283
2284 ### Start of font-backend (under X11) section.
2285 if test "${HAVE_X11}" = "yes"; then
2286    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2287
2288    ## Use -lXft if available, unless `--with-xft=no'.
2289    HAVE_XFT=maybe
2290     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2291       with_xft="no";
2292     fi
2293     if test "x${with_xft}" != "xno"; then
2294
2295       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2296       ## Because xftfont.c uses XRenderQueryExtension, we also
2297       ## need to link to -lXrender.
2298       HAVE_XRENDER=no
2299       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2300       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2301         OLD_CPPFLAGS="$CPPFLAGS"
2302         OLD_CFLAGS="$CFLAGS"
2303         OLD_LIBS="$LIBS"
2304         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2305         CFLAGS="$CFLAGS $XFT_CFLAGS"
2306         XFT_LIBS="-lXrender $XFT_LIBS"
2307         LIBS="$XFT_LIBS $LIBS"
2308         AC_CHECK_HEADER(X11/Xft/Xft.h,
2309           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2310
2311         if test "${HAVE_XFT}" = "yes"; then
2312           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2313             AC_SUBST(XFT_LIBS)
2314           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2315         else
2316           CPPFLAGS="$OLD_CPPFLAGS"
2317           CFLAGS="$OLD_CFLAGS"
2318           LIBS="$OLD_LIBS"
2319         fi                        # "${HAVE_XFT}" = "yes"
2320       fi                          # "$HAVE_XFT" != no
2321     fi                            # "x${with_xft}" != "xno"
2322
2323     ## We used to allow building with FreeType and without Xft.
2324     ## However, the ftx font backend driver is not in good shape.
2325     if test "$HAVE_XFT" != "yes"; then
2326        dnl For the "Does Emacs use" message at the end.
2327        HAVE_XFT=no
2328        HAVE_FREETYPE=no
2329     else
2330        dnl Strict linkers fail with
2331        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2332        dnl if -lfreetype is not specified.
2333        dnl The following is needed to set FREETYPE_LIBS.
2334        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2335                          HAVE_FREETYPE=no)
2336
2337        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2338     fi
2339
2340     HAVE_LIBOTF=no
2341     if test "${HAVE_FREETYPE}" = "yes"; then
2342       AC_DEFINE(HAVE_FREETYPE, 1,
2343                 [Define to 1 if using the freetype and fontconfig libraries.])
2344       if test "${with_libotf}" != "no"; then
2345         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2346                           HAVE_LIBOTF=no)
2347         if test "$HAVE_LIBOTF" = "yes"; then
2348           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2349           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2350                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2351                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2352           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2353             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2354                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2355           fi
2356         fi
2357       fi
2358     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2359     dnl Does the new font backend require it, or can it work without it?
2360     fi
2361
2362     HAVE_M17N_FLT=no
2363     if test "${HAVE_LIBOTF}" = yes; then
2364       if test "${with_m17n_flt}" != "no"; then
2365         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2366         if test "$HAVE_M17N_FLT" = "yes"; then
2367           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2368         fi
2369       fi
2370     fi
2371 else
2372     HAVE_XFT=no
2373     HAVE_FREETYPE=no
2374     HAVE_LIBOTF=no
2375     HAVE_M17N_FLT=no
2376 fi
2377
2378 ### End of font-backend (under X11) section.
2379
2380 AC_SUBST(FREETYPE_CFLAGS)
2381 AC_SUBST(FREETYPE_LIBS)
2382 AC_SUBST(FONTCONFIG_CFLAGS)
2383 AC_SUBST(FONTCONFIG_LIBS)
2384 AC_SUBST(LIBOTF_CFLAGS)
2385 AC_SUBST(LIBOTF_LIBS)
2386 AC_SUBST(M17N_FLT_CFLAGS)
2387 AC_SUBST(M17N_FLT_LIBS)
2388
2389 ### Use -lXpm if available, unless `--with-xpm=no'.
2390 HAVE_XPM=no
2391 LIBXPM=
2392 if test "${HAVE_X11}" = "yes"; then
2393   if test "${with_xpm}" != "no"; then
2394     AC_CHECK_HEADER(X11/xpm.h,
2395       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2396     if test "${HAVE_XPM}" = "yes"; then
2397       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2398       AC_EGREP_CPP(no_return_alloc_pixels,
2399       [#include "X11/xpm.h"
2400 #ifndef XpmReturnAllocPixels
2401 no_return_alloc_pixels
2402 #endif
2403       ], HAVE_XPM=no, HAVE_XPM=yes)
2404
2405       if test "${HAVE_XPM}" = "yes"; then
2406         AC_MSG_RESULT(yes)
2407       else
2408         AC_MSG_RESULT(no)
2409       fi
2410     fi
2411   fi
2412
2413   if test "${HAVE_XPM}" = "yes"; then
2414     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2415     LIBXPM=-lXpm
2416   fi
2417 fi
2418 AC_SUBST(LIBXPM)
2419
2420 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2421 HAVE_JPEG=no
2422 LIBJPEG=
2423 if test "${HAVE_X11}" = "yes"; then
2424   if test "${with_jpeg}" != "no"; then
2425     dnl Checking for jpeglib.h can lose because of a redefinition of
2426     dnl  HAVE_STDLIB_H.
2427     AC_CHECK_HEADER(jerror.h,
2428       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2429   fi
2430
2431   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2432   if test "${HAVE_JPEG}" = "yes"; then
2433     AC_DEFINE(HAVE_JPEG)
2434     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2435         [#include <jpeglib.h>
2436          version=JPEG_LIB_VERSION
2437 ],
2438         [AC_DEFINE(HAVE_JPEG)],
2439         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2440         HAVE_JPEG=no])
2441   fi
2442   if test "${HAVE_JPEG}" = "yes"; then
2443     LIBJPEG=-ljpeg
2444   fi
2445 fi
2446 AC_SUBST(LIBJPEG)
2447
2448 ### Use -lpng if available, unless `--with-png=no'.
2449 HAVE_PNG=no
2450 LIBPNG=
2451 if test "${HAVE_X11}" = "yes"; then
2452   if test "${with_png}" != "no"; then
2453     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2454     # in /usr/include/libpng.
2455     AC_CHECK_HEADERS(png.h libpng/png.h)
2456     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2457       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2458     fi
2459   fi
2460
2461   if test "${HAVE_PNG}" = "yes"; then
2462     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2463     LIBPNG="-lpng -lz -lm"
2464   fi
2465 fi
2466 AC_SUBST(LIBPNG)
2467
2468 ### Use -ltiff if available, unless `--with-tiff=no'.
2469 HAVE_TIFF=no
2470 LIBTIFF=
2471 if test "${HAVE_X11}" = "yes"; then
2472   if test "${with_tiff}" != "no"; then
2473     AC_CHECK_HEADER(tiffio.h,
2474       [tifflibs="-lz -lm"
2475       # At least one tiff package requires the jpeg library.
2476       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2477       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2478   fi
2479
2480   if test "${HAVE_TIFF}" = "yes"; then
2481     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2482     dnl FIXME -lz -lm, as per libpng?
2483     LIBTIFF=-ltiff
2484   fi
2485 fi
2486 AC_SUBST(LIBTIFF)
2487
2488 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2489 HAVE_GIF=no
2490 LIBGIF=
2491 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2492   AC_CHECK_HEADER(gif_lib.h,
2493 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2494 # Earlier versions can crash Emacs.
2495     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2496
2497   if test "$HAVE_GIF" = yes; then
2498     LIBGIF=-lgif
2499   elif test "$HAVE_GIF" = maybe; then
2500 # If gif_lib.h but no libgif, try libungif.
2501     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2502     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2503   fi
2504
2505   if test "${HAVE_GIF}" = "yes"; then
2506     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2507   fi
2508 fi
2509 AC_SUBST(LIBGIF)
2510
2511 dnl Check for required libraries.
2512 if test "${HAVE_X11}" = "yes"; then
2513   MISSING=""
2514   WITH_NO=""
2515   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2516     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2517   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2518     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2519   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2520     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2521   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2522     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2523   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2524     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2525
2526   if test "X${MISSING}" != X; then
2527     AC_MSG_ERROR([The following required libraries were not found:
2528     $MISSING
2529 Maybe some development libraries/packages are missing?
2530 If you don't want to link with them give
2531     $WITH_NO
2532 as options to configure])
2533   fi
2534 fi
2535
2536 ### Use -lgpm if available, unless `--with-gpm=no'.
2537 HAVE_GPM=no
2538 LIBGPM=
2539 if test "${with_gpm}" != "no"; then
2540   AC_CHECK_HEADER(gpm.h,
2541     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2542
2543   if test "${HAVE_GPM}" = "yes"; then
2544     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2545     LIBGPM=-lgpm
2546   fi
2547 fi
2548 AC_SUBST(LIBGPM)
2549
2550 dnl Check for malloc/malloc.h on darwin
2551 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2552
2553 C_SWITCH_X_SYSTEM=
2554 ### Use NeXTstep API to implement GUI.
2555 if test "${HAVE_NS}" = "yes"; then
2556   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2557   if test "${NS_IMPL_COCOA}" = "yes"; then
2558     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2559     GNU_OBJC_CFLAGS=
2560   fi
2561   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2562     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2563     # See also .m.o rule in Makefile.in */
2564     # FIXME: are all these flags really needed?  Document here why.  */
2565     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2566     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2567   fi
2568   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2569     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2570   fi
2571   # We also have mouse menus.
2572   HAVE_MENUS=yes
2573   OTHER_FILES=ns-app
2574 fi
2575
2576
2577 ### Use session management (-lSM -lICE) if available
2578 HAVE_X_SM=no
2579 LIBXSM=
2580 if test "${HAVE_X11}" = "yes"; then
2581   AC_CHECK_HEADER(X11/SM/SMlib.h,
2582     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2583
2584   if test "${HAVE_X_SM}" = "yes"; then
2585     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2586     LIBXSM="-lSM -lICE"
2587     case "$LIBS" in
2588       *-lSM*) ;;
2589       *)      LIBS="$LIBXSM $LIBS" ;;
2590     esac
2591   fi
2592 fi
2593 AC_SUBST(LIBXSM)
2594
2595 ### Use libxml (-lxml2) if available
2596 if test "${with_xml2}" != "no"; then
2597   ### I'm not sure what the version number should be, so I just guessed.
2598   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2599   if test "${HAVE_LIBXML2}" = "yes"; then
2600     LIBS="$LIBXML2_LIBS $LIBS"
2601     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2602     if test "${HAVE_LIBXML2}" = "yes"; then
2603       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2604     else
2605       LIBXML2_LIBS=""
2606       LIBXML2_CFLAGS=""
2607     fi
2608   fi
2609 fi
2610 AC_SUBST(LIBXML2_LIBS)
2611 AC_SUBST(LIBXML2_CFLAGS)
2612
2613 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2614 AC_CACHE_CHECK(whether netdb declares h_errno,
2615                emacs_cv_netdb_declares_h_errno,
2616 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2617   [[return h_errno;]])],
2618   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2619 if test $emacs_cv_netdb_declares_h_errno = yes; then
2620   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2621 fi
2622
2623 # fmod, logb, and frexp are found in -lm on most systems.
2624 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2625 AC_CHECK_LIB(m, sqrt)
2626
2627 # Check for mail-locking functions in a "mail" library.  Probably this should
2628 # have the same check as for liblockfile below.
2629 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2630 if test $have_mail = yes; then
2631   LIBS_MAIL=-lmail
2632   LIBS="$LIBS_MAIL $LIBS"
2633   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2634 else
2635   LIBS_MAIL=
2636 fi
2637 dnl Debian, at least:
2638 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2639 if test $have_lockfile = yes; then
2640    LIBS_MAIL=-llockfile
2641    LIBS="$LIBS_MAIL $LIBS"
2642    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2643 else
2644 # If we have the shared liblockfile, assume we must use it for mail
2645 # locking (e.g. Debian).  If we couldn't link against liblockfile
2646 # (no liblockfile.a installed), ensure that we don't need to.
2647   dnl This works for files generally, not just executables.
2648   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2649   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2650                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2651   if test $ac_cv_prog_liblockfile = yes; then
2652     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2653 This probably means that movemail could lose mail.
2654 There may be a `development' package to install containing liblockfile.])
2655   fi
2656 fi
2657 AC_CHECK_FUNCS(touchlock)
2658 AC_CHECK_HEADERS(maillock.h)
2659 AC_SUBST(LIBS_MAIL)
2660
2661 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2662 ## interlock access to the mail spool.  The alternative is a lock file named
2663 ## /usr/spool/mail/$USER.lock.
2664 mail_lock=no
2665 case "$opsys" in
2666   aix4-2) mail_lock="lockf" ;;
2667
2668   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2669
2670   ## On GNU/Linux systems, both methods are used by various mail programs.
2671   ## I assume most people are using newer mailers that have heard of flock.
2672   ## Change this if you need to.
2673   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2674   ## configure gets the right answers, and that means *NOT* using flock.
2675   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2676   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2677   ## Debian maintainer hasn't provided a clean fix for Emacs.
2678   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2679   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2680   ## correct logic.  -- fx
2681   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2682   ## liblockfile is a Free Software replacement for libmail, used on
2683   ## Debian systems and elsewhere. -rfr.
2684   gnu-*)
2685     mail_lock="flock"
2686     if test $have_mail = yes || test $have_lockfile = yes; then
2687       test $ac_cv_header_maillock_h = yes && mail_lock=no
2688     fi
2689     ;;
2690 esac
2691
2692 BLESSMAIL_TARGET=
2693 case "$mail_lock" in
2694   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2695
2696   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2697
2698   *) BLESSMAIL_TARGET="need-blessmail" ;;
2699 esac
2700 AC_SUBST(BLESSMAIL_TARGET)
2701
2702
2703 AC_CHECK_FUNCS(gethostname getdomainname \
2704 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2705 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2706 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2707 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2708 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm strchr strrchr \
2709 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2710 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2711 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2712 cfmakeraw cfsetspeed isnan copysign __executable_start)
2713
2714 dnl Cannot use AC_CHECK_FUNCS
2715 AC_CACHE_CHECK([for __builtin_unwind_init],
2716                emacs_cv_func___builtin_unwind_init,
2717 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2718                 emacs_cv_func___builtin_unwind_init=yes,
2719                 emacs_cv_func___builtin_unwind_init=no)])
2720 if test $emacs_cv_func___builtin_unwind_init = yes; then
2721   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2722             [Define to 1 if you have the `__builtin_unwind_init' function.])
2723 fi
2724
2725 AC_CHECK_HEADERS(sys/un.h)
2726
2727 AC_FUNC_FSEEKO
2728
2729 AC_FUNC_GETPGRP
2730
2731 # UNIX98 PTYs.
2732 AC_CHECK_FUNCS(grantpt)
2733
2734 # PTY-related GNU extensions.
2735 AC_CHECK_FUNCS(getpt)
2736
2737 # Check this now, so that we will NOT find the above functions in ncurses.
2738 # That is because we have not set up to link ncurses in lib-src.
2739 # It's better to believe a function is not available
2740 # than to expect to find it in ncurses.
2741 # Also we need tputs and friends to be able to build at all.
2742 have_tputs_et_al=true
2743 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2744 if test "$have_tputs_et_al" != true; then
2745   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2746 Maybe some development libraries/packages are missing?  Try installing
2747 libncurses-dev(el), libterminfo-dev(el) or similar.])
2748 fi
2749 # Must define this when any termcap library is found.
2750 AC_DEFINE(HAVE_LIBNCURSES, 1,
2751           [Define to 1 if you have the `ncurses' library (-lncurses).])
2752 ## FIXME This was the cpp logic, but I am not sure it is right.
2753 ## The above test has not necessarily found libncurses.
2754 HAVE_LIBNCURSES=yes
2755
2756 ## Use terminfo instead of termcap?
2757 ## Note only system files NOT using terminfo are:
2758 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2759 ## darwin|gnu without ncurses.
2760 TERMINFO=no
2761 LIBS_TERMCAP=
2762 case "$opsys" in
2763   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2764   ## hpux10-20: Use the system provided termcap(3) library.
2765   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2766   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2767   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2768
2769   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2770   ##  The ncurses library has been moved out of the System framework in
2771   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2772   ##  option to use it.
2773   darwin|gnu*)
2774     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2775     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2776       TERMINFO=yes
2777       LIBS_TERMCAP="-lncurses"
2778     fi
2779     ;;
2780
2781   freebsd)
2782     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2783     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2784     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2785 [[#if __FreeBSD_version < 400000
2786 fail;
2787 #endif
2788 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2789
2790     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2791
2792     if test $emacs_cv_freebsd_terminfo = yes; then
2793       TERMINFO=yes
2794       LIBS_TERMCAP="-lncurses"
2795     else
2796       LIBS_TERMCAP="-ltermcap"
2797     fi
2798     ;;
2799
2800   netbsd)
2801     if test $ac_cv_search_tputs = -lterminfo; then
2802       TERMINFO=yes
2803       LIBS_TERMCAP="-lterminfo"
2804     else
2805       LIBS_TERMCAP="-ltermcap"
2806     fi
2807     ;;
2808
2809 esac
2810
2811 case "$opsys" in
2812   ## hpux: Make sure we get select from libc rather than from libcurses
2813   ##  because libcurses on HPUX 10.10 has a broken version of select.
2814   ##  We used to use -lc -lcurses, but this may be cleaner.
2815   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2816
2817   openbsd) LIBS_TERMCAP="-lncurses" ;;
2818
2819   ## Must use system termcap, if we use any termcap.  It does special things.
2820   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2821 esac
2822
2823 TERMCAP_OBJ=tparam.o
2824 if test $TERMINFO = yes; then
2825   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2826
2827   ## Default used to be -ltermcap.  Add a case above if need something else.
2828   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2829
2830   TERMCAP_OBJ=terminfo.o
2831 fi
2832 AC_SUBST(LIBS_TERMCAP)
2833 AC_SUBST(TERMCAP_OBJ)
2834
2835
2836 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2837 resolv=no
2838 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2839 #include <arpa/nameser.h>
2840 #include <resolv.h>]],
2841     [[return res_init();]])],
2842     have_res_init=yes, have_res_init=no)
2843 if test "$have_res_init" = no; then
2844   OLIBS="$LIBS"
2845   LIBS="$LIBS -lresolv"
2846   AC_MSG_CHECKING(for res_init with -lresolv)
2847   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2848 #include <arpa/nameser.h>
2849 #include <resolv.h>]],
2850     [[return res_init();]])],
2851     have_res_init=yes, have_res_init=no)
2852   AC_MSG_RESULT($have_res_init)
2853   if test "$have_res_init" = yes ; then
2854     resolv=yes
2855   fi
2856   LIBS="$OLIBS"
2857 fi
2858
2859 if test "$have_res_init" = yes; then
2860   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2861 fi
2862
2863 # Do we need the Hesiod library to provide the support routines?
2864 LIBHESIOD=
2865 if test "$with_hesiod" != no ; then
2866   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2867   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2868      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2869                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2870   if test "$resolv" = yes ; then
2871     RESOLVLIB=-lresolv
2872   else
2873     RESOLVLIB=
2874   fi
2875   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2876         hesiod=yes, :, $RESOLVLIB)])
2877
2878   if test x"$hesiod" = xyes; then
2879     AC_DEFINE(HAVE_LIBHESIOD, 1,
2880               [Define to 1 if you have the hesiod library (-lhesiod).])
2881     LIBHESIOD=-lhesiod
2882   fi
2883 fi
2884 AC_SUBST(LIBHESIOD)
2885
2886 # Do we need libresolv (due to res_init or Hesiod)?
2887 if test "$resolv" = yes ; then
2888   AC_DEFINE(HAVE_LIBRESOLV, 1,
2889             [Define to 1 if you have the resolv library (-lresolv).])
2890   LIBRESOLV=-lresolv
2891 else
2892   LIBRESOLV=
2893 fi
2894 AC_SUBST(LIBRESOLV)
2895
2896 # These tell us which Kerberos-related libraries to use.
2897 COM_ERRLIB=
2898 CRYPTOLIB=
2899 KRB5LIB=
2900 DESLIB=
2901 KRB4LIB=
2902
2903 if test "${with_kerberos}" != no; then
2904   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2905   if test $have_com_err = yes; then
2906     COM_ERRLIB=-lcom_err
2907     LIBS="$COM_ERRLIB $LIBS"
2908     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2909   fi
2910   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2911   if test $have_crypto = yes; then
2912     CRYPTOLIB=-lcrypto
2913     LIBS="$CRYPTOLIB $LIBS"
2914     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2915   fi
2916   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2917   if test $have_k5crypto = yes; then
2918     CRYPTOLIB=-lk5crypto
2919     LIBS="$CRYPTOLIB $LIBS"
2920     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2921   fi
2922   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2923   if test $have_krb5=yes; then
2924     KRB5LIB=-lkrb5
2925     LIBS="$KRB5LIB $LIBS"
2926     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2927   fi
2928   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2929   if test "${with_kerberos5}" = no; then
2930     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2931     if test $have_des425 = yes; then
2932       DESLIB=-ldes425
2933       LIBS="$DESLIB $LIBS"
2934       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2935     else
2936       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2937       if test $have_des = yes; then
2938         DESLIB=-ldes
2939         LIBS="$DESLIB $LIBS"
2940         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2941       fi
2942     fi
2943     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2944     if test $have_krb4 = yes; then
2945       KRB4LIB=-lkrb4
2946       LIBS="$KRB4LIB $LIBS"
2947       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2948     else
2949       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2950       if test $have_krb = yes; then
2951         KRB4LIB=-lkrb
2952         LIBS="$KRB4LIB $LIBS"
2953         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2954       fi
2955     fi
2956   fi
2957
2958   if test "${with_kerberos5}" != no; then
2959     AC_CHECK_HEADERS(krb5.h,
2960       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2961                         [#include <krb5.h>])])
2962   else
2963     AC_CHECK_HEADERS(des.h,,
2964                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2965                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2966     AC_CHECK_HEADERS(krb.h,,
2967                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2968                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2969   fi
2970   AC_CHECK_HEADERS(com_err.h)
2971 fi
2972
2973 AC_SUBST(COM_ERRLIB)
2974 AC_SUBST(CRYPTOLIB)
2975 AC_SUBST(KRB5LIB)
2976 AC_SUBST(DESLIB)
2977 AC_SUBST(KRB4LIB)
2978
2979 # Solaris requires -lintl if you want strerror (which calls dgettext)
2980 # to return localized messages.
2981 AC_CHECK_LIB(intl, dgettext)
2982
2983 AC_MSG_CHECKING(whether localtime caches TZ)
2984 AC_CACHE_VAL(emacs_cv_localtime_cache,
2985 [if test x$ac_cv_func_tzset = xyes; then
2986 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
2987 char TZ_GMT0[] = "TZ=GMT0";
2988 char TZ_PST8[] = "TZ=PST8";
2989 main()
2990 {
2991   time_t now = time ((time_t *) 0);
2992   int hour_GMT0, hour_unset;
2993   if (putenv (TZ_GMT0) != 0)
2994     exit (1);
2995   hour_GMT0 = localtime (&now)->tm_hour;
2996   unsetenv("TZ");
2997   hour_unset = localtime (&now)->tm_hour;
2998   if (putenv (TZ_PST8) != 0)
2999     exit (1);
3000   if (localtime (&now)->tm_hour == hour_GMT0)
3001     exit (1);
3002   unsetenv("TZ");
3003   if (localtime (&now)->tm_hour != hour_unset)
3004     exit (1);
3005   exit (0);
3006 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3007 [# If we have tzset, assume the worst when cross-compiling.
3008 emacs_cv_localtime_cache=yes])
3009 else
3010         # If we lack tzset, report that localtime does not cache TZ,
3011         # since we can't invalidate the cache if we don't have tzset.
3012         emacs_cv_localtime_cache=no
3013 fi])dnl
3014 AC_MSG_RESULT($emacs_cv_localtime_cache)
3015 if test $emacs_cv_localtime_cache = yes; then
3016   AC_DEFINE(LOCALTIME_CACHE, 1,
3017             [Define to 1 if localtime caches TZ.])
3018 fi
3019
3020 if test "x$HAVE_TIMEVAL" = xyes; then
3021   AC_CHECK_FUNCS(gettimeofday)
3022   if test $ac_cv_func_gettimeofday = yes; then
3023     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
3024                    emacs_cv_gettimeofday_two_arguments,
3025     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3026 #ifdef TIME_WITH_SYS_TIME
3027 #include <sys/time.h>
3028 #include <time.h>
3029 #else
3030 #ifdef HAVE_SYS_TIME_H
3031 #include <sys/time.h>
3032 #else
3033 #include <time.h>
3034 #endif
3035 #endif]],
3036       [[struct timeval time;
3037        gettimeofday (&time, 0);]])],
3038       emacs_cv_gettimeofday_two_arguments=yes,
3039       emacs_cv_gettimeofday_two_arguments=no)])
3040     if test $emacs_cv_gettimeofday_two_arguments = no; then
3041       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3042                 [Define to 1 if gettimeofday accepts only one argument.])
3043     fi
3044   fi
3045 fi
3046
3047 ok_so_far=yes
3048 AC_CHECK_FUNC(socket, , ok_so_far=no)
3049 if test $ok_so_far = yes; then
3050   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3051 fi
3052 if test $ok_so_far = yes; then
3053   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3054 fi
3055 if test $ok_so_far = yes; then
3056 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3057   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3058             [Define to 1 if you have inet sockets.])
3059 fi
3060
3061 if test -f /usr/lpp/X11/bin/smt.exp; then
3062   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3063             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3064 fi
3065
3066 AC_MSG_CHECKING(whether system supports dynamic ptys)
3067 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3068   AC_MSG_RESULT(yes)
3069   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3070 else
3071   AC_MSG_RESULT(no)
3072 fi
3073
3074 AC_FUNC_FORK
3075
3076 dnl Adapted from Haible's version.
3077 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3078   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3079     [[char* cs = nl_langinfo(CODESET);]])],
3080     emacs_cv_langinfo_codeset=yes,
3081     emacs_cv_langinfo_codeset=no)
3082   ])
3083 if test $emacs_cv_langinfo_codeset = yes; then
3084   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3085     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3086 fi
3087
3088 AC_TYPE_MBSTATE_T
3089
3090 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3091   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3092                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3093 if test "$emacs_cv_c_restrict_arr" = yes; then
3094   AC_DEFINE(__restrict_arr, __restrict,
3095     [Define to compiler's equivalent of C99 restrict keyword in array
3096      declarations.  Define as empty for no equivalent.])
3097 fi
3098
3099 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3100 dnl how the tty code is related to POSIX and/or other versions of termios.
3101 dnl The following looks like a useful start.
3102 dnl
3103 dnl AC_SYS_POSIX_TERMIOS
3104 dnl if test $ac_cv_sys_posix_termios = yes; then
3105 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3106 dnl                                and macros for terminal control.])
3107 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3108 dnl fi
3109
3110 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3111
3112 # Set up the CFLAGS for real compilation, so we can substitute it.
3113 CFLAGS="$REAL_CFLAGS"
3114 CPPFLAGS="$REAL_CPPFLAGS"
3115
3116 ## Hack to detect a buggy GCC version.
3117 if test "x$GCC" = xyes \
3118    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3119    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3120    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3121    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3122 fi
3123
3124 version=$PACKAGE_VERSION
3125
3126 ### Specify what sort of things we'll be editing into Makefile and config.h.
3127 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3128 AC_SUBST(version)
3129 AC_SUBST(configuration)
3130 ## Unused?
3131 AC_SUBST(canonical)
3132 AC_SUBST(srcdir)
3133 AC_SUBST(prefix)
3134 AC_SUBST(exec_prefix)
3135 AC_SUBST(bindir)
3136 AC_SUBST(datadir)
3137 AC_SUBST(sharedstatedir)
3138 AC_SUBST(libexecdir)
3139 AC_SUBST(mandir)
3140 AC_SUBST(infodir)
3141 AC_SUBST(lispdir)
3142 AC_SUBST(locallisppath)
3143 AC_SUBST(lisppath)
3144 AC_SUBST(x_default_search_path)
3145 AC_SUBST(etcdir)
3146 AC_SUBST(archlibdir)
3147 AC_SUBST(docdir)
3148 AC_SUBST(bitmapdir)
3149 AC_SUBST(gamedir)
3150 AC_SUBST(gameuser)
3151 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3152 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3153 ## end of LIBX_BASE, but nothing ever set it.
3154 AC_SUBST(LD_SWITCH_X_SITE)
3155 AC_SUBST(C_SWITCH_X_SITE)
3156 AC_SUBST(C_SWITCH_X_SYSTEM)
3157 AC_SUBST(CFLAGS)
3158 ## Used in lwlib/Makefile.in.
3159 AC_SUBST(X_TOOLKIT_TYPE)
3160 if test -n "${machfile}"; then
3161   M_FILE="\$(srcdir)/${machfile}"
3162 else
3163   M_FILE=
3164 fi
3165 S_FILE="\$(srcdir)/${opsysfile}"
3166 AC_SUBST(M_FILE)
3167 AC_SUBST(S_FILE)
3168 AC_SUBST(ns_appdir)
3169 AC_SUBST(ns_appbindir)
3170 AC_SUBST(ns_appresdir)
3171 AC_SUBST(ns_appsrc)
3172 AC_SUBST(GNU_OBJC_CFLAGS)
3173 AC_SUBST(OTHER_FILES)
3174
3175 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3176                    [Define to the canonical Emacs configuration name.])
3177 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3178                    [Define to the options passed to configure.])
3179 if test -n "$machfile"; then
3180   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3181                      [Define to the used machine dependent file.])
3182 fi
3183 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3184                    [Define to the used os dependent file.])
3185
3186 XMENU_OBJ=
3187 XOBJ=
3188 FONT_OBJ=
3189 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3190   AC_DEFINE(HAVE_X_WINDOWS, 1,
3191             [Define to 1 if you want to use the X window system.])
3192   XMENU_OBJ=xmenu.o
3193   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3194   FONT_OBJ=xfont.o
3195   if test "$HAVE_XFT" = "yes"; then
3196     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3197   elif test "$HAVE_FREETYPE" = "yes"; then
3198     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3199   fi
3200   AC_SUBST(FONT_OBJ)
3201 fi
3202 AC_SUBST(XMENU_OBJ)
3203 AC_SUBST(XOBJ)
3204 AC_SUBST(FONT_OBJ)
3205
3206 WIDGET_OBJ=
3207 MOTIF_LIBW=
3208 if test "${USE_X_TOOLKIT}" != "none" ; then
3209   WIDGET_OBJ=widget.o
3210   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3211   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3212     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3213   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3214     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3215     MOTIF_LIBW=-lXm
3216     case "$opsys" in
3217       gnu-linux)
3218         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3219         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3220         ;;
3221
3222       unixware)
3223         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3224         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3225         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3226         ;;
3227
3228       aix4-2)
3229         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3230         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3231         ;;
3232     esac
3233     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3234   fi
3235 fi
3236 AC_SUBST(WIDGET_OBJ)
3237
3238 TOOLKIT_LIBW=
3239 case "$USE_X_TOOLKIT" in
3240   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3241   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3242   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3243 esac
3244 AC_SUBST(TOOLKIT_LIBW)
3245
3246 if test "$USE_X_TOOLKIT" = "none"; then
3247   LIBXT_OTHER="\$(LIBXSM)"
3248   OLDXMENU_TARGET="really-oldXMenu"
3249 else
3250   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3251   OLDXMENU_TARGET="really-lwlib"
3252 fi
3253 AC_SUBST(LIBXT_OTHER)
3254
3255 ## The X Menu stuff is present in the X10 distribution, but missing
3256 ## from X11.  If we have X10, just use the installed library;
3257 ## otherwise, use our own copy.
3258 if test "${HAVE_X11}" = "yes" ; then
3259   AC_DEFINE(HAVE_X11, 1,
3260             [Define to 1 if you want to use version 11 of X windows.
3261              Otherwise, Emacs expects to use version 10.])
3262
3263   if test "$USE_X_TOOLKIT" = "none"; then
3264     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3265   else
3266     OLDXMENU="\${lwlibdir}/liblw.a"
3267   fi
3268   LIBXMENU="\$(OLDXMENU)"
3269   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3270   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3271 else
3272   ## For a syntactically valid Makefile; not actually used for anything.
3273   ## See comments in src/Makefile.in.
3274   OLDXMENU=nothing
3275   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3276   if test "${HAVE_X_WINDOWS}" = "yes"; then
3277     LIBXMENU="-lXMenu"
3278   else
3279     LIBXMENU=
3280   fi
3281   LIBX_OTHER=
3282   OLDXMENU_DEPS=
3283 fi
3284
3285 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3286   OLDXMENU_TARGET=
3287   OLDXMENU=nothing
3288   LIBXMENU=
3289   OLDXMENU_DEPS=
3290 fi
3291
3292 AC_SUBST(OLDXMENU_TARGET)
3293 AC_SUBST(OLDXMENU)
3294 AC_SUBST(LIBXMENU)
3295 AC_SUBST(LIBX_OTHER)
3296 AC_SUBST(OLDXMENU_DEPS)
3297
3298 if test "${HAVE_MENUS}" = "yes" ; then
3299   AC_DEFINE(HAVE_MENUS, 1,
3300             [Define to 1 if you have mouse menus.
3301              (This is automatic if you use X, but the option to specify it remains.)
3302              It is also defined with other window systems that support xmenu.c.])
3303 fi
3304
3305 if test "${GNU_MALLOC}" = "yes" ; then
3306   AC_DEFINE(GNU_MALLOC, 1,
3307             [Define to 1 if you want to use the GNU memory allocator.])
3308 fi
3309
3310 RALLOC_OBJ=
3311 if test "${REL_ALLOC}" = "yes" ; then
3312   AC_DEFINE(REL_ALLOC, 1,
3313             [Define REL_ALLOC if you want to use the relocating allocator for
3314              buffer space.])
3315
3316   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3317 fi
3318 AC_SUBST(RALLOC_OBJ)
3319
3320 if test "$opsys" = "cygwin"; then
3321   CYGWIN_OBJ="sheap.o"
3322   ## Cygwin differs because of its unexec().
3323   PRE_ALLOC_OBJ=
3324   POST_ALLOC_OBJ=lastfile.o
3325 else
3326   CYGWIN_OBJ=
3327   PRE_ALLOC_OBJ=lastfile.o
3328   POST_ALLOC_OBJ=
3329 fi
3330 AC_SUBST(CYGWIN_OBJ)
3331 AC_SUBST(PRE_ALLOC_OBJ)
3332 AC_SUBST(POST_ALLOC_OBJ)
3333
3334 # Configure gnulib here, now that we know LIBS.
3335 gl_ASSERT_NO_GNULIB_POSIXCHECK
3336 gl_ASSERT_NO_GNULIB_TESTS
3337 gl_INIT
3338
3339 case "$opsys" in
3340   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3341
3342   darwin)
3343    ## The -headerpad option tells ld (see man page) to leave room at the
3344    ## end of the header for adding load commands.  Needed for dumping.
3345    ## 0x690 is the total size of 30 segment load commands (at 56
3346    ## each); under Cocoa 31 commands are required.
3347    if test "$HAVE_NS" = "yes"; then
3348      libs_nsgui="-framework AppKit"
3349      headerpad_extra=6C8
3350    else
3351      libs_nsgui=
3352      headerpad_extra=690
3353    fi
3354    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3355
3356    ## This is here because src/Makefile.in did some extra fiddling around
3357    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3358    ##   #ifndef LD_SWITCH_SYSTEM
3359    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3360    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3361    ## not using gcc, darwin system not on an alpha (ie darwin, since
3362    ## darwin + alpha does not occur).
3363    ## Because this was done in src/Makefile.in, the resulting part of
3364    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3365    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3366    ## rather than LD_SWITCH_SYSTEM.
3367    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3368      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3369    ;;
3370
3371   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3372   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3373   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3374   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3375   ## had different values in configure (in ac_link) and src/Makefile.in.
3376   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3377   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3378
3379   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3380 esac
3381
3382 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3383   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3384 fi
3385
3386 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3387
3388
3389 LD_FIRSTFLAG=
3390 ORDINARY_LINK=
3391 case "$opsys" in
3392   ## gnu: GNU needs its own crt0.
3393   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3394
3395   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3396   ## library search parth, i.e. it won't search /usr/lib for libc and
3397   ## friends.  Using -nostartfiles instead avoids this problem, and
3398   ## will also work on earlier NetBSD releases.
3399   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3400
3401   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3402   ##   MkLinux/LinuxPPC needs this.
3403   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3404   gnu-*)
3405     case "$machine" in
3406       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3407     esac
3408     ;;
3409 esac
3410
3411
3412 if test "x$ORDINARY_LINK" = "xyes"; then
3413
3414   LD_FIRSTFLAG=""
3415   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3416
3417 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3418 ## freebsd, gnu-* not on macppc|ibms390x.
3419 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3420
3421   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3422   ## places that are difficult to figure out at make time.  Fortunately,
3423   ## these same versions allow you to pass arbitrary flags on to the
3424   ## linker, so there is no reason not to use it as a linker.
3425   ##
3426   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3427   ## searching for libraries in its internal directories, so we have to
3428   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3429   LD_FIRSTFLAG="-nostdlib"
3430 fi
3431
3432 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3433 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3434
3435 AC_SUBST(LD_FIRSTFLAG)
3436
3437
3438 ## FIXME? The logic here is not precisely the same as that above.
3439 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3440 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3441 LIB_GCC=
3442 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3443
3444   case "$opsys" in
3445     freebsd|netbsd|openbsd) LIB_GCC= ;;
3446
3447     gnu-*)
3448       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3449       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3450       case $host_cpu in
3451       arm*)
3452         LIB_GCC="-lgcc_s"
3453         ;;
3454       *)
3455         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3456         ## immediately undefine it again and redefine it to empty.
3457         ## Was the C_SWITCH_X_SITE part really necessary?
3458 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3459         LIB_GCC=
3460         ;;
3461       esac
3462       ;;
3463
3464     ## Ask GCC where to find libgcc.a.
3465     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3466   esac
3467 fi                              dnl if $GCC
3468 AC_SUBST(LIB_GCC)
3469
3470
3471 ## If we're using X11/GNUstep, define some consequences.
3472 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3473   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3474   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3475 fi
3476
3477
3478 AH_TOP([/* GNU Emacs site configuration template file.
3479
3480 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2011
3481   Free Software Foundation, Inc.
3482
3483 This file is part of GNU Emacs.
3484
3485 GNU Emacs is free software: you can redistribute it and/or modify
3486 it under the terms of the GNU General Public License as published by
3487 the Free Software Foundation, either version 3 of the License, or
3488 (at your option) any later version.
3489
3490 GNU Emacs is distributed in the hope that it will be useful,
3491 but WITHOUT ANY WARRANTY; without even the implied warranty of
3492 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3493 GNU General Public License for more details.
3494
3495 You should have received a copy of the GNU General Public License
3496 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3497
3498
3499 /* No code in Emacs #includes config.h twice, but some bits of code
3500    intended to work with other packages as well (like gmalloc.c)
3501    think they can include it as many times as they like.  */
3502 #ifndef EMACS_CONFIG_H
3503 #define EMACS_CONFIG_H
3504 ])dnl
3505
3506 AH_BOTTOM([
3507 /* On AIX 3 this must be included before any other include file.  */
3508 #include <alloca.h>
3509 #if ! HAVE_ALLOCA
3510 # error "alloca not available on this machine"
3511 #endif
3512
3513 /* Define AMPERSAND_FULL_NAME if you use the convention
3514    that & in the full name stands for the login id.  */
3515 /* Turned on June 1996 supposing nobody will mind it.  */
3516 #define AMPERSAND_FULL_NAME
3517
3518 /* `subprocesses' should be defined if you want to
3519    have code for asynchronous subprocesses
3520    (as used in M-x compile and M-x shell).
3521    Only MSDOS does not support this (it overrides
3522    this in its config_opsysfile below).  */
3523
3524 #define subprocesses
3525
3526 /* Include the os and machine dependent files.  */
3527 #include config_opsysfile
3528 #ifdef config_machfile
3529 # include config_machfile
3530 #endif
3531
3532 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3533    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3534   (There is probably a better place to do this, but right now the
3535    Cocoa side does this in s/darwin.h and we cannot parallel this
3536    exactly since GNUstep is multi-OS.  */
3537 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3538 #  define SYSTEM_PURESIZE_EXTRA 30000
3539 #endif
3540
3541 #ifdef emacs /* Don't do this for lib-src.  */
3542 /* Tell regex.c to use a type compatible with Emacs.  */
3543 #define RE_TRANSLATE_TYPE Lisp_Object
3544 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3545 #ifdef make_number
3546 /* If make_number is a macro, use it.  */
3547 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3548 #else
3549 /* If make_number is a function, avoid it.  */
3550 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3551 #endif
3552 #endif
3553
3554 /* These default definitions are good for almost all machines.
3555    Any exceptions should override them in m/MACHINE.h.
3556    They must be usable in preprocessor conditionals.  */
3557
3558 #ifndef BITS_PER_CHAR
3559 #define BITS_PER_CHAR 8
3560 #endif
3561
3562 #ifndef BITS_PER_SHORT
3563 #define BITS_PER_SHORT 16
3564 #endif
3565
3566 #ifndef BITS_PER_INT
3567 #define BITS_PER_INT 32
3568 #endif
3569
3570 #ifndef BITS_PER_LONG
3571 #ifdef _LP64
3572 #define BITS_PER_LONG 64
3573 #else
3574 #define BITS_PER_LONG 32
3575 #endif
3576 #endif
3577
3578 #if !defined BITS_PER_LONG_LONG && HAVE_LONG_LONG_INT
3579 #define BITS_PER_LONG_LONG 64
3580 #endif
3581
3582 /* Define if the compiler supports function prototypes.  It may do so but
3583    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3584 #undef PROTOTYPES
3585
3586 #include <string.h>
3587 #include <stdlib.h>
3588
3589 #ifndef HAVE_STRCHR
3590 #define strchr(a, b) index (a, b)
3591 #endif
3592
3593 #ifndef HAVE_STRRCHR
3594 #define strrchr(a, b) rindex (a, b)
3595 #endif
3596
3597 #if defined __GNUC__ && (__GNUC__ > 2 \
3598                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3599 #define NO_RETURN       __attribute__ ((__noreturn__))
3600 #else
3601 #define NO_RETURN       /* nothing */
3602 #endif
3603
3604 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3605 #define NO_INLINE __attribute__((noinline))
3606 #else
3607 #define NO_INLINE
3608 #endif
3609
3610 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3611 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3612 #else
3613 #define EXTERNALLY_VISIBLE
3614 #endif
3615
3616 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3617 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3618 #else
3619 # define ATTRIBUTE_FORMAT(spec) /* empty */
3620 #endif
3621
3622 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3623 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3624    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3625 #else
3626 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3627    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3628 #endif
3629
3630 /* Some versions of GNU/Linux define noinline in their headers.  */
3631 #ifdef noinline
3632 #undef noinline
3633 #endif
3634
3635 /* These won't be used automatically yet.  We also need to know, at least,
3636    that the stack is continuous.  */
3637 #ifdef __GNUC__
3638 #  ifndef GC_SETJMP_WORKS
3639   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3640 #    define GC_SETJMP_WORKS 1
3641 #  endif
3642 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3643 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3644 #  endif
3645 #endif
3646
3647 #endif /* EMACS_CONFIG_H */
3648
3649 /*
3650 Local Variables:
3651 mode: c
3652 End:
3653 */
3654 ])dnl
3655
3656 #### Report on what we decided to do.
3657 #### Report GTK as a toolkit, even if it doesn't use Xt.
3658 #### It makes printing result more understandable as using GTK sets
3659 #### toolkit_scroll_bars to yes by default.
3660 if test "${HAVE_GTK}" = "yes"; then
3661   USE_X_TOOLKIT=GTK
3662 fi
3663
3664 and_machfile=
3665 if test -n "$machfile"; then
3666   and_machfile=" and \`${machfile}'"
3667 fi
3668
3669 echo "
3670 Configured for \`${canonical}'.
3671
3672   Where should the build process find the source code?    ${srcdir}
3673   What operating system and machine description files should Emacs use?
3674         \`${opsysfile}'${and_machfile}
3675   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3676   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3677   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3678   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3679   What window system should Emacs use?                    ${window_system}
3680   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3681
3682 if test -n "${x_includes}"; then
3683 echo "  Where do we find X Windows header files?                ${x_includes}"
3684 else
3685 echo "  Where do we find X Windows header files?                Standard dirs"
3686 fi
3687 if test -n "${x_libraries}"; then
3688 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3689 else
3690 echo "  Where do we find X Windows libraries?                   Standard dirs"
3691 fi
3692
3693 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3694 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3695 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3696 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3697 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3698 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3699 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3700 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3701
3702 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3703 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3704 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3705 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3706 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3707 echo "  Does Emacs use -lgnutls (2.6.x or higher)?              ${HAVE_GNUTLS}"
3708 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3709
3710 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3711 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3712 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3713 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3714
3715 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3716 echo
3717
3718 if test $USE_XASSERTS = yes; then
3719    echo "  Compiling with asserts turned on."
3720    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3721 fi
3722
3723 echo
3724
3725 if test "$HAVE_NS" = "yes"; then
3726    echo
3727    echo "You must run \"make install\" in order to test the built application.
3728 The installed application will go to nextstep/Emacs.app and can be
3729 run or moved from there."
3730    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3731       echo "The application will be fully self-contained."
3732     else
3733       echo "The lisp resources for the application will be installed under ${prefix}.
3734 You may need to run \"make install\" with sudo.  The application will fail
3735 to run if these resources are not installed."
3736    fi
3737    echo
3738 fi
3739
3740
3741 # Remove any trailing slashes in these variables.
3742 [test "${prefix}" != NONE &&
3743   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3744 test "${exec_prefix}" != NONE &&
3745   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3746
3747 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3748 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3749 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3750 dnl (else you get "no `Makefile.am' found for any configure output").
3751 dnl This will work, but you get a config.status that is not quite right
3752 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3753 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3754 dnl it seems better to just live with the duplication.
3755 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3756
3757 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3758        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3759        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3760        leim/Makefile])
3761
3762 dnl test/ is not present in release tarfiles.
3763 opt_makefile=test/automated/Makefile
3764
3765 if test -f $srcdir/${opt_makefile}.in; then
3766   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3767   dnl Again, it's best not to use a variable.  Though you can add
3768   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3769   AC_CONFIG_FILES([test/automated/Makefile])
3770 fi
3771
3772 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3773
3774 AC_SUBST(SUBDIR_MAKEFILES_IN)
3775
3776 dnl Make the necessary directories, if they don't exist.
3777 AC_CONFIG_COMMANDS([mkdirs], [
3778 for dir in etc lisp ; do
3779   test -d ${dir} || mkdir ${dir}
3780 done
3781 ])
3782
3783 dnl You might wonder (I did) why epaths.h is generated by running make,
3784 dnl rather than just letting configure generate it from epaths.in.
3785 dnl One reason is that the various paths are not fully expanded (see above);
3786 dnl eg gamedir=${prefix}/var/games/emacs.
3787 dnl Secondly, the GNU Coding standards require that one should be able
3788 dnl to run `make prefix=/some/where/else' and override the values set
3789 dnl by configure.  This also explains the `move-if-change' test and
3790 dnl the use of force in the `epaths-force' rule in Makefile.in.
3791 AC_CONFIG_COMMANDS([epaths], [
3792 echo creating src/epaths.h
3793 ${MAKE-make} epaths-force
3794 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3795
3796 AC_CONFIG_COMMANDS([gdbinit], [
3797 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3798   echo creating src/.gdbinit
3799   echo source $srcdir/src/.gdbinit > src/.gdbinit
3800 fi
3801 ])
3802
3803 AC_OUTPUT
3804
3805 dnl configure.in ends here