lisp/vc-git.el

   1 ;;; vc-git.el --- VC backend for the git version control system
   2
   3 ;; Copyright (C) 2006, 2007 Free Software Foundation, Inc.
   4
   5 ;; Author: Alexandre Julliard <julliard@winehq.org>
   6 ;; Keywords: tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 3, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This file contains a VC backend for the git version control
  28 ;; system.
  29 ;;
  30
  31 ;;; Installation:
  32
  33 ;; To install: put this file on the load-path and add Git to the list
  34 ;; of supported backends in `vc-handled-backends'; the following line,
  35 ;; placed in your ~/.emacs, will accomplish this:
  36 ;;
  37 ;;     (add-to-list 'vc-handled-backends 'Git)
  38
  39 ;;; Todo:
  40 ;;  - check if more functions could use vc-git-command instead
  41 ;;     of start-process.
  42 ;;  - changelog generation
  43
  44 ;; Implement the rest of the vc interface. See the comment at the
  45 ;; beginning of vc.el. The current status is:
  46 ;; ("??" means: "figure out what to do about it")
  47 ;;
  48 ;; FUNCTION NAME                                   STATUS
  49 ;; BACKEND PROPERTIES
  50 ;; * revision-granularity                          OK
  51 ;; STATE-QUERYING FUNCTIONS
  52 ;; * registered (file)                             OK
  53 ;; * state (file)                                  OK
  54 ;; - state-heuristic (file)                        NOT NEEDED
  55 ;; - dir-state (dir)                               OK
  56 ;; * working-revision (file)                       OK
  57 ;; - latest-on-branch-p (file)                     NOT NEEDED
  58 ;; * checkout-model (file)                         OK
  59 ;; - workfile-unchanged-p (file)                   OK
  60 ;; - mode-line-string (file)                       OK
  61 ;; - dired-state-info (file)                       OK
  62 ;; STATE-CHANGING FUNCTIONS
  63 ;; * create-repo ()                                OK
  64 ;; * register (files &optional rev comment)        OK
  65 ;; - init-revision (file)                          NOT NEEDED
  66 ;; - responsible-p (file)                          OK
  67 ;; - could-register (file)                         NOT NEEDED, DEFAULT IS GOOD
  68 ;; - receive-file (file rev)                       NOT NEEDED
  69 ;; - unregister (file)                             OK
  70 ;; * checkin (files rev comment)                   OK
  71 ;; * find-revision (file rev buffer)               OK
  72 ;; * checkout (file &optional editable rev)        OK
  73 ;; * revert (file &optional contents-done)         OK
  74 ;; - rollback (files)                              COULD BE SUPPORTED
  75 ;; - merge (file rev1 rev2)                        It would be possible to merge changes into
  76 ;;                                                 a single file, but when committing they
  77 ;;                                                 wouldn't be identified as a merge by git,
  78 ;;                                                 so it's probably not a good idea.
  79 ;; - merge-news (file)                             see `merge'
  80 ;; - steal-lock (file &optional revision)          NOT NEEDED
  81 ;; HISTORY FUNCTIONS
  82 ;; * print-log (files &optional buffer)            OK
  83 ;; - log-view-mode ()                              OK
  84 ;; - show-log-entry (revision)                     OK
  85 ;; - wash-log (file)                               COULD BE SUPPORTED
  86 ;; - logentry-check ()                             NOT NEEDED
  87 ;; - comment-history (file)                        ??
  88 ;; - update-changelog (files)                      COULD BE SUPPORTED
  89 ;; * diff (file &optional rev1 rev2 buffer)        OK
  90 ;; - revision-completion-table (files)             NEEDED?
  91 ;; - annotate-command (file buf &optional rev)     OK
  92 ;; - annotate-time ()                              OK
  93 ;; - annotate-current-time ()                      NOT NEEDED
  94 ;; - annotate-extract-revision-at-line ()          OK
  95 ;; SNAPSHOT SYSTEM
  96 ;; - create-snapshot (dir name branchp)            OK
  97 ;; - assign-name (file name)                       NOT NEEDED
  98 ;; - retrieve-snapshot (dir name update)           OK, needs to update buffers
  99 ;; MISCELLANEOUS
 100 ;; - make-version-backups-p (file)                 NOT NEEDED
 101 ;; - repository-hostname (dirname)                 NOT NEEDED
 102 ;; - previous-revision (file rev)                  OK
 103 ;; - next-revision (file rev)                      OK
 104 ;; - check-headers ()                              COULD BE SUPPORTED
 105 ;; - clear-headers ()                              NOT NEEDED
 106 ;; - delete-file (file)                            OK
 107 ;; - rename-file (old new)                         OK
 108 ;; - find-file-hook ()                             NOT NEEDED
 109 ;; - find-file-not-found-hook ()                   NOT NEEDED
 110
 111 (eval-when-compile (require 'cl) (require 'vc))
 112
 113 (defvar git-commits-coding-system 'utf-8
 114   "Default coding system for git commits.")
 115
 116 ;;; BACKEND PROPERTIES
 117
 118 (defun vc-git-revision-granularity ()
 119   'repository)
 120
 121 ;;; STATE-QUERYING FUNCTIONS
 122
 123 ;;;###autoload (defun vc-git-registered (file)
 124 ;;;###autoload   "Return non-nil if FILE is registered with git."
 125 ;;;###autoload   (if (vc-find-root file ".git")       ; short cut
 126 ;;;###autoload       (progn
 127 ;;;###autoload         (load "vc-git")
 128 ;;;###autoload         (vc-git-registered file))))
 129
 130 (defun vc-git-registered (file)
 131   "Check whether FILE is registered with git."
 132   (when (vc-git-root file)
 133     (with-temp-buffer
 134       (let* ((dir (file-name-directory file))
 135              (name (file-relative-name file dir)))
 136         (and (ignore-errors
 137                (when dir (cd dir))
 138                (vc-git--out-ok "ls-files" "-c" "-z" "--" name))
 139              (let ((str (buffer-string)))
 140                (and (> (length str) (length name))
 141                     (string= (substring str 0 (1+ (length name)))
 142                              (concat name "\0")))))))))
 143
 144 (defun vc-git-state (file)
 145   "Git-specific version of `vc-state'."
 146   (vc-git--call nil "add" "--refresh" "--" (file-relative-name file))
 147   (let ((diff (vc-git--run-command-string file "diff-index" "-z" "HEAD" "--")))
 148     (if (and diff (string-match ":[0-7]\\{6\\} [0-7]\\{6\\} [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} [ADMU]\0[^\0]+\0"
 149                                 diff))
 150         'edited
 151       'up-to-date)))
 152
 153 (defun vc-git-dir-state (dir)
 154   (with-temp-buffer
 155     (vc-git-command (current-buffer) nil nil "ls-files" "-t" "-c" "-m" "-o")
 156     (goto-char (point-min))
 157     (let ((status-char nil)
 158           (file nil))
 159       (while (not (eobp))
 160         (setq status-char (char-after))
 161         (setq file
 162               (expand-file-name
 163                (buffer-substring-no-properties (+ (point) 2)
 164                                                (line-end-position))))
 165         (cond
 166          ;; The rest of the possible states in "git ls-files -t" output:
 167          ;;      R              removed/deleted
 168          ;;      K              to be killed
 169          ;; should not show up in vc-dired, so don't deal with them
 170          ;; here.
 171          ((eq status-char ?H)
 172           (vc-file-setprop file 'vc-state 'up-to-date))
 173          ((eq status-char ?M)
 174           (vc-file-setprop file 'vc-state 'edited))
 175          ((eq status-char ?C)
 176           (vc-file-setprop file 'vc-state 'edited))
 177          ((eq status-char ??)
 178           (vc-file-setprop file 'vc-backend 'none)
 179           (vc-file-setprop file 'vc-state 'nil)))
 180         (forward-line)))))
 181
 182 (defun vc-git-working-revision (file)
 183   "Git-specific version of `vc-working-revision'."
 184   (let ((str (with-output-to-string
 185                (with-current-buffer standard-output
 186                  (vc-git--out-ok "symbolic-ref" "HEAD")))))
 187     (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 188         (match-string 2 str)
 189       str)))
 190
 191 (defun vc-git-checkout-model (file)
 192   'implicit)
 193
 194 (defun vc-git-workfile-unchanged-p (file)
 195   (eq 'up-to-date (vc-git-state file)))
 196
 197 (defun vc-git-mode-line-string (file)
 198   "Return string for placement into the modeline for FILE."
 199   (let* ((branch (vc-git-working-revision file))
 200          (def-ml (vc-default-mode-line-string 'Git file))
 201          (help-echo (get-text-property 0 'help-echo def-ml)))
 202     (if (zerop (length branch))
 203         (propertize
 204          (concat def-ml "!")
 205          'help-echo (concat help-echo "\nNo current branch (detached HEAD)"))
 206       (propertize def-ml
 207                   'help-echo (concat help-echo "\nCurrent branch: " branch)))))
 208
 209 (defun vc-git-dired-state-info (file)
 210   "Git-specific version of `vc-dired-state-info'."
 211   (let ((git-state (vc-state file)))
 212     (if (eq git-state 'edited)
 213         "(modified)"
 214       ;; fall back to the default VC representation
 215       (vc-default-dired-state-info 'Git file))))
 216
 217 ;;; STATE-CHANGING FUNCTIONS
 218
 219 (defun vc-git-create-repo ()
 220   "Create a new Git repository."
 221   (vc-git-command nil 0 nil "init"))
 222
 223 (defun vc-git-register (files &optional rev comment)
 224   "Register FILE into the git version-control system."
 225   (vc-git-command nil 0 files "update-index" "--add" "--"))
 226
 227 (defalias 'vc-git-responsible-p 'vc-git-root)
 228
 229 (defun vc-git-unregister (file)
 230   (vc-git-command nil 0 file "rm" "-f" "--cached" "--"))
 231
 232
 233 (defun vc-git-checkin (files rev comment)
 234   (let ((coding-system-for-write git-commits-coding-system))
 235     (vc-git-command nil 0 files "commit" "-m" comment "--only" "--")))
 236
 237 (defun vc-git-find-revision (file rev buffer)
 238   (let ((coding-system-for-read 'binary)
 239         (coding-system-for-write 'binary)
 240         (fullname (substring
 241                    (vc-git--run-command-string
 242                     file "ls-files" "-z" "--full-name" "--")
 243                    0 -1)))
 244     (vc-git-command
 245      buffer 0
 246      (concat (if rev rev "HEAD") ":" fullname) "cat-file" "blob")))
 247
 248 (defun vc-git-checkout (file &optional editable rev)
 249   (vc-git-command nil 0 file "checkout" (or rev "HEAD")))
 250
 251 (defun vc-git-revert (file &optional contents-done)
 252   "Revert FILE to the version stored in the git repository."
 253   (if contents-done
 254       (vc-git-command nil 0 file "update-index" "--")
 255     (vc-git-command nil 0 file "checkout" "HEAD")))
 256
 257 ;;; HISTORY FUNCTIONS
 258
 259 (defun vc-git-print-log (files &optional buffer)
 260   "Get change log associated with FILES."
 261   (let ((coding-system-for-read git-commits-coding-system)
 262         ;; Support both the old print-log interface that passes a
 263         ;; single file, and the new one that passes a file list.
 264         (flist (if (listp files) files (list files))))
 265     ;; `vc-do-command' creates the buffer, but we need it before running
 266     ;; the command.
 267     (vc-setup-buffer buffer)
 268     ;; If the buffer exists from a previous invocation it might be
 269     ;; read-only.
 270     (let ((inhibit-read-only t))
 271       ;; XXX `log-view-mode' needs to have something to identify where
 272       ;; the log for each individual file starts. It seems that by
 273       ;; default git does not output this info. So loop here and call
 274       ;; "git rev-list" on each file separately to make sure that each
 275       ;; file gets a "File:" header before the corresponding
 276       ;; log. Maybe there is a way to do this with one command...
 277       (dolist (file flist)
 278         (with-current-buffer
 279             buffer
 280           (insert "File: " (file-name-nondirectory file) "\n"))
 281         (vc-git-command buffer 'async (file-relative-name file)
 282                         "rev-list" "--pretty" "HEAD" "--")))))
 283
 284 (defvar log-view-message-re)
 285 (defvar log-view-file-re)
 286 (defvar log-view-font-lock-keywords)
 287
 288 (define-derived-mode vc-git-log-view-mode log-view-mode "Git-Log-View"
 289   (require 'add-log) ;; we need the faces add-log
 290   ;; Don't have file markers, so use impossible regexp.
 291   (set (make-local-variable 'log-view-file-re) "^File:[ \t]+\\(.+\\)")
 292   (set (make-local-variable 'log-view-message-re)
 293        "^commit *\\([0-9a-z]+\\)")
 294   (set (make-local-variable 'log-view-font-lock-keywords)
 295        (append
 296         `((,log-view-message-re  (1 'change-log-acknowledgement))
 297           (,log-view-file-re (1 'change-log-file-face)))
 298         ;; Handle the case:
 299         ;; user: foo@bar
 300         '(("^Author:[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 301            (1 'change-log-email))
 302           ;; Handle the case:
 303           ;; user: FirstName LastName <foo@bar>
 304           ("^Author:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 305            (1 'change-log-name)
 306            (2 'change-log-email))
 307           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 308            (1 'change-log-name))
 309           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 310            (1 'change-log-name)
 311            (2 'change-log-email))
 312           ("^Merge: \\([0-9a-z]+\\) \\([0-9a-z]+\\)"
 313            (1 'change-log-acknowledgement)
 314            (2 'change-log-acknowledgement))
 315           ("^Date:   \\(.+\\)" (1 'change-log-date))
 316           ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message))))))
 317
 318 (defun vc-git-show-log-entry (revision)
 319   "Move to the log entry for REVISION.
 320 REVISION may have the form BRANCH, BRANCH~N,
 321 or BRANCH^ (where \"^\" can be repeated)."
 322   (goto-char (point-min))
 323   (search-forward "\ncommit" nil t
 324                   (cond ((string-match "~\\([0-9]\\)$" revision)
 325                          (1+ (string-to-number (match-string 1 revision))))
 326                         ((string-match "\\^+$" revision)
 327                          (1+ (length (match-string 0 revision))))
 328                         (t nil)))
 329   (beginning-of-line))
 330
 331 (defun vc-git-diff (files &optional rev1 rev2 buffer)
 332   (let ((buf (or buffer "*vc-diff*")))
 333     (if (and rev1 rev2)
 334         (vc-git-command buf 1 files "diff-tree" "--exit-code" "-p"
 335                         rev1 rev2 "--")
 336       (vc-git-command buf 1 files "diff-index" "--exit-code" "-p"
 337                       (or rev1 "HEAD") "--"))))
 338
 339 (defun vc-git-revision-table (files)
 340   ;; What about `files'?!?  --Stef
 341   (let ((table (list "HEAD")))
 342     (with-temp-buffer
 343       (vc-git-command t nil nil "for-each-ref" "--format=%(refname)")
 344       (goto-char (point-min))
 345       (while (re-search-forward "^refs/\\(heads\\|tags\\)/\\(.*\\)$" nil t)
 346         (push (match-string 2) table)))
 347     table))
 348
 349 (defun vc-git-revision-completion-table (files)
 350   (lexical-let ((files files)
 351                 table)
 352     (setq table (lazy-completion-table
 353                  table (lambda () (vc-git-revision-table files))))
 354     table))
 355
 356 (defun vc-git-annotate-command (file buf &optional rev)
 357   ;; FIXME: rev is ignored
 358   (let ((name (file-relative-name file)))
 359     (vc-git-command buf 0 name "blame" (if rev (concat "-r" rev)))))
 360
 361 (defun vc-git-annotate-time ()
 362   (and (re-search-forward "[0-9a-f]+[^()]+(.* \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\) \\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\) \\([-+0-9]+\\) +[0-9]+) " nil t)
 363        (vc-annotate-convert-time
 364         (apply #'encode-time (mapcar (lambda (match)
 365                                        (string-to-number (match-string match)))
 366                                      '(6 5 4 3 2 1 7))))))
 367
 368 (defun vc-git-annotate-extract-revision-at-line ()
 369   (save-excursion
 370     (move-beginning-of-line 1)
 371     (and (looking-at "[0-9a-f]+")
 372          (buffer-substring-no-properties (match-beginning 0) (match-end 0)))))
 373
 374 ;;; SNAPSHOT SYSTEM
 375
 376 (defun vc-git-create-snapshot (dir name branchp)
 377   (let ((default-directory dir))
 378     (and (vc-git-command nil 0 nil "update-index" "--refresh")
 379          (if branchp
 380              (vc-git-command nil 0 nil "checkout" "-b" name)
 381            (vc-git-command nil 0 nil "tag" name)))))
 382
 383 (defun vc-git-retrieve-snapshot (dir name update)
 384   (let ((default-directory dir))
 385     (vc-git-command nil 0 nil "checkout" name)
 386     ;; FIXME: update buffers if `update' is true
 387     ))
 388
 389
 390 ;;; MISCELLANEOUS
 391
 392 (defun vc-git-previous-revision (file rev)
 393   "Git-specific version of `vc-previous-revision'."
 394   (let ((default-directory (file-name-directory (expand-file-name file)))
 395         (file (file-name-nondirectory file)))
 396     (vc-git-symbolic-commit
 397      (with-temp-buffer
 398        (and
 399         (vc-git--out-ok "rev-list" "-2" rev "--" file)
 400         (goto-char (point-max))
 401         (bolp)
 402         (zerop (forward-line -1))
 403         (not (bobp))
 404         (buffer-substring-no-properties
 405          (point)
 406          (1- (point-max))))))))
 407
 408 (defun vc-git-next-revision (file rev)
 409   "Git-specific version of `vc-next-revision'."
 410   (let* ((default-directory (file-name-directory
 411                              (expand-file-name file)))
 412          (file (file-name-nondirectory file))
 413          (current-rev
 414           (with-temp-buffer
 415             (and
 416              (vc-git--out-ok "rev-list" "-1" rev "--" file)
 417              (goto-char (point-max))
 418              (bolp)
 419              (zerop (forward-line -1))
 420              (bobp)
 421              (buffer-substring-no-properties
 422               (point)
 423               (1- (point-max)))))))
 424     (and current-rev
 425          (vc-git-symbolic-commit
 426           (with-temp-buffer
 427             (and
 428              (vc-git--out-ok "rev-list" "HEAD" "--" file)
 429              (goto-char (point-min))
 430              (search-forward current-rev nil t)
 431              (zerop (forward-line -1))
 432              (buffer-substring-no-properties
 433               (point)
 434               (progn (forward-line 1) (1- (point))))))))))
 435
 436 (defun vc-git-delete-file (file)
 437   (vc-git-command nil 0 file "rm" "-f" "--"))
 438
 439 (defun vc-git-rename-file (old new)
 440   (vc-git-command nil 0 (list old new) "mv" "-f" "--"))
 441
 442 \f
 443 ;;; Internal commands
 444
 445 (defun vc-git-root (file)
 446   (vc-find-root file ".git"))
 447
 448 (defun vc-git-command (buffer okstatus file-or-list &rest flags)
 449   "A wrapper around `vc-do-command' for use in vc-git.el.
 450 The difference to vc-do-command is that this function always invokes `git'."
 451   (apply 'vc-do-command buffer okstatus "git" file-or-list flags))
 452
 453 (defun vc-git--call (buffer command &rest args)
 454   (apply 'call-process "git" nil buffer nil command args))
 455
 456 (defun vc-git--out-ok (command &rest args)
 457   (zerop (apply 'vc-git--call '(t nil) command args)))
 458
 459 (defun vc-git--run-command-string (file &rest args)
 460   "Run a git command on FILE and return its output as string."
 461   (let* ((ok t)
 462          (str (with-output-to-string
 463                 (with-current-buffer standard-output
 464                   (unless (apply 'vc-git--out-ok
 465                                  (append args (list (file-relative-name
 466                                                      file))))
 467                     (setq ok nil))))))
 468     (and ok str)))
 469
 470 (defun vc-git-symbolic-commit (commit)
 471   "Translate COMMIT string into symbolic form.
 472 Returns nil if not possible."
 473   (and commit
 474        (with-temp-buffer
 475          (and
 476           (vc-git--out-ok "name-rev" "--name-only" "--tags" commit)
 477           (goto-char (point-min))
 478           (= (forward-line 2) 1)
 479           (bolp)
 480           (buffer-substring-no-properties (point-min) (1- (point-max)))))))
 481
 482 (provide 'vc-git)
 483
 484 ;; arch-tag: bd10664a-0e5b-48f5-a877-6c17b135be12
 485 ;;; vc-git.el ends here