lisp/find-file.el

   1 ;;; find-file.el --- find a file corresponding to this one given a pattern
   2
   3 ;; Author: Henry Guillaume <henri@tibco.com, henry@c032.aone.net.au>
   4 ;; Maintainer: FSF
   5 ;; Keywords: c, matching, tools
   6
   7 ;; Copyright (C) 1994-1995, 2001-2013 Free Software Foundation, Inc.
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; PURPOSE:
  27 ;; This package features a function called ff-find-other-file, which performs
  28 ;; the following function:
  29 ;;
  30 ;;     When in a .c file, find the first corresponding .h file in a set
  31 ;;     of directories and display it, and vice-versa from the .h file.
  32 ;;
  33 ;; Many people maintain their include file in a directory separate to their
  34 ;; src directory, and very often you may be editing a file and have a need to
  35 ;; visit the "other file". This package searches through a set of directories
  36 ;; to find that file.
  37 ;;
  38 ;; THE "OTHER FILE", or "corresponding file", generally has the same basename,
  39 ;; and just has a different extension as described by the ff-other-file-alist
  40 ;; variable:
  41 ;;
  42 ;;   '(("\\.cc$"  (".hh" ".h"))
  43 ;;     ("\\.hh$"  (".cc" ".C" ".CC" ".cxx" ".cpp")))
  44 ;;
  45 ;; If the current file has a .cc extension, ff-find-other-file will attempt
  46 ;; to look for a .hh file, and then a .h file in some directory as described
  47 ;; below. The mechanism here is to replace the matched part of the original
  48 ;; filename with each of the corresponding extensions in turn.
  49 ;;
  50 ;; Alternatively, there are situations where the filename of the other file
  51 ;; cannot be determined easily with regexps. For example, a .c file may
  52 ;; have two corresponding .h files, for its public and private parts, or
  53 ;; the filename for the .c file contains part of the pathname of the .h
  54 ;; file, as between src/fooZap.cc and include/FOO/zap.hh. In that case, the
  55 ;; format above can be changed to include a function to be called when the
  56 ;; current file matches the regexp:
  57 ;;
  58 ;;   '(("\\.cc$"  cc--function)
  59 ;;     ("\\.hh$"  hh-function))
  60 ;;
  61 ;; These functions must return a list consisting of the possible names of the
  62 ;; corresponding file, with or without path. There is no real need for more
  63 ;; than one function, and one could imagine the following value for cc-other-
  64 ;; file-alist:
  65 ;;
  66 ;;    (setq cc-other-file-alist
  67 ;;        '(("\\.cc$"  ff-cc-hh-converter)
  68 ;;          ("\\.hh$"  ff-cc-hh-converter)
  69 ;;          ("\\.c$"   (".h"))
  70 ;;          ("\\.h$"   (".c" ".cc" ".C" ".CC" ".cxx" ".cpp"))))
  71 ;;
  72 ;; ff-cc-hh-converter is included at the end of this file as a reference.
  73 ;;
  74 ;; SEARCHING is carried out in a set of directories specified by the
  75 ;; ff-search-directories variable:
  76 ;;
  77 ;;     ("." "../../src" "../include/*" "/usr/local/*/src/*" "$PROJECT/src")
  78 ;;
  79 ;; This means that the corresponding file will be searched for first in
  80 ;; the current directory, then in ../../src, then in one of the directories
  81 ;; under ../include, and so on. The star is _not_ a general wildcard
  82 ;; character: it just indicates that the subdirectories of this directory
  83 ;; must each be searched in turn. Environment variables will be expanded in
  84 ;; the ff-search-directories variable.
  85 ;;
  86 ;; If the point is on a #include line, the file to be #included is searched
  87 ;; for in the same manner. This can be disabled with the ff-ignore-include
  88 ;; variable, or by calling ff-get-other-file instead of ff-find-other-file.
  89 ;;
  90 ;; If the file was not found, ff-find-other-file will prompt you for where
  91 ;; to create the new "corresponding file" (defaults to the current directory),
  92 ;; unless the variable ff-always-try-to-create is set to nil.
  93 ;;
  94 ;; GIVEN AN ARGUMENT (with the ^U prefix), ff-find-other-file will get the
  95 ;; other file in another (the other?) window (see find-file-other-window and
  96 ;; switch-to-buffer-other-window). This can be set on a more permanent basis
  97 ;; by setting ff-always-in-other-window to t in which case the ^U prefix will
  98 ;; do the opposite of what was described above.
  99 ;;
 100 ;; THERE ARE FIVE AVAILABLE HOOKS, called in this order if non-nil:
 101 ;;
 102 ;; - ff-pre-find-hook     - called before the search for the other file starts
 103 ;; - ff-not-found-hook    - called when the other file could not be found
 104 ;; - ff-pre-load-hook     - called just before the other file is 'loaded'
 105 ;; - ff-file-created-hook - called when the other file is created
 106 ;; - ff-post-load-hook    - called just after the other file is 'loaded'
 107 ;;
 108 ;; The *load-hook allow you to place point where you want it in the other
 109 ;; file.
 110
 111 ;; CREDITS:
 112 ;; Many thanks go to TUSC Computer Systems Pty Ltd for providing an environ-
 113 ;; ment that made the development of this package possible.
 114 ;;
 115 ;; Many thanks also go to all those who provided valuable feedback throughout
 116 ;; the development of this package:
 117 ;;     Rolf Ebert in particular, Fritz Knabe, Heddy Boubaker, Sebastian Kremer,
 118 ;;     Vasco Lopes Paulo, Mark A. Plaksin, Robert Lang, Trevor West, Kevin
 119 ;;     Pereira, Benedict Lofstedt & Justin Vallon.
 120
 121 ;;; Code:
 122 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 123 ;; User definable variables:
 124
 125 (defgroup ff nil
 126   "Find a file corresponding to this one given a pattern."
 127   :prefix "ff-"
 128   :link '(emacs-commentary-link "find-file")
 129   :group 'find-file)
 130
 131 (defcustom ff-pre-find-hook nil
 132   "List of functions to be called before the search for the file starts."
 133   :type 'hook
 134   :group 'ff)
 135
 136 (defcustom ff-pre-load-hook nil
 137   "List of functions to be called before the other file is loaded."
 138   :type 'hook
 139   :group 'ff)
 140
 141 (defcustom ff-post-load-hook nil
 142   "List of functions to be called after the other file is loaded."
 143   :type 'hook
 144   :group 'ff)
 145
 146 (defcustom ff-not-found-hook nil
 147   "List of functions to be called if the other file could not be found."
 148   :type 'hook
 149   :group 'ff)
 150
 151 (defcustom ff-file-created-hook nil
 152   "List of functions to be called if the other file needs to be created."
 153   :type 'hook
 154   :group 'ff)
 155
 156 (defcustom ff-case-fold-search nil
 157   "Non-nil means ignore cases in matches (see `case-fold-search').
 158 If you have extensions in different cases, you will want this to be nil."
 159   :type 'boolean
 160   :group 'ff)
 161
 162 (defcustom ff-always-in-other-window nil
 163   "If non-nil, find the corresponding file in another window by default.
 164 To override this, give an argument to `ff-find-other-file'."
 165   :type 'boolean
 166   :group 'ff)
 167
 168 (defcustom ff-ignore-include nil
 169   "If non-nil, ignore `#include' lines."
 170   :type 'boolean
 171   :group 'ff)
 172
 173 (defcustom ff-always-try-to-create t
 174   "If non-nil, always attempt to create the other file if it was not found."
 175   :type 'boolean
 176   :group 'ff)
 177
 178 (defcustom ff-quiet-mode nil
 179   "If non-nil, trace which directories are being searched."
 180   :type 'boolean
 181   :group 'ff)
 182
 183 ;;;###autoload
 184 (defcustom ff-special-constructs
 185   ;; C/C++ include, for NeXTstep too
 186   `((,(purecopy "^\#\\s *\\(include\\|import\\)\\s +[<\"]\\(.*\\)[>\"]") .
 187      (lambda ()
 188        (buffer-substring (match-beginning 2) (match-end 2)))))
 189   ;; We include `ff-treat-as-special' documentation here so that autoload
 190   ;; can make it available to be read prior to loading this file.
 191   "List of special constructs recognized by `ff-treat-as-special'.
 192 Each element, tried in order, has the form (REGEXP . EXTRACT).
 193 If REGEXP matches the current line (from the beginning of the line),
 194 `ff-treat-as-special' calls function EXTRACT with no args.
 195 If EXTRACT returns nil, keep trying.  Otherwise, return the
 196 filename that EXTRACT returned."
 197   :type '(repeat (cons regexp function))
 198   :group 'ff)
 199
 200 (defvaralias 'ff-related-file-alist 'ff-other-file-alist)
 201 (defcustom ff-other-file-alist 'cc-other-file-alist
 202   "Alist of extensions to find given the current file's extension.
 203
 204 This list should contain the most used extensions before the others,
 205 since the search algorithm searches sequentially through each
 206 directory specified in `ff-search-directories'.  If a file is not found,
 207 a new one is created with the first matching extension (`.cc' yields `.hh').
 208 This alist should be set by the major mode."
 209   :type '(choice (repeat (list regexp (choice (repeat string) function)))
 210                  symbol)
 211   :group 'ff)
 212
 213 (defcustom ff-search-directories 'cc-search-directories
 214   "List of directories to search for a specific file.
 215
 216 Set by default to `cc-search-directories', expanded at run-time.
 217
 218 This list is searched through with each extension specified in
 219 `ff-other-file-alist' that matches this file's extension.  So the
 220 longer the list, the longer it'll take to realize that a file
 221 may not exist.
 222
 223 A typical format is
 224
 225     '(\".\" \"/usr/include\" \"$PROJECT/*/include\")
 226
 227 Environment variables can be inserted between slashes (`/').
 228 They will be replaced by their definition.  If a variable does
 229 not exist, it is replaced (silently) with an empty string.
 230
 231 The stars are *not* wildcards: they are searched for together with
 232 the preceding slash.  The star represents all the subdirectories except
 233 `..', and each of these subdirectories will be searched in turn."
 234   :type '(choice (repeat directory) symbol)
 235   :group 'ff)
 236
 237 (defcustom cc-search-directories
 238   '("." "/usr/include" "/usr/local/include/*")
 239   "See the description of the `ff-search-directories' variable."
 240   :type '(repeat directory)
 241   :group 'ff)
 242
 243 (defcustom cc-other-file-alist
 244   '(("\\.cc\\'"  (".hh" ".h"))
 245     ("\\.hh\\'"  (".cc" ".C"))
 246
 247     ("\\.c\\'"   (".h"))
 248     ("\\.m\\'"   (".h"))
 249     ("\\.h\\'"   (".c" ".cc" ".C" ".CC" ".cxx" ".cpp" ".m"))
 250
 251     ("\\.C\\'"   (".H"  ".hh" ".h"))
 252     ("\\.H\\'"   (".C"  ".CC"))
 253
 254     ("\\.CC\\'"  (".HH" ".H"  ".hh" ".h"))
 255     ("\\.HH\\'"  (".CC"))
 256
 257     ("\\.c\\+\\+\\'" (".h++" ".hh" ".h"))
 258     ("\\.h\\+\\+\\'" (".c++"))
 259
 260     ("\\.cpp\\'" (".hpp" ".hh" ".h"))
 261     ("\\.hpp\\'" (".cpp"))
 262
 263     ("\\.cxx\\'" (".hxx" ".hh" ".h"))
 264     ("\\.hxx\\'" (".cxx")))
 265   "Alist of extensions to find given the current file's extension.
 266
 267 This list should contain the most used extensions before the others,
 268 since the search algorithm searches sequentially through each directory
 269 specified in `ff-search-directories'.  If a file is not found, a new one
 270 is created with the first matching extension (`.cc' yields `.hh')."
 271   :version "24.4"                       ; add .m
 272   :type '(repeat (list regexp (choice (repeat string) function)))
 273   :group 'ff)
 274
 275 (defcustom modula2-other-file-alist
 276   '(
 277     ("\\.mi$" (".md")) ;; Modula-2 module definition
 278     ("\\.md$" (".mi")) ;; and implementation.
 279     )
 280   "See the description for the `ff-search-directories' variable."
 281   :type '(repeat (list regexp (choice (repeat string) function)))
 282   :group 'ff)
 283
 284
 285 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 286 ;; No user definable variables beyond this point!
 287 ;; ==============================================
 288
 289 (make-variable-buffer-local 'ff-pre-find-hook)
 290 (make-variable-buffer-local 'ff-pre-load-hook)
 291 (make-variable-buffer-local 'ff-post-load-hook)
 292 (make-variable-buffer-local 'ff-not-found-hook)
 293 (make-variable-buffer-local 'ff-file-created-hook)
 294 (make-variable-buffer-local 'ff-case-fold-search)
 295 (make-variable-buffer-local 'ff-always-in-other-window)
 296 (make-variable-buffer-local 'ff-ignore-include)
 297 (make-variable-buffer-local 'ff-quiet-mode)
 298 (make-variable-buffer-local 'ff-other-file-alist)
 299 (make-variable-buffer-local 'ff-search-directories)
 300
 301 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 302 ;; User entry points
 303
 304 ;;;###autoload
 305 (defun ff-get-other-file (&optional in-other-window)
 306   "Find the header or source file corresponding to this file.
 307 See also the documentation for `ff-find-other-file'.
 308
 309 If optional IN-OTHER-WINDOW is non-nil, find the file in another window."
 310   (interactive "P")
 311   (let ((ignore ff-ignore-include))
 312     (setq ff-ignore-include t)
 313     (ff-find-the-other-file in-other-window)
 314     (setq ff-ignore-include ignore)))
 315
 316 ;;;###autoload
 317 (defalias 'ff-find-related-file 'ff-find-other-file)
 318
 319 ;;;###autoload
 320 (defun ff-find-other-file (&optional in-other-window ignore-include)
 321   "Find the header or source file corresponding to this file.
 322 Being on a `#include' line pulls in that file.
 323
 324 If optional IN-OTHER-WINDOW is non-nil, find the file in the other window.
 325 If optional IGNORE-INCLUDE is non-nil, ignore being on `#include' lines.
 326
 327 Variables of interest include:
 328
 329  - `ff-case-fold-search'
 330    Non-nil means ignore cases in matches (see `case-fold-search').
 331    If you have extensions in different cases, you will want this to be nil.
 332
 333  - `ff-always-in-other-window'
 334    If non-nil, always open the other file in another window, unless an
 335    argument is given to `ff-find-other-file'.
 336
 337  - `ff-ignore-include'
 338    If non-nil, ignores #include lines.
 339
 340  - `ff-always-try-to-create'
 341    If non-nil, always attempt to create the other file if it was not found.
 342
 343  - `ff-quiet-mode'
 344    If non-nil, traces which directories are being searched.
 345
 346  - `ff-special-constructs'
 347    A list of regular expressions specifying how to recognize special
 348    constructs such as include files etc, and an associated method for
 349    extracting the filename from that construct.
 350
 351  - `ff-other-file-alist'
 352    Alist of extensions to find given the current file's extension.
 353
 354  - `ff-search-directories'
 355    List of directories searched through with each extension specified in
 356    `ff-other-file-alist' that matches this file's extension.
 357
 358  - `ff-pre-find-hook'
 359    List of functions to be called before the search for the file starts.
 360
 361  - `ff-pre-load-hook'
 362    List of functions to be called before the other file is loaded.
 363
 364  - `ff-post-load-hook'
 365    List of functions to be called after the other file is loaded.
 366
 367  - `ff-not-found-hook'
 368    List of functions to be called if the other file could not be found.
 369
 370  - `ff-file-created-hook'
 371    List of functions to be called if the other file has been created."
 372   (interactive "P")
 373   (let ((ignore ff-ignore-include))
 374     (setq ff-ignore-include ignore-include)
 375     (ff-find-the-other-file in-other-window)
 376     (setq ff-ignore-include ignore)))
 377
 378 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 379 ;; Support functions
 380
 381 (defun ff-find-the-other-file (&optional in-other-window)
 382   "Find the header or source file corresponding to the current file.
 383 Being on a `#include' line pulls in that file, but see the help on
 384 the `ff-ignore-include' variable.
 385
 386 If optional IN-OTHER-WINDOW is non-nil, find the file in another window."
 387
 388   (let (match           ;; matching regexp for this file
 389         suffixes        ;; set of replacing regexps for the matching regexp
 390         action          ;; function to generate the names of the other files
 391         fname           ;; basename of this file
 392         pos             ;; where we start matching filenames
 393         stub            ;; name of the file without extension
 394         alist           ;; working copy of the list of file extensions
 395         pathname        ;; the pathname of the file or the #include line
 396         default-name    ;; file we should create if none found
 397         format          ;; what we have to match
 398         found           ;; name of the file or buffer found - nil if none
 399         dirs            ;; local value of ff-search-directories
 400         no-match)       ;; whether we know about this kind of file
 401
 402     (run-hooks 'ff-pre-find-hook 'ff-pre-find-hooks)
 403
 404     (message "Working...")
 405
 406     (setq dirs
 407           (if (symbolp ff-search-directories)
 408               (ff-list-replace-env-vars (symbol-value ff-search-directories))
 409             (ff-list-replace-env-vars ff-search-directories)))
 410
 411     (setq fname (ff-treat-as-special))
 412
 413     (cond
 414      ((and (not ff-ignore-include) fname)
 415       (setq default-name fname)
 416       (setq found (ff-get-file dirs fname nil in-other-window)))
 417
 418      ;; let's just get the corresponding file
 419      (t
 420       (setq alist (if (symbolp ff-other-file-alist)
 421                       (symbol-value ff-other-file-alist)
 422                     ff-other-file-alist)
 423             pathname (if (buffer-file-name)
 424                          (buffer-file-name)
 425                        "/none.none"))
 426
 427       (setq fname (file-name-nondirectory pathname)
 428             no-match nil
 429             match (car alist))
 430
 431       ;; find the table entry corresponding to this file
 432       (setq pos (ff-string-match (car match) fname))
 433       (while (and match (if (and pos (>= pos 0)) nil (not pos)))
 434         (setq alist (cdr alist))
 435         (setq match (car alist))
 436         (setq pos (ff-string-match (car match) fname)))
 437
 438       ;; no point going on if we haven't found anything
 439       (if (not match)
 440           (setq no-match t)
 441
 442         ;; otherwise, suffixes contains what we need
 443         (setq suffixes (car (cdr match))
 444               action (car (cdr match))
 445               found nil)
 446
 447         ;; if we have a function to generate new names,
 448         ;; invoke it with the name of the current file
 449         (if (and (atom action) (fboundp action))
 450             (progn
 451               (setq suffixes (funcall action (buffer-file-name))
 452                     match (cons (car match) (list suffixes))
 453                     stub nil
 454                     default-name (car suffixes)))
 455
 456           ;; otherwise build our filename stub
 457           (cond
 458
 459            ;; get around the problem that 0 and nil both mean false!
 460            ((= pos 0)
 461             (setq format "")
 462             (setq stub "")
 463             )
 464
 465            (t
 466             (setq format (concat "\\(.+\\)" (car match)))
 467             (string-match format fname)
 468             (setq stub (substring fname (match-beginning 1) (match-end 1)))
 469             ))
 470
 471           ;; if we find nothing, we should try to get a file like this one
 472           (setq default-name
 473                 (concat stub (car (car (cdr match))))))
 474
 475         ;; do the real work - find the file
 476         (setq found
 477               (ff-get-file dirs
 478                            stub
 479                            suffixes
 480                            in-other-window)))))
 481
 482     (cond
 483      (no-match                     ;; could not even determine the other file
 484       (message ""))
 485
 486      (t
 487       (cond
 488
 489        ((not found)                ;; could not find the other file
 490
 491         (run-hooks 'ff-not-found-hook 'ff-not-found-hooks)
 492
 493         (cond
 494          (ff-always-try-to-create  ;; try to create the file
 495           (let (name pathname)
 496
 497             (setq name
 498                   (expand-file-name
 499                    (read-directory-name
 500                     (format "Find or create %s in: " default-name)
 501                     default-directory default-name nil)))
 502
 503             (setq pathname
 504                   (if (file-directory-p name)
 505                       (concat (file-name-as-directory name) default-name)
 506                     (setq found name)))
 507
 508             (ff-find-file pathname in-other-window t)))
 509
 510          (t                        ;; don't create the file, just whinge
 511           (message "No file found for %s" fname))))
 512
 513        (t                          ;; matching file found
 514         nil))))
 515
 516     found))                        ;; return buffer-name or filename
 517
 518 (defun ff-other-file-name ()
 519   "Return name of the header or source file corresponding to the current file.
 520 Being on a `#include' line pulls in that file, but see the help on
 521 the `ff-ignore-include' variable."
 522
 523   (let (match           ;; matching regexp for this file
 524         suffixes        ;; set of replacing regexps for the matching regexp
 525         action          ;; function to generate the names of the other files
 526         fname           ;; basename of this file
 527         pos             ;; where we start matching filenames
 528         stub            ;; name of the file without extension
 529         alist           ;; working copy of the list of file extensions
 530         pathname        ;; the pathname of the file or the #include line
 531         default-name    ;; file we should create if none found
 532         format          ;; what we have to match
 533         found           ;; name of the file or buffer found - nil if none
 534         dirs            ;; local value of ff-search-directories
 535         no-match)       ;; whether we know about this kind of file
 536
 537     (message "Working...")
 538
 539     (setq dirs
 540           (if (symbolp ff-search-directories)
 541               (ff-list-replace-env-vars (symbol-value ff-search-directories))
 542             (ff-list-replace-env-vars ff-search-directories)))
 543
 544     (setq fname (ff-treat-as-special))
 545
 546     (cond
 547      ((and (not ff-ignore-include) fname)
 548       (setq default-name fname)
 549       (setq found (ff-get-file-name dirs fname nil)))
 550
 551      ;; let's just get the corresponding file
 552      (t
 553       (setq alist (if (symbolp ff-other-file-alist)
 554                       (symbol-value ff-other-file-alist)
 555                     ff-other-file-alist)
 556             pathname (if (buffer-file-name)
 557                          (buffer-file-name)
 558                        "/none.none"))
 559
 560       (setq fname (file-name-nondirectory pathname)
 561             no-match nil
 562             match (car alist))
 563
 564       ;; find the table entry corresponding to this file
 565       (setq pos (ff-string-match (car match) fname))
 566       (while (and match (if (and pos (>= pos 0)) nil (not pos)))
 567         (setq alist (cdr alist))
 568         (setq match (car alist))
 569         (setq pos (ff-string-match (car match) fname)))
 570
 571       ;; no point going on if we haven't found anything
 572       (if (not match)
 573           (setq no-match t)
 574
 575         ;; otherwise, suffixes contains what we need
 576         (setq suffixes (car (cdr match))
 577               action (car (cdr match))
 578               found nil)
 579
 580         ;; if we have a function to generate new names,
 581         ;; invoke it with the name of the current file
 582         (if (and (atom action) (fboundp action))
 583             (progn
 584               (setq suffixes (funcall action (buffer-file-name))
 585                     match (cons (car match) (list suffixes))
 586                     stub nil
 587                     default-name (car suffixes)))
 588
 589           ;; otherwise build our filename stub
 590           (cond
 591
 592            ;; get around the problem that 0 and nil both mean false!
 593            ((= pos 0)
 594             (setq format "")
 595             (setq stub "")
 596             )
 597
 598            (t
 599             (setq format (concat "\\(.+\\)" (car match)))
 600             (string-match format fname)
 601             (setq stub (substring fname (match-beginning 1) (match-end 1)))
 602             ))
 603
 604           ;; if we find nothing, we should try to get a file like this one
 605           (setq default-name
 606                 (concat stub (car (car (cdr match))))))
 607
 608         ;; do the real work - find the file
 609         (setq found
 610               (ff-get-file-name dirs stub suffixes)))))
 611     found))                        ;; return buffer-name or filename
 612
 613 (defun ff-get-file (search-dirs filename &optional suffix-list other-window)
 614   "Find a file in the SEARCH-DIRS with the given FILENAME (or filename stub).
 615 If (optional) SUFFIX-LIST is nil, search for FILENAME, otherwise search
 616 for FILENAME with each of the given suffixes.  Get the file or the buffer
 617 corresponding to the name of the first file found, or nil."
 618   (let ((filename (ff-get-file-name search-dirs filename suffix-list)))
 619
 620     (cond
 621      ((not filename)
 622       nil)
 623
 624      ((bufferp (get-file-buffer filename))
 625       (ff-switch-to-buffer (get-file-buffer filename) other-window)
 626       filename)
 627
 628      ((file-exists-p filename)
 629       (ff-find-file filename other-window nil)
 630       filename)
 631
 632      (t
 633       nil))))
 634
 635 (defun ff-get-file-name (search-dirs fname-stub &optional suffix-list)
 636   "Find a file in SEARCH-DIRS with the given name (or stub) FNAME-STUB.
 637 If (optional) SUFFIX-LIST is nil, search for FNAME-STUB, otherwise
 638 search for FNAME-STUB with each of the given suffixes.  Return the
 639 name of the first file found."
 640   (let (dirs         ;; working copy of dirs to search
 641         dir          ;; the current dir considered
 642         file         ;; filename being looked for
 643         rest         ;; pathname after first /*
 644         this-suffix  ;; the suffix we are currently considering
 645         suffixes     ;; working copy of suffix-list
 646         filename     ;; built filename
 647         blist        ;; list of live buffers
 648         buf          ;; current buffer in blist
 649         found)       ;; whether we have found anything
 650
 651     (setq suffixes suffix-list)
 652
 653     ;; suffixes is nil => fname-stub is the file we are looking for
 654     ;; otherwise fname-stub is a stub, and we append a suffix
 655     (if suffixes
 656         (setq this-suffix (car suffixes))
 657       (setq this-suffix "")
 658       (setq suffixes (list "")))
 659
 660     ;; find whether the file is in a buffer first
 661     (while (and suffixes (not found))
 662       (setq filename (concat fname-stub this-suffix))
 663
 664       (if (not ff-quiet-mode)
 665           (message "Finding buffer %s..." filename))
 666
 667       (if (bufferp (get-file-buffer filename))
 668           (setq found (buffer-file-name (get-file-buffer filename))))
 669
 670       (setq blist (buffer-list))
 671       (setq buf (buffer-name (car blist)))
 672       (while (and blist (not found))
 673
 674         (if (string-match (concat filename "<[0-9]+>") buf)
 675             (setq found (buffer-file-name (car blist))))
 676
 677         (setq blist (cdr blist))
 678         (setq buf (buffer-name (car blist))))
 679
 680       (setq suffixes (cdr suffixes))
 681       (setq this-suffix (car suffixes)))
 682
 683     ;; now look for the real file
 684     (setq dirs search-dirs)
 685     (setq dir  (car dirs))
 686     (while (and (not found) dirs)
 687
 688       (setq suffixes suffix-list)
 689
 690       ;; if dir does not contain '/*', look for the file
 691       (if (and dir (not (string-match "\\([^*]*\\)/\\\*\\(/.*\\)*" dir)))
 692           (progn
 693
 694             ;; suffixes is nil => fname-stub is the file we are looking for
 695             ;; otherwise fname-stub is a stub, and we append a suffix
 696             (if suffixes
 697                 (setq this-suffix (car suffixes))
 698               (setq this-suffix "")
 699               (setq suffixes (list "")))
 700
 701             (while (and suffixes (not found))
 702
 703               (setq filename (concat fname-stub this-suffix))
 704               (setq file (concat dir "/" filename))
 705
 706               (if (not ff-quiet-mode)
 707                   (message "Finding %s..." file))
 708
 709               (if (file-exists-p file)
 710                   (setq found file))
 711
 712               (setq suffixes (cdr suffixes))
 713               (setq this-suffix (car suffixes))))
 714
 715         ;; otherwise dir matches the '/*', so search each dir separately
 716         (progn
 717           (if (match-beginning 2)
 718               (setq rest (substring dir (match-beginning 2) (match-end 2)))
 719             (setq rest "")
 720             )
 721           (setq dir  (substring dir (match-beginning 1) (match-end 1)))
 722
 723           (let ((dirlist (ff-all-dirs-under dir '("..")))
 724                 this-dir compl-dirs)
 725
 726             (setq this-dir (car dirlist))
 727             (while dirlist
 728               (setq compl-dirs
 729                     (append
 730                      compl-dirs
 731                      (list (concat this-dir rest))
 732                      ))
 733               (setq dirlist  (cdr dirlist))
 734               (setq this-dir (car dirlist)))
 735
 736             (if compl-dirs
 737                 (setq found (ff-get-file-name compl-dirs
 738                                               fname-stub
 739                                               suffix-list))))))
 740       (setq dirs (cdr dirs))
 741       (setq dir (car dirs)))
 742
 743     (if found
 744         (message "%s found" found))
 745
 746     found))
 747
 748 (defun ff-string-match (regexp string &optional start)
 749   "Like `string-match', but set `case-fold-search' temporarily.
 750 The value used comes from `ff-case-fold-search'."
 751   (let ((case-fold-search ff-case-fold-search))
 752     (if regexp
 753         (string-match regexp string start))))
 754
 755 (defun ff-list-replace-env-vars (search-list)
 756   "Replace environment variables (of the form $VARIABLE) in SEARCH-LIST."
 757   (let (list
 758         (var (car search-list)))
 759     (while search-list
 760       (if (string-match "\\(.*\\)\\$[({]*\\([a-zA-Z0-9_]+\\)[)}]*\\(.*\\)" var)
 761           (setq var
 762                 (concat
 763                  (substring var (match-beginning 1) (match-end 1))
 764                  (getenv (substring var (match-beginning 2) (match-end 2)))
 765                  (substring var (match-beginning 3) (match-end 3)))))
 766       (setq search-list (cdr search-list))
 767       (setq list (cons var list))
 768       (setq var (car search-list)))
 769     (setq search-list (reverse list))))
 770
 771 (defun ff-treat-as-special ()
 772   "Return the file to look for if the construct was special, else nil.
 773 See variable `ff-special-constructs'."
 774   (save-excursion
 775     (beginning-of-line 1)
 776     (let* (fname
 777            (list ff-special-constructs)
 778            (elem (car list))
 779            (regexp (car elem))
 780            (match (cdr elem)))
 781       (while (and list (not fname))
 782         (if (and (looking-at regexp) match)
 783             (setq fname (funcall match)))
 784         (setq list (cdr list))
 785         (setq elem (car list))
 786         (setq regexp (car elem))
 787         (setq match (cdr elem)))
 788       fname)))
 789
 790 (defun ff-basename (string)
 791   "Return the basename of pathname STRING."
 792   (setq string (concat "/" string))
 793   (string-match ".*/\\([^/]+\\)$" string)
 794   (setq string (substring string (match-beginning 1) (match-end 1))))
 795
 796 (defun ff-all-dirs-under (here &optional exclude)
 797   "Get all the directory files under directory HERE.
 798 Exclude all files in the optional EXCLUDE list."
 799   (if (file-directory-p here)
 800       (condition-case nil
 801           (progn
 802             (let ((files (directory-files here t))
 803                   (dirlist (list))
 804                   file)
 805               (while files
 806                 (setq file (car files))
 807                 (if (and
 808                      (file-directory-p file)
 809                      (not (member (ff-basename file) exclude)))
 810                     (setq dirlist (cons file dirlist)))
 811                 (setq files (cdr files)))
 812               (setq dirlist (reverse dirlist))))
 813         (error nil))
 814     nil))
 815
 816 (defun ff-switch-file (f1 f2 file &optional in-other-window new-file)
 817   "Call F1 or F2 on FILE, according to IN-OTHER-WINDOW.
 818 In addition, this runs various hooks.
 819
 820 Either F1 or F2 receives FILE as the sole argument.
 821 The decision of which one to call is based on IN-OTHER-WINDOW
 822 and on the global variable `ff-always-in-other-window'.
 823
 824 F1 and F2 are typically `find-file' / `find-file-other-window'
 825 or `switch-to-buffer' / `switch-to-buffer-other-window' function pairs.
 826
 827 If optional NEW-FILE is t, then a special hook (`ff-file-created-hook') is
 828 called before `ff-post-load-hook'."
 829   (run-hooks 'ff-pre-load-hook 'ff-pre-load-hooks)
 830   (if (or
 831        (and in-other-window (not ff-always-in-other-window))
 832        (and (not in-other-window) ff-always-in-other-window))
 833       (funcall f2 file)
 834     (funcall f1 file))
 835   (if new-file
 836       (run-hooks 'ff-file-created-hook 'ff-file-created-hooks))
 837   (run-hooks 'ff-post-load-hook 'ff-post-load-hooks))
 838
 839 (defun ff-find-file (file &optional in-other-window new-file)
 840   "Like `find-file', but may show the file in another window."
 841   (ff-switch-file 'find-file
 842                   'find-file-other-window
 843                   file in-other-window new-file))
 844
 845 (defun ff-switch-to-buffer (buffer-or-name &optional in-other-window)
 846   "Like `switch-to-buffer', but may show the buffer in another window."
 847
 848   (ff-switch-file 'switch-to-buffer
 849                   'switch-to-buffer-other-window
 850                   buffer-or-name in-other-window nil))
 851
 852 ;;;###autoload
 853 (defun ff-mouse-find-other-file (event)
 854   "Visit the file you click on."
 855   (interactive "e")
 856   (save-excursion
 857     (mouse-set-point event)
 858     (ff-find-other-file nil)))
 859
 860 ;;;###autoload
 861 (defun ff-mouse-find-other-file-other-window (event)
 862   "Visit the file you click on in another window."
 863   (interactive "e")
 864   (save-excursion
 865     (mouse-set-point event)
 866     (ff-find-other-file t)))
 867
 868 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 869 ;; This section offers an example of user defined function to select files
 870
 871 (defun ff-upcase-p (string &optional start end)
 872   "Return t if STRING is all uppercase.
 873 Given START and/or END, checks between these characters."
 874   (let (match str)
 875     (if (not start)
 876         (setq start 0))
 877     (if (not end)
 878         (setq end (length string)))
 879     (if (= start end)
 880         (setq end (1+ end)))
 881     (setq str (substring string start end))
 882     (if (and
 883          (ff-string-match "[A-Z]+" str)
 884          (setq match (match-data))
 885          (= (car match) 0)
 886          (= (car (cdr match)) (length str)))
 887         t
 888       nil)))
 889
 890 (defun ff-cc-hh-converter (arg)
 891   "Discriminate file extensions.
 892 Build up a new file list based possibly on part of the directory name
 893 and the name of the file passed in."
 894   (ff-string-match "\\(.*\\)/\\([^/]+\\)/\\([^.]+\\).\\([^/]+\\)$" arg)
 895   (let ((path (if (match-beginning 1)
 896                   (substring arg (match-beginning 1) (match-end 1)) nil))
 897         (dire (if (match-beginning 2)
 898                   (substring arg (match-beginning 2) (match-end 2)) nil))
 899         (file (if (match-beginning 3)
 900                   (substring arg (match-beginning 3) (match-end 3)) nil))
 901         (extn (if (match-beginning 4)
 902                   (substring arg (match-beginning 4) (match-end 4)) nil))
 903         return-list)
 904     (cond
 905      ;; fooZapJunk.cc => ZapJunk.{hh,h} or fooZapJunk.{hh,h}
 906      ((and (string= extn "cc")
 907            (ff-string-match "^\\([a-z]+\\)\\([A-Z].+\\)$" file))
 908       (let ((stub  (substring file (match-beginning 2) (match-end 2))))
 909         (setq dire (upcase (substring file (match-beginning 1) (match-end 1))))
 910         (setq return-list (list (concat stub ".hh")
 911                                 (concat stub ".h")
 912                                 (concat file ".hh")
 913                                 (concat file ".h")))
 914         ))
 915      ;; FOO/ZapJunk.hh => fooZapJunk.{cc,C} or ZapJunk.{cc,C}
 916      ((and (string= extn "hh") (ff-upcase-p dire) file)
 917       (let ((stub (concat (downcase dire) file)))
 918         (setq return-list (list (concat stub ".cc")
 919                                 (concat stub ".C")
 920                                 (concat file ".cc")
 921                                 (concat file ".C")))
 922         ))
 923      ;; zap.cc => zap.hh or zap.h
 924      ((string= extn "cc")
 925       (let ((stub file))
 926         (setq return-list (list (concat stub ".hh")
 927                                 (concat stub ".h")))
 928         ))
 929      ;; zap.hh => zap.cc or zap.C
 930      ((string= extn "hh")
 931       (let ((stub file))
 932         (setq return-list (list (concat stub ".cc")
 933                                 (concat stub ".C")))
 934         ))
 935      (t
 936       nil))
 937
 938     return-list))
 939
 940 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 941 ;; This section offers an example of user defined function to place point.
 942 ;; The regexps are Ada specific.
 943
 944 (defvar ff-function-name nil "Name of the function we are in.")
 945
 946 ;; bind with (setq ff-pre-load-hook 'ff-which-function-are-we-in)
 947 ;;
 948 (defvar ada-procedure-start-regexp)
 949 (defvar ada-package-start-regexp)
 950
 951 (defun ff-which-function-are-we-in ()
 952   "Return the name of the function whose definition/declaration point is in.
 953 Also remember that name in `ff-function-name'."
 954   (setq ff-function-name
 955         (save-excursion
 956           (if (or (re-search-backward ada-procedure-start-regexp nil t)
 957                   (re-search-backward ada-package-start-regexp nil t))
 958               (match-string 0)))))
 959
 960 ;; bind with (setq ff-post-load-hook 'ff-set-point-accordingly)
 961 ;;
 962 (defun ff-set-point-accordingly ()
 963   "Find the function specified in `ff-function-name'.
 964 That name was previously determined by `ff-which-function-are-we-in'."
 965   (if ff-function-name
 966       (progn
 967         (goto-char (point-min))
 968         (search-forward ff-function-name nil t))))
 969
 970 (provide 'find-file)
 971
 972 ;;; find-file.el ends here