lisp/doc-view.el

   1 ;;; doc-view.el --- View PDF/PostScript/DVI files in Emacs
   2
   3 ;; Copyright (C) 2007, 2008, 2009 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Tassilo Horn <tassilo@member.fsf.org>
   6 ;; Maintainer: Tassilo Horn <tassilo@member.fsf.org>
   7 ;; Keywords: files, pdf, ps, dvi
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Requirements:
  25
  26 ;; doc-view.el requires GNU Emacs 22.1 or newer.  You also need Ghostscript,
  27 ;; `dvipdf' (comes with Ghostscript) or `dvipdfm' (comes with teTeX or TeXLive)
  28 ;; and `pdftotext', which comes with xpdf (http://www.foolabs.com/xpdf/) or
  29 ;; poppler (http://poppler.freedesktop.org/).
  30
  31 ;;; Commentary:
  32
  33 ;; DocView is a document viewer for Emacs.  It converts PDF, PS and DVI files
  34 ;; to a set of PNG files, one PNG for each page, and displays the PNG images
  35 ;; inside an Emacs buffer.  This buffer uses `doc-view-mode' which provides
  36 ;; convenient key bindings for browsing the document.
  37 ;;
  38 ;; To use it simply open a document file with
  39 ;;
  40 ;;     C-x C-f ~/path/to/document RET
  41 ;;
  42 ;; and the document will be converted and displayed, if your emacs supports png
  43 ;; images.  With `C-c C-c' you can toggle between the rendered images
  44 ;; representation and the source text representation of the document.
  45 ;;
  46 ;; Since conversion may take some time all the PNG images are cached in a
  47 ;; subdirectory of `doc-view-cache-directory' and reused when you want to view
  48 ;; that file again.  To reconvert a document hit `g' (`doc-view-reconvert-doc')
  49 ;; when displaying the document.  To delete all cached files use
  50 ;; `doc-view-clear-cache'.  To open the cache with dired, so that you can tidy
  51 ;; it out use `doc-view-dired-cache'.
  52 ;;
  53 ;; When conversion in underway the first page will be displayed as soon as it
  54 ;; is available and the available pages are refreshed every
  55 ;; `doc-view-conversion-refresh-interval' seconds.  If that variable is nil the
  56 ;; pages won't be displayed before conversion of the document finished
  57 ;; completely.
  58 ;;
  59 ;; DocView lets you select a slice of the displayed pages.  This slice will be
  60 ;; remembered and applied to all pages of the current document.  This enables
  61 ;; you to cut away the margins of a document to save some space.  To select a
  62 ;; slice you can use `doc-view-set-slice' (bound to `s s') which will query you
  63 ;; for the coordinates of the slice's top-left corner and its width and height.
  64 ;; A much more convenient way to do the same is offered by the command
  65 ;; `doc-view-set-slice-using-mouse' (bound to `s m').  After invocation you
  66 ;; only have to press mouse-1 at the top-left corner and drag it to the
  67 ;; bottom-right corner of the desired slice.  To reset the slice use
  68 ;; `doc-view-reset-slice' (bound to `s r').
  69 ;;
  70 ;; You can also search within the document.  The command `doc-view-search'
  71 ;; (bound to `C-s') queries for a search regexp and initializes a list of all
  72 ;; matching pages and messages how many match-pages were found.  After that you
  73 ;; can jump to the next page containing a match with an additional `C-s'.  With
  74 ;; `C-r' you can do the same, but backwards.  To search for a new regexp give a
  75 ;; prefix arg to one of the search functions, e.g. by typing `C-u C-s'.  The
  76 ;; searching works by using a plain text representation of the document.  If
  77 ;; that doesn't already exist the first invocation of `doc-view-search' (or
  78 ;; `doc-view-search-backward') starts the conversion.  When that finishes and
  79 ;; you're still viewing the document (i.e. you didn't switch to another buffer)
  80 ;; you're queried for the regexp then.
  81 ;;
  82 ;; Dired users can simply hit `v' on a document file.  If it's a PS, PDF or DVI
  83 ;; it will be opened using `doc-view-mode'.
  84 ;;
  85
  86 ;;; Configuration:
  87
  88 ;; If the images are too small or too big you should set the "-rXXX" option in
  89 ;; `doc-view-ghostscript-options' to another value.  (The bigger your screen,
  90 ;; the higher the value.)
  91 ;;
  92 ;; This and all other options can be set with the customization interface.
  93 ;; Simply do
  94 ;;
  95 ;;     M-x customize-group RET doc-view RET
  96 ;;
  97 ;; and modify them to your needs.
  98
  99 ;;; Todo:
 100
 101 ;; - add print command.
 102 ;; - share more code with image-mode.
 103 ;; - better menu.
 104 ;; - Bind slicing to a drag event.
 105 ;; - doc-view-fit-doc-to-window and doc-view-fit-window-to-doc?
 106 ;; - zoom the region around the cursor (like xdvi).
 107 ;; - get rid of the silly arrow in the fringe.
 108 ;; - improve anti-aliasing (pdf-utils gets it better).
 109
 110 ;;;; About isearch support
 111
 112 ;; I tried implementing isearch by setting
 113 ;; `isearch-search-fun-function' buffer-locally, but that didn't
 114 ;; work too good.  The function doing the real search was called
 115 ;; endlessly somehow.  But even if we'd get that working no real
 116 ;; isearch feeling comes up due to the missing match highlighting.
 117 ;; Currently I display all lines containing a match in a tooltip and
 118 ;; each C-s or C-r jumps directly to the next/previous page with a
 119 ;; match.  With isearch we could only display the current match.  So
 120 ;; we had to decide if another C-s jumps to the next page with a
 121 ;; match (thus only the first match in a page will be displayed in a
 122 ;; tooltip) or to the next match, which would do nothing visible
 123 ;; (except the tooltip) if the next match is on the same page.
 124
 125 ;; And it's much slower than the current search facility, because
 126 ;; isearch really searches for each step forward or backward wheras
 127 ;; the current approach searches once and then it knows to which
 128 ;; pages to jump.
 129
 130 ;; Anyway, if someone with better isearch knowledge wants to give it a try,
 131 ;; feel free to do it.  --Tassilo
 132
 133 ;;; Code:
 134
 135 (eval-when-compile (require 'cl))
 136 (require 'dired)
 137 (require 'image-mode)
 138 (require 'jka-compr)
 139
 140 ;;;; Customization Options
 141
 142 (defgroup doc-view nil
 143   "In-buffer viewer for PDF, PostScript and DVI files."
 144   :link '(function-link doc-view)
 145   :version "22.2"
 146   :group 'applications
 147   :group 'multimedia
 148   :prefix "doc-view-")
 149
 150 (defcustom doc-view-ghostscript-program (executable-find "gs")
 151   "Program to convert PS and PDF files to PNG."
 152   :type 'file
 153   :group 'doc-view)
 154
 155 (defcustom doc-view-ghostscript-options
 156   '("-dSAFER" ;; Avoid security problems when rendering files from untrusted
 157               ;; sources.
 158     "-dNOPAUSE" "-sDEVICE=png16m" "-dTextAlphaBits=4"
 159     "-dBATCH" "-dGraphicsAlphaBits=4" "-dQUIET")
 160   "A list of options to give to ghostscript."
 161   :type '(repeat string)
 162   :group 'doc-view)
 163
 164 (defcustom doc-view-resolution 100
 165   "Dots per inch resolution used to render the documents.
 166 Higher values result in larger images."
 167   :type 'number
 168   :group 'doc-view)
 169
 170 (defcustom doc-view-dvipdfm-program (executable-find "dvipdfm")
 171   "Program to convert DVI files to PDF.
 172
 173 DVI file will be converted to PDF before the resulting PDF is
 174 converted to PNG.
 175
 176 If this and `doc-view-dvipdf-program' are set,
 177 `doc-view-dvipdf-program' will be preferred."
 178   :type 'file
 179   :group 'doc-view)
 180
 181 (defcustom doc-view-dvipdf-program (executable-find "dvipdf")
 182   "Program to convert DVI files to PDF.
 183
 184 DVI file will be converted to PDF before the resulting PDF is
 185 converted to PNG.
 186
 187 If this and `doc-view-dvipdfm-program' are set,
 188 `doc-view-dvipdf-program' will be preferred."
 189   :type 'file
 190   :group 'doc-view)
 191
 192 (defcustom doc-view-ps2pdf-program (executable-find "ps2pdf")
 193   "Program to convert PS files to PDF.
 194
 195 PS files will be converted to PDF before searching is possible."
 196   :type 'file
 197   :group 'doc-view)
 198
 199 (defcustom doc-view-pdftotext-program (executable-find "pdftotext")
 200   "Program to convert PDF files to plain text.
 201
 202 Needed for searching."
 203   :type 'file
 204   :group 'doc-view)
 205
 206 (defcustom doc-view-cache-directory
 207   (expand-file-name (format "docview%d" (user-uid))
 208                     temporary-file-directory)
 209   "The base directory, where the PNG images will be saved."
 210   :type 'directory
 211   :group 'doc-view)
 212
 213 (defvar doc-view-conversion-buffer " *doc-view conversion output*"
 214   "The buffer where messages from the converter programs go to.")
 215
 216 (defcustom doc-view-conversion-refresh-interval 1
 217   "Interval in seconds between refreshes of the DocView buffer while converting.
 218 After such a refresh newly converted pages will be available for
 219 viewing.  If set to nil there won't be any refreshes and the
 220 pages won't be displayed before conversion of the whole document
 221 has finished."
 222   :type 'integer
 223   :group 'doc-view)
 224
 225 ;;;; Internal Variables
 226
 227 (defun doc-view-new-window-function (winprops)
 228   (let ((ol (image-mode-window-get 'overlay winprops)))
 229     (if ol
 230         (setq ol (copy-overlay ol))
 231       (assert (not (get-char-property (point-min) 'display)))
 232       (setq ol (make-overlay (point-min) (point-max) nil t))
 233       (overlay-put ol 'doc-view t))
 234     (overlay-put ol 'window (car winprops))
 235     (image-mode-window-put 'overlay ol winprops)))
 236
 237 (defvar doc-view-current-files nil
 238   "Only used internally.")
 239 (make-variable-buffer-local 'doc-view-current-files)
 240
 241 (defvar doc-view-current-converter-processes nil
 242   "Only used internally.")
 243 (make-variable-buffer-local 'doc-view-current-converter-processes)
 244
 245 (defvar doc-view-current-timer nil
 246   "Only used internally.")
 247 (make-variable-buffer-local 'doc-view-current-timer)
 248
 249 (defvar doc-view-current-cache-dir nil
 250   "Only used internally.")
 251 (make-variable-buffer-local 'doc-view-current-cache-dir)
 252
 253 (defvar doc-view-current-search-matches nil
 254   "Only used internally.")
 255 (make-variable-buffer-local 'doc-view-current-search-matches)
 256
 257 (defvar doc-view-pending-cache-flush nil
 258   "Only used internally.")
 259
 260 (defvar doc-view-previous-major-mode nil
 261   "Only used internally.")
 262
 263 (defvar doc-view-buffer-file-name nil
 264   "Only used internally.
 265 The file name used for conversion.  Normally it's the same as
 266 `buffer-file-name', but for remote files, compressed files and
 267 files inside an archive it is a temporary copy of
 268 the (uncompressed, extracted) file residing in
 269 `doc-view-cache-directory'.")
 270
 271 (defvar doc-view-doc-type nil
 272   "The type of document in the current buffer.
 273 Can be `dvi', `pdf', or `ps'.")
 274
 275 ;;;; DocView Keymaps
 276
 277 (defvar doc-view-mode-map
 278   (let ((map (make-sparse-keymap)))
 279     (set-keymap-parent map image-mode-map)
 280     ;; Navigation in the document
 281     (define-key map (kbd "n")         'doc-view-next-page)
 282     (define-key map (kbd "p")         'doc-view-previous-page)
 283     (define-key map (kbd "<next>")    'forward-page)
 284     (define-key map (kbd "<prior>")   'backward-page)
 285     (define-key map [remap forward-page]  'doc-view-next-page)
 286     (define-key map [remap backward-page] 'doc-view-previous-page)
 287     (define-key map (kbd "SPC")       'doc-view-scroll-up-or-next-page)
 288     (define-key map (kbd "DEL")       'doc-view-scroll-down-or-previous-page)
 289     (define-key map (kbd "M-<")       'doc-view-first-page)
 290     (define-key map (kbd "M->")       'doc-view-last-page)
 291     (define-key map [remap goto-line] 'doc-view-goto-page)
 292     (define-key map (kbd "RET")       'image-next-line)
 293     ;; Zoom in/out.
 294     (define-key map "+"               'doc-view-enlarge)
 295     (define-key map "-"               'doc-view-shrink)
 296     ;; Killing the buffer (and the process)
 297     (define-key map (kbd "k")         'doc-view-kill-proc-and-buffer)
 298     (define-key map (kbd "K")         'doc-view-kill-proc)
 299     ;; Slicing the image
 300     (define-key map (kbd "s s")       'doc-view-set-slice)
 301     (define-key map (kbd "s m")       'doc-view-set-slice-using-mouse)
 302     (define-key map (kbd "s r")       'doc-view-reset-slice)
 303     ;; Searching
 304     (define-key map (kbd "C-s")       'doc-view-search)
 305     (define-key map (kbd "<find>")    'doc-view-search)
 306     (define-key map (kbd "C-r")       'doc-view-search-backward)
 307     ;; Show the tooltip
 308     (define-key map (kbd "C-t")       'doc-view-show-tooltip)
 309     ;; Toggle between text and image display or editing
 310     (define-key map (kbd "C-c C-c")   'doc-view-toggle-display)
 311     ;; Open a new buffer with doc's text contents
 312     (define-key map (kbd "C-c C-t")   'doc-view-open-text)
 313     ;; Reconvert the current document
 314     (define-key map (kbd "g")         'revert-buffer)
 315     (define-key map (kbd "r")         'revert-buffer)
 316     map)
 317   "Keymap used by `doc-view-mode' when displaying a doc as a set of images.")
 318
 319 (easy-menu-define doc-view-menu doc-view-mode-map
 320   "Menu for Doc View mode."
 321   '("DocView"
 322     ["Set Slice"                doc-view-set-slice-using-mouse]
 323     ["Set Slice (manual)"       doc-view-set-slice]
 324     ["Reset Slice"              doc-view-reset-slice]
 325     "---"
 326     ["Search"                   doc-view-search]
 327     ["Search Backwards"         doc-view-search-backward]
 328     ["Toggle display"           doc-view-toggle-display]
 329     ))
 330
 331 (defvar doc-view-minor-mode-map
 332   (let ((map (make-sparse-keymap)))
 333     ;; Toggle between text and image display or editing
 334     (define-key map (kbd "C-c C-c") 'doc-view-toggle-display)
 335     map)
 336   "Keymap used by `doc-minor-view-mode'.")
 337
 338 ;;;; Navigation Commands
 339
 340 (defmacro doc-view-current-page (&optional win)
 341   `(image-mode-window-get 'page ,win))
 342 (defmacro doc-view-current-info () `(image-mode-window-get 'info))
 343 (defmacro doc-view-current-overlay () `(image-mode-window-get 'overlay))
 344 (defmacro doc-view-current-image () `(image-mode-window-get 'image))
 345 (defmacro doc-view-current-slice () `(image-mode-window-get 'slice))
 346
 347 (defun doc-view-goto-page (page)
 348   "View the page given by PAGE."
 349   (interactive "nPage: ")
 350   (let ((len (length doc-view-current-files))
 351         (hscroll (window-hscroll)))
 352     (if (< page 1)
 353         (setq page 1)
 354       (when (and (> page len)
 355                  ;; As long as the converter is running, we don't know
 356                  ;; how many pages will be available.
 357                  (null doc-view-current-converter-processes))
 358         (setq page len)))
 359     (setf (doc-view-current-page) page
 360           (doc-view-current-info)
 361           (concat
 362            (propertize
 363             (format "Page %d of %d." page len) 'face 'bold)
 364            ;; Tell user if converting isn't finished yet
 365            (if doc-view-current-converter-processes
 366                " (still converting...)\n"
 367              "\n")
 368            ;; Display context infos if this page matches the last search
 369            (when (and doc-view-current-search-matches
 370                       (assq page doc-view-current-search-matches))
 371              (concat (propertize "Search matches:\n" 'face 'bold)
 372                      (let ((contexts ""))
 373                        (dolist (m (cdr (assq page
 374                                              doc-view-current-search-matches)))
 375                          (setq contexts (concat contexts "  - \"" m "\"\n")))
 376                        contexts)))))
 377     ;; Update the buffer
 378     ;; We used to find the file name from doc-view-current-files but
 379     ;; that's not right if the pages are not generated sequentially
 380     ;; or if the page isn't in doc-view-current-files yet.
 381     (let ((file (expand-file-name (format "page-%d.png" page)
 382                                   (doc-view-current-cache-dir))))
 383       (doc-view-insert-image file :pointer 'arrow)
 384       (set-window-hscroll (selected-window) hscroll)
 385       (when (and (not (file-exists-p file))
 386                  doc-view-current-converter-processes)
 387         ;; The PNG file hasn't been generated yet.
 388         (doc-view-pdf->png-1 doc-view-buffer-file-name file page
 389                              (lexical-let ((page page)
 390                                            (win (selected-window)))
 391                                (lambda ()
 392                                  (and (eq (current-buffer) (window-buffer win))
 393                                       ;; If we changed page in the mean
 394                                       ;; time, don't mess things up.
 395                                       (eq (doc-view-current-page win) page)
 396                                       (with-selected-window win
 397                                         (doc-view-goto-page page))))))))
 398     (overlay-put (doc-view-current-overlay)
 399                  'help-echo (doc-view-current-info))))
 400
 401 (defun doc-view-next-page (&optional arg)
 402   "Browse ARG pages forward."
 403   (interactive "p")
 404   (doc-view-goto-page (+ (doc-view-current-page) (or arg 1))))
 405
 406 (defun doc-view-previous-page (&optional arg)
 407   "Browse ARG pages backward."
 408   (interactive "p")
 409   (doc-view-goto-page (- (doc-view-current-page) (or arg 1))))
 410
 411 (defun doc-view-first-page ()
 412   "View the first page."
 413   (interactive)
 414   (doc-view-goto-page 1))
 415
 416 (defun doc-view-last-page ()
 417   "View the last page."
 418   (interactive)
 419   (doc-view-goto-page (length doc-view-current-files)))
 420
 421 (defun doc-view-scroll-up-or-next-page ()
 422   "Scroll page up if possible, else goto next page."
 423   (interactive)
 424   (let ((hscroll (window-hscroll))
 425         (cur-page (doc-view-current-page)))
 426     (when (= (window-vscroll) (image-scroll-up nil))
 427       (doc-view-next-page)
 428       (when (/= cur-page (doc-view-current-page))
 429         (image-bob)
 430         (image-bol 1))
 431       (set-window-hscroll (selected-window) hscroll))))
 432
 433 (defun doc-view-scroll-down-or-previous-page ()
 434   "Scroll page down if possible, else goto previous page."
 435   (interactive)
 436   (let ((hscroll (window-hscroll))
 437         (cur-page (doc-view-current-page)))
 438     (when (= (window-vscroll) (image-scroll-down nil))
 439       (doc-view-previous-page)
 440       (when (/= cur-page (doc-view-current-page))
 441         (image-eob)
 442         (image-bol 1))
 443       (set-window-hscroll (selected-window) hscroll))))
 444
 445 ;;;; Utility Functions
 446
 447 (defun doc-view-kill-proc ()
 448   "Kill the current converter process(es)."
 449   (interactive)
 450   (while doc-view-current-converter-processes
 451     (ignore-errors ;; Maybe it's dead already?
 452       (kill-process (pop doc-view-current-converter-processes))))
 453   (when doc-view-current-timer
 454     (cancel-timer doc-view-current-timer)
 455     (setq doc-view-current-timer nil))
 456   (setq mode-line-process nil))
 457
 458 (defun doc-view-kill-proc-and-buffer ()
 459   "Kill the current converter process and buffer."
 460   (interactive)
 461   (doc-view-kill-proc)
 462   (when (eq major-mode 'doc-view-mode)
 463     (kill-buffer (current-buffer))))
 464
 465 (defun doc-view-make-safe-dir (dir)
 466   (condition-case nil
 467       (let ((umask (default-file-modes)))
 468         (unwind-protect
 469             (progn
 470               ;; Create temp files with strict access rights.  It's easy to
 471               ;; loosen them later, whereas it's impossible to close the
 472               ;; time-window of loose permissions otherwise.
 473               (set-default-file-modes #o0700)
 474               (make-directory dir))
 475           ;; Reset the umask.
 476           (set-default-file-modes umask)))
 477     (file-already-exists
 478      (if (file-symlink-p dir)
 479          (error "Danger: %s points to a symbolic link" dir))
 480      ;; In case it was created earlier with looser rights.
 481      ;; We could check the mode info returned by file-attributes, but it's
 482      ;; a pain to parse and it may not tell you what we want under
 483      ;; non-standard file-systems.  So let's just say what we want and let
 484      ;; the underlying C code and file-system figure it out.
 485      ;; This also ends up checking a bunch of useful conditions: it makes
 486      ;; sure we have write-access to the directory and that we own it, thus
 487      ;; closing a bunch of security holes.
 488      (set-file-modes dir #o0700))))
 489
 490 (defun doc-view-current-cache-dir ()
 491   "Return the directory where the png files of the current doc should be saved.
 492 It's a subdirectory of `doc-view-cache-directory'."
 493   (if doc-view-current-cache-dir
 494       doc-view-current-cache-dir
 495     ;; Try and make sure doc-view-cache-directory exists and is safe.
 496     (doc-view-make-safe-dir doc-view-cache-directory)
 497     ;; Now compute the subdirectory to use.
 498     (setq doc-view-current-cache-dir
 499           (file-name-as-directory
 500            (expand-file-name
 501             (concat (file-name-nondirectory buffer-file-name)
 502                     "-"
 503                     (let ((file doc-view-buffer-file-name))
 504                       (with-temp-buffer
 505                         (set-buffer-multibyte nil)
 506                         (insert-file-contents-literally file)
 507                         (md5 (current-buffer)))))
 508             doc-view-cache-directory)))))
 509
 510 (defun doc-view-remove-if (predicate list)
 511   "Return LIST with all items removed that satisfy PREDICATE."
 512   (let (new-list)
 513     (dolist (item list (nreverse new-list))
 514       (when (not (funcall predicate item))
 515         (setq new-list (cons item new-list))))))
 516
 517 ;;;###autoload
 518 (defun doc-view-mode-p (type)
 519   "Return non-nil if image type TYPE is available for `doc-view'.
 520 Image types are symbols like `dvi', `postscript' or `pdf'."
 521   (and (display-graphic-p)
 522        (image-type-available-p 'png)
 523        (cond
 524         ((eq type 'dvi)
 525          (and (doc-view-mode-p 'pdf)
 526               (or (and doc-view-dvipdf-program
 527                        (executable-find doc-view-dvipdf-program))
 528                   (and doc-view-dvipdfm-program
 529                        (executable-find doc-view-dvipdfm-program)))))
 530         ((or (eq type 'postscript) (eq type 'ps) (eq type 'eps)
 531              (eq type 'pdf))
 532          (and doc-view-ghostscript-program
 533               (executable-find doc-view-ghostscript-program)))
 534         (t ;; unknown image type
 535          nil))))
 536
 537 ;;;; Conversion Functions
 538
 539 (defvar doc-view-shrink-factor 1.125)
 540
 541 (defun doc-view-enlarge (factor)
 542   "Enlarge the document."
 543   (interactive (list doc-view-shrink-factor))
 544   (set (make-local-variable 'doc-view-resolution)
 545        (* factor doc-view-resolution))
 546   (doc-view-reconvert-doc))
 547
 548 (defun doc-view-shrink (factor)
 549   "Shrink the document."
 550   (interactive (list doc-view-shrink-factor))
 551   (doc-view-enlarge (/ 1.0 factor)))
 552
 553 (defun doc-view-reconvert-doc ()
 554   "Reconvert the current document.
 555 Should be invoked when the cached images aren't up-to-date."
 556   (interactive)
 557   (doc-view-kill-proc)
 558   ;; Clear the old cached files
 559   (when (file-exists-p (doc-view-current-cache-dir))
 560     (dired-delete-file (doc-view-current-cache-dir) 'always))
 561   (doc-view-initiate-display))
 562
 563 (defun doc-view-sentinel (proc event)
 564   "Generic sentinel for doc-view conversion processes."
 565   (if (not (string-match "finished" event))
 566       (message "DocView: process %s changed status to %s."
 567                (process-name proc)
 568                (if (string-match "\\(.+\\)\n?\\'" event)
 569                    (match-string 1 event)
 570                  event))
 571     (when (buffer-live-p (process-get proc 'buffer))
 572       (with-current-buffer (process-get proc 'buffer)
 573         (setq doc-view-current-converter-processes
 574               (delq proc doc-view-current-converter-processes))
 575         (setq mode-line-process
 576               (if doc-view-current-converter-processes
 577                   (format ":%s" (car doc-view-current-converter-processes))))
 578         (funcall (process-get proc 'callback))))))
 579
 580 (defun doc-view-start-process (name program args callback)
 581   ;; Make sure the process is started in an existing directory, (rather than
 582   ;; some file-name-handler-managed dir, for example).
 583   (let* ((default-directory (if (file-readable-p default-directory)
 584                                 default-directory
 585                               (expand-file-name "~/")))
 586          (proc (apply 'start-process name doc-view-conversion-buffer
 587                       program args)))
 588     (push proc doc-view-current-converter-processes)
 589     (setq mode-line-process (list (format ":%s" proc)))
 590     (set-process-sentinel proc 'doc-view-sentinel)
 591     (process-put proc 'buffer   (current-buffer))
 592     (process-put proc 'callback callback)))
 593
 594 (defun doc-view-dvi->pdf (dvi pdf callback)
 595   "Convert DVI to PDF asynchronously and call CALLBACK when finished."
 596   ;; Prefer dvipdf over dvipdfm, because the latter has problems if the DVI
 597   ;; references and includes other PS files.
 598   (if (and doc-view-dvipdf-program
 599            (executable-find doc-view-dvipdf-program))
 600       (doc-view-start-process "dvi->pdf" doc-view-dvipdf-program
 601                             (list dvi pdf)
 602                             callback)
 603     (doc-view-start-process "dvi->pdf" doc-view-dvipdfm-program
 604                             (list "-o" pdf dvi)
 605                             callback)))
 606
 607
 608 (defun doc-view-pdf/ps->png (pdf-ps png)
 609   "Convert PDF-PS to PNG asynchronously."
 610   (doc-view-start-process
 611    "pdf/ps->png" doc-view-ghostscript-program
 612    (append doc-view-ghostscript-options
 613            (list (format "-r%d" (round doc-view-resolution))
 614                  (concat "-sOutputFile=" png)
 615                  pdf-ps))
 616    (lambda ()
 617      (when doc-view-current-timer
 618        (cancel-timer doc-view-current-timer)
 619        (setq doc-view-current-timer nil))
 620      (doc-view-display (current-buffer) 'force)))
 621   ;; Update the displayed pages as soon as they're done generating.
 622   (when doc-view-conversion-refresh-interval
 623     (setq doc-view-current-timer
 624           (run-at-time "1 secs" doc-view-conversion-refresh-interval
 625                        'doc-view-display
 626                        (current-buffer)))))
 627
 628 (defun doc-view-pdf->png-1 (pdf png page callback)
 629   "Convert a PAGE of a PDF file to PNG asynchronously.
 630 Call CALLBACK with no arguments when done."
 631   (doc-view-start-process
 632    "pdf->png-1" doc-view-ghostscript-program
 633    (append doc-view-ghostscript-options
 634            (list (format "-r%d" (round doc-view-resolution))
 635                  ;; Sadly, `gs' only supports the page-range
 636                  ;; for PDF files.
 637                  (format "-dFirstPage=%d" page)
 638                  (format "-dLastPage=%d" page)
 639                  (concat "-sOutputFile=" png)
 640                  pdf))
 641    callback))
 642
 643 (declare-function clear-image-cache "image.c" (&optional filter))
 644
 645 (defun doc-view-pdf->png (pdf png pages)
 646   "Convert a PDF file to PNG asynchronously.
 647 Start by converting PAGES, and then the rest."
 648   (if (null pages)
 649       (doc-view-pdf/ps->png pdf png)
 650     ;; We could render several `pages' with a single process if they're
 651     ;; (almost) consecutive, but since in 99% of the cases, there'll be only
 652     ;; a single page anyway, and of the remaining 1%, few cases will have
 653     ;; consecutive pages, it's not worth the trouble.
 654     (lexical-let ((pdf pdf) (png png) (rest (cdr pages)))
 655       (doc-view-pdf->png-1
 656        pdf (format png (car pages)) (car pages)
 657        (lambda ()
 658          (if rest
 659              (doc-view-pdf->png pdf png rest)
 660            ;; Yippie, the important pages are done, update the display.
 661            (clear-image-cache)
 662            ;; Convert the rest of the pages.
 663            (doc-view-pdf/ps->png pdf png)))))))
 664
 665 (defun doc-view-pdf->txt (pdf txt callback)
 666   "Convert PDF to TXT asynchronously and call CALLBACK when finished."
 667   (or doc-view-pdftotext-program
 668       (error "You need the `pdftotext' program to convert a PDF to text"))
 669   (doc-view-start-process "pdf->txt" doc-view-pdftotext-program
 670                           (list "-raw" pdf txt)
 671                           callback))
 672
 673 (defun doc-view-doc->txt (txt callback)
 674   "Convert the current document to text and call CALLBACK when done."
 675   (make-directory (doc-view-current-cache-dir) t)
 676   (case doc-view-doc-type
 677     (pdf
 678      ;; Doc is a PDF, so convert it to TXT
 679      (doc-view-pdf->txt doc-view-buffer-file-name txt callback))
 680     (ps
 681      ;; Doc is a PS, so convert it to PDF (which will be converted to
 682      ;; TXT thereafter).
 683      (lexical-let ((pdf (expand-file-name "doc.pdf"
 684                                           (doc-view-current-cache-dir)))
 685                    (txt txt)
 686                    (callback callback))
 687        (doc-view-ps->pdf doc-view-buffer-file-name pdf
 688                          (lambda () (doc-view-pdf->txt pdf txt callback)))))
 689     (dvi
 690      ;; Doc is a DVI.  This means that a doc.pdf already exists in its
 691      ;; cache subdirectory.
 692      (doc-view-pdf->txt (expand-file-name "doc.pdf"
 693                                           (doc-view-current-cache-dir))
 694                         txt callback))
 695     (t (error "DocView doesn't know what to do"))))
 696
 697 (defun doc-view-ps->pdf (ps pdf callback)
 698   "Convert PS to PDF asynchronously and call CALLBACK when finished."
 699   (or doc-view-ps2pdf-program
 700       (error "You need the `ps2pdf' program to convert PS to PDF"))
 701   (doc-view-start-process "ps->pdf" doc-view-ps2pdf-program
 702                           (list
 703                            ;; Avoid security problems when rendering files from
 704                            ;; untrusted sources.
 705                            "-dSAFER"
 706                            ;; in-file and out-file
 707                            ps pdf)
 708                           callback))
 709
 710 (defun doc-view-active-pages ()
 711   (let ((pages ()))
 712     (dolist (win (get-buffer-window-list (current-buffer) nil 'visible))
 713       (let ((page (image-mode-window-get 'page win)))
 714         (unless (memq page pages) (push page pages))))
 715     pages))
 716
 717 (defun doc-view-convert-current-doc ()
 718   "Convert `doc-view-buffer-file-name' to a set of png files, one file per page.
 719 Those files are saved in the directory given by the function
 720 `doc-view-current-cache-dir'."
 721   ;; Let stale files still display while we recompute the new ones, so only
 722   ;; flush the cache when the conversion is over.  One of the reasons why it
 723   ;; is important to keep displaying the stale page is so that revert-buffer
 724   ;; preserves the horizontal/vertical scroll settings (which are otherwise
 725   ;; resets during the redisplay).
 726   (setq doc-view-pending-cache-flush t)
 727   (let ((png-file (expand-file-name "page-%d.png"
 728                                     (doc-view-current-cache-dir)))
 729         (res-file (expand-file-name "resolution.el"
 730                                     (doc-view-current-cache-dir))))
 731     (make-directory (doc-view-current-cache-dir) t)
 732     ;; Save the used resolution so that it can be restored when
 733     ;; reading the cached files.
 734     (let ((res doc-view-resolution))
 735       (with-temp-buffer
 736         (princ res (current-buffer))
 737         ;; Don't use write-file, so as to avoid prompts for `require-newline',
 738         ;; or for pre-existing buffers with the same name, ...
 739         (write-region nil nil res-file nil 'silently)))
 740     (case doc-view-doc-type
 741       (dvi
 742        ;; DVI files have to be converted to PDF before Ghostscript can process
 743        ;; it.
 744        (lexical-let
 745            ((pdf (expand-file-name "doc.pdf" doc-view-current-cache-dir))
 746             (png-file png-file))
 747          (doc-view-dvi->pdf doc-view-buffer-file-name pdf
 748                             (lambda () (doc-view-pdf/ps->png pdf png-file)))))
 749      (pdf
 750       (let ((pages (doc-view-active-pages)))
 751         ;; Convert PDF to PNG images starting with the active pages.
 752         (doc-view-pdf->png doc-view-buffer-file-name png-file pages)))
 753       (t
 754        ;; Convert to PNG images.
 755        (doc-view-pdf/ps->png doc-view-buffer-file-name png-file)))))
 756
 757 ;;;; Slicing
 758
 759 (declare-function image-size "image.c" (spec &optional pixels frame))
 760
 761 (defun doc-view-set-slice (x y width height)
 762   "Set the slice of the images that should be displayed.
 763 You can use this function to tell doc-view not to display the
 764 margins of the document.  It prompts for the top-left corner (X
 765 and Y) of the slice to display and its WIDTH and HEIGHT.
 766
 767 See `doc-view-set-slice-using-mouse' for a more convenient way to
 768 do that.  To reset the slice use `doc-view-reset-slice'."
 769   (interactive
 770    (let* ((size (image-size (doc-view-current-image) t))
 771           (a (read-number (format "Top-left X (0..%d): " (car size))))
 772           (b (read-number (format "Top-left Y (0..%d): " (cdr size))))
 773           (c (read-number (format "Width (0..%d): " (- (car size) a))))
 774           (d (read-number (format "Height (0..%d): " (- (cdr size) b)))))
 775      (list a b c d)))
 776   (setf (doc-view-current-slice) (list x y width height))
 777   ;; Redisplay
 778   (doc-view-goto-page (doc-view-current-page)))
 779
 780 (defun doc-view-set-slice-using-mouse ()
 781   "Set the slice of the images that should be displayed.
 782 You set the slice by pressing mouse-1 at its top-left corner and
 783 dragging it to its bottom-right corner.  See also
 784 `doc-view-set-slice' and `doc-view-reset-slice'."
 785   (interactive)
 786   (let (x y w h done)
 787     (while (not done)
 788       (let ((e (read-event
 789                 (concat "Press mouse-1 at the top-left corner and "
 790                         "drag it to the bottom-right corner!"))))
 791         (when (eq (car e) 'drag-mouse-1)
 792           (setq x (car (posn-object-x-y (event-start e))))
 793           (setq y (cdr (posn-object-x-y (event-start e))))
 794           (setq w (- (car (posn-object-x-y (event-end e))) x))
 795           (setq h (- (cdr (posn-object-x-y (event-end e))) y))
 796           (setq done t))))
 797     (doc-view-set-slice x y w h)))
 798
 799 (defun doc-view-reset-slice ()
 800   "Reset the current slice.
 801 After calling this function whole pages will be visible again."
 802   (interactive)
 803   (setf (doc-view-current-slice) nil)
 804   ;; Redisplay
 805   (doc-view-goto-page (doc-view-current-page)))
 806
 807 ;;;; Display
 808
 809 (defun doc-view-insert-image (file &rest args)
 810   "Insert the given png FILE.
 811 ARGS is a list of image descriptors."
 812   (when doc-view-pending-cache-flush
 813     (clear-image-cache)
 814     (setq doc-view-pending-cache-flush nil))
 815   (let ((ol (doc-view-current-overlay))
 816         (image (if (and file (file-readable-p file))
 817                    (apply 'create-image file 'png nil args)))
 818         (slice (doc-view-current-slice)))
 819     (setf (doc-view-current-image) image)
 820     (move-overlay ol (point-min) (point-max))
 821     (overlay-put ol 'display
 822                  (cond
 823                   (image
 824                    (if slice
 825                        (list (cons 'slice slice) image)
 826                      image))
 827                   ;; We're trying to display a page that doesn't exist.
 828                   (doc-view-current-converter-processes
 829                    ;; Maybe the page doesn't exist *yet*.
 830                    "Cannot display this page (yet)!")
 831                   (t
 832                    ;; Typically happens if the conversion process somehow
 833                    ;; failed.  Better not signal an error here because it
 834                    ;; could prevent a subsequent reconversion from fixing
 835                    ;; the problem.
 836                    (concat "Cannot display this page!\n"
 837                            "Maybe because of a conversion failure!"))))
 838     (let ((win (overlay-get ol 'window)))
 839       (if (stringp (overlay-get ol 'display))
 840           (progn            ;Make sure the text is not scrolled out of view.
 841             (set-window-hscroll win 0)
 842             (set-window-vscroll win 0))
 843         (let ((hscroll (image-mode-window-get 'hscroll win))
 844               (vscroll (image-mode-window-get 'vscroll win)))
 845           ;; Reset scroll settings, in case they were changed.
 846           (if hscroll (set-window-hscroll win hscroll))
 847           (if vscroll (set-window-vscroll win vscroll)))))))
 848
 849 (defun doc-view-sort (a b)
 850   "Return non-nil if A should be sorted before B.
 851 Predicate for sorting `doc-view-current-files'."
 852   (or (< (length a) (length b))
 853       (and (= (length a) (length b))
 854            (string< a b))))
 855
 856 (defun doc-view-display (buffer &optional force)
 857   "Start viewing the document in BUFFER.
 858 If FORCE is non-nil, start viewing even if the document does not
 859 have the page we want to view."
 860   (with-current-buffer buffer
 861     (let ((prev-pages doc-view-current-files))
 862       (setq doc-view-current-files
 863             (sort (directory-files (doc-view-current-cache-dir) t
 864                                    "page-[0-9]+\\.png" t)
 865                   'doc-view-sort))
 866       (dolist (win (or (get-buffer-window-list buffer nil t)
 867                        (list (selected-window))))
 868         (let* ((page (doc-view-current-page win))
 869                (pagefile (expand-file-name (format "page-%d.png" page)
 870                                            (doc-view-current-cache-dir))))
 871           (when (or force
 872                     (and (not (member pagefile prev-pages))
 873                          (member pagefile doc-view-current-files)))
 874             (with-selected-window win
 875               (assert (eq (current-buffer) buffer))
 876               (doc-view-goto-page page))))))))
 877
 878 (defun doc-view-buffer-message ()
 879   ;; Only show this message initially, not when refreshing the buffer (in which
 880   ;; case it's better to keep displaying the "stale" page while computing
 881   ;; the fresh new ones).
 882   (unless (overlay-get (doc-view-current-overlay) 'display)
 883     (overlay-put (doc-view-current-overlay) 'display
 884                  (concat (propertize "Welcome to DocView!" 'face 'bold)
 885                          "\n"
 886                          "
 887 If you see this buffer it means that the document you want to view is being
 888 converted to PNG and the conversion of the first page hasn't finished yet or
 889 `doc-view-conversion-refresh-interval' is set to nil.
 890
 891 For now these keys are useful:
 892
 893 `q' : Bury this buffer.  Conversion will go on in background.
 894 `k' : Kill the conversion process and this buffer.
 895 `K' : Kill the conversion process.\n"))))
 896
 897 (declare-function tooltip-show "tooltip" (text &optional use-echo-area))
 898
 899 (defun doc-view-show-tooltip ()
 900   (interactive)
 901   (tooltip-show (doc-view-current-info)))
 902
 903 (defun doc-view-open-text ()
 904   "Open a buffer with the current doc's contents as text."
 905   (interactive)
 906   (if doc-view-current-converter-processes
 907       (message "DocView: please wait till conversion finished.")
 908     (let ((txt (expand-file-name "doc.txt" (doc-view-current-cache-dir))))
 909       (if (file-readable-p txt)
 910           (find-file txt)
 911         (doc-view-doc->txt txt 'doc-view-open-text)))))
 912
 913 ;;;;; Toggle between editing and viewing
 914
 915
 916 (defun doc-view-toggle-display ()
 917   "Toggle between editing a document as text or viewing it."
 918   (interactive)
 919   (if (eq major-mode 'doc-view-mode)
 920       ;; Switch to editing mode
 921       (progn
 922         (doc-view-kill-proc)
 923         (setq buffer-read-only nil)
 924         (remove-overlays (point-min) (point-max) 'doc-view t)
 925         (set (make-local-variable 'image-mode-winprops-alist) t)
 926         ;; Switch to the previously used major mode or fall back to fundamental
 927         ;; mode.
 928         (if doc-view-previous-major-mode
 929             (funcall doc-view-previous-major-mode)
 930           (fundamental-mode))
 931         (doc-view-minor-mode 1))
 932     ;; Switch to doc-view-mode
 933     (when (and (buffer-modified-p)
 934                (y-or-n-p "The buffer has been modified.  Save the changes? "))
 935       (save-buffer))
 936     (doc-view-mode)))
 937
 938 ;;;; Searching
 939
 940
 941 (defun doc-view-search-internal (regexp file)
 942   "Return a list of FILE's pages that contain text matching REGEXP.
 943 The value is an alist of the form (PAGE CONTEXTS) where PAGE is
 944 the pagenumber and CONTEXTS are all lines of text containing a match."
 945   (with-temp-buffer
 946     (insert-file-contents file)
 947     (let ((page 1)
 948           (lastpage 1)
 949           matches)
 950       (while (re-search-forward (concat "\\(?:\\([\f]\\)\\|\\("
 951                                         regexp "\\)\\)") nil t)
 952         (when (match-string 1) (setq page (1+ page)))
 953         (when (match-string 2)
 954           (if (/= page lastpage)
 955               (push (cons page
 956                           (list (buffer-substring
 957                                  (line-beginning-position)
 958                                  (line-end-position))))
 959                     matches)
 960             (setq matches (cons
 961                            (append
 962                             (or
 963                              ;; This page already is a match.
 964                              (car matches)
 965                              ;; This is the first match on page.
 966                              (list page))
 967                             (list (buffer-substring
 968                                    (line-beginning-position)
 969                                    (line-end-position))))
 970                            (cdr matches))))
 971           (setq lastpage page)))
 972       (nreverse matches))))
 973
 974 (defun doc-view-search-no-of-matches (list)
 975   "Extract the number of matches from the search result LIST."
 976   (let ((no 0))
 977     (dolist (p list)
 978       (setq no (+ no (1- (length p)))))
 979     no))
 980
 981 (defun doc-view-search-backward (new-query)
 982   "Call `doc-view-search' for backward search.
 983 If prefix NEW-QUERY is given, ask for a new regexp."
 984   (interactive "P")
 985   (doc-view-search new-query t))
 986
 987 (defun doc-view-search (new-query &optional backward)
 988   "Jump to the next match or initiate a new search if NEW-QUERY is given.
 989 If the current document hasn't been transformed to plain text
 990 till now do that first.
 991 If BACKWARD is non-nil, jump to the previous match."
 992   (interactive "P")
 993   (if (and (not new-query)
 994            doc-view-current-search-matches)
 995       (if backward
 996           (doc-view-search-previous-match 1)
 997         (doc-view-search-next-match 1))
 998     ;; New search, so forget the old results.
 999     (setq doc-view-current-search-matches nil)
1000     (let ((txt (expand-file-name "doc.txt"
1001                                  (doc-view-current-cache-dir))))
1002       (if (file-readable-p txt)
1003           (progn
1004             (setq doc-view-current-search-matches
1005                   (doc-view-search-internal
1006                    (read-from-minibuffer "Regexp: ")
1007                    txt))
1008             (message "DocView: search yielded %d matches."
1009                      (doc-view-search-no-of-matches
1010                       doc-view-current-search-matches)))
1011         ;; We must convert to TXT first!
1012         (if doc-view-current-converter-processes
1013             (message "DocView: please wait till conversion finished.")
1014           (doc-view-doc->txt txt (lambda () (doc-view-search nil))))))))
1015
1016 (defun doc-view-search-next-match (arg)
1017   "Go to the ARGth next matching page."
1018   (interactive "p")
1019   (let* ((next-pages (doc-view-remove-if
1020                       (lambda (i) (<= (car i) (doc-view-current-page)))
1021                       doc-view-current-search-matches))
1022          (page (car (nth (1- arg) next-pages))))
1023     (if page
1024         (doc-view-goto-page page)
1025       (when (and
1026              doc-view-current-search-matches
1027              (y-or-n-p "No more matches after current page.  Wrap to first match? "))
1028         (doc-view-goto-page (caar doc-view-current-search-matches))))))
1029
1030 (defun doc-view-search-previous-match (arg)
1031   "Go to the ARGth previous matching page."
1032   (interactive "p")
1033   (let* ((prev-pages (doc-view-remove-if
1034                       (lambda (i) (>= (car i) (doc-view-current-page)))
1035                       doc-view-current-search-matches))
1036          (page (car (nth (1- arg) (nreverse prev-pages)))))
1037     (if page
1038         (doc-view-goto-page page)
1039       (when (and
1040              doc-view-current-search-matches
1041              (y-or-n-p "No more matches before current page.  Wrap to last match? "))
1042         (doc-view-goto-page (caar (last doc-view-current-search-matches)))))))
1043
1044 ;;;; User interface commands and the mode
1045
1046 ;; (put 'doc-view-mode 'mode-class 'special)
1047
1048 (defun doc-view-already-converted-p ()
1049   "Return non-nil if the current doc was already converted."
1050   (and (file-exists-p (doc-view-current-cache-dir))
1051        (> (length (directory-files (doc-view-current-cache-dir) nil "\\.png$")) 0)))
1052
1053 (defun doc-view-initiate-display ()
1054   ;; Switch to image display if possible
1055   (if (doc-view-mode-p doc-view-doc-type)
1056       (progn
1057         (doc-view-buffer-message)
1058         (setf (doc-view-current-page) (or (doc-view-current-page) 1))
1059         (if (doc-view-already-converted-p)
1060             (progn
1061               (message "DocView: using cached files!")
1062               ;; Load the saved resolution
1063               (let ((res-file (expand-file-name "resolution.el"
1064                                                 (doc-view-current-cache-dir)))
1065                     (res doc-view-resolution))
1066                 (with-temp-buffer
1067                   (when (file-exists-p res-file)
1068                     (insert-file-contents res-file)
1069                     (setq res (read (current-buffer)))))
1070                 (when (numberp res)
1071                   (set (make-local-variable 'doc-view-resolution) res)))
1072               (doc-view-display (current-buffer) 'force))
1073           (doc-view-convert-current-doc))
1074         (message
1075          "%s"
1076          (substitute-command-keys
1077           (concat "Type \\[doc-view-toggle-display] to toggle between "
1078                   "editing or viewing the document."))))
1079     (message
1080      "%s"
1081      (substitute-command-keys
1082       (concat "No PNG support available or some conversion utility for "
1083               (file-name-extension doc-view-buffer-file-name)" files is missing.  "
1084               "Type \\[doc-view-toggle-display] to switch to "
1085               (if (eq doc-view-doc-type 'ps)
1086                   "ps-mode"
1087                 "fundamental-mode")
1088               ", \\[doc-view-open-text] to show the doc as text in a separate buffer "
1089               " or \\[doc-view-kill-proc-and-buffer] to kill this buffer.")))))
1090
1091 (defvar bookmark-make-record-function)
1092
1093 (defun doc-view-clone-buffer-hook ()
1094   ;; FIXME: There are several potential problems linked with reconversion
1095   ;; and auto-revert when we have indirect buffers because they share their
1096   ;; /tmp cache directory.  This sharing is good (you'd rather not reconvert
1097   ;; for each clone), but that means that clones need to collaborate a bit.
1098   ;; I guess it mostly means: detect when a reconversion process is already
1099   ;; running, and run the sentinel in all clones.
1100   ;;
1101   ;; Maybe the clones should really have a separate /tmp directory
1102   ;; so they could have a different resolution and you could use clones
1103   ;; for zooming.
1104   (remove-overlays (point-min) (point-max) 'doc-view t)
1105   (if (consp image-mode-winprops-alist) (setq image-mode-winprops-alist nil)))
1106
1107 (defun doc-view-intersection (l1 l2)
1108   (let ((l ()))
1109     (dolist (x l1) (if (memq x l2) (push x l)))
1110     l))
1111
1112 ;;;###autoload
1113 (defun doc-view-mode ()
1114   "Major mode in DocView buffers.
1115
1116 DocView Mode is an Emacs document viewer.  It displays PDF, PS
1117 and DVI files (as PNG images) in Emacs buffers.
1118
1119 You can use \\<doc-view-mode-map>\\[doc-view-toggle-display] to
1120 toggle between displaying the document or editing it as text.
1121 \\{doc-view-mode-map}"
1122   (interactive)
1123
1124   (if (or (not (file-exists-p buffer-file-name))
1125           (= (point-min) (point-max)))
1126       ;; The doc is empty or doesn't exist at all, so fallback to
1127       ;; another mode.
1128       (let ((auto-mode-alist (remq (rassq 'doc-view-mode auto-mode-alist)
1129                                    auto-mode-alist)))
1130         (normal-mode))
1131
1132     (let* ((prev-major-mode (if (eq major-mode 'doc-view-mode)
1133                                 doc-view-previous-major-mode
1134                               major-mode)))
1135       (kill-all-local-variables)
1136       (set (make-local-variable 'doc-view-previous-major-mode) prev-major-mode))
1137
1138     ;; Figure out the document type.
1139     (let ((name-types
1140            (when buffer-file-name
1141              (cdr (assoc (file-name-extension buffer-file-name)
1142                          '(("dvi" dvi)
1143                            ("pdf" pdf)
1144                            ("epdf" pdf)
1145                            ("ps" ps)
1146                            ("eps" ps))))))
1147           (content-types
1148            (save-excursion
1149              (goto-char (point-min))
1150              (cond
1151               ((looking-at "%!") '(ps))
1152               ((looking-at "%PDF") '(pdf))
1153               ((looking-at "\367\002") '(dvi))))))
1154       (set (make-local-variable 'doc-view-doc-type)
1155            (car (or (doc-view-intersection name-types content-types)
1156                     (when (and name-types content-types)
1157                       (error "Conflicting types: name says %s but content says %s"
1158                              name-types content-types))
1159                     name-types content-types
1160                     (error "Cannot determine the document type")))))
1161
1162     (doc-view-make-safe-dir doc-view-cache-directory)
1163     ;; Handle compressed files, remote files, files inside archives
1164     (set (make-local-variable 'doc-view-buffer-file-name)
1165          (cond
1166           (jka-compr-really-do-compress
1167            (expand-file-name
1168             (file-name-nondirectory
1169              (file-name-sans-extension buffer-file-name))
1170             doc-view-cache-directory))
1171           ;; Is the file readable by local processes?
1172           ;; We used to use `file-remote-p' but it's unclear what it's
1173           ;; supposed to return nil for things like local files accessed via
1174           ;; `su' or via file://...
1175           ((let ((file-name-handler-alist nil))
1176              (not (file-readable-p buffer-file-name)))
1177            (expand-file-name
1178             (file-name-nondirectory buffer-file-name)
1179             doc-view-cache-directory))
1180           (t buffer-file-name)))
1181     (when (not (string= doc-view-buffer-file-name buffer-file-name))
1182       (write-region nil nil doc-view-buffer-file-name))
1183
1184     (add-hook 'change-major-mode-hook
1185               (lambda ()
1186                 (doc-view-kill-proc)
1187                 (remove-overlays (point-min) (point-max) 'doc-view t))
1188               nil t)
1189     (add-hook 'clone-indirect-buffer-hook 'doc-view-clone-buffer-hook nil t)
1190     (add-hook 'kill-buffer-hook 'doc-view-kill-proc nil t)
1191
1192     (remove-overlays (point-min) (point-max) 'doc-view t) ;Just in case.
1193     ;; Keep track of display info ([vh]scroll, page number, overlay,
1194     ;; ...)  for each window in which this document is shown.
1195     (add-hook 'image-mode-new-window-functions
1196               'doc-view-new-window-function nil t)
1197     (image-mode-setup-winprops)
1198
1199     (set (make-local-variable 'mode-line-position)
1200          '(" P" (:eval (number-to-string (doc-view-current-page)))
1201            "/" (:eval (number-to-string (length doc-view-current-files)))))
1202     ;; Don't scroll unless the user specifically asked for it.
1203     (set (make-local-variable 'auto-hscroll-mode) nil)
1204     (set (make-local-variable 'cursor-type) nil)
1205     (use-local-map doc-view-mode-map)
1206     (set (make-local-variable 'after-revert-hook) 'doc-view-reconvert-doc)
1207     (set (make-local-variable 'bookmark-make-record-function)
1208          'doc-view-bookmark-make-record)
1209     (setq mode-name "DocView"
1210           buffer-read-only t
1211           major-mode 'doc-view-mode)
1212     (doc-view-initiate-display)
1213     (run-mode-hooks 'doc-view-mode-hook)))
1214
1215 ;;;###autoload
1216 (define-minor-mode doc-view-minor-mode
1217   "Toggle Doc view minor mode.
1218 With arg, turn Doc view minor mode on if arg is positive, off otherwise.
1219 See the command `doc-view-mode' for more information on this mode."
1220   nil " DocView" doc-view-minor-mode-map
1221   :group 'doc-view
1222   (when doc-view-minor-mode
1223     (add-hook 'change-major-mode-hook (lambda () (doc-view-minor-mode -1)) nil t)
1224     (message
1225      "%s"
1226      (substitute-command-keys
1227       "Type \\[doc-view-toggle-display] to toggle between editing or viewing the document."))))
1228
1229 (defun doc-view-clear-cache ()
1230   "Delete the whole cache (`doc-view-cache-directory')."
1231   (interactive)
1232   (dired-delete-file doc-view-cache-directory 'always))
1233
1234 (defun doc-view-dired-cache ()
1235   "Open `dired' in `doc-view-cache-directory'."
1236   (interactive)
1237   (dired doc-view-cache-directory))
1238
1239
1240 ;;;; Bookmark integration
1241
1242 (declare-function bookmark-make-record-default "bookmark"
1243                   (&optional point-only))
1244 (declare-function bookmark-prop-get "bookmark" (bookmark prop))
1245 (declare-function bookmark-default-handler "bookmark" (bmk))
1246
1247 (defun doc-view-bookmark-make-record ()
1248   (nconc (bookmark-make-record-default)
1249          `((page     . ,(doc-view-current-page))
1250            (handler  . doc-view-bookmark-jump))))
1251
1252
1253 ;;;###autoload
1254 (defun doc-view-bookmark-jump (bmk)
1255   ;; This implements the `handler' function interface for record type
1256   ;; returned by `doc-view-bookmark-make-record', which see.
1257   (prog1 (bookmark-default-handler bmk)
1258     (let ((page (bookmark-prop-get bmk 'page)))
1259       (when (not (eq major-mode 'doc-view-mode))
1260         (doc-view-toggle-display))
1261       (with-selected-window
1262           (or (get-buffer-window (current-buffer) 0)
1263               (selected-window))
1264         (doc-view-goto-page page)))))
1265
1266
1267 (provide 'doc-view)
1268
1269 ;; Local Variables:
1270 ;; mode: outline-minor
1271 ;; End:
1272
1273 ;; arch-tag: 5d6e5c5e-095f-489e-b4e4-1ca90a7d79be
1274 ;;; doc-view.el ends here