lisp/font-lock.el

   1 ;;; font-lock.el --- Electric font lock mode
   2
   3 ;; Copyright (C) 1992, 93, 94, 95, 96, 97, 98, 1999, 2000, 2001, 02, 2003, 2004
   4 ;;  Free Software Foundation, Inc.
   5
   6 ;; Author: jwz, then rms, then sm
   7 ;; Maintainer: FSF
   8 ;; Keywords: languages, faces
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Font Lock mode is a minor mode that causes your comments to be displayed in
  30 ;; one face, strings in another, reserved words in another, and so on.
  31 ;;
  32 ;; Comments will be displayed in `font-lock-comment-face'.
  33 ;; Strings will be displayed in `font-lock-string-face'.
  34 ;; Regexps are used to display selected patterns in other faces.
  35 ;;
  36 ;; To make the text you type be fontified, use M-x font-lock-mode RET.
  37 ;; When this minor mode is on, the faces of the current line are updated with
  38 ;; every insertion or deletion.
  39 ;;
  40 ;; To turn Font Lock mode on automatically, add this to your ~/.emacs file:
  41 ;;
  42 ;;  (add-hook 'emacs-lisp-mode-hook 'turn-on-font-lock)
  43 ;;
  44 ;; Or if you want to turn Font Lock mode on in many modes:
  45 ;;
  46 ;;  (global-font-lock-mode t)
  47 ;;
  48 ;; Fontification for a particular mode may be available in a number of levels
  49 ;; of decoration.  The higher the level, the more decoration, but the more time
  50 ;; it takes to fontify.  See the variable `font-lock-maximum-decoration', and
  51 ;; also the variable `font-lock-maximum-size'.  Support modes for Font Lock
  52 ;; mode can be used to speed up Font Lock mode.  See `font-lock-support-mode'.
  53 \f
  54 ;;; How Font Lock mode fontifies:
  55
  56 ;; When Font Lock mode is turned on in a buffer, it (a) fontifies the entire
  57 ;; buffer and (b) installs one of its fontification functions on one of the
  58 ;; hook variables that are run by Emacs after every buffer change (i.e., an
  59 ;; insertion or deletion).  Fontification means the replacement of `face' text
  60 ;; properties in a given region; Emacs displays text with these `face' text
  61 ;; properties appropriately.
  62 ;;
  63 ;; Fontification normally involves syntactic (i.e., strings and comments) and
  64 ;; regexp (i.e., keywords and everything else) passes.  There are actually
  65 ;; three passes; (a) the syntactic keyword pass, (b) the syntactic pass and (c)
  66 ;; the keyword pass.  Confused?
  67 ;;
  68 ;; The syntactic keyword pass places `syntax-table' text properties in the
  69 ;; buffer according to the variable `font-lock-syntactic-keywords'.  It is
  70 ;; necessary because Emacs' syntax table is not powerful enough to describe all
  71 ;; the different syntactic constructs required by the sort of people who decide
  72 ;; that a single quote can be syntactic or not depending on the time of day.
  73 ;; (What sort of person could decide to overload the meaning of a quote?)
  74 ;; Obviously the syntactic keyword pass must occur before the syntactic pass.
  75 ;;
  76 ;; The syntactic pass places `face' text properties in the buffer according to
  77 ;; syntactic context, i.e., according to the buffer's syntax table and buffer
  78 ;; text's `syntax-table' text properties.  It involves using a syntax parsing
  79 ;; function to determine the context of different parts of a region of text.  A
  80 ;; syntax parsing function is necessary because generally strings and/or
  81 ;; comments can span lines, and so the context of a given region is not
  82 ;; necessarily apparent from the content of that region.  Because the keyword
  83 ;; pass only works within a given region, it is not generally appropriate for
  84 ;; syntactic fontification.  This is the first fontification pass that makes
  85 ;; changes visible to the user; it fontifies strings and comments.
  86 ;;
  87 ;; The keyword pass places `face' text properties in the buffer according to
  88 ;; the variable `font-lock-keywords'.  It involves searching for given regexps
  89 ;; (or calling given search functions) within the given region.  This is the
  90 ;; second fontification pass that makes changes visible to the user; it
  91 ;; fontifies language reserved words, etc.
  92 ;;
  93 ;; Oh, and the answer is, "Yes, obviously just about everything should be done
  94 ;; in a single syntactic pass, but the only syntactic parser available
  95 ;; understands only strings and comments."  Perhaps one day someone will write
  96 ;; some syntactic parsers for common languages and a son-of-font-lock.el could
  97 ;; use them rather then relying so heavily on the keyword (regexp) pass.
  98
  99 ;;; How Font Lock mode supports modes or is supported by modes:
 100
 101 ;; Modes that support Font Lock mode do so by defining one or more variables
 102 ;; whose values specify the fontification.  Font Lock mode knows of these
 103 ;; variable names from (a) the buffer local variable `font-lock-defaults', if
 104 ;; non-nil, or (b) the global variable `font-lock-defaults-alist', if the major
 105 ;; mode has an entry.  (Font Lock mode is set up via (a) where a mode's
 106 ;; patterns are distributed with the mode's package library, and (b) where a
 107 ;; mode's patterns are distributed with font-lock.el itself.  An example of (a)
 108 ;; is Pascal mode, an example of (b) is Lisp mode.  Normally, the mechanism is
 109 ;; (a); (b) is used where it is not clear which package library should contain
 110 ;; the pattern definitions.)  Font Lock mode chooses which variable to use for
 111 ;; fontification based on `font-lock-maximum-decoration'.
 112 ;;
 113 ;; Font Lock mode fontification behaviour can be modified in a number of ways.
 114 ;; See the below comments and the comments distributed throughout this file.
 115
 116 ;;; Constructing patterns:
 117
 118 ;; See the documentation for the variable `font-lock-keywords'.
 119 ;;
 120 ;; Efficient regexps for use as MATCHERs for `font-lock-keywords' and
 121 ;; `font-lock-syntactic-keywords' can be generated via the function
 122 ;; `regexp-opt'.
 123
 124 ;;; Adding patterns for modes that already support Font Lock:
 125
 126 ;; Though Font Lock highlighting patterns already exist for many modes, it's
 127 ;; likely there's something that you want fontified that currently isn't, even
 128 ;; at the maximum fontification level.  You can add highlighting patterns via
 129 ;; `font-lock-add-keywords'.  For example, say in some C
 130 ;; header file you #define the token `and' to expand to `&&', etc., to make
 131 ;; your C code almost readable.  In your ~/.emacs there could be:
 132 ;;
 133 ;;  (font-lock-add-keywords 'c-mode '("\\<\\(and\\|or\\|not\\)\\>"))
 134 ;;
 135 ;; Some modes provide specific ways to modify patterns based on the values of
 136 ;; other variables.  For example, additional C types can be specified via the
 137 ;; variable `c-font-lock-extra-types'.
 138
 139 ;;; Adding patterns for modes that do not support Font Lock:
 140
 141 ;; Not all modes support Font Lock mode.  If you (as a user of the mode) add
 142 ;; patterns for a new mode, you must define in your ~/.emacs a variable or
 143 ;; variables that specify regexp fontification.  Then, you should indicate to
 144 ;; Font Lock mode, via the mode hook setting `font-lock-defaults', exactly what
 145 ;; support is required.  For example, say Foo mode should have the following
 146 ;; regexps fontified case-sensitively, and comments and strings should not be
 147 ;; fontified automagically.  In your ~/.emacs there could be:
 148 ;;
 149 ;;  (defvar foo-font-lock-keywords
 150 ;;    '(("\\<\\(one\\|two\\|three\\)\\>" . font-lock-keyword-face)
 151 ;;      ("\\<\\(four\\|five\\|six\\)\\>" . font-lock-type-face))
 152 ;;    "Default expressions to highlight in Foo mode.")
 153 ;;
 154 ;;  (add-hook 'foo-mode-hook
 155 ;;   (lambda ()
 156 ;;     (make-local-variable 'font-lock-defaults)
 157 ;;     (setq font-lock-defaults '(foo-font-lock-keywords t))))
 158
 159 ;;; Adding Font Lock support for modes:
 160
 161 ;; Of course, it would be better that the mode already supports Font Lock mode.
 162 ;; The package author would do something similar to above.  The mode must
 163 ;; define at the top-level a variable or variables that specify regexp
 164 ;; fontification.  Then, the mode command should indicate to Font Lock mode,
 165 ;; via `font-lock-defaults', exactly what support is required.  For example,
 166 ;; say Bar mode should have the following regexps fontified case-insensitively,
 167 ;; and comments and strings should be fontified automagically.  In bar.el there
 168 ;; could be:
 169 ;;
 170 ;;  (defvar bar-font-lock-keywords
 171 ;;    '(("\\<\\(uno\\|due\\|tre\\)\\>" . font-lock-keyword-face)
 172 ;;      ("\\<\\(quattro\\|cinque\\|sei\\)\\>" . font-lock-type-face))
 173 ;;    "Default expressions to highlight in Bar mode.")
 174 ;;
 175 ;; and within `bar-mode' there could be:
 176 ;;
 177 ;;  (make-local-variable 'font-lock-defaults)
 178 ;;  (setq font-lock-defaults '(bar-font-lock-keywords nil t))
 179 \f
 180 ;; What is fontification for?  You might say, "It's to make my code look nice."
 181 ;; I think it should be for adding information in the form of cues.  These cues
 182 ;; should provide you with enough information to both (a) distinguish between
 183 ;; different items, and (b) identify the item meanings, without having to read
 184 ;; the items and think about it.  Therefore, fontification allows you to think
 185 ;; less about, say, the structure of code, and more about, say, why the code
 186 ;; doesn't work.  Or maybe it allows you to think less and drift off to sleep.
 187 ;;
 188 ;; So, here are my opinions/advice/guidelines:
 189 ;;
 190 ;; - Highlight conceptual objects, such as function and variable names, and
 191 ;;   different objects types differently, i.e., (a) and (b) above, highlight
 192 ;;   function names differently to variable names.
 193 ;; - Keep the faces distinct from each other as far as possible.
 194 ;;   i.e., (a) above.
 195 ;; - Use the same face for the same conceptual object, across all modes.
 196 ;;   i.e., (b) above, all modes that have items that can be thought of as, say,
 197 ;;   keywords, should be highlighted with the same face, etc.
 198 ;; - Make the face attributes fit the concept as far as possible.
 199 ;;   i.e., function names might be a bold colour such as blue, comments might
 200 ;;   be a bright colour such as red, character strings might be brown, because,
 201 ;;   err, strings are brown (that was not the reason, please believe me).
 202 ;; - Don't use a non-nil OVERRIDE unless you have a good reason.
 203 ;;   Only use OVERRIDE for special things that are easy to define, such as the
 204 ;;   way `...' quotes are treated in strings and comments in Emacs Lisp mode.
 205 ;;   Don't use it to, say, highlight keywords in commented out code or strings.
 206 ;; - Err, that's it.
 207 \f
 208 ;;; Code:
 209
 210 (require 'syntax)
 211
 212 ;; Define core `font-lock' group.
 213 (defgroup font-lock '((jit-lock custom-group))
 214   "Font Lock mode text highlighting package."
 215   :link '(custom-manual "(emacs)Font Lock")
 216   :link '(custom-manual "(elisp)Font Lock Mode")
 217   :group 'faces)
 218
 219 (defgroup font-lock-highlighting-faces nil
 220   "Faces for highlighting text."
 221   :prefix "font-lock-"
 222   :group 'font-lock)
 223
 224 (defgroup font-lock-extra-types nil
 225   "Extra mode-specific type names for highlighting declarations."
 226   :group 'font-lock)
 227
 228 ;; Define support mode groups here to impose `font-lock' group order.
 229 (defgroup fast-lock nil
 230   "Font Lock support mode to cache fontification."
 231   :load 'fast-lock
 232   :group 'font-lock)
 233
 234 (defgroup lazy-lock nil
 235   "Font Lock support mode to fontify lazily."
 236   :load 'lazy-lock
 237   :group 'font-lock)
 238 \f
 239 ;; User variables.
 240
 241 (defcustom font-lock-maximum-size 256000
 242   "*Maximum size of a buffer for buffer fontification.
 243 Only buffers less than this can be fontified when Font Lock mode is turned on.
 244 If nil, means size is irrelevant.
 245 If a list, each element should be a cons pair of the form (MAJOR-MODE . SIZE),
 246 where MAJOR-MODE is a symbol or t (meaning the default).  For example:
 247  ((c-mode . 256000) (c++-mode . 256000) (rmail-mode . 1048576))
 248 means that the maximum size is 250K for buffers in C or C++ modes, one megabyte
 249 for buffers in Rmail mode, and size is irrelevant otherwise."
 250   :type '(choice (const :tag "none" nil)
 251                  (integer :tag "size")
 252                  (repeat :menu-tag "mode specific" :tag "mode specific"
 253                          :value ((t . nil))
 254                          (cons :tag "Instance"
 255                                (radio :tag "Mode"
 256                                       (const :tag "all" t)
 257                                       (symbol :tag "name"))
 258                                (radio :tag "Size"
 259                                       (const :tag "none" nil)
 260                                       (integer :tag "size")))))
 261   :group 'font-lock)
 262
 263 (defcustom font-lock-maximum-decoration t
 264   "*Maximum decoration level for fontification.
 265 If nil, use the default decoration (typically the minimum available).
 266 If t, use the maximum decoration available.
 267 If a number, use that level of decoration (or if not available the maximum).
 268 If a list, each element should be a cons pair of the form (MAJOR-MODE . LEVEL),
 269 where MAJOR-MODE is a symbol or t (meaning the default).  For example:
 270  ((c-mode . t) (c++-mode . 2) (t . 1))
 271 means use the maximum decoration available for buffers in C mode, level 2
 272 decoration for buffers in C++ mode, and level 1 decoration otherwise."
 273   :type '(choice (const :tag "default" nil)
 274                  (const :tag "maximum" t)
 275                  (integer :tag "level" 1)
 276                  (repeat :menu-tag "mode specific" :tag "mode specific"
 277                          :value ((t . t))
 278                          (cons :tag "Instance"
 279                                (radio :tag "Mode"
 280                                       (const :tag "all" t)
 281                                       (symbol :tag "name"))
 282                                (radio :tag "Decoration"
 283                                       (const :tag "default" nil)
 284                                       (const :tag "maximum" t)
 285                                       (integer :tag "level" 1)))))
 286   :group 'font-lock)
 287
 288 (defcustom font-lock-verbose 0
 289   "*If non-nil, means show status messages for buffer fontification.
 290 If a number, only buffers greater than this size have fontification messages."
 291   :type '(choice (const :tag "never" nil)
 292                  (other :tag "always" t)
 293                  (integer :tag "size"))
 294   :group 'font-lock)
 295 \f
 296
 297 ;; Originally these variable values were face names such as `bold' etc.
 298 ;; Now we create our own faces, but we keep these variables for compatibility
 299 ;; and they give users another mechanism for changing face appearance.
 300 ;; We now allow a FACENAME in `font-lock-keywords' to be any expression that
 301 ;; returns a face.  So the easiest thing is to continue using these variables,
 302 ;; rather than sometimes evaling FACENAME and sometimes not.  sm.
 303 (defvar font-lock-comment-face          'font-lock-comment-face
 304   "Face name to use for comments.")
 305
 306 (defvar font-lock-string-face           'font-lock-string-face
 307   "Face name to use for strings.")
 308
 309 (defvar font-lock-doc-face              'font-lock-doc-face
 310   "Face name to use for documentation.")
 311
 312 (defvar font-lock-keyword-face          'font-lock-keyword-face
 313   "Face name to use for keywords.")
 314
 315 (defvar font-lock-builtin-face          'font-lock-builtin-face
 316   "Face name to use for builtins.")
 317
 318 (defvar font-lock-function-name-face    'font-lock-function-name-face
 319   "Face name to use for function names.")
 320
 321 (defvar font-lock-variable-name-face    'font-lock-variable-name-face
 322   "Face name to use for variable names.")
 323
 324 (defvar font-lock-type-face             'font-lock-type-face
 325   "Face name to use for type and class names.")
 326
 327 (defvar font-lock-constant-face         'font-lock-constant-face
 328   "Face name to use for constant and label names.")
 329
 330 (defvar font-lock-warning-face          'font-lock-warning-face
 331   "Face name to use for things that should stand out.")
 332
 333 (defvar font-lock-preprocessor-face     'font-lock-preprocessor-face
 334   "Face name to use for preprocessor directives.")
 335
 336 (defvar font-lock-reference-face        'font-lock-constant-face)
 337 (make-obsolete-variable 'font-lock-reference-face 'font-lock-constant-face)
 338
 339 ;; Fontification variables:
 340
 341 (defvar font-lock-keywords nil
 342   "A list of the keywords to highlight.
 343 There are two kinds of values: user-level, and compiled.
 344
 345 A user-level keywords list is what a major mode or the user would
 346 set up.  Normally the list would come from `font-lock-defaults'.
 347 through selection of a fontification level and evaluation of any
 348 contained expressions.  You can also alter it by calling
 349 `font-lock-add-keywords' or `font-lock-remove-keywords' with MODE = nil.
 350
 351 Each element in a user-level keywords list should have one of these forms:
 352
 353  MATCHER
 354  (MATCHER . MATCH)
 355  (MATCHER . FACENAME)
 356  (MATCHER . HIGHLIGHT)
 357  (MATCHER HIGHLIGHT ...)
 358  (eval . FORM)
 359
 360 where MATCHER can be either the regexp to search for, or the function name to
 361 call to make the search (called with one argument, the limit of the search) and
 362 return non-nil if it succeeds (and set `match-data' appropriately).
 363 MATCHER regexps can be generated via the function `regexp-opt'.
 364
 365 FORM is an expression, whose value should be a keyword element, evaluated when
 366 the keyword is (first) used in a buffer.  This feature can be used to provide a
 367 keyword that can only be generated when Font Lock mode is actually turned on.
 368
 369 HIGHLIGHT should be either MATCH-HIGHLIGHT or MATCH-ANCHORED.
 370
 371 For highlighting single items, for example each instance of the word \"foo\",
 372 typically only MATCH-HIGHLIGHT is required.
 373 However, if an item or (typically) items are to be highlighted following the
 374 instance of another item (the anchor), for example each instance of the
 375 word \"bar\" following the word \"anchor\" then MATCH-ANCHORED may be required.
 376
 377 MATCH-HIGHLIGHT should be of the form:
 378
 379  (MATCH FACENAME OVERRIDE LAXMATCH)
 380
 381 MATCH is the subexpression of MATCHER to be highlighted.  FACENAME is an
 382 expression whose value is the face name to use.  Face default attributes
 383 can be modified via \\[customize].  Instead of a face, FACENAME can
 384 evaluate to a property list of the form (face VAL1 PROP2 VAL2 PROP3 VAL3 ...)
 385 in which case all the listed text-properties will be set rather than
 386 just `face'.  In such a case, you will most likely want to put those
 387 properties in `font-lock-extra-managed-props' or to override
 388 `font-lock-unfontify-region-function'.
 389
 390 OVERRIDE and LAXMATCH are flags.  If OVERRIDE is t, existing fontification can
 391 be overwritten.  If `keep', only parts not already fontified are highlighted.
 392 If `prepend' or `append', existing fontification is merged with the new, in
 393 which the new or existing fontification, respectively, takes precedence.
 394 If LAXMATCH is non-nil, no error is signaled if there is no MATCH in MATCHER.
 395
 396 For example, an element of the form highlights (if not already highlighted):
 397
 398  \"\\\\\\=<foo\\\\\\=>\"                discrete occurrences of \"foo\" in the value of the
 399                         variable `font-lock-keyword-face'.
 400  (\"fu\\\\(bar\\\\)\" . 1)      substring \"bar\" within all occurrences of \"fubar\" in
 401                         the value of `font-lock-keyword-face'.
 402  (\"fubar\" . fubar-face)       Occurrences of \"fubar\" in the value of `fubar-face'.
 403  (\"foo\\\\|bar\" 0 foo-bar-face t)
 404                         occurrences of either \"foo\" or \"bar\" in the value
 405                         of `foo-bar-face', even if already highlighted.
 406  (fubar-match 1 fubar-face)
 407                         the first subexpression within all occurrences of
 408                         whatever the function `fubar-match' finds and matches
 409                         in the value of `fubar-face'.
 410
 411 MATCH-ANCHORED should be of the form:
 412
 413  (MATCHER PRE-MATCH-FORM POST-MATCH-FORM MATCH-HIGHLIGHT ...)
 414
 415 where MATCHER is a regexp to search for or the function name to call to make
 416 the search, as for MATCH-HIGHLIGHT above, but with one exception; see below.
 417 PRE-MATCH-FORM and POST-MATCH-FORM are evaluated before the first, and after
 418 the last, instance MATCH-ANCHORED's MATCHER is used.  Therefore they can be
 419 used to initialise before, and cleanup after, MATCHER is used.  Typically,
 420 PRE-MATCH-FORM is used to move to some position relative to the original
 421 MATCHER, before starting with MATCH-ANCHORED's MATCHER.  POST-MATCH-FORM might
 422 be used to move, before resuming with MATCH-ANCHORED's parent's MATCHER.
 423
 424 For example, an element of the form highlights (if not already highlighted):
 425
 426  (\"\\\\\\=<anchor\\\\\\=>\" (0 anchor-face) (\"\\\\\\=<item\\\\\\=>\" nil nil (0 item-face)))
 427
 428  discrete occurrences of \"anchor\" in the value of `anchor-face', and subsequent
 429  discrete occurrences of \"item\" (on the same line) in the value of `item-face'.
 430  (Here PRE-MATCH-FORM and POST-MATCH-FORM are nil.  Therefore \"item\" is
 431  initially searched for starting from the end of the match of \"anchor\", and
 432  searching for subsequent instance of \"anchor\" resumes from where searching
 433  for \"item\" concluded.)
 434
 435 The above-mentioned exception is as follows.  The limit of the MATCHER search
 436 defaults to the end of the line after PRE-MATCH-FORM is evaluated.
 437 However, if PRE-MATCH-FORM returns a position greater than the position after
 438 PRE-MATCH-FORM is evaluated, that position is used as the limit of the search.
 439 It is generally a bad idea to return a position greater than the end of the
 440 line, i.e., cause the MATCHER search to span lines.
 441
 442 These regular expressions can match text which spans lines, although
 443 it is better to avoid it if possible since updating them while editing
 444 text is slower, and it is not guaranteed to be always correct when using
 445 support modes like jit-lock or lazy-lock.
 446
 447 This variable is set by major modes via the variable `font-lock-defaults'.
 448 Be careful when composing regexps for this list; a poorly written pattern can
 449 dramatically slow things down!
 450
 451 A compiled keywords list starts with t.  It is produced internal
 452 by `font-lock-compile-keywords' from a user-level keywords list.
 453 Its second element is the user-level keywords list that was
 454 compiled.  The remaining elements have the same form as
 455 user-level keywords, but normally their values have been
 456 optimized.")
 457
 458 (defvar font-lock-keywords-alist nil
 459   "*Alist of `font-lock-keywords' local to a `major-mode'.
 460 This is normally set via `font-lock-add-keywords' and
 461 `font-lock-remove-keywords'.")
 462
 463 (defvar font-lock-removed-keywords-alist nil
 464   "*Alist of `font-lock-keywords' removed from `major-mode'.
 465 This is normally set via `font-lock-add-keywords' and
 466 `font-lock-remove-keywords'.")
 467
 468 (defvar font-lock-keywords-only nil
 469   "*Non-nil means Font Lock should not fontify comments or strings.
 470 This is normally set via `font-lock-defaults'.")
 471
 472 (defvar font-lock-keywords-case-fold-search nil
 473   "*Non-nil means the patterns in `font-lock-keywords' are case-insensitive.
 474 This is normally set via `font-lock-defaults'.")
 475 (make-variable-buffer-local 'font-lock-keywords-case-fold-search)
 476
 477 (defvar font-lock-syntactically-fontified 0
 478   "Point up to which `font-lock-syntactic-keywords' has been applied.
 479 If nil, this is ignored, in which case the syntactic fontification may
 480 sometimes be slightly incorrect.")
 481 (make-variable-buffer-local 'font-lock-syntactically-fontified)
 482
 483 (defvar font-lock-syntactic-face-function
 484   (lambda (state)
 485     (if (nth 3 state) font-lock-string-face font-lock-comment-face))
 486   "Function to determine which face to use when fontifying syntactically.
 487 The function is called with a single parameter (the state as returned by
 488 `parse-partial-sexp' at the beginning of the region to highlight) and
 489 should return a face.")
 490
 491 (defvar font-lock-syntactic-keywords nil
 492   "A list of the syntactic keywords to highlight.
 493 Can be the list or the name of a function or variable whose value is the list.
 494 See `font-lock-keywords' for a description of the form of this list;
 495 the differences are listed below.  MATCH-HIGHLIGHT should be of the form:
 496
 497  (MATCH SYNTAX OVERRIDE LAXMATCH)
 498
 499 where SYNTAX can be a string (as taken by `modify-syntax-entry'), a syntax
 500 table, a cons cell (as returned by `string-to-syntax') or an expression whose
 501 value is such a form.  OVERRIDE cannot be `prepend' or `append'.
 502
 503 For example, an element of the form highlights syntactically:
 504
 505  (\"\\\\$\\\\(#\\\\)\" 1 \".\")
 506
 507  a hash character when following a dollar character, with a SYNTAX of
 508  \".\" (meaning punctuation syntax).  Assuming that the buffer syntax table does
 509  specify hash characters to have comment start syntax, the element will only
 510  highlight hash characters that do not follow dollar characters as comments
 511  syntactically.
 512
 513  (\"\\\\('\\\\).\\\\('\\\\)\"
 514   (1 \"\\\"\")
 515   (2 \"\\\"\"))
 516
 517  both single quotes which surround a single character, with a SYNTAX of
 518  \"\\\"\" (meaning string quote syntax).  Assuming that the buffer syntax table
 519  does not specify single quotes to have quote syntax, the element will only
 520  highlight single quotes of the form 'c' as strings syntactically.
 521  Other forms, such as foo'bar or 'fubar', will not be highlighted as strings.
 522
 523 This is normally set via `font-lock-defaults'.")
 524
 525 (defvar font-lock-syntax-table nil
 526   "Non-nil means use this syntax table for fontifying.
 527 If this is nil, the major mode's syntax table is used.
 528 This is normally set via `font-lock-defaults'.")
 529
 530 (defvar font-lock-beginning-of-syntax-function nil
 531   "*Non-nil means use this function to move back outside all constructs.
 532 When called with no args it should move point backward to a place which
 533 is not in a string or comment and not within any bracket-pairs (or else,
 534 a place such that any bracket-pairs outside it can be ignored for Emacs
 535 syntax analysis and fontification).
 536
 537 If this is nil, the beginning of the buffer is used, which is
 538 always correct but tends to be slow.
 539 This is normally set via `font-lock-defaults'.
 540 This variable is semi-obsolete; we recommend setting
 541 `syntax-begin-function' instead.")
 542
 543 (defvar font-lock-mark-block-function nil
 544   "*Non-nil means use this function to mark a block of text.
 545 When called with no args it should leave point at the beginning of any
 546 enclosing textual block and mark at the end.
 547 This is normally set via `font-lock-defaults'.")
 548
 549 (defvar font-lock-fontify-buffer-function 'font-lock-default-fontify-buffer
 550   "Function to use for fontifying the buffer.
 551 This is normally set via `font-lock-defaults'.")
 552
 553 (defvar font-lock-unfontify-buffer-function 'font-lock-default-unfontify-buffer
 554   "Function to use for unfontifying the buffer.
 555 This is used when turning off Font Lock mode.
 556 This is normally set via `font-lock-defaults'.")
 557
 558 (defvar font-lock-fontify-region-function 'font-lock-default-fontify-region
 559   "Function to use for fontifying a region.
 560 It should take two args, the beginning and end of the region, and an optional
 561 third arg VERBOSE.  If non-nil, the function should print status messages.
 562 This is normally set via `font-lock-defaults'.")
 563
 564 (defvar font-lock-unfontify-region-function 'font-lock-default-unfontify-region
 565   "Function to use for unfontifying a region.
 566 It should take two args, the beginning and end of the region.
 567 This is normally set via `font-lock-defaults'.")
 568
 569 (defvar font-lock-inhibit-thing-lock nil
 570   "List of Font Lock mode related modes that should not be turned on.
 571 Currently, valid mode names are `fast-lock-mode', `jit-lock-mode' and
 572 `lazy-lock-mode'.  This is normally set via `font-lock-defaults'.")
 573
 574 (defvar font-lock-multiline nil
 575   "Whether font-lock should cater to multiline keywords.
 576 If nil, don't try to handle multiline patterns.
 577 If t, always handle multiline patterns.
 578 If `undecided', don't try to handle multiline patterns until you see one.
 579 Major/minor modes can set this variable if they know which option applies.")
 580
 581 (defvar font-lock-fontified nil)        ; Whether we have fontified the buffer.
 582 \f
 583 ;; Font Lock mode.
 584
 585 (eval-when-compile
 586   ;;
 587   ;; We don't do this at the top-level as we only use non-autoloaded macros.
 588   (require 'cl)
 589   ;;
 590   ;; Borrowed from lazy-lock.el.
 591   ;; We use this to preserve or protect things when modifying text properties.
 592   (defmacro save-buffer-state (varlist &rest body)
 593     "Bind variables according to VARLIST and eval BODY restoring buffer state."
 594     (let ((modified (make-symbol "modified")))
 595       `(let* ,(append varlist
 596                       `((,modified (buffer-modified-p))
 597                         (buffer-undo-list t)
 598                         (inhibit-read-only t)
 599                         (inhibit-point-motion-hooks t)
 600                         (inhibit-modification-hooks t)
 601                         deactivate-mark
 602                         buffer-file-name
 603                         buffer-file-truename))
 604          (progn
 605            ,@body)
 606          (unless ,modified
 607            (restore-buffer-modified-p nil)))))
 608   (put 'save-buffer-state 'lisp-indent-function 1)
 609   (def-edebug-spec save-buffer-state let)
 610   ;;
 611   ;; Shut up the byte compiler.
 612   (defvar font-lock-face-attributes))   ; Obsolete but respected if set.
 613
 614 ;;;###autoload
 615 (defun font-lock-mode-internal (arg)
 616   ;; Turn on Font Lock mode.
 617   (when arg
 618     (add-hook 'after-change-functions 'font-lock-after-change-function t t)
 619     (font-lock-set-defaults)
 620     (font-lock-turn-on-thing-lock)
 621     ;; Fontify the buffer if we have to.
 622     (let ((max-size (font-lock-value-in-major-mode font-lock-maximum-size)))
 623       (cond (font-lock-fontified
 624              nil)
 625             ((or (null max-size) (> max-size (buffer-size)))
 626              (font-lock-fontify-buffer))
 627             (font-lock-verbose
 628              (message "Fontifying %s...buffer size greater than font-lock-maximum-size"
 629                       (buffer-name))))))
 630   ;; Turn off Font Lock mode.
 631   (unless font-lock-mode
 632     (remove-hook 'after-change-functions 'font-lock-after-change-function t)
 633     (font-lock-unfontify-buffer)
 634     (font-lock-turn-off-thing-lock)))
 635
 636 ;;;###autoload
 637 (defun font-lock-add-keywords (mode keywords &optional append)
 638   "Add highlighting KEYWORDS for MODE.
 639 MODE should be a symbol, the major mode command name, such as `c-mode'
 640 or nil.  If nil, highlighting keywords are added for the current buffer.
 641 KEYWORDS should be a list; see the variable `font-lock-keywords'.
 642 By default they are added at the beginning of the current highlighting list.
 643 If optional argument APPEND is `set', they are used to replace the current
 644 highlighting list.  If APPEND is any other non-nil value, they are added at the
 645 end of the current highlighting list.
 646
 647 For example:
 648
 649  (font-lock-add-keywords 'c-mode
 650   '((\"\\\\\\=<\\\\(FIXME\\\\):\" 1 font-lock-warning-face prepend)
 651     (\"\\\\\\=<\\\\(and\\\\|or\\\\|not\\\\)\\\\\\=>\" . font-lock-keyword-face)))
 652
 653 adds two fontification patterns for C mode, to fontify `FIXME:' words, even in
 654 comments, and to fontify `and', `or' and `not' words as keywords.
 655
 656 When used from an elisp package (such as a minor mode), it is recommended
 657 to use nil for MODE (and place the call in a loop or on a hook) to avoid
 658 subtle problems due to details of the implementation.
 659
 660 Note that some modes have specialized support for additional patterns, e.g.,
 661 see the variables `c-font-lock-extra-types', `c++-font-lock-extra-types',
 662 `objc-font-lock-extra-types' and `java-font-lock-extra-types'."
 663   (cond (mode
 664          ;; If MODE is non-nil, add the KEYWORDS and APPEND spec to
 665          ;; `font-lock-keywords-alist' so `font-lock-set-defaults' uses them.
 666          (let ((spec (cons keywords append)) cell)
 667            (if (setq cell (assq mode font-lock-keywords-alist))
 668                (if (eq append 'set)
 669                    (setcdr cell (list spec))
 670                  (setcdr cell (append (cdr cell) (list spec))))
 671              (push (list mode spec) font-lock-keywords-alist)))
 672          ;; Make sure that `font-lock-removed-keywords-alist' does not
 673          ;; contain the new keywords.
 674          (font-lock-update-removed-keyword-alist mode keywords append))
 675         (t
 676          ;; Otherwise set or add the keywords now.
 677          ;; This is a no-op if it has been done already in this buffer.
 678          (font-lock-set-defaults)
 679          (let ((was-compiled (eq (car font-lock-keywords) t)))
 680            ;; Bring back the user-level (uncompiled) keywords.
 681            (if was-compiled
 682                (setq font-lock-keywords (cadr font-lock-keywords)))
 683            ;; Now modify or replace them.
 684            (if (eq append 'set)
 685                (setq font-lock-keywords keywords)
 686              (font-lock-remove-keywords nil keywords) ;to avoid duplicates
 687              (let ((old (if (eq (car-safe font-lock-keywords) t)
 688                             (cdr font-lock-keywords)
 689                           font-lock-keywords)))
 690                (setq font-lock-keywords (if append
 691                                             (append old keywords)
 692                                           (append keywords old)))))
 693            ;; If the keywords were compiled before, compile them again.
 694            (if was-compiled
 695                (set (make-local-variable 'font-lock-keywords)
 696                     (font-lock-compile-keywords keywords t)))))))
 697
 698 (defun font-lock-update-removed-keyword-alist (mode keywords append)
 699   ;; Update `font-lock-removed-keywords-alist' when adding new
 700   ;; KEYWORDS to MODE.
 701   ;;
 702   ;; When font-lock is enabled first all keywords in the list
 703   ;; `font-lock-keywords-alist' are added, then all keywords in the
 704   ;; list `font-lock-removed-keywords-alist' are removed.  If a
 705   ;; keyword was once added, removed, and then added again it must be
 706   ;; removed from the removed-keywords list.  Otherwise the second add
 707   ;; will not take effect.
 708   (let ((cell (assq mode font-lock-removed-keywords-alist)))
 709     (if cell
 710         (if (eq append 'set)
 711             ;; A new set of keywords is defined.  Forget all about
 712             ;; our old keywords that should be removed.
 713             (setq font-lock-removed-keywords-alist
 714                   (delq cell font-lock-removed-keywords-alist))
 715           ;; Delete all previously removed keywords.
 716           (dolist (kword keywords)
 717             (setcdr cell (delete kword (cdr cell))))
 718           ;; Delete the mode cell if empty.
 719           (if (null (cdr cell))
 720               (setq font-lock-removed-keywords-alist
 721                     (delq cell font-lock-removed-keywords-alist)))))))
 722
 723 ;; Written by Anders Lindgren <andersl@andersl.com>.
 724 ;;
 725 ;; Case study:
 726 ;; (I)  The keywords are removed from a major mode.
 727 ;;      In this case the keyword could be local (i.e. added earlier by
 728 ;;      `font-lock-add-keywords'), global, or both.
 729 ;;
 730 ;;      (a) In the local case we remove the keywords from the variable
 731 ;;          `font-lock-keywords-alist'.
 732 ;;
 733 ;;      (b) The actual global keywords are not known at this time.
 734 ;;          All keywords are added to `font-lock-removed-keywords-alist',
 735 ;;          when font-lock is enabled those keywords are removed.
 736 ;;
 737 ;;      Note that added keywords are taken out of the list of removed
 738 ;;      keywords.  This ensure correct operation when the same keyword
 739 ;;      is added and removed several times.
 740 ;;
 741 ;; (II) The keywords are removed from the current buffer.
 742 ;;;###autoload
 743 (defun font-lock-remove-keywords (mode keywords)
 744   "Remove highlighting KEYWORDS for MODE.
 745
 746 MODE should be a symbol, the major mode command name, such as `c-mode'
 747 or nil.  If nil, highlighting keywords are removed for the current buffer.
 748
 749 When used from an elisp package (such as a minor mode), it is recommended
 750 to use nil for MODE (and place the call in a loop or on a hook) to avoid
 751 subtle problems due to details of the implementation."
 752   (cond (mode
 753          ;; Remove one keyword at the time.
 754          (dolist (keyword keywords)
 755            (let ((top-cell (assq mode font-lock-keywords-alist)))
 756              ;; If MODE is non-nil, remove the KEYWORD from
 757              ;; `font-lock-keywords-alist'.
 758              (when top-cell
 759                (dolist (keyword-list-append-pair (cdr top-cell))
 760                  ;; `keywords-list-append-pair' is a cons with a list of
 761                  ;; keywords in the car top-cell and the original append
 762                  ;; argument in the cdr top-cell.
 763                  (setcar keyword-list-append-pair
 764                          (delete keyword (car keyword-list-append-pair))))
 765                ;; Remove keyword list/append pair when the keyword list
 766                ;; is empty and append doesn't specify `set'.  (If it
 767                ;; should be deleted then previously deleted keywords
 768                ;; would appear again.)
 769                (let ((cell top-cell))
 770                  (while (cdr cell)
 771                    (if (and (null (car (car (cdr cell))))
 772                             (not (eq (cdr (car (cdr cell))) 'set)))
 773                        (setcdr cell (cdr (cdr cell)))
 774                      (setq cell (cdr cell)))))
 775                ;; Final cleanup, remove major mode cell if last keyword
 776                ;; was deleted.
 777                (if (null (cdr top-cell))
 778                    (setq font-lock-keywords-alist
 779                          (delq top-cell font-lock-keywords-alist))))
 780              ;; Remember the keyword in case it is not local.
 781              (let ((cell (assq mode font-lock-removed-keywords-alist)))
 782                (if cell
 783                    (unless (member keyword (cdr cell))
 784                      (nconc cell (list keyword)))
 785                  (push (cons mode (list keyword))
 786                        font-lock-removed-keywords-alist))))))
 787         (t
 788          ;; Otherwise remove it immediately.
 789          (font-lock-set-defaults)
 790          (let ((was-compiled (eq (car font-lock-keywords) t)))
 791            ;; Bring back the user-level (uncompiled) keywords.
 792            (if was-compiled
 793                (setq font-lock-keywords (cadr font-lock-keywords)))
 794
 795            ;; Edit them.
 796            (setq font-lock-keywords (copy-sequence font-lock-keywords))
 797            (dolist (keyword keywords)
 798              (setq font-lock-keywords
 799                    (delete keyword font-lock-keywords)))
 800
 801            ;; If the keywords were compiled before, compile them again.
 802            (if was-compiled
 803                (set (make-local-variable 'font-lock-keywords)
 804                     (font-lock-compile-keywords keywords t)))))))
 805 \f
 806 ;;; Font Lock Support mode.
 807
 808 ;; This is the code used to interface font-lock.el with any of its add-on
 809 ;; packages, and provide the user interface.  Packages that have their own
 810 ;; local buffer fontification functions (see below) may have to call
 811 ;; `font-lock-after-fontify-buffer' and/or `font-lock-after-unfontify-buffer'
 812 ;; themselves.
 813
 814 (defcustom font-lock-support-mode 'jit-lock-mode
 815   "*Support mode for Font Lock mode.
 816 Support modes speed up Font Lock mode by being choosy about when fontification
 817 occurs.  Known support modes are Fast Lock mode (symbol `fast-lock-mode'),
 818 Lazy Lock mode (symbol `lazy-lock-mode'), and Just-in-time Lock mode (symbol
 819 `jit-lock-mode'.  See those modes for more info.
 820 If nil, means support for Font Lock mode is never performed.
 821 If a symbol, use that support mode.
 822 If a list, each element should be of the form (MAJOR-MODE . SUPPORT-MODE),
 823 where MAJOR-MODE is a symbol or t (meaning the default).  For example:
 824  ((c-mode . fast-lock-mode) (c++-mode . fast-lock-mode) (t . lazy-lock-mode))
 825 means that Fast Lock mode is used to support Font Lock mode for buffers in C or
 826 C++ modes, and Lazy Lock mode is used to support Font Lock mode otherwise.
 827
 828 The value of this variable is used when Font Lock mode is turned on."
 829   :type '(choice (const :tag "none" nil)
 830                  (const :tag "fast lock" fast-lock-mode)
 831                  (const :tag "lazy lock" lazy-lock-mode)
 832                  (const :tag "jit lock" jit-lock-mode)
 833                  (repeat :menu-tag "mode specific" :tag "mode specific"
 834                          :value ((t . jit-lock-mode))
 835                          (cons :tag "Instance"
 836                                (radio :tag "Mode"
 837                                       (const :tag "all" t)
 838                                       (symbol :tag "name"))
 839                                (radio :tag "Support"
 840                                       (const :tag "none" nil)
 841                                       (const :tag "fast lock" fast-lock-mode)
 842                                       (const :tag "lazy lock" lazy-lock-mode)
 843                                       (const :tag "JIT lock" jit-lock-mode)))
 844                          ))
 845   :version "21.1"
 846   :group 'font-lock)
 847
 848 (defvar fast-lock-mode)
 849 (defvar lazy-lock-mode)
 850 (defvar jit-lock-mode)
 851
 852 (defun font-lock-turn-on-thing-lock ()
 853   (let ((thing-mode (font-lock-value-in-major-mode font-lock-support-mode)))
 854     (cond ((eq thing-mode 'fast-lock-mode)
 855            (fast-lock-mode t))
 856           ((eq thing-mode 'lazy-lock-mode)
 857            (lazy-lock-mode t))
 858           ((eq thing-mode 'jit-lock-mode)
 859            ;; Prepare for jit-lock
 860            (remove-hook 'after-change-functions
 861                         'font-lock-after-change-function t)
 862            (set (make-local-variable 'font-lock-fontify-buffer-function)
 863                 'jit-lock-refontify)
 864            ;; Don't fontify eagerly (and don't abort is the buffer is large).
 865            (set (make-local-variable 'font-lock-fontified) t)
 866            ;; Use jit-lock.
 867            (jit-lock-register 'font-lock-fontify-region
 868                               (not font-lock-keywords-only))))))
 869
 870 (defun font-lock-turn-off-thing-lock ()
 871   (cond ((and (boundp 'fast-lock-mode) fast-lock-mode)
 872          (fast-lock-mode -1))
 873         ((and (boundp 'jit-lock-mode) jit-lock-mode)
 874          (jit-lock-unregister 'font-lock-fontify-region)
 875          ;; Reset local vars to the non-jit-lock case.
 876          (kill-local-variable 'font-lock-fontify-buffer-function))
 877         ((and (boundp 'lazy-lock-mode) lazy-lock-mode)
 878          (lazy-lock-mode -1))))
 879
 880 (defun font-lock-after-fontify-buffer ()
 881   (cond ((and (boundp 'fast-lock-mode) fast-lock-mode)
 882          (fast-lock-after-fontify-buffer))
 883         ;; Useless now that jit-lock intercepts font-lock-fontify-buffer.  -sm
 884         ;; (jit-lock-mode
 885         ;;  (jit-lock-after-fontify-buffer))
 886         ((and (boundp 'lazy-lock-mode) lazy-lock-mode)
 887          (lazy-lock-after-fontify-buffer))))
 888
 889 (defun font-lock-after-unfontify-buffer ()
 890   (cond ((and (boundp 'fast-lock-mode) fast-lock-mode)
 891          (fast-lock-after-unfontify-buffer))
 892         ;; Useless as well.  It's only called when:
 893         ;; - turning off font-lock: it does not matter if we leave spurious
 894         ;;   `fontified' text props around since jit-lock-mode is also off.
 895         ;; - font-lock-default-fontify-buffer fails: this is not run
 896         ;;   any more anyway.   -sm
 897         ;;
 898         ;; (jit-lock-mode
 899         ;;  (jit-lock-after-unfontify-buffer))
 900         ((and (boundp 'lazy-lock-mode) lazy-lock-mode)
 901          (lazy-lock-after-unfontify-buffer))))
 902
 903 ;;; End of Font Lock Support mode.
 904 \f
 905 ;;; Fontification functions.
 906
 907 ;; Rather than the function, e.g., `font-lock-fontify-region' containing the
 908 ;; code to fontify a region, the function runs the function whose name is the
 909 ;; value of the variable, e.g., `font-lock-fontify-region-function'.  Normally,
 910 ;; the value of this variable is, e.g., `font-lock-default-fontify-region'
 911 ;; which does contain the code to fontify a region.  However, the value of the
 912 ;; variable could be anything and thus, e.g., `font-lock-fontify-region' could
 913 ;; do anything.  The indirection of the fontification functions gives major
 914 ;; modes the capability of modifying the way font-lock.el fontifies.  Major
 915 ;; modes can modify the values of, e.g., `font-lock-fontify-region-function',
 916 ;; via the variable `font-lock-defaults'.
 917 ;;
 918 ;; For example, Rmail mode sets the variable `font-lock-defaults' so that
 919 ;; font-lock.el uses its own function for buffer fontification.  This function
 920 ;; makes fontification be on a message-by-message basis and so visiting an
 921 ;; RMAIL file is much faster.  A clever implementation of the function might
 922 ;; fontify the headers differently than the message body.  (It should, and
 923 ;; correspondingly for Mail mode, but I can't be bothered to do the work.  Can
 924 ;; you?)  This hints at a more interesting use...
 925 ;;
 926 ;; Languages that contain text normally contained in different major modes
 927 ;; could define their own fontification functions that treat text differently
 928 ;; depending on its context.  For example, Perl mode could arrange that here
 929 ;; docs are fontified differently than Perl code.  Or Yacc mode could fontify
 930 ;; rules one way and C code another.  Neat!
 931 ;;
 932 ;; A further reason to use the fontification indirection feature is when the
 933 ;; default syntactual fontification, or the default fontification in general,
 934 ;; is not flexible enough for a particular major mode.  For example, perhaps
 935 ;; comments are just too hairy for `font-lock-fontify-syntactically-region' to
 936 ;; cope with.  You need to write your own version of that function, e.g.,
 937 ;; `hairy-fontify-syntactically-region', and make your own version of
 938 ;; `hairy-fontify-region' call that function before calling
 939 ;; `font-lock-fontify-keywords-region' for the normal regexp fontification
 940 ;; pass.  And Hairy mode would set `font-lock-defaults' so that font-lock.el
 941 ;; would call your region fontification function instead of its own.  For
 942 ;; example, TeX modes could fontify {\foo ...} and \bar{...}  etc. multi-line
 943 ;; directives correctly and cleanly.  (It is the same problem as fontifying
 944 ;; multi-line strings and comments; regexps are not appropriate for the job.)
 945
 946 ;;;###autoload
 947 (defun font-lock-fontify-buffer ()
 948   "Fontify the current buffer the way the function `font-lock-mode' would."
 949   (interactive)
 950   (let ((font-lock-verbose (or font-lock-verbose (interactive-p))))
 951     (funcall font-lock-fontify-buffer-function)))
 952
 953 (defun font-lock-unfontify-buffer ()
 954   (funcall font-lock-unfontify-buffer-function))
 955
 956 (defun font-lock-fontify-region (beg end &optional loudly)
 957   (funcall font-lock-fontify-region-function beg end loudly))
 958
 959 (defun font-lock-unfontify-region (beg end)
 960   (funcall font-lock-unfontify-region-function beg end))
 961
 962 (defun font-lock-default-fontify-buffer ()
 963   (let ((verbose (if (numberp font-lock-verbose)
 964                      (> (buffer-size) font-lock-verbose)
 965                    font-lock-verbose)))
 966     (with-temp-message
 967         (when verbose
 968           (format "Fontifying %s..." (buffer-name)))
 969       ;; Make sure we have the right `font-lock-keywords' etc.
 970       (unless font-lock-mode
 971         (font-lock-set-defaults))
 972       ;; Make sure we fontify etc. in the whole buffer.
 973       (save-restriction
 974         (widen)
 975         (condition-case nil
 976             (save-excursion
 977               (save-match-data
 978                 (font-lock-fontify-region (point-min) (point-max) verbose)
 979                 (font-lock-after-fontify-buffer)
 980                 (setq font-lock-fontified t)))
 981           ;; We don't restore the old fontification, so it's best to unfontify.
 982           (quit (font-lock-unfontify-buffer)))))))
 983
 984 (defun font-lock-default-unfontify-buffer ()
 985   ;; Make sure we unfontify etc. in the whole buffer.
 986   (save-restriction
 987     (widen)
 988     (font-lock-unfontify-region (point-min) (point-max))
 989     (font-lock-after-unfontify-buffer)
 990     (setq font-lock-fontified nil)))
 991
 992 (defvar font-lock-dont-widen nil
 993   "If non-nil, font-lock will work on the non-widened buffer.
 994 Useful for things like RMAIL and Info where the whole buffer is not
 995 a very meaningful entity to highlight.")
 996
 997 (defun font-lock-default-fontify-region (beg end loudly)
 998   (save-buffer-state
 999       ((parse-sexp-lookup-properties font-lock-syntactic-keywords)
1000        (old-syntax-table (syntax-table)))
1001     (unwind-protect
1002         (save-restriction
1003           (unless font-lock-dont-widen (widen))
1004           ;; Use the fontification syntax table, if any.
1005           (when font-lock-syntax-table
1006             (set-syntax-table font-lock-syntax-table))
1007           ;; check to see if we should expand the beg/end area for
1008           ;; proper multiline matches
1009           (when (and font-lock-multiline
1010                      (> beg (point-min))
1011                      (get-text-property (1- beg) 'font-lock-multiline))
1012             ;; We are just after or in a multiline match.
1013             (setq beg (or (previous-single-property-change
1014                            beg 'font-lock-multiline)
1015                           (point-min)))
1016             (goto-char beg)
1017             (setq beg (line-beginning-position)))
1018           (when font-lock-multiline
1019             (setq end (or (text-property-any end (point-max)
1020                                              'font-lock-multiline nil)
1021                           (point-max))))
1022           (goto-char end)
1023           (setq end (line-beginning-position 2))
1024           ;; Now do the fontification.
1025           (font-lock-unfontify-region beg end)
1026           (when font-lock-syntactic-keywords
1027             (font-lock-fontify-syntactic-keywords-region beg end))
1028           (unless font-lock-keywords-only
1029             (font-lock-fontify-syntactically-region beg end loudly))
1030           (font-lock-fontify-keywords-region beg end loudly))
1031       ;; Clean up.
1032       (set-syntax-table old-syntax-table))))
1033
1034 ;; The following must be rethought, since keywords can override fontification.
1035 ;      ;; Now scan for keywords, but not if we are inside a comment now.
1036 ;      (or (and (not font-lock-keywords-only)
1037 ;              (let ((state (parse-partial-sexp beg end nil nil
1038 ;                                               font-lock-cache-state)))
1039 ;                (or (nth 4 state) (nth 7 state))))
1040 ;         (font-lock-fontify-keywords-region beg end))
1041
1042 (defvar font-lock-extra-managed-props nil
1043   "Additional text properties managed by font-lock.
1044 This is used by `font-lock-default-unfontify-region' to decide
1045 what properties to clear before refontifying a region.")
1046
1047 (defun font-lock-default-unfontify-region (beg end)
1048   (save-buffer-state nil
1049     (remove-list-of-text-properties
1050      beg end (append
1051               font-lock-extra-managed-props
1052               (if font-lock-syntactic-keywords
1053                   '(syntax-table face font-lock-multiline)
1054                 '(face font-lock-multiline))))))
1055
1056 ;; Called when any modification is made to buffer text.
1057 (defun font-lock-after-change-function (beg end old-len)
1058   (let ((inhibit-point-motion-hooks t)
1059         (inhibit-quit t))
1060     (save-excursion
1061       (save-match-data
1062         ;; Rescan between start of lines enclosing the region.
1063         (font-lock-fontify-region
1064          (progn (goto-char beg) (beginning-of-line) (point))
1065          (progn (goto-char end) (forward-line 1) (point)))))))
1066
1067 (defun font-lock-fontify-block (&optional arg)
1068   "Fontify some lines the way `font-lock-fontify-buffer' would.
1069 The lines could be a function or paragraph, or a specified number of lines.
1070 If ARG is given, fontify that many lines before and after point, or 16 lines if
1071 no ARG is given and `font-lock-mark-block-function' is nil.
1072 If `font-lock-mark-block-function' non-nil and no ARG is given, it is used to
1073 delimit the region to fontify."
1074   (interactive "P")
1075   (let ((inhibit-point-motion-hooks t) font-lock-beginning-of-syntax-function
1076         deactivate-mark)
1077     ;; Make sure we have the right `font-lock-keywords' etc.
1078     (if (not font-lock-mode) (font-lock-set-defaults))
1079     (save-excursion
1080       (save-match-data
1081         (condition-case error-data
1082             (if (or arg (not font-lock-mark-block-function))
1083                 (let ((lines (if arg (prefix-numeric-value arg) 16)))
1084                   (font-lock-fontify-region
1085                    (save-excursion (forward-line (- lines)) (point))
1086                    (save-excursion (forward-line lines) (point))))
1087               (funcall font-lock-mark-block-function)
1088               (font-lock-fontify-region (point) (mark)))
1089           ((error quit) (message "Fontifying block...%s" error-data)))))))
1090
1091 (if (boundp 'facemenu-keymap)
1092     (define-key facemenu-keymap "\M-g" 'font-lock-fontify-block))
1093
1094 ;;; End of Fontification functions.
1095 \f
1096 ;;; Additional text property functions.
1097
1098 ;; The following text property functions should be builtins.  This means they
1099 ;; should be written in C and put with all the other text property functions.
1100 ;; In the meantime, those that are used by font-lock.el are defined in Lisp
1101 ;; below and given a `font-lock-' prefix.  Those that are not used are defined
1102 ;; in Lisp below and commented out.  sm.
1103
1104 (defun font-lock-prepend-text-property (start end prop value &optional object)
1105   "Prepend to one property of the text from START to END.
1106 Arguments PROP and VALUE specify the property and value to prepend to the value
1107 already in place.  The resulting property values are always lists.
1108 Optional argument OBJECT is the string or buffer containing the text."
1109   (let ((val (if (listp value) value (list value))) next prev)
1110     (while (/= start end)
1111       (setq next (next-single-property-change start prop object end)
1112             prev (get-text-property start prop object))
1113       (put-text-property start next prop
1114                          (append val (if (listp prev) prev (list prev)))
1115                          object)
1116       (setq start next))))
1117
1118 (defun font-lock-append-text-property (start end prop value &optional object)
1119   "Append to one property of the text from START to END.
1120 Arguments PROP and VALUE specify the property and value to append to the value
1121 already in place.  The resulting property values are always lists.
1122 Optional argument OBJECT is the string or buffer containing the text."
1123   (let ((val (if (listp value) value (list value))) next prev)
1124     (while (/= start end)
1125       (setq next (next-single-property-change start prop object end)
1126             prev (get-text-property start prop object))
1127       (put-text-property start next prop
1128                          (append (if (listp prev) prev (list prev)) val)
1129                          object)
1130       (setq start next))))
1131
1132 (defun font-lock-fillin-text-property (start end prop value &optional object)
1133   "Fill in one property of the text from START to END.
1134 Arguments PROP and VALUE specify the property and value to put where none are
1135 already in place.  Therefore existing property values are not overwritten.
1136 Optional argument OBJECT is the string or buffer containing the text."
1137   (let ((start (text-property-any start end prop nil object)) next)
1138     (while start
1139       (setq next (next-single-property-change start prop object end))
1140       (put-text-property start next prop value object)
1141       (setq start (text-property-any next end prop nil object)))))
1142
1143 ;; For completeness: this is to `remove-text-properties' as `put-text-property'
1144 ;; is to `add-text-properties', etc.
1145 ;(defun remove-text-property (start end property &optional object)
1146 ;  "Remove a property from text from START to END.
1147 ;Argument PROPERTY is the property to remove.
1148 ;Optional argument OBJECT is the string or buffer containing the text.
1149 ;Return t if the property was actually removed, nil otherwise."
1150 ;  (remove-text-properties start end (list property) object))
1151
1152 ;; For consistency: maybe this should be called `remove-single-property' like
1153 ;; `next-single-property-change' (not `next-single-text-property-change'), etc.
1154 ;(defun remove-single-text-property (start end prop value &optional object)
1155 ;  "Remove a specific property value from text from START to END.
1156 ;Arguments PROP and VALUE specify the property and value to remove.  The
1157 ;resulting property values are not equal to VALUE nor lists containing VALUE.
1158 ;Optional argument OBJECT is the string or buffer containing the text."
1159 ;  (let ((start (text-property-not-all start end prop nil object)) next prev)
1160 ;    (while start
1161 ;      (setq next (next-single-property-change start prop object end)
1162 ;           prev (get-text-property start prop object))
1163 ;      (cond ((and (symbolp prev) (eq value prev))
1164 ;            (remove-text-property start next prop object))
1165 ;           ((and (listp prev) (memq value prev))
1166 ;            (let ((new (delq value prev)))
1167 ;              (cond ((null new)
1168 ;                     (remove-text-property start next prop object))
1169 ;                    ((= (length new) 1)
1170 ;                     (put-text-property start next prop (car new) object))
1171 ;                    (t
1172 ;                     (put-text-property start next prop new object))))))
1173 ;      (setq start (text-property-not-all next end prop nil object)))))
1174
1175 ;;; End of Additional text property functions.
1176 \f
1177 ;;; Syntactic regexp fontification functions.
1178
1179 ;; These syntactic keyword pass functions are identical to those keyword pass
1180 ;; functions below, with the following exceptions; (a) they operate on
1181 ;; `font-lock-syntactic-keywords' of course, (b) they are all `defun' as speed
1182 ;; is less of an issue, (c) eval of property value does not occur JIT as speed
1183 ;; is less of an issue, (d) OVERRIDE cannot be `prepend' or `append' as it
1184 ;; makes no sense for `syntax-table' property values, (e) they do not do it
1185 ;; LOUDLY as it is not likely to be intensive.
1186
1187 (defun font-lock-apply-syntactic-highlight (highlight)
1188   "Apply HIGHLIGHT following a match.
1189 HIGHLIGHT should be of the form MATCH-HIGHLIGHT,
1190 see `font-lock-syntactic-keywords'."
1191   (let* ((match (nth 0 highlight))
1192          (start (match-beginning match)) (end (match-end match))
1193          (value (nth 1 highlight))
1194          (override (nth 2 highlight)))
1195     (if (not start)
1196         ;; No match but we might not signal an error.
1197         (or (nth 3 highlight)
1198             (error "No match %d in highlight %S" match highlight))
1199       (when (and (consp value) (not (numberp (car value))))
1200         (setq value (eval value)))
1201       (when (stringp value) (setq value (string-to-syntax value)))
1202       ;; Flush the syntax-cache.  I believe this is not necessary for
1203       ;; font-lock's use of syntax-ppss, but I'm not 100% sure and it can
1204       ;; still be necessary for other users of syntax-ppss anyway.
1205       (syntax-ppss-after-change-function start)
1206       (cond
1207        ((not override)
1208         ;; Cannot override existing fontification.
1209         (or (text-property-not-all start end 'syntax-table nil)
1210             (put-text-property start end 'syntax-table value)))
1211        ((eq override t)
1212         ;; Override existing fontification.
1213         (put-text-property start end 'syntax-table value))
1214        ((eq override 'keep)
1215         ;; Keep existing fontification.
1216         (font-lock-fillin-text-property start end 'syntax-table value))))))
1217
1218 (defun font-lock-fontify-syntactic-anchored-keywords (keywords limit)
1219   "Fontify according to KEYWORDS until LIMIT.
1220 KEYWORDS should be of the form MATCH-ANCHORED, see `font-lock-keywords',
1221 LIMIT can be modified by the value of its PRE-MATCH-FORM."
1222   (let ((matcher (nth 0 keywords)) (lowdarks (nthcdr 3 keywords)) highlights
1223         ;; Evaluate PRE-MATCH-FORM.
1224         (pre-match-value (eval (nth 1 keywords))))
1225     ;; Set LIMIT to value of PRE-MATCH-FORM or the end of line.
1226     (if (and (numberp pre-match-value) (> pre-match-value (point)))
1227         (setq limit pre-match-value)
1228       (setq limit (line-end-position)))
1229     (save-match-data
1230       ;; Find an occurrence of `matcher' before `limit'.
1231       (while (if (stringp matcher)
1232                  (re-search-forward matcher limit t)
1233                (funcall matcher limit))
1234         ;; Apply each highlight to this instance of `matcher'.
1235         (setq highlights lowdarks)
1236         (while highlights
1237           (font-lock-apply-syntactic-highlight (car highlights))
1238           (setq highlights (cdr highlights)))))
1239     ;; Evaluate POST-MATCH-FORM.
1240     (eval (nth 2 keywords))))
1241
1242 (defun font-lock-fontify-syntactic-keywords-region (start end)
1243   "Fontify according to `font-lock-syntactic-keywords' between START and END.
1244 START should be at the beginning of a line."
1245   ;; Ensure the beginning of the file is properly syntactic-fontified.
1246   (when (and font-lock-syntactically-fontified
1247              (< font-lock-syntactically-fontified start))
1248     (setq start (max font-lock-syntactically-fontified (point-min)))
1249     (setq font-lock-syntactically-fontified end))
1250   ;; If `font-lock-syntactic-keywords' is a symbol, get the real keywords.
1251   (when (symbolp font-lock-syntactic-keywords)
1252     (setq font-lock-syntactic-keywords (font-lock-eval-keywords
1253                                         font-lock-syntactic-keywords)))
1254   ;; If `font-lock-syntactic-keywords' is not compiled, compile it.
1255   (unless (eq (car font-lock-syntactic-keywords) t)
1256     (setq font-lock-syntactic-keywords (font-lock-compile-keywords
1257                                         font-lock-syntactic-keywords)))
1258   ;; Get down to business.
1259   (let ((case-fold-search font-lock-keywords-case-fold-search)
1260         (keywords (cdr font-lock-syntactic-keywords))
1261         keyword matcher highlights)
1262     (while keywords
1263       ;; Find an occurrence of `matcher' from `start' to `end'.
1264       (setq keyword (car keywords) matcher (car keyword))
1265       (goto-char start)
1266       (while (if (stringp matcher)
1267                  (re-search-forward matcher end t)
1268                (funcall matcher end))
1269         ;; Apply each highlight to this instance of `matcher', which may be
1270         ;; specific highlights or more keywords anchored to `matcher'.
1271         (setq highlights (cdr keyword))
1272         (while highlights
1273           (if (numberp (car (car highlights)))
1274               (font-lock-apply-syntactic-highlight (car highlights))
1275             (font-lock-fontify-syntactic-anchored-keywords (car highlights)
1276                                                            end))
1277           (setq highlights (cdr highlights))))
1278       (setq keywords (cdr keywords)))))
1279
1280 ;;; End of Syntactic regexp fontification functions.
1281 \f
1282 ;;; Syntactic fontification functions.
1283
1284 (defun font-lock-fontify-syntactically-region (start end &optional loudly ppss)
1285   "Put proper face on each string and comment between START and END.
1286 START should be at the beginning of a line."
1287   (let (state face beg)
1288     (if loudly (message "Fontifying %s... (syntactically...)" (buffer-name)))
1289     (goto-char start)
1290     ;;
1291     ;; Find the state at the `beginning-of-line' before `start'.
1292     (setq state (or ppss (syntax-ppss start)))
1293     ;;
1294     ;; Find each interesting place between here and `end'.
1295     (while
1296         (progn
1297           (when (or (nth 3 state) (nth 4 state))
1298             (setq face (funcall font-lock-syntactic-face-function state))
1299             (setq beg (max (nth 8 state) start))
1300             (setq state (parse-partial-sexp (point) end nil nil state
1301                                             'syntax-table))
1302             (when face (put-text-property beg (point) 'face face)))
1303           (setq state (parse-partial-sexp (point) end nil nil state
1304                                           'syntax-table))
1305           (< (point) end)))))
1306
1307 ;;; End of Syntactic fontification functions.
1308 \f
1309 ;;; Keyword regexp fontification functions.
1310
1311 (defsubst font-lock-apply-highlight (highlight)
1312   "Apply HIGHLIGHT following a match.
1313 HIGHLIGHT should be of the form MATCH-HIGHLIGHT, see `font-lock-keywords'."
1314   (let* ((match (nth 0 highlight))
1315          (start (match-beginning match)) (end (match-end match))
1316          (override (nth 2 highlight)))
1317     (if (not start)
1318         ;; No match but we might not signal an error.
1319         (or (nth 3 highlight)
1320             (error "No match %d in highlight %S" match highlight))
1321       (let ((val (eval (nth 1 highlight))))
1322         (when (eq (car-safe val) 'face)
1323           (add-text-properties start end (cddr val))
1324           (setq val (cadr val)))
1325         (cond
1326          ((not override)
1327           ;; Cannot override existing fontification.
1328           (or (text-property-not-all start end 'face nil)
1329               (put-text-property start end 'face val)))
1330          ((eq override t)
1331           ;; Override existing fontification.
1332           (put-text-property start end 'face val))
1333          ((eq override 'prepend)
1334           ;; Prepend to existing fontification.
1335           (font-lock-prepend-text-property start end 'face val))
1336          ((eq override 'append)
1337           ;; Append to existing fontification.
1338           (font-lock-append-text-property start end 'face val))
1339          ((eq override 'keep)
1340           ;; Keep existing fontification.
1341           (font-lock-fillin-text-property start end 'face val)))))))
1342
1343 (defsubst font-lock-fontify-anchored-keywords (keywords limit)
1344   "Fontify according to KEYWORDS until LIMIT.
1345 KEYWORDS should be of the form MATCH-ANCHORED, see `font-lock-keywords',
1346 LIMIT can be modified by the value of its PRE-MATCH-FORM."
1347   (let ((matcher (nth 0 keywords)) (lowdarks (nthcdr 3 keywords)) highlights
1348         (lead-start (match-beginning 0))
1349         ;; Evaluate PRE-MATCH-FORM.
1350         (pre-match-value (eval (nth 1 keywords))))
1351     ;; Set LIMIT to value of PRE-MATCH-FORM or the end of line.
1352     (if (not (and (numberp pre-match-value) (> pre-match-value (point))))
1353         (setq limit (line-end-position))
1354       (setq limit pre-match-value)
1355       (when (and font-lock-multiline (>= limit (line-beginning-position 2)))
1356         ;; this is a multiline anchored match
1357         ;; (setq font-lock-multiline t)
1358         (put-text-property (if (= limit (line-beginning-position 2))
1359                                (1- limit)
1360                              (min lead-start (point)))
1361                            limit
1362                            'font-lock-multiline t)))
1363     (save-match-data
1364       ;; Find an occurrence of `matcher' before `limit'.
1365       (while (and (< (point) limit)
1366                   (if (stringp matcher)
1367                       (re-search-forward matcher limit t)
1368                     (funcall matcher limit)))
1369         ;; Apply each highlight to this instance of `matcher'.
1370         (setq highlights lowdarks)
1371         (while highlights
1372           (font-lock-apply-highlight (car highlights))
1373           (setq highlights (cdr highlights)))))
1374     ;; Evaluate POST-MATCH-FORM.
1375     (eval (nth 2 keywords))))
1376
1377 (defun font-lock-fontify-keywords-region (start end &optional loudly)
1378   "Fontify according to `font-lock-keywords' between START and END.
1379 START should be at the beginning of a line.
1380 LOUDLY, if non-nil, allows progress-meter bar."
1381   (unless (eq (car font-lock-keywords) t)
1382     (setq font-lock-keywords
1383           (font-lock-compile-keywords font-lock-keywords t)))
1384   (let ((case-fold-search font-lock-keywords-case-fold-search)
1385         (keywords (cddr font-lock-keywords))
1386         (bufname (buffer-name)) (count 0)
1387         keyword matcher highlights)
1388     ;;
1389     ;; Fontify each item in `font-lock-keywords' from `start' to `end'.
1390     (while keywords
1391       (if loudly (message "Fontifying %s... (regexps..%s)" bufname
1392                           (make-string (incf count) ?.)))
1393       ;;
1394       ;; Find an occurrence of `matcher' from `start' to `end'.
1395       (setq keyword (car keywords) matcher (car keyword))
1396       (goto-char start)
1397       (while (and (< (point) end)
1398                   (if (stringp matcher)
1399                       (re-search-forward matcher end t)
1400                     (funcall matcher end)))
1401         (when (and font-lock-multiline
1402                    (>= (point)
1403                        (save-excursion (goto-char (match-beginning 0))
1404                                        (forward-line 1) (point))))
1405           ;; this is a multiline regexp match
1406           ;; (setq font-lock-multiline t)
1407           (put-text-property (if (= (point)
1408                                     (save-excursion
1409                                       (goto-char (match-beginning 0))
1410                                       (forward-line 1) (point)))
1411                                  (1- (point))
1412                                (match-beginning 0))
1413                              (point)
1414                              'font-lock-multiline t))
1415         ;; Apply each highlight to this instance of `matcher', which may be
1416         ;; specific highlights or more keywords anchored to `matcher'.
1417         (setq highlights (cdr keyword))
1418         (while highlights
1419           (if (numberp (car (car highlights)))
1420               (font-lock-apply-highlight (car highlights))
1421             (font-lock-fontify-anchored-keywords (car highlights) end))
1422           (setq highlights (cdr highlights))))
1423       (setq keywords (cdr keywords)))))
1424
1425 ;;; End of Keyword regexp fontification functions.
1426 \f
1427 ;; Various functions.
1428
1429 (defun font-lock-compile-keywords (keywords &optional regexp)
1430   "Compile KEYWORDS into the form (t KEYWORDS COMPILED...)
1431 Here each COMPILED is of the form (MATCHER HIGHLIGHT ...) as shown in the
1432 `font-lock-keywords' doc string.
1433 If REGEXP is non-nil, it means these keywords are used for
1434 `font-lock-keywords' rather than for `font-lock-syntactic-keywords'."
1435   (if (eq (car-safe keywords) t)
1436       keywords
1437     (setq keywords
1438           (cons t (cons keywords
1439                         (mapcar 'font-lock-compile-keyword keywords))))
1440     (if (and regexp
1441              (eq (or syntax-begin-function
1442                      font-lock-beginning-of-syntax-function)
1443                  'beginning-of-defun)
1444              (not beginning-of-defun-function))
1445         ;; Try to detect when a string or comment contains something that
1446         ;; looks like a defun and would thus confuse font-lock.
1447         (nconc keywords
1448                `((,(if defun-prompt-regexp
1449                        (concat "^\\(?:" defun-prompt-regexp "\\)?\\s(")
1450                      "^\\s(")
1451                   (0
1452                    (if (memq (get-text-property (1- (point)) 'face)
1453                              '(font-lock-string-face font-lock-doc-face
1454                                font-lock-comment-face))
1455                        font-lock-warning-face)
1456                    prepend)))))
1457     keywords))
1458
1459 (defun font-lock-compile-keyword (keyword)
1460   (cond ((nlistp keyword)                       ; MATCHER
1461          (list keyword '(0 font-lock-keyword-face)))
1462         ((eq (car keyword) 'eval)               ; (eval . FORM)
1463          (font-lock-compile-keyword (eval (cdr keyword))))
1464         ((eq (car-safe (cdr keyword)) 'quote)   ; (MATCHER . 'FORM)
1465          ;; If FORM is a FACENAME then quote it.  Otherwise ignore the quote.
1466          (if (symbolp (nth 2 keyword))
1467              (list (car keyword) (list 0 (cdr keyword)))
1468            (font-lock-compile-keyword (cons (car keyword) (nth 2 keyword)))))
1469         ((numberp (cdr keyword))                ; (MATCHER . MATCH)
1470          (list (car keyword) (list (cdr keyword) 'font-lock-keyword-face)))
1471         ((symbolp (cdr keyword))                ; (MATCHER . FACENAME)
1472          (list (car keyword) (list 0 (cdr keyword))))
1473         ((nlistp (nth 1 keyword))               ; (MATCHER . HIGHLIGHT)
1474          (list (car keyword) (cdr keyword)))
1475         (t                                      ; (MATCHER HIGHLIGHT ...)
1476          keyword)))
1477
1478 (defun font-lock-eval-keywords (keywords)
1479   "Evalulate KEYWORDS if a function (funcall) or variable (eval) name."
1480   (if (listp keywords)
1481       keywords
1482     (font-lock-eval-keywords (if (fboundp keywords)
1483                                  (funcall keywords)
1484                                (eval keywords)))))
1485
1486 (defun font-lock-value-in-major-mode (alist)
1487   "Return value in ALIST for `major-mode', or ALIST if it is not an alist.
1488 Structure is ((MAJOR-MODE . VALUE) ...) where MAJOR-MODE may be t."
1489   (if (consp alist)
1490       (cdr (or (assq major-mode alist) (assq t alist)))
1491     alist))
1492
1493 (defun font-lock-choose-keywords (keywords level)
1494   "Return LEVELth element of KEYWORDS.
1495 A LEVEL of nil is equal to a LEVEL of 0, a LEVEL of t is equal to
1496 \(1- (length KEYWORDS))."
1497   (cond ((not (and (listp keywords) (symbolp (car keywords))))
1498          keywords)
1499         ((numberp level)
1500          (or (nth level keywords) (car (reverse keywords))))
1501         ((eq level t)
1502          (car (reverse keywords)))
1503         (t
1504          (car keywords))))
1505
1506 (defvar font-lock-set-defaults nil)     ; Whether we have set up defaults.
1507
1508 (defun font-lock-set-defaults ()
1509   "Set fontification defaults appropriately for this mode.
1510 Sets various variables using `font-lock-defaults' (or, if nil, using
1511 `font-lock-defaults-alist') and `font-lock-maximum-decoration'."
1512   ;; Set fontification defaults iff not previously set.
1513   (unless font-lock-set-defaults
1514     (set (make-local-variable 'font-lock-set-defaults) t)
1515     (make-local-variable 'font-lock-fontified)
1516     (make-local-variable 'font-lock-multiline)
1517     (let* ((defaults (or font-lock-defaults
1518                          (cdr (assq major-mode font-lock-defaults-alist))))
1519            (keywords
1520             (font-lock-choose-keywords (nth 0 defaults)
1521                                        (font-lock-value-in-major-mode font-lock-maximum-decoration)))
1522            (local (cdr (assq major-mode font-lock-keywords-alist)))
1523            (removed-keywords
1524             (cdr-safe (assq major-mode font-lock-removed-keywords-alist))))
1525       (set (make-local-variable 'font-lock-defaults) defaults)
1526       ;; Syntactic fontification?
1527       (when (nth 1 defaults)
1528         (set (make-local-variable 'font-lock-keywords-only) t))
1529       ;; Case fold during regexp fontification?
1530       (when (nth 2 defaults)
1531         (set (make-local-variable 'font-lock-keywords-case-fold-search) t))
1532       ;; Syntax table for regexp and syntactic fontification?
1533       (when (nth 3 defaults)
1534         (set (make-local-variable 'font-lock-syntax-table)
1535              (copy-syntax-table (syntax-table)))
1536         (dolist (selem (nth 3 defaults))
1537           ;; The character to modify may be a single CHAR or a STRING.
1538           (let ((syntax (cdr selem)))
1539             (dolist (char (if (numberp (car selem))
1540                               (list (car selem))
1541                             (mapcar 'identity (car selem))))
1542               (modify-syntax-entry char syntax font-lock-syntax-table)))))
1543       ;; Syntax function for syntactic fontification?
1544       (when (nth 4 defaults)
1545         (set (make-local-variable 'font-lock-beginning-of-syntax-function)
1546              (nth 4 defaults)))
1547       ;; Variable alist?
1548       (dolist (x (nthcdr 5 defaults))
1549         (set (make-local-variable (car x)) (cdr x)))
1550       ;; Set up `font-lock-keywords' last because its value might depend
1551       ;; on other settings (e.g. font-lock-compile-keywords uses
1552       ;; font-lock-beginning-of-syntax-function).
1553       (set (make-local-variable 'font-lock-keywords)
1554            (font-lock-eval-keywords keywords))
1555       ;; Local fontification?
1556       (while local
1557         (font-lock-add-keywords nil (car (car local)) (cdr (car local)))
1558         (setq local (cdr local)))
1559       (when removed-keywords
1560         (font-lock-remove-keywords nil removed-keywords))
1561       ;; Now compile the keywords.
1562       (unless (eq (car font-lock-keywords) t)
1563         (set (make-local-variable 'font-lock-keywords)
1564              (font-lock-compile-keywords font-lock-keywords t))))))
1565 \f
1566 ;;; Colour etc. support.
1567
1568 ;; Originally face attributes were specified via `font-lock-face-attributes'.
1569 ;; Users then changed the default face attributes by setting that variable.
1570 ;; However, we try and be back-compatible and respect its value if set except
1571 ;; for faces where M-x customize has been used to save changes for the face.
1572 (when (boundp 'font-lock-face-attributes)
1573   (let ((face-attributes font-lock-face-attributes))
1574     (while face-attributes
1575       (let* ((face-attribute (pop face-attributes))
1576              (face (car face-attribute)))
1577         ;; Rustle up a `defface' SPEC from a `font-lock-face-attributes' entry.
1578         (unless (get face 'saved-face)
1579           (let ((foreground (nth 1 face-attribute))
1580                 (background (nth 2 face-attribute))
1581                 (bold-p (nth 3 face-attribute))
1582                 (italic-p (nth 4 face-attribute))
1583                 (underline-p (nth 5 face-attribute))
1584                 face-spec)
1585             (when foreground
1586               (setq face-spec (cons ':foreground (cons foreground face-spec))))
1587             (when background
1588               (setq face-spec (cons ':background (cons background face-spec))))
1589             (when bold-p
1590               (setq face-spec (append '(:weight bold) face-spec)))
1591             (when italic-p
1592               (setq face-spec (append '(:slant italic) face-spec)))
1593             (when underline-p
1594               (setq face-spec (append '(:underline t) face-spec)))
1595             (custom-declare-face face (list (list t face-spec)) nil)))))))
1596
1597 ;; But now we do it the custom way.  Note that `defface' will not overwrite any
1598 ;; faces declared above via `custom-declare-face'.
1599 (defface font-lock-comment-face
1600   '((((class grayscale) (background light))
1601      (:foreground "DimGray" :weight bold :slant italic))
1602     (((class grayscale) (background dark))
1603      (:foreground "LightGray" :weight bold :slant italic))
1604     (((class color) (min-colors 88) (background light))
1605      (:foreground "Firebrick"))
1606     (((class color) (min-colors 88) (background dark))
1607      (:foreground "chocolate1"))
1608     (((class color) (min-colors 16) (background light))
1609      (:foreground "red"))
1610     (((class color) (min-colors 16) (background dark))
1611      (:foreground "red1"))
1612     (((class color) (min-colors 8) (background light))
1613      (:foreground "red"))
1614     (((class color) (min-colors 8) (background dark))
1615      (:foreground "red1"))
1616     (t (:weight bold :slant italic)))
1617   "Font Lock mode face used to highlight comments."
1618   :group 'font-lock-highlighting-faces)
1619
1620 (defface font-lock-string-face
1621   '((((class grayscale) (background light)) (:foreground "DimGray" :slant italic))
1622     (((class grayscale) (background dark)) (:foreground "LightGray" :slant italic))
1623     (((class color) (min-colors 88) (background light)) (:foreground "RosyBrown"))
1624     (((class color) (min-colors 88) (background dark)) (:foreground "LightSalmon"))
1625     (((class color) (min-colors 16) (background light)) (:foreground "RosyBrown"))
1626     (((class color) (min-colors 16) (background dark)) (:foreground "LightSalmon"))
1627     (((class color) (min-colors 8)) (:foreground "green"))
1628     (t (:slant italic)))
1629   "Font Lock mode face used to highlight strings."
1630   :group 'font-lock-highlighting-faces)
1631
1632 (defface font-lock-doc-face
1633   '((t :inherit font-lock-string-face))
1634   "Font Lock mode face used to highlight documentation."
1635   :group 'font-lock-highlighting-faces)
1636
1637 (defface font-lock-keyword-face
1638   '((((class grayscale) (background light)) (:foreground "LightGray" :weight bold))
1639     (((class grayscale) (background dark)) (:foreground "DimGray" :weight bold))
1640     (((class color) (min-colors 88) (background light)) (:foreground "Purple"))
1641     (((class color) (min-colors 88) (background dark)) (:foreground "Cyan"))
1642     (((class color) (min-colors 16) (background light)) (:foreground "Purple"))
1643     (((class color) (min-colors 16) (background dark)) (:foreground "Cyan"))
1644     (((class color) (min-colors 8)) (:foreground "cyan" :weight bold))
1645     (t (:weight bold)))
1646   "Font Lock mode face used to highlight keywords."
1647   :group 'font-lock-highlighting-faces)
1648
1649 (defface font-lock-builtin-face
1650   '((((class grayscale) (background light)) (:foreground "LightGray" :weight bold))
1651     (((class grayscale) (background dark)) (:foreground "DimGray" :weight bold))
1652     (((class color) (min-colors 88) (background light)) (:foreground "Orchid"))
1653     (((class color) (min-colors 88) (background dark)) (:foreground "LightSteelBlue"))
1654     (((class color) (min-colors 16) (background light)) (:foreground "Orchid"))
1655     (((class color) (min-colors 16) (background dark)) (:foreground "LightSteelBlue"))
1656     (((class color) (min-colors 8)) (:foreground "blue" :weight bold))
1657     (t (:weight bold)))
1658   "Font Lock mode face used to highlight builtins."
1659   :group 'font-lock-highlighting-faces)
1660
1661 (defface font-lock-function-name-face
1662   '((((class color) (min-colors 88) (background light)) (:foreground "Blue"))
1663     (((class color) (min-colors 88) (background dark)) (:foreground "LightSkyBlue"))
1664     (((class color) (min-colors 16) (background light)) (:foreground "Blue"))
1665     (((class color) (min-colors 16) (background dark)) (:foreground "LightSkyBlue"))
1666     (((class color) (min-colors 8)) (:foreground "blue" :weight bold))
1667     (t (:inverse-video t :weight bold)))
1668   "Font Lock mode face used to highlight function names."
1669   :group 'font-lock-highlighting-faces)
1670
1671 (defface font-lock-variable-name-face
1672   '((((class grayscale) (background light))
1673      (:foreground "Gray90" :weight bold :slant italic))
1674     (((class grayscale) (background dark))
1675      (:foreground "DimGray" :weight bold :slant italic))
1676     (((class color) (min-colors 88) (background light)) (:foreground "DarkGoldenrod"))
1677     (((class color) (min-colors 88) (background dark)) (:foreground "LightGoldenrod"))
1678     (((class color) (min-colors 16) (background light)) (:foreground "DarkGoldenrod"))
1679     (((class color) (min-colors 16) (background dark)) (:foreground "LightGoldenrod"))
1680     (((class color) (min-colors 8)) (:foreground "yellow" :weight light))
1681     (t (:weight bold :slant italic)))
1682   "Font Lock mode face used to highlight variable names."
1683   :group 'font-lock-highlighting-faces)
1684
1685 (defface font-lock-type-face
1686   '((((class grayscale) (background light)) (:foreground "Gray90" :weight bold))
1687     (((class grayscale) (background dark)) (:foreground "DimGray" :weight bold))
1688     (((class color) (min-colors 88) (background light)) (:foreground "ForestGreen"))
1689     (((class color) (min-colors 88) (background dark)) (:foreground "PaleGreen"))
1690     (((class color) (min-colors 16) (background light)) (:foreground "ForestGreen"))
1691     (((class color) (min-colors 16) (background dark)) (:foreground "PaleGreen"))
1692     (((class color) (min-colors 8)) (:foreground "green"))
1693     (t (:weight bold :underline t)))
1694   "Font Lock mode face used to highlight type and classes."
1695   :group 'font-lock-highlighting-faces)
1696
1697 (defface font-lock-constant-face
1698   '((((class grayscale) (background light))
1699      (:foreground "LightGray" :weight bold :underline t))
1700     (((class grayscale) (background dark))
1701      (:foreground "Gray50" :weight bold :underline t))
1702     (((class color) (min-colors 88) (background light)) (:foreground "CadetBlue"))
1703     (((class color) (min-colors 88) (background dark)) (:foreground "Aquamarine"))
1704     (((class color) (min-colors 16) (background light)) (:foreground "CadetBlue"))
1705     (((class color) (min-colors 16) (background dark)) (:foreground "Aquamarine"))
1706     (((class color) (min-colors 8)) (:foreground "magenta"))
1707     (t (:weight bold :underline t)))
1708   "Font Lock mode face used to highlight constants and labels."
1709   :group 'font-lock-highlighting-faces)
1710
1711 (defface font-lock-warning-face
1712   '((((class color) (min-colors 88) (background light)) (:foreground "Red" :weight bold))
1713     (((class color) (min-colors 88) (background dark)) (:foreground "Pink" :weight bold))
1714     (((class color) (min-colors 16) (background light)) (:foreground "Red" :weight bold))
1715     (((class color) (min-colors 16) (background dark)) (:foreground "Pink" :weight bold))
1716     (((class color) (min-colors 8)) (:foreground "red"))
1717     (t (:inverse-video t :weight bold)))
1718   "Font Lock mode face used to highlight warnings."
1719   :group 'font-lock-highlighting-faces)
1720
1721 (defface font-lock-preprocessor-face
1722   '((t :inherit font-lock-builtin-face))
1723   "Font Lock mode face used to highlight preprocessor directives."
1724   :group 'font-lock-highlighting-faces)
1725
1726 ;;; End of Colour etc. support.
1727 \f
1728 ;;; Menu support.
1729
1730 ;; This section of code is commented out because Emacs does not have real menu
1731 ;; buttons.  (We can mimic them by putting "( ) " or "(X) " at the beginning of
1732 ;; the menu entry text, but with Xt it looks both ugly and embarrassingly
1733 ;; amateur.)  If/When Emacs gets real menus buttons, put in menu-bar.el after
1734 ;; the entry for "Text Properties" something like:
1735 ;;
1736 ;; (define-key menu-bar-edit-menu [font-lock]
1737 ;;   (cons "Syntax Highlighting" font-lock-menu))
1738 ;;
1739 ;; and remove a single ";" from the beginning of each line in the rest of this
1740 ;; section.  Probably the mechanism for telling the menu code what are menu
1741 ;; buttons and when they are on or off needs tweaking.  I have assumed that the
1742 ;; mechanism is via `menu-toggle' and `menu-selected' symbol properties.  sm.
1743
1744 ;;;;###autoload
1745 ;(progn
1746 ;  ;; Make the Font Lock menu.
1747 ;  (defvar font-lock-menu (make-sparse-keymap "Syntax Highlighting"))
1748 ;  ;; Add the menu items in reverse order.
1749 ;  (define-key font-lock-menu [fontify-less]
1750 ;    '("Less In Current Buffer" . font-lock-fontify-less))
1751 ;  (define-key font-lock-menu [fontify-more]
1752 ;    '("More In Current Buffer" . font-lock-fontify-more))
1753 ;  (define-key font-lock-menu [font-lock-sep]
1754 ;    '("--"))
1755 ;  (define-key font-lock-menu [font-lock-mode]
1756 ;    '("In Current Buffer" . font-lock-mode))
1757 ;  (define-key font-lock-menu [global-font-lock-mode]
1758 ;    '("In All Buffers" . global-font-lock-mode)))
1759 ;
1760 ;;;;###autoload
1761 ;(progn
1762 ;  ;; We put the appropriate `menu-enable' etc. symbol property values on when
1763 ;  ;; font-lock.el is loaded, so we don't need to autoload the three variables.
1764 ;  (put 'global-font-lock-mode 'menu-toggle t)
1765 ;  (put 'font-lock-mode 'menu-toggle t)
1766 ;  (put 'font-lock-fontify-more 'menu-enable '(identity))
1767 ;  (put 'font-lock-fontify-less 'menu-enable '(identity)))
1768 ;
1769 ;;; Put the appropriate symbol property values on now.  See above.
1770 ;(put 'global-font-lock-mode 'menu-selected 'global-font-lock-mode)
1771 ;(put 'font-lock-mode 'menu-selected 'font-lock-mode)
1772 ;(put 'font-lock-fontify-more 'menu-enable '(nth 2 font-lock-fontify-level))
1773 ;(put 'font-lock-fontify-less 'menu-enable '(nth 1 font-lock-fontify-level))
1774 ;
1775 ;(defvar font-lock-fontify-level nil)   ; For less/more fontification.
1776 ;
1777 ;(defun font-lock-fontify-level (level)
1778 ;  (let ((font-lock-maximum-decoration level))
1779 ;    (when font-lock-mode
1780 ;      (font-lock-mode))
1781 ;    (font-lock-mode)
1782 ;    (when font-lock-verbose
1783 ;      (message "Fontifying %s... level %d" (buffer-name) level))))
1784 ;
1785 ;(defun font-lock-fontify-less ()
1786 ;  "Fontify the current buffer with less decoration.
1787 ;See `font-lock-maximum-decoration'."
1788 ;  (interactive)
1789 ;  ;; Check in case we get called interactively.
1790 ;  (if (nth 1 font-lock-fontify-level)
1791 ;      (font-lock-fontify-level (1- (car font-lock-fontify-level)))
1792 ;    (error "No less decoration")))
1793 ;
1794 ;(defun font-lock-fontify-more ()
1795 ;  "Fontify the current buffer with more decoration.
1796 ;See `font-lock-maximum-decoration'."
1797 ;  (interactive)
1798 ;  ;; Check in case we get called interactively.
1799 ;  (if (nth 2 font-lock-fontify-level)
1800 ;      (font-lock-fontify-level (1+ (car font-lock-fontify-level)))
1801 ;    (error "No more decoration")))
1802 ;
1803 ;;; This should be called by `font-lock-set-defaults'.
1804 ;(defun font-lock-set-menu ()
1805 ;  ;; Activate less/more fontification entries if there are multiple levels for
1806 ;  ;; the current buffer.  Sets `font-lock-fontify-level' to be of the form
1807 ;  ;; (CURRENT-LEVEL IS-LOWER-LEVEL-P IS-HIGHER-LEVEL-P) for menu activation.
1808 ;  (let ((keywords (or (nth 0 font-lock-defaults)
1809 ;                     (nth 1 (assq major-mode font-lock-defaults-alist))))
1810 ;       (level (font-lock-value-in-major-mode font-lock-maximum-decoration)))
1811 ;    (make-local-variable 'font-lock-fontify-level)
1812 ;    (if (or (symbolp keywords) (= (length keywords) 1))
1813 ;       (font-lock-unset-menu)
1814 ;      (cond ((eq level t)
1815 ;            (setq level (1- (length keywords))))
1816 ;           ((or (null level) (zerop level))
1817 ;            ;; The default level is usually, but not necessarily, level 1.
1818 ;            (setq level (- (length keywords)
1819 ;                           (length (member (eval (car keywords))
1820 ;                                           (mapcar 'eval (cdr keywords))))))))
1821 ;      (setq font-lock-fontify-level (list level (> level 1)
1822 ;                                         (< level (1- (length keywords))))))))
1823 ;
1824 ;;; This should be called by `font-lock-unset-defaults'.
1825 ;(defun font-lock-unset-menu ()
1826 ;  ;; Deactivate less/more fontification entries.
1827 ;  (setq font-lock-fontify-level nil))
1828
1829 ;;; End of Menu support.
1830 \f
1831 ;;; Various regexp information shared by several modes.
1832 ;;; Information specific to a single mode should go in its load library.
1833
1834 ;; Font Lock support for C, C++, Objective-C and Java modes is now in
1835 ;; cc-fonts.el (and required by cc-mode.el).  However, the below function
1836 ;; should stay in font-lock.el, since it is used by other libraries.  sm.
1837
1838 (defun font-lock-match-c-style-declaration-item-and-skip-to-next (limit)
1839   "Match, and move over, any declaration/definition item after point.
1840 Matches after point, but ignores leading whitespace and `*' characters.
1841 Does not move further than LIMIT.
1842
1843 The expected syntax of a declaration/definition item is `word' (preceded by
1844 optional whitespace and `*' characters and proceeded by optional whitespace)
1845 optionally followed by a `('.  Everything following the item (but belonging to
1846 it) is expected to be skip-able by `scan-sexps', and items are expected to be
1847 separated with a `,' and to be terminated with a `;'.
1848
1849 Thus the regexp matches after point:    word (
1850                                         ^^^^ ^
1851 Where the match subexpressions are:       1  2
1852
1853 The item is delimited by (match-beginning 1) and (match-end 1).
1854 If (match-beginning 2) is non-nil, the item is followed by a `('.
1855
1856 This function could be MATCHER in a MATCH-ANCHORED `font-lock-keywords' item."
1857   (when (looking-at "[ \n\t*]*\\(\\sw+\\)[ \t\n]*\\(((?\\)?")
1858     (when (and (match-end 2) (> (- (match-end 2) (match-beginning 2)) 1))
1859       ;; If `word' is followed by a double open-paren, it's probably
1860       ;; a macro used for "int myfun P_ ((int arg1))".  Let's go back one
1861       ;; word to try and match `myfun' rather than `P_'.
1862       (let ((pos (point)))
1863         (skip-chars-backward " \t\n")
1864         (skip-syntax-backward "w")
1865         (unless (looking-at "\\(\\sw+\\)[ \t\n]*\\sw+[ \t\n]*\\(((?\\)?")
1866           ;; Looks like it was something else, so go back to where we
1867           ;; were and reset the match data by rematching.
1868           (goto-char pos)
1869           (looking-at "[ \n\t*]*\\(\\sw+\\)[ \t\n]*\\(((?\\)?"))))
1870     (save-match-data
1871       (condition-case nil
1872           (save-restriction
1873             ;; Restrict to the LIMIT.
1874             (narrow-to-region (point-min) limit)
1875             (goto-char (match-end 1))
1876             ;; Move over any item value, etc., to the next item.
1877             (while (not (looking-at "[ \t\n]*\\(\\(,\\)\\|;\\|\\'\\)"))
1878               (goto-char (or (scan-sexps (point) 1) (point-max))))
1879             (goto-char (match-end 2)))
1880         (error t)))))
1881 \f
1882 ;; Lisp.
1883
1884 (defconst lisp-font-lock-keywords-1
1885   (eval-when-compile
1886     (list
1887      ;;
1888      ;; Definitions.
1889      (list (concat "(\\(def\\("
1890                    ;; Function declarations.
1891                    "\\(advice\\|varalias\\|alias\\|generic\\|macro\\*?\\|method\\|"
1892                    "setf\\|subst\\*?\\|un\\*?\\|"
1893                    "ine-\\(condition\\|\\(?:derived\\|minor\\)-mode\\|"
1894                    "method-combination\\|setf-expander\\|skeleton\\|widget\\|"
1895                    "function\\|\\(compiler\\|modify\\|symbol\\)-macro\\)\\)\\|"
1896                    ;; Variable declarations.
1897                    "\\(const\\(ant\\)?\\|custom\\|face\\|parameter\\|var\\)\\|"
1898                    ;; Structure declarations.
1899                    "\\(class\\|group\\|theme\\|package\\|struct\\|type\\)"
1900                    "\\)\\)\\>"
1901                    ;; Any whitespace and defined object.
1902                    "[ \t'\(]*"
1903                    "\\(setf[ \t]+\\sw+)\\|\\sw+\\)?")
1904            '(1 font-lock-keyword-face)
1905            '(9 (cond ((match-beginning 3) font-lock-function-name-face)
1906                      ((match-beginning 6) font-lock-variable-name-face)
1907                      (t font-lock-type-face))
1908                nil t))
1909      ;;
1910      ;; Emacs Lisp autoload cookies.
1911      '("^;;;###\\(autoload\\)" 1 font-lock-warning-face prepend)
1912      ))
1913   "Subdued level highlighting for Lisp modes.")
1914
1915 (defconst lisp-font-lock-keywords-2
1916   (append lisp-font-lock-keywords-1
1917    (eval-when-compile
1918      (list
1919       ;;
1920       ;; Control structures.  Emacs Lisp forms.
1921       (cons (concat
1922              "(" (regexp-opt
1923                   '("cond" "if" "while" "let" "let*"
1924                     "prog" "progn" "progv" "prog1" "prog2" "prog*"
1925                     "inline" "lambda" "save-restriction" "save-excursion"
1926                     "save-window-excursion" "save-selected-window"
1927                     "save-match-data" "save-current-buffer" "unwind-protect"
1928                     "condition-case" "track-mouse"
1929                     "eval-after-load" "eval-and-compile" "eval-when-compile"
1930                     "eval-when"
1931                     "with-category-table"
1932                     "with-current-buffer" "with-electric-help"
1933                     "with-local-quit" "with-no-warnings"
1934                     "with-output-to-string" "with-output-to-temp-buffer"
1935                     "with-selected-window" "with-syntax-table"
1936                     "with-temp-buffer" "with-temp-file" "with-temp-message"
1937                     "with-timeout" "with-timeout-handler") t)
1938              "\\>")
1939             1)
1940       ;;
1941       ;; Control structures.  Common Lisp forms.
1942       (cons (concat
1943              "(" (regexp-opt
1944                   '("when" "unless" "case" "ecase" "typecase" "etypecase"
1945                     "ccase" "ctypecase" "handler-case" "handler-bind"
1946                     "restart-bind" "restart-case" "in-package"
1947                     "cerror" "break" "ignore-errors"
1948                     "loop" "do" "do*" "dotimes" "dolist" "the" "locally"
1949                     "proclaim" "declaim" "declare" "symbol-macrolet"
1950                     "lexical-let" "lexical-let*" "flet" "labels" "compiler-let"
1951                     "destructuring-bind" "macrolet" "tagbody" "block"
1952                     "multiple-value-bind"
1953                     "return" "return-from"
1954                     "with-accessors" "with-compilation-unit"
1955                     "with-condition-restarts" "with-hash-table-iterator"
1956                     "with-input-from-string" "with-open-file"
1957                     "with-open-stream" "with-output-to-string"
1958                     "with-package-iterator" "with-simple-restart"
1959                     "with-slots" "with-standard-io-syntax") t)
1960              "\\>")
1961             1)
1962       ;;
1963       ;; Exit/Feature symbols as constants.
1964       (list (concat "(\\(catch\\|throw\\|featurep\\|provide\\|require\\)\\>"
1965                     "[ \t']*\\(\\sw+\\)?")
1966             '(1 font-lock-keyword-face)
1967             '(2 font-lock-constant-face nil t))
1968       ;;
1969       ;; Erroneous structures.
1970       '("(\\(abort\\|assert\\|error\\|signal\\)\\>" 1 font-lock-warning-face)
1971       ;;
1972       ;; Words inside \\[] tend to be for `substitute-command-keys'.
1973       '("\\\\\\\\\\[\\(\\sw+\\)]" 1 font-lock-constant-face prepend)
1974       ;;
1975       ;; Words inside `' tend to be symbol names.
1976       '("`\\(\\sw\\sw+\\)'" 1 font-lock-constant-face prepend)
1977       ;;
1978       ;; Constant values.
1979       '("\\<:\\sw+\\>" 0 font-lock-builtin-face)
1980       ;;
1981       ;; ELisp and CLisp `&' keywords as types.
1982       '("\\&\\sw+\\>" . font-lock-type-face)
1983       ;;
1984 ;;; This is too general -- rms.
1985 ;;; A user complained that he has functions whose names start with `do'
1986 ;;; and that they get the wrong color.
1987 ;;;      ;; CL `with-' and `do-' constructs
1988 ;;;      '("(\\(\\(do-\\|with-\\)\\(\\s_\\|\\w\\)*\\)" 1 font-lock-keyword-face)
1989       )))
1990   "Gaudy level highlighting for Lisp modes.")
1991
1992 (defvar lisp-font-lock-keywords lisp-font-lock-keywords-1
1993   "Default expressions to highlight in Lisp modes.")
1994 \f
1995 (provide 'font-lock)
1996
1997 ;;; arch-tag: 682327e4-64d8-4057-b20b-1fbb9f1fc54c
1998 ;;; font-lock.el ends here