configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.62)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 lispdir='${datadir}/emacs/${version}/lisp'
  36 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  37 '${datadir}/emacs/site-lisp'
  38 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  39 etcdir='${datadir}/emacs/${version}/etc'
  40 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  41 docdir='${datadir}/emacs/${version}/etc'
  42 gamedir='${localstatedir}/games/emacs'
  43
  44 gameuser=games
  45
  46 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  47 dnl Create a new --with option that defaults to being disabled.
  48 dnl NAME is the base name of the option.  The shell variable with_NAME
  49 dnl   will be set to either the user's value (if the option is
  50 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  51 dnl   option is not specified).  Note that the shell variable name is
  52 dnl   constructed as autoconf does, by replacing non-alphanumeric
  53 dnl   characters with "_".
  54 dnl HELP-STRING is the help text for the option.
  55 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  56   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  57     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  58 ])dnl
  59
  60 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  61 dnl Create a new --with option that defaults to being enabled.  NAME
  62 dnl   is the base name of the option.  The shell variable with_NAME
  63 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  64 dnl   'yes' (if the option is not specified).  Note that the shell
  65 dnl   variable name is constructed as autoconf does, by replacing
  66 dnl   non-alphanumeric characters with "_".
  67 dnl HELP-STRING is the help text for the option.
  68 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  69   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  70    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  71 ])dnl
  72
  73 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  74 if test "$with_pop" = yes; then
  75    AC_DEFINE(MAIL_USE_POP)
  76 fi
  77 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  78
  79 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  80 if test "$with_kerberos" != no; then
  81    AC_DEFINE(KERBEROS)
  82 fi
  83 AH_TEMPLATE(KERBEROS,
  84             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  85
  86 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  87 if test "${with_kerberos5}" != no; then
  88   if test "${with_kerberos}" = no; then
  89     with_kerberos=yes
  90     AC_DEFINE(KERBEROS)
  91   fi
  92   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  93 fi
  94
  95 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  96 dnl FIXME hesiod support may not be present, so it seems like an error
  97 dnl to define, or at least use, this unconditionally.
  98 if test "$with_hesiod" != no; then
  99   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 100 fi
 101
 102 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 103 if test "$with_mmdf" != no; then
 104    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 105 fi
 106
 107 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 108 if test "$with_mail_unlink" != no; then
 109    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 110 fi
 111
 112 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 113     [string giving default POP mail host])],
 114     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 115
 116 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 117
 118 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 119 if test "$with_sync_input" = yes; then
 120    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 121 fi
 122
 123 dnl FIXME currently it is not the last.
 124 dnl This should be the last --with option, because --with-x is
 125 dnl added later on when we find the path of X, and it's best to
 126 dnl keep them together visually.
 127 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 128  [use an X toolkit (KIT one of: yes or gtk, lucid or athena, motif, no)])],
 129 [         case "${withval}" in
 130             y | ye | yes )      val=gtk ;;
 131             n | no )            val=no  ;;
 132             l | lu | luc | luci | lucid )       val=lucid ;;
 133             a | at | ath | athe | athen | athena )      val=athena ;;
 134             m | mo | mot | moti | motif )       val=motif ;;
 135             g | gt | gtk  )     val=gtk ;;
 136             * )
 137 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 138 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 139 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 140             ;;
 141           esac
 142           with_x_toolkit=$val
 143 ])
 144
 145 dnl _ON results in a '--without' option in the --help output, so
 146 dnl the help text should refer to "don't compile", etc.
 147 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 148 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 149 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 150 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 151 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 152 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 153
 154 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 155 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 156 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 157
 158 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 159 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 160 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 161 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 162
 163 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 164 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 165 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 166 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 167
 168 ## For the times when you want to build Emacs but don't have
 169 ## a suitable makeinfo, and can live without the manuals.
 170 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 171 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 172
 173 AC_ARG_WITH([pkg-config-prog],dnl
 174 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 175                   [path to pkg-config for finding GTK and librsvg])])
 176 if test "X${with_pkg_config_prog}" != X; then
 177    if test "${with_pkg_config_prog}" != yes; then
 178       PKG_CONFIG="${with_pkg_config_prog}"
 179    fi
 180 fi
 181
 182 CRT_DIR=
 183 AC_ARG_WITH([crt-dir],dnl
 184 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 185 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 186 CRT_DIR="${with_crt_dir}"
 187
 188 AC_ARG_WITH([gnustep-conf],dnl
 189 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 190 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 191   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 192 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 193      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 194
 195 AC_ARG_ENABLE(ns-self-contained,
 196 [AS_HELP_STRING([--disable-ns-self-contained],
 197                 [disable self contained build under NeXTstep])],
 198    EN_NS_SELF_CONTAINED=$enableval,
 199    EN_NS_SELF_CONTAINED=yes)
 200
 201 AC_ARG_ENABLE(asserts,
 202 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 203       USE_XASSERTS=$enableval,
 204       USE_XASSERTS=no)
 205
 206 AC_ARG_ENABLE(maintainer-mode,
 207 [AS_HELP_STRING([--enable-maintainer-mode],
 208                 [enable make rules and dependencies not useful (and sometimes
 209                  confusing) to the casual installer])],
 210       USE_MAINTAINER_MODE=$enableval,
 211       USE_MAINTAINER_MODE=no)
 212 if test $USE_MAINTAINER_MODE = yes; then
 213   MAINT=
 214 else
 215   MAINT=#
 216 fi
 217 AC_SUBST(MAINT)
 218
 219 AC_ARG_ENABLE(locallisppath,
 220 [AS_HELP_STRING([--enable-locallisppath=PATH],
 221                 [directories Emacs should search for lisp files specific
 222                  to this site])],
 223 if test "${enableval}" = "no"; then
 224   locallisppath=
 225 elif test "${enableval}" != "yes"; then
 226   locallisppath=${enableval}
 227 fi)
 228
 229 AC_ARG_ENABLE(checking,
 230 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 231                 [enable expensive run-time checks.  With LIST,
 232                  enable only specific categories of checks.
 233                  Categories are: all,yes,no.
 234                  Flags are: stringbytes, stringoverrun, stringfreelist,
 235                  xmallocoverrun, conslist])],
 236 [ac_checking_flags="${enableval}"],[])
 237 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 238 for check in $ac_checking_flags
 239 do
 240         case $check in
 241         # these set all the flags to specific states
 242         yes)            ac_enable_checking=1 ;;
 243         no)             ac_enable_checking= ;
 244                         ac_gc_check_stringbytes= ;
 245                         ac_gc_check_string_overrun= ;
 246                         ac_gc_check_string_free_list= ;
 247                         ac_xmalloc_overrun= ;
 248                         ac_gc_check_cons_list= ;;
 249         all)            ac_enable_checking=1 ;
 250                         ac_gc_check_stringbytes=1 ;
 251                         ac_gc_check_string_overrun=1 ;
 252                         ac_gc_check_string_free_list=1 ;
 253                         ac_xmalloc_overrun=1 ;
 254                         ac_gc_check_cons_list=1 ;;
 255         # these enable particular checks
 256         stringbytes)    ac_gc_check_stringbytes=1 ;;
 257         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 258         stringfreelist) ac_gc_check_string_free_list=1 ;;
 259         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 260         conslist)       ac_gc_check_cons_list=1 ;;
 261         *)      AC_MSG_ERROR(unknown check category $check) ;;
 262         esac
 263 done
 264 IFS="$ac_save_IFS"
 265
 266 if test x$ac_enable_checking != x ; then
 267   AC_DEFINE(ENABLE_CHECKING, 1,
 268 [Enable expensive run-time checking of data types?])
 269 fi
 270 if test x$ac_gc_check_stringbytes != x ; then
 271   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 272 [Define this temporarily to hunt a bug.  If defined, the size of
 273    strings is redundantly recorded in sdata structures so that it can
 274    be compared to the sizes recorded in Lisp strings.])
 275 fi
 276 if test x$ac_gc_check_stringoverrun != x ; then
 277   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 278 [Define this to check for short string overrun.])
 279 fi
 280 if test x$ac_gc_check_string_free_list != x ; then
 281   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 282 [Define this to check the string free list.])
 283 fi
 284 if test x$ac_xmalloc_overrun != x ; then
 285   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 286 [Define this to check for malloc buffer overrun.])
 287 fi
 288 if test x$ac_gc_check_cons_list != x ; then
 289   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 290 [Define this to check for errors in cons list.])
 291 fi
 292
 293 AC_ARG_ENABLE(profiling,
 294 [AS_HELP_STRING([--enable-profiling],
 295                 [build emacs with profiling support.
 296                  This might not work on all platforms])],
 297 [ac_enable_profiling="${enableval}"],[])
 298 if test x$ac_enable_profiling != x ; then
 299    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 300    PROFILING_LDFLAGS="-pg"
 301 else
 302    PROFILING_CFLAGS=
 303    PROFILING_LDFLAGS=
 304 fi
 305
 306 AC_ARG_ENABLE(autodepend,
 307 [AS_HELP_STRING([--enable-autodepend],
 308                 [automatically generate dependencies to .h-files.
 309                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 310                  found])],
 311 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 312
 313 #### Make srcdir absolute, if it isn't already.  It's important to
 314 #### avoid running the path through pwd unnecessarily, since pwd can
 315 #### give you automounter prefixes, which can go away.  We do all this
 316 #### so Emacs can find its files when run uninstalled.
 317 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 318 unset CDPATH
 319 case "${srcdir}" in
 320   /* ) ;;
 321   . )
 322     ## We may be able to use the $PWD environment variable to make this
 323     ## absolute.  But sometimes PWD is inaccurate.
 324     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 325     ## but that tested only for a well-formed and valid PWD,
 326     ## it did not object when PWD was well-formed and valid but just wrong.
 327     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 328     then
 329       srcdir="$PWD"
 330     else
 331       srcdir="`(cd ${srcdir}; pwd)`"
 332     fi
 333   ;;
 334   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 335 esac
 336
 337 #### Check if the source directory already has a configured system in it.
 338 if test `pwd` != `(cd ${srcdir} && pwd)` \
 339    && test -f "${srcdir}/src/config.h" ; then
 340   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 341    as a build directory right now; it has been configured in its own
 342    right.  To configure in another directory as well, you MUST
 343    use GNU make.  If you do not have GNU make, then you must
 344    now do `make distclean' in ${srcdir},
 345    and then run $0 again.]])
 346 fi
 347
 348 #### Given the configuration name, set machfile and opsysfile to the
 349 #### names of the m/*.h and s/*.h files we should use.
 350
 351 ### Canonicalize the configuration name.
 352
 353 AC_CANONICAL_HOST
 354 canonical=$host
 355 configuration=${host_alias-${build_alias-$host}}
 356
 357 dnl This used to use changequote, but, apart from `changequote is evil'
 358 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 359 dnl the great gob of text.  Thus it's not processed for possible expansion.
 360 dnl Just make sure the brackets remain balanced.
 361 dnl
 362 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 363 dnl indicated by comments.
 364 dnl quotation begins
 365 [
 366
 367 ### If you add support for a new configuration, add code to this
 368 ### switch statement to recognize your configuration name and select
 369 ### the appropriate operating system and machine description files.
 370
 371 ### You would hope that you could choose an m/*.h file pretty much
 372 ### based on the machine portion of the configuration name, and an s-
 373 ### file based on the operating system portion.  However, it turns out
 374 ### that each m/*.h file is pretty manufacturer-specific - for
 375 ### example mips.h is MIPS
 376 ### So we basically have to have a special case for each
 377 ### configuration name.
 378 ###
 379 ### As far as handling version numbers on operating systems is
 380 ### concerned, make sure things will fail in a fixable way.  If
 381 ### /etc/MACHINES doesn't say anything about version numbers, be
 382 ### prepared to handle anything reasonably.  If version numbers
 383 ### matter, be sure /etc/MACHINES says something about it.
 384 ###
 385 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 386 ### "System V Release 4"; he writes, "The old convention encouraged
 387 ### confusion between `system' and `release' levels'."
 388
 389 machine='' opsys='' unported=no
 390 case "${canonical}" in
 391
 392   ## FreeBSD ports
 393   *-*-freebsd* )
 394     opsys=freebsd
 395     case "${canonical}" in
 396       alpha*-*-freebsd*)        machine=alpha ;;
 397       arm*-*-freebsd*)          machine=arm ;;
 398       ia64-*-freebsd*)          machine=ia64 ;;
 399       sparc-*-freebsd*)         machine=sparc ;;
 400       sparc64-*-freebsd*)       machine=sparc ;;
 401       powerpc-*-freebsd*)       machine=macppc ;;
 402       i[3456]86-*-freebsd*)     machine=intel386 ;;
 403       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 404     esac
 405   ;;
 406
 407   ## FreeBSD kernel + glibc based userland
 408   *-*-kfreebsd*gnu* )
 409     opsys=gnu-kfreebsd
 410     case "${canonical}" in
 411       alpha*-*-kfreebsd*)       machine=alpha ;;
 412       ia64-*-kfreebsd*)         machine=ia64 ;;
 413       sparc-*-kfreebsd*)        machine=sparc ;;
 414       sparc64-*-kfreebsd*)      machine=sparc ;;
 415       powerpc-*-kfreebsd*)      machine=macppc ;;
 416       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 417       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 418     esac
 419   ;;
 420
 421   ## NetBSD ports
 422   *-*-netbsd* )
 423     opsys=netbsd
 424     case "${canonical}" in
 425       alpha*-*-netbsd*) machine=alpha ;;
 426       i[3456]86-*-netbsd*) machine=intel386 ;;
 427       mips-*-netbsd*)   machine=mips ;;
 428       mipsel-*-netbsd*) machine=mips ;;
 429       mipseb-*-netbsd*) machine=mips ;;
 430       powerpc-*-netbsd*) machine=macppc ;;
 431       sparc*-*-netbsd*) machine=sparc ;;
 432       vax-*-netbsd*)    machine=vax ;;
 433       arm-*-netbsd*)    machine=arm ;;
 434       x86_64-*-netbsd*) machine=amdx86-64 ;;
 435       hppa-*-netbsd*)   machine=hp800 ;;
 436       m68k-*-netbsd*)   machine=m68k ;;
 437     esac
 438   ;;
 439
 440   ## OpenBSD ports
 441   *-*-openbsd* )
 442     opsys=openbsd
 443     case "${canonical}" in
 444       alpha*-*-openbsd*)        machine=alpha ;;
 445       arm-*-openbsd*)          machine=arm ;;
 446       i386-*-openbsd*)         machine=intel386 ;;
 447       powerpc-*-openbsd*)      machine=macppc ;;
 448       sparc*-*-openbsd*)       machine=sparc ;;
 449       vax-*-openbsd*)          machine=vax ;;
 450       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 451       hppa-*-openbsd*)         machine=hp800 ;;
 452     esac
 453   ;;
 454
 455   alpha*-*-linux-gnu* )
 456     machine=alpha opsys=gnu-linux
 457   ;;
 458
 459   arm*-*-linux-gnu* )
 460     machine=arm opsys=gnu-linux
 461   ;;
 462
 463   ## Apple Darwin / Mac OS X
 464   *-apple-darwin* )
 465     case "${canonical}" in
 466       i[3456]86-* )  machine=intel386 ;;
 467       powerpc-* )    machine=macppc ;;
 468       x86_64-* )     machine=amdx86-64 ;;
 469       * )            unported=yes ;;
 470     esac
 471     opsys=darwin
 472     # Define CPP as follows to make autoconf work correctly.
 473     CPP="${CC-cc} -E -no-cpp-precomp"
 474     # Use fink packages if available.
 475     if test -d /sw/include && test -d /sw/lib; then
 476       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 477       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 478       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 479     fi
 480   ;;
 481
 482   ## HP 9000 series 700 and 800, running HP/UX
 483   hppa*-hp-hpux10.2* )
 484     machine=hp800 opsys=hpux10-20
 485   ;;
 486   hppa*-hp-hpux1[1-9]* )
 487     machine=hp800 opsys=hpux11
 488     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 489   ;;
 490
 491   hppa*-*-linux-gnu* )
 492     machine=hp800 opsys=gnu-linux
 493   ;;
 494
 495   ## IBM machines
 496   s390-*-linux-gnu* )
 497     machine=ibms390 opsys=gnu-linux
 498   ;;
 499   s390x-*-linux-gnu* )
 500     machine=ibms390x opsys=gnu-linux
 501   ;;
 502   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 503     machine=ibmrs6000 opsys=aix4-2
 504   ;;
 505   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 506     machine=ibmrs6000 opsys=aix4-2
 507   ;;
 508   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 509     machine=ibmrs6000 opsys=aix4-2
 510   ;;
 511   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 512     machine=ibmrs6000 opsys=aix4-2
 513   ;;
 514
 515   ## Macintosh PowerPC
 516   powerpc*-*-linux-gnu* )
 517     machine=macppc opsys=gnu-linux
 518   ;;
 519
 520   ## Silicon Graphics machines
 521   ## Iris 4D
 522   mips-sgi-irix6.5 )
 523     machine=iris4d opsys=irix6-5
 524     # Without defining _LANGUAGE_C, things get masked out in the headers
 525     # so that, for instance, grepping for `free' in stdlib.h fails and
 526     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 527     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 528     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 529   ;;
 530
 531   ## Suns
 532   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 533     machine=sparc opsys=gnu-linux
 534   ;;
 535
 536   *-sun-solaris* \
 537     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 538     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 539     case "${canonical}" in
 540       i[3456]86-*-* )     machine=intel386 ;;
 541       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 542       sparc* )          machine=sparc ;;
 543       * )               unported=yes ;;
 544     esac
 545     case "${canonical}" in
 546       *-sunos5.6* | *-solaris2.6* )
 547                 opsys=sol2-6
 548                 NON_GNU_CPP=/usr/ccs/lib/cpp
 549                 RANLIB="ar -ts"
 550                 ;;
 551       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 552                 opsys=sol2-6
 553                 emacs_check_sunpro_c=yes
 554                 NON_GNU_CPP=/usr/ccs/lib/cpp
 555                 ;;
 556       *-sunos5* | *-solaris* )
 557                 opsys=sol2-10
 558                 emacs_check_sunpro_c=yes
 559                 NON_GNU_CPP=/usr/ccs/lib/cpp
 560                 ;;
 561     esac
 562     ## Watch out for a compiler that we know will not work.
 563     case "${canonical}" in
 564      *-solaris* | *-sunos5* )
 565                 if [ "x$CC" = x/usr/ucb/cc ]; then
 566                   ## /usr/ucb/cc doesn't work;
 567                   ## we should find some other compiler that does work.
 568                   unset CC
 569                 fi
 570                 ;;
 571       *) ;;
 572     esac
 573   ;;
 574
 575   ## IA-64
 576   ia64*-*-linux* )
 577     machine=ia64 opsys=gnu-linux
 578   ;;
 579
 580   ## Intel 386 machines where we don't care about the manufacturer
 581   i[3456]86-*-* )
 582     machine=intel386
 583     case "${canonical}" in
 584       *-cygwin )                opsys=cygwin ;;
 585       *-darwin* )               opsys=darwin
 586                                 CPP="${CC-cc} -E -no-cpp-precomp"
 587                                 ;;
 588       *-linux-gnu* )            opsys=gnu-linux ;;
 589       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 590       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 591       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 592       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 593     esac
 594   ;;
 595
 596   ## m68k Linux-based GNU system
 597   m68k-*-linux-gnu* )
 598     machine=m68k opsys=gnu-linux
 599   ;;
 600
 601   ## Mips Linux-based GNU system
 602   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 603     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 604     machine=mips opsys=gnu-linux
 605   ;;
 606
 607   ## AMD x86-64 Linux-based GNU system
 608   x86_64-*-linux-gnu* )
 609     machine=amdx86-64 opsys=gnu-linux
 610   ;;
 611
 612   ## Tensilica Xtensa Linux-based GNU system
 613   xtensa*-*-linux-gnu* )
 614     machine=xtensa opsys=gnu-linux
 615     ;;
 616
 617   ## SuperH Linux-based GNU system
 618   sh[34]*-*-linux-gnu* )
 619     machine=sh3 opsys=gnu-linux
 620   ;;
 621
 622   * )
 623     unported=yes
 624   ;;
 625 esac
 626
 627 ### If the code above didn't choose an operating system, just choose
 628 ### an operating system based on the configuration name.  You really
 629 ### only want to use this when you have no idea what the right
 630 ### operating system is; if you know what operating systems a machine
 631 ### runs, it's cleaner to make it explicit in the case statement
 632 ### above.
 633 if test x"${opsys}" = x; then
 634   case "${canonical}" in
 635     *-gnu* )                            opsys=gnu ;;
 636     * )
 637       unported=yes
 638     ;;
 639   esac
 640 fi
 641
 642 ]
 643 dnl quotation ends
 644
 645 if test $unported = yes; then
 646   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 647 Check `etc/MACHINES' for recognized configuration names.])
 648 fi
 649
 650 machfile="m/${machine}.h"
 651 opsysfile="s/${opsys}.h"
 652
 653
 654 #### Choose a compiler.
 655 test -n "$CC" && cc_specified=yes
 656
 657 # Save the value of CFLAGS that the user specified.
 658 SPECIFIED_CFLAGS="$CFLAGS"
 659
 660 dnl Sets GCC=yes if using gcc.
 661 AC_PROG_CC
 662
 663 # On Suns, sometimes $CPP names a directory.
 664 if test -n "$CPP" && test -d "$CPP"; then
 665   CPP=
 666 fi
 667
 668 ## If not using gcc, and on Solaris, and no CPP specified, see if
 669 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 670 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 671  test x"$CPP" = x; then
 672   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 673   AC_CACHE_VAL(emacs_cv_sunpro_c,
 674   [AC_TRY_LINK([],
 675 [#ifndef __SUNPRO_C
 676 fail;
 677 #endif
 678 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 679   AC_MSG_RESULT($emacs_cv_sunpro_c)
 680
 681   if test x"$emacs_cv_sunpro_c" = xyes; then
 682     NON_GNU_CPP="$CC -E -Xs"
 683   fi
 684 fi
 685
 686 #### Some systems specify a CPP to use unless we are using GCC.
 687 #### Now that we know whether we are using GCC, we can decide whether
 688 #### to use that one.
 689 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 690 then
 691   CPP="$NON_GNU_CPP"
 692 fi
 693
 694 #### Some systems specify a CC to use unless we are using GCC.
 695 #### Now that we know whether we are using GCC, we can decide whether
 696 #### to use that one.
 697 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 698   test x$cc_specified != xyes
 699 then
 700   CC="$NON_GNU_CC"
 701 fi
 702
 703 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 704 then
 705   CC="$CC $GCC_TEST_OPTIONS"
 706 fi
 707
 708 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 709 then
 710   CC="$CC $NON_GCC_TEST_OPTIONS"
 711 fi
 712
 713 dnl checks for Unix variants
 714 AC_USE_SYSTEM_EXTENSIONS
 715
 716 ### Use -Wno-pointer-sign if the compiler supports it
 717 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 718 SAVE_CFLAGS="$CFLAGS"
 719 CFLAGS="$CFLAGS -Wno-pointer-sign"
 720 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 721 if test $has_option = yes; then
 722    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 723 fi
 724 AC_MSG_RESULT($has_option)
 725 CFLAGS="$SAVE_CFLAGS"
 726 unset has_option
 727 unset SAVE_CFLAGS
 728
 729 ### Use -Wdeclaration-after-statement if the compiler supports it
 730 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 731 SAVE_CFLAGS="$CFLAGS"
 732 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 733 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 734 if test $has_option = yes; then
 735    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 736 fi
 737 AC_MSG_RESULT($has_option)
 738 CFLAGS="$SAVE_CFLAGS"
 739 unset has_option
 740 unset SAVE_CFLAGS
 741
 742 #### Some other nice autoconf tests.
 743
 744 dnl checks for programs
 745 AC_PROG_CPP
 746 AC_PROG_INSTALL
 747 if test "x$RANLIB" = x; then
 748   AC_PROG_RANLIB
 749 fi
 750
 751 ## Although we're running on an amd64 kernel, we're actually compiling for
 752 ## the x86 architecture.  The user should probably have provided an
 753 ## explicit --build to `configure', but if everything else than the kernel
 754 ## is running in i386 mode, we can help them out.
 755 if test "$machine" = "amdx86-64"; then
 756   AC_CHECK_DECL([i386])
 757   if test "$ac_cv_have_decl_i386" = "yes"; then
 758     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 759     machine=intel386
 760     machfile="m/${machine}.h"
 761   fi
 762 fi
 763
 764 AC_PATH_PROG(INSTALL_INFO, install-info)
 765 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 766 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 767 dnl Don't use GZIP, which is used by gzip for additional parameters.
 768 AC_PATH_PROG(GZIP_PROG, gzip)
 769
 770
 771 ## Need makeinfo >= 4.6 (?) to build the manuals.
 772 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 773 dnl By this stage, configure has already checked for egrep and set EGREP,
 774 dnl or exited with an error if no egrep was found.
 775 if test "$MAKEINFO" != "no" && \
 776   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 777    MAKEINFO=no
 778 fi
 779
 780 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 781 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 782 ## therefore in the category of "special tools" not normally required, which
 783 ## configure does not have to check for (eg autoconf itself).
 784 ## In a Bazaar checkout on the other hand, the manuals are not included.
 785 ## So makeinfo is a requirement to build from Bazaar, and configure
 786 ## should test for it as it does for any other build requirement.
 787 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 788 ## with pre-built manuals, from a Bazaar checkout.
 789 if test "$MAKEINFO" = "no"; then
 790   if test "x${with_makeinfo}" = "xno"; then
 791     MAKEINFO=off
 792   elif test ! -e $srcdir/info/emacs; then
 793     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 794 source tree does not seem to have pre-built manuals in the `info' directory.
 795 Either install a suitable version of makeinfo, or re-run configure
 796 with the `--without-makeinfo' option to build without the manuals.] )
 797   fi
 798 fi
 799
 800 dnl Add our options to ac_link now, after it is set up.
 801
 802 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 803 then
 804   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 805 fi
 806
 807 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 808 then
 809   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 810 fi
 811
 812 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 813 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 814 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 815 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 816 dnl if not built to support GNU ld.
 817
 818 late_LDFLAGS=$LDFLAGS
 819 if test "$GCC" = yes; then
 820   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 821 else
 822   LDFLAGS="$LDFLAGS -znocombreloc"
 823 fi
 824
 825 AC_MSG_CHECKING([for -znocombreloc])
 826 AC_LINK_IFELSE([main(){return 0;}],
 827   [AC_MSG_RESULT(yes)],
 828   LDFLAGS=$late_LDFLAGS
 829   [AC_MSG_RESULT(no)])
 830
 831 #### Extract some information from the operating system and machine files.
 832
 833 AC_CHECKING([the machine- and system-dependent files to find out
 834  - which libraries the lib-src programs will want, and
 835  - whether the GNU malloc routines are usable])
 836
 837 ### First figure out CFLAGS (which we use for running the compiler here)
 838 ### and REAL_CFLAGS (which we use for real compilation).
 839 ### The two are the same except on a few systems, where they are made
 840 ### different to work around various lossages.  For example,
 841 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 842 ### as implying static linking.
 843
 844 ### If the CFLAGS env var is specified, we use that value
 845 ### instead of the default.
 846
 847 ### It's not important that this name contain the PID; you can't run
 848 ### two configures in the same directory and have anything work
 849 ### anyway.
 850 tempcname="conftest.c"
 851
 852 echo '
 853 #include "'${srcdir}'/src/'${opsysfile}'"
 854 #include "'${srcdir}'/src/'${machfile}'"
 855
 856 configure___ LIBX=-lX11
 857
 858 configure___ unexec=UNEXEC
 859
 860 #ifdef CANNOT_DUMP
 861 configure___ cannot_dump=yes
 862 #else
 863 configure___ cannot_dump=no
 864 #endif
 865
 866 #ifdef SYSTEM_MALLOC
 867 configure___ system_malloc=yes
 868 #else
 869 configure___ system_malloc=no
 870 #endif
 871
 872 #ifdef USE_MMAP_FOR_BUFFERS
 873 configure___ use_mmap_for_buffers=yes
 874 #else
 875 configure___ use_mmap_for_buffers=no
 876 #endif
 877
 878 #ifndef C_OPTIMIZE_SWITCH
 879 #ifdef __GNUC__
 880 #define C_OPTIMIZE_SWITCH -O2
 881 #else
 882 #define C_OPTIMIZE_SWITCH -O
 883 #endif
 884 #endif
 885
 886 #ifndef C_WARNINGS_SWITCH
 887 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 888 #endif
 889
 890 #ifdef THIS_IS_CONFIGURE
 891
 892 /* Get the CFLAGS for tests in configure.  */
 893 #ifdef __GNUC__
 894 configure___ CFLAGS=-g C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 895 #else
 896 configure___ CFLAGS='${SPECIFIED_CFLAGS}'
 897 #endif
 898
 899 #else /* not THIS_IS_CONFIGURE */
 900
 901 /* Get the CFLAGS for real compilation.  */
 902 #ifdef __GNUC__
 903 configure___ REAL_CFLAGS=-g C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 904 #else
 905 configure___ REAL_CFLAGS='${SPECIFIED_CFLAGS}'
 906 #endif
 907
 908 #endif /* not THIS_IS_CONFIGURE */
 909 ' > ${tempcname}
 910
 911 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 912
 913 # The value of CPP is a quoted variable reference, so we need to do this
 914 # to get its actual value...
 915 CPP=`eval "echo $CPP"`
 916 [eval `${CPP} -Isrc ${tempcname} \
 917        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 918 if test "x$SPECIFIED_CFLAGS" = x; then
 919   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 920          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 921 else
 922   REAL_CFLAGS="$CFLAGS"
 923 fi]
 924 rm ${tempcname}
 925
 926
 927 AC_SUBST(cannot_dump)
 928
 929
 930 LD_SWITCH_SYSTEM=
 931 case "$opsys" in
 932   freebsd)
 933    ## Let `ld' find image libs and similar things in /usr/local/lib.
 934    ## The system compiler, GCC, has apparently been modified to not
 935    ## look there, contrary to what a stock GCC would do.
 936    LD_SWITCH_SYSTEM=-L/usr/local/lib
 937    ;;
 938
 939   gnu-linux)
 940    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 941    test "$machine" = "mips" && LD_SWITCH_SYSTEM="-G 0"
 942    ;;
 943
 944   netbsd)
 945    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 946    ;;
 947
 948   openbsd)
 949    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 950    ## otherwise Emacs dumps core on elf systems.
 951    LD_SWITCH_SYSTEM="-Z"
 952    ;;
 953 esac
 954 AC_SUBST(LD_SWITCH_SYSTEM)
 955
 956 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 957
 958 ## This is fun.  Some settings of LD_SWITCH_SYSTEM reference
 959 ## LD_SWITCH_X_SITE_AUX, which has not been defined yet.  When using
 960 ## cpp, it was expanded to null.  Thus LD_SWITCH_SYSTEM had different
 961 ## values in configure and the Makefiles.  How helpful.
 962 ## FIXME why not use LD_SWITCH_SYSTEM_TEMACS (or somesuch) instead?
 963 case "$opsys" in
 964   gnu-linux)
 965    ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
 966    LD_SWITCH_SYSTEM="$LD_SWITCH_SYSTEM \$(LD_SWITCH_X_SITE_AUX)" ;;
 967
 968   netbsd|openbsd)
 969    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 970    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 971 esac
 972
 973
 974 C_SWITCH_MACHINE=
 975 if test "$machine" = "alpha"; then
 976   AC_CHECK_DECL([__ELF__])
 977   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 978     ## With ELF, make sure that all common symbols get allocated to in the
 979     ## data section.  Otherwise, the dump of temacs may miss variables in
 980     ## the shared library that have been initialized.  For example, with
 981     ## GNU libc, __malloc_initialized would normally be resolved to the
 982     ## shared library's .bss section, which is fatal.
 983     if test "x$GCC" = "xyes"; then
 984       C_SWITCH_MACHINE="-fno-common"
 985     else
 986       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 987     fi
 988   fi
 989 fi
 990 AC_SUBST(C_SWITCH_MACHINE)
 991
 992
 993 C_SWITCH_SYSTEM=
 994 ## Some programs in src produce warnings saying certain subprograms
 995 ## are too complex and need a MAXMEM value greater than 2000 for
 996 ## additional optimization.  --nils@exp-math.uni-essen.de
 997 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 998   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 999 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1000 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1001 AC_SUBST(C_SWITCH_SYSTEM)
