lisp/textmodes/reftex-dcr.el

   1 ;;; reftex-dcr.el --- viewing cross references and citations with RefTeX
   2
   3 ;; Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Carsten Dominik <dominik@science.uva.nl>
   7 ;; Maintainer: auctex-devel@gnu.org
   8 ;; Version: 4.31
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (eval-when-compile (require 'cl))
  32 (provide 'reftex-dcr)
  33 (provide 'reftex-vcr)
  34 (require 'reftex)
  35 ;;;
  36
  37 (defun reftex-view-crossref (&optional arg auto-how fail-quietly)
  38   "View cross reference of macro at point.  Point must be on the KEY
  39 argument.  When at at `\\ref' macro, show corresponding `\\label'
  40 definition, also in external documents (`xr').  When on a label, show
  41 a locations where KEY is referenced.  Subsequent calls find additional
  42 locations.  When on a `\\cite', show the associated `\\bibitem' macro or
  43 the BibTeX database entry.  When on a `\\bibitem', show a `\\cite' macro
  44 which uses this KEY. When on an `\\index', show other locations marked
  45 by the same index entry.
  46 To define additional cross referencing items, use the option
  47 `reftex-view-crossref-extra'.  See also `reftex-view-crossref-from-bibtex'.
  48 With one or two C-u prefixes, enforce rescanning of the document.
  49 With argument 2, select the window showing the cross reference.
  50 AUTO-HOW is only for the automatic crossref display and is handed through
  51 to the functions `reftex-view-cr-cite' and `reftex-view-cr-ref'."
  52
  53   (interactive "P")
  54   ;; See where we are.
  55   (let* ((macro (car (reftex-what-macro-safe 1)))
  56          (key (reftex-this-word "^{}%\n\r, \t"))
  57          dw)
  58
  59     (if (or (null macro) (reftex-in-comment))
  60         (or fail-quietly
  61             (error "Not on a crossref macro argument"))
  62
  63       (setq reftex-call-back-to-this-buffer (current-buffer))
  64
  65       (cond
  66        ((string-match "\\`\\\\cite\\|cite\\*?\\'\\|bibentry" macro)
  67         ;; A citation macro: search for bibitems or BibTeX entries
  68         (setq dw (reftex-view-cr-cite arg key auto-how)))
  69        ((string-match "\\`\\\\ref\\|ref\\(range\\)?\\*?\\'" macro)
  70         ;; A reference macro: search for labels
  71         (setq dw (reftex-view-cr-ref arg key auto-how)))
  72        (auto-how nil)  ;; No further action for automatic display (speed)
  73        ((or (equal macro "\\label")
  74             (member macro reftex-macros-with-labels))
  75         ;; A label macro: search for reference macros
  76         (reftex-access-scan-info arg)
  77         (setq dw (reftex-view-regexp-match
  78                   (format reftex-find-reference-format (regexp-quote key))
  79                   4 nil nil)))
  80        ((equal macro "\\bibitem")
  81         ;; A bibitem macro: search for citations
  82         (reftex-access-scan-info arg)
  83         (setq dw (reftex-view-regexp-match
  84                   (format reftex-find-citation-regexp-format (regexp-quote key))
  85                   4 nil nil)))
  86        ((member macro reftex-macros-with-index)
  87         (reftex-access-scan-info arg)
  88         (setq dw (reftex-view-regexp-match
  89                   (format reftex-find-index-entry-regexp-format
  90                           (regexp-quote key))
  91                   3 nil nil)))
  92        (t
  93         (reftex-access-scan-info arg)
  94         (catch 'exit
  95           (let ((list reftex-view-crossref-extra)
  96                 entry mre action group)
  97             (while (setq entry (pop list))
  98               (setq mre (car entry)
  99                     action (nth 1 entry)
 100                     group (nth 2 entry))
 101               (when (string-match mre macro)
 102                 (setq dw (reftex-view-regexp-match
 103                           (format action key) group nil nil))
 104                 (throw 'exit t))))
 105           (error "Not on a crossref macro argument"))))
 106       (if (and (eq arg 2) (windowp dw)) (select-window dw)))))
 107
 108 (defun reftex-view-cr-cite (arg key how)
 109   ;; View crossreference of a ref cite.  HOW can have the values
 110   ;; nil:         Show in another window.
 111   ;; echo:        Show one-line info in echo area.
 112   ;; tmp-window:  Show in small window and arrange for window to disappear.
 113
 114   ;; Ensure access to scanning info
 115   (reftex-access-scan-info (or arg current-prefix-arg))
 116
 117   (if (eq how 'tmp-window)
 118       ;; Remember the window configuration
 119       (put 'reftex-auto-view-crossref 'last-window-conf
 120            (current-window-configuration)))
 121
 122   (let (files size item (pos (point)) (win (selected-window)) pop-win
 123               (bibtype (reftex-bib-or-thebib)))
 124     ;; Find the citation mode and the file list
 125     (cond
 126 ;     ((assq 'bib (symbol-value reftex-docstruct-symbol))
 127      ((eq bibtype 'bib)
 128       (setq item nil
 129             files (reftex-get-bibfile-list)))
 130 ;     ((assq 'thebib (symbol-value reftex-docstruct-symbol))
 131      ((eq bibtype 'thebib)
 132       (setq item t
 133             files (reftex-uniquify
 134                    (mapcar 'cdr
 135                            (reftex-all-assq
 136                             'thebib (symbol-value reftex-docstruct-symbol))))))
 137      (reftex-default-bibliography
 138       (setq item nil
 139             files (reftex-default-bibliography)))
 140      (how)  ;; don't throw for special display
 141      (t (error "Cannot display crossref")))
 142
 143     (if (eq how 'echo)
 144         ;; Display in Echo area
 145         (reftex-echo-cite key files item)
 146       ;; Display in a window
 147       (if (not (eq how 'tmp-window))
 148           ;; Normal display
 149           (reftex-pop-to-bibtex-entry key files nil t item)
 150         ;; A temporary window
 151         (condition-case nil
 152             (reftex-pop-to-bibtex-entry key files nil t item)
 153           (error (goto-char pos)
 154                  (message "cite: no such citation key %s" key)
 155                  (error "")))
 156         ;; Resize the window
 157         (setq size (max 1 (count-lines (point)
 158                                        (reftex-end-of-bib-entry item))))
 159         (let ((window-min-height 2))
 160           (shrink-window (1- (- (window-height) size)))
 161           (recenter 0))
 162         ;; Arrange restoration
 163         (add-hook 'pre-command-hook 'reftex-restore-window-conf))
 164
 165         ;; Normal display in other window
 166       (add-hook 'pre-command-hook 'reftex-highlight-shall-die)
 167       (setq pop-win (selected-window))
 168       (select-window win)
 169       (goto-char pos)
 170       (when (equal arg 2)
 171         (select-window pop-win)))))
 172
 173 (defun reftex-view-cr-ref (arg label how)
 174   ;; View crossreference of a ref macro.  HOW can have the values
 175   ;; nil:         Show in another window.
 176   ;; echo:        Show one-line info in echo area.
 177   ;; tmp-window:  Show in small window and arrange for window to disappear.
 178
 179   ;; Ensure access to scanning info
 180   (reftex-access-scan-info (or arg current-prefix-arg))
 181
 182   (if (eq how 'tmp-window)
 183       ;; Remember the window configuration
 184       (put 'reftex-auto-view-crossref 'last-window-conf
 185            (current-window-configuration)))
 186
 187   (let* ((xr-data (assoc 'xr (symbol-value reftex-docstruct-symbol)))
 188          (xr-re (nth 2 xr-data))
 189          (entry (assoc label (symbol-value reftex-docstruct-symbol)))
 190          (win (selected-window)) pop-win (pos (point)))
 191
 192     (if (and (not entry) (stringp label) xr-re (string-match xr-re label))
 193         ;; Label is defined in external document
 194         (save-excursion
 195           (save-match-data
 196             (set-buffer
 197              (or (reftex-get-file-buffer-force
 198                   (cdr (assoc (match-string 1 label) (nth 1
 199                                                           xr-data))))
 200                  (error "Problem with external label %s" label))))
 201           (setq label (substring label (match-end 1)))
 202           (reftex-access-scan-info)
 203           (setq entry
 204                 (assoc label (symbol-value reftex-docstruct-symbol)))))
 205     (if (eq how 'echo)
 206         ;; Display in echo area
 207         (reftex-echo-ref label entry (symbol-value reftex-docstruct-symbol))
 208       (let ((window-conf (current-window-configuration)))
 209         (condition-case nil
 210             (reftex-show-label-location entry t nil t t)
 211           (error (set-window-configuration window-conf)
 212                  (message "ref: Label %s not found" label)
 213                  (error "ref: Label %s not found" label)))) ;; 2nd is line OK
 214       (add-hook 'pre-command-hook 'reftex-highlight-shall-die)
 215
 216       (when (eq how 'tmp-window)
 217         ;; Resize window and arrange restauration
 218         (shrink-window (1- (- (window-height) 9)))
 219         (recenter '(4))
 220         (add-hook 'pre-command-hook 'reftex-restore-window-conf))
 221       (setq pop-win (selected-window))
 222       (select-window win)
 223       (goto-char pos)
 224       (when (equal arg 2)
 225         (select-window pop-win)))))
 226
 227 (defun reftex-mouse-view-crossref (ev)
 228   "View cross reference of \\ref or \\cite macro where you click.
 229 If the macro at point is a \\ref, show the corresponding label definition.
 230 If it is a \\cite, show the BibTeX database entry.
 231 If there is no such macro at point, search forward to find one.
 232 With argument, actually select the window showing the cross reference."
 233   (interactive "e")
 234   (mouse-set-point ev)
 235   (reftex-view-crossref current-prefix-arg))
 236
 237 (defun reftex-view-crossref-when-idle ()
 238   ;; Display info about crossref at point in echo area or a window.
 239   ;; This function was desigend to work with an idle timer.
 240   ;; We try to get out of here as quickly as possible if the call is useless.
 241   (and reftex-mode
 242        ;; Make sure message area is free if we need it.
 243        (or (eq reftex-auto-view-crossref 'window) (not (current-message)))
 244        ;; Make sure we are not already displaying this one
 245        (not (memq last-command '(reftex-view-crossref
 246                                  reftex-mouse-view-crossref)))
 247        ;; Quick precheck if this might be a relevant spot
 248        ;; `reftex-view-crossref' will do a more thorough check.
 249        (save-excursion
 250          (search-backward "\\" nil t)
 251          (looking-at "\\\\[a-zA-Z]*\\(cite\\|ref\\|bibentry\\)"))
 252
 253        (condition-case nil
 254            (let ((current-prefix-arg nil))
 255              (cond
 256               ((eq reftex-auto-view-crossref t)
 257                (reftex-view-crossref -1 'echo 'quiet))
 258               ((eq reftex-auto-view-crossref 'window)
 259                (reftex-view-crossref -1 'tmp-window 'quiet))
 260               (t nil)))
 261          (error nil))))
 262
 263 (defun reftex-restore-window-conf ()
 264   (set-window-configuration (get 'reftex-auto-view-crossref 'last-window-conf))
 265   (put 'reftex-auto-view-crossref 'last-window-conf nil)
 266   (remove-hook 'pre-command-hook 'reftex-restore-window-conf))
 267
 268 (defun reftex-echo-ref (label entry docstruct)
 269   ;; Display crossref info in echo area.
 270   (cond
 271    ((null docstruct)
 272     (message "%s"
 273              (substitute-command-keys (format reftex-no-info-message "ref"))))
 274    ((null entry)
 275     (message "ref: unknown label: %s" label))
 276    (t
 277     (when (stringp (nth 2 entry))
 278       (message "ref(%s): %s" (nth 1 entry) (nth 2 entry)))
 279     (let ((buf (get-buffer " *Echo Area*")))
 280       (when buf
 281         (save-excursion
 282           (set-buffer buf)
 283           (run-hooks 'reftex-display-copied-context-hook)))))))
 284
 285 (defun reftex-echo-cite (key files item)
 286   ;; Display citation info in echo area.
 287   (let* ((cache (assq 'bibview-cache (symbol-value reftex-docstruct-symbol)))
 288          (cache-entry (assoc key (cdr cache)))
 289          entry string buf (all-files files))
 290
 291     (if (and reftex-cache-cite-echo cache-entry)
 292         ;; We can just use the cache
 293         (setq string (cdr cache-entry))
 294
 295       ;; Need to look in the database
 296       (unless reftex-revisit-to-echo
 297         (setq files (reftex-visited-files files)))
 298
 299       (setq entry
 300             (condition-case nil
 301                 (save-excursion
 302                   (reftex-pop-to-bibtex-entry key files nil nil item t))
 303               (error
 304                (if (and files (= (length all-files) (length files)))
 305                    (message "cite: no such database entry: %s" key)
 306                  (message "%s" (substitute-command-keys
 307                                 (format reftex-no-info-message "cite"))))
 308                nil)))
 309       (when entry
 310         (if item
 311             (setq string (reftex-nicify-text entry))
 312           (setq string (reftex-make-cite-echo-string
 313                         (reftex-parse-bibtex-entry entry)
 314                         reftex-docstruct-symbol)))))
 315     (unless (or (null string) (equal string ""))
 316       (message "cite: %s" string))
 317     (when (setq buf (get-buffer " *Echo Area*"))
 318       (save-excursion
 319         (set-buffer buf)
 320         (run-hooks 'reftex-display-copied-context-hook)))))
 321
 322 (defvar reftex-use-itimer-in-xemacs nil
 323   "*Non-nil means use the idle timers in XEmacs for crossref display.
 324 Currently, idle timer restart is broken and we use the post-command-hook.")
 325
 326 (defun reftex-toggle-auto-view-crossref ()
 327   "Toggle the automatic display of crossref information in the echo area.
 328 When active, leaving point idle in the argument of a \\ref or \\cite macro
 329 will display info in the echo area."
 330   (interactive)
 331   (if reftex-auto-view-crossref-timer
 332       (progn
 333         (if (featurep 'xemacs)
 334             (if reftex-use-itimer-in-xemacs
 335                 (delete-itimer reftex-auto-view-crossref-timer)
 336               (remove-hook 'post-command-hook 'reftex-start-itimer-once))
 337           (cancel-timer reftex-auto-view-crossref-timer))
 338         (setq reftex-auto-view-crossref-timer nil)
 339         (message "Automatic display of crossref information was turned off"))
 340     (setq reftex-auto-view-crossref-timer
 341           (if (featurep 'xemacs)
 342               (if reftex-use-itimer-in-xemacs
 343                   (start-itimer "RefTeX Idle Timer"
 344                                 'reftex-view-crossref-when-idle
 345                                 reftex-idle-time reftex-idle-time t)
 346                 (add-hook 'post-command-hook 'reftex-start-itimer-once)
 347                 t)
 348             (run-with-idle-timer
 349              reftex-idle-time t 'reftex-view-crossref-when-idle)))
 350     (unless reftex-auto-view-crossref
 351       (setq reftex-auto-view-crossref t))
 352     (message "Automatic display of crossref information was turned on")))
 353
 354 (defun reftex-start-itimer-once ()
 355    (and (featurep 'xemacs) reftex-mode
 356         (not (itimer-live-p reftex-auto-view-crossref-timer))
 357         (setq reftex-auto-view-crossref-timer
 358               (start-itimer "RefTeX Idle Timer"
 359                             'reftex-view-crossref-when-idle
 360                             reftex-idle-time nil t))))
 361
 362 (declare-function bibtex-beginning-of-entry "bibtex" ())
 363
 364 (defun reftex-view-crossref-from-bibtex (&optional arg)
 365   "View location in a LaTeX document which cites the BibTeX entry at point.
 366 Since BibTeX files can be used by many LaTeX documents, this function
 367 prompts upon first use for a buffer in RefTeX mode.  To reset this
 368 link to a document, call the function with with a prefix arg.
 369 Calling this function several times find successive citation locations."
 370   (interactive "P")
 371   (when arg
 372     ;; Break connection to reference buffer
 373     (put 'reftex-bibtex-view-cite-locations :ref-buffer nil))
 374   (let ((ref-buffer (get 'reftex-bibtex-view-cite-locations :ref-buffer)))
 375     ;; Establish connection to reference buffer
 376     (unless ref-buffer
 377       (setq ref-buffer
 378             (save-excursion
 379               (completing-read
 380                "Reference buffer: "
 381                (delq nil
 382                      (mapcar
 383                       (lambda (b)
 384                         (set-buffer b)
 385                         (if reftex-mode (list (buffer-name b)) nil))
 386                       (buffer-list)))
 387                nil t)))
 388       (put 'reftex-bibtex-view-cite-locations :ref-buffer ref-buffer))
 389     ;; Search for citations
 390     (bibtex-beginning-of-entry)
 391     (if (looking-at
 392          "@[a-zA-Z]+[ \t\n\r]*[{(][ \t\n\r]*\\([^, \t\r\n}]+\\)")
 393         (progn
 394           (goto-char (match-beginning 1))
 395           (reftex-view-regexp-match
 396            (format reftex-find-citation-regexp-format
 397                    (regexp-quote (match-string 1)))
 398            4 arg ref-buffer))
 399       (error "Cannot find citation key in BibTeX entry"))))
 400
 401 (defun reftex-view-regexp-match (re &optional highlight-group new ref-buffer)
 402   ;; Search for RE in current document or in the document of REF-BUFFER.
 403   ;; Continue the search, if the same re was searched last.
 404   ;; Highlight the group HIGHLIGHT-GROUP of the match.
 405   ;; When NEW is non-nil, start a new search regardless.
 406   ;; Match point is displayed in another window.
 407   ;; Upon success, returns the window which displays the match.
 408
 409   ;;; Decide if new search or continued search
 410   (let* ((oldprop (get 'reftex-view-regexp-match :props))
 411          (newprop (list (current-buffer) re))
 412          (cont (and (not new) (equal oldprop newprop)))
 413          (cnt (if cont (get 'reftex-view-regexp-match :cnt) 0))
 414          (current-window (selected-window))
 415          (window-conf (current-window-configuration))
 416          match pop-window)
 417     (switch-to-buffer-other-window (or ref-buffer (current-buffer)))
 418     ;; Search
 419     (condition-case nil
 420         (if cont
 421             (setq match (reftex-global-search-continue))
 422           (reftex-access-scan-info)
 423           (setq match (reftex-global-search re (reftex-all-document-files))))
 424       (error nil))
 425     ;; Evaluate the match.
 426     (if match
 427         (progn
 428           (put 'reftex-view-regexp-match :props newprop)
 429           (put 'reftex-view-regexp-match :cnt (incf cnt))
 430           (reftex-highlight 0 (match-beginning highlight-group)
 431                             (match-end highlight-group))
 432           (add-hook 'pre-command-hook 'reftex-highlight-shall-die)
 433           (setq pop-window (selected-window)))
 434       (put 'reftex-view-regexp-match :props nil)
 435       (or cont (set-window-configuration window-conf)))
 436     (select-window current-window)
 437     (if match
 438         (progn
 439           (message "Match Nr. %s" cnt)
 440           pop-window)
 441       (if cont
 442           (error "No further matches (total number of matches: %d)" cnt)
 443         (error "No matches")))))
 444
 445 (defvar reftex-global-search-marker (make-marker))
 446 (defun reftex-global-search (regexp file-list)
 447   ;; Start a search for REGEXP in all files of FILE-LIST
 448   (put 'reftex-global-search :file-list file-list)
 449   (put 'reftex-global-search :regexp regexp)
 450   (move-marker reftex-global-search-marker nil)
 451   (reftex-global-search-continue))
 452
 453 (defun reftex-global-search-continue ()
 454   ;; Continue a global search started with `reftex-global-search'
 455   (unless (get 'reftex-global-search :file-list)
 456     (error "No global search to continue"))
 457   (let* ((file-list (get 'reftex-global-search :file-list))
 458          (regexp (get 'reftex-global-search :regexp))
 459          (buf (or (marker-buffer reftex-global-search-marker)
 460                   (reftex-get-file-buffer-force (car file-list))))
 461          (pos (or (marker-position reftex-global-search-marker) 1))
 462          file)
 463     ;; Take up starting position
 464     (unless buf (error "No such buffer %s" buf))
 465     (switch-to-buffer buf)
 466     (widen)
 467     (goto-char pos)
 468     ;; Search and switch file if necessary
 469     (if (catch 'exit
 470           (while t
 471             (when (re-search-forward regexp nil t)
 472               (move-marker reftex-global-search-marker (point))
 473               (throw 'exit t))
 474             ;; No match - goto next file
 475             (pop file-list)
 476             (or file-list (throw 'exit nil))
 477             (setq file (car file-list)
 478                   buf (reftex-get-file-buffer-force file))
 479             (unless buf (error "Cannot access file %s" file))
 480             (put 'reftex-global-search :file-list file-list)
 481             (switch-to-buffer buf)
 482             (widen)
 483             (goto-char 1)))
 484         t
 485       (move-marker reftex-global-search-marker nil)
 486       (error "All files processed"))))
 487
 488 ;; arch-tag: d2f52b56-744e-44ad-830d-1fc193b90eda
 489 ;;; reftex-dcr.el ends here