1002
1003
1004 LIBS_SYSTEM=
1005 case "$opsys" in
1006   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1007   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1008
1009   freebsd) LIBS_SYSTEM="-lutil" ;;
1010
1011   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1012
1013   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
1014
1015   ## Motif needs -lgen.
1016   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1017 esac
1018 AC_SUBST(LIBS_SYSTEM)
1019
1020
1021 ### Make sure subsequent tests use flags consistent with the build flags.
1022
1023 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1024   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1025 else
1026   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1027 fi
1028
1029 dnl For AC_FUNC_GETLOADAVG, at least:
1030 AC_CONFIG_LIBOBJ_DIR(src)
1031
1032 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1033 AC_SYS_LARGEFILE
1034
1035
1036 ## If user specified a crt-dir, use that unconditionally.
1037 if test "X$CRT_DIR" = "X"; then
1038
1039   case "$canonical" in
1040     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1041     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1042     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1043     ## For anything else (eg /usr/lib32), it is up the user to specify
1044     ## the location (bug#5655).
1045     ## Test for crtn.o, not just the directory, because sometimes the
1046     ## directory exists but does not have the relevant files (bug#1287).
1047     ## FIXME better to test for binary compatibility somehow.
1048     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1049     ;;
1050
1051     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1052   esac
1053
1054   case "$opsys" in
1055     hpux10-20) CRT_DIR=/lib ;;
1056   esac
1057
1058   ## Default is /usr/lib.
1059   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1060
1061 else
1062
1063   ## Some platforms don't use any of these files, so it is not
1064   ## appropriate to put this test outside the if block.
1065   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1066     AC_MSG_ERROR([crt*.o not found in specified location.])
1067
1068 fi
1069
1070 AC_SUBST(CRT_DIR)
1071
1072 LIB_MATH=-lm
1073 LIB_STANDARD=
1074 START_FILES=
1075
1076 case $opsys in
1077   cygwin )
1078     LIB_MATH=
1079     START_FILES='ecrt0.o'
1080     ;;
1081   darwin )
1082     ## Adding -lm confuses the dynamic linker, so omit it.
1083     LIB_MATH=
1084     START_FILES='pre-crt0.o'
1085     ;;
1086   freebsd )
1087     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1088     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1089     ;;
1090   gnu-linux | gnu-kfreebsd )
1091     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1092     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1093     ;;
1094   hpux10-20 | hpux11 )
1095     LIB_STANDARD=-lc
1096     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1097     ;;
1098   netbsd | openbsd )
1099     if test -f $CRT_DIR/crti.o; then
1100         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1101         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1102     else
1103         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1104         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1105     fi
1106     ;;
1107 esac
1108
1109 AC_SUBST(LIB_MATH)
1110 AC_SUBST(START_FILES)
1111
1112 dnl This function definition taken from Gnome 2.0
1113 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1114 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1115 dnl also defines GSTUFF_PKG_ERRORS on error
1116 AC_DEFUN([PKG_CHECK_MODULES], [
1117   succeeded=no
1118
1119   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1120
1121   if test "$PKG_CONFIG" = "no" ; then
1122      ifelse([$4], , [AC_MSG_ERROR([
1123       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1124   else
1125      PKG_CONFIG_MIN_VERSION=0.9.0
1126      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1127         AC_MSG_CHECKING(for $2)
1128
1129         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1130             AC_MSG_RESULT(yes)
1131             succeeded=yes
1132
1133             AC_MSG_CHECKING($1_CFLAGS)
1134             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1135             AC_MSG_RESULT($$1_CFLAGS)
1136
1137             AC_MSG_CHECKING($1_LIBS)
1138             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1139             AC_MSG_RESULT($$1_LIBS)
1140         else
1141             AC_MSG_RESULT(no)
1142             $1_CFLAGS=""
1143             $1_LIBS=""
1144             ## If we have a custom action on failure, don't print errors, but
1145             ## do set a variable so people can do so.
1146             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1147             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1148         fi
1149
1150         AC_SUBST($1_CFLAGS)
1151         AC_SUBST($1_LIBS)
1152      else
1153         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1154         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1155      fi
1156   fi
1157
1158   if test $succeeded = yes; then
1159      ifelse([$3], , :, [$3])
1160   else
1161      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1162   fi
1163 ])
1164
1165
1166 if test "${with_sound}" != "no"; then
1167   # Sound support for GNU/Linux and the free BSDs.
1168   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1169   # Emulation library used on NetBSD.
1170   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1171   AC_SUBST(LIBSOUND)
1172
1173   ALSA_REQUIRED=1.0.0
1174   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1175   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1176   if test $HAVE_ALSA = yes; then
1177     SAVE_CFLAGS="$CFLAGS"
1178     SAVE_LDFLAGS="$LDFLAGS"
1179     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1180     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1181     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1182                     emacs_alsa_normal=yes,
1183                     emacs_alsa_normal=no)
1184     if test "$emacs_alsa_normal" != yes; then
1185       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1186                      [snd_lib_error_set_handler (0);],
1187                      emacs_alsa_subdir=yes,
1188                      emacs_alsa_subdir=no)
1189       if test "$emacs_alsa_subdir" != yes; then
1190         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1191       fi
1192       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1193     fi
1194
1195     CFLAGS="$SAVE_CFLAGS"
1196     LDFLAGS="$SAVE_LDFLAGS"
1197     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1198     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1199     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1200   fi
1201   AC_SUBST(CFLAGS_SOUND)
1202 fi
1203
1204 dnl checks for header files
1205 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1206   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1207   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1208   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1209   sys/utsname.h pwd.h utmp.h)
1210
1211 AC_MSG_CHECKING(if personality LINUX32 can be set)
1212 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1213                emacs_cv_personality_linux32=yes,
1214                emacs_cv_personality_linux32=no)
1215 AC_MSG_RESULT($emacs_cv_personality_linux32)
1216
1217 if test $emacs_cv_personality_linux32 = yes; then
1218   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1219             [Define to 1 if personality LINUX32 can be set.])
1220 fi
1221
1222 dnl On Solaris 8 there's a compilation warning for term.h because
1223 dnl it doesn't define `bool'.
1224 AC_CHECK_HEADERS(term.h, , , -)
1225 AC_HEADER_STDC
1226 AC_HEADER_TIME
1227 AC_CHECK_DECLS([sys_siglist])
1228 if test $ac_cv_have_decl_sys_siglist != yes; then
1229   # For Tru64, at least:
1230   AC_CHECK_DECLS([__sys_siglist])
1231   if test $ac_cv_have_decl___sys_siglist = yes; then
1232     AC_DEFINE(sys_siglist, __sys_siglist,
1233               [Define to any substitute for sys_siglist.])
1234   fi
1235 fi
1236 AC_HEADER_SYS_WAIT
1237
1238 dnl Some systems have utime.h but don't declare the struct anyplace.
1239 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1240 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1241 #include <sys/time.h>
1242 #include <time.h>
1243 #else
1244 #ifdef HAVE_SYS_TIME_H
1245 #include <sys/time.h>
1246 #else
1247 #include <time.h>
1248 #endif
1249 #endif
1250 #ifdef HAVE_UTIME_H
1251 #include <utime.h>
1252 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1253   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1254 if test $emacs_cv_struct_utimbuf = yes; then
1255   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1256 fi
1257
1258 dnl checks for typedefs
1259 AC_TYPE_SIGNAL
1260
1261 dnl Check for speed_t typedef.
1262 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1263   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1264     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1265 if test $emacs_cv_speed_t = yes; then
1266   AC_DEFINE(HAVE_SPEED_T, 1,
1267            [Define to 1 if `speed_t' is declared by <termios.h>.])
1268 fi
1269
1270 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1271 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1272 #include <sys/time.h>
1273 #include <time.h>
1274 #else
1275 #ifdef HAVE_SYS_TIME_H
1276 #include <sys/time.h>
1277 #else
1278 #include <time.h>
1279 #endif
1280 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1281   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1282 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1283 if test $emacs_cv_struct_timeval = yes; then
1284   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1285 fi
1286
1287 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1288 AC_TRY_COMPILE([#include <math.h>],
1289 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1290   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1291 HAVE_EXCEPTION=$emacs_cv_struct_exception
1292 if test $emacs_cv_struct_exception != yes; then
1293   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1294 fi
1295
1296 AC_CHECK_HEADERS(sys/socket.h)
1297 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1298 #if HAVE_SYS_SOCKET_H
1299 #include <sys/socket.h>
1300 #endif])
1301
1302 dnl checks for structure members
1303 AC_STRUCT_TM
1304 AC_STRUCT_TIMEZONE
1305 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1306                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1307                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1308                 [#include <time.h>])
1309 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1310                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1311                   struct ifreq.ifr_addr], , ,
1312                  [AC_INCLUDES_DEFAULT
1313 #if HAVE_SYS_SOCKET_H
1314 #include <sys/socket.h>
1315 #endif
1316 #if HAVE_NET_IF_H
1317 #include <net/if.h>
1318 #endif])
1319
1320 dnl checks for compiler characteristics
1321
1322 dnl Testing __STDC__ to determine prototype support isn't good enough.
1323 dnl DEC C, for instance, doesn't define it with default options, and
1324 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1325 dnl and void *.
1326 AC_C_PROTOTYPES
1327 AC_C_VOLATILE
1328 AC_C_CONST
1329 dnl This isn't useful because we can't turn on use of `inline' unless
1330 dnl the compiler groks `extern inline'.
1331 dnl AC_C_INLINE
1332 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1333   [AC_TRY_COMPILE(, [void * foo;],
1334                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1335 if test $emacs_cv_void_star = yes; then
1336   AC_DEFINE(POINTER_TYPE, void)
1337 else
1338   AC_DEFINE(POINTER_TYPE, char)
1339 fi
1340 AH_TEMPLATE(POINTER_TYPE,
1341             [Define as `void' if your compiler accepts `void *'; otherwise
1342              define as `char'.])dnl
1343
1344
1345
1346 dnl This could be used for targets which can have both byte sexes.
1347 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1348 dnl AC_C_BIGENDIAN
1349
1350 dnl check for Make feature
1351 AC_PROG_MAKE_SET
1352
1353 DEPFLAGS=
1354 MKDEPDIR=":"
1355 deps_frag=deps.mk
1356 dnl check for GNU Make if we have GCC and autodepend is on.
1357 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1358    AC_MSG_CHECKING([whether we are using GNU Make])
1359    HAVE_GNU_MAKE=no
1360    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1361    if test "x$testval" != x; then
1362       HAVE_GNU_MAKE=yes
1363    else
1364       ac_enable_autodepend=no
1365    fi
1366    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1367    if test $HAVE_GNU_MAKE = yes; then
1368       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1369       SAVE_CFLAGS="$CFLAGS"
1370       CFLAGS="$CFLAGS -MMD -MF deps.d"
1371       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1372       CFLAGS="$SAVE_CFLAGS"
1373       test -f deps.d || ac_enable_autodepend=no
1374       rm -rf deps.d
1375       AC_MSG_RESULT([$ac_enable_autodepend])
1376    fi
1377    if test $ac_enable_autodepend = yes; then
1378       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1379       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR}'
1380       deps_frag=autodeps.mk
1381    fi
1382 fi
1383 deps_frag=$srcdir/src/$deps_frag
1384 AC_SUBST(MKDEPDIR)
1385 AC_SUBST(DEPFLAGS)
1386 AC_SUBST_FILE(deps_frag)
1387
1388
1389 dnl checks for operating system services
1390 AC_SYS_LONG_FILE_NAMES
1391
1392 #### Choose a window system.
1393
1394 AC_PATH_X
1395 if test "$no_x" = yes; then
1396   window_system=none
1397 else
1398   window_system=x11
1399 fi
1400
1401 ## Workaround for bug in autoconf <= 2.62.
1402 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1403 ## No need to do anything special for these standard directories.
1404 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1405
1406    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1407
1408 fi
1409
1410 LD_SWITCH_X_SITE_AUX=
1411 LD_SWITCH_X_SITE_AUX_RPATH=
1412 if test "${x_libraries}" != NONE; then
1413   if test -n "${x_libraries}"; then
1414     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1415     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1416     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1417   fi
1418   x_default_search_path=""
1419   x_search_path=${x_libraries}
1420   if test -z "${x_search_path}"; then
1421     x_search_path=/usr/lib
1422   fi
1423   for x_library in `echo ${x_search_path}: | \
1424                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1425     x_search_path="\
1426 ${x_library}/X11/%L/%T/%N%C%S:\
1427 ${x_library}/X11/%l/%T/%N%C%S:\
1428 ${x_library}/X11/%T/%N%C%S:\
1429 ${x_library}/X11/%L/%T/%N%S:\
1430 ${x_library}/X11/%l/%T/%N%S:\
1431 ${x_library}/X11/%T/%N%S"
1432     if test x"${x_default_search_path}" = x; then
1433       x_default_search_path=${x_search_path}
1434     else
1435       x_default_search_path="${x_search_path}:${x_default_search_path}"
1436     fi
1437   done
1438 fi
1439 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1440 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1441
1442 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1443   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1444 fi
1445
1446 if test x"${x_includes}" = x; then
1447   bitmapdir=/usr/include/X11/bitmaps
1448 else
1449   # accumulate include directories that have X11 bitmap subdirectories
1450   bmd_acc="dummyval"
1451   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1452     if test -d "${bmd}/X11/bitmaps"; then
1453       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1454     fi
1455     if test -d "${bmd}/bitmaps"; then
1456       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1457     fi
1458   done
1459   if test ${bmd_acc} != "dummyval"; then
1460     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1461   fi
1462 fi
1463
1464 HAVE_NS=no
1465 NS_IMPL_COCOA=no
1466 NS_IMPL_GNUSTEP=no
1467 NS_IMPL_GNUSTEP_INC=
1468 NS_IMPL_GNUSTEP_TEMACS_LDFLAGS=
1469 tmp_CPPFLAGS="$CPPFLAGS"
1470 tmp_CFLAGS="$CFLAGS"
1471 CPPFLAGS="$CPPFLAGS -x objective-c"
1472 CFLAGS="$CFLAGS -x objective-c"
1473 TEMACS_LDFLAGS2="\${LDFLAGS}"
1474 dnl I don't think it's especially important, but src/Makefile.in
1475 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1476 dnl trailing "/" to it, so now we do it here.
1477 if test "${with_ns}" != no; then
1478   if test "${opsys}" = darwin; then
1479      NS_IMPL_COCOA=yes
1480      ns_appdir=`pwd`/nextstep/Emacs.app/
1481      ns_appbindir=${ns_appdir}Contents/MacOS/
1482      ns_appresdir=${ns_appdir}Contents/Resources
1483      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1484   elif test -f $GNUSTEP_CONFIG_FILE; then
1485      NS_IMPL_GNUSTEP=yes
1486      ns_appdir=`pwd`/nextstep/Emacs.app/
1487      ns_appbindir=${ns_appdir}
1488      ns_appresdir=${ns_appdir}Resources
1489      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1490      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1491      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1492      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1493      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1494      ## Pull in stuff from GNUstep-make.
1495      ## FIXME? Cleaner to use AC_SUBST_FILE for this?
1496      NS_IMPL_GNUSTEP_INC="FOUNDATION_LIB=gnu
1497 GUI_LIB=gnu
1498 include $GNUSTEP_MAKEFILES/Additional/base.make
1499 include $GNUSTEP_MAKEFILES/Additional/gui.make
1500 shared=no
1501 "
1502      dnl Presumably ${CONFIG_SYSTEM_LIBS} is defined by above includes.
1503      NS_IMPL_GNUSTEP_TEMACS_LDFLAGS="-L${GNUSTEP_SYSTEM_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc \${CONFIG_SYSTEM_LIBS} -lpthread"
1504      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1505      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1506      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1507      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1508      LIB_STANDARD=
1509      START_FILES=
1510      TEMACS_LDFLAGS2=
1511   fi
1512   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1513                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1514   files are missing or cannot be compiled.])])
1515   NS_HAVE_NSINTEGER=yes
1516   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1517                                      [NSInteger i;])],
1518                     ns_have_nsinteger=yes,
1519                     ns_have_nsinteger=no)
1520   if test $ns_have_nsinteger = no; then
1521     NS_HAVE_NSINTEGER=no
1522   fi
1523 fi
1524 AC_SUBST(NS_IMPL_GNUSTEP_INC)
1525 AC_SUBST(NS_IMPL_GNUSTEP_TEMACS_LDFLAGS)
1526 AC_SUBST(TEMACS_LDFLAGS2)
1527
1528 NS_OBJ=
1529 NS_SUPPORT=
1530 if test "${HAVE_NS}" = yes; then
1531   window_system=nextstep
1532   with_xft=no
1533   # set up packaging dirs
1534   exec_prefix=${ns_appbindir}
1535   libexecdir=${ns_appbindir}/libexec
1536   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1537      prefix=${ns_appresdir}
1538   fi
1539   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1540   NS_SUPPORT="\${lispsource}emacs-lisp/easymenu.elc \${lispsource}term/ns-win.elc"
1541 fi
1542 CFLAGS="$tmp_CFLAGS"
1543 CPPFLAGS="$tmp_CPPFLAGS"
1544 AC_SUBST(NS_OBJ)
1545 AC_SUBST(NS_SUPPORT)
1546 AC_SUBST(LIB_STANDARD)
1547
1548 case "${window_system}" in
1549   x11 )
1550     HAVE_X_WINDOWS=yes
1551     HAVE_X11=yes
1552     case "${with_x_toolkit}" in
1553       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1554       motif ) USE_X_TOOLKIT=MOTIF ;;
1555       gtk ) with_gtk=yes
1556 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1557 dnl USE_X_TOOLKIT is set.
1558             USE_X_TOOLKIT=none ;;
1559       no ) USE_X_TOOLKIT=none ;;
1560 dnl If user did not say whether to use a toolkit, make this decision later:
1561 dnl use the toolkit if we have gtk, or X11R5 or newer.
1562       * ) USE_X_TOOLKIT=maybe ;;
1563     esac
1564   ;;
1565   nextstep | none )
1566     HAVE_X_WINDOWS=no
1567     HAVE_X11=no
1568     USE_X_TOOLKIT=none
1569   ;;
1570 esac
1571
1572 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1573    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1574    if test "$HAVE_XSERVER" = true ||
1575       test -n "$DISPLAY" ||
1576       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1577         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1578 were found.  You should install the relevant development files for X
1579 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1580 sure you have development files for image handling, i.e.
1581 tiff, gif, jpeg, png and xpm.
1582 If you are sure you want Emacs compiled without X window support, pass
1583   --without-x
1584 to configure.])
1585    fi
1586 fi
1587
1588 ### If we're using X11, we should use the X menu package.
1589 HAVE_MENUS=no
1590 case ${HAVE_X11} in
1591   yes ) HAVE_MENUS=yes ;;
1592 esac
1593
1594 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1595 # Assume not, until told otherwise.
1596 GNU_MALLOC=yes
1597 doug_lea_malloc=yes
1598 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1599 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1600 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1601                emacs_cv_var___after_morecore_hook,
1602 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1603   emacs_cv_var___after_morecore_hook=yes,
1604   emacs_cv_var___after_morecore_hook=no)])
1605 if test $emacs_cv_var___after_morecore_hook = no; then
1606   doug_lea_malloc=no
1607 fi
1608
1609 if test "${system_malloc}" = "yes"; then
1610   GNU_MALLOC=no
1611   GNU_MALLOC_reason="
1612     (The GNU allocators don't work with this system configuration.)"
1613   GMALLOC_OBJ=
1614   VMLIMIT_OBJ=
1615 else
1616   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1617   VMLIMIT_OBJ=vm-limit.o
1618 fi
1619 AC_SUBST(GMALLOC_OBJ)
1620 AC_SUBST(VMLIMIT_OBJ)
1621
1622 if test "$doug_lea_malloc" = "yes" ; then
1623   if test "$GNU_MALLOC" = yes ; then
1624     GNU_MALLOC_reason="
1625       (Using Doug Lea's new malloc from the GNU C Library.)"
1626   fi
1627   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1628             [Define to 1 if you are using the GNU C Library.])
1629
1630   ## Use mmap directly for allocating larger buffers.
1631   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1632   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1633   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1634   case "$opsys" in
1635     gnu*) REL_ALLOC=no ;;
1636   esac
1637 fi
1638
1639 if test x"${REL_ALLOC}" = x; then
1640   REL_ALLOC=${GNU_MALLOC}
1641 fi
1642
1643 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1644 dnl the system configuration file (s/*.h) to turn the use of mmap
1645 dnl in the relocating allocator on.
1646
1647 AC_FUNC_MMAP
1648 if test $use_mmap_for_buffers = yes; then
1649   REL_ALLOC=no
1650 fi
1651
1652 LIBS="$LIBS_SYSTEM $LIBS"
1653
1654 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1655 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1656 AC_CHECK_LIB(dnet, dnet_ntoa)
1657 dnl This causes -lresolv to get used in subsequent tests,
1658 dnl which causes failures on some systems such as HPUX 9.
1659 dnl AC_CHECK_LIB(resolv, gethostbyname)
1660
1661 dnl FIXME replace main with a function we actually want from this library.
1662 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1663
1664 AC_CHECK_LIB(pthreads, cma_open)
1665
1666 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1667 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1668 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1669 ## added to LIBS in configure would never contain the pthreads part,
1670 ## but the value used in Makefiles might.  FIXME?
1671 ##
1672 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1673 ## be harmless on older versions of X where it happens to exist.
1674 test "$opsys" = "aix4-2" && \
1675   test $ac_cv_lib_pthreads_cma_open = yes && \
1676   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1677
1678 dnl Check for need for bigtoc support on IBM AIX
1679
1680 case ${host_os} in
1681 aix*)
1682   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1683     case $GCC in
1684     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1685     *) gdb_cv_bigtoc=-bbigtoc ;;
1686     esac
1687
1688     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1689     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1690   ])
1691   ;;
1692 esac
1693
1694 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1695 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1696 # REAL_CPPFLAGS later on.
1697
1698 REAL_CPPFLAGS="$CPPFLAGS"
1699
1700 if test "${HAVE_X11}" = "yes"; then
1701   DEFS="$C_SWITCH_X_SITE $DEFS"
1702   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1703   LIBS="$LIBX $LIBS"
1704   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1705   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1706
1707   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1708   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1709   # but it's more convenient here to set LD_RUN_PATH
1710   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1711   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1712     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1713     export LD_RUN_PATH
1714   fi
1715
1716   if test "${opsys}" = "gnu-linux"; then
1717     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1718     AC_TRY_LINK([],
1719      [XOpenDisplay ("foo");],
1720      [xlinux_first_failure=no],
1721      [xlinux_first_failure=yes])
1722     if test "${xlinux_first_failure}" = "yes"; then
1723       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1724       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1725       OLD_CPPFLAGS="$CPPFLAGS"
1726       OLD_LIBS="$LIBS"
1727       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1728       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1729       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1730       LIBS="$LIBS -b i486-linuxaout"
1731       AC_TRY_LINK([],
1732        [XOpenDisplay ("foo");],
1733        [xlinux_second_failure=no],
1734        [xlinux_second_failure=yes])
1735       if test "${xlinux_second_failure}" = "yes"; then
1736         # If we get the same failure with -b, there is no use adding -b.
1737         # So take it out.  This plays safe.
1738         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1739         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1740         CPPFLAGS="$OLD_CPPFLAGS"
1741         LIBS="$OLD_LIBS"
1742         AC_MSG_RESULT(no)
1743       else
1744         AC_MSG_RESULT(yes)
1745       fi
1746     else
1747       AC_MSG_RESULT(no)
1748     fi
1749   fi
1750
1751   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1752   # header files included from there.
1753   AC_MSG_CHECKING(for Xkb)
1754   AC_TRY_LINK([#include <X11/Xlib.h>
1755 #include <X11/XKBlib.h>],
1756         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1757         emacs_xkb=yes, emacs_xkb=no)
1758   AC_MSG_RESULT($emacs_xkb)
1759   if test $emacs_xkb = yes; then
1760     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1761   fi
1762
1763   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1764 XScreenNumberOfScreen XSetWMProtocols)
1765 fi
1766
1767 if test "${window_system}" = "x11"; then
1768   AC_MSG_CHECKING(X11 version 6)
1769   AC_CACHE_VAL(emacs_cv_x11_version_6,
1770   [AC_TRY_LINK([#include <X11/Xlib.h>],
1771 [#if XlibSpecificationRelease < 6
1772 fail;
1773 #endif
1774 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1775   if test $emacs_cv_x11_version_6 = yes; then
1776     AC_MSG_RESULT(6 or newer)
1777     AC_DEFINE(HAVE_X11R6, 1,
1778               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1779   else
1780     AC_MSG_RESULT(before 6)
1781   fi
1782 fi
1783
1784
1785 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1786 HAVE_RSVG=no
1787 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1788   if test "${with_rsvg}" != "no"; then
1789     RSVG_REQUIRED=2.11.0
1790     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1791
1792     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1793     AC_SUBST(RSVG_CFLAGS)
1794     AC_SUBST(RSVG_LIBS)
1795
1796     if test ".${RSVG_CFLAGS}" != "."; then
1797       HAVE_RSVG=yes
1798       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1799       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1800       LIBS="$RSVG_LIBS $LIBS"
1801     fi
1802   fi
1803 fi
1804
1805
1806 HAVE_GTK=no
1807 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1808   GLIB_REQUIRED=2.6
1809   GTK_REQUIRED=2.6
1810   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1811
1812   dnl Checks for libraries.
1813   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1814   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1815      AC_MSG_ERROR($GTK_PKG_ERRORS)
1816   fi
1817 fi
1818
1819
1820 GTK_OBJ=
1821 if test x"$pkg_check_gtk" = xyes; then
1822
1823   AC_SUBST(GTK_CFLAGS)
1824   AC_SUBST(GTK_LIBS)
1825   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1826   CFLAGS="$CFLAGS $GTK_CFLAGS"
1827   LIBS="$GTK_LIBS $LIBS"
1828   dnl Try to compile a simple GTK program.
1829   GTK_COMPILES=no
1830   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1831   if test "${GTK_COMPILES}" != "yes"; then
1832     if test "$USE_X_TOOLKIT" != "maybe"; then
1833       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1834     fi
1835   else
1836     HAVE_GTK=yes
1837     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1838     GTK_OBJ=gtkutil.o
1839     USE_X_TOOLKIT=none
1840     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1841       :
1842     else
1843       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1844        closing open displays.  This is no problem if you just use
1845        one display, but if you use more than one and close one of them
1846        Emacs may crash.]])
1847       sleep 3
1848     fi
1849   fi
1850
1851 fi
1852 AC_SUBST(GTK_OBJ)
1853
1854
1855 if test "${HAVE_GTK}" = "yes"; then
1856
1857   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1858   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1859   if test "$with_toolkit_scroll_bars" != no; then
1860     with_toolkit_scroll_bars=yes
1861   fi
1862
1863   dnl  Check if we can use multiple displays with this GTK version.
1864   dnl  If gdk_display_open exists, assume all others are there also.
1865   HAVE_GTK_MULTIDISPLAY=no
1866   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1867   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1868     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1869               [Define to 1 if GTK can handle more than one display.])
1870   fi
1871
1872   dnl  Check if we have the old file selection dialog declared and
1873   dnl  in the link library.  In 2.x it may be in the library,
1874   dnl  but not declared if deprecated featured has been selected out.
1875   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1876   HAVE_GTK_FILE_SELECTION=no
1877   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1878                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1879 #include <gtk/gtk.h>])
1880   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1881     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1882                    HAVE_GTK_FILE_SELECTION=no)
1883   fi
1884
1885   dnl  Check if we have the new file chooser dialog
1886   HAVE_GTK_FILE_CHOOSER=no
1887   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1888                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1889 #include <gtk/gtk.h>])
1890   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1891     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1892                    HAVE_GTK_FILE_CHOOSER=no)
1893   fi
1894
1895   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1896      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1897     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1898               [Define to 1 if GTK has both file selection and chooser dialog.])
1899   fi
1900
1901   dnl Check if pthreads are available.  Emacs only needs this when using
1902   dnl gtk_file_chooser under Gnome.
1903   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1904     HAVE_GTK_AND_PTHREAD=no
1905     AC_CHECK_HEADERS(pthread.h)
1906     if test "$ac_cv_header_pthread_h"; then
1907       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1908     fi
1909     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1910       case "${canonical}" in
1911         *-hpux*) ;;
1912         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1913       esac
1914       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1915                [Define to 1 if you have GTK and pthread (-lpthread).])
1916     fi
1917   fi
1918 fi
1919
1920 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1921 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1922 dnl also not configured.
1923 HAVE_DBUS=no
1924 DBUS_OBJ=
1925 if test "${with_dbus}" = "yes"; then
1926    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1927    if test "$HAVE_DBUS" = yes; then
1928      LIBS="$LIBS $DBUS_LIBS"
1929      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1930      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1931      DBUS_OBJ=dbusbind.o
1932    fi
1933 fi
1934 AC_SUBST(DBUS_OBJ)
1935
1936 dnl GConf has been tested under GNU/Linux only.
1937 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1938 HAVE_GCONF=no
1939 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1940    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1941    if test "$HAVE_GCONF" = yes; then
1942       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1943    fi
1944 fi
1945
1946 dnl SELinux is available for GNU/Linux only.
1947 HAVE_LIBSELINUX=no
1948 LIBSELINUX_LIBS=
1949 if test "${with_selinux}" = "yes"; then
1950    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1951    if test "$HAVE_LIBSELINUX" = yes; then
1952       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1953       LIBSELINUX_LIBS=-lselinux
1954    fi
1955 fi
1956 AC_SUBST(LIBSELINUX_LIBS)
1957
1958 dnl Do not put whitespace before the #include statements below.
1959 dnl Older compilers (eg sunos4 cc) choke on it.
1960 HAVE_XAW3D=no
1961 LUCID_LIBW=
1962 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1963   if test "$with_xaw3d" != no; then
1964     AC_MSG_CHECKING(for xaw3d)
1965     AC_CACHE_VAL(emacs_cv_xaw3d,
1966     [AC_TRY_LINK([
1967 #include <X11/Intrinsic.h>
1968 #include <X11/Xaw3d/Simple.h>],
1969       [],
1970       emacs_cv_xaw3d=yes,
1971       emacs_cv_xaw3d=no)])
1972   else
1973     emacs_cv_xaw3d=no
1974   fi
1975   if test $emacs_cv_xaw3d = yes; then
1976     AC_MSG_RESULT([yes; using Lucid toolkit])
1977     USE_X_TOOLKIT=LUCID
1978     HAVE_XAW3D=yes
1979     LUCID_LIBW=-lXaw3d
1980     AC_DEFINE(HAVE_XAW3D, 1,
1981               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1982   else
1983     AC_MSG_RESULT(no)
1984     AC_MSG_CHECKING(for libXaw)
1985     AC_CACHE_VAL(emacs_cv_xaw,
1986     [AC_TRY_LINK([
1987 #include <X11/Intrinsic.h>
1988 #include <X11/Xaw/Simple.h>],
1989       [],
1990       emacs_cv_xaw=yes,
1991       emacs_cv_xaw=no)])
1992     if test $emacs_cv_xaw = yes; then
1993       AC_MSG_RESULT([yes; using Lucid toolkit])
1994       USE_X_TOOLKIT=LUCID
1995       LUCID_LIBW=-lXaw
1996     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1997       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1998     else
1999       AC_MSG_RESULT([no; do not use toolkit by default])
2000       USE_X_TOOLKIT=none
2001     fi
2002   fi
2003 fi
2004
2005 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2006
2007 LIBXTR6=
2008 if test "${USE_X_TOOLKIT}" != "none"; then
2009   AC_MSG_CHECKING(X11 toolkit version)
2010   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2011   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2012 [#if XtSpecificationRelease < 6
2013 fail;
2014 #endif
2015 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2016   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2017   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2018     AC_MSG_RESULT(6 or newer)
2019     AC_DEFINE(HAVE_X11XTR6, 1,
2020               [Define to 1 if you have the X11R6 or newer version of Xt.])
2021     LIBXTR6="-lSM -lICE"
2022     case "$opsys" in
2023       ## Use libw.a along with X11R6 Xt.
2024       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2025     esac
2026   else
2027     AC_MSG_RESULT(before 6)
2028   fi
2029
2030 dnl If using toolkit, check whether libXmu.a exists.
2031 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2032   OLDLIBS="$LIBS"
2033   if test x$HAVE_X11XTR6 = xyes; then
2034     LIBS="-lXt -lSM -lICE $LIBS"
2035   else
2036     LIBS="-lXt $LIBS"
2037   fi
2038   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2039   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2040 fi
2041 AC_SUBST(LIBXTR6)
2042
2043 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2044 dnl Why not just test for libxmu in the normal way?
2045 LIBXMU=-lXmu
2046 case "$machine" in
2047   ## These machines don't supply Xmu.
2048   hpux* | aix4-2 )
2049     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2050     ;;
2051 esac
2052 AC_SUBST(LIBXMU)
2053
2054 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2055 if test "${HAVE_X11}" = "yes"; then
2056   if test "${USE_X_TOOLKIT}" != "none"; then
2057     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2058   fi
2059 fi
2060
2061 LIBXP=
2062 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2063   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2064   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2065     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2066 int x = 5;
2067 #else
2068 Motif version prior to 2.1.
2069 #endif],
2070     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2071   if test $emacs_cv_motif_version_2_1 = yes; then
2072     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2073   else
2074     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2075     # We put this in CFLAGS temporarily to precede other -I options
2076     # that might be in CFLAGS temporarily.
2077     # We put this in CPPFLAGS where it precedes the other -I options.
2078     OLD_CPPFLAGS=$CPPFLAGS
2079     OLD_CFLAGS=$CFLAGS
2080     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2081     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2082     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2083       [int x = 5;],
2084       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2085     if test $emacs_cv_lesstif = yes; then
2086       # Make sure this -I option remains in CPPFLAGS after it is set
2087       # back to REAL_CPPFLAGS.
2088       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2089       # have those other -I options anyway.  Ultimately, having this
2090       # directory ultimately in CPPFLAGS will be enough.
2091       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2092       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2093     else
2094       CFLAGS=$OLD_CFLAGS
2095       CPPFLAGS=$OLD_CPPFLAGS
2096     fi
2097   fi
2098 fi
2099
2100 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2101 dnl using Motif or Xaw3d is available, and unless
2102 dnl --with-toolkit-scroll-bars=no was specified.
2103
2104 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2105             [Define to 1 if we should use toolkit scroll bars.])dnl
2106 USE_TOOLKIT_SCROLL_BARS=no
2107 if test "${with_toolkit_scroll_bars}" != "no"; then
2108   if test "${USE_X_TOOLKIT}" != "none"; then
2109     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2110       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2111       HAVE_XAW3D=no
2112       USE_TOOLKIT_SCROLL_BARS=yes
2113     elif test "${HAVE_XAW3D}" = "yes"; then
2114       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2115       USE_TOOLKIT_SCROLL_BARS=yes
2116     fi
2117   elif test "${HAVE_GTK}" = "yes"; then
2118     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2119     USE_TOOLKIT_SCROLL_BARS=yes
2120   elif test "${HAVE_NS}" = "yes"; then
2121     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2122     USE_TOOLKIT_SCROLL_BARS=yes
2123   fi
2124 fi
2125
2126 dnl See if XIM is available.
2127 AC_TRY_COMPILE([
2128           #include <X11/Xlib.h>
2129           #include <X11/Xresource.h>],
2130          [XIMProc  callback;],
2131          [HAVE_XIM=yes
2132          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2133          HAVE_XIM=no)
2134
2135 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2136
2137 if test "${with_xim}" != "no"; then
2138   AC_DEFINE(USE_XIM, 1,
2139             [Define to 1 if we should use XIM, if it is available.])
2140 fi
2141
2142
2143 if test "${HAVE_XIM}" != "no"; then
2144   late_CFLAGS=$CFLAGS
2145   if test "$GCC" = yes; then
2146     CFLAGS="$CFLAGS --pedantic-errors"
2147   fi
2148   AC_TRY_COMPILE([
2149 #include <X11/Xlib.h>
2150 #include <X11/Xresource.h>],
2151 [Display *display;
2152 XrmDatabase db;
2153 char *res_name;
2154 char *res_class;
2155 XIMProc  callback;
2156 XPointer *client_data;
2157 #ifndef __GNUC__
2158 /* If we're not using GCC, it's probably not XFree86, and this is
2159    probably right, but we can't use something like --pedantic-errors.  */
2160 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2161                                            char*, XIMProc, XPointer*);
2162 #endif
2163 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2164    client_data);],
2165     [emacs_cv_arg6_star=yes])
2166   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2167          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2168 either XPointer or XPointer*.])dnl
2169   if test "$emacs_cv_arg6_star" = yes; then
2170     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2171   else
2172     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2173   fi
2174   CFLAGS=$late_CFLAGS
2175 fi
2176
2177 ### Start of font-backend (under any platform) section.
2178 # (nothing here yet -- this is a placeholder)
2179 ### End of font-backend (under any platform) section.
2180
2181 ### Start of font-backend (under X11) section.
2182 if test "${HAVE_X11}" = "yes"; then
2183    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2184
2185    ## Use -lXft if available, unless `--with-xft=no'.
2186    HAVE_XFT=maybe
2187     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2188       with_xft="no";
2189     fi
2190     if test "x${with_xft}" != "xno"; then
2191
2192       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2193       ## Because xftfont.c uses XRenderQueryExtension, we also
2194       ## need to link to -lXrender.
2195       HAVE_XRENDER=no
2196       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2197       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2198         OLD_CPPFLAGS="$CPPFLAGS"
2199         OLD_CFLAGS="$CFLAGS"
2200         OLD_LIBS="$LIBS"
2201         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2202         CFLAGS="$CFLAGS $XFT_CFLAGS"
2203         XFT_LIBS="-lXrender $XFT_LIBS"
2204         LIBS="$XFT_LIBS $LIBS"
2205         AC_CHECK_HEADER(X11/Xft/Xft.h,
2206           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2207
2208         if test "${HAVE_XFT}" = "yes"; then
2209           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2210             AC_SUBST(XFT_LIBS)
2211           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2212         else
2213           CPPFLAGS="$OLD_CPPFLAGS"
2214           CFLAGS="$OLD_CFLAGS"
2215           LIBS="$OLD_LIBS"
2216         fi                        # "${HAVE_XFT}" = "yes"
2217       fi                          # "$HAVE_XFT" != no
2218     fi                            # "x${with_xft}" != "xno"
2219
2220     dnl For the "Does Emacs use" message at the end.
2221     if test "$HAVE_XFT" != "yes"; then
2222        HAVE_XFT=no
2223     fi
2224
2225
2226     HAVE_FREETYPE=no
2227     ## We used to allow building with FreeType and without Xft.
2228     ## However, the ftx font backend driver is not in good shape.
2229     if test "${HAVE_XFT}" = "yes"; then
2230       dnl As we use Xft, we anyway use freetype.
2231       dnl There's no need for additional CFLAGS and LIBS.
2232       HAVE_FREETYPE=yes
2233       FONTCONFIG_CFLAGS=
2234       FONTCONFIG_LIBS=
2235     fi
2236
2237     HAVE_LIBOTF=no
2238     if test "${HAVE_FREETYPE}" = "yes"; then
2239       AC_DEFINE(HAVE_FREETYPE, 1,
2240                 [Define to 1 if using the freetype and fontconfig libraries.])
2241       if test "${with_libotf}" != "no"; then
2242         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2243                           HAVE_LIBOTF=no)
2244         if test "$HAVE_LIBOTF" = "yes"; then
2245           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2246           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2247                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2248                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2249           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2250             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2251                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2252           fi
2253         fi
2254       fi
2255     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2256     dnl Does the new font backend require it, or can it work without it?
2257     fi
2258
2259     HAVE_M17N_FLT=no
2260     if test "${HAVE_LIBOTF}" = yes; then
2261       if test "${with_m17n_flt}" != "no"; then
2262         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2263         if test "$HAVE_M17N_FLT" = "yes"; then
2264           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2265         fi
2266       fi
2267     fi
2268 else
2269     HAVE_XFT=no
2270     HAVE_FREETYPE=no
2271     HAVE_LIBOTF=no
2272     HAVE_M17N_FLT=no
2273 fi
2274
2275 ### End of font-backend (under X11) section.
2276
2277 AC_SUBST(FREETYPE_CFLAGS)
2278 AC_SUBST(FREETYPE_LIBS)
2279 AC_SUBST(FONTCONFIG_CFLAGS)
2280 AC_SUBST(FONTCONFIG_LIBS)
2281 AC_SUBST(LIBOTF_CFLAGS)
2282 AC_SUBST(LIBOTF_LIBS)
2283 AC_SUBST(M17N_FLT_CFLAGS)
2284 AC_SUBST(M17N_FLT_LIBS)
2285
2286 ### Use -lXpm if available, unless `--with-xpm=no'.
2287 HAVE_XPM=no
2288 LIBXPM=
2289 if test "${HAVE_X11}" = "yes"; then
2290   if test "${with_xpm}" != "no"; then
2291     AC_CHECK_HEADER(X11/xpm.h,
2292       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2293     if test "${HAVE_XPM}" = "yes"; then
2294       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2295       AC_EGREP_CPP(no_return_alloc_pixels,
2296       [#include "X11/xpm.h"
2297 #ifndef XpmReturnAllocPixels
2298 no_return_alloc_pixels
2299 #endif
2300       ], HAVE_XPM=no, HAVE_XPM=yes)
2301
2302       if test "${HAVE_XPM}" = "yes"; then
2303         AC_MSG_RESULT(yes)
2304       else
2305         AC_MSG_RESULT(no)
2306       fi
2307     fi
2308   fi
2309
2310   if test "${HAVE_XPM}" = "yes"; then
2311     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2312     LIBXPM=-lXpm
2313   fi
2314 fi
2315 AC_SUBST(LIBXPM)
2316
2317 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2318 HAVE_JPEG=no
2319 LIBJPEG=
2320 if test "${HAVE_X11}" = "yes"; then
2321   if test "${with_jpeg}" != "no"; then
2322     dnl Checking for jpeglib.h can lose because of a redefinition of
2323     dnl  HAVE_STDLIB_H.
2324     AC_CHECK_HEADER(jerror.h,
2325       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2326   fi
2327
2328   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2329   if test "${HAVE_JPEG}" = "yes"; then
2330     AC_DEFINE(HAVE_JPEG)
2331     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2332         [#include <jpeglib.h>
2333          version=JPEG_LIB_VERSION
2334 ],
2335         [AC_DEFINE(HAVE_JPEG)],
2336         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2337         HAVE_JPEG=no])
2338   fi
2339   if test "${HAVE_JPEG}" = "yes"; then
2340     LIBJPEG=-ljpeg
2341   fi
2342 fi
2343 AC_SUBST(LIBJPEG)
2344
2345 ### Use -lpng if available, unless `--with-png=no'.
2346 HAVE_PNG=no
2347 LIBPNG=
2348 if test "${HAVE_X11}" = "yes"; then
2349   if test "${with_png}" != "no"; then
2350     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2351     # in /usr/include/libpng.
2352     AC_CHECK_HEADERS(png.h libpng/png.h)
2353     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2354       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2355     fi
2356   fi
2357
2358   if test "${HAVE_PNG}" = "yes"; then
2359     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2360     LIBPNG="-lpng -lz -lm"
2361   fi
2362 fi
2363 AC_SUBST(LIBPNG)
2364
2365 ### Use -ltiff if available, unless `--with-tiff=no'.
2366 HAVE_TIFF=no
2367 LIBTIFF=
2368 if test "${HAVE_X11}" = "yes"; then
2369   if test "${with_tiff}" != "no"; then
2370     AC_CHECK_HEADER(tiffio.h,
2371       [tifflibs="-lz -lm"
2372       # At least one tiff package requires the jpeg library.
2373       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2374       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2375   fi
2376
2377   if test "${HAVE_TIFF}" = "yes"; then
2378     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2379     dnl FIXME -lz -lm, as per libpng?
2380     LIBTIFF=-ltiff
2381   fi
2382 fi
2383 AC_SUBST(LIBTIFF)
2384
2385 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2386 HAVE_GIF=no
2387 LIBGIF=
2388 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2389   AC_CHECK_HEADER(gif_lib.h,
2390 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2391 # Earlier versions can crash Emacs.
2392     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2393
2394   if test "$HAVE_GIF" = yes; then
2395     LIBGIF=-lgif
2396   elif test "$HAVE_GIF" = maybe; then
2397 # If gif_lib.h but no libgif, try libungif.
2398     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2399     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2400   fi
2401
2402   if test "${HAVE_GIF}" = "yes"; then
2403     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2404   fi
2405 fi
2406 AC_SUBST(LIBGIF)
2407
2408 dnl Check for required libraries.
2409 if test "${HAVE_X11}" = "yes"; then
2410   MISSING=""
2411   WITH_NO=""
2412   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2413     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2414   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2415     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2416   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2417     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2418   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2419     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2420   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2421     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2422
2423   if test "X${MISSING}" != X; then
2424     AC_MSG_ERROR([The following required libraries were not found:
2425     $MISSING
2426 Maybe some development libraries/packages are missing?
2427 If you don't want to link with them give
2428     $WITH_NO
2429 as options to configure])
2430   fi
2431 fi
2432
2433 ### Use -lgpm if available, unless `--with-gpm=no'.
2434 HAVE_GPM=no
2435 LIBGPM=
2436 MOUSE_SUPPORT=
2437 if test "${with_gpm}" != "no"; then
2438   AC_CHECK_HEADER(gpm.h,
2439     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2440
2441   if test "${HAVE_GPM}" = "yes"; then
2442     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2443     LIBGPM=-lgpm
2444     ## May be reset below.
2445     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2446   fi
2447 fi
2448 AC_SUBST(LIBGPM)
2449
2450 dnl Check for malloc/malloc.h on darwin
2451 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2452
2453 C_SWITCH_X_SYSTEM=
2454 ### Use NeXTstep API to implement GUI.
2455 if test "${HAVE_NS}" = "yes"; then
2456   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2457   if test "${NS_IMPL_COCOA}" = "yes"; then
2458     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2459     GNU_OBJC_CFLAGS=
2460   fi
2461   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2462     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2463     # See also .m.o rule in Makefile.in */
2464     # FIXME: are all these flags really needed?  Document here why.  */
2465     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2466     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2467   fi
2468   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2469     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2470   fi
2471   # We also have mouse menus.
2472   HAVE_MENUS=yes
2473   OTHER_FILES=ns-app
2474 fi
2475
2476
2477 ### Use session management (-lSM -lICE) if available
2478 HAVE_X_SM=no
2479 LIBXSM=
2480 if test "${HAVE_X11}" = "yes"; then
2481   AC_CHECK_HEADER(X11/SM/SMlib.h,
2482     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2483
2484   if test "${HAVE_X_SM}" = "yes"; then
2485     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2486     LIBXSM="-lSM -lICE"
2487     case "$LIBS" in
2488       *-lSM*) ;;
2489       *)      LIBS="$LIBXSM $LIBS" ;;
2490     esac
2491   fi
2492 fi
2493 AC_SUBST(LIBXSM)
2494
2495 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2496 AC_CACHE_CHECK(whether netdb declares h_errno,
2497                emacs_cv_netdb_declares_h_errno,
2498 [AC_TRY_LINK([#include <netdb.h>],
2499   [return h_errno;],
2500   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2501 if test $emacs_cv_netdb_declares_h_errno = yes; then
2502   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2503 fi
2504
2505 AC_FUNC_ALLOCA
2506
2507 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2508 dnl FIXME is there an autoconf test that does the right thing, without
2509 dnl needing to call A_M_E afterwards?
2510 if test x"$ac_cv_func_alloca_works" != xyes; then
2511    AC_MSG_ERROR( [a system implementation of alloca is required] )
2512 fi
2513
2514 # fmod, logb, and frexp are found in -lm on most systems.
2515 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2516 AC_CHECK_LIB(m, sqrt)
2517
2518 # Check for mail-locking functions in a "mail" library.  Probably this should
2519 # have the same check as for liblockfile below.
2520 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2521 if test $have_mail = yes; then
2522   LIBS_MAIL=-lmail
2523   LIBS="$LIBS_MAIL $LIBS"
2524   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2525 else
2526   LIBS_MAIL=
2527 fi
2528 dnl Debian, at least:
2529 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2530 if test $have_lockfile = yes; then
2531    LIBS_MAIL=-llockfile
2532    LIBS="$LIBS_MAIL $LIBS"
2533    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2534 else
2535 # If we have the shared liblockfile, assume we must use it for mail
2536 # locking (e.g. Debian).  If we couldn't link against liblockfile
2537 # (no liblockfile.a installed), ensure that we don't need to.
2538   dnl This works for files generally, not just executables.
2539   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2540   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2541                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2542   if test $ac_cv_prog_liblockfile = yes; then
2543     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2544 This probably means that movemail could lose mail.
2545 There may be a `development' package to install containing liblockfile.])
2546   fi
2547 fi
2548 AC_CHECK_FUNCS(touchlock)
2549 AC_CHECK_HEADERS(maillock.h)
2550 AC_SUBST(LIBS_MAIL)
2551
2552 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2553 ## interlock access to the mail spool.  The alternative is a lock file named
2554 ## /usr/spool/mail/$USER.lock.
2555 mail_lock=no
2556 case "$opsys" in
2557   aix4-2) mail_lock="lockf" ;;
2558
2559   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2560
2561   ## On GNU/Linux systems, both methods are used by various mail programs.
2562   ## I assume most people are using newer mailers that have heard of flock.
2563   ## Change this if you need to.
2564   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2565   ## configure gets the right answers, and that means *NOT* using flock.
2566   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2567   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2568   ## Debian maintainer hasn't provided a clean fix for Emacs.
2569   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2570   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2571   ## correct logic.  -- fx
2572   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2573   ## liblockfile is a Free Software replacement for libmail, used on
2574   ## Debian systems and elsewhere. -rfr.
2575   gnu-*)
2576     mail_lock="flock"
2577     if test $have_mail = yes || test $have_lockfile = yes; then
2578       test $ac_cv_header_maillock_h = yes && mail_lock=no
2579     fi
2580     ;;
2581 esac
2582
2583 BLESSMAIL_TARGET=
2584 case "$mail_lock" in
2585   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2586
2587   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2588
2589   *) BLESSMAIL_TARGET="need-blessmail" ;;
2590 esac
2591 AC_SUBST(BLESSMAIL_TARGET)
2592
2593
2594 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2595 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2596 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2597 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2598 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2599 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2600 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2601 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2602 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2603 cfmakeraw cfsetspeed isnan copysign)
2604
2605 AC_CHECK_HEADERS(sys/un.h)
2606
2607 AC_FUNC_MKTIME
2608 if test "$ac_cv_func_working_mktime" = no; then
2609   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2610 fi
2611
2612 AC_FUNC_GETLOADAVG
2613
2614 AC_FUNC_FSEEKO
2615
2616 # Configure getopt.
2617 m4_include([m4/getopt.m4])
2618 gl_GETOPT_IFELSE([
2619   gl_GETOPT_SUBSTITUTE_HEADER
2620   gl_PREREQ_GETOPT
2621   GETOPTOBJS='getopt.o getopt1.o'
2622 ])
2623 AC_SUBST(GETOPTOBJS)
2624
2625 AC_FUNC_GETPGRP
2626
2627 AC_FUNC_STRFTIME
2628
2629 # UNIX98 PTYs.
2630 AC_CHECK_FUNCS(grantpt)
2631
2632 # PTY-related GNU extensions.
2633 AC_CHECK_FUNCS(getpt)
2634
2635 # Check this now, so that we will NOT find the above functions in ncurses.
2636 # That is because we have not set up to link ncurses in lib-src.
2637 # It's better to believe a function is not available
2638 # than to expect to find it in ncurses.
2639 # Also we need tputs and friends to be able to build at all.
2640 have_tputs_et_al=true
2641 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2642 if test "$have_tputs_et_al" != true; then
2643   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2644 Maybe some development libraries/packages are missing?  Try installing
2645 libncurses-dev(el), libterminfo-dev(el) or similar.])
2646 fi
2647 # Must define this when any termcap library is found.
2648 AC_DEFINE(HAVE_LIBNCURSES, 1,
2649           [Define to 1 if you have the `ncurses' library (-lncurses).])
2650 ## FIXME This was the cpp logic, but I am not sure it is right.
2651 ## The above test has not necessarily found libncurses.
2652 HAVE_LIBNCURSES=yes
2653
2654 ## Use terminfo instead of termcap?
2655 ## Note only system files NOT using terminfo are:
2656 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2657 ## darwin|gnu without ncurses.
2658 TERMINFO=no
2659 LIBS_TERMCAP=
2660 case "$opsys" in
2661   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2662   ## hpux10-20: Use the system provided termcap(3) library.
2663   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2664   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2665   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2666
2667   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2668   ##  The ncurses library has been moved out of the System framework in
2669   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2670   ##  option to use it.
2671   darwin|gnu*)
2672     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2673     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2674       TERMINFO=yes
2675       LIBS_TERMCAP="-lncurses"
2676     fi
2677     ;;
2678
2679   freebsd)
2680     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2681     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2682     [AC_TRY_LINK([#include <osreldate.h>],
2683 [#if __FreeBSD_version < 400000
2684 fail;
2685 #endif
2686 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2687
2688     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2689
2690     if test $emacs_cv_freebsd_terminfo = yes; then
2691       TERMINFO=yes
2692       LIBS_TERMCAP="-lncurses"
2693     else
2694       LIBS_TERMCAP="-ltermcap"
2695     fi
2696     ;;
2697
2698   netbsd)
2699     if test $ac_cv_search_tputs = -lterminfo; then
2700       TERMINFO=yes
2701       LIBS_TERMCAP="-lterminfo"
2702     else
2703       LIBS_TERMCAP="-ltermcap"
2704     fi
2705     ;;
2706
2707 esac
2708
2709 case "$opsys" in
2710   ## hpux: Make sure we get select from libc rather than from libcurses
2711   ##  because libcurses on HPUX 10.10 has a broken version of select.
2712   ##  We used to use -lc -lcurses, but this may be cleaner.
2713   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2714
2715   openbsd) LIBS_TERMCAP="-lncurses" ;;
2716
2717   ## Must use system termcap, if we use any termcap.  It does special things.
2718   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2719 esac
2720
2721 TERMCAP_OBJ=tparam.o
2722 if test $TERMINFO = yes; then
2723   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2724
2725   ## Default used to be -ltermcap.  Add a case above if need something else.
2726   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2727
2728   TERMCAP_OBJ=terminfo.o
2729 fi
2730 AC_SUBST(LIBS_TERMCAP)
2731 AC_SUBST(TERMCAP_OBJ)
2732
2733
2734 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2735 resolv=no
2736 AC_TRY_LINK([#include <netinet/in.h>
2737 #include <arpa/nameser.h>
2738 #include <resolv.h>],
2739     [return res_init();],
2740     have_res_init=yes, have_res_init=no)
2741 if test "$have_res_init" = no; then
2742   OLIBS="$LIBS"
2743   LIBS="$LIBS -lresolv"
2744   AC_MSG_CHECKING(for res_init with -lresolv)
2745   AC_TRY_LINK([#include <netinet/in.h>
2746 #include <arpa/nameser.h>
2747 #include <resolv.h>],
2748     [return res_init();],
2749     have_res_init=yes, have_res_init=no)
2750   AC_MSG_RESULT($have_res_init)
2751   if test "$have_res_init" = yes ; then
2752     resolv=yes
2753   fi
2754   LIBS="$OLIBS"
2755 fi
2756
2757 if test "$have_res_init" = yes; then
2758   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2759 fi
2760
2761 # Do we need the Hesiod library to provide the support routines?
2762 LIBHESIOD=
2763 if test "$with_hesiod" != no ; then
2764   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2765   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2766      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2767                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2768   if test "$resolv" = yes ; then
2769     RESOLVLIB=-lresolv
2770   else
2771     RESOLVLIB=
2772   fi
2773   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2774         hesiod=yes, :, $RESOLVLIB)])
2775
2776   if test x"$hesiod" = xyes; then
2777     AC_DEFINE(HAVE_LIBHESIOD, 1,
2778               [Define to 1 if you have the hesiod library (-lhesiod).])
2779     LIBHESIOD=-lhesiod
2780   fi
2781 fi
2782 AC_SUBST(LIBHESIOD)
2783
2784 # Do we need libresolv (due to res_init or Hesiod)?
2785 if test "$resolv" = yes ; then
2786   AC_DEFINE(HAVE_LIBRESOLV, 1,
2787             [Define to 1 if you have the resolv library (-lresolv).])
2788   LIBRESOLV=-lresolv
2789 else
2790   LIBRESOLV=
2791 fi
2792 AC_SUBST(LIBRESOLV)
2793
2794 # These tell us which Kerberos-related libraries to use.
2795 COM_ERRLIB=
2796 CRYPTOLIB=
2797 KRB5LIB=
2798 DESLIB=
2799 KRB4LIB=
2800
2801 if test "${with_kerberos}" != no; then
2802   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2803   if test $have_com_err = yes; then
2804     COM_ERRLIB=-lcom_err
2805     LIBS="$COM_ERRLIB $LIBS"
2806     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2807   fi
2808   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2809   if test $have_crypto = yes; then
2810     CRYPTOLIB=-lcrypto
2811     LIBS="$CRYPTOLIB $LIBS"
2812     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2813   fi
2814   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2815   if test $have_k5crypto = yes; then
2816     CRYPTOLIB=-lk5crypto
2817     LIBS="$CRYPTOLIB $LIBS"
2818     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2819   fi
2820   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2821   if test $have_krb5=yes; then
2822     KRB5LIB=-lkrb5
2823     LIBS="$KRB5LIB $LIBS"
2824     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2825   fi
2826   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2827   if test "${with_kerberos5}" = no; then
2828     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2829     if test $have_des425 = yes; then
2830       DESLIB=-ldes425
2831       LIBS="$DESLIB $LIBS"
2832       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2833     else
2834       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2835       if test $have_des = yes; then
2836         DESLIB=-ldes
2837         LIBS="$DESLIB $LIBS"
2838         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2839       fi
2840     fi
2841     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2842     if test $have_krb4 = yes; then
2843       KRB4LIB=-lkrb4
2844       LIBS="$KRB4LIB $LIBS"
2845       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2846     else
2847       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2848       if test $have_krb = yes; then
2849         KRB4LIB=-lkrb
2850         LIBS="$KRB4LIB $LIBS"
2851         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2852       fi
2853     fi
2854   fi
2855
2856   if test "${with_kerberos5}" != no; then
2857     AC_CHECK_HEADERS(krb5.h,
2858       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2859                         [#include <krb5.h>])])
2860   else
2861     AC_CHECK_HEADERS(des.h,,
2862                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2863                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2864     AC_CHECK_HEADERS(krb.h,,
2865                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2866                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2867   fi
2868   AC_CHECK_HEADERS(com_err.h)
2869 fi
2870
2871 AC_SUBST(COM_ERRLIB)
2872 AC_SUBST(CRYPTOLIB)
2873 AC_SUBST(KRB5LIB)
2874 AC_SUBST(DESLIB)
2875 AC_SUBST(KRB4LIB)
2876
2877 # Solaris requires -lintl if you want strerror (which calls dgettext)
2878 # to return localized messages.
2879 AC_CHECK_LIB(intl, dgettext)
2880
2881 AC_MSG_CHECKING(whether localtime caches TZ)
2882 AC_CACHE_VAL(emacs_cv_localtime_cache,
2883 [if test x$ac_cv_func_tzset = xyes; then
2884 AC_TRY_RUN([#include <time.h>
2885 extern char **environ;
2886 unset_TZ ()
2887 {
2888   char **from, **to;
2889   for (to = from = environ; (*to = *from); from++)
2890     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2891       to++;
2892 }
2893 char TZ_GMT0[] = "TZ=GMT0";
2894 char TZ_PST8[] = "TZ=PST8";
2895 main()
2896 {
2897   time_t now = time ((time_t *) 0);
2898   int hour_GMT0, hour_unset;
2899   if (putenv (TZ_GMT0) != 0)
2900     exit (1);
2901   hour_GMT0 = localtime (&now)->tm_hour;
2902   unset_TZ ();
2903   hour_unset = localtime (&now)->tm_hour;
2904   if (putenv (TZ_PST8) != 0)
2905     exit (1);
2906   if (localtime (&now)->tm_hour == hour_GMT0)
2907     exit (1);
2908   unset_TZ ();
2909   if (localtime (&now)->tm_hour != hour_unset)
2910     exit (1);
2911   exit (0);
2912 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2913 [# If we have tzset, assume the worst when cross-compiling.
2914 emacs_cv_localtime_cache=yes])
2915 else
2916         # If we lack tzset, report that localtime does not cache TZ,
2917         # since we can't invalidate the cache if we don't have tzset.
2918         emacs_cv_localtime_cache=no
2919 fi])dnl
2920 AC_MSG_RESULT($emacs_cv_localtime_cache)
2921 if test $emacs_cv_localtime_cache = yes; then
2922   AC_DEFINE(LOCALTIME_CACHE, 1,
2923             [Define to 1 if localtime caches TZ.])
2924 fi
2925
2926 if test "x$HAVE_TIMEVAL" = xyes; then
2927   AC_CHECK_FUNCS(gettimeofday)
2928   if test $ac_cv_func_gettimeofday = yes; then
2929     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2930                    emacs_cv_gettimeofday_two_arguments,
2931     [AC_TRY_COMPILE([
2932 #ifdef TIME_WITH_SYS_TIME
2933 #include <sys/time.h>
2934 #include <time.h>
2935 #else
2936 #ifdef HAVE_SYS_TIME_H
2937 #include <sys/time.h>
2938 #else
2939 #include <time.h>
2940 #endif
2941 #endif],
2942       [struct timeval time;
2943        gettimeofday (&time, 0);],
2944       emacs_cv_gettimeofday_two_arguments=yes,
2945       emacs_cv_gettimeofday_two_arguments=no)])
2946     if test $emacs_cv_gettimeofday_two_arguments = no; then
2947       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2948                 [Define to 1 if gettimeofday accepts only one argument.])
2949     fi
2950   fi
2951 fi
2952
2953 ok_so_far=yes
2954 AC_CHECK_FUNC(socket, , ok_so_far=no)
2955 if test $ok_so_far = yes; then
2956   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2957 fi
2958 if test $ok_so_far = yes; then
2959   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2960 fi
2961 if test $ok_so_far = yes; then
2962 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2963   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2964             [Define to 1 if you have inet sockets.])
2965 fi
2966
2967 AC_CHECK_HEADERS(sys/ioctl.h)
2968
2969 if test -f /usr/lpp/X11/bin/smt.exp; then
2970   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2971             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2972 fi
2973
2974 AC_MSG_CHECKING(whether system supports dynamic ptys)
2975 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2976   AC_MSG_RESULT(yes)
2977   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2978 else
2979   AC_MSG_RESULT(no)
2980 fi
2981
2982 AC_FUNC_FORK
2983
2984 dnl Adapted from Haible's version.
2985 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2986   [AC_TRY_LINK([#include <langinfo.h>],
2987     [char* cs = nl_langinfo(CODESET);],
2988     emacs_cv_langinfo_codeset=yes,
2989     emacs_cv_langinfo_codeset=no)
2990   ])
2991 if test $emacs_cv_langinfo_codeset = yes; then
2992   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2993     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2994 fi
2995
2996 AC_CHECK_TYPES(size_t)
2997
2998 AC_TYPE_MBSTATE_T
2999
3000 dnl Restrict could probably be used effectively other than in regex.c.
3001 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
3002   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
3003                   emacs_cv_c_restrict=yes,
3004                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
3005                                   emacs_cv_c_restrict=__restrict,
3006                                   emacs_cv_c_restrict=no)])])
3007 case "$emacs_cv_c_restrict" in
3008   yes) emacs_restrict=restrict;;
3009   no) emacs_restrict="";;
3010   *) emacs_restrict="$emacs_cv_c_restrict";;
3011 esac
3012 if test "$emacs_restrict" != __restrict; then
3013   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
3014     [Define to compiler's equivalent of C99 restrict keyword.
3015      Don't define if equivalent is `__restrict'.])
3016 fi
3017
3018 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3019   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3020                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3021 if test "$emacs_cv_c_restrict_arr" = yes; then
3022   AC_DEFINE(__restrict_arr, __restrict,
3023     [Define to compiler's equivalent of C99 restrict keyword in array
3024      declarations.  Define as empty for no equivalent.])
3025 fi
3026
3027 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3028 dnl how the tty code is related to POSIX and/or other versions of termios.
3029 dnl The following looks like a useful start.
3030 dnl
3031 dnl AC_SYS_POSIX_TERMIOS
3032 dnl if test $ac_cv_sys_posix_termios = yes; then
3033 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3034 dnl                                and macros for terminal control.])
3035 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3036 dnl fi
3037
3038 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3039
3040 # Set up the CFLAGS for real compilation, so we can substitute it.
3041 CFLAGS="$REAL_CFLAGS"
3042 CPPFLAGS="$REAL_CPPFLAGS"
3043
3044 ## Hack to detect a buggy GCC version.
3045 if test "x$GCC" = xyes \
3046    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3047    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3048    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3049    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3050 fi
3051
3052 #### Find out which version of Emacs this is.
3053 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3054          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3055 if test x"${version}" = x; then
3056   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3057 fi
3058 if test x"${version}" != x"$PACKAGE_VERSION"; then
3059   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3060 fi
3061
3062 ### Specify what sort of things we'll be editing into Makefile and config.h.
3063 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3064 AC_SUBST(version)
3065 AC_SUBST(configuration)
3066 ## Unused?
3067 AC_SUBST(canonical)
3068 AC_SUBST(srcdir)
3069 AC_SUBST(prefix)
3070 AC_SUBST(exec_prefix)
3071 AC_SUBST(bindir)
3072 AC_SUBST(datadir)
3073 AC_SUBST(sharedstatedir)
3074 AC_SUBST(libexecdir)
3075 AC_SUBST(mandir)
3076 AC_SUBST(infodir)
3077 AC_SUBST(lispdir)
3078 AC_SUBST(locallisppath)
3079 AC_SUBST(lisppath)
3080 AC_SUBST(x_default_search_path)
3081 AC_SUBST(etcdir)
3082 AC_SUBST(archlibdir)
3083 AC_SUBST(docdir)
3084 AC_SUBST(bitmapdir)
3085 AC_SUBST(gamedir)
3086 AC_SUBST(gameuser)
3087 AC_SUBST(unexec)
3088 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3089 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3090 ## end of LIBX_BASE, but nothing ever set it.
3091 AC_SUBST(LD_SWITCH_X_SITE)
3092 AC_SUBST(C_SWITCH_X_SITE)
3093 AC_SUBST(C_SWITCH_X_SYSTEM)
3094 AC_SUBST(CFLAGS)
3095 ## Used in lwlib/Makefile.in.
3096 AC_SUBST(X_TOOLKIT_TYPE)
3097 AC_SUBST(machfile)
3098 AC_SUBST(opsysfile)
3099 AC_SUBST(GETLOADAVG_LIBS)
3100 AC_SUBST(ns_appdir)
3101 AC_SUBST(ns_appbindir)
3102 AC_SUBST(ns_appresdir)
3103 AC_SUBST(ns_appsrc)
3104 AC_SUBST(GNU_OBJC_CFLAGS)
3105 AC_SUBST(OTHER_FILES)
3106
3107 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3108                    [Define to the canonical Emacs configuration name.])
3109 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3110                    [Define to the options passed to configure.])
3111 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3112                    [Define to the used machine dependent file.])
3113 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3114                    [Define to the used os dependent file.])
3115
3116 XMENU_OBJ=
3117 XOBJ=
3118 FONT_OBJ=
3119 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3120   AC_DEFINE(HAVE_X_WINDOWS, 1,
3121             [Define to 1 if you want to use the X window system.])
3122   XMENU_OBJ=xmenu.o
3123   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3124   FONT_OBJ=xfont.o
3125   if test "$HAVE_XFT" = "yes"; then
3126     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3127   elif test "$HAVE_FREETYPE" = "yes"; then
3128     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3129   fi
3130   AC_SUBST(FONT_OBJ)
3131 fi
3132 AC_SUBST(XMENU_OBJ)
3133 AC_SUBST(XOBJ)
3134 AC_SUBST(FONT_OBJ)
3135
3136 WIDGET_OBJ=
3137 MOTIF_LIBW=
3138 if test "${USE_X_TOOLKIT}" != "none" ; then
3139   WIDGET_OBJ=widget.o
3140   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3141   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3142     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3143   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3144     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3145     MOTIF_LIBW=-lXm
3146     case "$opsys" in
3147       gnu-linux)
3148         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3149         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3150         ;;
3151
3152       unixware)
3153         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3154         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3155         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3156         ;;
3157
3158       aix4-2)
3159         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3160         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3161         ;;
3162     esac
3163     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3164   fi
3165 fi
3166 AC_SUBST(WIDGET_OBJ)
3167
3168 TOOLKIT_LIBW=
3169 case "$USE_X_TOOLKIT" in
3170   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3171   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3172   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3173 esac
3174 AC_SUBST(TOOLKIT_LIBW)
3175
3176 if test "$USE_X_TOOLKIT" = "none"; then
3177   LIBXT_OTHER="\$(LIBXSM)"
3178   OLDXMENU_TARGET="really-oldXMenu"
3179 else
3180   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3181   OLDXMENU_TARGET="really-lwlib"
3182 fi
3183 AC_SUBST(LIBXT_OTHER)
3184 AC_SUBST(OLDXMENU_TARGET)
3185
3186 ## The X Menu stuff is present in the X10 distribution, but missing
3187 ## from X11.  If we have X10, just use the installed library;
3188 ## otherwise, use our own copy.
3189 if test "${HAVE_X11}" = "yes" ; then
3190   AC_DEFINE(HAVE_X11, 1,
3191             [Define to 1 if you want to use version 11 of X windows.
3192              Otherwise, Emacs expects to use version 10.])
3193
3194   if test "$USE_X_TOOLKIT" = "none"; then
3195     OLDXMENU="\${oldXMenudir}libXMenu11.a"
3196   else
3197     OLDXMENU="\${lwlibdir}liblw.a"
3198   fi
3199   LIBXMENU="\$(OLDXMENU)"
3200   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3201   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3202 else
3203   OLDXMENU=
3204   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3205   if test "${HAVE_X_WINDOWS}" = "yes"; then
3206     LIBXMENU="-lXMenu"
3207   else
3208     LIBXMENU=
3209   fi
3210   LIBX_OTHER=
3211   OLDXMENU_DEPS=
3212 fi
3213
3214 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3215   OLDXMENU=
3216   LIBXMENU=
3217   OLDXMENU_DEPS=
3218 fi
3219
3220 AC_SUBST(OLDXMENU)
3221 AC_SUBST(LIBXMENU)
3222 AC_SUBST(LIBX_OTHER)
3223 AC_SUBST(OLDXMENU_DEPS)
3224
3225 if test "${HAVE_MENUS}" = "yes" ; then
3226   AC_DEFINE(HAVE_MENUS, 1,
3227             [Define to 1 if you have mouse menus.
3228              (This is automatic if you use X, but the option to specify it remains.)
3229              It is also defined with other window systems that support xmenu.c.])
3230 fi
3231
3232 if test "${GNU_MALLOC}" = "yes" ; then
3233   AC_DEFINE(GNU_MALLOC, 1,
3234             [Define to 1 if you want to use the GNU memory allocator.])
3235 fi
3236
3237 RALLOC_OBJ=
3238 if test "${REL_ALLOC}" = "yes" ; then
3239   AC_DEFINE(REL_ALLOC, 1,
3240             [Define REL_ALLOC if you want to use the relocating allocator for
3241              buffer space.])
3242
3243   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3244 fi
3245 AC_SUBST(RALLOC_OBJ)
3246
3247 if test "$opsys" = "cygwin"; then
3248   CYGWIN_OBJ="sheap.o"
3249   ## Cygwin differs because of its unexec().
3250   PRE_ALLOC_OBJ=
3251   POST_ALLOC_OBJ=lastfile.o
3252 else
3253   CYGWIN_OBJ=
3254   PRE_ALLOC_OBJ=lastfile.o
3255   POST_ALLOC_OBJ=
3256 fi
3257 AC_SUBST(CYGWIN_OBJ)
3258 AC_SUBST(PRE_ALLOC_OBJ)
3259 AC_SUBST(POST_ALLOC_OBJ)
3260
3261
3262 case "$opsys" in
3263   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3264
3265   darwin)
3266   ## The -headerpad option tells ld (see man page) to leave room at the
3267   ## end of the header for adding load commands.  Needed for dumping.
3268   ## 0x690 is the total size of 30 segment load commands (at 56
3269   ## each); under Cocoa 31 commands are required.
3270   if test "$HAVE_NS" = "yes"; then
3271     libs_nsgui="-framework AppKit"
3272     headerpad_extra=6C8
3273   else
3274     libs_nsgui=
3275     headerpad_extra=690
3276   fi
3277   LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3278   ;;
3279
3280   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3281 esac
3282 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3283
3284
3285 ## This exists because src/Makefile.in did some extra fiddling around
3286 ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3287 ##   #ifndef LD_SWITCH_SYSTEM
3288 ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3289 ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3290 ## not using gcc, darwin system not on an alpha (ie darwin, since
3291 ## darwin + alpha does not occur).
3292 ## Note that unlike L_S_S, this is not used in ac_link.
3293 if test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3294    test "$opsys" = "darwin"; then
3295   LD_SWITCH_SYSTEM_EXTRA="-X"
3296 else
3297   LD_SWITCH_SYSTEM_EXTRA=
3298 fi
3299 AC_SUBST(LD_SWITCH_SYSTEM_EXTRA)
3300
3301
3302 LINKER=
3303 ORDINARY_LINK=
3304 case "$opsys" in
3305   ## gnu: GNU needs its own crt0.
3306   aix4-2|darwin|gnu|usg5-4|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3307
3308   cygwin) LINKER="\$(CC)" ;;
3309
3310   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3311   ## library search parth, i.e. it won't search /usr/lib for libc and
3312   ## friends.  Using -nostartfiles instead avoids this problem, and
3313   ## will also work on earlier NetBSD releases.
3314   netbsd|openbsd) LINKER="\$(CC) -nostartfiles" ;;
3315
3316   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3317   ##   MkLinux/LinuxPPC needs this.
3318   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3319   gnu-*)
3320     case "$machine" in
3321       macppc|ibms390x) LINKER="\$(CC) -nostdlib" ;;
3322     esac
3323     ;;
3324 esac
3325
3326 ## A macro which other sections of Makefile can redefine to munge the
3327 ## flags before they are passed to LD.  This is helpful if you have
3328 ## redefined LD to something odd, like "gcc".
3329 ## (The YMF prefix is a holdover from the old name "ymakefile".)
3330 YMF_PASS_LDFLAGS=flags
3331 if test "x$ORDINARY_LINK" = "xyes"; then
3332
3333   LINKER="\$(CC)"
3334   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3335
3336 ## The system files defining neither ORDINARY_LINK nor LINKER are:
3337 ## (bsd-common), freebsd, gnu-* not on macppc|ibms390x, hpux*.
3338 elif test "x$GCC" = "xyes" && test "x$LINKER" = "x"; then
3339
3340   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3341   ## places that are difficult to figure out at make time.  Fortunately,
3342   ## these same versions allow you to pass arbitrary flags on to the
3343   ## linker, so there is no reason not to use it as a linker.
3344   ##
3345   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3346   ## searching for libraries in its internal directories, so we have to
3347   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3348   LINKER="\$(CC) -nostdlib"
3349   ## GCC passes any argument prefixed with -Xlinker directly to the linker.
3350   ## See prefix-args.c for an explanation of why we do not do this with the
3351   ## shell''s ``for'' construct.  Note that sane people do not have '.' in
3352   ## their paths, so we must use ./prefix-args.
3353   ## TODO either make prefix-args check ORDINARY_LINK internally,
3354   ## or remove it altogether (bug#6184), removing the need for this macro.
3355   YMF_PASS_LDFLAGS='`./prefix-args -Xlinker flags`'
3356 fi
3357 AC_SUBST(YMF_PASS_LDFLAGS)
3358
3359 test "x$LINKER" = "x" && LINKER=ld
3360 ## FIXME? What setting of YMF_PASS_LDFLAGS should this have?
3361 test "$NS_IMPL_GNUSTEP" = "yes" && LINKER="\$(CC) -rdynamic"
3362
3363 AC_SUBST(LINKER)
3364
3365
3366 ## FIXME? The logic here is not precisely the same as that above
3367 ## setting YMF_PASS_LDFLAGS.  There is no check here for a pre-defined
3368 ## LINKER.  Should we only be setting LIB_GCC if LD ~ -nostdlib?
3369 LIB_GCC=
3370 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3371
3372   case "$opsys" in
3373     ## cygwin: don't link against static libgcc.
3374     cygwin|freebsd|netbsd|openbsd) LIB_GCC= ;;
3375
3376     gnu-*)
3377       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3378       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3379       ## Note that m/arm.h never bothered to undefine LIB_GCC first.
3380       if test "$machine" = "arm"; then
3381         LIB_GCC="-lgcc_s"
3382       else
3383         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3384         ## immediately undefine it again and redefine it to empty.
3385         ## Was the C_SWITCH_X_SITE part really necessary?
3386 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3387         LIB_GCC=
3388       fi
3389       ;;
3390
3391     ## Ask GCC where to find libgcc.a.
3392     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3393   esac
3394 fi                              dnl if $GCC
3395 AC_SUBST(LIB_GCC)
3396
3397
3398 TOOLTIP_SUPPORT=
3399 WINDOW_SUPPORT=
3400 ## If we're using X11/GNUstep, define some consequences.
3401 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3402   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3403   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3404   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3405   TOOLTIP_SUPPORT="\${lispsource}mouse.elc"
3406
3407   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3408   test "$HAVE_X_WINDOWS" = "yes" && \
3409     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3410
3411 fi
3412 AC_SUBST(MOUSE_SUPPORT)
3413 AC_SUBST(TOOLTIP_SUPPORT)
3414 AC_SUBST(WINDOW_SUPPORT)
3415
3416
3417 AH_TOP([/* GNU Emacs site configuration template file.
3418    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3419      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
3420
3421 This file is part of GNU Emacs.
3422
3423 GNU Emacs is free software: you can redistribute it and/or modify
3424 it under the terms of the GNU General Public License as published by
3425 the Free Software Foundation, either version 3 of the License, or
3426 (at your option) any later version.
3427
3428 GNU Emacs is distributed in the hope that it will be useful,
3429 but WITHOUT ANY WARRANTY; without even the implied warranty of
3430 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3431 GNU General Public License for more details.
3432
3433 You should have received a copy of the GNU General Public License
3434 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3435
3436
3437 /* No code in Emacs #includes config.h twice, but some bits of code
3438    intended to work with other packages as well (like gmalloc.c)
3439    think they can include it as many times as they like.  */
3440 #ifndef EMACS_CONFIG_H
3441 #define EMACS_CONFIG_H
3442 ])dnl
3443
3444 AH_BOTTOM([
3445 /* Define AMPERSAND_FULL_NAME if you use the convention
3446    that & in the full name stands for the login id.  */
3447 /* Turned on June 1996 supposing nobody will mind it.  */
3448 #define AMPERSAND_FULL_NAME
3449
3450 /* Define HAVE_SOUND if we have sound support.  We know it works
3451    and compiles only on the specified platforms.   For others,
3452    it probably doesn't make sense to try.  */
3453
3454 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
3455 #ifdef HAVE_MACHINE_SOUNDCARD_H
3456 #define HAVE_SOUND 1
3457 #endif
3458 #ifdef HAVE_SYS_SOUNDCARD_H
3459 #define HAVE_SOUND 1
3460 #endif
3461 #ifdef HAVE_SOUNDCARD_H
3462 #define HAVE_SOUND 1
3463 #endif
3464 #ifdef HAVE_ALSA
3465 #define HAVE_SOUND 1
3466 #endif
3467 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
3468
3469 /* If using GNU, then support inline function declarations.  */
3470 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3471    generally, because even if non-gcc compilers accept `inline', they
3472    may reject `extern inline'.  */
3473 #if defined (__GNUC__) && defined (OPTIMIZE)
3474 #define INLINE __inline__
3475 #else
3476 #define INLINE
3477 #endif
3478
3479 /* `subprocesses' should be defined if you want to
3480    have code for asynchronous subprocesses
3481    (as used in M-x compile and M-x shell).
3482    Only MSDOS does not support this (it overrides
3483    this in its config_opsysfile below).  */
3484
3485 #define subprocesses
3486
3487 /* Include the os and machine dependent files.  */
3488 #include config_opsysfile
3489 #include config_machfile
3490
3491 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
3492   (There is probably a better place to do this, but right now the Cocoa
3493    side does this in s/darwin.h and we cannot
3494    parallel this exactly since GNUstep is multi-OS.  */
3495 #ifdef HAVE_NS
3496 # ifdef NS_IMPL_GNUSTEP
3497 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3498 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
3499 #  define SYSTEM_PURESIZE_EXTRA 30000
3500 # endif /* NS_IMPL_GNUSTEP */
3501 #endif /* HAVE_NS */
3502
3503 /* SIGTYPE is the macro we actually use.  */
3504 #ifndef SIGTYPE
3505 #define SIGTYPE RETSIGTYPE
3506 #endif
3507
3508 #ifdef emacs /* Don't do this for lib-src.  */
3509 /* Tell regex.c to use a type compatible with Emacs.  */
3510 #define RE_TRANSLATE_TYPE Lisp_Object
3511 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3512 #ifdef make_number
3513 /* If make_number is a macro, use it.  */
3514 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3515 #else
3516 /* If make_number is a function, avoid it.  */
3517 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3518 #endif
3519 #endif
3520
3521 /* Avoid link-time collision with system mktime if we will use our own.  */
3522 #if ! HAVE_MKTIME || BROKEN_MKTIME
3523 #define mktime emacs_mktime
3524 #endif
3525
3526 #define my_strftime nstrftime   /* for strftime.c */
3527
3528 /* The rest of the code currently tests the CPP symbol BSTRING.
3529    Override any claims made by the system-description files.
3530    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
3531 #undef BSTRING
3532 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
3533 #define BSTRING
3534 #endif
3535
3536 /* Some of the files of Emacs which are intended for use with other
3537    programs assume that if you have a config.h file, you must declare
3538    the type of getenv.
3539
3540    This declaration shouldn't appear when alloca.s or Makefile.in
3541    includes config.h.  */
3542 #ifndef NOT_C_CODE
3543 extern char *getenv ();
3544 #endif
3545
3546 /* These default definitions are good for almost all machines.
3547    The exceptions override them in m/MACHINE.h.  */
3548
3549 #ifndef BITS_PER_CHAR
3550 #define BITS_PER_CHAR 8
3551 #endif
3552
3553 #ifndef BITS_PER_SHORT
3554 #define BITS_PER_SHORT 16
3555 #endif
3556
3557 /* Note that lisp.h uses this in a preprocessor conditional, so it
3558    would not work to use sizeof.  That being so, we do all of them
3559    without sizeof, for uniformity's sake.  */
3560 #ifndef BITS_PER_INT
3561 #define BITS_PER_INT 32
3562 #endif
3563
3564 #ifndef BITS_PER_LONG
3565 #ifdef _LP64
3566 #define BITS_PER_LONG 64
3567 #else
3568 #define BITS_PER_LONG 32
3569 #endif
3570 #endif
3571
3572 /* Define if the compiler supports function prototypes.  It may do so
3573    but not define __STDC__ (e.g. DEC C by default) or may define it as
3574    zero.  */
3575 #undef PROTOTYPES
3576 /* For mktime.c:  */
3577 #ifndef __P
3578 # if defined PROTOTYPES
3579 #  define __P(args) args
3580 # else
3581 #  define __P(args) ()
3582 # endif  /* GCC.  */
3583 #endif /* __P */
3584
3585 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
3586 #ifndef NOT_C_CODE
3587 #ifdef HAVE_STRING_H
3588 #include "string.h"
3589 #endif
3590 #ifdef HAVE_STRINGS_H
3591 #include "strings.h"  /* May be needed for bcopy & al.  */
3592 #endif
3593 #ifdef HAVE_STDLIB_H
3594 #include <stdlib.h>
3595 #endif
3596 #ifndef __GNUC__
3597 # ifdef HAVE_ALLOCA_H
3598 #  include <alloca.h>
3599 # else /* AIX files deal with #pragma.  */
3600 #  ifndef alloca /* predefined by HP cc +Olibcalls */
3601 char *alloca ();
3602 #  endif
3603 # endif /* HAVE_ALLOCA_H */
3604 #endif /* __GNUC__ */
3605 #ifndef HAVE_SIZE_T
3606 typedef unsigned size_t;
3607 #endif
3608 #endif /* NOT_C_CODE */
3609
3610 /* Define HAVE_X_I18N if we have usable i18n support.  */
3611
3612 #ifdef HAVE_X11R6
3613 #define HAVE_X_I18N
3614 #endif
3615
3616 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
3617
3618 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
3619 #define HAVE_X11R6_XIM
3620 #endif
3621
3622 #if defined __GNUC__ && (__GNUC__ > 2 \
3623                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3624 #define NO_RETURN       __attribute__ ((__noreturn__))
3625 #else
3626 #define NO_RETURN       /* nothing */
3627 #endif
3628
3629 /* These won't be used automatically yet.  We also need to know, at least,
3630    that the stack is continuous.  */
3631 #ifdef __GNUC__
3632 #  ifndef GC_SETJMP_WORKS
3633   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3634 #    define GC_SETJMP_WORKS 1
3635 #  endif
3636 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3637 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3638 #  endif
3639 #endif
3640
3641 #ifndef HAVE_BCOPY
3642 #define bcopy(a,b,s) memcpy (b,a,s)
3643 #endif
3644 #ifndef HAVE_BZERO
3645 #define bzero(a,s) memset (a,0,s)
3646 #endif
3647 #ifndef HAVE_BCMP
3648 #define BCMP memcmp
3649 #endif
3650
3651 #endif /* EMACS_CONFIG_H */
3652
3653 /*
3654 Local Variables:
3655 mode: c
3656 End:
3657 */
3658 ])dnl
3659
3660 #### Report on what we decided to do.
3661 #### Report GTK as a toolkit, even if it doesn't use Xt.
3662 #### It makes printing result more understandable as using GTK sets
3663 #### toolkit_scroll_bars to yes by default.
3664 if test "${HAVE_GTK}" = "yes"; then
3665   USE_X_TOOLKIT=GTK
3666 fi
3667
3668 echo "
3669 Configured for \`${canonical}'.
3670
3671   Where should the build process find the source code?    ${srcdir}
3672   What operating system and machine description files should Emacs use?
3673         \`${opsysfile}' and \`${machfile}'
3674   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3675   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3676   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3677   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3678   What window system should Emacs use?                    ${window_system}
3679   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3680
3681 if test -n "${x_includes}"; then
3682 echo "  Where do we find X Windows header files?                ${x_includes}"
3683 else
3684 echo "  Where do we find X Windows header files?                Standard dirs"
3685 fi
3686 if test -n "${x_libraries}"; then
3687 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3688 else
3689 echo "  Where do we find X Windows libraries?                   Standard dirs"
3690 fi
3691
3692 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3693 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3694 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3695 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3696 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3697 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3698 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3699 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3700 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3701 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3702 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3703
3704 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3705 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3706 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3707 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3708
3709 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3710 echo
3711
3712 if test $USE_XASSERTS = yes; then
3713    echo "  Compiling with asserts turned on."
3714    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3715 fi
3716
3717 echo
3718
3719 if test "$HAVE_NS" = "yes"; then
3720    echo
3721    echo "You must run \"make install\" in order to test the built application.
3722 The installed application will go to nextstep/Emacs.app and can be
3723 run or moved from there."
3724    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3725       echo "The application will be fully self-contained."
3726     else
3727       echo "The lisp resources for the application will be installed under ${prefix}.
3728 You may need to run \"make install\" with sudo.  The application will fail
3729 to run if these resources are not installed."
3730    fi
3731    echo
3732 fi
3733
3734 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3735   echo "D-Bus integration has been tested for GNU/Linux only."
3736   echo
3737 fi
3738
3739
3740 # Remove any trailing slashes in these variables.
3741 [test "${prefix}" != NONE &&
3742   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3743 test "${exec_prefix}" != NONE &&
3744   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3745
3746 # Now get this: Some word that is part of the ${srcdir} directory name
3747 # or the ${configuration} value might, just might, happen to be an
3748 # identifier like `sun4' or `i386' or something, and be predefined by
3749 # the C preprocessor to some helpful value like 1, or maybe the empty
3750 # string.  Needless to say consequent macro substitutions are less
3751 # than conducive to the makefile finding the correct directory.
3752 # src/Makefile.in used to treat X11 as equivalent to HAVE_X11.
3753 # But nothing in Emacs defines X11, and everywhere else uses HAVE_X11,
3754 # so that cannot have been doing anything.
3755 [cpp_undefs="`echo $srcdir $configuration $canonical unix mktime register X11 |
3756   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3757   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
3758
3759 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3760 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3761 ## from Makefile.c can correctly provide the arg `-traditional' to the
3762 ## C preprocessor.
3763
3764 AC_EGREP_CPP(yes..yes,
3765         [yes..yes],
3766         CPP_NEED_TRADITIONAL=no,
3767         CPP_NEED_TRADITIONAL=yes)
3768
3769 AC_OUTPUT(Makefile lib-src/Makefile oldXMenu/Makefile \
3770         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3771         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3772         lwlib/Makefile lisp/Makefile leim/Makefile, [
3773
3774 ### Make the necessary directories, if they don't exist.
3775 for dir in etc lisp ; do
3776   test -d ${dir} || mkdir ${dir}
3777 done
3778
3779 # Build src/Makefile from ${srcdir}/src/Makefile.c
3780 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3781 # This must be done after src/config.h is built, since we rely on that file.
3782
3783 echo creating src/epaths.h
3784 ${MAKE-make} epaths-force
3785
3786 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3787 # `..' to `. .'  unless invoked with -traditional
3788
3789 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3790   CPPFLAGS="$CPPFLAGS -traditional"
3791 fi
3792
3793 echo creating src/Makefile
3794 ( cd src
3795   rm -f junk.c junk1.c junk2.c
3796   sed -e '/start of cpp stuff/q' \
3797       < Makefile.c > junk1.c
3798   sed -e '1,/start of cpp stuff/d'\
3799       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3800       < Makefile.c > junk.c
3801   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3802       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3803   cat junk1.c junk2.c > Makefile.new
3804   rm -f junk.c junk1.c junk2.c
3805   chmod 444 Makefile.new
3806   mv -f Makefile.new Makefile
3807 )
3808
3809 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3810   echo creating src/.gdbinit
3811   echo source $srcdir/src/.gdbinit > src/.gdbinit
3812 fi
3813
3814 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3815
3816 m4_if(dnl       Do not change this comment
3817    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3818 )dnl